gnuplot に関する情報やメモ (2007)

ページが長いので「しおり」の仕組みを用意してみました。「しおり用」と書かれた所をクリックしてからブックマークに入れると、それはページの先頭ではなく、その箇所へのブックマークになります。
(03/03 2006)

(12/15 2007) (しおり用)
gnuplot Q&A 掲示板で、松岡＠名古屋大さんから、png terminal (gd ドライバ) で PostScript の Symbol フォントのような記号 (ギリシャ文字や簡単な数式記号) を使いたい場合、Unix の場合はどうするのかという質問がありました (1668 番の記事「Unix user は png terminal でどうやって symbol を使うのでしょう」)。色々長い話になりますので、独立して以下にまとめます。

Linux では "Microsoft TrueType core font" という TrueType フォントが広く流布していて、ここには MS-Windows では有名な Times, Courier, Arial などのフォントが含まれているのですが、 symbol.ttf は含まれていません。よってこれでは出せないのでは、という話だったようです。

postpcript terminal では、Symbol フォントを指定すれば、例えば 'abcdefg' という文字列がギリシャ文字の小文字 'αβχδεφγ' が表示されるのですが、例えば OpenOffice.org 付属の Symbol フォント opens___.ttf は、 Unicode エンコーディングらしく、 gd ドライバではうまくいかない、ということのようでした。

これに対して、松田＠東京電機大さんが、いくつかのフォントのテストを行った結果を公開されました。
- OpenOffice.org 付属の Symbol フォント opens___.ttf、 ghostscript 付属の Symbol フォント s050000l.pfb (Type 1)、 Acrobat Reader 付属の Symbol フォント SY______.PFB (Type 1) はいずれも gd ドライバではうまくいかず、 MS-Windows に付属している symbol.ttf ならうまくいく
- MS-Windows の symbol.ttf も Microsoft Typography から入手できるのでは。
- フリーのギリシャ文字の TrueType フォント (Aristarcoj2.ttf 等) を使用する、という手もある
しかし、これを拝見していて、ふと以下のことを疑問に思いました:
うちで gnuplot の EPS 出力を表示する gv (Ghostscript 経由) では Symbol フォントがちゃんと表示されるが、それは s050000l.pfb のフォントを使って表示されているはずで、それがなぜ gdlib 経由の gd ドライバだとうまくいかないのか
それで、gnuplot の gd ドライバ、gd ライブラリ、およびそれが内部で使用している FreeType ライブラリのソースを見ながらテストしてみると、次のようなことがわかりました。
- FreeType からは、s050000l.pfb の encode charmap は 'Unicode' と 'Adobe_Custom' の 2 つあるように見え、このうち 'Adobe_Custom' charmap を使用すれば PostScript と同じ文字コードでいけそうなんだけど、 gdlib からは標準的に 'Unicode' charmap の方が使用されてしまう
- 'Unicode' charmap でも「ちゃんと」Unicode 文字番号でフォント指定をすれば、ちゃんと表示できる
- gdlib では 'Unicode' 文字は '&#nnn;' (10 進) や '&#xnnn;' (16 進) の指定が可能なので、これで適切なコード (例えばギリシャ文字の場合は 913 (391H) 辺りから始まる) を指定すれば、
  set label 'αβγ' at 0.1,0.9 font "s050000l.pfb,14" # 16 進 set label 'αβγ' at 0.1,0.9 font "s050000l.pfb,14" # 10 進
  のようにして png terminal でも一応使える
- opens___.ttf の方は、Unicode の特別な領域に文字が入っているので、このフォントを利用するのは一覧表がないと難しそう
- gdlib-2.0.34 以降 (+ FreeType-2.1.3 以降) の場合は、 'Adobe_Custom' charmap 指定もできるようになっている
- CVS 版の最新の gnuplot の gd ドライバでも、「gnuplot encoding (set encoding) が utf8 ではなく、 enhanced text mode であり、かつフォント名が "Symbol"」の場合のみ、自動的に 'Adobe_Custom' charmap が選択されるようになっているので、s050000l.pfb へのシンボリックリンクとして Symbol.pfb を作成すると、以下のようにして PostScript と同じように Symbol フォントが使えるようになる:
  set term png enhanced set out 'test.png' set label "{/Symbol=14 \141\142\143}" at 0.1,0.9 set label "{/* \141\142\143}" at 0.1,0.8 font "Symbol,14" # どちらも同じ
  ただし、この文字列は "" で囲む必要がある (通常は "" 内だと \\141 のようにしないといけないはず ?)
上のことを確認するのには、 FreeType ライブラリのテストプログラムと gdlib の perl ラッパーである GD.pm を使ったテストプログラムを書いたのですが、それらを少し修正したものを以下にあげておきます。使用法は、それぞれ先頭部分にコメントとして書いておきます。

なお、現在の gdlib (2.0.34 以降) では encode charmap はある程度自動的に選択される (されてしまう) のですが、 Adobe_Custom は指定できるようになっています。しかし、GD.pm (2.35) ではその指定がまだできません。よって、その辺りを改良して、Adobe_Custom 以外に Apple_Roman や MS_Symbol の encode charmap も選択できるようにする gdlib 用のパッチ、そしてそれに対応した GD.pm 用のパッチも作成してみましたので、それもついでに公開します。
- FreeType (2.X) を利用した、フォント (.ttf, .pfb, .pfa) のグリフと文字コードの対応表の出力ソフト
  testft2.c (4070 Byte)
- GD.pm を利用した、文字コード番号表から指定フォントのグリフの画像の一覧表を作成するソフト
  testgd5.pl (4700 Byte)
- gdlib で Apple_Roman, MS_Symbol の encode charmap を指定できるようにするパッチ (gd-2.0.34 以降; 一応 gd-2.0.35 用)
  gd-charmap-1.diff (1134 Byte)
- GD.pm で Adobe_Custom, Apple_Roman, MS_Symbol の encode charmap を指定できるようにするパッチ (一応 GD-2.35 用)
  GD-charmap-1.diff
これらを利用して作成したサンプルを以下に置きます。
- OpenOffice.org の opens___.ttf:
  - opens___.tbl1 (16423 Byte) (Apple Unicode でのグリフ番号と文字コードの対応表)
  - opens___.tbl2 (969 Byte) (Apple_Roman でのグリフ番号と文字コードの対応表)
  - opens___.tbl3 (16423 Byte) (MS-Windows Unicode でのグリフ番号と文字コードの対応表)
  - opens___-u-1.png (31693 Byte) (.tbl1 のグリフ表; 1 枚目)
  - opens___-u-2.png (32196 Byte) (.tbl1 のグリフ表; 2 枚目)
  - opens___-u-3.png (32985 Byte) (.tbl1 のグリフ表; 3 枚目)
  - opens___-u-4.png (21127 Byte) (.tbl1 のグリフ表; 4 枚目)
- gs 付属の s050000l.pfb:
  - s050000l.tbl1 (3419 Byte) (MS-Windows Unicode でのグリフ番号と文字コードの対応表)
  - s050000l.tbl2 (3253 Byte) (Adobe_Custom でのグリフ番号と文字コードの対応表)
  - s050000l-u.png (30187 Byte) (.tbl1 のグリフ表)
  - s050000l-AC.png (21533 Byte) (Adobe_Custom での 00H-ffH のグリフ表)
(cf. 「情報やメモ (03/03 2011)」, 「情報やメモ (07/18 2014)」)
(12/14 2007) (しおり用)
下の「情報やメモ (12/03 2007)」で書いた "splot title 2" のような書き方を行うパッチですが、 CVS 版 gnuplot で採用されました。
(12/03 2007) (しおり用)
下の「情報やメモ (11/09 2007; no.2)」で、splot では "title 2" のような使い方ができない、と書きましたが、以下のようなパッチを当てると、一応使えるようになるみたいです。
- splot-title1.diff (3058 Byte)
ただし、かなり適当なので、これを当てることで他の部分で問題が出るかもしれません。何かこの機能を splot では意図的に使わないようにしているようにも見えるソースコードがあるのですが、その部分をよく理解していませんので、何か問題が起こる可能性は十分あります。

一応 CVS 版のソースへのパッチですが、 gnuplot-4.2.2 にも当たるようです。問題がなさそうなら本家にも投げてみたいと思います。

(cf. 「情報やメモ (12/14 2007)」)
(11/22 2007) (しおり用)
2 ちゃんねるの掲示板「gnuplot を使おう。その 2」(アドレスはリンクリスト参照) に書かれた情報について、多少気になるものがありましたので、少し書いておきます。
- with point で点のデータを書くときに、座標以外のデータ (3 列目) を使って各点に色を指定することはできますか、という質問がありました (262)。
  
  それに対して、
  - 3 列目の数字に応じてファイルを分割する
  - awk を使って、
```
      plot "'<awk '{if ($3 == 1) print}' data" pt 1,\
      "'<awk '{if ($3 == 2) print}' data" pt 2,\
      ...
      
```
    のようにする
  のような回答がありました。
  
  確かにそれらも解の一つなのですが、 awk を使わなくても上と同等のことを行うことも可能ですし、実は現在の gnuplot-4.2 なら、もっと柔軟な方法で行うことも可能です。それらを以下に紹介しましょう。
  - awk なしでデータを選択して表示する:
    これは、対象となるデータ以外を無効データとして扱うことで可能となります。無効データにするには、1/0 を利用します:
```
      choose(n,y,z) = (z==n)?y:1/0
      plot 'data' using 1:(choose(1,$2,$3)) with point pt 1,\
      '' using 2:(choose(2,$2,$3)) with point pt 2,\
      '' using 3:(choose(3,$2,$3)) with point pt 3
      
```
    なお、これなら gnuplot-3.7 でも可能ですが、点種を変えているので点 (point) の形も変わってしまいます。
  - gnuplot-4.2 以降の rgbcolor variable を使う:
    gnuplot-4.2 以降には、linetype の指定として色を指定できますが、その指定の一つに "rgbcolor variable" というものがあり、これは追加の入力列を必要とし、それを色指定とみなす、というもので、点毎、線分毎に色を変えて表示を行うことを可能にします。この方法ならば点の形は共通で、色だけを変えることができます。詳しくは、"help rgbcolor" を参照してください。以下に使用例をあげます:
```
      cv(n)=(n==1)?16711680:(n==2)?16753920:(n==3)?6737322:(n==4)?13481421:0
      plot 'data' using 1:2:(cv($3)) with points lt rgbcolor variable
      
```
    cv(n) が 3 列目のデータに応じて色を与える関数です。なにやら大きな数字が書いてありますが、これは rgbcolor variable がいわゆる 24bit RGB 形式の数字 (RR * 65536 + GG * 256 + BB) であるとみなすためで、上の 4 つの数字は、それぞれ PNG terminal のデフォルトの色である、 0xff0000, 0xffa500, 0x66cdaa, 0xcdb5cd (help png 参照) を指定したものです。16 進数を直接指定することはできません。
    
    なお、gnuplot-4.2 のマニュアルには、 rgbcolor variable は 3D (splot) でしか使えない、と書いてあるようですが、一応 plot でも使えるようです。
- plot で、x の範囲毎に with dots の色を変えたい、という質問がありました (267)。
  
  これも、上と同様に awk を使った回答があげられていましたが、これも上とほぼ同じ方法で awk なしでできます:
```
    choose(x1,x2,x,y) = (x>=x1 && x<x2)?y:1/0
    plot 'data' using 1:(choose(0,1000,$1,$2)) with dots lt 1,\
    '' using 2:(choose(1000,2000,$2,$3)) with dots lt 2,\
    '' using 3:(choose(2000,3000,$2,$3)) with dots lt 3
    
```
  gnuplot-3.7 以降で使えると思います。
(11/19 2007) (しおり用)
2 ちゃんねるの掲示板「gnuplot を使おう。その 2」(アドレスはリンクリスト参照) に書かれた情報について、多少気になるものがありましたので、少し書いておきます。
- PostScript 出力で、タイトルや凡例に日本語を使いたいが、「set term postscript eps enhanced "fontname"」の fontname に何を指定してもうまくいかない、という話がありました (259)。
  
  元記事の人は、どうやら ttf ファイル名 (TrueType フォント) を指定してみたようですが、それでは出ないのは当然です。指定しなければいけないのは日本語 PostScript フォント名で、標準的には Ryumin-Light-EUC-H, GothicBBB-Medium-EUC-H 等です。
  
  ただし、ghostscript の設定によっては、 TrueType フォントを日本語フォントとして使えるようになっているかもしれません (gv などで) が、その場合も実際の TrueType フォントファイル名ではなく、 ghostscript の設定 (CIDFnmap 等) によって使えるようになっているフォント名を指定する必要があります。例えば、CIDFnmap に、
  /Sazanami-Mincho (/usr/local/share/font/ttf/sazanami-mincho.ttf) ;
  のような設定があれば、この Sazanami-Mincho が PostScript フォント名になりますので、 Sanazami-Mincho-EUC-H のようなフォント名で gnuplot で使用してそれを gv などで見ることができます。
  
  ただし、set term post の行にフォントを指定してしまうと、数字などのフォントもすべてこのフォントに変わってしまうので、本当は変えたいフォントだけ指定する方がいいでしょう。元記事の人が使っている gnuplot-4.2.2 では残念ながら key のフォントを変更することはできませんが、 CVS 版の gnuplot (4.3) ならば key のフォントも指定できますので、以下のようにして、タイトルと凡例の両方で日本語が使えます:
  
  set term post eps
  set output 'test.eps'
  set title "日本語タイトル" font "Ryumin-Light-EUC-H,17"
  set key font "GothicBBB-Medium-EUC-H,14"
  plot sin(x) title "正弦函数のグラフ"
  set out
- 水平に伸びる棒グラフを書くために、x 軸と y 軸を入れかえたい、という話がありました (247)。
  
  これは、どのような出力形式で出したいのかは不明ですが、 gnuplot では x=f(y) のグラフを (棒グラフを書く形式で) 自然に書くことはできませんから、できた画像を回転するのが自然でしょう。ただし、そのためには、以下のような準備が必要となるでしょう:
  - set size で縦横比を調整する
  - 軸の見出しを左と下に出したいならば、 x1 軸 (下) と y2 軸 (右) を使っておいて、それでできた画像を時計回りに 90 度回転する
  - x1 軸と y2 軸の見出しを回転しておく (set xtics rotate, set y2tics rotate)
  - set title の代わりに、「set label at x0,y0 "タイトル" rotate by 90」を使う
  ただし、CVS 版でもさすがに key の回転はできません (位置は移動できますが) から、 key の処理は別に行う必要があると思います。
- これはよくある質問ですが、「gnuplot ってなんて発音するんですか」というものがありました (256)。
  
  これに対しては、たまに「ニュープロット」と読むべき、なる意見を目にすることもあるのですが、これは開発者から正式な見解がでているわけではないので、個人的には、わかりやすい読み方をするのであればどう発音してもいいのだろうと思っています。実際、私は「ニュープロット」ではなく、多分多くの人がそう読むであろう「グニュープロット」という読み方を使っています。
  
  「ニュープロット」であるという根拠は、多分 gnuplot の FAQ の「1.2 それはどこから来て、そしてなぜ gnuplot と呼ばれているのですか」に書いてある次の話だと思います (正確には原文を参照のこと):
  gnuplot は GNU プロジェクトや FSF とは、極わずかの意味を除けば少しも関係ありません。我々のソフトウェアは完全に独立にデザインされたもので、そして "gnuplot" という名前は実は妥協によるものです。私は "llamaplot" と呼びたかったし、 Colin は "nplot" と呼びたかったのです。そして、我々は "newplot" がいいだろうということで合意しましたが、しかしそのときその名前を持つ、絶対的におぞましい Pascal のプログラムを計算機科学部でたまに使っていることを知りました。それで私は "gnuplot" がいいごろ合わせになるとして、後で Colin もそれに同意したのです。
  ここには、確かに作者は一旦「ニュープロット (newplot)」としてそれを「gnuplot」にした、と書かれてありますが、「gnuplot をどう発音すべきか」については何も述べていません。だから私の意見では、「ニュープロット」でも「グニュープロット」でもどちらでもいいのではないかと思っています。
(cf. 「情報やメモ (10/16 2008; no.2)」)
(11/09 2007; no.2) (しおり用)
gnuplot Q&A 掲示板での見聞き等で得た情報を備忘録として書いておきます。
- 松岡＠名古屋大さんから、 Cygwin 用の CVS 版 gnuplot (4.3) のバイナリの公開のお知らせがありました。 gcc-4.2.1 を使っているせいか、大分軽いそうです。
  
  (1623 の記事から始まるスレッド「Cygwin 版 gnuplot 4.3 (CVS) 版のバイナリーを公開しています」)
- Cygwin 用の gnuplot の X 用オプション (-geometry) に関して、 Octave で使用する場合、 Octaverc にそれを書くことで制御できるという報告がありました。
  
  そこから発展して、環境変数 GNUPLOT_DRIVER_DIR に関する挙動が CVS 版で変わったこと、およびこの変数の意味や必要性に関する議論が行われました。
  
  なお、最初の質問は "man X(1)" の "1" に関する話でしたが、これは Unix のオンラインマニュアルにおける慣習で、別のオンラインマニュアルを参照する場合に、 "X(1)" のように、マニュアルセクションのセクション番号をつけて書くならわしになっています。 Unix のオンラインマニュアルでは、別セクションのマニュアル名が一致してしまった場合のために、必要ならセクション番号を指定して読めるようになっているので、マニュアルで参照する場合はセクション番号も書くことになっているわけです。
  
  (1625 の記事から始まるスレッド「X(1) マニュアルページ」)
- 松岡＠名古屋大さんから、 DJGPP 版の gnuplot-4.2.2 バイナリに関する報告がありました。
  
  私はもう長いことその辺は触っていませんが、それなりに利用価値はあると思います。 MS-Windows に移行していない (移行できない) MS-DOS ユーザなんてのはもうあまりいないかもしれませんが (個人的には 0 ではないと信じています)、そういう環境を利用している人には重要ですね。
  
  (1637 の記事「gd422dj2.zip」)
- plot だけのスクリプトを wgnuplot のコマンドラインから食わせると、すぐに終了してしまうが、グラフを残してかつ対話型のターミナルを残すには、という質問がありました。スクリプトに "pause -1" を入れるとグラフは残りますが、対話型ターミナルが出ません。
  
  これに対して、
  - wgnuplot -persist load.gp
  - wgnuplot -noend load.gp
  - wgnuplot load.gp - で、ウィンドウバーのクリックで対話型ターミナルを開く
  - スクリプトにエラーがあった場合に止まるようにするためには、以前この掲示板で多少議論があった (pgnuplot を利用)
  などの回答がありました。
  
  (1638 の記事から始まるスレッド「コマンドラインからの使用に関して」)
- cgm terminal のフォントサイズの問題に対する情報が報告されました。これは現在は修正されています (cf. 「情報やメモ (11/09 2007)」)。で、ついでに、以前のフォント指定方法の「set term cgm "fontname" fontsize」が、最近の指定方法である「set term cgm font "fontname, fontsize"」のような書式に変更されたようです。徐々にこのような統一された記法になっていくんだと思いますが、まだ多くの terminal ドライバは古い記法のままになっています。
  # だれかまとめてやってくれないかな ?
  
  (1643 の記事から始まるスレッド「cvs 版 gnuplot cgm terminal の old syntax bug が Fix されました」)
- 極座標モードでは、曲線を bezier では補間 (smooth) できるみたいであるが、 cspline による補間はできないのか、という質問がありました。
  
  実際には cspline でもできないわけではなく、問題なく使えます。ただ、bezier で補間がうまくいって、cspline でだめ、ということは、多分そのデータの方が cspline に向かないデータなんではないかと思います。 cspline のような補間は、データによっては元のデータからはだいぶ外れたものになることもありえます。しかも gnuplot の補間は、極座標データを xy 座標に直した後で補間しますから、データからは予想できないものになる、という可能性もあります。
  
  そのようなことを見越して、松田＠東京電機大さんが、極座標データの状態で cspline 補間して、それを xy 座標に直したものを書く、というスクリプトサンプルを紹介しておられます。松田＠東京電機大さんお得意の table 出力を利用して、元データを cspline 補間した table データを作成し、それを改めて極座標モードにして描画する、という手法です。
  
  (1646 の記事から始まるスレッド「極座標での曲線表示」)
- VB (Visual Basic) で書くプログラムから gnuplot を呼び出すには、という質問がありました。
  
  それに対して、
  - VB でパイプを実現する「パイプマン」なるフリーソフト (DLL) がある
  - パイプなら .NET なら System.Diagnostics クラスを利用すればいいし、パイプでないなら Win32API を使って wgnuplot.exe のウィンドウに gnuplot のコマンドを送ればいい
  という回答がありました。
  
  元記事の人は、pgnuplot.exe を利用して、 System.Diagnostics の ProcessStartInfo クラスを利用してうまくいったようで、サンプルコードも上げてあります。
  # 私は VB も .NET もまるで知りませんので (?_?)
  
  (1651 の記事から始まるスレッド「VB から呼び出す方法」)
- gnuplot-4.2.X では、データに含まれている文字列を利用して各グラフにタイトルをつける、
  plot 'data' using 1:2 title 2
  のような使い方ができるが、splot ではうまくいかない、という質問がありました。
  
  調べてみると、マニュアル等には明示的には示されていませんが、 splot では "title [n]" のような使用法はまだ実装されていないようです (CVS 版でも)。
  
  回避策としては、 splot では key を書かずに (unset key)、それに multiplot で plot のグラフを重ねてそちらで key だけ書く、とごまかす手はあります:
```
    set multiplot
    unset key
    splot "data" using 1:2:3
    set key
    unset border
    unset tics
    plot [0:1][0:1] "data" using 1:(1/0) title 2
    unset multiplot
    
```
  なお元記事の人は、 every を利用してデータをアニメーション化するときに、画面に現在が何ステップ目かを表示したい、という目的のようでしたが、 gnuplot の if + reread を使うなら、そこで使用されるパラメータを利用して、各ステップ毎に異なるタイトルを表示させればいいので、 gnuplot-4.2 以降の文字列関数を利用して、 reread する方で
```
    a=a+1
    splot "data" every ::a::a title sprintf("%d step",a) w p
    if (a<lasta) reread
    
```
  のようにすればいいでしょう。
  
  私なら key ではなくて、むしろグラフ全体のタイトルを
```
    a=a+1
    set title sprintf("%d step",a)
    splot "data" every ::a::a notitle w p
    if (a<lasta) reread
    
```
  のようにするでしょうか。
  
  元記事の方は、結局はステップ数ではなく、「sprintf("time = %f",a*dt)」のようにして利用したそうです。
  
  (1656 の記事から始まるスレッド「splot の title にデータファイルの文字列を渡したい」)
(cf. 「情報やメモ (12/03 2007)」)
(11/09 2007) (しおり用)
前回の報告 (07/30 2007; no.2)以後、現在の CVS 版に入れられた主な機能について紹介します (ChangeLog, manual の更新部分等より)。
- 一般的な機能
  - polar filledcurve のバグの修正
  - set encoding locale の追加
  - 曲面の隠面処理ルーチンの改良
  - 箱の描画時のバグの修正
  - show *range の現在の値の表示のバグの修正
  - splot 時の key の処理を 2D に合わせて改良
  - = と , 演算子の拡張/導入
  - Octave-2.9.X に対応した修正 (パイプ入力時のマウス処理) と、それに伴う refresh コマンド、plot の volatile オプションの追加
  - 対数軸を大きな範囲で使用している時の問題の修正
  - set encoding に utf8 オプションを追加
  - rgbcolor を設定した場合の問題の修正
  - y2 軸で with label を使用した場合の問題の修正
  - 読み出し専用変数 GPVAL_ERRNO, GPVAL_ERRMSG のサポートと reset コマンドの errors オプションのサポート
  - pause の文字列引数部分で文字列式もサポート
  - splot のユーザ定義の線種に関する問題の修正
  - 点を持つ線種に関する問題の修正
  - pm3d の depthorder オプションの追加
  - set key title を等高線 (contour) で使用したときの問題の修正
  - set bars に {front|back} オプションの追加
- terminal ドライバ
  - x11 terminal のバグの修正
  - cairopdf terminal に dashlength オプションが追加
  - cairopdf terminal, wxt terminal の改良
  - gd driver の改良/修正
  - PostScript terminal の長方形の塗り潰し時の問題の修正
  - cgm terminal のフォントサイズ指定の問題の修正
  - cairopdf terminal を pdfcairo に変更し、pngcairo terminal を追加
  - iris4d terminal の削除
  - PostScript terminal の、スペースの含まれるフォント名の問題の修正
  - PostScript terminal の prorogue ファイルを読む位置を修正
- その他
  - configure の改良
  - set timestamp の offset オプションに関するドキュメントの修正
  - 文字列変数を常に使えるように変更 (従来は configure 時に選択)
  - Mac OSX のコンパイラ用の修正
  - gnuplot.doc の行頭の 'F' (画像の埋め込み) のサポート
  - doc2texi.el の XEmacs 用の修正
- デモ
  - electron.dem のバグの修正
  - running_avg.dem (= と , による移動平均デモ) の追加
  - html/webify.pl のフォント指定の修正
set encoding の locale オプション、'=' や ',' 演算子、 {pdf|png}cairo terminal, GPVAL_ERR{NO|MSG} については既に下で説明してあります (cf. 「情報やメモ (08/06 2007)」, 「情報やメモ (08/31 2007)」, 「情報やメモ (10/11 2007)」, 「情報やメモ (10/19 2007)」)

その他で言うと、"set encoding utf8" は、現在は gd ドライバくらいでしか対応してはおらず、それも多分日本語が使えるかどうかとはあまり関係のないものだと思います。

Octave の問題は、ChangeLog を見ると、 Octave が一時ファイル経由でデータを gnuplot に渡すのではなくて、全部パイプでインラインデータとして渡すようになったため、その際のマウス機能が使えなくなったので、それへの対処である、という感じのようです。 Octave 2.9.X に関しては、「情報やメモ (07/30 2007; no.3)」にも多少情報があります。

(cf. 「情報やメモ (11/09 2007; no.2)」, 「情報やメモ (01/25 2008)」)
(10/25 2007) (しおり用)
2 ちゃんねるの掲示板「gnuplot を使おう。その 2」(アドレスはリンクリスト参照) に書かれた情報について、多少気になるものがありましたので、少し書いておきます。
- 例えば次のようなデータ:
```
    A 1 3 
    B 3 8 
    C 5 7 
    D 6 5 
    E 7 9 
    F 9 4 
    
```
  に対して、2 列目を x 座標、3 列目を y 座標として、 1 列目を x 軸の見出し (2 列目の x 座標のところ) に使用することはできないか、という質問がありました (234)。
  
  gnuplot-4.0 では、データを前処理して set label などを使うようなスクリプトを生成しないといけないでしょうが、 gnuplot-4.2 以降ならデータからラベル文字列を読みとって、軸の見出しにも使うことができますので、
  plot 'data' using 2:3:xticlabels(1) with linespoints
  のようにして簡単に実現できます。この、軸の見出しは、x 軸だけでなく、 y 軸、x2 軸、y2 軸、z 軸 (splot の場合) も使うことができます。詳しくは、help plot using xticlabels を参照してください。
- MS-Windows 用の wgnuplot は、 4.2 以降ファイル検索ディレクトリの仕様が変わった、という話がありました (225)。 4.0 以前は、以前実行した際の検索ディレクトリを覚えておいて検索してくれたのに、 4.2 以降では、常にカレントディレクトリを開くようになった、ということです。
  
  これは、多分以下のパッチの影響だろうと思われます:
```
    2006-08-09  Bastian Maerkisch  <bmaerkisch@web.de>

    SF Patch [1505261] wgnuplot: open file-open-dialog in current dir

    * src/win/wmenu.c (SendMacro): Windows XP uses a strange initial
    directory for the file open dialog. This patch forces the dialog to
    always open in the current directory. So now, if you change the
    directory via 'cd', the file open dialog opens where expected.
    
```
  既に「バグの修正」として取りこまれていますので、これ以後の wgnuplot ではそのような挙動になってしまいます。
  
  以前の挙動にするには、という意見でしたが、それはちょっと難しいと思います。強引にやるなら、その wmenu.c へのパッチを取り除いて自分で make するか、または 4.0 以前の wgnuplot を使うしかないのではないかと思います。
(cf. 「情報やメモ (10/16 2008; no.2)」)
(10/19 2007) (しおり用)
CVS 版 gnuplot (4.3) で、読み出し専用変数 GPVAL_ERRNO と GPVAL_ERRMSG がサポートされました。これらは、以下のような変数です。
- GPVAL_ERRNO: エラーが起きた場合 0 以外の値がセットされる
- GPVAL_ERRMSG: そのエラーメッセージがこの文字列変数に保存される
以前、 gnuplot Q&A 掲示板に、正確には少し違いますが以下のような質問がありました (716 番の記事「対話モードでの起動方法」。 cf. 「情報やメモ (01/30 2005)」):
「スクリプトなどを gnuplot に食わせると、エラーが起きてもそのまま終わってしまうが、エラーが起きた場合は対話モードにするようなことはできないか」
この GPVAL_ERRNO と "exit gnuplot" (exit や quit よりも強い) を組み合わせればそれが実現できるかもしれません。

例えば、gnuplot スクリプトの最後に、
```
    ....
    if ( GPVAL_ERRNO == 0 ) exit gnuplot
  
```
のように書いておいて、そのスクリプトを
```
    gnuplot script.gp -
  
```
のように最後に '-' をつけて実行します。この場合、もし script.gp の実行にエラーがなければ、 exit gnuplot によって script.gp の後ろの '-' も無視されて gnuplot は終了しますが、 script.gp の実行にエラーがあれば、 script.gp の次の '-' によって対話モードになることになります。

ただ、GPVAL_ERRNO がどんなときにセットされるか少し実験してみると、
- set output の出力ファイルへの書き出しができない
- font 指定されたフォントが見つからない
などの場合はこの GPVAL_ERRNO はセットされないようです。

そうなると、実際に良く遭遇するような問題の場合はこれがセットされず、結局は残念ながら上のようにしてもあまり意味がないような気がします。

(cf. 「情報やメモ (11/09 2007)」)
(10/11 2007) (しおり用)
CVS 版 gnuplot (4.3) で、 cairopdf terminal ドライバを拡張して、 cairo による PNG 出力がサポートされました。これで、PDF 出力と PNG 出力のドライバが、
- PDF 出力: pdf, pdfcairo
- PNG 出力: png, pngcairo
のようにそれぞれ 2 種類できたことになります (pdf terminal は pdflib を使用、png terminal は gdlib を使用)。なお、以前の cairopdf terminal は、pdfcairo terminal に名称変更されました。

それぞれのメリットについては、まだちゃんと調べたわけではないので、今後色々試したいとは思いますが、
- pdfcairo, pngcairo は fontconfig 経由でフォントを使用するので、日本語にも対応するし、色々なエンコード (Shift_JIS, EUC-JP, UTF-8) も特に意識しなくても対応する。
- pdfcairo, pngcairo はオプションもほぼ共通なので、フォント名を含めて、両者でスクリプトをほとんど変更せずに同様の出力が得られる。
といったことが想像されます。現在のそれぞれの terminal のオプションを以下に紹介します。
- pdfcairo:
```
  set term pdfcairo
    {{no}enhanced} {mono|color} {solid|dashed}
    {font <font>}
    {linewidth <lw>} {rounded|butt} {dashlength <dl>}
    {size <XX>{unit},<YY>{unit}}
  
```
- pngcairo:
```
  set term pngcairo
    {{no}enhanced} {mono|color} {solid|dashed}
    {transparent} {font <font>}
    {linewidth <lw>} {rounded|butt} {dashlength <dl>}
    {size <XX>{unit},<YY>{unit}}
  
```
- pdf:
```
  set terminal pdf {monochrome|color|colour}
    {{no}enhanced}
    {fname "<font>"} {fsize <fontsize>}
    {font "<fontname>{,<fontsize>}"}
    {linewidth <lw>} {rounded|butt}
    {solid|dashed} {dl <dashlength>}}
    {size <XX>{unit},<YY>{unit}}
  
```
- png:
```
  set terminal png 
    {{no}transparent} {{no}interlace}
    {{no}truecolor} {rounded|butt}
    {linewidth <lw>} {dashlength <dl>}
    {tiny | small | medium | large | giant}
    {font <face> {<pointsize>}}
    {size <x>,<y>} {{no}crop}
    {{no}enhanced}
    {<color0> <color1> <color2> ...}
  
```
現時点では、png terminal の方が pngcairo terminal よりもオプションは多いようですが、 pdf と pdfcairo ではオプションは違いはないようです。 pdf terminal では日本語がそもそも使えませんから、 PDF 出力に関しては、pdfcairo の方が優位と言えるでしょう。

PNG 出力では、png terminal の方が interlace, truecolor, crop, 色指定などのオプションで優位なようですが、日本語の利用に関して言えば、以下のような状況だろうと思いますので、その点ではやや pngcairo が優位な気がします。
- png terminal:
  - 日本語指定をして作った gdlib (-DJISX0208) では、 EUC-JP, Shift_JIS のエンコードの日本語が使用できるが、 UTF-8 は使用できず、日本語指定をせずに作った gdlib では、 UTF-8 のエンコードの日本語が使用できるが、 EUC-JP, Shift_JIS は使用できないので、それぞれ用の gdlib を用意するか、スクリプトのコードを変換する必要がある。
  - フォントは TrueType フォントか Adobe Type 1 (*.pfa) フォントが使用できるが、そのフォント名の絶対パスを指定する必要がある (置き場所に対して環境変数 GDFONTPATH を使うことも可能)
- pngcairo terminal:
  - スクリプトのエンコードは、必要なら "set encoding locale" を実行することで、実行時の環境のエンコーディングをそのまま利用できる (EUC-JP や UTF-8 も)。
  - フォントは fontconfig 経由なので、それが管理するフォントを、フォント名の指定だけで利用できる
以下に実行例を少し示します。まずは、test コマンドの出力から。いずれも表示しているのは screenshot の GIF 画像で、リンク先として PDF, PNG 画像を置きます。
- pdfcairo terminal:
- pngcairo terminal:
- pdf terminal:
- png terminal:
デフォルトのフォントが {pdf,png}cairo ではやや大きい (特に pdfcairo) ようなので、だいぶ感じが違って見えますが、 pdfcairo と pngcairo では線の色と点種が共通であることが特徴です。 png terminal は、点種はそれに近いのですが、少し違いがありますし、色の並びはだいぶ違います。 pdf terminal は色も点種もだいぶ違うことがわかります。また、デフォルトのフォントでは、png terminal は回転が使えません (TrueType フォントなら回転できます)。

次は、日本語のテストです。pdf terminal は日本語が使えないので、他の 3 つに対して以下のようなスクリプトを食わせます (環境変数 GDFONTPATH を適当に設定した上で):
```
  # pngcairo
  set encoding locale
  set term pngcairo
  set out "pngcairo-2.png"
  set key font "IPAMincho,12"
  set title "This is test (これはテスト)" font "Sazanami Gothic,17"
  set xlabel "漢字: これは xlabel" font "IPAGothic,24"
  set ylabel "漢字: これは ylabel" font "IPAMincho,24"
  set label "回転する日本語フォント" rotate by 60 \
          font "Sazanami Mincho,24" tc lt 3
  plot sin(x) title "漢字: これは sin(x)"
  set out
  # pdfcairo
  set term pdfcairo
  set out "pdfcairo-2.pdf"
  replot
  set out
  # png
  reset
  set term png
  set out "pngold-2.png"
  set key font "ipam.ttf,12"
  set title "This is test (これはテスト)" font "sazanami-gothic.ttf,17"
  set xlabel "漢字: これは xlabel" font "ipag.ttf,24"
  set ylabel "漢字: これは ylabel" font "ipam.ttf,24"
  set label "回転する日本語フォント" rotate by 60 \
          font "sazanami-mincho,24" tc lt 3
  plot sin(x) title "漢字: これは sin(x)"
  set out
  
```
この出力は以下の通りです。
- pdfcairo terminal:
- pngcairo terminal:
- png terminal:
フォントは同じ TrueType フォントを使用しているのですが、だいぶ感じが違うことがわかると思います。特に pdfcairo terminal の出力はフォントがかなり大きくなってしまっているのですが、フォントの単位が違うのでしょうか。そうだとすると、その点は pngcairo と pdfcairo は共通のスクリプトが使えない、ということになります。ただ、xtics のフォントは pngcairo と pdfcairo でほぼ同じ大きさに見えるので、もしかしたらバグかもしれません。

png terminal と pngcairo terminal の出力を比較すると、日本語文字の幅と位置の認識に差があるようで、余白部分の大きさや上下の位置合わせに違いが見られます。 png terminal の方は xlabel が xtics の見出しと重なっていることから、 png terminal (gdlib) よりも pngcairo (cairo) の方が多分正しいのだろうと思いますが、 pngcairo は xlabel の下が切れてしまっているので、その点は完全ではないような気もします。

また、key のフォントが png terminal と pngcairo terminal で違っているように見えますが、これは、うちの gdlib には「情報やメモ (03/08 2005)」で紹介したパッチを当ててあるため、小さいフォントに対して埋め込みビットマップを使ったり使わなかったりするからです。 key のフォントは回転しないため埋め込みビットマップが使われています。 pngcairo は、小さいフォントでも埋め込みビットマップを使っていないようで、それでフォントが違って見えます。しかも、pngcairo は埋め込みビットマップを使わないので、「情報やメモ (03/08 2005)」のような問題も起きず、回転は常にうまく行きます。

(cf. 「情報やメモ (11/09 2007)」)
(09/23 2007) (しおり用)
「情報やメモ (09/08 2007)」, 「情報やメモ (09/13 2007)」, 「情報やメモ (09/14 2007)」で始めた、CVS gnuplot (4.3) の「あまり意味のないデモ」の 5 つ目を紹介します。
1. グルグル渦巻き
  これも単なるアニメーションですが、今度はグラフ描画によるアニメーションを一つ紹介します。渦巻きを書いてそれを回転させるものです。
  
  「情報やメモ (09/14 2007)」に比べてさほど新しい内容があるわけではありませんが、グラフアニメーションの一例として置いておきます。なお、これも前回同様、シェルスクリプト (csh) での形式で紹介します。
```
    #!/bin/csh -f
    ## 変数定義
    setenv GDFONTPATH /usr/local/share/fonts/ttf
    set load1 = load1.gp
    set loops = 12
    set lines = 3
    set outf = spiral1.gif
    # loops = 1 回転の分割数
    # lines = 曲線数

    ## load1.gp の作成
    cat <<EOF > $load1
    plot for [i=1:$lines] xfunc(t,i*dth1+n*dth2),yfunc(t,i*dth1+n*dth2) \
      w l lt rgb fcolor(i)
    n=n+1
    if(n<=$loops) reread
    EOF

    ## gnuplot の実行部分
    gnuplot << EOF
    #set term gif animate delay 10 size 400,400
    set term gif animate size 400,400
    set output "$outf"
    jfont1 = "ipam.ttf"
    jfont2 = "ipag.ttf"
    set size square
    unset tics
    unset key
    set parametric
    set sample 1000
    maxt = 10*pi
    #set trange [0:maxt]
    set trange [0:1.5*maxt]
    set xrange [-1:1]
    set yrange [-1:1]
    set title "グルグル渦巻き" font jfont1.",17"

    # 関数定義
    xfunc(t,a) = (t/maxt)*cos(t+a)
    yfunc(t,a) = (t/maxt)*sin(t+a)
    colorstr = "#990000,#009900,#000099,#999900,#990099,#009999"
    fcolor(n) = (m=(n-1)%$loops,colorstr[8*m+1:8*m+7])
    # dth1 = 曲線毎の差分角
    # dth2 = 回転毎の差分角 (左回り)
    dth1 = 2.0*pi/$lines
    dth2 = 2.0*pi/$loops
    #dth2 = -2.0*pi/$loops
    # (こちらは右回り)
    n = 0 ; load "$load1"
    EOF

    ## それの表示
    xanim $outf
    
```
  この出力が以下のものです。
  渦巻きのらせん曲線は、極座標で言えば r=(t-t0)/maxt のような関数を、 t=t0 から t=t0+maxt まで描いていることに相当します (t は中心角)。しかし、今回は、複数のらせん曲線を同時に描くため、 trange は共通にしなければいけないので、極座標モード (set polar) は使用せず、媒介変数モード (set parametric) で書いています。
  
  曲線の数は簡単に変えられるように、CVS 版 gnuplot の iteration 機能 (for [i=1:$lines]) を利用しています。dth1 = 2*pi/$lines で、この角ずつ回した曲線を $lines 本だけ描きます。また、一回転を $loops 個のフレームに分け、毎回それを dth2=2*pi/$loops だけ回転した曲線を描くようにしています。各フレームは if + reread によって自動的に複数生成し、それを GIF アニメーションファイルとしています。
  
  高速なマシンならば、1 回転のフレーム数 ($loops) の数をもっと増やした方が、滑らかな回転が見られると思います。
  
  なお、trange は [0:maxt] だと r=1 のところまでのらせんしか描きませんが、それだと、描画領域 (一辺 2 の正方形) に内接する円内にしか描かれないことになり、4 隅のところにすきまができます。よって、それを防ぐために、trange を [0:1.5*maxt] としています (正確には隅のところは sqrt(2)*maxt まで)。

(09/14 2007) (しおり用)

「情報やメモ (09/08 2007)」, 「情報やメモ (09/13 2007)」で始めた、CVS gnuplot (4.3) の「あまり意味のないデモ」の 4 つ目を紹介します。

文字アニメーション

gnuplot-4.2 以降には、GIF アニメーションを作成する機能が含まれています (対応する GD ライブラリが必要)。これは、plot 毎にフレームを構成して、それを自動的に GIF アニメーションにするもので、ごく手軽に GIF アニメーションを作成できます。これを使って、文字アニメーションのサンプルを作ってみたものを紹介します。

なお、今回は一つの gnuplot スクリプトに書くと大変なので、 reread + if の機能を使ったループにしてあって、それをシェルスクリプトで実行していますので、そのシェルスクリプト (csh) 自体を紹介します:

    #!/bin/csh -f
    ## 変数定義
    setenv GDFONTPATH /usr/local/share/fonts/ttf
    set load1 = load1.gp
    set load2 = load2.gp
    set load3 = load3.gp
    set load4 = load4.gp
    set loops = 8
    set fsize = 24
    set outf = stranim1.gif

    ## load1.gp の作成
    ## 色の変化
    cat <<EOF > $load1
    n=n+1
    unset label 1
    set label 1 "竹" at screen 0.1,0.2 center font lfont tc rgb fcolor(n)
    plot 1/0
    if(n<$loops) reread
    EOF

    ## load2.gp の作成
    ## 角度の変化
    cat <<EOF > $load2
    n=n+1
    unset label 2
    set label 2 "野" at screen 0.3,0.2 center font lfont tc rgb "#009900" \
      rotate by farg(n)
    plot 1/0
    if(n<$loops) reread
    EOF

    ## load3.gp の作成
    ## 位置の変化
    cat <<EOF > $load3
    n=n+1
    unset label 3
    set label 3 "茂" at screen 0.5,fposy(n) center font lfont tc rgb "#000099"
    plot 1/0
    if(n<$loops) reread
    EOF

    ## load4.gp の作成
    ## フォントサイズの変化
    cat <<EOF > $load4
    n=n+1
    unset label 4
    set label 4 "治" at screen 0.7,0.2 center font ffont(n) tc rgb "#990099"
    plot 1/0
    if(n<$loops) reread
    EOF

    ## gnuplot の実行部分
    gnuplot <<EOF
    jfont1 = "ipam.ttf"
    jfont2 = "ipag.ttf"
    set term gif animate delay 10 size 400,200
    set output "$outf"
    unset key
    unset border
    unset tics
    set xrange [0:1]
    set yrange [0:1]
    set title "文字アニメーション" font jfont1.",17"
    lfont = sprintf("%s,%d",jfont2,$fsize)

    # 関数定義
    colorstr = "#99eeee,#99cccc,#99aaaa,#998888,#996666,#994444,#992222,#990000"
    fcolor(n) = (m=(n-1)%$loops,colorstr[8*m+1:8*m+7])
    farg(n) = 360*n/$loops
    fposy(n) = 0.8-(0.8-0.2)*(n-1)/($loops-1)
    ffont(n) = sprintf("%s,%d",jfont2,$fsize+3*($loops-n))

    # 各スクリプトファイルのロード
    n=0 ; load "$load1"
    plot 1/0 ; plot 1/0
    n=0 ; load "$load2"
    plot 1/0 ; plot 1/0
    n=0 ; load "$load3"
    plot 1/0 ; plot 1/0
    n=0 ; load "$load4"
    plot 1/0 ; plot 1/0
    set out
    EOF

    ## それを表示する
    xanim $outf

この出力が以下のものです。

plot 命令は 1/0 の空打ちのみ行って、 set label で設定した文字の更新を行っています。各スクリプトは loops=8 だけのアニメーションフレームを作成しています。 fcolor(n) は、colorstr で 8 つの色しか定義していないので、 n-1 を loops で割った余りを使って色を取りだすようにしています (, は最近の CVS 版の機能)。これで、スクリプトの先頭で loops を変えることで容易にフレーム数を変えられることになります。

文字の回転は、位置合わせを center にしているのですが、若干文字の中心と回転中心がずれてしまっているように見えます。これは、TTF ファイルの日本語文字のサイズを、 GD ライブラリが正しく認識できていないのかもしれません。

(cf. 「情報やメモ (09/23 2007)」)

(09/13 2007) (しおり用)
「情報やメモ (09/08 2007)」で始めた、CVS gnuplot (4.3) の「あまり意味のないデモ」の 3 つ目を紹介します。
1. 文字の回転サンプル
  文字を回転して表示するサンプル:
```
    ipa = 1
    set term gif
    if ( ipa ) set out "srotate-ipa.gif"
    if ( ! ipa ) set out "srotate-saza.gif"
    if ( ipa ) jfont1 = "ipam.ttf"
    if ( ipa ) jfont2 = "ipag.ttf"
    if ( ! ipa ) jfont1 = "sazanami-mincho.ttf"
    if ( ! ipa ) jfont2 = "sazanami-gothic.ttf"
    unset key
    unset border
    unset xtics
    unset ytics
    labelstr = "   こんにちは、CVS gnuplot-4.3 です。"
    labelfont = jfont2.",14"
    if ( ipa ) set title "文字の回転 (IPA フォント)" font jfont1.",17"
    if ( ! ipa ) set title "文字の回転 (sazanami フォント)" font jfont1.",17"

    set label 1 labelstr at screen 0.5,0.5 rotate by 0 \
        font labelfont tc rgb "#00ff00"
    set label 2 labelstr at screen 0.5,0.5 rotate by 30 \
        font labelfont tc rgb "#ff0000"
    set label 3 labelstr at screen 0.5,0.5 rotate by 60 \
        font labelfont tc rgb "#0000ff"
    set label 4 labelstr at screen 0.5,0.5 rotate by 90 \
        font labelfont tc rgb "#ff00ff"
    set label 5 labelstr at screen 0.5,0.5 rotate by 120 \
        font labelfont tc rgb "#00ffff"
    set label 6 labelstr at screen 0.5,0.5 rotate by 150 \
        font labelfont tc rgb "#ffff00"
    set label 7 labelstr at screen 0.5,0.5 rotate by 180 \
        font labelfont tc rgb "#009900"
    set label 8 labelstr at screen 0.5,0.5 rotate by 210 \
        font labelfont tc rgb "#990000"
    set label 9 labelstr at screen 0.5,0.5 rotate by 240 \
        font labelfont tc rgb "#000099"
    set label 10 labelstr at screen 0.5,0.5 rotate by 270 \
        font labelfont tc rgb "#990099"
    set label 11 labelstr at screen 0.5,0.5 rotate by 300 \
        font labelfont tc rgb "#009999"
    set label 12 labelstr at screen 0.5,0.5 rotate by 330 \
        font labelfont tc rgb "#999900"
    plot [0:1][0:1] 1/0
    
```
  この出力が以下のものです。
  上では、ipa という変数を使って、どちらのフォントを使うかの切り替えを行なっています。実際には、これはシェルスクリプトのヒアドキュメントを使って実行していて、その変数の値もシェル変数で制御し、その値に応じて、同じスクリプト内で "xli -fork srotate-ipa.gif" なども実行しています。
  
  なお、上のサンプルは、さざなみフォントの場合の文字の回転がうまく行っていないように見えますが、これは、「情報やメモ (03/08 2005)」で説明した問題です。そこで紹介したパッチを GD ライブラリに当てれば、さざなみフォントでも IPA フォント同様の表示になります。なお、そのパッチは、最新の GD ライブラリ gd-2.0.34 にも当たります。
  
  このサンプルでは、"set label" の同じようなものをくり返しだらだら並べて書くのが面倒ですが、 CVS 版 gnuplot では、iteration 機能がありますので、これと "with labels" を使えば、以下のように多少自動化することもできます:
```
    ipa = 1
    set term gif
    if ( ipa ) set out "srotate-ipa.gif"
    if ( ! ipa ) set out "srotate-saza.gif"
    if ( ipa ) jfont1 = "ipam.ttf"
    if ( ipa ) jfont2 = "ipag.ttf"
    if ( ! ipa ) jfont1 = "sazanami-mincho.ttf"
    if ( ! ipa ) jfont2 = "sazanami-gothic.ttf"
    unset key
    unset border
    unset xtics
    unset ytics
    labelstr = "   こんにちは、CVS gnuplot-4.3 です。"
    labelfont = jfont2.",14"
    if ( ipa ) set title "文字の回転 (IPA フォント)" font jfont1.",17"
    if ( ! ipa ) set title "文字の回転 (sazanami フォント)" font jfont1.",17"

    colorstr =          "#00ff00,#ff0000,#0000ff,#ff00ff,#00ffff,#ffff00,"
    colorstr = colorstr."#009900,#990000,#000099,#990099,#009999,#999900"
    fcolor(n) = colorstr[8*(n-1)+1:8*(n-1)+7]
    farg(n) = 30*(n-1)
    set sample 2
    set xrange [0:1]
    set yrange [0:1]
    plot for [i=1:12] '+' using (0.5):(0.5):(labelstr) with labels left \
      font labelfont tc rgb fcolor(i) rotate by farg(i)
    
```
  違うのは、"colorstr" 以降の部分ですが、まず、ラベル毎に与える色の文字列を長い文字列にしておいて、各ラベル番号毎に fcolor(n) という関数で文字列値として返すようにし、 farg(n) で回転角も各ラベル番号毎に数値として返すように作っておきます。
  
  "with labels" はデータファイルにしか使えませんから、色の情報も入れた 12 行のデータを作ってもいいのですが、それだと各行毎に回転角を指定できませんから、「疑似ファイル入力 '+' によって 1 行のデータを出力する」という作業を iteration 機能により 12 回繰り返す、とすればいいわけです。こうすれば、iteration の変数を fcolor() や farg() に渡すことで各文字の色や回転角を指定できます。
  
  ただし、"set sample" は 2 以上の値しか指定できないので、 2 の値を指定していますが、これは同じ場所に 3 回重ね書きしていることになります (多分)。また、"with labels" の場合は、位置合わせが center がデフォルトのよう ("set label" の場合は left がデフォルトのよう) なので、left を指定しています。これで、見た目には上とほぼ同じものができます。
(cf. 「情報やメモ (09/14 2007)」, 「情報やメモ (09/23 2007)」)
(09/08 2007) (しおり用)
CVS 版 gnuplot (あるいは gnuplot-4.2.X) では、だいぶ色んな表現ができるようになってきています。ここでは、それらの機能を利用した、2 つのサンプルを紹介します。
1. ワープロみたいに文字だけを書くサンプル
  まず、単にワープロみたいに文字を書くサンプル:
```
    jfont1="sazanami-mincho.ttf"
    jfont2="sazanami-gothic.ttf"
    set term gif
    set out "teststr1.gif"
    unset border
    unset key
    unset xtics
    unset ytics
    set title "全然 gnuplot らしくない出力" \
      offset character 0,-3 font jfont2.",22" tc rgb "#333333"
    set label 1 "新潟工科大学 竹野茂治" \
      at 1,0.8 right offset character -5,0 font '${jfont1},15' tc rgb "#ff0000"
    set label 2 "こんなものを、gnuplot のグラフ画面に書くのは" \
      at 0.5,0.7 center font jfont1.",14" tc rgb "#000066"
    set label 3 "もちろん変なのですが、まあこういうことも" \
      at 0.5,0.6 center font jfont1.",14" tc rgb "#006666"
    set label 4 "できるということを見せると、現在の gnuplot (CVS 版) の" \
      at 0.5,0.5 center font jfont1.",14" tc rgb "#666666"
    set label 5 "表現力の高さ、可能性を示すことにもなるのかなとも思います。" \
      at 0.5,0.4 center font jfont1.",14" tc rgb "#6666ff"
    set label 6 "2007 年 9 月 8 日" \
      at 0.0,0.2 left offset character 5,0 font jfont1.",12" tc rgb "#009900"
    
    plot [0:1][0:1] 1/0
    set out
    
```
  この出力が以下のものです。
  グラフの本文に書いたように、こういうものを gnuplot で書くことに特にたいした意味はないのですが、 gnuplot では、現在 gif/png/jpeg terminal では TrueType フォントを容易に指定して利用できますし、大きさ、色、回転、位置合わせなども指定できます (回転は上のサンプルでは使ってません)。
  
  こういう画像ファイルを作るには、お絵描きソフト、ワープロソフトなどでをやるのが普通でしょうが、上のように gnuplot でやることもできます。この場合、gnuplot の方で再利用したり、または gnuplot がサポートする別の出力形式の画像にもできる、というメリット (?) もあります。しかし、座標を指定する作業などがほとんど原始的ですから、もちろん gnuplot でやる必要はありません。
2. 文字でグラフを書く
  現在、gnuplot-4.2.X 以降は with labels をサポートしていますので、それを利用するとデータに沿って文字列を描画できます。さらに、現在の CVS 版の gnuplot では、疑似ファイル '+' もサポートしていますので、データでなくても with labels を利用して文字によるグラフを描くことができます:
```
    jfont1="sazanami-mincho.ttf"
    jfont2="sazanami-gothic.ttf"
    set term gif
    set out "teststr2.gif"
    unset key
    set title "文字グラフ" font jfont2",14" tc rgb "#009900"
    set samples 80
    plot [-2:10] \
      '+' using ($1):(sin($1)):("青") \
      with labels font jfont2.",12" tc lt 3, \
      '' using ($1):(cos($1)):("赤") \
      with labels font jfont1.",12" tc lt 1
    set out
    
```
  この出力が以下のものです。
  ここでは、単純な文字で書いてみましたが、もっと色んな TrueType フォントを利用すれば、もっと変わったものも描けるかもしれません。これは、plot with points の表現力を改良するものになる可能性があります (?)
(cf. 「情報やメモ (09/13 2007)」, 「情報やメモ (09/14 2007)」, 「情報やメモ (09/23 2007)」, 「情報やメモ (05/28 2009)」)
(09/05 2007) (しおり用)
「情報やメモ (08/27 2007)」で、 gnuplot-4.2.1 がリリースされた、と報告しましたが、その後重大な問題があったようで、急遽 gnuplot-4.2.2 に更新されました。

また、「情報やメモ (03/05 2007)」で、 gnuplot-4.2.0 の、gnuplot-4.0 以降の機能の更新情報を紹介しましたが、ここで gnuplot-4.2.2 の、gnuplot-4.2.0 以降の機能の更新情報を追加しておきます。これは、gnuplot の配布物に含まれるファイル NEWS の訳です。

「gnuplot version 4.2.2 での新しい機能、変更、修正」
- 新規: 2 次元描画で色の情報を持つ追加列を指定可能に
- 新規: set term latex {size XX,YY} が可能に
- 修正: 非常に長い入力行のバッファリング
- 修正: 描画境界に対する画像データのクリッピング処理
- 修正: 多角形のクリッピングのバグ
- 修正: variable による色指定の描画の場合の key の凡例の問題
- 修正: gnu でないシステムでの wxt の初期化の問題
- 修正: sprintf() の書式文字列内のエスケープ文字列 %% の処理
- 修正: "set style incr user" を 3 次元等高線、 columnstacked histograms に適用
- 修正: "set key {no}enhanced" をファイルから読み込んだ key タイトルに適用
- 修正: 文字列変数を "fit via <filename>" の filename に使用可能に
- 変更: x11 の初期化を後回しに
- 変更: amg, cyg, mgw, dj2 に対する設定ファイルの整理
- 変更: SVG 出力を非推奨ビューワにも対応するように
- 変更: 'stringcolumn()' の略記として 'strcol()' が使えるように
- 変更: TeX ベースの PostScript 系の terminal でデフォルトを "blacktext" に
(cf. 「情報やメモ (03/11 2008)」)
(08/31 2007) (しおり用)
最新の CVS 版に、代入演算子 a=b と累次評価演算子 (a,b) がサポートされました。代入演算子は、今までもある意味ではありましたが、これらは using 指定の数式で利用できる点が異なります。

累次評価演算子は、一般には 2 個以上の要素を取ることができ、例えば
(e1,e2,e3,e4)
のように指定すると、e1,e2,e3,e4 の数式が順に評価され、 e4 の値が式の値として返されます。

これとともに demo/running_avg.dem が追加されたのですが、そこにはデータの移動平均を書くグラフの例が紹介されています。ここでは、簡単な例を 2 つほど紹介します。
- データの 2 列目 (y 座標) をそのまま使う代わりに、 1 行目からそこまでの平均を取ったものを表示する:
  sum=0
  N=0
  plot 'data' using 1:2 w l, \
  '' using 1:(sum=sum+$2,N=N+1,sum/N) w l
  この後者の "using 1:" の後ろの部分が新しい機能です。 () の中に 3 本の数式が入っていますが、最初の式 "sum=sum+$2" は sum に y 座標の和を保存する部分、 2 番目の式 "N=N+1" はデータの個数を保存する部分 ($0+1 を使ってもよい)、 3 番目の式 "sum/N" が y 座標値として使用される平均値となります。これによって、N 行目の値をそのまま出力する代わりに、 1 行目から N 行目までの値の平均値を y 座標として出力できるようになります。
- データの 2 列目 (y 座標) をそのまま使う代わりに、一つ前の行との差を取ったものを表示する:
  lastv = 0
  plot 'data' using 1:2 w l, \
  '' using 1:(diff=$2-lastv,lastv=$2,diff) w l
  この場合、"diff=$2-lastv" が差を保存し、現在行の $2 の値を lastv に保存し、先に計算した差の値 (diff) を式の値としています。
以前は、このような作業は awk などを使わないとできませんでしたが、これらの機能により、簡単なものなら gnuplot 内でできるようになりました。

なお、複数列の値を処理しながら描画、ということをこの累次評価を行ってやろうとすると失敗することがあります。次の例を見てください:
plot 'data' using 1:(sum=$2) w l, \
'' using 1:(sum=sum+$3) w l
この描画の場合、気持ちとしては、最初の using は "using 1:($2)" で、もう一つの using は "using 1:($2+$3)" となるように見えるかもしれませんが、残念ながらそうはなりません。これは、gnuplot のデータ走査と関連しています。

この例の場合、先に "using 1:(sum=$2)" のデータ走査が最後まで行われて最初のグラフが描画され、次に "using 1:(sum=sum+$3)" のデータ走査が最後まで行われて 2 つ目のグラフが描画される、という形で実行されます。よって、最初のグラフは正しいのですが、 2 つ目のグラフの最初の y 座標を計算する際の sum の値は、データの最初の行の 2 列目の値ではなく最後の行の 2 列目の値になっていますので、
「sum = (データの 2 列目の最後の行の値) + (最初の行の $3 の値)」
となります。以後、
「sum = (直前の sum の値) + ($3 の値)」
が y 座標の値となってしまうので、結局 2 本目のグラフは、
「2 列目の最後の行の値 + 1 行目から N 行目までの 3 列目の和」
のようなもののグラフになってしまいます。

他にも、これらを使う何か有用な例が思いついたら紹介したいと思いますが、おもしろい例があったら教えてください。

(cf. 「情報やメモ (11/09 2007)」, 「情報やメモ (04/02 2009)」)
(08/27 2007) (しおり用)
gnuplot-4.2.1 がリリースされました。
- SourceForge のダウンロードサイト:
  http://sourceforge.net/project/showfiles.php?group_id=2055&package_id=1996&release_id=535031
4.2.0 との違いの大半は、バグの修正だと思いますが、 CVS 版で取り入れられた小さい改良なども多少は含まれているようです。

(cf. 「情報やメモ (09/05 2007)」)
(08/06 2007) (しおり用)
「情報やメモ (07/23 2007)」, 「情報やメモ (07/30 2007)」, 「情報やメモ (07/31 2007)」に書いた cairopdf 出力形式ですが、スクリプトを食わせた場合に日本語文字が文字化けする問題に対して、「情報やメモ (07/31 2007)」では環境変数 CHARSET で解決する、という回避策を書きましたが、 gnuplot の開発者に報告したところ、それは gnuplot のバグである、ということで、より真っ当な対処をしてもらいました。

set encoding に新たに "set encoding locale" というオプションが新設されました (08/04 2007 以降の最新の CVS 版)。これにより、encoding は locale のものと認識されるようになります。よって、この場合は、スクリプトのエンコーディングと locale (LANG) の設定のエンコーディングが一致している必要があります。とりあえず、次のようなスクリプトにすればいいことになります。
```
  set encoding locale
  set term cairopdf
  set out 'cairopdf.pdf'
  set title "ABCDE 日本語" font "Sazanami Gothic,20"
  set xlabel "ABCDE 日本語" font "IPAGothic,16"
  set ylabel "ABCDE 日本語" font "IPAMincho,14"
  set label "ABCDE 日本語" rotate by 60 font "Sazanami Mincho,24" tc lt 3
  plot sin(x)
  set out
  
```
(cf. 「情報やメモ (11/09 2007)」)
(08/03 2007; no.2) (しおり用)
2 ちゃんねるの掲示板「gnuplot を使おう。その 2」(アドレスはリンクリスト参照) に書かれた情報について、多少気になるものがありましたので、少し書いておきます。

gnuplot のスクリプトファイルの標準的な拡張子は何 ? という質問がありました (191)。もちろん、Unix ではそのような拡張子にはあまり意味はありませんが、
- MS-Windows では意味がある
- Unix でも Emacs の auto-mode-alist に書くときに意味がある
ということのようです。まあ MS-Windows でも、適当な拡張子にしておいてそれを wgnuplot が実行するように割り当てればいいわけですし、 Emacs の auto-mode-alist にも適当な拡張子を設定すればいいわけですから、拡張子としては何を設定してもいいのですが、「標準的」なものは何なのかと気になる人もいるのでしょう。

実は、gnuplot のソース配布物内では、ある意味で 4 種類の「拡張子」が使われています。
- .dem (demo/ ディレクトリ内のデモスクリプト)
- .plt
- .gpl (INSTALL 内の記述)
- .gp
.plt は、wgnuplot.mnu に書かれていますので、多分 wgnuplot (MS-Windows 上) ではデフォルトでは .plt なんだと思われている方が多いかもしれません。また、tutorial/ (gnuplot 入門) ディレクトリ以下のスクリプトでも .plt という拡張子が使われていますし、 src/lasergnu (レーザープリンタ用の補助スクリプト), src/rgipgnu (Uniplex 用の RGIP 出力スクリプト) でも一時スクリプトの拡張子として .plt が使われています。

.gpl は、付属の説明文書の一つ INSTALL に、 MS-Windows 用の拡張子として .plt とともに書かれているのですが、他では使われてはいません。

一方、.gp は、FAQ 内のサンプルスクリプト名として使われていますし、 gnuplot のオンラインヘルプのサンプルでも .gp が標準的に使用されています。付属の emacs の gnuplot-mode Lisp ファイルにも、 auto-mode-alist の拡張子としてはデフォルトでは .gp の設定例が書かれています (もちろん任意のものに変更可能)。

しかも、上に書いたように tutorial 自体のスクリプトファイルは .plt になっているのですが、 tutorial に書いてある説明の中では実は .gp という拡張子が使われています。 gnuplot に関する本「使いこなす gnuplot」「gnuplot パーフェクト・マニュアル」 (cf. 「gnuplot に関する文献等」) でも .gp という拡張子が標準的に使われているようです。

ということで、.plt か .gp あたりが標準と考えてよろしいのだろうと思います。私も普段は .gp を使用していますが、 emacs の auto-mode-alist では、 .gp も .plt も gnuplot-mode 用に受け付けるように書いています。
(08/03 2007) (しおり用)
「情報やメモ (07/30 2007; no.3)」に書いた、 gnuplot Q&A 掲示板の情報の中の、 1581 の記事 ( 「gnuplot だけで複数ファイルの任意の行をまとめてプロットする方法」) からのスレッドの話と、 1589 の記事 ( 「Octave 2.912 リリースにともない，gnuplot の扱いが変わりました。」) からのスレッドの話に関して、記事を書かれた松岡＠名古屋大さんからのご指摘により多少修正をしました。詳しくは、 gnuplot Q&A 掲示板の 1618 番の記事 ( 「gnuplot に関する情報やメモ」) をご覧ください。大変失礼いたしました。
# よくわからないものは適当に書いているのがバレバレ (^^;

他にも、このページなどに書いていることで、内容のおかしいものがあれば、遠慮なくメール (shige.iee.niit.ac.jp) でご指摘ください。
(07/31 2007) (しおり用)
「情報やメモ (07/23 2007)」, 「情報やメモ (07/30 2007)」に書いた cairopdf 出力形式ですが、コマンドラインからスクリプトファイルを食わせる場合に文字化けする問題の解消方法を見つけましたので報告します。

その問題は、対話的に立ち上げた場合は日本語も文字化けしないが、コマンドラインからスクリプトを食わせる場合は文字化けする、というものでしたが、それは、コマンドラインから立ち上げる場合に、 glib が日本語の charset をうまく取得できていない、ということがわかりました。そのため、その場合は、
```
  Unable to convert "文字列": the sequence is invalid 
  in the current charset (ASCII), falling back to iso_8859_1
  
```
のようなメッセージが表示されます ("文字列" のところはスクリプトで使用している日本語文字列)。

これは、glib が「charset = ASCII」と見ていることを意味しているようで、対話的に立ち上げると、この charset は正しく「charset = EUC-JP」や「chaset = UTF-8」のようになるようです。

この charset の値は、glib の g_get_charset() を用いて取得していますので、環境変数 CHARSET を設定してあげることで、正しい charset を認識させることができるようで、よって、以下のようにやれば OK です。
- EUC-JP のスクリプトファイルの場合は gnuplot を実行する前に環境変数 CHARSET を EUC-JP と設定する
- Shift_JIS のスクリプトファイルの場合は gnuplot を実行する前に環境変数 CHARSET を SHIFT_JIS と設定する
- UTF-8 のスクリプトファイルの場合は gnuplot を実行する前に環境変数 CHARSET を UTF-8 と設定する
これで、コマンドラインからでも文字化けのない cairopdf の日本語出力が得られます。

なお、コマンドラインから実行する場合は、環境変数 LANG はあまり関係ないようです。

(cf. 「情報やメモ (08/06 2007)」)
(07/30 2007; no.3; 08/03 2007 修正) (しおり用)
gnuplot Q&A 掲示板での見聞き等で得た情報を備忘録として書いておきます。
- データに列が 1000 個あって、それを 2 次元プロットするのに、
  plot "test.dat" using 1:2, "test.dat" using 1:3, ...
  というのを 1000 まで書いていく方法しかないでしょうか、という質問がありました。
  
  1000 本もグラフを重ねたら、まるでわからないグラフになるような気はしますが、これをやるには、例えば次のような手があります。
  - CVS 版の gnuplot (4.3) の iteration 機能を用いて、
    plot for [j=2:1000] "test.dat" using 1:j
  - plot "test.dat" using 1:2, \
    "" using 1:3, \
    "" using 1:4, \
    ...
    "" using 1:1000
    のようなものを吐く awk スクリプト (test.awk) を作り、
    load "< awk -f test.awk"
    とする
  - C 言語などから pipe を利用して gnuplot を呼びだして、そこに上のような gnuplot の命令を (ループを利用して) 出力する
  上の awk スクリプト test.awk は、例えば
```
    BEGIN{
      print "plot \"test.dat\" using 1:2, \\";
      for(j=3;j<1000;j++) 
        printf "\"\" using 1:%d, \\\n",j;
      print "\"\" using 1:1000\n";
    }
    
```
  といった具合ですし、pipe を利用する場合は、これも awk で書けば例えば、
```
    BEGIN{ 
      p = "gnuplot -persist";
      printf "plot 'test.dat' using 1:2,\\\n" | p;
      for(j=3;j<1000;j++) 
        printf "'' using 1:%d,\\\n",j | p;
      printf "'' using 1:10\n" | p;
      # fflush(p);
    }
    
```
  といった具合です。
  
  (1547 の記事から始まるスレッド「複数列のプロット」)
- x 軸が時系列データであるデータが、
```
    070404.143000.00 1
    070404.143000.10 2
    070404.143000.20 3
    ...
    
```
  のようになっていて、これは、 timefmt が "%y%m%d.%H%M%S" であることを意味している (例えば 1 行目のデータは "2007 年 4 月 4 日 14 時 30 分 00.00 秒) とする。このデータのように秒以下の違いがある場合、 gnuplot では秒は整数としてしか読んでくれないが、これを読ませることはできないか、という質問がありました。
  
  gnuplot の timefmt では、確かに秒は整数としてしか見ませんので、秒以下の違いがあってもそれは無視されてしまいます。しかし、以下のような意味でそれなりに意味があると思います。
  - 上のように、秒以下 (0.1 秒程度) の違いを x 軸に反映させるとすると、解像度からして、x の範囲はその最小の違いの 300 倍位以下でないと見分けがつかない
  - 0.1 秒の 300 倍は 30 秒だから、分以上の単位は必要なく、よって、x のデータを timefmt で時間と読ませることすら必要ない
  例えば、元記事の人は、x の範囲は 1 分から、15 分程度、と書いておられたのですが、もし x の範囲が 15 分程度だとすると、 1 秒はその 1/900 ですから、 0.1 秒はどんなに大きなグラフを書いても見分けがつきません (通常のグラフの解像度では表現できません)。だから、本質的に timefmt を必要とするようなデータ (時:分:秒) のグラフの描画では、秒以下の違いは不必要なのだと思います。
  
  描画範囲を 2,3 分とするのであれば、むしろ timefmt 使わずに考えた方がいいだろうと思います。例えば、xtics は手動にして、以下のようにします。
```
    # 1430000.00 ==> 30:00 (14 時は捨てる) ==> 1800 秒
    set xtics ( "30:00" 1800, "31:00" 1860, "32:00" 1920 )
    plot 'data' using ($1*60+$2):($3) "%*6lf.%*2lf%2lf%5lf %lf" w lp
    
```
  この using 指定の後ろについている format 指定で、x 座標のうち、最初の小数点の前の 6 桁の数字を無視し (%*6lf)、次の 2 桁も無視し (%*2lf)、次の 2 桁 = $1 (%2lf = 30)、その次の 5 桁 = $2 (%5lf = 00.00)、その次の 2 列目のデータ = $3、とするようにしています。
  
  その後で、$1*60+$2 によって、データの分以下の値を秒単位のデータに直して描画していますが、set xtics によって軸の表示には 30:00, 31:00 のように出るようにしてあります。
  
  xtics を手動でしたくない場合は、multiplot を使った重ね書き、という手もあります。
```
    set multiplot
    # まずは目盛の見出しだけ
    set xtics
    unset ytics
    set lmargin 5
    set key
    set timefmt "%y%m%d.%H%M%S"
    set xdata time
    set format x "%M:%S"
    set xrange ["070404.143000":"070404.143200"]
    set yrange [0:1]
    plot 'data' using 1:(1/0)
    # 次はグラフ
    unset timefmt
    set xdata
    unset xtics
    set bmargin 2
    set ytics
    set xrange [1800:1920]
    set yrange [*:*]
    unset key
    plot 'data' using ($1*60+$2):($3) "%*6lf.%*2lf%2lf%5lf %lf" w lp
    unset multiplot
    
```
  後半のグラフの描画部分は、ほぼ上と同様ですが、前半は、"1/0" の描画 (実際には空打ち) によって、 xtics だけ書かせる、ということを行っています。ただし、上のように margin を適当に設定する必要があるでしょう。
  
  (1556 の記事から始まるスレッド「秒の小数点以下の表現」)
- gnuplot-4.0 までは、set term postscript などで set output で出力ファイル指定した場合、描画の最後に "set output" (ファイル指定なし) を入れないと次に set term x11 などと切りかえたときに PS 出力がうまくクローズされない、ということになっていました (FAQ にもあります) が、松田＠東京電機大さんによれば、 gnuplot-4.1 以降ではそれをしなくてもうまくいくようです。
  
  調べてみると、2005 年 5 月位にそのような修正が入っているようで、 x11, win, pm, be, aquaterm といった代表的な対話型 terminal に切り替えるときは、その前に出力があったときにはそれをクローズする、という使用になったようです。
  
  (1560 の記事から始まるスレッド「eps ファイルの連続出力」)
- gnuplot の 3 次元グラフでは、それを包む箱の辺が書かれるだけで、いわゆる x 軸 (y=z=0), y 軸, z 軸は通常は描画されません。 xzeroaxis, yzeroaxis, zzeroaxis (zzeroaxis は gnuplot-4.2 以降) を使えば多少書けるのですが、 x, y 軸自体が xy 平面 (z=0) に書かれるのではなく、グラフの底面 (z=0 ではない) に書かれるので、あまり期待したものにはなりません。
  
  これに対して、松田＠東京電機大さんが、描画範囲があらかじめわかっているのであれば set arrow を使って軸を書く、という解を提示しておられます。通常数学などでは「軸」は矢先を持った形で書きますので、確かに zeroaxis よりも arrow を使って書くのが見た目にもいいかもしれません。ちなみに、そこで松田＠東京電機大さんが提示しておられるサンプルはとても綺麗なグラフで、非常に参考になると思います。
  
  (1569 の記事から始まるスレッド「3 次元グラフの軸の場所」)
- 複数のファイルに x, y のデータが記録されていて、 "gnuplot だけを使って" そのファイルのある x のデータだけ取り出してグラフとして描画することは可能ですか、という質問がありました。具体的には、file_10.txt に
```
    1.0, 2
    1.5, 1
    2.0, 0    
    
```
  とあり、file_20.txt に
```
    1.0, 3
    1.5, 4
    2.0, 5    
    
```
  とある場合に、x=1.5 のデータだけとって、さらに、「ファイル名のファイル番号を利用」して、
```
    10, 1
    20, 4
    
```
  のようなデータの描画をしたい、ということのようでした。 MS-Windows 系の OS で、また使用するマシンが不特定多数なので、追加ソフトなしでやりたい、ということでした。
  
  gnuplot のデータ処理は、残念ながらそこまで柔軟ではなく、 gnuplot 単体ではそれは不可能です。 MS-Windows 付属の標準コマンドは、テキスト処理はあまり得意ではないので、その付属コマンドやバッチファイルを使ってもかなり面倒そうです。
  
  松岡＠名古屋大さんから、WSH (VBscript、Jscript) を使えば色々できるでしょう、ただし awk (gawk) は大きくないので awk を入れて前処理すればいいのでは、という回答がありました。
  
  元の質問者も、それくらいなら USB メモリにも入りそうだし、移植性もあるので、awk でやります、ということでした。こうやって awk ユーザが増えるのはうれしいことですね (^^)
  
  ちなみに、awk で上のような前処理をするには、以下のようなスクリプト (test.awk) を使って、
```
    BEGIN{ if(x == "") x=1.0 }
    (fname != FILENAME){ 
      fname=FILENAME; N=fname; sub(/file_/,"",N); sub(/\.txt/,"",N); 
    }
    ($1 == x){ printf "%d, %d\n",N,$2; next }    
    
```
  以下のようにすればできます:
```
    gawk -F "," -v x=1.5 test.awk file_*.txt > matome.txt
    
```
  (1581 の記事から始まるスレッド「gnuplot だけで複数のファイルの任意の行をまとめてプロットする方法」)
- 松岡＠名古屋大さんから、新しい Octave 2.912 では、gnuplot 以外に独自の描画エンジンを持っていて (octplot)、低レベルの命令が gnuplot とリンクしなくなっている (私は Octave は使わないのでよくわかりません)、という報告がありました。詳しくは、 1589, 1593, 1618 の記事を参照してください。
  
  (1589 の記事から始まるスレッド「Octave 2.912　リリースにともない、gnuplot の扱いが変わりました」)
  
  さらに松岡＠名古屋大さんから、 MS-Windows 用の Octave では gnuplot と双方向の通信を行うようになったようで、それをやるためには、Octave 用に独自にパッチを当てた wgnuplot (4.2) が必要になる、という報告がありました。将来、本家の gnuplot の方にそのパッチが提供される可能性もあるようです。
  
  (1597 の記事から始まるスレッド「From Octave maintainers ML」)
- 極座標 (set polar) を使用している場合、その grid (set grid polar) には x, y 軸の目盛りのラベルししかつかないが、角度と原点からの距離の目盛りのラベルをつけたい、という質問がありました。
  
  実は、以前のバージョン (gnuplot-3.5) では、極座標の場合は格子の角度 (0, 90, 180, 270 度のみ) にもラベルがついたのですが、 gnuplot-3.7 以降ではそれはやめられました。それは多分「ラベル文字をどこに、どのように置くか」という問題が、 x,y 直交座標の場合よりも面倒だからだろうと思います。最近のヘルプにも、以下のように書かれています:
```
    version 3.7 では、極座標モードにおいていくつか変更がなされ、よって、
    version 3.5 やそれ以前の版用のスクリプトには修正が必要になるでしょう。
    主な変更は、仮変数 t が角度として使われるようになったことで、それによ
    り x と y の値の範囲が独立に制御できるようになりました。その他の変更は
    以下の通りです:
    1) 目盛りはもう 0 軸に自動的にはつきません
    － `set xtics axis nomirror`; `set ytics axis nomirror` を使ってください
    2) 格子が選択されてもそれは自動的に極座標には従いません
    － `set grid polar` を使ってください
    3) 格子は角度に関してはラベル付けされません
    － 必要なら `set label` を使ってください
    
```
  ということで、これに対しては、以下のような回答がありました:
  - set xtics axis nomirror を使って、 grid のところに丁度 x 軸のラベルが来るようにする。角度は set label を使って手書きするしかないだろう。
  - CVS 版の gnuplot では疑似ファイル '+' が使えるから、それと with labels を組み合わせれば、と思ったけど、残念ながら '+' は polar や parametric mode は未サポートである。
  - awk を使えるなら、awk で角度のラベルデータを作成しておいて、それを plot with labels notitle で表示させる、という手がある。同じような極座標の図をいくつも書くなら、これが便利かも。
  - CVS 版の gnuplot の疑似ファイル '+' と multiplot を使えば、多少角度のラベルを自動化することはできる。
  この最後のものは、以下のようにします:
```
    set multiplot
    # グラフの描画
    set polar
    set grid polar
    plot 1
    # 角度見出しの描画
    unset polar
    unset key
    unset xtics
    unset ytics
    set sample 13
    # 30 度毎なので、360/30 +1 = 13
    set xrange [-1:1]
    set yrange [-1:1]
    set angle degree
    tr(x) = 180*(x+1)
    plot '+' using (cos(tr($1))):(sin(tr($1))):(sprintf("%d",tr($1)+0.5)) with labels
    unset multiplot
    
```
  後半 (といってもそっちの方がかなり長いですが ...) が角度の見出しを書いています。このようなことができることが、疑似ファイル '+' のメリットの一つです。
  
  (1594 の記事から始まるスレッド「極座標表示の目盛り」)
- gnuplot では background color (背景色) の指定はできたでしょうか、という質問がありました。これに対して、以下のような回答がありました。
  - x11 terminal なら、X のリソース (または -bg) で指定可能、 gd ドライバ (PNG/GIF/JPEG terminal) では、最初のカラー指定が背景色。
  - multiplot を使えば、背景色指定ができる:
```
      set multiplot
      set lmargin 0
      set rmargin 0
      set tmargin 0
      set bmargin 0
      set yrange [0:1]
      unset border
      unset ytics
      unset xtics
      plot 1 with filledcurves y1=0 2
      reset
      plot sin(x)
      unset multiplot      
      
```
  - X11 の反転表示なら -rv, あるいは -bg '#00cccc' とかがある。ただ、プレゼンテーション用に、パワーポイントに図を取り込む、という使い方であれば、背景は透明色がいいだろう。 gnuplot が吐く EPS は背景を透明化できないが、 epsrv.sty というスタイルファイルを使えば TeX 側でそれを行えて、 prosper と組み合わせればプレゼンテーションも可能。
  - CVS 版のマニュアルには、set object を使う背景色指定の例が書かれている:
```
      # 座標軸で囲まれた領域全体の背景を水色に
      set object 1 rect from graph 0, graph 0 to graph 1, graph 1 back
      set object 1 rect fc rgb "cyan" fillstyle solid 1.0      
      
```
  - それを使えば、~/.gnuplot にマクロを書いておいて、そのマクロを呼び出すだけで簡単に反転表示できるようになる
  最後のマクロのサンプルは、松田＠東京電機大さんによるものなのですが、これはなかなかすごいです。確かに、背景色指定や、反転表示などは、今の gnuplot ならソースコードを改変してそれほど難しくなく実装できるのではないかと思いますが、このようなマクロによる実装は、ソースコードをいじらなくても各ユーザが欲しい機能を追加できる、という点で優れていて、そのような (しかも実用的な) CVS 版の機能をフルに生かした素晴しいサンプルになっていると思います。
  
  (1604 の記事から始まるスレッド「background color」)
- fit multi-branch のヘルプには、using 指定が "1:-1:2:3" のようになっているが、この y 座標は -1 よりも -2 が自然なのでは、という質問がありました。 demo スクリプトである fit.dem でも -2 になっているようです。
  
  これに対して、ついうろ覚えで -1 はバグでは、と書いて、さらに gnuplot-beta にもそのように書いて送ってしまったのですが、開発者から指摘されてよく考えたら、別にバグではありませんでした。 -1 であるか -2 であるかは、ヘルプにも書かれている通り、データが 1 行の空行で区切られているか、 2 行の空行で区切られているかの違いでしかなく、よって、データの形式に依存して使い分けるだけのことなので、 -1 でも間違いではありませんでした。
  
  ただ、demo と合っていないのはよろしくない、と思ったのか、開発者の一人が CVS 版のヘルプの方を -2 に変えてくれたようです (^^;
  
  (1613 の記事から始まるスレッド「fit multi-branch」)
(cf. 「情報やメモ (08/03 2007)」, 「情報やメモ (11/09 2007)」, 「情報やメモ (01/08 2009)」)
(07/30 2007; no.2) (しおり用)
前回の報告 (06/10 2007)以後、現在の CVS 版に入れられた主な機能について紹介します (ChangeLog, manual の更新部分等より)。
- 一般的な機能
  - save の [xyz]tics に関するバグの修正。
  - % (%%) を sprintf() の最後に使用すると正しく表示されないバグの修正。
  - 環境変数 PAGER が使われている場合は help のサブトピックの一覧を表示しないように変更。
  - 線種のユーザ選択時 (set style increment user) でも、 set clabel の等高線と columnstacked のヒストグラムはデフォルトの線種を increment するように変更。
  - xy 平面と z 軸の描画に関する改良。
  - set decimalsign, LC_NUMERIC による小数点処理の改良。
  - set xrange [] reverse に関する問題の修正。
  - splot の logscale 軸に関する修正。
  - mouse の zoom 処理に関する改良。
  - sprintf() の引数を 10 個以上も使えるように改良。
  - fit のファイル名が文字列変数で与えられた場合の問題の修正。
  - 極座標での 2 つの曲線間の塗り潰しのサポート。
- terminal ドライバ
  - gd terminal ドライバ (PNG/GIF/JPEG) で、 grid の点線の線幅に現在の線幅が設定されるように。
  - x11 terminal (gnuplot_x11) で multiplot による複数の palette の使用に関する改良。
  - wxt terminal に size オプションの追加。
  - cairopdf terminal の追加。
  - win terminal のヘルプの wgnuplot.ini の置き場所に関する部分を修正 (%APPDATA%)。
- その他
  - plot sytle のヘルプを大幅に書き直し。
  - rgbcolor variable のヘルプを追加。
- デモ
  - multipalette.dem (multiplot による複数の palette デモ) の追加。
今回の目玉は、既にアナウンス済みですが、新しい PDF 出力形式として cairopdf terminal が追加されたことでしょう (cairo-1.2 以降が必要)。

環境変数 PAGER の件は、PAGER に less などを設定している場合、今までは help の項目のサブトピックの一覧が最後についていたのですが、それを less には流さなくなりました。一応 "Help topic:" のところで '?' とすればサブトピックは参照できるものの、やや不便な気がします。

plot sytle のヘルプの書き直しは、例えば lines であれば、
```
  2 次元の場合
    1 列:  y           # 行番号による暗黙の x の値
    2 列:  x  y
  3 次元の場合
    1 列:  z           # x は暗黙の行番号、y は index から
    3 列:  x  y  z
  
```
boxes なら、
```
  2 列:  x  y
  3 列:  x  y  x_width
  
```
のように、データの指定方法に関する、よりわかりやすい説明が統一してつけられるようになりました。

(cf. 「情報やメモ (11/09 2007)」)
(07/30 2007) (しおり用)
「情報やメモ (07/23 2007)」に書いた cairopdf 出力形式ですが、 cairo-1.2.4 をインストールして試してみました (cf. 「Unix に関するメモ等 (07/30 2007)」)。簡単に、
```
  set term cairopdf
  set out 'cairopdf.pdf'
  set title "ABCDE 日本語" font "Sazanami Gothic,20"
  set xlabel "ABCDE 日本語" font "IPAGothic,16"
  set ylabel "ABCDE 日本語" font "IPAMincho,14"
  set label "ABCDE 日本語" rotate by 60 font "Sazanami Mincho,24" tc lt 3
  plot sin(x)
  set out
  
```
のようなスクリプトで試したところ、以下のような感じです。
- UTF-8 のスクリプトファイルを gnuplot のコマンドラインに食わせると、日本語部分が文字化けする (LANG=ja_JP.UTF-8 でもだめ)
- EUC-JP のスクリプトファイルを gnuplot のコマンドラインに食わせても日本語部分が文字化けする
- UTF-8 のスクリプトファイルを gnuplot を立ち上げた後で load すると、 LANG=ja_JP.UTF-8 のときは文字化けせずに出る (cairopdf-utf-1.pdf)
- EUC_JP のスクリプトファイルを gnuplot を立ち上げた後で load すると、 LANG=ja_JP.EUC のときは文字化けせずに出る (cairopdf-euc-1.pdf)
つまり、コマンドラインからだとどうも日本語がうまくいかず、 gnuplot を立ち上げた後に load する場合は、 LANG に応じてうまくいくようです。

しかし、このような画像出力形式の terminal は、コマンドラインからちゃんと使えないとかなり不便なので、これらの原因を少し調査してみたいと思います。

また、上のサンプルを見るとわかりますが、日本語文字が大きいため (そしてそれを正確に計算できていないため) か、周囲の余白が足りません。よって、実際には set margin などで余白を調節する必要がありそうです。

(cf. 「Unix に関するメモ等 (07/30 2007)」, 「情報やメモ (07/31 2007)」, 「情報やメモ (08/06 2007)」)
(07/23 2007) (しおり用)
現在の CVS 版の更新状況の詳細は後で報告しますが、最新版では、新たに cairopdf 出力形式 (set term cairopdf) なるものが追加されました。まだ試していませんが、これは wxt 出力形式のコードを利用して作られたもので、 cairo と pango を使用して、PDF 出力を生成するものです (多分 wxWidget が必要です)。

これまでの PDF ライブラリによる PDF 出力形式 (set terminal pdf) と比較すると、PDF 出力形式で指定できたオプションは enhanced も含め cairopdf でもほぼすべて指定でき (一部オプション名が異なるものがある)、しかもフォントは Unix では fontconfig ベースとなるため、日本語も容易に使えるのではないかと思います (未確認) から、その点は PDF 出力形式よりもいいかもしれません (PDF 出力形式では現在は 1 バイト文字のみサポート)。

ただ、ヘルプには utf-8 エンコードでないとだめ、と書かれています。 wxt 出力形式では EUC-JP でも Shift_JIS でもちゃんと日本語は出るようなので、その辺りは確認してみる必要がありそうです。

(cf. 「Unix に関するメモ等 (07/30 2007)」, 「情報やメモ (07/30 2007)」, 「情報やメモ (07/31 2007)」, 「情報やメモ (08/06 2007)」)
(06/16 2007) (しおり用)
「情報やメモ (12/10 2006)」に書いたように、2 ちゃんねるに gnuplot に関する掲示板ができています。今は「gnuplot を使おう。その 2」(アドレスはリンクリスト参照) に移行していますが、そこに書かれた情報について多少気になるものがありましたので、少し書いておきます。

最近の質問で、各行 3 列のデータがあり、
第 1 列 = x 座標、第 2 列 = y 座標、第 3 列 = 1 or -1
のようなデータがあるとき、この第 3 列が 1 であるか -1 であるかに応じて、赤と青の点 (with points) で書き分けることができるか、という質問がありました。

これに対して、awk を使って第 3 列が 1 のデータを取り出して書き、同じく awk を使って第 3 列が -1 のデータを取り出して書く、という回答が示されていましたが、これは awk を使わなくてもできます。

例えば、gnuplot-3.7 以降ならば以下のようにすればできます:
```
  f(a,b,c) = (b==c)?a:(1/0)
  set pointsize 5
  plot 'data' using 1:(f($2,$3,1)) with p 3, \
    '' using 1:(f($2,$3,-1)) with p 4
  
```
関数 f(a,b,c) は、b==c のときには a を、そうでないときは未定義値 (1/0) を返す関数なので、これによって条件に合わないデータを捨てることができます。

また、現在の CVS 版の gnuplot では、 2D plot でも "rgbcolor variable" が使用可能になっていますので (マニュアルにはまだ 3D しかできないと書いてありますが、 2D でも現在は可能です。ただし、gnuplot-4.2 では不可)、データから色を取得して色を塗り分けることができます。例えば以下の通りです:
```
  mycolor(c) = (c==1)? 256*256*255:255
  set pointsize 5
  plot 'data' using 1:2:(mycolor($3)) with points lc rgb variable
  
```
この mycolor(c) という関数は、c==1 なら 255*256*256 = 赤を返し、それ以外では、255 = 青を返します。この色指定は、8bit (0~255) 毎の赤、緑、青 (RGB) の強度を、 R*256*256+G*256+B として指定します (help rgbcolor 参照)。こちらの方が、1 つの描画でできる分シンプルですが、点の色は変えられるものの点の種類は変えられないので、点の種類も変えたければ前のやり方を使う必要があります。

まあ、そう考えると、少なくとも with points, dots, impulses, errorbars, boxes, vectors などは linestyle/pointstyle も、そろそろデータ (の追加列) から取れるように "variable" キーワードをサポートする必要があるのかもしれませんね。
(06/10 2007) (しおり用)
前回の報告 (03/31 2007; no.2)以後、現在の CVS 版に入れられた主な機能について紹介します (ChangeLog, manual の更新部分等より)。
- 一般的な機能
  - 数字を数桁ずつ区切る format 指定 ' を可能に
  - set desimal locale に関する問題の修正
  - unset key のときにも key 用の設定を保存する問題の修正
  - norm() 関数内部で erf() でなく erfc() を使うように修正 (underflow を起こさないように)
  - 対数軸の場合に set xyplane at XX が機能しない問題の修正
  - set table の出力のコメント部分の改良や vector, labelpoints の出力をサポート
  - splot で 'lc rgb "hoge"' の場合の key の点の凡例の色がおかしかった問題の修正
  - Octave などで長い plot 行が渡された場合の問題の改良
  - key タイトルをデータファイルから取得する場合、拡張文字列処理 (enhanced text mode) を行うかどうかは "set key {no}enhanced" に従うように修正
  - readline に関する修正
  - plot の "with lines lc rgb variable" を可能に
  - "bind Close" を追加
  - x 軸のラベルの回転もサポート (をドキュメントに明示)
  - 存在しない label への "unset label" のエラーの扱いを修正
  - 現在の描画ウィンドウ以外でのマウスクリックを明示的に無視するように修正
- terminal ドライバ
  - set term wxt {rounded|butt} が可能に
  - x11 terminal で、sample を変更すると filledcurves が失敗する問題の修正
  - TeX 系 ps terminal (pstex, pslatex, epslatex) で、デフォルトで color パッケージを必要としないようにデフォルトの文字を黒に変更
  - x11 terminal で、multiplot 時に exit すると segmentation fault する問題の修正
  - wxt terminal の persist に関するものなどの改良
  - png/gif/jpeg terminal の画像の x 方向のクリッピングの問題の修正
  - aqua terminal のオプションで変数が使えなくなっていた問題の修正
  - x11 terminal の image データに関する問題の修正
  - wxt terminal で wxMac をサポート
  - win terminal で "pause -1" がスクリプトの最初に来ている場合の問題の修正、および pause まわりの改良
  - svg terminal のフォントサイズ、enhanced text に関する修正
  - latex terminal に size オプションを追加
  - svga terminal の色の並びを他の terminal に合わせて修正
  - post terminal のヘッダ部分のバグの修正
  - wxt terminal の描画ウィンドウのイベント、および "set term wxt close" に関する修正
  - wxt terminal で軸のスケーリングの情報を保持するように修正
- その他
  - configure 時の --with-plot 指定に関する修正
  - DJGPP 用の Makefile 等の改良
  - 古い PNG ドライバを使わず gd 2.0 以降を使うようにドキュメントや Makefile 等を修正
  - DOS (DJGPP) での welcome メッセージ時の問題の修正
- デモ
  - histograms.dem, histograms2.dem を noenhanced に修正
  - fillcrvs.dem に filledcurve による世界地図の塗り潰しを追加
  - multiaxis.dem の追加。
前回の報告から少し期間が空いてしまいましたので、それなりに修正等がかなり多く行われていますが、 gnuplot-4.2 の公開以降、以前より開発活動は小さいように感じます。今回も新しい機能の追加、というよりもほとんどがバグ等の修正でした。

数桁ずつ区切る format 指定 ' というのは、 3 桁ずつ ',' を入れて区切るような表示で、例えば以下のようになります (環境変数 LC_NUMERIC が設定されていない場合):
```
    gnuplot> show locale

        LC_CTYPE is ja
        LC_TIME is C

    gnuplot> print gprintf("%'.2f",160000)
    160000.00
    gnuplot> set decimalsign locale "ja"
    decimal_sign in local is .
    gnuplot> show locale

        LC_CTYPE is ja
        LC_TIME is C
        LC_NUMERIC is ja

    gnuplot> print gprintf("%'.2f",160000)
    160,000.00
    gnuplot> set decimalsign locale "de"
    decimal_sign in local is ,
    gnuplot> show locale

        LC_CTYPE is ja
        LC_TIME is C
        LC_NUMERIC is de

    gnuplot> print gprintf("%'.2f",160000)
    160.000,00
  
```
なお、これは Solaris 9 の上での実行ですので、それ以外のシステムでは "ja" や "de" の代わりに適切な locale を与える必要があります。

また、table 出力の改良とは、例えば、gnuplot 4.2 ならば
```
  gnuplot> set table 'file.dat'
  gnuplot> plot sin(x) with vectors
  gnuplot> unset table
  
```
(注: sin(x) を with vector で書くこと自体はあまり意味のある例ではありません) とすると、
```
  #Curve 0 of 1, 100 points
  #x y type
  -10  0.544021  i
  -9.79798  0.364599  i
  -9.59596  0.170347  i
  -9.39394 -0.0308337  i
  ...
  
```
のようなデータが作成され、with vector がない場合と同じだったのですが、現在の CVS 版では、
```
  # Curve 0 of 1, 100 points
  # Curve title: "sin(x)"
  # x y delta_x delta_y type
  -10  0.544021  10 -0.544021  i
  -9.79798  0.364599  9.79798 -0.364599  i
  -9.59596  0.170347  9.59596 -0.170347  i
  -9.39394 -0.0308337  9.39394  0.0308337  i
  ...
  
```
のように、ベクトルデータとして保存されるようになりました。先頭のコメント部分の出力も多少改善されています。

それから、plot の "with lines lc rgb variable" の件ですが、実はまだマニュアルには、"rgbcolor variable" は splot にしか使えない、と書いてあるのですが、実際には 2D の plot でも使用可能で、 points, dots, labels, impulses では既に使えるようになっていました。これを今回 lines にも使えるようにした、ということです。ただ、lines は前後の点で線分が決まるので、その他のスタイルと違い、色はどちらの点に指定された色を使うのか、という問題があり、それで今まで lines には実装されていなかったのではないかと想像します。結局は、P1 と P2 を結ぶ線分の色は、 P2 に対する色を塗るようにしているようです。

(cf. 「情報やメモ (07/30 2007; no.2)」)
(05/11 2007) (しおり用)
「情報やメモ (05/10 2007)」に書いた立体視ですが、横に 2 つ並べての立体視の他に、赤と青で左右のグラフをほぼ重ねて書いて、それを赤と青のメガネで見る、という、昔からよく使われている方法もあります。それだと、図の間隔を気にする必要がないので、大きな図を見ることができますし、あまり訓練しなくても見れる、というメリットがありますが、カラー画像を使えない、という問題もあります。

画像処理ソフト (群) として有名な netpbm には、 2 つの画像をそのような赤と青 (正確にはシアン) の図にして重ねた画像を作る ppm3d というソフトが含まれていますので、それを利用すれば簡単にそのような立体視画像を作ることもできます。「情報やメモ (05/10 2007)」と同じ z=x²-y² のグラフを、これを用いて作ったものを以下に紹介します。
- 以下の画像の作成スクリプト (gnuplot-4.2 の X11/GIF terminal 用): see3d-2.gp
- そのサンプル画像: (左が青、右が赤のメガネで見る; GIF 形式)
この場合は、pm3d を使っても最終的には濃淡になるだけですし、また、その濃淡が重なったところが見にくくなりますので、 pm3d はやめて、その代わりに hidden3d を使ってあります。また大きな画像にできるので、視度差を 3 度にしてあります。左目に青、右目に赤のセロハンを当ててみると立体視できると思います。タイトルの文字が一つに重なるように見てみてください。

さらに、このような画像を何枚か作れば、 3D の GIF アニメーションを作ることもできます。サンプルを以下に置きます。
- 上のグラフを 3 度ずつ回転させたの (animation GIF 形式) see3d-anim.gif (195546 Byte)
(05/10 2007) (しおり用)
ふと、視方向を set view で少し変えた 3 次元グラフを multiplot を使って 2 つ並べれば、3 次元グラフの立体視ができるのでは、と思いたったのでやってみました。

あまり綺麗なグラフではありませんが、 z=x²-y² のグラフを試しに以下にあげてみます。うまく立体視できるでしょうか。
- 以下の画像の作成スクリプト (gnuplot-4.2 の X11/GIF terminal 用): see3d-1.gp
- そのサンプル画像 No.1: (平行法; GIF 形式)
- そのサンプル画像 No.2: (交差法; GIF 形式)
平行法、交差法は、立体視する際の視線の合わせ方の種類です。立体視については、例えば以下を参照してください。
- 立体写真 (ステレオ写真) の原理と見方
  http://www.stereoeye.jp/howto/
- 摩訶不思議な世界 - 3Dアート
  http://www2.aimnet.ne.jp/nakahara/3dart/3art.html
- 裸眼立体視の種類 (3-1)
  http://www.lares.dti.ne.jp/~rew/stereo/kaisetu/3-1.html
平行法だと、図があまり離れていると立体視できないので 500x400 の図にしてあります。ただ、見てわかると思いますが、残念ながら上のグラフはそれほど立体的には見えず、多少そんな風に見える、という程度です。もっと立体視風のいいグラフが書けたら教えてください。

(cf. 「情報やメモ (05/11 2007)」)
(03/31 2007; no.2) (しおり用)
前回の報告 (02/11 2007; no.2)以後、現在の CVS 版に入れられた主な機能について紹介します (ChangeLog, manual の更新部分等より)。
- 一般的な機能
  - cb range に関するバグの修正
  - stringcolumn() の省略形として strcol() を追加
  - unset style line を追加
  - x 軸のラベルに上付、下付 (enhanced text) 文字がある場合の BoundingBox の改良
  - candlesticks の箱の横幅を強制的に奇数ピクセル数に (中心線で対称になるように)
  - 疑似ファイル名 '+' によるインライン関数の関数描画
  - set view map で軸のラベルが書かれない問題の修正
  - for [] に関連した ':' 処理の改良
  - strftime(), strptime() の追加 (2000 年からの秒数)
  - set multiplot に title オプションを追加
  - 時刻用の書式文字列の小さい修正 ("%d" が 1~31 だったのを 01~31 に修正など)
- terminal ドライバ
  - metapost terminal のクリッピング処理を Postscript ドライバ同様に
  - latex terminal で塗り潰しのサポート (パターン等は制限あり)
  - gd ドライバの BoundingBox のクリッピングの改良
  - gd ドライバの境界を白にした場合の問題の修正
  - win terminal で APPDATA が設定されない場合の問題の改良
- その他
  - alpha 上での configure 環境の改良
- デモ
  - いくつかのデモで version のチェックを 4.3 に更新
  - pm3d.dem に test palette の追加
  - 4D_data.dem, approximate.dem の追加
  - transparent.dem, histograms.dem の pause 部分の改良
  - wxt terminal の pango の文字列処理の改良
今回の改良の目玉は、疑似ファイル名 '+' と strftime()/strptime() の追加でしょうか。 '+' は、これと using 指定によって、関数による疑似ファイルを実現します。例えば、
plot '+' using ($1):(sin($1)) w l
によって y=sin(x) のグラフを書きますが、これだと "plot sin(x)" と変わりませんが、マニュアルには
plot '+' using ($1):(sin($1)):(sin($1)**2) with filledcurves
のような例が載っています。関数描画は通常 y の値を 1 つしか持たないので、 filledcurves や candlesticks など、複数の y の値を必要とする描画スタイルには関数を指定することはこれまではできず、データからの描画でしかそれは行えず、よって、一度そのようなデータを作成しないと gnuplot では描画できなかったのですが、 '+' によって using のフィールドに直接関数を指定することで、ファイルからの入力と同じことが関数でもできるようになりました。

strftime(),strptime() は、C や AWK などでは良く知られたものですが、時刻のデータとそれの表示用の文字列の変換を、書式文字列によって行う関数です。 s=strftime(format,t) は時刻 t を文字列 s に、 t=strptime(format,s) は文字列 s を時刻 t に変換します。ただし、t は 2000 年からの秒数なので、通常の C や AWK の実装とは違いますので注意が必要です。

(cf. 「情報やメモ (06/10 2007)」)

(03/31 2007) (しおり用)

gnuplot Q&A 掲示板での見聞き等で得た情報を備忘録として書いておきます。

Linux と FreeBSD で set logscale y の軸の見出しの表示が違うのですが、という報告がありました。デフォルトでは軸の見出しは "% g" で、それは固定小数 (0.002 等) と浮動小数 (1e-5 等) の表示を自動的に切り替える仕様になっています。それが、例えば公比 0.1 の等比数列で言えば、

FreeBSD の場合は、0.01, 0.001, 0.0001, 1e-5, 1e-6, ...
Linux の場合は、0.01, 0.001, 1e-4, 1e-5, 1e-6, ...

となる。これを Linux の方式に統一したいのだが、ということでした。

これは、色々調べたところ、どうやら gnuplot の問題ではなく、 Linux の C ライブラリ (glibc) によって起こる現象のようでした。正しく 0.001, 0.0001, 0.00001 という値ならば、どの環境でも "%g" は 0.001, 0.0001, 1e-5 となるのですが、データにわずかに誤差が含まれていて、 0.0009999, 0.00009999, 0.000009999 のようになっていると、 "%.2g" (2 は有効数字の桁数を意味する) 繰り上がったときに Linux 以外 (FreeBSD, Solaris 等) は上と同じですが、 Linux だけ 0.001, 1e-4, 1e-5 となるようです。

man printf の "%g" の説明を見ると、どうも Linux, FreeBSD, Solaris はともにそんなに違わなくて、 Linux や FreeBSD では

The double argument is converted in style f or e (or E for G conversions). The precision specifies the number of significant digits. If the precision is missing, 6 digits are given; if the precision is zero, it is treated as 1. Style e is used if the exponent from its conversion is less than -4 or greater than or equal to the precision. Trailing zeros are removed from the fractional part of the result; a decimal point appears only if it is followed by at least one digit.

Solaris では

The double argument is printed in style f or e (or in style E in the case of a G conversion character), with the precision specifying the number of significant digits. If an explicit precision is 0, it is taken as 1. The style used depends on the value converted: style e (or E) will be used only if the exponent resulting from the conversion is less than -4 or greater than or equal to the precision. Trailing zeros are removed from the fractional part of the result. A radix character appears only if it is followed by a digit.

のようになっています。 Solaris の方が多少丁寧に「resulting」というのがついていますが、いずれにせよ、小さい数の場合は指数部が -4 (10 の -4 乗) より小さい場合に "%e" の表示形式を採用する、ということになっているのがわかります。

これは、元々 printf() では "%g" は、 "%f" と "%e" の表記のうち、短い方を採用する、という考えで導入されたためで、例えば、以下の表記を見ればわかる通り、仮数部に小数点 '.' が含まれて、指数部が 2 桁で書かれるときは指数部が -4 のときに長さが等しくなります。

"%f"	"%e"
0.012345 (8 桁) 0.0012345 (9 桁) 0.00012345 (10 桁) 0.000012345 (11 桁) 0.0000012345 (12 桁)	1.2345e-02 (10 桁) 1.2345e-03 (10 桁) 1.2345e-04 (10 桁) 1.2345e-05 (10 桁) 1.2345e-06 (10 桁)

だからここまでは "%g" は "%f" の方を採用して、 -5 からは "%e" の方を採用しているわけです。

よって、もちろん -4 から "%e" になっても長さの点では問題はないのですが、一応仕様上は「-5 から」となっています。そして Linux 以外の実装は、0.000099999 のような数字に対しては、「丸められた結果 1.0e-04 になったので "%f" とする」となっているのですが、Linux は「丸められた結果ではなく、元の数字の指数部が -5 ならば "%e" とする」としているように見えます。上のマニュアルを見る限り、結果の指数部を見ることになっているはずなのですが、 Linux の glibc ではそうなってはいないようです。 (ちなみに、K&R (第 2 版) にも同様に書かれていますが、変換後の指数部なのか、変換前の指数部なのかは明示されていないみたいです。)

ただ、この -4 と -5 の境い目は、上にあげたような数字の場合は確かにそこで長さが分かれるのでいいのですが、 gnuplot の軸の見出しのような 1.0e-XX のような丁度の数字の場合は、実は "1e-05", "1e-06" のように小数点 '.' がつかないので、"1e-04" でも "%e" の方が短かく、 "0.001" (1e-03) でやっと等しくなります。となると、"%f" と "%e" の短い方を選んでいることになっていません。実際、元の質問者もそれで Linux の仕様の方がいい、と思ったらしいです。

gnuplot は、実は printf() の出力をさらに拡張した gprintf() という関数を持っていて、それで軸の表示などは行っているのですが、その中では指数部や仮数部を取り出す書式 ("%T", "%t") もあります。よって、gnuplot スクリプトの中でそれを改善することは無理かもしれませんが、 gnuplot の gprintf() (src/util.c) 自体を改良して、そういうことを実装するのは難しくないかもしれません。

なお、Linux の日本語の man printf では、「式 e は、変換される値の指数が -4 より小さい場合」のように書かれているようで、これだと確かに変換前の値だと見えなくもありませんが、 Open Group の IEEE Std 1003.1 (2004) には、「style e (or E ) shall be used only if the exponent resulting from such a conversion is less than -4」のように書かれているそうですから、やはり Linux の実装が少しおかしいように見えるみたいです。

ちなみに、うちの以下のいくつかの環境 (標準の C ライブラリ) で試してみましたが、いずれも FreeBSD や Solaris と同様に変換後の数字を見ているようで、 Linux と同じ変換をしたものはありませんでした。なお、うちは Linux ひとつもはありませんので、 Linux だけは確認できていません。

FreeBSD (4.7, 4.11, 5.4)
Solaris (9)
HP-UX (9.05)
NEC EWS-UX (4.2; /usr/necccs/bin/cc, /usr/abiccs/bin/cc, gcc)
SGI IRIX (6.2)
LSI-C 86 (3.30; MS-Windows)
Borland C++ (5.5.1; MS-Windows)
VC++ Toolkit2003 (CL version 13.10.3077; MS-Windows)

(1513 の記事から始まるスレッド「logscale での固定/浮動小数点の表示の切替え」)

(cf. 「情報やメモ (02/26 2009)」)

(03/26 2007) (しおり用)
「情報やメモ (02/15 2007)」, 「情報やメモ (02/16 2007)」に書いた、日本地図の塗り分けですが、フリーの日本地図のデータを少し探してみると、一応はあるようなのですが、
- 大半は画像データだけに限られていて、 gnuplot で使える輪郭線の数値データのようなものはほとんどない
- 都道府県毎の閉曲線としての輪郭線データがない
- 利用は自由であっても再配布が禁止、といった制限がついているものが多い
という状況のようでしたので、せっかくなので自分で書いてみました。「情報やメモ (02/16 2007)」の東北 3 県のデータ同様、地図を見ながら Tgif で手書きで書いてその座標データを抜きだしたものなので、正確なデータではありませんが、自由に利用 (改変、再配布) して結構です。ただし、使用に関する一切の責任は持ちませんので、自己責任でご利用ください。
- 都道府県の輪郭線データ (japan_map.dat; rev 1.2; 6479 Byte)
- テスト用の都道府県の人口と面積のデータ (maptest2.dat; 1084 Byte)
- gnuplot-4.3 用の gnuplot スクリプトファイル (maptest2.gp; 1046 Byte)
- gnuplot-4.2 用の AWK スクリプトファイル (maptest2.awk; 1680 Byte)
- そのサンプル出力画像 (maptest2.gif; x11 出力形式のスナップショット)
- そのサンプル出力画像 (maptest2-2.gif; gif 出力形式)
以下に、上のサンプルに関する注意を上げます。
- 輪郭線データは都道府県毎に 2 行の空行を入れ (index 化)、県に属する島 (淡路島と佐渡島のみ) は 1 行の空行で追加しています。よって、"index j with lines" や "index j with filledcurves closed" で (島も含めて) 指定した県を描画したり塗り潰すことができます。
- データには # で始まるコメント行が入れてあり、各都道府県データの先頭に ## で始まるコメント行として番号と都道府県名を入れてあります。
- 都道府県の順番は、標準的な並び (北海道、東北、関東、中部、関西、中国、四国、九州) にしてあります。
- 滋賀県には琵琶湖のデータは入れてありませんし、和歌山県の飛び地のデータも入れてありません。
- データは手書きのデータなので、正確なものではありません。
- maptest2.dat には、都道府県番号、都道府県名、人口、面積が入れてあります。ただしそのデータは 30 年程前のものです。
- maptest2.gp、maptest2.awk は、maptest2.dat のデータを元に、人口密度を計算して、それにともなって各県に色を塗るサンプルです。ただし、人口密度は高いところ (東京、大阪など) がずば抜けて高くて、線形軸で書くとそこだけ色が違って後はべったり同じ色になってしまうので、対数軸にして、人口密度の対数に応じた色を塗るようにしています。
- maptest2.gp は gnuplot-4.3 用です。 "plot for" を用いているので、gnuplot-4.2 では使えません。 gnuplot-4.2 の場合は maptest2.awk を使ってください。
- maptest2.awk は gnuplot スクリプトを吐きだす awk スクリプトです。
  % awk -f maptest2.awk maptest2.dat > test.gp
  % gnuplot -persist test.gp
  とするか、gnuplot 内で
  gnuplot> load '<awk -f maptest2.awk maptest2.dat'
  として実行してください。
- maptest2.gp で利用している system()+sprintf() による外部関数は maptest2.awk では使っていませんが、この機能自体は gnuplot-4.2 でも使えるのですが、 maptest2.awk ではその処理でデータを読み込んでいるので、そのような機能を使う必要がないので使っていないだけです。
なお、このテストに関連して、次の 2 つのことに気がつきました。
1. gnuplot 内で「load '< awk -f ...'」とした後は、 help が読めなくなる
2. gnuplot-4.2 では、cbtics への文字は、 "set cbtics (c1,c2,c3,...)" としても表示されない
後者は、gnuplot-4.3 ではうまくいくので、 gnuplot-4.2 のバグかもしれませんが、一応明示的に「set cbtics ("s1" c1,"s2" c2,...)」とすると gnuplot-4.2 でも表示できますので、 maptest2.awk ではそのようにしています。

(cf. 「情報やメモ (04/01 2011)」, 「情報やメモ (08/20 2021)」)
(03/05 2007) (しおり用)
ついに、gnuplot-4.2.0 が正式リリースされました。
配布物の中に、NEWS というファイルが含まれていて、そこに 4.0 以降に新規に追加されたもの、変更されたもの、修正された問題の一覧が書いてあります。 gnuplot-4.2.0 のそれを日本語に訳したものも以下に上げておきます。

「gnuplot version 4.0 以降の新しい機能、変更、修正」
- 新規: GPVAL_ で始まる、又は "show variables all" の読み出し専用の自動生成変数
- 新規: 日本語ドキュメント - FAQ とユーザマニュアル
- 新規: 多プラットホームで動作する対話型 wxWidgets 出力形式
- 新規: windows 出力形式の拡張文字列処理 (enhanced text mode) サポート
- 新規: グラフ、あるいは描画領域内に長方形を個別に配置できるように
- 新規: "set style increment user" でデフォルトの線種列をカスタマイズ可能に
- 新規: コマンド raise と lower (ウィンドウの重なりを上下)
- 新規: y, y2 軸ラベルの回転を明示的に制御可能に (2D 描画のみ)
- 新規: {no}enhanced フラグをラベル毎に指定可能に
- 新規: 'set pm3d interpolate' による曲面の重線形補間
- 新規: 3D 描画で入力データから RGB 3 つ組の色を読み込んでの描画が可能に
- 新規: gnuplot の readline でもコマンドヒストリをファイルに書き出すように
- 新規: より柔軟な key の配置とカスタマイズが可能に
- 新規: あらかじめ 'set pm3d' とせずに 'splot x*y with pm3d' が可能に
- 新規: 描画列をアニメーション GIF 用に保存 (2.0.28 より後の libgd が必要)
- 新規: x11 でのマルチバイトフォントのサポート (LC_CTYPE の locale 設定による)
- 新規: 小数点の変換を LC_NUMERIC の locale 設定で切り替え
- 新規: pstex, pslatex, epslatex 出力形式の機能を postscript 出力形式と統合
- 新規: オプション "set pm3d corners2color min|max" の追加
- 新規: オプション "set pm3d depthorder" による陰面処理 (ある意味で)
- 新規: "lt {palette {frac <val> | cb <val>}}" で線種として色を指定可能に
- 新規: "lt {rgbcolor {"name" | "#RRGGBB"}}" で線種として色を指定可能に
- 新規: パレットと RGB 色線種を 2D,3D のすべての描画要素で指定可能に
- 新規: ユーザ定義変数で文字列が使えるように
- 新規: 数式で文字列を操作し返すことができるように
- 新規: 組み込み文字列関数: sprintf, gprintf, substr, strstrt, word, words
- 新規: 組み込み文字列関数: system("shell command")
- 新規: コマンドラインマクロ展開 @<stringvariablename> のサポート
- 新規: "call" の引数の数を自動変数 $# で取得可能に
- 新規: (ほとんどの) 画像バイナリファイルの読み込みが可能に
- 新規: 描画スタイル "with image", "with rgbimage"
- 新規: 描画スタイル "with labels" で X/Y/Z 軸の見出し文字列データを読めるように
- 新規: 描画スタイル "with histograms" で固まり型/積上げ型ヒストグラムのサポート
- 新規: "set multiplot layout <rows>, <cols>" による multiplot の自動配置
- 新規: "with filledcurves" による 2 つの曲線の囲む領域内の塗り潰し
- 新規: "with filledcurves" による曲線の上/下の領域の塗り潰し
- 新規: using のオプション {x|y|z}ticlabels(<col>) の新設
- 新規: タイトルをデータから読むオプション: set key autotitle columnheader
- 新規: 'set termoption <foo>' で現在の出力形式の一つの属性のみを変更可能に
- 新規: png 出力形式でアンチエイリアスと TrueColor 画像のサポート
- 新規: koi8-u エンコーディングのサポート
- 新規: 2D,3D の両描画用の描画スタイル "with vectors"
- 新規: 描画スタイル "with points" がデータファイルからポイントサイズを入力可能に
- 新規: "set tics" が {x|y|z|cb}tics のほとんどの設定を一度に設定可能に
- 新規: "set {x|y|z|cb}tics scale" による刻みのサイズ指定が可能に
- 変更: デフォルトでヒストリファイルの書き出しを行う (~/.gnuplot_history)
- 変更: PostScript 定義ファイルと文字エンコーディングを別ファイルとして分離
- 変更: 3D 描画の z 軸ラベルの位置を x,y 軸と同等に
- 変更: "set ticsscale" (非推奨) の代わりに "set tics scale" を新設
- 変更: x11 の gnuplot のマウス機能を起動時から可能に
- 変更: 'set datafile fortran' を D 型、Q 型定数を読む目的にのみ使用するように
- 変更: '{s}plot ... notitle "string"' の文字列をエラーでなく無視するように
- 変更: 2.0.28+ の libgd で PNG/JPEG 同様 GIF をサポートするように
- 変更: libgd ではない古い GIF, PNG ドライバの削除
- 変更: X のリソース gnuplot*ctrlq:on で <ctrl>q が描画ウィンドウを終了するように
- 変更: X のリソース gnuplot*exportselection:off でクリップボードへの送信を無効に
- 変更: キーワード offset を 'set [xyz]label "foo" offset -1,-1' と使用するように
- 変更: 'set table "outfile"; ...; unset table' を 'set term table' に変更
- 変更: 'defined(foo)' (非推奨) の代わりに 'exists("foo")' を新設
- 修正: 空のデータファイルで致命的なエラーにならないように
- 修正: setenv GNUTERM が PNG/JPEG/GIF 出力形式で動作するように
- 修正: PostScript 出力を Level 1 互換機能に制限できるように
- 修正: emf 出力を MSWin XP SP 2 互換に
- 修正: X11 のサイズの制限を X ディスプレイの最大値の半分を要求するように
- 修正: 矢の軸が点線の場合でも矢先は実線になるように (PostScript)
- 修正: 拡張文字処理 (enhanced text) モードで実際の文字の長さを評価するように
- 修正: 曲線間の塗り潰し (filledcurves) のクリッピング
改めてこうやってみると、ずっと追いかけてきたつもりでしたが、もう忘れてしまっているものもだいぶありますね。なお、これらはあくまで「主な変更」であり、細かい機能の追加や修正などは、ここに上げた以外にもまだまだあります。

(cf. 「情報やメモ (09/05 2007)」,
(02/16 2007) (しおり用)
「情報やメモ (02/15 2007)」に書いた地図の塗り分けですが、新潟や兵庫のように島がある場合はどうしたらいいかな、と思ったのですが、その場合も簡単にできるようです。

「情報やメモ (02/15 2007)」の例では、各県のデータ (tohoku.dat) は 2 行毎の空行で区切られて書かれていて、 index を用いて各県を指定していますが、島がある場合はその県のデータの下に 1 行の空行を空けて島のデータを追加すればいいだけのようです。これでちゃんと県と同じ色で島が塗られるようになるようです。サンプルを一つ紹介しておきます。前回のデータの秋田県の沿岸に架空の菱形の島を追加してあります。
- 前回のデータに菱形の島を追加したデータ: tohoku-add.dat
- 東北 3 県 (＋架空の島) に色づけしたもの
(cf. 「情報やメモ (03/26 2007)」)
(02/15 2007) (しおり用)
せっかくなので、「情報やメモ (02/14 2007)」に書いたことを、サンプルを使って説明することにします。以下では、gnuplot は CVS 版の最新の gnuplot (4.3) を仮定します。

まず、各県の地図データですが、ここでは簡単に Tgif を使って青森、秋田、岩手だけの図を書いて、その Tgif データ (.obj) から座標を抜きだしたものを利用します。なお、Tgif では座標軸が上下逆なので y 座標には - の符号をつけてありますし、またそのまま gnuplot で表示させるとアスペクト比が違うようなので、 gnuplot 内で set size ratio で調整する必要があります (手書きなので、かなりいいかげんです)。
- 東北 3 県の境界データ (tohoku.dat; 775Byte)
これを、以下のようにすると境界線が表示されます:

set size ratio 8.0/5.0 unset key unset xtics unset ytics unset border plot "tohoku.dat" w l lt -1
- gif terminal 出力
色をつけて塗りつぶすには、filledcurves closed を用いて、 linetype として塗りつぶし色を指定します:

set size ratio 8.0/5.0 set key outside unset xtics unset ytics unset border plot "tohoku.dat" index 0 w filledc c title "青森" lt rgb "#00ffff",\ "" index 1 w filledc c title "秋田" lt rgb "#ff00ff",\ "" index 2 w filledc c title "岩手" lt rgb "#ffff00",\ for [j=0:2] "" index j w l notitle lt -1
- gif terminal 出力
この plot の最後の for の部分は、先程の境界の描画と同じで、塗りつぶしを行った後で境界の描画を行っていて、前半部分が色による塗りつぶしになっています。

この前半部分を一つ一つ指定するのでなく、別なデータファイルからその情報を読みとるようにするためには、前回説明した、awk を利用してデータから値を取得する関数を作ります。まず、以下のようなデータ tohoku3.dat を用意します:

# 東北 3 県の情報のデータ (30 年前) # index [県名] [デフォルト色] [人口 (万人)] [面積 (平方 km)] 0 "青森" "#00ffff" 152 9000 1 "秋田" "#ff00ff" 126 11431 2 "岩手" "#ffff00" 142 15094

これに対して、次のような関数を使います。
getcol(x,j,name)=system(sprintf("awk '($1==%d){gsub(/\\\"/,\"\"); \ print $%d}' %s",x,j,name))
これは、name という名前のファイルの、1 列目が x に等しい行から j 列目の値を文字列として取得する関数で、 gsub() を使って文字列の前後についている '"' を削除するようにしています。

ただ gsub() を sprintf() の引数に書くために、本来 awk では「gsub(/\"/,"")」と書くべきところを、 '\' と '"' を \ でエスケープする必要があるので「gsub(/\\\"/,\"\")」のように書く必要があります。

この関数を使えば、先程と同じものを以下のようにして得ることができます:

set size ratio 8.0/5.0 set key outside unset xtics unset ytics unset border getcol(x,j,name)=system(sprintf("awk '($1==%d){gsub(/\\\"/,\"\"); \ print $%d}' %s",x,j,name)) plot for [j=0:2] "tohoku.dat" index j w filledc c title getcol(j,2,"tohoku3.dat") \ lt rgb getcol(j,3,"tohoku3.dat"), \ for [j=0:2] "" index j w l notitle lt -1

getcol(j,2,"tohoku3.dat") によって県名を取得してそれを title に渡し、 getcol(j,3,"tohoku3.dat") によって色名を取得してそれを lt rgb に渡しています。

次は、人口別にグラデーションを利用して塗り分けてみます。 cbrange を人口の範囲に合わせて設定して、カラーパレットを使用して色の塗り分けを行います。人口の数値は getcol(j,4,"tohoku3.dat") で取得します:

set size ratio 8.0/5.0 set key outside unset xtics unset ytics unset border getcol(x,j,name)=system(sprintf("awk '($1==%d){gsub(/\\\"/,\"\"); \ print $%d}' %s",x,j,name)) set palette color set cbrange [100:200] set colorbox user origin 0.8,0.3 plot for [j=0:2] "tohoku.dat" index j w filledc c notitle \ lt palette cb getcol(j,4,"tohoku3.dat"), \ for [j=0:2] "" index j w l notitle lt -1
- gif terminal 出力
最後に、連続的な塗り分けではなくて、「離散的」な塗り分けを行う例を紹介します。県の面積を、10000 平方 km 未満、15000 平方 km 未満、15000 平方 km 以上の 3 種類に分けて、それぞれを別の色で塗り分けます。それには、値が色名であるような階段関数を設定して、その値を lt rgb の後ろに指定すればいいわけです。
set size ratio 8.0/5.0 set key outside unset xtics unset ytics unset border set style fill solid 1.0 getcol(x,j,name)=system(sprintf("awk '($1==%d){gsub(/\\\"/,\"\"); \ print $%d}' %s",x,j,name)) ar2clr(n) = (n<10000)?"red": (n<15000)?"yellow":"cyan" plot 1/0 w boxes fill title "10000 平方 km 未満" lt rgb ar2clr(0),\ 1/0 w boxes fill title "15000 平方 km 未満" lt rgb ar2clr(10000),\ 1/0 w boxes fill title "15000 平方 km 以上" lt rgb ar2clr(15000),\ for [j=0:2] "tohoku.dat" index j w filledc c notitle \ lt rgb ar2clr(getcol(j,5,"tohoku3.dat")),\ for [j=0:2] "" index j w l notitle lt -1
- gif terminal 出力
ar2clr(n) がその階段関数で、3 項演算子を使って 10000 未満なら "red", 15000 未満なら "yellow", 15000 以上なら "cyan" を返す関数になっています。よって、ar2clr(getcol(j,5,"tohoku3.dat")) で求める色名が得られます。

また、この plot では、最初に 1/0 を 3 回出力していますが、これは key を作成するための空打ちで、値が 1/0 (無効値) なのでグラフの描画は行われませんが、これによりタイトルとそのサンプルが右上に出力されます。そのサンプルを塗りつぶしにするために "set style fill solid 1.0" を設定しています。

このようにすれば、県の境界線のデータ (上の tohoku.dat に相当) だけあれば、後はその各県に対するシンプルな形式のデータ (上の tohoku3.dat に相当) に従って、各県に異なる色を塗ることでそれらを表現できることが分かると思います。従来の gnuplot では、このようなことをやるには色々面倒でしたが、現在の CVS 版では、iteration 機能 (for) や system()、文字列変数機能により、それらがかなり容易に行えるようになっていることが、上の例からもわかるのではないかと思います。

(cf. 「情報やメモ (02/16 2007)」, 「情報やメモ (03/26 2007)」)
(02/14 2007) (しおり用)
以前、「情報やメモ (01/30 2005)」で書いたように、日本地図のデータがあると、その上に各県に対応した棒グラフを作ることができます。以下の松田＠東京電機大さんのサイトにもサンプルが置かれています。
- Gnuplot Tips 「3 次元棒グラフ」 http://ayapin-film.sakura.ne.jp/Gnuplot/Tips/impulse.html
ところで、現在の CVS 版の gnuplot なら閉曲線内の塗りつぶしもできるし (with filledcurves closed)、色のグラデーションによる値の違いの表現も使えます (例えば linetype palette frac 0.5 とか) から、同じことを、日本地図の各県を2 次元的に違う色や色の濃さで塗り分けることで表現できないかなと考えてみました。

簡単にやろうと思えば、各県の閉曲線データを作って (またはどこかから持って来て)、それをスペース区切りのデータや 2 行ずつのスペース区切りのデータにして every や index で一つずつそのデータブロックを選んで書いていけばいいんですが、問題は塗りつぶし色の指定です。
set palette gray plot for [j=1:47] "pref.dat" index j with filledcurves closed \ lt palette cb f(j)
のようにすれば、例えば各県の塗りつぶし色を関数で与えられる場合はそれが可能になるのですが、通常はそれは関数ではなくてデータとして与えたいわけですから、これは工夫が必要です。

このサンプルの各県の折れ線データである pref.dat とは別に、各県毎のデータを次のように作るとします:
# population.dat # $1 = 県番号、$2 = 人口 (万人; 30 年前のデータ) # (県番号は pref.dat の index 番号に対応) 0 542 # 北海道 1 152 # 青森 2 142 # 岩手 ...
この population.dat から、 index j に対応する人口データを読み出して、それを上の関数の値 f(j) とすればいいわけですから、この f(j) (のようなもの) は例えば awk を使って次のようにして作ることができます (CVS 版 gnuplot の場合):
f(j,name)=real(system(sprintf("awk '($1 == %d){print $2}' %s", j,name)))
ここでは、汎用性を持たせるために第 2 引数をファイル名としました。 awk に、データの 1 フィールド目が j に等しい行の 2 行目を関数の値としています。ただ、これだと 1 フィールド目にない j の値を与えた場合は問題になりますので、本当はもうちょっとちゃんと書くといいでしょう。とりあえずこれを使えば、
plot for [j=1:47] "pref.dat" index j with filledcurves closed \ lt palette cb f(j,"population.dat")
のようにして、上に書いたことが実現できます。

もちろん、awk などを使って、population.dat から、
plot "pref.dat" index 0 w filledc c lt pal cb 542,\ "" index 1 w filledc c lt pal cb 152,\ "" index 2 w filledc c lt pal cb 142,\ ...
のような gnuplot スクリプトを作成して、それを gnuplot に食わせることもできますが、上の方法ならば一つの gnuplot スクリプト内で閉じることができます (シェルスクリプトのヒアドキュメントを使えば、この方法でも一つのシェルスクリプト内に閉じることができますが)。

ということで、後は日本地図のデータを作ればいいんですが... サンプルとして紹介しますので、なんでしたらどなたかフリーのデータを作っていただけないでしょうか。

なお、このような手法を使えば、以前紹介した円グラフの描画 (cf. 「情報やメモ (02/08 2005)」) も実装できるのではないかとぼんやり思っています。

(cf. 「情報やメモ (02/15 2007)」)
(02/11 2007; no.2) (しおり用)
前回の報告 (01/08 2007)以後、現在の CVS 版に入れられた主な機能について紹介します (ChangeLog, manual の更新部分等より)。
- 一般的な機能
  - データファイルの index に名前の設定/指定が可能に
  - set key に textcolor オプションが追加 (rgb variable で 3.7 の挙動に)
  - set label の textcolor で RGB 色指定が可能に
  - image failsafe オプションの追加 (不十分な最適化ルーチンの無効化)
  - set title の textcolor で RGB 指定、パレット色指定を可能に
  - set view map ; splot [][y1:y2] で y 軸が逆向きになる問題の修正
  - with impulses, dots で、3 列目のデータを使って色の指定を可能に
  - with lables のカラー処理の問題の修正
  - あいまいな表現に対する問題の修正 (まだ完全ではない)
  - 線分の clipping 時の問題の修正
- terminal ドライバ
  - hp2623a terminal のメモリに関する問題の修正
  - いくつかのドライバで set term <foo> font ",<newsize>" の形式をサポート (フォントサイズのみの変更)
  - pdf terminal のフォントエラー処理の改善。
  - x11 terminal で default の encoding を設定するリソースを追加 (xorg-7.1 用)
  - gd (png/gif/jpeg), pdf, post, wxt ドライバで、画像 (image) のクリッピング処理の改善
  - libgd 2.0.34 に合わせた gd ドライバの修正 (Adobe Symbol font encoding に関して)
  - gd ドライバの格子線を、transparent に対応させた修正
  - pdf terminal の点種の問題の修正
  - win terminal のマウスの "pause mouse" に関する問題の修正
  - win terminal でグラフウィンドウがまだない場合にコンソールからの改行キー入力待ちに (マウスクリックの代わりに)
  - latex terminal で追加の点種をサポート (amssymb パッケージを使用)
- その他
  - makeinfo, doc2gih 用に gnuplot.doc, gnuplot.texi の修正
  - readline は GNU readline をデフォルトに (今までは builtin readline がデフォルト)
  - gnuplot_x11 の名前を configure 時に変更できるように修正
- デモ
  - borders.dem の bug の修正
  - pm3d.dem のタイトルの修正
  - colorscheme.dem の追加
今回の修正で目立つのは、データ index に名前を指定できる機能でしょうか。データファイルにコメントを埋め込むことで各 index に名前をつけて、その名前を index に指定していて呼びだすことができるようになりました。

それから、set key に textcolor オプションが追加されたのですが、そこで "textcolor rgb variable" と指定すると、以前の gnuplot の「key の各エントリのタイトルの方もグラフと同じ色になる」という機能が再現できるようになりました。

後は with impulses, with dots の色をデータから取得できるようになったことと、 latex terminal の amssymb パッケージを利用した点種の変更くらいでしょうか。この点種は今までは、・、◇、＋、□、△、*、○ (小、中、大)、● (小、中、大) のような感じだったのですが、今度は、・、＋、×、*、□、■、○、●、△、▲、▽、▼、◇、◆、ハートマーク、スペードマーク、などのようになっているようです。他のドライバ (post など) に、合わせるように変更したようですね。
(02/11 2007) (しおり用)
gnuplot Q&A 掲示板での見聞き等で得た情報を備忘録として書いておきます。
- pdf terminal の出力は横になっているのだけどこれを縦にするには、という質問がありました。今のところ、CVS 版でも PDF terminal にはそのようなオプションはないのですが、以下のような回答がありました。
  - できた PDF ファイルを何らかの方法で回転
  - postscript terminal で PS ファイルを出力して、それを PDF に変換する (postscript terminal なら landscape, portrait の指定が可能)
  - gnuplot-4.2 以降の pdf terminal の size オプションを使う (サイズの変更はできるが縦横の回転はできない)
  - postscript terminal で EPS として出力して、他のツールで取り込んでレイアウトする
  (1504 の記事から始まるスレッド「pdf出力について」)
- 日時データに、"02/11/2007 11:30:00" のように空白が含まれる場合、それを一旦外部ツールでタブに変換しているが、という話がありました。
  
  確かにタブに変換してから処理すると、まぎらわしくなく処理できるのですが、一応空白が含まれる場合もそのまま処理はできますが、少し注意が必要で、例えばこの場合
  set timefmt "%m/%d/%Y %H:%M:%S"
  とすると、例えばデータが、
  02/11/2007 11:30:00 1.00 02/11/2007 12:00:00 2.00
  のような場合は、$1 が日時データになりますが、 1.00 や 2.00 の方は $2 ではなく、$3 になります。詳しくは、help set timefmt, help time/date を参照してください。
  
  (1501 の記事から始まるスレッド「plotコマンドの指定についてお教え願います」)
- gnuplot が「line3: ';' expected」のようなエラーを出すが、これはどういう意味か、という質問がありました。
  
  こういうエラーは、プログラミング言語のコンパイルエラーと似ていて、コンピュータ側が解釈に困った場所のエラーを出しているので、実際には、それより前に問題が起きている場合があったり、本当の間違いの意味とは異なる表示を行っている場合があります。
  
  直接的には、「3 行目に ';' が足りない」と言っています。多分、その ';' が足りない (と gnuplot が思っている) 箇所に、その一つ上の行で '^' のような記号でその場所を指示していると思います。
  
  今回は、その 3 行目には「set xdata depth」というものが書かれていたことによる問題でした。set xdata は、正しくは
  set xdata
  set xdata time
  のいずれかの使用のみ許されています。よって「set xdata depth」は、本来ならば「最後の depth がおかしい」と言うべきですが、 gnuplot はこの行を頭から解釈し、 "set xdata" の次に "time" 以外のオプションが現れたことで、
  「これはここに ';' を入れ忘れたのではないか、すなわち "set xdata ; depth" として一旦その set 命令を終わりたかったのではないか」
  と解釈したわけです。そうでないと set xdata の命令が仕様としておかしいからです。そういう意味で ';' が足りないと言っているわけです。もちろん、この場合は ';' をそこに入れても、 "depth" なんていうコマンドはありませんからやはりエラーになるのですが、後ろの depth はまだ認識せずに、とりあえず行の頭から解釈してきたときにそうとしか解釈できなくなったので、このようなエラーを出したわけです。
  
  この辺は、コンパイルエラーを読み解くのと同じで、エラーが果たしてどういうことを意味しているのかを知るのは、経験みたいなものが必要になります。よって、よくわらなければ、とりあえずはエラーが出ている行に書いたコマンドを、オンラインヘルプで調べてみるのがいいと思います。
  
  (1490 の記事から始まるスレッド「エラーが出ます」)
- 古い記事へのフォローの形で、目盛りにつける見出し (数字) を軸から離す方策として、
  set format x "%15.1f"
  のようなものが紹介されました。ちなみに、古い記事 (218) では、
  set format x "\n%g"
  のようなものが紹介されていました。
  
  これらは gnuplot-4.2 以降であれば、 set xtics の offset オプションで見出し位置を明示的にずらすことができます。しかも、その指定数値の座標系も `first`, `second`, `graph`, `screen`, `character` のようなものをつけて指定することができます。
  
  なお、4.2 (rc 版) 以降の MS-Windows 版バイナリは、以下にあります。
  - 4.2 (rc 版): http://gnuplot.sourceforge.net/development/binaries/
  - 4.3 (CVS 版; 角藤さん作): ftp://ftp.ring.gr.jp/pub/text/TeX/ptex-win32/utils/
  (1489 の記事から始まるスレッド「目盛の数字を軸から離すには」)
- y=f(x1) という x1 軸から y 軸へのグラフを書き、 x1 と x2 の関係式を与えておいて、その x1 軸の目盛りに対応する x2 軸の目盛り (非線形な目盛り) をつけることはできないか、という質問がありました。
  
  個人的には、非線形な目盛りは、その刻み (tics) を見ても、刻みと刻みの間隔は不等間隔なので、その軸上の値が何であるかはわかりにくいし、それなら x2 軸と y へのグラフを別に書く、あるいはそのグラフに重ねて書けばいいのでは、と思いますが、そのような非線形軸を実現する方法として、以下のような回答がありました。
  - データをあるプログラムに作らせるなら、いっそその中で set x2tics の明示的な指定もデータファイルとして作成させる
  - gnuplot 4.2 以降ならば、データから目盛りの見出しの数字を with labels で適当な位置へ書き出せるから、それと yerrorlines を使って x2tics を自作してしまう例 (1482 の記事)
  - x2 軸はあくまで線形軸にしておいて、そこから with vector を使って、x2 軸から、その y=f(x1) のグラフ上の対応する点へ矢印を書く
  1482 の記事の例は、この掲示板のオーナーでもある松田＠東京電機大さんの例ですが、 gnuplot の新しい機能を使った、まさに超絶技巧な例です。
  
  ところで、上記の例は 2 つとも x2 軸のグラフ上の位置、すなわちグラフ内の y の最大値が必要になるのですが、これはこちらから yrange を指定するのなら問題はありませんが、自動縮尺の場合は gnuplot-4.2 以降ならば GPVAL_Y_MAX という変数でそれを gnuplot 内で取得することができます。もちろん、一度描画データを読み込ませる必要があるので、 1 度空表示をしなければいけませんが、 set term post として set output "/dev/null" (Unix の場合; MS-Windows の場合は &uqot;NUL" ?) などへ空表示させればいいでしょう。そうすれば GPVAL_Y_MAX に gnuplot が自動計算するグラフの y の最大値が保存され、それを利用することができます (help gnuplot-defined, show variable all 参照)。
  
  (1478 の記事から始まるスレッド「目盛の振り方について」)
(01/25 2007) (しおり用)
昨日 (01/24 2007)、 4.2 rc4 の公開のアナウンスをしましたが、そこでマニュアルの日本語訳は少し後になると書いたのですが、マニュアル等の変更部分は 4.3 の開発版の方に入っているものがほとんどだったので、(試験の採点の息抜きに) やってしまいました。「gnuplot マニュアルの日本語訳」のページを参照してください。
(01/24 2007; no.2) (しおり用)
gnuplot のページのリンクリストを修正しました。リンク切れの削除等が主ですが、2 つ新たに追加もしました。かなりのリンクが切れていましたので、ちょっと寂しくなったかな ?
(01/24 2007) (しおり用)
gnuplot-4.2-rc4 が出ました。これが 4.2 rc の最終版だろうと思います (としたいようです)。

なお、gnuplot-4.2-rc4 の直前に 4.2-rc3 が出たのですが、その configure スクリプト (readline 周り) を修正して 4.2-rc4 としたようです。詳しくは以下参照:
- comp.graphics.apps.gnuplot に流れたアナウンス記事: 「Gnuplot version 4.2-rc4 (-rc3 contained a mangled file)」
このマニュアルの日本語訳や日本語化キットの公開は、今少し忙しいので、今週末か来週末くらいにはやりたいと思います (前のとそう違わなければ早いかも)。
(01/19 2007) (しおり用)
「注意、その他 (01/08 2007)」にも書きましたが、現在の CVS 版 (4.3) の gnuplot はコマンドのあいまいさが少し取り除かれていて少し今までの書式と違うところがあります。

gnuplot.doc ドキュメントには、「backwards compatibility」の節に、
「以前の版で使われていたいくつかの書式は gnuplot 4.0 で非推奨となりましたが、それは今でも認識はされ続けています。これは現在コンパイル時に制御され、以下のようにして無効にできます:
./configure --disable-backwards-compatibility
注意: 非推奨の書式は、未来の gnuplot のある版からは、完全に無効になってしまうかもしれません。」
と書かれているのですが、実際には現在の CVS 版は既に、
--enable-backwards-compatibility : 非推奨の書式を有効にする
をつけて configure しないと認識されないようになっています。

例えば、新しい仕様だと、
plot sin(x) w lp 3
のような書き方は許されず、
plot sin(x) w lp lt 3
のようにしなければいけません。今までのスクリプトを利用したまま CVS 版に入れ変えるとちょっと混乱するかもしれません。
(01/08 2007; no.2) (しおり用)
gnuplot Q&A 掲示板での見聞き等で得た情報を備忘録として書いておきます。
- MS-Windows 版の wgnuplot で、日本語名のファイルを取りこむことができない、といった報告がありました。 wgnuplot では、gnuplot スクリプトファイルを MS-Windows 版の wgnuplot で、gnuplot スクリプトファイルをマウスでドラッグして wgnuplot のコマンドウィンドウにドロップすると自動的に "load 'C:\なんたら'" というものが wgnuplot 上で実行されるのですが、どうやらこれがうまくいかない、らしいです。
  元記事の方が試したところ、 MS-Windows のシステムフォント (wgnuplot のフォント設定ではなく)、 MSゴシックなどから Tahoma などのフォントに変更したらうまくいくよういなった、という報告がありました。
  こちらではそのような問題が再現されませんし、そもそも MS-Windows についてはよくわかりませんが、そういうこともあるんでしょうかね。
  (1435 の記事から始まるスレッド「外部データの取り込みについて (関連事項)」)
- gnuplot が作成したようなデータ (gnugraph terminal) から、元のデータを復元することはできないか、という質問がありました。
  少なくとも gnuplot が作成する gnugraph データはバイナリのデータファイルで、 gnuplot はこのデータを処理することはできません。処理をしたければ、GNU plotutils のツールで、ということになるのでしょうが、それでも元のデータを復元できるかは知りません。
  (1454 の記事から始まるスレッド「TXT　⇒　グラフ　でなく、グラフ　⇒　ＴＸＴ　は可能か？」)
- 主目盛と副目盛のところにそれぞれ 2 種類の格子線 (grid) を書きたい、という質問がありました。
  help grid を見ればわかりますが、 gnuplot-3.7 位からそれぞれ別の線種、線幅で書けるようになっています。逆に、明示的に指定しないと、副目盛の格子線は主目盛の格子線と同じになります。
  (1462 の記事から始まるスレッド「方眼紙のような２種類の線種を使ったグリッド表示」)
- MS-Word に貼り付けたいという目的でグラフの画像を作りたいのだが、 enhanced mode を利用して軸や key に日本語を使っている場合、文字化けしたり (png terminal)、回転されたり (win terminal + クリップボード)、 MS-Word に拒否されたり (emf terminal) してうまくないが、という質問がありました。
  質問者は MS-Windows だけでなく Linux でも使える、ということでしたが、これに対して、
  - Linux が使えるなら PostScript を作っておいてそれを ImageMagick などで画像化してはどうか
  - png terminal で文字化けするのは、 gnuplot のホームページのものは original の gd library をリンクしてるだろうから多分 UTF-8 で書けばうまくいくだろうし、角藤版なら Shift_JIS のままでうまくいくだろう、それでもだめならフォント指定の問題では
  - term win enh でベクトル画像として貼り付けるとレイアウトが崩れるのでビットマップとして貼るとよい
  - term post enh だと、illustrator に通すか、 gsview でビットマップに変換する必要があるだろう
  - 日本語が必要な場合は、MS-Word に貼り付けた後でそちらで日本語を打つ方が早い
  といった回答がありました。
  (1465 の記事から始まるスレッド「軸名や凡例が日本語やギリシア文字のときのWORDへの貼り付け」)
- 散布図の各データに数値を並べて書きたいが、という質問がありましたが、まさにこのような目的で 4.1 以降に with labels というものが導入され、これを使えば可能、という回答がありました。
  (1472 の記事から始まるスレッド「データ表示」)
(01/08 2007) (しおり用)
前回の報告 (11/13 2006)以後、現在の CVS 版に入れられた主な機能について紹介します (ChangeLog, manual の更新部分等より)。
- 一般的な機能
  - hidden3d の空データのチェックを強化
  - set view map と 2D グラフに関する bug の修正
  - splot における rgbimage の制限の緩和 (長方形面以外も描画可能)
  - newhistogram の bug の修正
  - 幅 0 の box 描画をしないように修正
  - impulse に対するファイルからの色の値が使われなかった問題の修正
  - splot で最初のデータファイルに有効なデータがなかった場合に自動縮尺に失敗する問題の修正
  - 画像描画と逆向きの range に対する問題の修正
  - x2tics out mirror での bug の修正
  - カンマ区切りデータファイル内の引用文字列の処理の問題の修正
  - set view map の front/back, bmargin の処理の修正
  - binary array などの指定の ',' 区切りを ':' 区切りに変更
  - set label, set title の tc に rgb 指定サポートが追加
- terminal ドライバ
  - パレットをサポートしないドライバでも rgbimage が使えるように修正
  - emf terminal で rgbimage, pm3d, rgb color 指定、point type のサポート
  - fig terminal の多角形描画ルーチンの改良
  - fig terminal の色の処理ルーチンの bug の修正
  - svg terminal の改良
  - pdf terminal の set size の処理の bug の修正
  - pbm driver の size 処理の修正
  - gd driver の bug の修正とブラシに関する改良
  - wxt terminal とそれに関する configure の修正
  - svg terminal の Unicode 処理を改変
  - png terminal の trucolor transparent のときの問題の修正
  - postscript 以外の terminal で set size (描画サイズの変更) と 'set term ... size' (全体の画像サイズ) の役割を統一化 (see "help canvas", "help set size")
- その他
  - tutorial/ のファイルの修正
  - 後方互換性を configure オプションにし (デフォルトでは使用されない)、ドキュメントにそれに関する節を追加
- デモ
  - image.dem の修正
  - margins.dem, html/webify.pl, html/index.save の修正
  - layout.dem にデモを追加
  - rgb_variables.dem の修正
  - image.dem を image.dem, image2.dem に分割
  - borders.dem の修正
  - transparent_solids.dem の修正
見てわかる通り、今回は新しい機能はなくほとんどが問題の修正やちょっとした改良なのですが、 "set size" と "set terminal ... size" の考え方に統一性を持たせるようにした、というのは重要だと思います。ただ、これで「情報やメモ (05/23 2006; no.2)」に書いたような、png, ps, x11 で違うことがある、というものが改善されるわけではないようです。

(cf. 「情報やメモ (01/19 2007)」, 「情報やメモ (02/11 2007; no.2)」)

gnuplot (shige) のページへ戻る

作成日: 08/20 2021
竹野茂治＠新潟工科大学 (shige@iee.niit.ac.jp)