7 注意

以下に、いくつか注意を上げます。

• スペースや改行
  csh スクリプトでは、先頭行の #! 以外では、 見やすさのために行頭にインデント (いくつかのタブやスペース) を入れることは構いません。 適宜空行を入れることも可能です。

  ただし、スペースを入れるべきところにスペースを入れないとエラーとなります。 例えば if や while とカッコの間は、 C 言語とは違いスペースを入れる必要があります。

  set も、= の左右のスペースが合っていないとエラーになるようで、 ``set a=3'', ``set a = 3'' はいいのですが、 ``set a =3'', ``set a= 3'' はだめなようです。

• 変数展開と構文解釈のタイミング
  csh スクリプトでは、各行を読み込んだときに、 行全体の変数展開が行われてから構文の解釈が行われるようなので、 例えば if 文では以下はエラーになりえます。

  if ( $#argv > 0 ) goto $argv[1]
  if ( $#argv > 0 && $argv[1] == "2" ) then
  　　...

  C 言語ならば、 最初の方は $#argv が 0 のときは goto の部分は無視されるので、 $argv[1] が定義されていようがいまいが関係ないのですが、 csh スクリプトの場合は、 この if 文の評価の前に $#argv と $argv[1] の展開をするので、 $#argv が 0 ならば $argv[1] が定義されていないという エラーになってしまいます。 後者も、C 言語ならば $#argv が 0 のときは && の後半は無視されるのですが、 csh スクリプトでは先に $#argv と $argv[1] の展開をしてから if 文の評価をしようとするのでエラーとなります。

• - から始まる文字列
  Unix では ``-h'' のように、 - から始まる文字列をオプションとして使うことが多いですが、 そのような文字列を直接以下のように比較するとエラーとなります:

  if ( $argv[1] == -h ) then
  　　...

  この場合例えば $argv[1] に ``-h'' のような文字列が入っていると、 if 文のカッコ内が ``-h'' から始まることになり、 それがファイル検査式と判断されようとしてエラーになるので、 先頭に余計なアルファベットを付加して、

  if ( "X$argv[1]" == X-h ) then
  　　...

  のようにしないといけません。

  なお、while 文のカッコ内も式の評価が行われますので同じ問題が起こりますが、 switch 文のカッコ内は式の評価が行われませんので、 このような対処は不要です。

• リスト変数に部分リスト変数を代入
  リスト変数は、それ自体を他のリスト変数に部分リストとして代入することで 結合することができます。例:

  set s1 = ( 3 4 5 )
  set s2 = ( 1 2 $s1 6 7 )

  とすると、s2 には ( 1 2 3 4 5 6 7 ) が入ります。 csh スクリプトでは、変数の展開が行われてから式の評価が行われるので、 以下の s2 も上と同じ結果になります:

  set s1 = "3 4 5"
  set s2 = ( 1 2 $s1 6 7 )

  しかし、これを

  set s1 = ( 3 4 5 )
  set s2 = ( 1 2 "$s1" 6 7 )

  としてしまうと、$s2[3] が ``3 4 5'' という文字列、 $#s2 は 5 となります。 だから、逆に、

  set s1 = ( "1 2" 3 )
  set s2 = ( $s1 4 5 )

  とすると、s1 が持っていたスペースの含まれる文字列要素 $s1[1] を s2 では保持することができず、バラバラの要素に分かれてしまいます。 特に、`*', `?', `[ ]' のような特別な文字が含まれる 文字列を要素として持つ場合は、 引用符で囲まれなくなった時点で ファイル名パターンマッチ機能が働こうとしておかしくなり得ます。

• サブルーチン
  csh スクリプト内ではサブルーチンを書けません。 goto ジャンプを使えば多少は実現できますが、 goto ジャンプでは while や foreach 文などのループの中に 戻ることはできません。