書式:
with <style> { {linestyle | ls <line_style>}
| {{linetype | lt <line_type>}
{linewidth | lw <line_width>}
{pointtype | pt <point_type>}
{pointsize | ps <point_size>}} }
ここで、
style
は lines, points, linespoints, impulses, dots,
steps, fsteps, histeps, errorbars, xerrorbars, yerrorbars,
xyerrorbars, boxes, boxerrorbars, boxxyerrorbars, financebars,
candlesticks, vector の中のいずれかです。これらのいくつかに対しては
データを付け足す必要があります。それぞれのスタイルの詳細については set
style style をご覧ください。
デフォルトのスタイルは set function style や set data style コマン ドで決定されます。
デフォルトでは、それぞれの関数やデータファイルは、使うことができる型の 最大数に達するまで異なる線種、点種を使います。すべての端末用ドライバは 最低 6 つの異なる点種をサポートしていて、もしたくさん要求された場合、 それらを順に再利用していきます。LaTeX ドライバは、それより 6 つ多く点種 (いずれも円の変種) を持っていて、よって点での曲線の描画は 12 種類の曲線 が繰り返されるのみです。PostScript ドライバは (postscript) 全部で 64 種類の 点種を持っています。
一つの描画で線種や点種を選びたいならば、line_type や point_type を
指定してください。これらの値は、その描画で使われる線種や点種を指定する
正の整定数 (または数式) です。使用する端末で使える線種、点種を表示する
には test コマンドを使ってください。
描画の線の幅や点の大きさは line_width や point_size で変更できます。
これらはその各々の端末のデフォルトの値に対する相対的な値として指定しま
す。点の大きさは全体に通用するように変更できます - 詳細は set
pointsize を参照してください。しかし、ここでセットされる point_size
と、set pointsize でセットされる大きさは、いずれもデフォルトのポイント
サイズに掛けられることに注意してください - すなわち、それらの効果は
累積はしません。例えば、set pointsize 2; plot x w p ps 3 は、デフォ
ルトのサイズの 3 倍であって、6 倍ではありません。
set linestyle を使って線種/線幅、点種/点幅の組を定義すれば、そのスタ
イルの番号を line_style にセットすることでそれらを使うことができます。
キーワードは暗示するような形で省略可能です。
linewidth と pointsize オプションは全ての端末装置でサポートされて いるわけではないことに注意してください。
例:
以下は、sin(x) を鉛直線で描画します:
plot sin(x) with impulses
以下は、x を点で描画し、x**2 をデフォルトの方式で描画します:
plot x w points, x**2
以下は、tan(x) を関数のデフォルトの方式で、"data.1" を折れ線で描画します:
plot [ ] [-2:5] tan(x), 'data.1' with l
以下は、"leastsq.dat" を鉛直線で描画します:
plot 'leastsq.dat' w i
以下は、データファイル "population" を矩形で描画します:
plot 'population' with boxes
以下は、"exper.dat" をエラーバー付きの折れ線で描画します (エラーバーは
3 列、あるいは 4 列のデータを必要とします):
plot 'exper.dat' w lines, 'exper.dat' notitle w errorbars
以下は、sin(x) と cos(x) をマーカー付きの折れ線で描画します。折れ線は
同じ線種ですが、マーカーは異なったものを使います:
plot sin(x) with linesp lt 1 pt 3, cos(x) with linesp lt 1 pt 4
以下は "data" を点種 3 で、点の大きさを通常の 2 倍で描画します:
plot 'data' with points pointtype 3 pointsize 2
以下は、2 つのデータ集合に対して、幅のみ異なる線を用いて描画します:
plot 'd1' t "good" w l lt 2 lw 3, 'd2' t "bad" w l lt 2 lw 1
デフォルトの表示方法の変更方法については、set style を参照して下さい。