23.2.4 例: 風向風力記号 (Example: windbarbs)

本節で示す 3 種類の風向風力記号 (windbarb) のマークは、以下のデモで使 用されているフルセットから抜きだしたものです。 windbarbs.dem

    #
    # 5, 25, 50 ノットの風力を示す風向風力記号
    # 5 列の plot コマンドで一定の大きさで回転させる
    #     plot with marks using x:y:scale:scale:angle units gxx

    $MARK_5 <<EOM
    0        0        1
    0        1        1

    0        0.870    1
    0.235    0.956    1
    EOM

    $MARK_25 <<EOM
    0        0        1
    0        1        1

    0        1        1
    0.470    1.171    1

    0        0.870    1
    0.470    1.041    1

    0        0.740    1
    0.235    0.826    1
    EOM

    $MARK_50 <<EOM
    0        0        1
    0        1.100    1

    0        0.900    3
    0.470    1.071    3
    0        1.100    3
    0        0.900    3
    EOM

    set mark  5 $MARK_5   title " 5 knots" fill solid
    set mark 25 $MARK_25  title "25 knots" fill solid
    set mark 50 $MARK_50  title "50 knots" fill solid

    unset border; unset tics
    set key horizontal reverse Left samplen 1 height 3
    set xrange [0:10]
    set yrange [0:8]
    SIZE = 0.05     # 矢羽根のサイズをグラフ幅の 5% に (単位 gxx)

    plot [t=1:9:2] '+' using (t):(6):(SIZE):(SIZE):(36*t) notitle \
           with marks mt 5 units gxx, \
         [t=1:9:2] '+' using (t):(4):(SIZE):(SIZE):(15*t) notitle \
           with marks mt 25 units gxx, \
         [t=1:9:2] '+' using (t):(2):(SIZE):(SIZE):(25*t) notitle \
           with marks mt 50 units gxx, \
         keyentry with marks mt  5 ps 4 lc "black" title "5 knots", \
         keyentry with marks mt 25 ps 4 lc "black" title "25 knots", \
         keyentry with marks mt 50 ps 4 lc "black" title "50 knots"