GNUPLOT
An Interactive Plotting Program
Thomas Williams & Colin Kelley
Version 4.0 organized by: Lars Hecking
Copyright (C) 1986 - 1993, 1998, 2004 Thomas Williams, Colin Kelley
Mailing list for comments: gnuplot-info@lists.sourceforge.net
Mailing list for bug reports: gnuplot-bugs@lists.sourceforge.net
This manual was prepared by Dick Crawford
3 December 1998
Major contributors (alphabetic order):
Copyright (C) 1986 - 1993, 1998, 2004 Thomas Williams, Colin Kelley
Permission to use, copy, and distribute this software and its documentation for any purpose with or without fee is hereby granted, provided that the above copyright notice appear in all copies and that both that copyright notice and this permission notice appear in supporting documentation.
Permission to modify the software is granted, but not the right to distribute the complete modified source code. Modifications are to be distributed as patches to the released version. Permission to distribute binaries produced by compiling modified sources is granted, provided you
1. distribute the corresponding source modifications from the
released version in the form of a patch file along with the binaries,
2. add special version identification to distinguish your version
in addition to the base release version number,
3. provide your name and address as the primary contact for the
support of your modified version, and
4. retain our contact information in regard to use of the base
software.
Permission to distribute the released version of the source code along with corresponding source modifications in the form of a patch file is granted with same provisions 2 through 4 for binary distributions.
This software is provided "as is" without express or implied warranty to the extent permitted by applicable law.
AUTHORS
Original Software:
Thomas Williams, Colin Kelley.
Gnuplot 2.0 additions:
Russell Lang, Dave Kotz, John Campbell.
Gnuplot 3.0 additions:
Gershon Elber and many others.
Gnuplot 4.0 additions:
See list of contributors at head of this document.
(以下おおまかな訳; 訳は正しくないかも知れませんので詳しくは上記の原文 を当たってください。訳者は責任を持ちません。)
Copyright (C) 1986 - 1993, 1998 Thomas Williams, Colin Kelley
このソフトウェアとその付属文書の使用、複製、配布の許可は、上記の著作権 (copyright) 表示が、全ての複製物に書かれていること、および著作権表示と この許諾文の両方がその支援文書に書かれていることを条件とした上で、この 文書により保証されます。
このソフトウェアの修正も認められています。しかし、修正を含む全ソースコ ードの配布の権利は認められません。修正はリリース版に対するパッチの形で 配布しなければなりません。修正されたソースをコンパイルして作られたバイ ナリの配布は、以下の条件の元で認められます:
1. リリース版からのソースの修正部分を、パッチの形でバイナリと共に配
布すること
2. ベースとなるリリース版と区別するために、そのバージョン番号に特別
なバージョン指定子を付加すること
3. その修正版のサポート用に、あなたの名前とアクセス可能なアドレスと
を提供すること
4. ベースとなるソフトウェアの使用に関しては、我々の連絡情報を保持し
続けること
リリース版のソースコードを、パッチの形でのソースの修正と一緒に配布する ことは、バイナリ配布に関する条項 2 から 4 までの条件の元で許されます。
このソフトウェアは "あるがまま" 提供され、適用可能な法律で許められる範 囲の保証を表明あるいは暗示していはいません。
著者
オリジナルソフトウェア:
Thomas Williams, Colin Kelley.
Gnuplot 2.0 追加:
Russell Lang, Dave Kotz, John Campbell.
Gnuplot 3.0 追加:
Gershon Elber とその他の人々。
Gnuplot 4.0 追加:
この文書の最初にある寄与者 (contributors) のリスト参照。
`gnuplot` は，コマンド入力方式の対話的な関数描画プログラムです．コマン ドや関数名は大文字小文字を区別します．いずれのコマンドも，あいまいさ の無い限りにおいて省略することができます．1行中にはセミコロン(;)で区 切って複数のコマンドを書くことができます (ただし、`load` と call は 最後のコマンドでなければなりません)．文字列は引用符を使って表します． 引用符は，一重でも，二重でも構いません．例えば
load "filename"
cd 'dir'
しかし、両者には微妙な違いがあります (詳細は `syntax` を参照してくだ さい)。
コマンドラインでの引数は `gnuplot` 用のコマンドの書かれたファイルの名前 であるものとします．但し標準の X11 の引数は例外で，まず最初に処理され ます．各ファイルはコマンドライン上で指定された順に `load` コマンドで ロードされます．`gnuplot` は，最後に指定されたファイルを処理し終ると終 了します．ファイルが1つも指定されていない場合は，`gnuplot` は対話モー ドになります．特別なファイル名 "-" は標準入力を表します。詳細は "help batch/interactive" を参照してください。
`gnuplot` のコマンドの多くは複数のオプションを持っています。これらの オプションは、ほとんどの場合、不必要なものが省略できるよう、適切な 順序で指定することになっています。よって、もしコマンドの全部の指定が "command a b c" である場合、"command a c" は多分うまくいくでしょうが、 "command c a" はうまくいかないかもしれません。
コマンドは，複数行にまたがることができます．その場合は，最終行以外の 全ての行の行末にバックスラッシュ (\) を書く必要があります．バックス ラッシュは必ず各行 *最後* の文字でなくてはなりません．その結果として バックスラッシュと，それに続く改行文字が存在しなかったかのように扱わ れます．つまり，改行文字がスペースの役をすることもありませんし，改行 によってコメントが終了することもありません．ですから複数行にまたがる 行の先頭をコメントアウトすると，そのコマンド全体がコメントアウトされ ることになります (`comment` 参照)．なお注意しますが、もし、複数行のコ マンドのどこかでエラーが起きたとき、パーサはその場所を正確には指示す ることができませんし、また、正しい行に指示する必要もないでしょう。
このドキュメントにおいて，中括弧 ({}) は省略可能な引数を表すものとし、 縦棒 (|) は，互いに排他的な引数を区切るものとします．`gnuplot` のキー ワードや help における項目名は，バッククオート (｀) または可能な場合 には `boldface` (太字) で表します．角括弧 (<>) は，それに対応するもの に置き換えられるべきものを表します．多くの場合、オプションの引数には それが省略されるとデフォルトの値が使用されます。しかし、これらの場合 必ずしも角括弧が中括弧で囲まれて書かれているわけではありません。
ある項目についてのヘルプが必要なときには，help に続けてその項目名を 入力して下さい．または単に help や `?` でもヘルプの項目のメニューが 現われます。
初めて `gnuplot` を使う方は，`plotting` に関する説明から読みはじめると 良いでしょう (現在使用中であれば `help plotting` と入力して下さい)．
simple.dem デモを参照してください。あるいは以下の Web ページにも他のデ モと一緒にあります。 http://www.gnuplot.info/demo/simple.html
`gnuplot` ユーザのためのメーリングリストがあります。しかし、ニュースグ ループ
comp.graphics.apps.gnuplot
は、そのメーリングリストと同等であることに注意してください (どちらにも 同じメッセージが流れます)。私達はメーリングリストに参加するより、むし ろニュースグループのメッセージを読むことを勧めます。メーリングリストに 参加する方法に関しては、SouceForge にある gnuplot の開発 Web サイト http://sourceforge.net/projects/gnuplot を参照してください。
メーリングリストメンバーへのメールアドレス:
gnuplot-info@lists.sourceforge.net
バグリポート、ソースの改良等は次のところへ:
gnuplot-bugs@lists.sourceforge.net
βテスト版に関するメーリングリスト:
gnuplot-beta@lists.sourceforge.net
公式の (そしてたまに更新が遅れることもある) WWW ページもあります。 http://www.gnuplot.info
助けを求める前に、次をチェックしてください: FAQ (度々聞かれる質問; Frequently Asked Questions) の一覧
何か質問を投稿するときは、あなたが使用している `gnuplot` のバージョン、 実行マシン、オペレーティングシステム、といった全ての情報を含むようにし てください。その問題を引き起こす _小さい_ スクリプトがあればなお良いで す。その場合、データファイルのプロットよりも関数のプロットの方がより良 いです。もし、gnuplot-info へメールをするなら、そのメーリングリストの 購読をしているかどうかを述べてください。そうすれば、ニュースを見たユー ザはあなたへの返事をメールで出せば良いことが分かるでしょうから。そのよ うな記事のポストの form が WWW サイトにあります。
これまでの最新の gnuplot の公式な リリース版は version 3.7 で、それは 3.7.3 まで更新されています。gnuplot version 4.0 では新しい機能がたくさ ん備えられていて、それらは 3.8a から 3.8k での開発スナップショット版の 中で徐々に追加されて来たものです。この節では主な追加機能や、修正や小さ な追加機能を一部紹介します。gnuplot の配布物には、それらの機能のとても たくさんのデモを行うサンプルスクリプトが付属していますので、ここではそ の名前を参照することにします。
マウス、またはホットキーによる現在の描画への作用が、X11, OS/2 プレゼン テーションマネージャ、ggi, windows 出力ドライバでサポートされています。 マウス動作に関する詳細は `mouse input` を、ホットキーに関する詳細は bind を参照してください。また、ggi, `pm`, `windows`, `x11` それぞ れのマウス動作に関する記述も参照してください。
ここでいくつか有用なホットキーを紹介します。 対話可能な出力ウィンドウ上で、'h' はヘルプ、'm' はマウス機能の ON/OFF、 'g' はグリッド、'l' は対数軸、'e' は replot となります。 'r' は特定の点での値と比較するための定規 (ruler) を用意します。通常の 軸では定規との距離、対数軸では定規の値との比を計測できます。'5' は極座 標での定規用です。 マウスでの拡大 (MB3) に対して拡大の履歴への移動は 'p', 'u', 'n' で、 'a' は自動縮尺機能です。 他のマウスボタンは現在のマウスの位置をクリップボードに出力したり (MB1 のダブルクリック)、一時的な、あるいは永続的な見出しをつけたり (真中の ボタン MB2) します。 3 次元曲面はマウスで回転します。 space キーで gnuplot のコマンドウィンドウに移ります。
サンプルスクリプト: mousevariables.dem
`png` および `jpeg`: libgd を使う新しいドライバによる PNG 画像、JPEG 画像出力のサポート。新しいドライバは、TrueType フォントなど、以前の PNG ドライバよりもより多くの機能をサポートします。libgd が必要です。
`postscript`: PostScript ドライバは、現在は oblique symbol フォントも 使えますし、実行時に PostScript フォントを埋め込むことも可能です。また 文字エンコードも追加されてサポートされています。 `postscript fontfile` と encoding を参照。
サンプルスクリプト: fontfile.dem svg: 縮尺可能なベクトルグラフィックス (Scalable Vector Graphics) を 出力する新しい出力形式。
`x11`: X-windows ドライバは現在では、フォントの指定が可能になっていま す。`set term x11 x11_fonts` を参照。x11 で同時に使用できる描画ウィン ドウ数の制限は現在はなくなっていますし、それぞれの描画ウィンドウにそれ ぞれのタイトルを付けることも可能です。`set term x11` 参照。
コマンド `splot` は現在では、2 次元の色地図や 3 次元曲面を、灰色階調や カラーパレットで連続階調で塗ることができます。pm3d, palette, cbrange, `set view map`, `set colorbox`, palette 参照。
サンプルスクリプト: pm3d.dem pm3dcolors.dem pm3dgamma.dem
`filledcurves` 描画スタイルでは、描画される曲線と水平線の間の領域を塗 りつぶすことができます。
サンプルスクリプト: fillcrvs.dem
boxes 描画スタイルを含む幾つかの描画スタイルに対して、カラーによるベタ 塗り、またはパターンによる塗りつぶしを設定できます。`boxes`, `boxerrorbars`, `boxxyerrorbars`, `candlesticks`, `set style fill` 参照。
サンプルスクリプト: fillstyle.dem candlesticks.dem
データの近似や補間に関する幾つかのルーチンが用意されていて、それで入力 データをフィルタできます。smooth, `frequency`, `unique` 参照。
サンプルスクリプト: step.dem mgr.dem
文字列のラベルを生成するほとんどの gnuplot の描画コマンドは、現在は文 字色、フォント、大きさ、回転角度の指定を受け付けます。label 参照。 しかし、全ての出力形式がこれらをサポートしているわけではありません。 拡張テキストモードは postscript, pm 出力形式では既に有効だったものです がそれが、他の出力形式にも拡張されました。この機能をサポートしているの は、dump, jpeg, pdf, pm, png, postscript, x11 などです。`enhanced text` を参照。
サンプルスクリプト: textcolor.dem textrotate.dem
`postscript`, `x11`, `pm` などのいくつかの出力形式で、文字コード化 (`encodings`) のサポートがいくつか追加されています: ISO 8859-1 (Latin 1), ISO 8859-2 (Latin 2), ISO 8859-15 (ユーロ記号を含む 8859-1 の亜種), KOI8-R (キリル文字), および幾つかのコードページ。詳細は encoding 参 照。
片方、あるいは両端に矢先のついた矢を、`plot with vectors` スタイルを用 いて、データファイルから、あるいはコマンドラインから別々に描画グラフ上 に配置することが可能です。arrow, `plotting styles vectors` 参照。
サンプルスクリプト: arrowstyle.dem
新しい `set datafile` コマンドは、入力データの形式に関する情報を指定す るのに使えますが、例えばフィールドを分離する文字やコメント行を意味する 文字、欠けたデータを示す文字の指定などに使えます。gnuplot は、現在は datafile 形式の設定に基づいて、空白を持つような文字列フィールドも単一 項目とみなすことができます。これにより表計算ソフトが出力するような csv (コンマ分離形式) ファイルの入力も可能になります。`set datafile` 参照。
`set <something>` を undo するコマンドは現在は `set no<something>` で はなくて `unset <something>` になっていて、以前の形は批判されてきました。 Version 4.0 では、まだ古い書式も使えるようになっていますが、そのような 後方互換性は将来の版では失われるでしょう。
`set <something> <style>` の形式のコマンドも、より一般的な形式である `set style <something> <options>` に置き換えられています。現在は多くの 描画要素自身がスタイルオプションを持つようになっています。例えば矢 (arrows)、塗りつぶされた領域 (filled area)、線 (lines)、点 (points) な どです。入力データの設定や、書式に関するスタイルもあります。style, decimalsign, `set datastyle` 参照。
2 次元、3 次元のクリッピング (隠線処理) も改良されました。
全ての出力形式に渡って、点のスタイル、デフォルトの書式スタイルがより一 貫した形になりました。選択している出力形式のデフォルトスタイルや描画機 能のチェックは test を使ってください。 label コマンドは、点 (point) の関連付け、点の形 (point style) の 指定、文字列のスタイル (フォント、回転等) の指定等が可能になりました。 ラベル文字列に書式修飾子を使って変数の値を入れることもできるようになり ました。label 参照。
新しいコマンド `set view map` は 3 次元曲面描画の 2 次元射影の真上から 表示を選択するものです。
`set term push` と `set term pop` も新しいコマンドで、これはプラットホ ームに依存しない形式で、何らかの出力後にある出力形式を復帰する方法を提 供します。
コマンド `load` と save は、それぞれパイプ入力、パイプ出力も受け付け るようになりました。
コマンド `history` (gnuplot 自身の readline に関しての話で、GNU readline に関してではありません) は現在いくつか有用なオプションを持っ ています。
組み込み関数 `rand(x)` は、疑似乱数の生成用の種 (seed) を明示的に指定 できるように修正されました。`random` 参照。
MS Windows パッケージには実行ファイル `pgnuplot.exe` が追加されていま すが、これは標準入力からのパイプをサポートするためのものです。そのよう なパイプ機能は、そのシステムの標準ではグラフィックアプリケーションには 提供されていません。
docs/psdocs/ ディレクトリには、gnuplot の PostScript 出力ガイドといく つかのコード化 (encoding) におけるポストスクリプトの記号の一覧がありま すが、そこからも新しい情報を得ることができます。
FAQ も改良されています。公の場で質問する前に、是非それを一読してくださ い。
demo/ ディレクトリにはとてもたくさんの新しいデモファイル *.dem があり ます。助けを請う前に、例えば
load "all.dem"
のようにして是非それらを実行してみてください。デモスクリプトで生成され る描画は以下でも見ることができます。 http://www.gnuplot.info/demo/
`gnuplot` は多くのシステム上で、バッチ処理形式、あるいは対話型のどちら の形式でも実行でき、それらを組み合わせることも可能です。
コマンドライン引数は `gnuplot` コマンドを含むファイルのファイル名であ ると解釈されます (先に指定される標準的な X11 用コマンドの引数を除いて)。 各ファイルは、指定された順に `load` コマンドで読み込まれます。最後のフ ァイルを実行した後は `gnuplot` は終了します。ロードファイルを指定しな い場合は、`gnuplot` は対話モードに入ります。特別なファイル名 "-" は標 準入力を指定するのに使われます。 exit と quit はどちらも現在のコマンドファイルを終了し、まだ全ての ファイルが終っていなければ、次のファイルを `load` するのに使われます。
例:
対話を開始する:
gnuplot
2 つのコマンドファイル "input1", "input2" を使ってバッチ処理を行なう:
gnuplot input1 input2
初期化ファイル "header" の後、対話型モードを起動し、その後別のコマンド ファイル "tailer" を実行する:
gnuplot header - trailer
コマンドライン編集は Unix, Atari, VMS, MS-DOS and OS/2 上の `gnuplot` でサポートされています。履歴 (ヒストリ) 機能で、以前のコマンドを編集し 再実行することも出来ます。コマンドラインの編集後は、カーソルがどこにい ても改行や復帰キーによって行全体が入力されます。
(`gnuplot` における readline 関数は、GNU Bash や GNU Emacs で使われる readline 関数と全く同じではありません。もし、GNU 版を望むなら、コンパ イル時に `gnuplot` 版の代わりに選択できます)
編集コマンドは以下の通りです:
`行編集`:
^B 1 文字前へ戻す
^F 1 文字先へ進める
^A 行の先頭に移動
^E 行の最後に移動
^H,DEL 直前の文字を削除
^D 現在位置の文字を削除
^K 現在位置から行末まで削除
^L,^R 壊れた表示の行を再表示
^U 行全体の削除
^W カーソル手前の単語から行末まで削除
`履歴`:
^P 前の履歴へ移動
^N 次の履歴へ移動
IBM PC では、行編集用に DOSEDIT とか CED などの TSR (常駐) プログラム を使いたいと思うかも知れません。デフォルトの makefile はこれを仮定して いて、`gnuplot` はデフォルトでは行編集機能無しでコンパイルされます。も し `gnuplot` の行編集機能を使用したければ、makefile の READLINE をセッ トしてリンクファイルとして readline.obj を追加してください。IBM PC と Atari 版で readline を使う場合は以下のキーも使えます。
左矢印 (←) - ^B と同じ
右矢印 (→) - ^F と同じ
Ctrl + 左矢印 - ^A と同じ
Ctrl + 右矢印 - ^E と同じ
上矢印 (↑) - ^P と同じ
下矢印 (↓) - ^N と同じ
Atari 版の readline は更にいくつかのエイリアスが定義されています:
Undo - ^L と同じ
Home - ^A と同じ
Ctrl Home - ^E と同じ
Esc - ^U と同じ
Help - help + return.
Ctrl Help - help.
コメントは次のように実装されています: 文字 '#' は，行中のたいていの場 所に書くことができます．このとき `gnuplot` はその行の残りの部分を無視し ます．ただし，引用符の中，数 (複素数を含む) の中，コマンド置換 (command substitution) の中などではこの効果がありません．簡単に言うと，意味 のあるような使い方をしさえすれば，正しく動作すると言うことです．
データファイル中のコメント文字の指定は、`set datafile commentschars` を参照してください。
コマンド arrow, key, label はグラフ上の任意の位置が 指定できます。その位置は以下の書式で指定します:
{<system>} <x>, {<system>} <y> {,{<system>} <z>}
各座標系指定 <system> には、`first`, `second`, `graph`, `screen` のい ずれかが入ります。
`first` は左と下の軸で定義される x,y (3D の場合は z も) の座標系を使用 します。`second` は第 2 軸 (上と右の軸) を使用します。`graph` はグラフ 描画領域内の相対的位置を指定し、左下が 0,0 で 右上が 1,1 (splot の場合 はグラフ描画領域内の左下が 0,0,0 で、土台の位置は負の z の値を使用しま す。ticslevel 参照) となります。`screen` は表示範囲内 (範囲全体 であり、size で選択される一部分ではありません) を指定し、左下が 0,0 で 右上が 1,1 となります。
x の座標系が指定されていない場合は `first` が使われます。y の座標系が 指定されていない場合は x に対する座標系が使用されます。
一つ (あるいはそれ以上) の軸が時間軸である場合、timefmt の書式文字列 に従って、引用符で囲まれた時間文字列で適切な座標を指定する必要がありま す。xdata, timefmt を参照してください。また、`gnuplot` は 整数表記も認めていて、その場合その整数は 2000 年 1 月 1 日からの秒数と 解釈されます。
`gnuplot` は多くのシェル環境変数を認識します。必須のものはありませんが、 使えば便利になるかも知れません。
GNUTERM が定義されている場合、それは使用される出力形式 (terminal) の名 前として使われます。これは `gnuplot` が起動時に見つけた出力形式に優先 して使用されますが、.gnuplot (またはそれに相当する) スタートアップファ イル (`start-up` 参照) による指定や、当り前のことですが、その後に明示 的に指定した物の方が優先されます。
Unix, AmigaOS, AtariTOS, MS-DOS, OS/2 では、GNUHELP にヘルプファイル (gnuplot.gih) のパス名を定義しておくことができます。
VMS では、論理名 GNUPLOT$HELP を `gnuplot` のヘルプライブラリの名前と して定義します。`gnuplot` のヘルプは任意のシステムのヘルプライブラリに 入れることができ、`gnuplot` の内部からでも外部からでも参照して構いませ ん。
Unix においては、カレントディレクトリに .gnuplot というファイルがない 場合には、HOME に定義されたディレクトリを探します。AmigaOS, AtariTOS, MS-DOS, Windows, OS/2 では GNUPLOT がその役割に使われます。Windows で は、NT 専用の変数 USERPROFILE も参照されます。VMS では SYS$LOGIN です。 `help start-up` と打ってみてください。
Unix においては、PAGER がヘルプメッセージの出力用のフィルタとして使わ れます。
Unix, AtariTOS, AmigaOS では、SHELL が shell コマンドの際に使われま す。MS-DOS, OS/2 では COMSPEC が shell コマンドの際に使われます。
MS-DOS で BGI または Watcom インターフェースが使われている場合、PCTRM が、使用するモニタがサポートする最大解像度を指示するのに使われます。 PCTM は S<最大水平解像度> のように指定します。例えば、モニタの最大解像 度が 800x600 ならば、以下のように指定します:
set PCTRM=S800
PCTRM が設定されていなければ、標準的な VGA (640x480) が使われます。
FIT_SCRIPT は、当てはめ (fit) が中断されたときに実行する `gnuplot` コ マンドの指定に使われます。`fit` を参照してください。FIT_LOG は当てはめ によるログファイルのデフォルトのファイル名の指定に使われます。
GNUPLOT_LIB は、データやコマンドファイルの検索ディレクトリを追加定義す るのに使われます。その変数は、一つのディレクトリ名かまたは複数のディレ クトリ名を書くことができますが、ディレクトリの区切りはプラットホーム毎 に違います。例えば Unix では ':' で、DOS,Windows,OS/2,Amiga では ';' です。GNUPLOT_LIB の値は変数 loadpath に追加されますが、それは save や `save set` コマンドでは保存されません。
出力ドライバの中には gd ライブラリ経由で TrueType フォントを扱えるもの もいくつかあります。これらのドライバのフォント検索パスは、環境変数 GDFONTPATH で制御できます。さらに、それらのドライバでのデフォルトのフ ォントは環境変数 GNUPLOT_DEFAULT_GDFONT で制御できます。
postscript 出力ドライバは自分で持っているフォント検索パスを使いますが、 それは環境変数 GNUPLOT_FONTPATH で制御できます。書式は GNUPLOT_LIB と 同じです。GNUPLOT_FONTPATH の値は変数 fontpath に追加されますが、そ れは save や `save set` コマンドでは保存されません。
基本的には C, FORTRAN, Pascal, BASIC において利用可能な数学表現を使用 できます。 演算子の優先順位は C 言語の仕様に従います。数式中の空白文字 とタブ文字は無視されます。
複素数の定数は {<real>,<imag>} と表現します。ここで <real> と <imag> (実部、虚部) は数値定数である必要があります。例えば {3,2} は 3 + 2i を あらわし、{0,1} は 'i' 自身を表します。これらには明示的に中カッコを使 う必要があります。
gnuplot は "実数" と "整数" 演算を FORTRAN や C のように扱うということ に注意してください。"1", "-10" などは整数と見なされ、"1.0", "-10.0", "1e1", 3.5e-1 などは実数と見なされます。 これら 2 つのもっとも重要な違 いは割算です。整数の割算は切り捨てられます: 5/2 = 2。実数はそうではあ りません: 5.0/2.0 = 2.5。それらが混在した式の場合、計算の前に整数は実 数に "拡張" されます: 5/2e0 = 2.5。負の整数を正の整数で割る場合、その 値はコンパイラによって変わります。"print -5/2" として、あなたのシステ ムが -2 と -3 のどちらを答えとするかを確認してください。
数式 "1/0" は "未定義値 (undefined)" フラグを生成し、それによりその点 は無視されます。`ternary` 演算子 (三項演算子) の項にその例があります。
複素数表現の実数部分、虚数部分は、どんな形で入力されても常に実数です: {3,2} の "3" と "2" は実数であり、整数ではありません。
`gnuplot` の関数は、Unix 数学ライブラリの関数とほぼ同じですが、特に注 意がなければ全ての関数が整数、実数、複素数の引数を取ることができます。
度、あるいはラジアンのどちらかで角度を引数としたり戻り値としたりする関 数 (sin(x), cos(x), tan(x), asin(x), acos(x), atan(x), atan2(x), arg(z)) に対しては、その単位は angles で選択でき、デフォルトはラジアンで す。
関数 `abs(x)` 引数の絶対値を返します。返り値の型は引数と同じです。
複素数の引数に対しては, abs(x) は複素平面における x の長さと定義されて います [すなわち sqrt(real(x)**2 + imag(x)**2) ]。
関数 `acos(x)` は引数のアークコサイン (逆余弦) を返します。`acos` の 返す値がラジアン単位かまたは度であるかは angles で選択されます。
関数 `acosh(x)` は逆ハイパボリックコサイン (逆双曲余弦) の値をラジアンで 返します。
関数 `arg(x)` は複素数の偏角を、angles の設定にしたがってラジアン、 または度で返します。
関数 `asin(x)` は引数のアークサイン (逆正弦) を返します。`asin` の 返す値は angles の設定によってラジアン単位かまたは度になります。
関数 `asinh(x)` は逆ハイパボリックサイン (逆双曲正弦) の値をラジアンで 返します。
関数 `atan(x)` は引数のアークタンジェント (逆正接) の値を返します。 `atan` の返す値は angles の設定によってラジアン単位かまたは度に なります。
関数 `atan2(y,x)` は引数の実数部分の比のアークタンジェント (逆正接) の 値を返します。atan2 は angles の設定によってラジアン単位か度に なる、適切な四分円における値を返します。
関数 `atanh(x)` は逆ハイパボリックタンジェント (逆双曲正接) の値をラジ アンで返します。
関数 `besj0(x)` は引数の j0 次ベッセル関数の値を返します。besj0 には 引数はラジアンで与えます。
関数 `besj1(x)` は引数の j1 次ベッセル関数の値を返します。besj1 には 引数はラジアンで与えます。
関数 `besy0(x)` は引数の y0 次ベッセル関数の値を返します。besy0 には 引数はラジアンで与えます。
関数 `besy1(x)` は引数の y1 次ベッセル関数の値を返します。besy1 には 引数はラジアンで与えます。
関数 `ceil(x)` は引数以上の最小の整数を返します。複素数引数に対しては その実数部分以上の最小の整数を返します。
関数 `cos(x)` は引数のコサイン (余弦) の値を返します。`cos` は angles の選択にしたがって、ラジアンまたは度の引数を受け付けます。
関数 `cosh(x)` は引数のハイパボリックコサインの値を返します。cosh の 引数はラジアンで与えます。
関数 `erf(x)` は引数の実部の誤差関数の値を返します。引数が複素数の場合は 虚部は無視されます。erfc, inverf, norm も参照してください。
関数 `erfc(x)` は 1.0 から、引数の実部の誤差関数の値を引いたものを返し ます。引数が複素数の場合は虚部は無視されます。`erf`, inverf, norm も参照してください。
関数 `exp(x)` 引数の指数関数の値 (`e` の引数乗) を返します。環境によっては (特に sun) 大きい x の値に対する exp(-x) は未定義値を返す場合があります。 このような場合、safe(x) = x<-100 ? 0 : exp(x) のようなユーザ定義関数が役に 立つでしょう。
関数 `floor(x)` はその引数以下の最大の整数を返します。複素数引数に対しては floor はその引数の実部以下の最大の整数を返します。
関数 `gamma(x)` は引数の実部のガンマ関数の値を返します。整数 n に対しては gamma(n+1) = n! です。引数が複素数の場合、虚数部分は無視されます。
関数 `ibeta(p,q,x)` は引数の実部の不完全ベータ関数の値を返します。p, q > 0 で x は [0:1] 内の値です。引数が複素数の場合は虚部は無視されます。
関数 `inverf(x)` は引数の実部の逆誤差関数の値を返します。`erf` や invnorm も参照してください。
関数 `igamma(a,x)` 引数の実部の不完全ガンマ関数の値を返します。a > 0, x >= 0 です。引数が複素数の場合は虚部は無視されます。
関数 `imag(x)` は引数の虚数部分を実数として返します。
関数 `invnorm(x)` は引数の実部の逆正規分布関数の値を返します。norm も参照してください。
関数 `int(x)` は、引数の整数部分 (0 に向かって丸めた) を返します。
lambertw 関数は Lambert の W 関数の主値を返します。これは、 (W(z)*exp(W(z))=z で定義されます。z は z >= -exp(-1) を満たす実数でな ければいけません。
関数 `lgamma(x)` は引数の実部のガンマ関数値の自然対数の値を返します。 引数が複素数の場合、虚部は無視されます。
関数 `log(x)` は引数の自然対数 (底 `e`) の値を返します。log10 も参照 してください。
関数 `log10(x)` は引数の対数 (底 10) を返します。
関数 `norm(x)` は引数の実部の正規分布 (ガウス分布) 関数の値を返します。 invnorm, `erf`, erfc も参照してください。
`rand(0)` 内部に持つ 2 つの 32bit の種 (seed) の現在の値から生成され
る [0:1] 区間内の疑似乱数値を返す
`rand(-1)` 2 つの種の値を標準値に戻す `rand(x)` x>0 ならば両方の種に x の値に基づく値を設定する `rand({x,y})` x>0 ならば seed1 を x に、seed2 を y に設定する 注意: これは gnuplot version 3.8l から変更された挙動です。よって、古い gnuplot スクリプトで、rand(x>0) により同じ種からなる疑似乱数列が生成さ れることを期待しているような場合は、代わりに rand(0) を使うように修正 してください。
関数 `real(x)` は引数の実部を返します。
関数 `sgn(x)` は引数が正なら 1 を、負なら -1 を、0 ならば 0 を返します。 引数が複素数の場合虚部は無視されます。
関数 `sin(x)` は引数のサイン (正弦) の値を返します。`sin` は angles の選択にしたがって、ラジアンまたは度の引数を受け付けます。
関数 `sinh(x)` は引数のハイパボリックサインの値を返します。sinh の 引数はラジアンで与えます。
関数 `sqrt(x)` は引数の平方根の値を返します。
関数 `tan(x)` は引数のタンジェント (正接) の値を返します。`tan` は angles の選択にしたがって、ラジアンまたは度の引数を受け付けます。
関数 `tanh(x)` は引数のハイパボリックタンジェントの値を返します。tanh の 引数はラジアンで与えます。
さらにいくつかの関数が追加されています。
`column(x)` は fit あるいはデータファイルプロットでの using の操作の 数式の一部としてのみ使われます。using を参照してくださ い。
`defined(X)` は、変数 X が定義されていれば 1 そうでなければ 0 を返します。
関数 tm_hour は引数を 2000 年 1 月 1 日からの秒数と解釈し、それが 時刻の何時 (0-23 の範囲の整数) であるかを、実数として返します。
関数 tm_mday は引数を 2000 年 1 月 1 日からの秒数と解釈し、それが その月の何日 (1-31 の範囲の整数) であるかを、実数として返します。
関数 tm_min は引数を 2000 年 1 月 1 日からの秒数と解釈し、それが 時刻の何分 (0-59 の範囲の整数) であるかを、実数として返します。
関数 tm_mon は引数を 2000 年 1 月 1 日からの秒数と解釈し、それが 何月 (0-11 の範囲の整数) であるかを、実数として返します。
関数 tm_sec は引数を 2000 年 1 月 1 日からの秒数と解釈し、それが 時刻の何秒 (0-59 の範囲の整数) であるかを、実数として返します。
関数 tm_wday は引数を 2000 年 1 月 1 日からの秒数と解釈し、それが その週の何日目 (0-6 の範囲の整数) であるかを、実数として返します。
関数 tm_yday は引数を 2000 年 1 月 1 日からの秒数と解釈し、それが その年の何日目 (1-366 の範囲の整数) であるかを、実数として返します。
関数 tm_year は引数を 2000 年 1 月 1 日からの秒数と解釈し、それが 西暦何年 (整数) であるかを、実数として返します。
`valid(x)` は、データ描画か fit における using の式の中でしか使われ ません。using を参照してください。
以下も参照してください。 airfoil.dem: 関数と複素変数を翼に使ったデモ
組み込み関数 `rand(x)` の挙動は version 3.8l で変更されました。古い gnuplot スクリプトで、rand(x>0) により同じ種からなる疑似乱数列が生成さ れることを期待しているような場合は、代わりに rand(0) を使うように修正 する必要があります。現在の挙動は以下の通りです: `rand(0)` 内部に持つ 2 つの 32bit の種 (seed) の現在の値から生成され
る [0:1] 区間内の疑似乱数値を返す
`rand(-1)` 2 つの種の値を標準値に戻す `rand(x)` x>0 ならば両方の種に x の値に基づく値を設定する `rand({x,y})` x>0 ならば seed1 を x に、seed2 を y に設定する
`gnuplot` の演算子は、C 言語の演算子とほぼ同じですが、特に注意がなけれ ば全ての演算子が整数、実数、複素数の引数を取ることができます。また、 FORTRAN で使える ** (累乗) 演算子もサポートされています。
演算の評価の順序を変更するにはかっこを使います。
以下は、単項演算子とその使用法の一覧です:
記号 例 説明
- -a マイナス符号
+ +a プラス符号 (何もしない)
~ ~a * 1 の補数 (ビット反転)
! !a * 論理的否定
! a! * 階乗
$ $3 * using 内での引数/列指定
説明に星印 (*) のついた演算子の引数は整数でなければなりません。
演算子の優先順位は Fortran や C と同じです。それらの言語同様、演算の評 価される順序を変えるためにかっこが使われます。よって -2**2 = -4 で、 (-2)**2 = 4 です。
階乗演算子は、大きな値を返せるように実数を返します。
以下は、二項演算子とその使用法の一覧です:
記号 例 説明
** a**b 累乗
* a*b 積
/ a/b 商
% a%b * 余り
+ a+b 和
- a-b 差
== a==b 等しい
!= a!=b 等しくない
< a<b より小さい
<= a<=b 以下
> a>b より大きい
>= a>=b 以上
& a&b * ビット積 (AND)
^ a^b * ビット排他論理和 (XOR)
| a|b * ビット和 (OR)
&& a&&b * 論理的 AND
|| a||b * 論理的 OR
説明に星印 (*) のついた演算子の引数は整数でなければなりません。
論理演算子の AND (&&) と OR (||) は C 言語同様に必要最小限の評価しかし ません。すなわち、`&&` の第 2 引数は、第 1 引数が偽ならば評価されませ んし、`||` の第 2 引数は、第 1 引数が真ならば評価されません。
一つだけ三項演算子があります:
記号 例 説明
?: a?b:c 三項演算子
三項演算子は C のものと同じ働きをします。最初の引数 (a) は整数でなけれ ばいけません。この値が評価され、それが真 (ゼロでない) ならば 2 番目の 引数 (b) が評価されその値が返され、そうでなければ 3 番目の引数 (c) が 評価され、その値が返されます。
三項演算子は、区分的に定義された関数や、ある条件が満たされた場合にのみ 点を描画する、といったことを行なう場合に有用です。
例:
0 <= x < 1 では sin(x) に、1 <= x < 2 では 1/x に等しくて、それ以外の x では定義されない関数を描画:
f(x) = 0<=x && x<1 ? sin(x) : 1<=x && x<2 ? 1/x : 1/0
plot f(x)
`gnuplot` は未定義値に対しては何も表示せずにただ無視するので、最後の場 合の関数 (1/0) は点を何も出力しないことに注意してください。また、この 関数描画の描画スタイルが lines (線描画) の場合、不連続点 (x=1) の所も 連続関数として線が結ばれてしまうことにも注意してください。その点を不連 続になるようにするには、関数を 2 つの部分それぞれに分けてください (こ のような場合、媒介変数関数を使うのが便利です)。
ファイル 'file' のデータで、4 列目のデータが負でないときだけ、1 列目の データに関する 2 列目と 3 列目のデータの平均値を描画:
plot 'file' using 1:( $4<0 ? 1/0 : ($2+$3)/2 )
using の書式の説明に関しては using を参照してくださ
い。
新たなユーザ定義変数と 1 個から 5 個までの引数を持つユーザ定義関数を、 任意の場所で定義したり使ったりすることができます。それは `plot` コマン ド上でも可能です。
ユーザ定義関数書式:
<func-name>( <dummy1> {,<dummy2>} ... {,<dummy5>} ) = <expression>
ここで <expression> は仮変数 <dummy1> から <dummy5> で表される数式です。
ユーザ定義変数書式:
<variable-name> = <constant-expression>
例:
w = 2
q = floor(tan(pi/2 - 0.1))
f(x) = sin(w*x)
sinc(x) = sin(pi*x)/(pi*x)
delta(t) = (t == 0)
ramp(t) = (t > 0) ? t : 0
min(a,b) = (a < b) ? a : b
comb(n,k) = n!/(k!*(n-k)!)
len3d(x,y,z) = sqrt(x*x+y*y+z*z)
plot f(x) = sin(x*a), a = 0.2, f(x), a = 0.4, f(x)
円周率 `pi` は既に定義されています。しかしこれは決して手品のようなもの ではなく、好きなように再定義することができます。
変数名や関数名の命名規則は、大抵のプログラミング言語と同じで、先頭はア ルファベットで、その後の文字はアルファベット、数字、"$", "_" が使えま す。ただし、`fit` のサブルーチンでいくつか "FIT_" で始まる変数を使用す ることに注意してください。よってそのような名前を使うのは避けるべきでし ょう。しかし、`fit` の使用に際しては、例えば "FIT_LIMIT" のように再定 義をする必要があるような変数はあります。詳しくは `fit` に関する説明を 参照してください。
`show functions`, variables, `fit` も参照してください。
このドキュメント全体に渡って、用語に関する一貫性の維持が考えられていま す。しかしこの試みは完全には成功していません。それは `gnuplot` が時間 をかけて進化してきたように、コマンドやキーワードの名前もそのような完全 性を排除するかのように採用されて来ているからです。この節では、これらの キーワードのいくつかがどのように使われているかを説明します。
"ページ (page)" または "表示画面 (screen)" は `gnuplot` がアクセス可能 な領域全体を指します。ディスプレイモニタでは、これは画面全体を指し、プ ロッタでは、一枚の紙全体になります。
表示画面は、一つ、またはそれ以上の "グラフ描画 (plot)" を含みます。グ ラフ描画は一つの横座標と一つの縦座標で定義されますが、余白 (margin) や その中に書かれる文字列 (text) 同様、それらは実際にその上に表示されてい る必要はありません。
グラフ描画は一つの "グラフ" を含みます。グラフは一つの横座標と一つの縦 座標で定義されますが、これらは実際にその上に表示されている必要はありま せん。
グラフは一つまたはそれ以上の "曲線 (line)" を含みます。曲線は一つの関 数、またはデータセットです。用語 "line" は描画スタイルとしても使われま す。さらにこの用語は "文字列の一行 (a line of text)" のように使われる こともあります。多分文脈からそれらは区別できるでしょう。
一つのグラフ上の複数の曲線はそれぞれ名前を持ちます。その名前は、その曲 線の表現に使われる描画スタイルのサンプルとともに "(説明) key" 内に一覧 表示されます。説明は、時には "(表題) legend" とも呼ばれます。
用語 "タイトル (title)" は `gnuplot` では複数の意味で使われます。この ドキュメントではそれらを区別するために、形容詞として "描画の (plot)"、 "曲線の (line)"、"説明の (key)" を頭につけたりもします。
2 次元のグラフは 4 つまでの見出し付けされる軸を持つことができます。こ れらの使われ方の中の 4 つの軸の名前はそれぞれ、グラフ描画の下の境界に 沿う軸である "x"、左の境界に沿う軸 "y"、上の境界に沿う軸 "x2"、右の境 界に沿う軸 "y2" となっています。
3 次元のグラフは 4 つまでの見出し付けされる軸 "x","y","z" を持つこと ができます。どの特定の軸に関してもそれがグラフ上でどこに書かれるかを述 べることはできません。それは、view でグラフを見る方向を変更でき るからです。
データファイルに関する議論では、用語 "行 (record)" を復活し、ファイル の一行の文字列、すなわち、改行文字や行末文字同士の間の文字列、を指し示 すのに使います。"点 (point)" は行から取り出した一つのデータです。"デー タブロック (datablock)" は、空行で区切られた連続した複数の行からなる点 の集合です。データファイルの議論の中で "line" が参照される場合は、これ はデータブロックの部分集合を指します。
(訳注: この日本語訳の中ではここに書かれているような用語の統一は考慮さ れてはおらず、よって混乱を引き起こす可能性があります。厳密には原文を参 照すべきでしょう。)
出力形式 `x11`, `pm`, `windows`, ggi では、現在の描画にマウスを使って 作用をすることが可能になっています。これらはホットキーの定義もサポート していて、マウスカーソルが有効な描画ウィンドウにあるときに、あるキーを 押すことであらかじめ定義した関数を実行させることができます。マウス入力 を `batch` コマンドスクリプトと組み合わせることも可能で、例えば `pause mouse` として、その後にマウスクリックによってパラメータとして返 って来るマウス変数をその後のスクリプト動作に反映させることができます。 bind, variables, も参照してください。また、コマンド `set mouse` も参照してください。
修飾キーを含む複数のキーの定義は引用符で囲む必要があることに注意してく ださい。
書式:
bind [<key-sequence>] ["<gnuplot commands>"]
bind!
例:
- キー割当の設定:
bind a "replot"
bind "ctrl-a" "plot x*x"
bind "ctrl-alt-a" 'print "great"'
bind Home "set view 60,30; replot"
- キー割当を表示:
bind "ctrl-a" # ctrl-a に対するキー割当を表示
bind # 全てのキー定義を表示
- キー割当を削除:
bind "ctrl-alt-a" "" # ctrl-alt-a のキー割当を削除
(組み込みキー定義は削除されません)
bind! # デフォルト (組み込み) のキー定義を導入
- トグルスイッチ形式にキー割当:
v=0
bind "ctrl-r" "v=v+1;if(v%2)set term x11 noraise; else set term x11 raise"
修飾キー (ctrl / alt) は大文字小文字の区別はありませんが、キーはそうで はありません:
ctrl-alt-a == CtRl-alT-a
ctrl-alt-a != ctrl-alt-A
修飾キー (alt == meta) の一覧:
ctrl, alt
サポートされている特殊キーの一覧:
"BackSpace", "Tab", "Linefeed", "Clear", "Return", "Pause", "Scroll_Lock",
"Sys_Req", "Escape", "Delete", "Home", "Left", "Up", "Right", "Down",
"PageUp", "PageDown", "End", "Begin",
"KP_Space", "KP_Tab", "KP_Enter", "KP_F1", "KP_F2", "KP_F3", "KP_F4",
"KP_Home", "KP_Left", "KP_Up", "KP_Right", "KP_Down", "KP_PageUp",
"KP_PageDown", "KP_End", "KP_Begin", "KP_Insert", "KP_Delete", "KP_Equal",
"KP_Multiply", "KP_Add", "KP_Separator", "KP_Subtract", "KP_Decimal",
"KP_Divide",
"KP_1" - "KP_9", "F1" - "F12"
`mouse`, if の項目も参照してください。
マウス機能が有効な場合、現在のウィンドウ上でのマウスクリックによって gnuplot のコマンドライン上で使うことができる色々なユーザ変数が設定され ます。クリック時のマウスの座標は変数 MOUSE_X, MOUSE_Y, MOUSE_X2, MOUSE_Y2 に代入されます。クリックされたボタンや、そのときのメタキーの 状態は MOUSE_BUTTON, MOUSE_SHIFT, MOUSE_ALT, MOUSE_CTRL に代入されます。 これらの変数は任意の描画の開始時には未定義で、有効な描画ウィンドウ中で のマウスクリックイベントによって初めて定義されます。有効な描画ウィンド ウ中でマウスが既にクリックされたかどうかをスクリプトから調べるには、こ れらの変数のうちのどれか一つが定義されているかどうかをチェックすれば十 分です。
plot 'something'
set pause mouse
if (defined(MOUSE_BUTTON)) call 'something_else'; \
else print "No mouse click."
`gnuplot` には描画を生成する 3 つのコマンド、`plot`, `splot`, replot があります。`plot` は 2 次元描画を生成し、`splot` は 3 次元描画 (もち ろん実際には 2 次元面への射影) を生成します。replot は与えられた引数 を、直前の `plot` または `splot` コマンドに追加し、それを実行します。
描画に関する一般的な情報の大半は、`plot` に関する項で見つかります。3 次元描画に固有の情報は `splot` の項にあります。
`plot` は xy 直交座標系と極座標系が使えます。極座標系の詳細に関しては `set polar` を参照してください。`splot` は xyz 直交座標系のみしか扱え ませんが、コマンド mapping で他の 2, 3 の座標系を使用することが 出来ます。さらに、オプション using を使えば、`plot` でも `splot` で もほとんどどんな座標系でもそれを定義して使うことが出来ます。
`plot` では、4 つの境界 x (下), x2 (上), y (左), y2 (右) をそれぞれ独 立な軸として扱うこともできます。オプション `axes` で、与えられた関数や データ集合をどの軸のペアで表示させるかを選べます。また、各軸の縮尺や見 出しづけを完全に制御するために十分な補佐となる `set` コマンド群が存在 します。いくつかのコマンドは、xlabel のように軸の名前をその中に 持っていますし、それ以外のものは `set logscale xy` のように、1 つ、ま たは複数の軸の名前をオプションとしてとります。z 軸を制御するオプション やコマンドは 2 次元グラフには効力を持ちません。
`splot` は、曲面の描画と、点や線を加えて等高線を書くことも出来ます。3 次元の関数の格子定義に関する情報については、`splot` と isosamples の項目を、3 次元データのファイルに必要な形態に関しては `splot datafile` の項目を、等高線に関する情報については contour と cntrparam の項目を参照してください。
`splot` での縮尺や見出し付けの制御は、x2 軸と y2 軸を制御するコマンド やオプションは効果がなく、z 軸を制御するものにはもちろん効果がある、と いうことを除けば `plot` と全く同じです。
`splot` ではバイナリデータや行列形式のデータも描画できますが、それは指 定されたデータ形式に限ります。詳細は `splot` を参照してください。
`gnuplot` が起動されるとき，初期設定ファイルを読み込もうとします．この ファイルは Unix と AmigaOS では，`.gnuplot` であり，その他の処理系で は `GNUPLOT.INI` となっています．このファイルがカレントディレクトリに 無い場合，`gnuplot` はホームディレクトリを検索します (AmigaOS, Atari (single)TOS, MS-DOS, Windows, OS/2 では，環境変数 `GNUPLOT` にホームデ ィレクトリに対応するディレクトリを指定します; Windows NT では、GNUPLOT が定義されていなければ `USERPROFILE` が使われます)．注意: インストール の時に NOCWDRC を定義した場合には，`gnuplot` はカレントディレクトリか らは読みません．
初期設定ファイルが見つかると，`gnuplot` はこのファイルに書かれているコ マンドを実行します．ここには任意の正しい `gnuplot` コマンドを書くこと が可能ですが、一般的には、出力装置の指定や、よく使う関数や変数の定義を 設定する程度に抑えておきます。
シェルコマンドをバッククォートで囲むことによってコマンド置換を行うこ とができます。このコマンドは子プロセスで実行され、その出力結果でコマ ンド (およびそれを囲んでいる引用符) を置き換えます。処理系によっては パイプがサポートされている場合もあります。special-filenames を参照してください。
コマンド置換は、単一引用符内の文字列以外は、`gnuplot` のコマンドライ ン中、どこででも使用可能です。
例:
以下の例は，`leastsq` というプログラムを実行し、その出力結果で、 `leastsq` を (まわりの引用符こみで) 置き換えます:
f(x) = `leastsq`
ただし VMS では、
f(x) = `run leastsq`
以下は現在の日付とユーザー名のラベルを生成します:
set label "generated on `date +%Y-%m-%d`by `whoami`" at 1,1
set timestamp "generated on %Y-%m-%d by `whoami`"
`gnuplot` における記号や区切りの用法に関する一般的な規則は、キーワード とオプションは順序依存である、ということです。リストや座標がコンマ (,) 区切りであるのに対し、オプションやそれに伴うパ ラメータはスペース ( ) 区切りです。範囲はコロン (:) で区切ってかぎかっこ ([]) でくくりますし、 文字列やファイル名は引用符でくくり、他にいくつかカッコ (()) でくくるも のがあります。中カッコ ({}) は特別な目的で使われます。
コンマは以下の区切りで使用されます。`set` コマンドの arrow, key, label の座標; 当てはめ (fit) られる変数のリスト (コマンド `fit` のキ ーワード `via` に続くリスト); コマンド cntrparam で指定されると びとびの等高線の値やそのループパラメータのリスト; `set` コマンドの dgrid3d dummy, isosamples, offsets, origin, samples, size, `time`, view の引数; 目盛りの位置やそのループパラメータのリ スト; タイトルや軸の見出しの位置; `plot`, replot, `splot` コマンドの x,y,z 座標の計算に使われる媒介変数関数のリスト; `plot`, replot, `splot` コマンドの複数の描画 (データ、または関数) のそれぞれの一連のキ ーワードのリスト。
(丸) カッコは、目盛りの見出しを (ループパラメータではなく) 明示的に集 合与える場合の区切りとして、または `fit`, `plot`, replot, `splot` コ マンドの using フィルタでの計算を指示するために使われます。
(カッコやコンマは通常の関数の表記でも使われます。)
かぎかっこは、`set`, `plot`, `splot` コマンド上で用いられた場合は範囲 を区切るのに使われます。
コロンは `range` (範囲) 指定 (`set`, `plot`, `splot` コマンドで使われ る) の両端の値を区切るのに、または `plot`, replot, `splot`, `fit` コ マンドの using フィルタの各エントリを区切るのに使われます。
セミコロン (;) は、一行のコマンド行内で与えられる複数のコマンドを区切 るのに使われます。
中カッコは、`postscript` のようないくつかの出力形式で特別に処理される 文字列内で使用されます。または複素数を記述するのにも使われます: {3,2} = 3 + 2i となります。
文字列は単一引用符 (") または二重引用符 ("") で囲まれます。\n (改行) や \345 (8 進表記の文字コード) のような文字列でのバックスラッシュ (\) は、2 重引用符内の文字列では効力がありますが、単一引用符内では効力を持 ちません。
1 つの複数行文字列に関する位置合わせは各行に同等に働きます。よって、中 央に位置合わせされた文字列
"This is the first line of text.\nThis is the second line."
は次のように表示されます:
This is the first line of text.
This is the second line.
しかし
'This is the first line of text.\nThis is the second line.'
だと次のようになります。
This is the first line of text.\nThis is the second line.
ファイル名は単一引用符、あるいは二重引用符内で囲みます。このマニュアル では一般にコマンドの例示では、わかりやすくするためにファイル名は単一引 用符でくくり、他の文字列は二重引用符でくくります。
`enhanced postscript` 出力形式 (terminal) を使う場合、現在は、{} の内 部に \n を入れてはいけません。
EEPIC, Imagen, Uniplex, LaTeX, TPIC の各ドライバでは、単一引用符内の \\ または二重引用符内の \\\\ で改行を示すことが可能です。
バッククォート (｀｀) は置換のためにシステムコマンドを囲むのに使います。
`gnuplot` は入力データとして時間/日付情報の使用をサポートしています。 この機能は `set xdata time`, `set ydata time` などのコマンドによって有 効になります。
内部では全ての時間/日付は 2000 年からの秒数に変換されます。コマンド timefmt は全ての入力書式を定義します。データファイル、範囲、軸の 目盛りの見出し、ラベルの位置 - 手短に言えば、データの値を受けとる全て のものがこの書式にしたがって受けとらなければいけません。一時には一つの 入力書式のみが有効なので、同じときに入力される全ての時間/日付のデータは 同じ書式である必要があります。よって、ファイル内の x と y の両方が時間 /日付データである場合は、それらは同じ書式でなければいけません。
秒数へ (秒数から) の変換は国際標準時 (UT; グリニッジ標準時 (GMT) と同 じ) が使われます。各国標準時や夏時間への変換の機能は何も持ち合わせてい ません。もしデータがすべて同じ標準時間帯に従っているなら (そして全てが 夏時間か、そうでないかのどちらか一方にのみ従うなら) これに関して何も心 配することはありません。しかし、あなたが使用するアプリケーションで絶対 的な時刻を厳密に考察しなければいけない場合は、あなた自身が UT に変換す べきでしょう。 xrange のようなコマンドは、その整数値を timefmt に従って解釈 し直します。timefmt を変更してもう一度 `show` でその値を表示させると それは新しい timefmt に従って表示されます。このため、もし機能を停止 させるコマンド (xdata のような) を与えると、その値は整数値として 表示されることになります。
コマンド `set format` は、指定された軸が時間/日付であるなしに関わらず 目盛りの見出しに使われる書式を定義します。
時間/日付情報がファイルから描画される場合、`plot`, `splot` コマンドで は using オプションを「必ず」使う必要があります。`plot`, `splot` で は各行のデータ列の分離にスペースを使いますが、時間/日付データはその中 にスペースを含み得るからです。もしタブ区切りを使用しているのなら、あな たのシステムがそれをどう扱うか確かめるために何度もテストする必要がある でしょう。
次の例は時間/日付データの描画の例です。
ファイル "data" は以下のような行からなるとします:
03/21/95 10:00 6.02e23
このファイルは以下のようにして表示されます:
set xdata time
set timefmt "%m/%d/%y"
set xrange ["03/21/95":"03/22/95"]
set format x "%m/%d"
set timefmt "%m/%d/%y %H:%M"
plot "data" using 1:3
ここで、x 軸の目盛りの見出しは "03/21" のように表示されます。
各コマンドの詳細はそれぞれの項の記述を参照してください。
このセクションでは `gnuplot` が受け付けるコマンドをアルファベット順に 並べています。このドキュメントを紙に印刷したものは全てのコマンドを含ん でいますが、オンラインドキュメントの方は完全ではない可能性があります。 実際、この見出しの下に何のコマンドも表示されないシステムがあります。
ほとんどの場合、コマンド名とそのオプションは、紛らわしくない範囲で省略 することが可能です。すなわち、"`plot f(x) with lines`" の代わりに "`p f(x) w li`" とすることができます。
書式の記述において、中カッコ ({}) は追加指定できる引数を意味し、 縦棒 (|) は互いに排他的な引数を区切るものとします。
書式:
cd '<ディレクトリ名>'
ディレクトリ名は引用符に囲まれていなければなりません．
例:
cd 'subdir'
cd '..'
DOS では、二重引用符内 (") ではバックスラッシュ (\) が特別な意味を持っ てしまうため、一重引用符 (') を用いなければなりません。 例えば
cd "c:\newdata"
では失敗しますが、
cd 'c:\newdata'
なら期待通りに動くでしょう。
書式:
call "<入力ファイル>" <パラメータ 0> <パ 1> ... <パ 9>
入力ファイル名は引用符で囲まなければなりません．そして、パラメータも 引用符で囲むことを推奨します (gnuplot の将来のバージョンでは引用符で 囲んである部分と囲んでない部分に対しては違う取り扱いをする予定です)。
例:
ファイル 'calltest.gp' は以下の行を含んでいるとすると:
pause 0 "p0=$0 p1=$1 p2=$2 p3=$3 p4=$4 p5=$5 p6=$6 p7=x$7x"
次の行を入力すると:
call 'calltest.gp' "abcd" 1.2 + "'quoted'" -- "$2"
以下のように表示されるでしょう:
p0=abcd p1=1.2 p2=+ p3='quoted' p4=- p5=- p6=$2 p7=xx
注意: using を使用しているデータファイルでは文法的に重なってしまいま す。その場合、call されたデータファイルからプロットするときは、デー タの n カラム目の指示には `$$n` または `column(n)` を使用してください。
いくつかの出力装置は clear コマンドでは size で定義された描画 領域のみを消去します。そのため、multiplot とともに使用することで 挿入図を一つ作ることができます。
例:
set multiplot
plot sin(x)
set origin 0.5,0.5
set size 0.4,0.4
clear
plot cos(x)
unset multiplot
これらのコマンドの詳細については multiplot, size, origin を参照してください。
これらのコマンドは，出力装置を clear コマンドと同様にクリアしてして から終了させます．
`fit` コマンドはユーザ定義関数を (x,y) または (x,y,z) の形式のデータ点の 集合への当てはめを可能にします。それには Marquardt-Levenberg 法による 非線形最小自乗法 (NLLS) の実装が用いられます。関数内部に現われるユーザ 定義変数はいずれも当てはめのパラメータとして使うことができます。ただ、 その関数の返り値は実数である必要があります。
書式:
fit {[xrange] {[yrange]}} <function> '<datafile>'
{datafile-modifiers}
via '<parameter file>' | <var1>{,<var2>,...}
範囲 (xrange,yrange) は、当てはめられるデータ点を一時的に制限するのに 使うことができ、その範囲を超えたデータは全て無視されます。その書式は `plot` コマンド同様
[{dummy_variable=}{<min>}{:<max>}],
です (ranges 参照)。
<function> は通常はあらかじめユーザ定義された f(x) または f(x,y) の形 の関数ですが、`gnuplot` で有効な任意の数式を指定できます。
<datafile> は `plot` コマンドと同様に扱われます。`plot datafile` の修 飾子 (using, every,...) は、smooth とあまり勧められない thru を除いて、全て `fit` に使うことができます。`plot datafile` を参照して ください。
当てはめる 1 変数関数 y=f(x) へのデフォルトのデータの書式は {x:}y か x:y:s で、これらはデータファイルへの using 指定子で変更できます。こ の 3 番目の項目 (列番号、または数式) が与えられた場合は、それは対応す る y の値の標準偏差として解釈され、それはそのデータへの重み (=1/s**2) を計算するのに使われます。そうでなければ、全てのデータは同じ重み (1) で計算されます。using オプションを全く指定しなかった場合、3 列目のデ ータがあった場合でもデータから y の偏差は読まれませんので、その場合は 重み 1 になります。
2 変数関数 z=f(x,y) を当てはめる場合、データの書式は using による 4 つの項目 x:y:z:s が要求されます。これは完全に全てが与えられなければな りません-不足する項目に対してはどの列もデフォルトは仮定されていません。 各データ点の重みは上と同様に 's' から計算されます。もし誤差評価を持っ ていなければ、定数値を定数式として指定すればいいでしょう (using 参照)。例えば `using 1:2:3:(1)` のように。
複数のデータ集合も複数の 1 変数関数に同時に当てはめることも、y を '仮 変数' とすれば可能です。例えばデータ行番号を使い、2 変数関数への当ては め、とすればいいでしょう。multi-branch を参照してください。
`via` 指定子はパラメータの調節を直接か、またはパラメータファイルを参照 することによって行うかを指定します。
例:
f(x) = a*x**2 + b*x + c
g(x,y) = a*x**2 + b*y**2 + c*x*y
FIT_LIMIT = 1e-6
fit f(x) 'measured.dat' via 'start.par'
fit f(x) 'measured.dat' using 3:($7-5) via 'start.par'
fit f(x) './data/trash.dat' using 1:2:3 via a, b, c
fit g(x,y) 'surface.dat' using 1:2:3:(1) via a, b, c
反復の個々のステップの後で、当てはめの現在の状態についての詳細な情報が 画面に表示されます。そし最初と最後の状態に関する同じ情報が "fit.log" というログファイルにも書き出されます。このファイルは前の当てはめの履歴 を消さないように常に追加されていきます。これは望むなら削除、あるいは別 な名前にできます。コマンド `set fit logfile` を使ってログファイルの名 前を変更することもできます。
gnuplot が、`set fit errorvariables` を使えるようにインストールされて いて、そのコマンドを使用した場合、各当てはめパラメータの誤差は、そのパ ラメータと似た名前 ("_err" が追加された名前) の変数に保存されます。よ ってその誤差を更なる計算の入力として使用することができます。
当てはめの反復は Ctrl-C を押すことで中断できます (MSDOS と Atari マル チタスクシステムでは Ctrl-C 以外の任意のキー)。現在の反復が正常に終了 した後、(1) 当てはめを止めて現在のパラメータの値を採用する, (2) 当ては めを続行する, (3) 環境変数 FIT_SCRIPT で指定した `gnuplot` コマンドを 実行する、のいずれかを選ぶことができます。FIT_SCRIPT のデフォルトは replot であり、よってもしデータと当てはめ関数を一つのグラフにあらか じめ描画してあれば、現在の当てはめの状態を表示することができます。
`fit` が終了した後は、最後のパラメータの値を保存するのに update コマ ンドを使います。その値は再びパラメータの値として使うことができます。 詳細は update を参照。
`via` はパラメータを調節するための 2 つの方法を指定できます。一つは コマンドラインから直接指示するもので、もう一つはパラメータファイルを 参照して間接的に行うものです。この 2 つは初期値の設定で違った方法を取 ります。
調整するパラメータは、`via` キーワードの後ろにコンマで区切られた変数名 のリストを書くことで指定できます。定義されていない変数は初期値 1.0 と して作られます。しかし当てはめは、変数の初期値があらかじめ適切な値に設 定されている方が多分速く収束するでしょう。
パラメータファイルは個々のパラメータを、個別に 1 行に一つずつ、初期値を 次のような形で指定して書きます。
変数名 = 初期値
'#' で始まるコメント行や空行も許されます。特別な形式として
変数名 = 初期値 # FIXED
は、この変数が固定されたパラメータであることを意味し、それはこのファイ ルで初期化されますが、調節はされません。これは、`fit` でレポートされる 変数の中で、どれが固定された変数であるかを明示するのに有用でしょう。な お、`# FIXED` と言うキーワードは厳密にこの形でなくてはなりません。
`fit` は、与えられたデータ点を与えられたユーザ定義関数にもっとも良く 当てはめるようなパラメータを見つけるのに使われます。その当てはめは、 同じ場所での入力データ点と関数値との自乗誤差、あるいは残差 (SSR:Sum of the Squared Residuals) の和を基に判定されます。この量は通常χ(カイ) 自乗と呼ばれます。このアルゴリズムは SSR を 最小化することをしようと します。もう少し詳しく言うと、データ誤差 (または 1.0) の重みつき残差の 自乗和 (WSSR) の最小化を行っています。詳細は `fit error_estimate` 参照。
これが、(非線形) 最小自乗当てはめ法と呼ばれるゆえんです。`非線形` が 何を意味しているのかを見るための例を紹介しますが、その前にいくつかの 仮定について述べておきます。ここでは簡単のため、1 変数のユーザー定義 関数は z=f(x), 2 変数の関数は z=f(x,y) のようにし、いずれも従属変数と して z を用いることにします。パラメータとは `fit` が調整して適切な値を 決定するユーザ定義変数で、関数の定義式中の未知数です。ここで言う、線形 性/非線形性とは、従属変数 z と `fit` が調整するパラメータとの関係に対 するものであり、z と独立変数 x (または x と y) との関係のことではあり ません (数学的に述べると、線形最小自乗問題では、当てはめ関数のパラメー タによる 2 階 (そして更に高階の) 導関数は 0、ということになります)。
線形最小自乗法 (LLS) では、ユーザ定義関数は単純な関数の和であり、それ ぞれは一つのパラメータの定数倍で他のパラメータを含まない項になります。 非線形最小自乗法 (NLLS) ではより複雑な関数を扱い、パラメータは色んな 使われ方をされます。フーリエ級数は線形と非線形の最小自乗法の違いを表す 一つの例です。フーリエ級数では一つの項は
z=a*sin(c*x) + b*cos(c*x).
のように表されます。もし、a と b が未知なパラメータで c は定数だとすれば パラメータの評価は線形最小自乗問題になります。しかし、c が未知なパラメー タならばそれは非線形問題になります。
線形の場合、パラメータの値は比較的簡単な線形代数の直接法によって決定で きます。しかしそのような LLS は特殊な場合であり、'gnuplot' が使用する 反復法は、もちろんそれも含めて、より一般的な NLLS 問題を解くことができ ます。`fit` は検索を行うことで最小値を探そうとします。反復の各ステップ は、パラメータの新しい値の組に対して WSSR を計算します。Marquardt- Levenberg のアルゴリズムは次のステップのパラメータの値を選択します。そ してそれはあらかじめ与えた基準、すなわち、(1) 当てはめが "収束した" (WSSR の相対誤差が FIT_LIMIT より小さくなった場合)、または (2) あらか じめ設定された反復数の限界 FIT_MAXITER (variables 参照) に達した場合、のいずれかを満たすまで続けられます。キーボードからその 当てはめの反復は中断できますし、それに続いて中止することもできます (`fit` 参照)。
当てはめに使われる関数はしばしばあるモデル (またはある理論) を元にして いて、それはデータの振舞を記述したり、あるいは予測しようとします。よっ て `fit` は、データがそのモデルにどれくらいうまく当てはまっているのかを 決定するため、そして個々のパラメータの誤差の範囲を評価するために、モデ ルの自由なパラメータの値を求めるのに使われます。`fit error_estimates` も 参照してください。
そうでなければ、曲線による当てはめにおける関数は、モデルとは無関係に選 ばれています (それは十分な表現力と最も少ない数のパラメータを持ち、デー タの傾向を記述しそうな関数として経験に基づいて選ばれるでしょう)。
しかし、もしあなたが全てのデータ点を通るような滑らかな曲線を欲しいなら `fit` ではなく、むしろ `plot` の smooth オプションでそれを行うべきで しょう。
`fit` において "誤差" という用語は 2 つの異なった文脈で用いられます。 一つはデータ誤差、もう一つはパラメータ誤差です。
データ誤差は、平方残差の重み付きの和 WSSR、すなわちχ自乗を決定する際 個々のデータ点の相対的な重みを計算するのに用いられます。それらはパラメ ータの評価に影響を与えます。それは、それらが、当てはめられた関数からの 個々のデータ点の偏差が最終的な値に与える影響の大きさを決定することによ ります。正確なデータ誤差評価が与えられている場合には、パラメータの誤差 評価等の `fit` が出力する情報はより役に立つでしょう。
'statistical overview' では `fit` の出力のいくつかを説明し、'practical
guidelines' に対する背景を述べています。
非線形最小自乗法 (Non-Linear Least-Squares; NLLS) の理論は、誤差の正規 分布の点から一般的に記述されています。すなわち、入力データは与えられた 平均とその平均に対する与えられた標準偏差を持つガウス (正規) 分布に従う 母集団からの標本と仮定されます。十分大きい標本、そして母集団の標準偏差 を知ることに対しては、χ自乗分布統計を用いて、通常「χ自乗」と呼ばれる 値を調べることにより「当てはめの良さ」を述べることができます。減らされ た自由度のχ自乗 (χ自乗の自由度は、データ点の数から当てはめられるパラ メータの個数だけ引いた数) が 1.0 である場合は、データ点と当てはめられた 関数との偏差の重みつき自乗和が、現在のパラメータ値に対する関数と与えら れた標準偏差によって特徴付けられた母集団の、ランダムなサンプルに対する 自乗和とが全く同じであることを意味します。
分散 = 総計である数え上げ統計学同様、母集団の標準偏差が定数でない場合、 各点は観測される偏差の和と期待される偏差の和を比較するときに個別に重み づけされるべきです。
最終段階で `fit` は 'stdfit'、すなわち残差の RMS (自乗平均平方根) で求 められる当てはめの標準偏差と、データ点が重みづけられている場合に '減ら されたχ自乗' とも呼ばれる残差の分散をレポートします。自由度 (データ点 の数から当てはめパラメータの数を引いたもの) はこれらの評価で使用されま す。なぜなら、データ点の残差の計算で使われるパラメータは同じデータから 得られるものだからです。
パラメータに関する信頼レベルを評価することで、当てはめから得られる最小 のχ自乗と、要求する信頼レベルのχ自乗の値を決定するためのχ自乗の統計 を用いることが出来ます。しかし、そのような値を生成するパラメータの組を 決定するには、相当のさらなる計算が必要となるでしょう。
`fit` は信頼区間の決定よりむしろ、最後の反復後の分散-共分散行列から直 ちに得られるパラメータの誤差評価を報告します。これらの評価は、標準偏差 として計算される量の指定に関する統計上の条件が、一般には非線形最小自乗 問題では保証されないのですが、線形最小自乗問題での標準誤差 (各パラメー タの標準偏差) と同じ方法で計算されます。そしてそのため慣例により、これ らは "標準誤差" とか "漸近標準誤差" と呼ばれています。漸近標準誤差は一 般に楽観過ぎ、信頼レベルの決定には使うべきではありませんが、定性的な指 標としては役に立つでしょう。
最終的な解は相関行列も生成します。それは解の範囲におけるパラメータの相 関の表示を与えてくれます:もし一つのパラメータが変更されると、χ自乗の 増加が、他の補正の変更を行なう ? 主対角成分、すなわち自己相関はすべて 1 で、もし全てのパラメータが独立ならば他の成分はすべて 0 に近い値にな ります。完全に他を補いあう 2 つ変数は、大きさが 1 で、関係が正の相関か 負の相関かによって正か負になる符号を持つ非対角成分を持ちます。非対角要 素の大きさが小さいほど、各パラメータの標準偏差の評価は、漸近標準誤差に 近くなります。
個々のデータ点への重みづけの割り当ての基礎を知っているなら、それが測定 結果に対するより詳しい情報を使用させようとするでしょう。例えば、幾つか の点は他の点より当てになるということを考慮に入れることが可能です。そし て、それらは最終的なパラメータの値に影響します。
データの重み付けは、最後の反復後の `fit` の追加出力に対する解釈の基礎 を与えます。各点に同等に重み付けを行なうにしても、重み 1 を使うことよ りもむしろ平均標準偏差を評価することが、χ自乗が定義によりそうであるよ うに、WSSR を 無次元変数とすることになります。
当てはめ反復の各段階で、当てはめの進行の評価に使うことが出来る情報が表 示されます ('*' はより小さい WSSR を見つけられなかったこと、そして再試 行していることを意味します)。'sum of squares of residuals' (残差の自乗 和) は、'chisquare' (χ自乗) とも呼ばれますが、これはデータと当てはめ 関数との間の WSSR を意味していて、`fit` はこれを最小化しようとします。 この段階で、重み付けされたデータによって、χ自乗の値は自由度 (= データ 点の数 - パラメータの数) に近付くことが期待されます。WSSR は補正された χ自乗値 (WSSR/ndf; ndf = 自由度)、または当てはめ標準偏差 (stdfit = sqrt(WSSR/ndf)) を計算するのに使われます。それらは最終的な WSSR に対し てレポートされます。
データが重み付けされていなければ、stdfit は、ユーザの単位での、データ と当てはめ関数の偏差の RMS (自乗平均平方根) になります。
もし妥当なデータ誤差を与え、データ点が十分多く、モデルが正しければ、 補正χ自乗値はほぼ 1 になります (詳細は、適当な統計学の本の 'χ自乗分 布' の項を参照してください)。この場合、この概要に書かれていること以外 に、モデルがデータにどれくらい良く当てはっているかを決定するための追加 の試験方法がいくつかあります。
補正χ自乗が 1 よりはるかに大きくなったら、それは不正なデータ誤差評価、 正規分布しないデータ誤差、システム上の測定誤差、孤立した標本値 (outliers)、または良くないモデル関数などのためでしょう。例えば `plot 'datafile' using 1:($2-f($1))` などとして残差を描画することは、それら のシステム的な傾向を知るための手がかりとなります。データ点と関数の両者 を描画することは、他のモデルを考えための手がかりとなるでしょう。
同様に、1.0 より小さい補正χ自乗は、WSSR が、正規分布する誤差を持つラ ンダムなサンプルと関数に対して期待されるものよりも小さいことを意味しま す。データ誤差評価が大きすぎるのか、統計的な仮定が正しくないのか、また はモデル関数が一般的すぎて、内在的傾向に加えて特殊なサンプルによる変動 の当てはめになっているのでしょう。最後の場合は、よりシンプルな関数にす ればうまく行くでしょう。
標準的なエラーを、パラメータの不確定性に関する、あるより現実的な評価に 関係付けること、および相関行列の重要性を評価することができるようになる 前に、あなたは `fit` と、それを適用しようとするある種の問題に慣れてお く必要があるでしょう。
`fit` は、大抵の非線形最小自乗法の実装では共通して、距離の自乗 (y-f(x))**2 の重み付きの和を最小化しようとすることに注意してください。 それは、x の値の "誤差" を計算に関してはどんな方法も与えてはおらず、単 に y に関する評価のみです。また、"孤立点" (正規分布のモデルのから外れ ているデータ点) は常に解を悪化させる可能性があります。
`fit` に影響を与えるために定義できるたくさんの `gnuplot` の変数があり ます。それらは `gnuplot` の動作中に一度定義できますが、それは `control_variable` で紹介し、`gnuplot` が立 ち上がる前に設定する変数は `environment_variables` で紹介します。
デフォルトのもっとも小さい数字の限界 (1e-5) は、変数
FIT_LIMIT
で変更できます。残差の平方自乗和が 2 つの反復ステップ間で、この数値よ り小さい数しか変化しなかった場合、当てはめルーチンは、これを '収束した' と見なします。
反復数の最大値は変数
FIT_MAXITER
で制限されます。0 (または定義しない場合) は制限無しを意味します。
更にそのアルゴリズムを制御したい場合で、かつ Marquardt-Levenberg アル ゴリズムを良く知っている場合は、さらにそれに影響を与える変数があります。 `lambda` (λ) の最初の値は、通常 ML 行列から自動的に計算されますが、も しそれをあらかじめ用意した値にセットしたければ
FIT_START_LAMBDA
にセットしてください。FIT_START_LAMBDA を 0 以下にセットすると、自動的 に計算されるようになります。変数
FIT_LAMBDA_FACTOR
は、χ自乗化された関数が増加、あるいは減少するにつれて `lambda` が増加 あるいは減少する因数を与えます。FIT_LAMBDA_FACTOR を 0 とすると、それは デフォルトの因数 10.0 が使用されます。
`fit` には FIT_ から始まる変数が他にもありますから、ユーザ定義変数とし てはそのような名前で始まる変数は使わないようにするのが安全でしょう。
変数 FIT_SKIP と FIT_INDEX は、以前の版の `gnuplot` の、`gnufit` と呼 ばれていた `fit` パッチで使われていたもので、現在は使用されていません。 FIT_SKIP の機能はデータファイルに対する every 指定子で用意されていま す。FIT_INDEX は複数当てはめ法 (multi-branch fitting) で使われていたも のですが、1 変数の複数当てはめ法は、今では 疑似 3 次元当てはめとして行 なわれていて、そこでは枝の指定には 2 変数と using が使われています。 multi-branch を参照してください。
環境変数は `gnuplot` が立ち上がる前に定義しなければなりません。その設 定方法はオペレーティングシステムに依存します。
FIT_LOG
は、当てはめのログが書かれるファイル名 (およびパス) を変更します。デフ ォルトでは、作業ディレクトリ上の "fit.log" となっています。そのデフォ ルトの値はコマンド `set fitlogfile` を使って上書きできます。
FIT_SCRIPT
は、ユーザが中断した後に実行するコマンドを指定します。デフォルトでは replot ですが、`plot` や `load` コマンドとすれば、当てはめの進行状 況の表示をカスタマイズするのに便利でしょう。
複数当てはめ法 (multi-branch fitting) では、複数のデータ集合を、共通の パラメータを持つ複数の 1 変数の関数に、WSSR の総和を最小化することによ って同時に当てはめることが出来ます。各データセットに対する関数とパラメ ータ (枝) は '疑似変数' を使うことで選択できます。例えば、データ行番号 (-1; 'データ列' の番号) またはデータファイル番号 (-2) を 2 つ目の独立 変数とします。
例: 2 つの指数減衰形 z=f(x) が与えられていて、それぞれ異なるデータ集合 を記述しているが、共通した減衰時間を持ち、そのパラメータの値を評価する。 データファイルが x:z:s の形式であったとすると、この場合以下のようにす ればよい。
f(x,y) = (y==0) ? a*exp(-x/tau) : b*exp(-x/tau)
fit f(x,y) 'datafile' using 1:-1:2:3 via a, b, tau
より複雑な例については、デモファイル "fit.dem" で使われる "hexa.fnc" を参照してください。
もし従属変数のスケールに差がある場合、単位の重み付けでは 1 つの枝が支 配してしまう可能性があるので、適当な重み付けが必要になります。各枝をバ ラバラに当てはめるのに複数当てはめ法の解を初期値として用いるのは、全体 を合わせた解の各枝に対する相対的な影響に関する表示を与えることになるで しょう。
非線形当てはめは、大域的な最適値 (残差の自乗和 (SSR) の最小値を持つ解) への収束は保証はしませんが、局所的な極小値を与えることはできます。その サブルーチンはそれを決定する方法を何も持ち合わせていないので、これが起 こったかどうかを判断するのはあなたの責任となります。
`fit` は、解から遠くから始めると失敗するかも知れませんし、しばしばそれ は起こり得ます。遠くというのは、SSR が大きく、パラメータの変化に対して その変化が小さい、あるいは数値的に不安定な領域 (例えば数値が大きすぎて 浮動小数の桁あふれを起こす) に到達してしまって、その結果 "未定義値 (undefined value)" のメッセージか `gnuplot` の停止を引き起こしてしまう ような場合を意味します。
大域的な最適値を見つける可能性を改善するには、最初の値をその解に少なく ともほぼ近くに取るべきでしょう。例えば、もし可能ならば一桁分の大きさの 範囲内で。最初の値が解に近いほど他の解で終了してしまう可能性は低くなり ます。最初の値を見つける一つの方法は、データと当てはめ関数を同じグラフ の上に描画して適当な近さに達するまで、パラメータの値を変更して replot することを繰り返すことです。その描画は、よくない当てはめの極小値で当て はめが終了したかどうかをチェックするのにも有用です。
もちろん、適度に良い当てはめが、"それよりよい" 当てはめ (ある改良され た当てはめの良さの基準によって特徴付けられた統計学的な意味で、あるいは そのモデルのより適切な解である、という物理的な意味で) が存在しないこと の証明にはなりません。問題によっては、各パラメータの意味のある範囲をカ バーするような様々な初期値の集合に対して `fit` することが望ましいかも 知れません。
ここでは、`fit` を最大限に利用するためにいくつか覚えておくべきヒントを 紹介します。それらは組織的ではないので、その本質がしみ込むまで何回もよ く読んでください。
`fit` の引数の `via` には、2 つの大きく異なる目的のための 2 つの形式が あります。`via "file"` の形式は、バッチ処理 (非対話型での実行が可能) で最も良く使われ、そのファイルで初期値を与え、またその後で結果を他の (または 同じ) パラメータファイルにコピーするために update を使うこ とも出来ます。
`via var1, var2, ...` の形式は対話型の実行で良く使われ、コマンドヒスト リの機構が使ってパラメータリストの編集を行い、当てはめを実行したり、あ るいは新しい初期値を与えて次の実行を行なったりします。これは難しい問題 に対しては特に有用で、全てのパラメータに対して 1 度だけ当てはめを直接 実行しても、良い初期値でなければうまくいかないことが起こり得るからです。 それを見つけるには、いくつかのパラメータのみに対して何回か反復を行ない、 最終的には全てのパラメータに対する 1 度の当てはめがうまくいくところに 十分近くなるまでそれを繰り返すことです。
当てはめを行なう関数のパラメータ間に共通の依存関係がないことは確認して おいてください。例えば、a*exp(x+b) を当てはめに使ってはいけません。そ れは a*exp(x+b)=a*exp(b)*exp(x) だからです。よってこの場合は a*exp(x) または exp(x+b) を使ってください。
技術的なお話: パラメータの大きさはあまり違いすぎてはいけません。絶対値 が最も大きいパラメータと最も小さいパラメータの比が大きい程当てはめの収 束は遅くなります。その比が、マシンの浮動小数の精度の逆数に近いか、また はそれ以上ならば、ほとんど永久に収束しないか、拒否されるでしょう。よっ てその関数をこれを避けるように改良しなければいけません。例えば、関数の 定義で 'parameter' を '1e9*parameter' にするとか、または最初の値を 1e9 で割るとか。
もし、関数を、当てはめるパラメータを係数とする、単純な関数の線形結合で 書けるなら、それはとてもいいので是非そうしてください。何故なら、問題が もはや非線形ではないので、反復は少ない回数で収束するでしょう。もしかし たらたった一回ですむかもしれません。
実際の実験の講義ではデータ解析に対するいくつかの指示が与えられ、それで データへの最初の関数の当てはめが行なわれます。もしかすると、基礎理論の 複数の側面にひとつずつ対応する複数回のプロセスが必要かも知れませんが、 そしてそれらの関数の当てはめのパラメータから本当に欲しかった情報を取り 出すでしょう。しかし、`fit` を使えば、求めるパラメータの視点から直接モ デル関数を書くことにより、それはしばしば 1 回で済むのです。時々はより 難しい当てはめ問題の計算コストがかかりますが、データ変換もかなりの割合 で避けることが出来ます。もしこれが、当てはめ関数の単純化に関して、前の 段落と矛盾してると思うなら、それは正解です。
"singular matrix" のメッセージは、この Marquardt-Levenberg アルゴリズ ムのルーチンが、次の反復に対するパラメータの値の計算が出来ないことを意 味します。この場合、別な初期値から始めるか、関数を別な形で書き直すか、 より簡単な関数にしてみてください。
最後に、他の当てはめパッケージ (fudgit) のマニュアルから、これらの文書 を要約するようないい引用を上げます: "Nonlinear fitting is an art! (非 線形当てはめ法は芸術だ !)"
help {<項目名>}
もし <項目名> が指定されなかった場合は，`gnuplot` についての簡単な説 明が表示されます．指定した項目についての説明が表示された後，それに対 する細目のメニューが表示され、その細目名を入力することで細目に対する ヘルプを続けることができます。そして，その細目の説明が表示された後に， さらなる細目名の入力を要求されるか、または 1 つ前の項目のレベルへ戻り ます。これを繰り返すとやがて，`gnuplot` のコマンドラインへと戻ります．
また、疑問符 (?) を項目として指定すると、現在のレベルの項目のリストが 表示されます。
コマンド `history` は、過去に編集したコマンドラインの履歴 (history) の 一覧を表示したり、その一部を保存したり、その一つを実行したりします。
具体例で使用法を紹介します:
history # 履歴全体を表示
history 5 # 履歴内の直前の 5 つを表示
history quiet 5 # エントリ番号なしで直前の 5 つを表示
history "hist.gp" # 履歴全体をファイル hist.gp に書き出す
history "hist.gp" append # 履歴全体をファイル hist.gp に追加する
history 10 "hist.gp" # 直前の 10 個をファイル hist.gp に出力
history 10 "|head -5 >>diary.gp" # パイプで履歴を 5 つ書き出す
history ?load # 履歴内の "load" で始まるものすべてを表示
history ?"set c" # 上と同様 (複数の語は引用符で囲む)
hi !reread # "reread" で始まる最も新しい行を実行
hist !"set xr" # 上と同様 (複数の語は引用符で囲む)
hi !hi # 当ててみて :-))
popen 関数をサポートするようなシステム (Unix など) では、履歴の出力を パイプ経由で他の外部プログラムに渡すことができます。その場合、上の例の 一つにあるように、ファイル名としてコマンド名の先頭に '|' をつけたもの を使います。
書式:
if (<条件>) <コマンド行> [; else if (<条件>) ...; else ...]
<条件> が評価され、もしそれが真 (ゼロでない) ならば、<コマンド行> のコ マンドが実行されます。もし、<条件> が偽 (ゼロ) ならば、次の `else` ま での <コマンド行> 全体が無視されます。`;` を使うと同じ行に複数のコマン ド置くことが可能ですが、これで条件付きのコマンド (if の構文自体) は 終っていないことに注意してください。
例:
pi=3
if (pi!=acos(-1)) print "?Fixing pi!"; pi=acos(-1); print pi
を実行すると、
?Fixing pi!
3.14159265358979
と表示されますが、
if (1==2) print "Never see this"; print "Or this either"
とすると、何も表示されません。
その他:
v=0
v=v+1; if (v%2) print "2" ; else if (v%3) print "3" ; else print "fred"
(何度も最後の行を繰り返してみてください !) if と reread を使ってループを構成する例については reread を参照 してください。
`load` コマンドは，指定された入力ファイルの各行を、それが対話的に入力 されたかのように実行します。save コマンドでつくられたファイルは、 `load` することができます。有効なコマンドの書かれたテキストファイルを つくれば、それは、`load`コマンドによって、実行することができます。 `load` 中のファイルの中にさらに `load` または call コマンドがあって も構いません。コマンド中のコメントについては、`comments` を参照して下 さい。`load` するときに引数を与える方法については call を参照してく ださい。
`load` コマンドは、複数のコマンドからなる行の中では最後のコマンドでな ければなりません。
書式:
load "<入力ファイル名>"
入力ファイル名は引用符で囲まなければなりません。
`load` コマンドは、標準入力からのコマンドの入力のために、特別なファイ ル名 "-" を用意しています。これは、`gnuplot` のコマンドファイルが、い くつかのコマンドを標準入力から受け付けることを意味します。詳細について は "help batch/interactive" を参照してください。
Unix のように popen 関数をサポートするようなシステムでは、'<' で始まる ファイル名にすることで、入力ファイルをパイプから読み込むことができます。
例:
load 'work.gnu'
load "func.dat"
load "< loadfile_generator.sh"
`gnuplot` への引数として与えられたファイル名は、暗黙のうちに `load` コ マンドによって実行されます。これらは、指定された順にロードされ、その後 `gnuplot` は終了します。
書式:
pause <時間> {"<文字列>"}
pause mouse {"<文字列>"}
<時間> は、任意の定数または式です。-1 を指定すると改行キーが押されるま で待ちます。0 を指定すると一切待たず、正の数を指定するとその秒数だけ待 ちます。実行環境が秒以下の時間指定をサポートしていない場合、その時間は 整数の秒数に丸められます。`pause 0` は `print` と同じです。
使用している出力形式がマウス機能をサポートしている場合、`pause mouse` は、マウスクリックがあるか ctrl-C が押されるまで待つようになります。そ うでない出力形式、またはマウス機能が有効になってない場合 `pause mouse` は `pause -1` と同じです。
注意: pause コマンドは OS へのコマンドであり描画の一部ではないので、 異なる出力装置では異なる動作をする可能性があります。(これは、テキスト とグラフィックスが、どのように混在するかによります。)
例:
pause -1 # 改行キーが押されるまで待つ
pause 3 # 3 秒待つ
pause -1 "Hit return to continue"
pause 10 "Isn't this pretty? It's a cubic spline."
pause mouse "Click mouse on selected data point"
`plot` は `gnuplot` で図を描くための基本的なコマンドです。 それは関数 やデータを実に多くの方法で表示します。`plot` は 2 次元の関数やデータを 描くのに使われ、`splot` は 3 次元の曲面やデータの 2 次元投影を描きます。 `plot` と `splot` は多くの共通の特徴点を持ちますが、その違いについては `splot` の項を参照してください。特に注意しておきますが、`splot` の binary と matrix のオプションは `plot` には存在しませんし、`plot` の `axes` オプションは `splot` には存在しません。
書式:
plot {<範囲 (ranges)>}
{ <関数 (function)>
| {"<データファイル (datafile)>" {データファイル修飾子}}}
{axes <軸 (axes)>}{<表題 (title)>}{with <スタイル (style)>}
{, {定義,} <関数> ...}
<関数> または引用符で囲まれたデータファイル名のどちらか一方を与えます。 関数は一本の数式、または parametric mode においては 2 つの数式の組です。 数式は完全に定義してもいいですし、前の方の `gnuplot` のコマンド列で部 分的に定義してもいいです (`user-defined` の項目参照)。
関数とパラメータは `plot` コマンド自身の上で定義をすることも可能です。 これは単に他の項目とコンマで分離して記述することでなされます。
軸は、4 種類の組が利用できます; キーワード <軸> は、特定の直線をどの軸 に尺度を合わせるか、ということを選択するのに使われます。`x1y1` は下の 軸と左の軸を指定; `x2y2` は上と右の軸の指定; `x1y2` は下と右の軸の指定; `x2y1` は上と左の軸の指定です。`plot` コマンドで指定された範囲は、この 最初の軸の組 (下と左) にのみ適用されます。
例:
plot sin(x)
plot f(x) = sin(x*a), a = .2, f(x), a = .4, f(x)
plot [t=1:10] [-pi:pi*2] tan(t), \
"data.1" using (tan($2)):($3/$4) smooth csplines \
axes x1y2 notitle with lines 5
`show plot` も参照してください。
ファイルに納められた離散的なデータは、`plot` コマンドライン上で、その データファイル名 (単一引用符または二重引用符で囲まれた) を指定すること によって表示できます。
書式：
plot '<ファイル名>' {index <index list>}
{every <every list>}
{thru <thru expression>}
{using <using list>}
{smooth <option>}
修正子の index, every, thru, using, smooth は、それぞれに分 けて説明します。簡単に言うと、index はマルチデータセットファイルから どのデータセットを表示するのかを選び、every が、一つのデータセットか らどの点を表示するのかを選び、using は一行からどの列を解釈するのかを 決定し (thru は、using の特別な場合である)、そして smooth が、単 純な補間と近似を行います。(`splot` は、よく似た書式を持っていますが、 smooth オプションと thru オプションはサポートしていません)
データファイルは、一行につき少なくとも一つのデータ点を含む必要がありま す (using は一行から一つのデータポイントを選ぶことができます)。`#` (VMS では `!`) で始まる行は、コメントとして扱われ、無視されます。各デ ータ点は、(x,y) の組を表します。エラーバー、または折れ線表示付エラーバ ーの `plot` では (errorbars または errorlines 参照)、各データ点は、(x,y,ydelta), (x,y,ylow,yhigh), (x,y,xdelta), (x,y,xlow,xhigh), (x,y,xlow,xhigh,ylow,yhigh) のいずれかを意味します。
どんな場合でも、書式の指定子が using オプションによって与えられてい なければ、データファイルの各行の数字は、ホワイトスペース (一つまたは複 数の空白かタブ) によって区切られている必要があります。このホワイトスペ ースは、各行を列の項目に区切ります。ただし、二重引用符で囲まれたホワイ トスペースは列の勘定では無視され、よって次のようなデータ行は 3 列、と 見なされます:
1.0 "second column" 3.0
データは、指数部に e, E, d, D, q, Q の文字をつけた指数表記で書かれてい ても構いません。
必要であるのはただ一つの列 (y の値) のみです。もし x の値が省略された ら、`gnuplot` はそれを 0 で始まる整数値として用意します。
データファイルにおいて、ブランク行 (空白と改行、復帰以外に文字を含まな い行) は重要です --- ブランク行の対は、index (index 参照) を区切ります。2 つのブランク行で分離されたデータは、別々のデータ ファイルのデータであるかのように扱われます。
一つのブランク行は、`plot` に不連続を指示します; ブランク行によって区 切られた点は線で結ばれることはありません (line style で書かれている場 合には)。
もし autoscale の状態であれば (autoscale 参照)、軸は全てのデータ ポイントを含むように自動的に引き伸ばされて、目盛りが書かれる状態ならば 全ての目盛りがマークされます。これは、2 つの結果を引き起こします: i) `splot` では、曲面の角は底面の角に一致していないことがあります。この場 合、縦の線は書かれることはありません。ii) 2 種類の軸での、同じ x の範 囲のデータの表示の際、もし x2 の軸に対する目盛りが書かれていない場合は、 x 座標があっていないことがあります。これは x 軸 (x1) は全ての目盛りに まで自動的に引き延ばされるのに対し、x2 軸はそうではないからです。次の 例でその問題を見ることができます:
reset; plot '-', '-' axes x2y1
1 1
19 19
e
1 1
19 19
e
これを避けるには、autoscale コマンドの `fixmin`/`fixmax` オプシ ョンを使うことができます。これは、軸の範囲を自動的に拡張して、次の目盛 りの刻みに合うようにする機能を無効にします。
キーワード every は、描画するデータをデータセットから周期的にサンプ リングすることを可能にします。ここでは 「ポイント」はファイル中の 1 つ の行によって定義されるデータとし、ここでの「ブロック」は「データ・ブロ ック」(`glossary` 参照)と同じものを意味することとします。
書式：
plot 'file' every {<ポイント増分>}
{:{<ブロック増分>}
{:{<開始ポイント>}
{:{<開始ブロック>}
{:{<終了ポイント>}
{:<終了ブロック>}}}}}
プロットされるデータポイントは、<開始ポイント> から <終了ポイント> ま で <ポイント増分> の増加で選ばれ、ブロックは <開始ブロック> から <終了 ブロック> まで <ブロック増分> の増加で選ばれます。
各ブロックの最初のデータは、ファイル中の最初のブロックと同じように、 「0 番」とされます。
プロットできない情報を含んでいる行もカウントされることに注意して下さい。
いくつかの数字は省略することができます; 増分のデフォルトは 1 、開始の 値は最初のポイントか最初のブロック、そして終了の値は最後のポイントか最 後のブロックに設定されます。every が指定されないなら、全ての行の全て のポイントがプロットされます。
例:
every :::3::3 # 4 番目のブロックだけ選ばれます (0 番が最初)
every :::::9 # 最初の 10 ブロックが選ばれます
every 2:2 # 1 つおきのブロックで 1 つおきのポイントが選ば
# れます
every ::5::15 # それぞれのブロックでポイント 5 から 15 までが
# 選ばれます
参照: 単純な plot デモ (simple.dem) , 非パラメータモードでの splot デモ , パラメータモードでの splot デモ
次の例は、ファイル "population.dat" 中のデータと理論曲線を図にするもの です。
pop(x) = 103*exp((1965-x)/10)
plot [1960:1990] 'population.dat', pop(x)
ファイル "population.dat" は次のようなファイルです。
# Gnu population in Antarctica since 1965
1965 103
1970 55
1975 34
1980 24
1985 10
キーワード index はマルチデータセットファイルの中の、いくつかのデー タセットのみを選び出すのに使われます。
書式:
plot 'file' index <m>{{:<n>}:<p>}
データセットは 2 行の空白で分離されています。`index <m>` は <m> 番目の セットだけを選択します; `index <m>:<n>` は <m> から <n> までのデータセ ットの選択; `index <m>:<n>:<p>` は、<m>, <m>+<p>, <m>+2<p>, など、<p> おきのセットを選択し、セット <n> で終了します。C 言語の添字 (index) の 付け方に従い、index 0 はそのファイルの最初のデータセットを意味します。 大きすぎる index の指定にはエラーメッセージが返されます。index が指 定されない場合は、全てのデータセットが単一のデータセットとして描かれま す。
例:
plot 'file' index 4:5
index を使った splot のデモ
`gnuplot` は、データの補間と近似を行う汎用的なルーチンをいくつか持っ ています。これ smooth オプションの中にグループ化されています。より 洗練されたデータ処理をしたければ、外部においてデータの前処理をするか、 または適切なモデルで fit を使うのがいいでしょう。
書式:
smooth {unique | frequency | csplines | acsplines | bezier | sbezier}
`unique` と `frequency` は、データを単調に揃えた後でそれらを plot しま す。他のルーチンはいずれも、データの両端の点の間を結ぶ、ある連続曲線の 係数を決定するためにデータを使います。この曲線は、関数として同じ方法で 描画されます。すなわち、それらの値は x 座標に沿う同じ幅の区間ごとに選 ばれ (samples 参照)、それらの点を線分でつなぐことにより (もし line style が選ばれているのならば) 描画されます。
もし autoscale の状態であれば、描画範囲はグラフの境界線の中に曲線が 収まるように計算されます。
もし autoscale の状態でなく、smooth のオプションが `acspline` か `cspline` であれば、生成する曲線の標本化は、入力データを含むような x の範囲と、xrange などで定義される固定された横座標の範囲の共通部 分の上で行なわれます。
選択されたオプションを適用するのにデータの点数が少なすぎる場合は、エ ラーメッセージが表示されます。その最小のデータ数は `unique` と `frequency` では 1 つ、`acsplines` では 4 つ、他のオプションでは 3 つ です。 smooth オプションは、関数の描画のときには無視されます。
-- ACSPLINES --
`acsplines` オプションは「自然な滑らかなスプライン」でデータを近似しま す。データが x に関して単調にされた後 (`smooth unique` 参照)、1 つの曲 線が、いくつかの 3 次多項式の一部分により区分的に構成されます。それら の 3 次式の係数は、いくつかのデータポイントの重み付けによって求められ ます。重みは、データファイルの 3 列目に与えます。そのデフォルトの値は、 using の 3 番目の項目によって変更することができます。例えば次のよう にします。
plot 'data-file' using 1:2:(1.0) smooth acsplines
性質上、重みの絶対的な大きさは、曲線を構成するのに使われる区分の数を決 定します。もし重みが大きければ、個々のデータの影響は大きくなり、そして その曲線は、隣り合う点同志を自然 3 次スプラインでつないで得られるもの に近づきます。もし重みが小さければ、その曲線はより少ない区分で構成され、 それによってより平滑的になります。その最も極端な場合はただ 1 つの区分 からなる場合であり、それは全てのデータに重みの付き線形最小 2 乗近似に よって作られます。誤差の立場から言えば、平滑さの重みは、その曲線に対す る「平滑化因子」によって分割された各点への、統計的な重みと見ることがで きます。それにより、そのファイル中の (標準的な) 誤差は平滑さの重みとし て使うことができます。
例:
sw(x,S)=1/(x*x*S)
plot 'data_file' using 1:2:(sw($3,100)) smooth acsplines
-- BEZIER --
`bezier` オプションは、n 次 (データ点の個数) のベジェ曲線でデータを近 似します。この曲線は両端の点をつなぎます。
-- CSPLINES --
`csplines` オプションはデータを単調に揃えた後で (`smooth unique` 参照) 自然 3 次スプライン曲線で引き続く点をつなぎます。
-- SBEZIER --
`sbezier` オプションは、最初にデータを単調に揃え (`unique` 参照) そし て `bezier` アルゴリズムを適用します。
-- UNIQUE --
`unique` オプションは、データを x 方向に単調にします。同じ x を持つデ ータ点は y の値を平均して一つの点で置き換えます。そしてその結果として 得られる点を線分で結びます。 デモ
-- FREQUENCY --
オプション `frequency` は、データを x に関して単調にします。x 座標が同 じ点は、それらの y の値の合計を y の値として持つ一つの点に置き換えられ ます。結果としてそれらの点は真っすぐな線分で結ばれることになります。
`'-'` という特別なファイル名は、データがインラインであることを指示し ます。すなわち、データをコマンドの後に続けて指定します。このときはデ ータのみがコマンドに続き得ます。よって、`plot` コマンドに対するフィル ター、タイトル、ラインスタイルといったオプションは、`plot` のコマンド ラインの方に書かないといけません。これは、unix シェルスクリプトにおけ る << (ヒアドキュメント)、あるいは VMS DCL における $DECK と同様です。 そのデータは、それらがファイルから読み込まれたかのように、1 行につき 1 つずつのデータ点が入力されます。そしてデータの終りは、1 列目の始めに 文字 "e" を置くことで指示します。using オプションをこれらのデータに 適用することは可能です - ある関数を通しデータをフィルターすることに使 うのは意味があるでしょうが、列を選ぶのに使うことは多分意味がないでしょ う。
`'-'` は、データとコマンドを一緒に持つことが有用である場合のためにあ ります。例えば、`gnuplot` があるフロントアプリケーションのサブプロセ スとして起動される場合などがこれにあたります。例として、デモンストレ ーションでこの機能を使うものがあるでしょう。index や every のよう な `plot` のオプションが与えられていると、それらはあなたに使われるこ とのないデータを入力する事を強要します。次の例を見てください。
plot '-' index 0, '-' index 1
2
4
6
10
12
14
e
2
4
6
10
12
14
e
これは、実際に動作しますが、
plot '-' , '-'
2
4
6
e
10
12
14
e
とタイプする方が楽でしょう。
もし、replot コマンドで `'-'` を使うなら、あなたは 1 度以上データを 入力する必要があでしょう。
空のファイル名 (") は、直前のファイル名が再び使われることを指示しま す。これは、
plot 'ある/とても/長い/ファイル名' using 1:2, '' using 1:3, '' using 1:4
のようなときに便利です。(もし同じ plot コマンド上で、`'-'` と `"` の 両方を使用すると、上の例にあるように、インラインデータの 2 つのセット を与える必要があります。)
popen 関数を持っているコンピュータシステム (Unix) の上では、データフ ァイルは、'<' で始まるファイル名によって、シェルコマンドからパイプ入 力することができます。例えば
pop(x) = 103*exp(-x/10)
plot "< awk '{print $1-1965, $2}' population.dat", pop(x)
は、最初の人口の例と同じ情報を描画します。ただし、x 座標は 1965 年か らの経過年を表すようになります。この例を実行するときは、上のデータフ ァイルのコメント行をすべて削除しなければなりませんが、または上のコマ ンドの最初の部分を次のように変えることもできます (コンマに続く部分):
plot "< awk '$0 !~ /^#/ {print $1-1965, $2}' population.dat"
このアプローチは最も柔軟性がありますが、using あるいは thru キー ワードを用いた単純なフィルタリングで行うことも可能です。
書式:
plot 'file' thru f(x)
これは次と同様です:
plot 'file' using 1:(f($2))
後者の方がより複雑に見えますが、この方が柔軟性を持っています。さらに 自然な
plot 'file' thru f(y)
も動作します (すなわち、y をダミー変数として使うことができます)。 thru は `splot` と `fit` でも通りますが、何の効果も持ちません。
最もよく使われるデータファイルの修飾子は using です。
書式:
plot 'file' using {<entry> {:<entry> {:<entry> ...}}} {'format'}
もし、フォーマット (format) が指定されれば、C のライブラリ関数 'scanf' を 使ってデータファイルの各行をそのフォーマット文字列に従って読み込みます。 そうでなければ、行はスペースまたはタブの所で列に分割されて読み込まれます。 もし時系列フォーマットデータ (time-format data) を使っている場合は、 フォーマットを指定することはできません (これは `set data time` で行わ なければなりません)。
データは entry の指定に従った列に並び直されます。各 <entry> には、 データを選び出すための単なる列の番号、カッコで囲まれた数式を指定するか、 あるいは何も指定しません。数式中では、最初の列の値を読み込むために $1、 2 番目の列の項目を使うために $2、といった書き方を使用できます。 また、`column(x)` や `valid(x)` といったものも使うことができます。 ここで、x は結果として整数になる任意の数式です。`column(x)` は x 番目の データを返します。`valid(x)` は x 番目のデータが有効な値かをテストします。 列番号の 0 は、各点毎に 0 から始まる番号を表し、それは 2 行の空行が 来たところでリセットされます。列番号の -1 は 0 から始まるデータ行の 番号を意味します。これは 1 行の空行毎に 1 ずつ増加し、2 行の空行が来た ところでリセットされます。列番号の -2 は index を意味します。これは 2 行の空行が来たところで 1 ずつ増加します。<entry> に何も書かなければ その entry のリストの順にデフォルトの値が使われます。例えば `using ::4` は `using 1:2:4` と解釈されます。
注: call コマンドも $ を特別な文字として使います。call の引数リスト の中に列番号を含ませる方法の詳細については call の項目を参照してくだ さい。 using にただ一つの entry を指定した場合はその <entry> は y の値とし て使われ、データ点の番号が x として使われます。例えば "`plot 'file' using 1`" は "`plot 'file' using 0:1`" と同じ意味です。using に 2 つ の entry を与えた場合、それらは x, y として使われます。 さらに entry を追加すると、それらは x および/または y の誤差に使われます。誤差情報 を使った plot スタイルの詳細については style を、そして、回帰曲 線法での誤差情報の使用については `fit` を参照してください。
'scanf' 関数では色々なデータ形式の数値入力が使えますが、`gnuplot` は 全ての入力データを倍精度浮動小数とみなしますから、`gnuplot` では `lf` が唯一の数値入力指定、ということになります。'scanf' は数と数の間に ホワイトスペース - 空白、タブ ("\t")、改行 ("\n")、または改ページ ("\f") - があると期待します。それ以外の入力は明示的にスキップされる べきです。
"\t", "\n", "\f" を使うときはシングルクォートよりむしろダブルクォートを 使うべきであることに注意してください。
例:
次の例は、1 番目のデータに対する 2 番目と 3 番目の和の値を plot します。 書式文字列は、各列データがスペース区切りでなく、カンマ区切りであること を指示していますが、同じことが `set datafile separator ","` を指定する ことでも可能です。
plot 'file' using 1:($2+$3) '%lf,%lf,%lf'
次の例は、より複雑な書式指定でデータをファイル "MyData" から読み込み ます。
plot 'MyData' using "%*lf%lf%*20[^\n]%lf"
この書式指定の意味は以下の通りです:
%*lf 数値を無視
%lf 倍精度浮動小数を読み込む (デフォルトでは x の値)
%*20[^\n] 20 個の改行以外の文字を無視
%lf 倍精度浮動小数を読み込む (デフォルトでは y の値)
3 項演算子 `?:` を使ってデータをフィルタする一つの芸当を紹介します。
plot 'file' using 1:($3>10 ? $2 : 1/0)
これは、1 列目のデータに対して、3 列目のデータが 10 以上であるような 2 列目のデータを plot します。`1/0` は未定義値であり、`gnuplot` は未定 義の点を無視するので、よって適切でない点は隠されることになります
カッコで始まっていない限りは定数式を列番号として使うことができます。 例えば `using 0+(複雑な式)` の様なことができます。そして、その数式は、 カッコでスタートしていなければ数式の値が一度評価され、カッコでスタート していれば個々のデータ点を読み込むためにその値が一度評価される、という 点が重要です。
時系列フォーマットデータを使っている場合、その時間のデータは複数の列に 渡らせることができます。その場合、他のデータの開始位置を計算するとき、 時間のデータに空白が含まれていることに注意してください。例えば、データ 行の最初の要素がスペースが埋め込まれた時間データであるならば、y の値は 3 列目の値として指定されるべきです。
`plot 'file'` と `plot 'file' using 1:2`、そして `plot 'file' using ($1):($2)` には微妙な違いがあることに注意してください。1) file が 1 列と 2 列のデータを持つ行をそれぞれ含んでいるとすると、データが 1 列 のみの行に対しては、最初のものは x の値を作り出し、2 番目のものはその 行は無視し、3 番目のものはそれを未定義の値として保存します (折れ線で plot している場合 (plot with lines)、その未定義の点を通過する線を結ば ないように)。2) 1 列目に文字列を含んでいるような行がある場合、最初の ものはエラーとして plot を中止しますが、2 番目と 3 番目のものはその 不要な行を読みとばします。
実際、最初に単に
plot 'file' using 1:2
と指定することで、大抵の場合どんなにゴミのデータを含む行を持つファイル をも plot することが可能になります。しかし、どうしてもデータファイルに 文字列を残しておきたいならば、そのテキスト行の第一列にコメント文字 (#) を置く方がより安全でしょう。 弱々しい using のデモ
エラーバーは、1 から 4 個の追加されたデータを読む (またはエントリを using で追加選択する) ことにより、2 次元データの描画において実現され ています。これら追加される値は、それぞれのエラーバースタイルで異なった 形で使われます。
デフォルトでは、`gnuplot` はデータファイルの各行に以下のような 3 つ、 4 つ、あるいは 6 つの列があることを期待しています:
(x, y, ydelta),
(x, y, ylow, yhigh),
(x, y, xdelta),
(x, y, xlow, xhigh),
(x, y, xdelta, ydelta),
(x, y, xlow, xhigh, ylow, yhigh)
x 座標は必ず指定しなければいけません。各数値を書く順序も上で挙げた通りで なくてはなりません。ただ、using 修飾子を使えばその順序を操作できますし、 欠けている列の値も補うことは可能ですが。例えば、
plot 'file' with errorbars
plot 'file' using 1:2:(sqrt($1)) with xerrorbars
plot 'file' using 1:2:($1-$3):($1+$3):4:5 with xyerrorbars
最後の例は、相対的な x の誤差と絶対的な y の誤差、という、サポートされて いない組のファイルに対するものです。using エントリが相対的な x の誤差 から絶対的な x の最小値と最大値を生成しています。
y のエラーバーは、(x, ylow) から (x, yhigh) への鉛直な線として描かれます。 ylow と yhigh の代わりに ydelta が指定されたときは、ylow = y - ydelta, yhigh = y + ydelta となります。ある行にデータが 2 つしかなければ、ylow と yhight はともに y となります。x エラーバーは同様に計算された水平線です。 データの各点を結ぶ折れ線を引きたい場合は、with errorbars と with lines を 指定して，同じデータファイルを 2 回 `plot` して下さい (ただし、キーの中に 2 つのエントリを作らないように、その一方には `notitle` オプションを使う ことを忘れないで下さい)。他の選択肢として、errorlines コマンドもあります (errorlines 参照)。
エラーバーには、もし bars を使っていなければ、そのそれぞれの端に垂直な 線分がつきます (詳細は bars をご覧下さい)。
自動範囲指定が有効であれば、その描画範囲はエラーバーも含むように調整 されます。 エラーバーのデモ
さらなる情報に関して、using, with, style も参照して 下さい。
誤差線 (errorbar) を伴う線描画は、2 次元データファイルの描画でサポート されていて、それは 1 個から 4 個の追加の (または using で指定する) 列データを与えることで行なわれます。これらの追加される値は、様々な errorline スタイルのそれぞれで異なった形で使われます。
デフォルトの状態では、`gnuplot` は、データファイルの各行に 3 個、4 個、 6 個のいずれかの個数のデータがあることを期待し、それぞれ以下のいずれか に対応します。
(x, y, ydelta),
(x, y, ylow, yhigh),
(x, y, xdelta),
(x, y, xlow, xhigh),
(x, y, xdelta, ydelta),
(x, y, xlow, xhigh, ylow, yhigh)
x 座標は指定する必要がありますし、データの順番も上の形式である必要があ りますが、using 修飾子でその順番を操作したり、欠けている列に対する値 を与えたりすることができます。例えば
plot 'file' with errorlines
plot 'file' using 1:2:(sqrt($1)) with xerrorlines
plot 'file' using 1:2:($1-$3):($1+$3):4:5 with xyerrorlines
最後の例は、相対的な x の誤差と絶対的な y の誤差、というサポートされて いない組合せのデータのファイルに対するもので、using で相対的な誤差か ら絶対的な x の最小値と最大値を生成しています。
y 誤差線は (x, ylow) から (x, yhigh) へ描画される縦線です。ylow, yhigh 代わりに ydelta が指定された場合は、ylow = y - ydelta, yhigh = y + ydelta と扱われます。ある行に 2 つのデータしかない場合、yhigh, ylow は両方と も y になります。x 誤差線は同様の方法で計算される水平線です。
誤差線には、bars が指定されていない場合、その両端で垂直に交わる 線分が付きます (詳細は bars 参照)。
自動縮尺 (autoscaling) が ON の場合、描画範囲は誤差線が入るように調整 されます。
更なる情報については、using, with, style を参照し てください。
媒介変数モード (`set parametric`) では、`plot` では 2 つの数式の組を、 `splot` では 3 つの数式の組を与える必要があります。
例:
plot sin(t),t**2
splot cos(u)*cos(v),cos(u)*sin(v),sin(u)
データファイルは前と同じように描画されます。ただし、データファイルが 描画のために与えられる前に、任意の媒介変数関数が先に完全に指定された 場合を除いてです。言い換えると、x の媒介変数関数 (上の例では `sin(t)`) と y の媒介変数関数 (上の例では `t**2`) との間に、他の修飾子やデータ 関数をはさみこんではいけません。そのようなことをすると、構文エラーにな り、媒介変数関数が完全には指定されていない、と表示されます。 with や `title` のような他の修飾子は、媒介変数関数の指定が完了した 後に指定しなければいけません。
plot sin(t),t**2 title 'Parametric example' with linespoints
以下も参照 媒介変数モードのデモ。
オプションの範囲は、表示されるグラフの領域範囲を指定します。
書式:
[{<dummy-var>=}{{<最小値>}:{<最大値>}}]
[{{<最小値>}:{<最大値>}}]
最初の範囲指定は独立変数の範囲 (xrange またはパラメトリックモードで は trange) で、2 番目のものは従属変数の範囲 yrange (パラメトリック モードでは xrange) となります。<dummy-var> には独立変数の新しい別名を 指定します (デフォルトの変数名は dummy で変更できます)。<最小値>, <最大値> には定数式、あるいは * を書くことができます。
パラメトリックモードでなければ、与えられるべき範囲指定は xrange, yrange の順になります。
パラメトリックモードでは、`plot` コマンドに対してはその順序は trange, xrange, yrange になります。以下の `plot` コマンドは、trange を [-pi:pi], xrange を [-1.3:1.3], yrange を [-1:1] に設定する例です。
plot [-pi:pi] [-1.3:1.3] [-1:1] sin(t),t**2
x2 の範囲と y2 の範囲はここでは指定できないことに注意してください。 それには x2range や y2range が使われます。
範囲は適切なモードに対して、上に示した順序で解釈されます。必要な範囲 指定が一度全て指定されると、再び指定し直すことはありませんが、必要ない 部分を全く指定しないようにはできません - その代わりそこに空の範囲指定 `[]` を置きます。
`*` は、最小値や最大値に自動範囲指定 (autoscale) の機能を使うことを 可能にします。autoscale も参照してください。
`plot` や `splot` のコマンド行で指定された範囲はそのグラフにのみ影響を 及ぼします。よって、その後のグラフのデフォルトの範囲を変更するには、 xrange や yrange を使用してください。
時間データに対しては、範囲はクォートで囲んで指定する必要があります (データファイルに現われる時間データと同じ形式の)。`gnuplot` はその 範囲を読みこむのに時間書式文字列 (timefmt) を使用します。詳しくは timefmt を参照してください。
例:
以下は現在の範囲を使用します:
plot cos(x)
以下は x の範囲のみの指定です:
plot [-10:30] sin(pi*x)/(pi*x)
以下は上と同じですが、仮変数として t を使います:
plot [t = -10 :30] sin(pi*t)/(pi*t)
以下は x と y の両方の範囲の指定です:
plot [-pi:pi] [-3:3] tan(x), 1/x
以下は、y の範囲のみの指定で、両方の軸の自動範囲指定機能を無効にします:
plot [ ] [-2:sin(5)*-8] sin(x)**besj0(x)
以下は x の最大値と y の最小値のみの指定です。
plot [:200] [-pi:] exp(sin(x))
以下は x の範囲を時系列データとして指定しています:
set timefmt "%d/%m/%y %H:%M"
plot ["1/6/93 12:00":"5/6/93 12:00"] 'timedata.dat'
以下も参照: range のデモ
各関数やデータに対する曲線のタイトルは、その曲線のサンプル、および (または) それを表示されるのに使われる記号とともにキーの中に表示されま す。それは `title` オプションで変更できます。
書式:
title "<title>" | notitle
ここで <title> はその曲線の新しいタイトルで、クォートで囲む必要があり ます。クォートはキーには表示されません。特殊文字も、バックスラッシュに 続く 8 進値 (例えば "\345" のように) を使うことで用いることができます。 タブ文字 "\t" は認識されます。バックスラッシュのそのような作用はダブル クォートで囲まれた文字列でしか効きません。逆にその作用を働かさないよう にするにはシングルクォートを使ってください。改行文字 "\n" はどちらの型の クォートでもキーでは働きません。
曲線タイトルとサンプルは予約語 `notitle` を使うことでキーから削除でき ます。何もないタイトル (`title "`) は `notitle` と同じ意味を持ちます。 サンプルだけが欲しいときは、一つ以上の空白をタイトルの後ろに入れてく ださい (`tilte ' '`)。
`key autotitles` が設定されて (デフォルト)、かつ `title` も `notitle` も指定されなかった場合、曲線のタイトルは `plot` コマンド上にある関数名 かデータファイル名になります。ファイル名の場合は、指定される任意のデー タファイル修飾子もそのデフォルトタイトルに含まれます。
位置やタイトルの位置揃えなどのキーのレイアウトは、key で制御でき ます。詳細は key の項目を参照してください。
例:
以下は y=x をタイトル 'x' で表示します:
plot x
以下は、x の 2 乗をタイトル "x^2" で、ファイル "data.1" をタイトル "measured data" で表示します:
plot x**2 title "x^2", 'data.1' t "measured data"
以下は、極座標グラフの周りに円形の境界を書き、タイトルなしで表示します:
set polar; plot my_function(t), 1 notitle
関数やデータの表示にはたくさんのスタイルのうちの一つを使うことができます。 キーワード with がその選択のために用意されています。
書式:
with <style> { {linestyle | ls <line_style>}
| {{linetype | lt <line_type>}
{linewidth | lw <line_width>}
{pointtype | pt <point_type>}
{pointsize | ps <point_size>}
{fill | fs <fillstyle>}
{palette}}
}
ここで、<style> は `lines`, `points`, `linespoints`, `impulses`, `dots`, `steps`, `fsteps`, `histeps`, errorbars, `xerrorbars`, `yerrorbars`, `xyerrorbars`, errorlines, `xerrorlines`, `yerrorlines`,`xyerrorlines`, `boxes`, `filledcurves`, `boxerrorbars`, `boxxyerrorbars`, `financebars`, `candlesticks`, `vectors`, pm3d の中のいずれかです。これらのいくつか に対してはデータを付け足す必要があります。それぞれのスタイルの詳細につ いては `plotting styles` をご覧ください。`fill` は 2 次元描画のみに 関係があります (今のところは `boxes`, `boxxyerrorbars` と `candlesticks` のみ)。`filledcurves` と pm3d (pm3d は `splot` でのみ使用される) には、上には書かれていない追加のオプションを与えることもできます。詳細 は、それらのヘルプや下にある例を参照してください。
デフォルトのスタイルは `set style function` や `set style data` コマン ドで決定されます。
デフォルトでは、それぞれの関数やデータファイルは、使うことができる型の 最大数に達するまで異なる線種、点種を使います。すべての端末用ドライバは 最低 6 つの異なる点種をサポートしていて、もしたくさん要求された場合、 それらを順に再利用していきます。LaTeX ドライバは、それより 6 つ多く点種 (いずれも円の変種) を持っていて、よって点での曲線の描画は 12 種類の曲線 が繰り返されるのみです。PostScript ドライバは (`postscript`) 全部で 64 種類の 点種を持っています。
一つの描画で線種や点種を選びたいならば、<line_type> や <point_type> を 指定してください。これらの値は、その描画で使われる線種や点種を指定する 正の整定数 (または数式) です。使用する端末で使える線種、点種を表示する には test コマンドを使ってください。
描画の線の幅や点の大きさは <line_width> や <point_size> で変更できます。 これらはその各々の端末のデフォルトの値に対する相対的な値として指定しま す。点の大きさは全体に通用するように変更できます。詳細は pointsize を参照してください。しかし、ここでセットされる <point_size> と、 pointsize でセットされる大きさは、いずれもデフォルトのポイントサ イズに掛けられることに注意してください - すなわち、それらの効果は累積 はしません。例えば、`set pointsize 2; plot x w p ps 3` は、デフォルト のサイズの 3 倍であって、6 倍ではありません。
`set style line` を使って線種/線幅、点種/点幅の組を定義すれば、そのス タイルの番号を <line_style> にセットすることでそれらを使うことができま す。
gnuplot が pm3d をサポートするようにインストールされているならば、 `splots` において lines, points, dots の色を滑らかに変化させるための特 別なキーワード palette が使えます。その色は、コマンド palette であらかじめ設定された滑らかに変化するカラーパレットから選択します。色 の値は、点の z 座標の値か、または using で 4 番目のパラメータとして 指定される色座標に対応します。2 次元の `plot` コマンドではこのオプショ ンは無視されます。
キーワードは暗示するような形で省略可能です。
`linewidth`, pointsize, palette オプションは全ての端末装置でサポー トされているわけではないことに注意してください。
例:
以下は、sin(x) を鉛直線で描画します:
plot sin(x) with impulses
以下は、x を点で描画し、x**2 をデフォルトの方式で描画します:
plot x w points, x**2
以下は、tan(x) を関数のデフォルトの方式で、"data.1" を折れ線で描画します:
plot [ ] [-2:5] tan(x), 'data.1' with l
以下は、"leastsq.dat" を鉛直線で描画します:
plot 'leastsq.dat' w i
以下は、データファイル "population" を矩形で描画します:
plot 'population' with boxes
以下は、"exper.dat" をエラーバー付きの折れ線で描画します (エラーバーは 3 列、あるいは 4 列のデータを必要とします):
plot 'exper.dat' w lines, 'exper.dat' notitle w errorbars
もう一つの "exper.dat" のエラーバー付きの折れ線 (errorlines) での描画 方法 (エラーバーは 3 列、あるいは 4 列のデータが必要):
plot 'exper.dat' w errorlines
以下は、sin(x) と cos(x) をマーカー付きの折れ線で描画します。折れ線は 同じ線種ですが、マーカーは異なったものを使います:
plot sin(x) with linesp lt 1 pt 3, cos(x) with linesp lt 1 pt 4
以下は、"data" を点種 3 で、点の大きさを通常の 2 倍で描画します:
plot 'data' with points pointtype 3 pointsize 2
以下は、2 つのデータ集合に対して、幅のみ異なる線を用いて描画します:
plot 'd1' t "good" w l lt 2 lw 3, 'd2' t "bad" w l lt 2 lw 1
以下は、x*x の曲線の内部の塗りつぶしと色の帯を描画します:
plot x*x with filledcurve closed, 40 with filledcurve y1=10
以下は、x*x の曲線と色の箱を描画します:
plot x*x, (x>=-5 && x<=5 ? 40 : 1/0) with filledcurve y1=10 lt 8
以下は、滑らかに変化する色の線で曲面を描画します:
splot x*x-y*y with line palette
以下は、2 つの色のついた曲面を、異なる高さで表示します:
splot x*x-y*y with pm3d, x*x+y*y with pm3d at t
デフォルトの表示方法の変更方法については、style を参照して下さい。 以下も参照してください。 スタイルのデモ
`print` コマンドは <式> の値を画面に表示します．これは `pause 0` と同 じです。<式> は、数を生成する `gnuplot` の数式か、または文字列です。
書式:
print <式>
`expressions` を参照して下さい。出力ファイルは `set print` で設定でき ます。
注意:
plot '-' ; ... ; replot
という使い方は推奨されません。`gnuplot` はインラインデータを保存しない ので、replot によって新たな情報が直前の `plot` に追加されて修正され たコマンドを実行することになったとしても、最初の plot の `'-'` は再び インラインデータを読もうとするからです。 replot コマンドは multiplot モードでは働きません。それは、それが 画面全体にではなく直前のプロットのみを再実行するものだからです。
最後に実行した `plot` (`splot`) コマンドの内容を修正する方法については `command line-editing` を参照して下さい。
直前の描画コマンドの全体を表示させることや、それを `history` の中に コピーする方法については `show plot` を参照してください。
例:
ファイル "looper" が次のようなファイルで
a=a+1
plot sin(x*a)
pause -1
if(a<5) reread
そして、`gnuplot` から次のように実行するとします。
a=0
load 'looper'
すると、pause のメッセージで分割された 4 回のプロットが行われることに なります。
ファイル "data" が、各行に、0 から 10 までの範囲 (yrange) の 6 つのデ ータ を持ち、最初が x 座標で、その他は 5 つの異なる関数の、その x での 値であるとします。そして、ファイル "plotter" が
c_p = c_p+1
plot "$0" using 1:c_p with lines linetype c_p
if(c_p < n_p) reread
で、`gnuplot` から次のように実行するとします。
n_p=6
c_p=1
unset key
set yrange [0:10]
set multiplot
call 'plotter' 'data'
unset multiplot
すると、5 つのプロットを合わせた 1 つのグラフができます。yrange は、 multiplot モードで最初のものに続けて書かれる 5 つのグラフが、同じ軸を 持つように、明示的に指定する必要があります。線種も指定しなければなりま せん。さもないと、全てのグラフが同じ線種で書かれることになります。 以下も参照してください。 Reread アニメーションデモ (animate.dem)
コマンド reset は `set` コマンドで定義できる、グラフに関する全てのオ プションをデフォルトの値に設定します。このコマンドは、例えばコマンドフ ァイルの最後にグラフのデフォルトの設定に復帰する、あるいはコマンドファ イル内でたくさんの設定を行なった場合に元の状態に戻すときなどに便利です。 様々なオプションの取るデフォルトの値を知るには、`set` コマンドの項を参 照してください。
以下の `set` コマンドはグラフの状態を変更しないので、reset もそれら を変化させません: `set term` による出力形式の設定、および output による出力ファイルの指定、および loadpath や fontpath によ るディレクトリパスの設定。
書式:
save {<オプション>} '<ファイル名>'
ここで，<オプション> は，`functions`, variables, terminal, `set` のいずれかです。どれも指定されなかった場合には、`gnuplot` は、ユーザ定 義関数、変数、set で設定するオプション、最後に実行した `plot` (または `splot`) コマンドの全てを保存します。 save は、テキスト形式で出力します。また、このファイルは `load` コマ ンドで読み込むことができます。`set` オプション付き、または何もオプショ ンをつけずに save を実行した場合、terminal の選択と output のフ ァイル名はコメント記号つきで書き出されます。これはその出力ファイルを 他の環境にインストールされた gnuplot 上で動かす場合に、修正なしに使え るようにする、あるいはうっかりファイルを上書きしてしまったりする危険性 を避ける、といった意味があります。 terminal は、terminal の状態を、コメント記号をつけずに書き出 します。これは主に、ちょっとの間だけ terminal の設定を入れ替え、その 後保存しておいた terminal の状態を読み込むことで以前の terminal の設 定に戻す場合などに役立ちます。ただ、単一の gnuplot セッションでは、現 在の terminal を保存/復元する他の方法であるコマンド `set term push` と `set term pop` を使う方がむしろいいかもしれません。`set term` を参照し てください。
ファイル名は引用符に囲われていなければなりません。
特別なファイル名 "-" により save コマンドに標準出力に出力させること ができます。popen 関数をサポートするようなシステム (Unix など) では、 save の出力をパイプ経由で他の外部プログラムに渡すことができます。その 場合、ファイル名としてコマンド名の先頭に '|' をつけたものを使います。 これは、`gnuplot` とパイプを通して通信するプログラムに、`gnuplot` の内 部設定に関する首尾一貫したインターフェースを提供します。詳細は "help batch/interactive" を参照してください。
例:
save 'work.gnu'
save functions 'func.dat'
save var 'var.dat'
save set 'options.dat'
save term 'myterm.gnu'
save '-'
save '|grep title >t.gp'
`set` コマンドは実に多くのオプションを設定するのに使われます。しかし、 `plot`, `splot`, replot コマンドが与えられるまで何も表示しません。
`show` コマンドはそれらの設定値を表示します．`show all` でそれら全て を表示します．
`set` コマンドで変更されたオプションは、それに対応する unset コマン ドを実行することでデフォルトの状態に戻すことができます。reset コマン ドも参照してください。これは全てのパラメータの設定をデフォルトの値に戻 します。
もし変数が日時のデータを含むならば、`show` は、timefmt によって 現在設定されている書式に従って表示します。それは変数が最初に設定されて いてその書式が効果を持たなかったとしてもです。
デフォルトでは `gnuplot` は極座標グラフの独立変数の単位はラジアンを仮定 します。`set polar` の前に `set angles degrees` を指定すると、その単位 は度になり、デフォルトの範囲は [0:360] となります。これはデータファイル の描画で特に便利でしょう。角度の設定は、mapping コマンドを設定す ることにより 3 次元でも有効です。
書式:
set angles {degrees | radians}
show angles
`set grid polar` で指定される角度も、angles で指定した単位で読まれ 表示されます。 angles は組み込み関数 sin(x), cos(x), tan(x) の引数や asin(x), acos(x), atan8x), atan2(x), arg(x) の出力にも影響を与えます。双曲線関 数や、ベッセル関数の引数には影響を与えません。しかし、複素数を引数とす る逆双曲線関数の出力には影響が出ます。それらの関数が使われるときは、 `set angles radians` は入出力の引数の間に一貫性を持った管理を実現して いなければなりません。
x={1.0,0.1}
set angles radians
y=sinh(x)
print y #prints {1.16933, 0.154051}
print asinh(y) #prints {1.0, 0.1}
しかし、
set angles degrees
y=sinh(x)
print y #prints {1.16933, 0.154051}
print asinh(y) #prints {57.29578, 5.729578}
以下も参照 poldat.dem: angles を用いた極座標描画のデモ
書式:
set arrow {<tag>} {from <position>} {to|rto <position>}
{ {arrowstyle | as <arrow_style>}
| {nohead | head | heads}
{size <length>,<angle>}
{filled | nofilled}
{front | back}
{ {linestyle | ls <line_style>}
| {linetype | lt <line_type>}
{linewidth | lw <line_width} } }
unset arrow {<tag>}
show arrow {<tag>}
タグ <tag> は各矢印を識別する整数です。タグを指定しない場合は、その 時点で未使用の最も小さい数が自動的に割り当てられます。タグを使うこと で、特定の矢印を変更したり、削除したりできます。既に存在する矢印の属性を 変更する場合は、タグを明示した set arrow コマンドで変更箇所を指定して ください。
<position> は x,y あるいは x,y,z で指定します。そしてその前に座標系を 選択するために `first`, `second`, `graph`, `screen` を置くことができま す。座標を指定しなければデフォルトでは 0 と見なされます。矢印の端点は、 四つの座標系 - `first` か `second` の軸、`graph` あるいは `screen` - のうちの 1 つを選択して指定できます。詳細は `coordinates` を参照して 下さい。"from" の場所の座標系指定子は、"to" の場所に影響を及ぼすことは ありません。グラフの枠をはみ出る矢印を書くこともできますが、出力端末に よってはエラーを生ずることがあります。終点が "to" の代わりに "rto" で 指定されている場合、始点からの相対的な位置に描かれます。
`nohead` を指定することで、矢先のない矢 - すなわち線分を書くことも できます。これは描画の上に線分を描く別な方法を与えます。デフォルトでは 矢先がついています。`heads` の指定で線分の両端に矢先が描かれます。
矢先の大きさは `size <length>,<angle>` で制御できます。<length> は、矢 先の枝の長さで、<angle> は矢先の枝と矢軸がなす角度 (単位は度) です。 <length> の単位は x 軸と同じですが、それは <length> の前に `first`, `second`, `graph`, `screen` をつけることで変更できます。詳細は `coordinates` を参照してください。
`filled` を指定すると、塗りつぶされた矢先を作ります (`heads` が使われ ている場合)。塗りつぶしは、多角形の塗りつぶしが行えるような出力形式で サポートされていて、そのリストについては pm3d を参照してください。 他の出力形式では矢先は閉三角形にはなりますが塗りつぶされません。また、 fig, `metafont`, `metapost`, latex, tgif のように、矢をそれら自 身の独自のルーチンで描くような出力形式では、矢先の塗りつぶしはもちろ んサポートされません。
線種はユーザの定義したラインスタイルのリストから選ぶこともできますし (`set style line` 参照)、用意されている <line_type> の値 (デフォルトの ラインスタイルのリストの番号) そして <linewidth> (デフォルトの幅の乗数) を使ってここで定義することもできます。
しかし、ユーザー定義済のラインスタイルが選択された場合、その属性 (線種、 幅) は、単に他の arrow コマンドで適当な番号や `lt`, `lw` などを 指定しても、変更はできないことに注意して下さい。
`front` を指定すると、矢はグラフのデータの上に描かれます。`back` が指 定された場合 (デフォルト) は矢はグラフのデータの下に描かれます。`front` を使えば、密集したデータで矢が見えなくなることを防ぐことができます。
例:
原点から (1,2) への矢印をユーザ定義済のラインスタイル 5 で描くには:
set arrow to 1,2 ls 5
描画領域の左下角から (-5,5,3) へタグ番号 3 の矢印を描くには:
set arrow 3 from graph 0,0 to -5,5,3
矢印の端を 1,1,1 に変更し、矢先を外して幅を 2 にするには:
set arrow 3 to 1,1,1 nohead lw 2
x=3 の所へグラフの下から上まで鉛直線を描くには:
set arrow from 3, graph 0 to 3, graph 1 nohead
T 字型の矢先を両端に持つ鉛直方向の矢を描くには:
set arrow 3 from 0,-5 to 0,5 heads size screen 0.1,90
始点からの相対的な距離をグラフ座標で与えて矢を描くには:
set arrow from 0,-5 rto graph 0.1,0.1
2 番の矢印を消すには:
unset arrow 2
全ての矢印を消すには:
unset arrow
全ての矢印の情報を (タグの順に) 見るには:
show arrow
以下も参照 矢印のデモ
自動縮尺機能 (autoscale) は x, y, z の各軸に対して独立に、または一括して 指定できます。デフォルトでは全ての軸に対して自動縮尺設定を行います。
書式:
set autoscale {<axes>{|min|max|fixmin|fixmax|fix} | fix | keepfix}
unset autoscale {<axes>}
show autoscale
ここで、<axes> (軸) は `x`, `y`, `z`, `cb`, `x2`, `y2`, `xy` のいずれ かです。`min` または `max` を軸に追加指定すると (`xy` では使えませんが) それは `gnuplot` にその軸の最小値、または最大値のみを自動縮尺させるこ とになります。軸も何も指定されていない場合は全ての軸が対象となります。
`fixmin` や `fixmax` や `fix` を追加指定すると、等間隔の目盛りの自動縮 尺時の、次の目盛り位置までの範囲の自動拡大を gnuplot に行わせないよう にします。`set autoscale fix` はこれを全ての軸に対して設定します。コマ ンド `set autoscale keepfix` は、直前の `fix` の設定を維持したまま全て の軸を自動縮尺にします。
自動縮尺機能を使うときは、描画範囲は自動的に割り出され、従属変数軸 (`plot` のときは y 軸、`splot` のときは z 軸) は、関数やデータの値域が 収まるように設定されます。
従属変数軸 (y または z) の自動縮尺機能が指定されていない場合は、現在の y や z の描画範囲がそのまま使われます。
独立変数軸 (`plot` のときは x 軸、`splot` のときは x,y 軸) の自動縮尺 機能が指定されている場合は、描画される全てのデータファイルの点が収まる ように定義域をとるようになります。データファイルが 1 つも指定されてい ない場合は、自動縮尺機能はなんの効果もありません。つまり、関数のみが 指定されていてデーターファイルを使わない場合は、x 軸の描画範囲 (z = f(x,y) を描画しているときは y 軸も) は影響をうけません。
範囲に関するより詳しい情報に関しては xrange を見てください。
媒介変数モード (parametric) でもも自動縮尺機能は有効です (`set parametric` 参照)。この場合、より多くの従属変数があるので、x, y, z 各軸 に関して、より多くの制御が行われます。媒介変数モードでの独立変数 (仮変数) は `plot` では t で `splot` では u, v です。そして媒介変数モードでは、 自動縮尺機能は (t, u, v, x, y, z) の全ての描画範囲を制御し、x, y ,z の 範囲の自動設定を完全に行います。
自動縮尺機能は、極座標モード (polar mode) でも `plot` の媒介変数モード と同様に機能しますが、極座標モードでは dummy で独立変数を t から 変更するできる (dummy 参照) という拡張があります。
目盛りが第二の軸に表示され、しかもこれらの軸に対する描画が行われなかっ た場合には、x2range と y2range は xrange と yrange の値を受け継ぎます。 これは、xrange と yrange が整数個の目盛り幅に自動縮尺される「前」に行わ れますので、場合によって予期しない結果をもたらす可能性があります。それ を避けるために `fixmin`, `fixmax` オプションを使うことができます。
例:
以下は y 軸の自動縮尺機能を指定します (他の軸には影響を与えません):
set autoscale y
以下は y 軸の最小値に対してのみ自動縮尺機能を指定します (y 軸の最大値、 および他の軸には影響を与えません):
set autoscale ymin
以下は x2 軸の隣の目盛りへの自動範囲拡大機能を無効にし、よって描画デー タ内、または関数に対する丁度の描画範囲を維持します:
set autoscale x2fixmin
set autoscale x2fixmax
以下は x, y 両軸の自動縮尺機能を指定します:
set autoscale xy
以下は x, y, z, x2, y2 全軸の自動縮尺機能を指定します:
set autoscale
以下は x, y, z, x2, y2 全軸の自動縮尺機能を禁止します:
unset autoscale
以下は z 軸のみについて自動縮尺機能を禁止します:
unset autoscale z
媒介変数表示モード (`set parametric`) においては，xrange も yrange と 同様に縮尺を変えることができます。つまり、媒介変数モードにおいては、 x 軸方向も自動的に縮尺が調整され、描こうとしている媒介変数表示の関数が 収まるようになります。もちろん、y 軸方向も媒介変数モードでない時同様に 自動的に縮尺を変えます。x 軸について自動縮尺機能が設定されていない場合 は、現在の x の範囲が使われます。
データファイルは媒介変数モードでもそうでない状態でも同様に描画され ます。しかし、データファイルと関数が混在している場合には、違いがあ ります: 媒介変数モードでなければ、x の自動縮尺機能は、関数の範囲を データの描画範囲に合わせます。しかし媒介変数モードではデータの範囲 は関数の範囲に影響しません。
それには、片手落ちにならないように `set autoscale t` というコマンド も用意されています。しかしその効果は非常に小さいものです。自動縮尺 機能が設定されていると、`gnuplot` が t の範囲が無くなってしまうと 判断した場合に範囲を少し調整します。自動縮尺機能が設定されていないと このようなときにはエラーとなります。このような動作は実はあまり意味が なく、よって `set autoscale t` というコマンドは存在意義に疑問があり ます。
`splot` では上記の発想の元に拡張されています．自動縮尺機能が設定され ている場合、x, y, z の各描画範囲は計算結果が収まるように設定され縮尺 調整されます。
極座標モード (`set polar`) では、xrange と yrange は極座標から求められ、 それによって自動的に範囲設定がなされます。言いかえると、極座標モードでは 描こうとしている極座標関数が収まるように x 軸、y 軸が自動的に縮尺が調整 されます。
極座標モードで関数を描画する場合、rrange も自動範囲設定されます。データ ファイルを描画する場合はさらに trange も自動範囲設定がなされます。もし、 trange がある象限 (四分円) に収まるならば、自動縮尺機能によりその象限のみ の描画が行われることに注意してください。
1 つ、あるいは 2 つの範囲は明示的に設定してその他のものを指定しない場合は 予期しない結果を引き起こすかも知れません。 以下も参照 極座標のデモ。
コマンド bars は誤差グラフ (errorbar) の両端のマークの幅、および 描画スタイル candlesticks, financebars の箱の幅を制御します。
書式:
set bars {small | large | <size>}
unset bars
show bars
`small` は 0.0, `large` は 1.0 と同じです。サイズを指定しなければデフォ ルトの値は 1.0 です。
コマンド bmargin は、下部の余白のサイズを設定します。詳細は margin を参照してください。
書式:
set border {<integer> { {linestyle | ls <line_style>}
| {linetype | lt <line_type> }
{linewidth | lw <line_width>} } }
unset border
show border
`set view 56,103` のように任意の方向で表示されうる `splot` では、 x-y 平面上の 4 つの角は 手前 (`front`), 後ろ (`back`) , 左 (`left`), 右 (`right`) のように参照されます。もちろんこの同じ 4 つの角は天井の面に もあります。よって、例えば x-y 平面上の後ろと右の角をつなぐ境界を "底の右後ろ (bottom right back)" と言い、底と天井の手前の角をつなぐ境 界を "鉛直手前 (front vertical)" と呼ぶことにします (この命名法は、読 者が下の表を理解するためだけに使われます)。
枠は、12 ビットの整数に符号化されています: 下位 4 ビットは `plot` に対 する外枠、`splot` に対しては底面の外枠、次の 4 ビットは `splot` の鉛直な 外枠、そして上位 4 ビットは `splot` の天井面の外枠を制御します。その `<整数>` 値は次の表の対応する項目の数字の和になります:
ビット plot splot
1 下 底の左手前
2 左 底の左後ろ
4 上 底の右手前
8 右 底の右後ろ
16 効果なし 鉛直左
32 効果なし 鉛直後ろ
64 効果なし 鉛直右
128 効果なし 鉛直手前
256 効果なし 天井の左後ろ
512 効果なし 天井の右後ろ
1024 効果なし 天井の左手前
2048 効果なし 天井の右手前
ビットは一つ一つ、あるいはいくつかをまとめて一緒にこのコマンドで付加で きます。
デフォルトの値は 31 で、これは `plot` では 4 方向の外枠全て、`splot` では底面の枠線全部と z 軸を描くことを意味します。
<line_style>, <line_type>, <line_width> を指定して、枠線の描画にそれ らを反映させることができます (現在の出力装置がサポートするものに限定 されます)。
`plot` では、第 2 軸を有効にすることで、下と左以外の境界に目盛りを描く ことができます。詳細は xtics を参照してください。
"`unset surface; set contour base`" などによって `splot` で底面にのみ 描画する場合、鉛直線や天井はそれらが指定されていても描画されません。
`set grid` のオプション 'back', 'front', 'layerdefault' でも、描画出力 の境界線を書く順番を制御できます。
例:
以下は、デフォルトの枠線を描きます:
set border
以下は、`plot` では左と下、`splot` では底面の左手前と左後ろの枠線を描 きます:
set border 3
以下は、`splot` で周りに完全な箱を描きます:
set border 4095
以下は、手前の鉛直面と天井のない箱を描きます:
set border 127+256+512 # または set border 1023-128
以下は、`plot` に対して上と右枠線のみを描き、それらを軸として目盛りづ けします:
unset xtics; unset ytics; set x2tics; set y2tics; set border 12
以下も参照 枠線のデモ
コマンド boxwidth は `boxes`, `boxerrorbar`, `candlesticks` スタ イルにおける棒のデフォルトの幅を設定するために使います。
書式:
set boxwidth {<width>} {absolute|relative}
show boxwidth
第 3, 4, 5 番目の列 (または using による項目指定) のないデータファイ ルの描画、あるいは関数の描画では、各々の棒の幅は boxwidth で設定 します (もしファイルと boxwidth の両方で幅が指定されている場合は ファイルの方の幅が使われます)。いずれの方法でも指定されていない場合は、 その隣合う棒に接するように各々の棒の幅が自動的に計算されます。 `relative` は、指定した幅が自動的に計算される棒の幅に対する相対的な値 (積因子) であることを意味します。そうでない場合は、指定された幅は絶対 的 (`absolute`) な値と見なされます (デフォルト)。4 列のデータの場合、 第 4 列目の値が棒の幅として使われます。ただし、その幅が -2.0 の場合に は、自動計算されます。詳細は `set style boxerrorbars` を参照してくださ い。
棒の幅を自動的にセットするには
set boxwidth
とする、あるいは 4 列のデータに対しては以下のようにします。
set boxwidth -2
`plot` のキーワード using を使っても同じ効果を得ることができます:
plot 'file' using 1:2:3:4:(-2)
棒の幅を自動的な値の半分にするには
set boxwidth 0.5 relative
棒の幅を絶対的な値 2 にするには
set boxwidth 2 absolute
とするか、または、その前に相対的な棒の幅をしていなければ
set boxwidth 2
`gnuplot` は、clabel が設定されている時には、各々の等高線のレベルに対 して使う線種を変化させます。このオプションが有効である場合 (デフォ ル ト)、凡例によって各々の線種を、それが表す z のレベルとともに表示されま す。
書式:
set clabel {'<format>'}
unset clabel
show clabel
書式文字列のデフォルトは %8.3g で、小数部分は 3 桁表示されます。もし key がそのデフォルトの値から変更されていれば、その配置は不十分なもの になるかもしれません。
最初の等高線の線種、または clabel が無効である場合の唯一つの等高線の 線種は、(曲面の線種 +1) になります。等高線の点は曲面の点と同じものに なります。 contour も参照してください。
`gnuplot` はグラフの端の辺りのデータ点や線をクリッピングすることができ ます。
書式:
set clip <clip-type>
unset clip <clip-type>
show clip
`gnuplot` は点や線に対するクリップ型 (clip-type) として、`points`, `one`, `two` の 3 種類をサポートしています。ある描画に対して、これらの クリップ型は任意の組み合せで設定することができます。pm3d の色地図や カラー曲面で塗りつぶされた四辺形はこのコマンドでは制御できませんが、 `set pm3d clip1in` や `set pm3d clip4in` によって可能であることに注意 してください。
クリップ型 `points` を設定すると，描画領域内にはあるけれど境界線に非 常に近いような点をクリップする (実際には描画しないだけですが) ように `gnuplot` に指示します。これは点として大きなマークを使用したときに、 そのマークが境界線からはみ出さないようにする効果があります。`points` をクリップしない場合、境界線の辺りの点が汚く見えるかもしれません。 その場合、x や y の描画範囲 (xrange, yrange) を調整してみて下さい。
クリップ型 `one` を設定すると、一端のみが描画領域にあるような線分も 描画するように `gnuplot` に指示します。この際、描画領域内にある部分 のみが実際に描画される範囲です。設定しなかった場合、このような線分は 描画対象とならず、どの部分も描画されません。
両端は共に描画範囲に無いが描画領域を通過するという線分もあります。 クリップ型 `two` を設定することによって、このような線分の描画領域の 部分を描画することができます。
どのような状況でも、描画範囲の外に線が引かれることはありません。
デフォルトでは、`noclip points`, `clip one`, `noclip two` となって います。
全てのクリップ型の設定状況を見るには以下のようにします:
show clip
過去のバージョンとの互換性のため以下の書式も使用可能です:
set clip
unset clip
clip は `set clip points` と同義です。clip は 3 種の
クリップ型全てを無効にします。
書式:
set cntrparam { { linear
| cubicspline
| bspline
| points <n>
| order <n>
| levels { auto {<n>} | <n>
| discrete <z1> {,<z2>{,<z3>...}}
| incremental <start>, <incr> {,<end>}
}
}
}
show contour
このコマンドは 2 つの機能を持っています。一つは等高線上の点 (データ点の 線形補間、あるいは関数の標本化 (isosample) による点) での z の値の設定で、 もう一つは、そのように決定された z が等しい点同士を等高線で結ぶ方法の制御 です。<n> は整数型の定数式、<z1>, <z2> ... は任意の定数式です。各オプショ ン変数の意味は次の通りです:
`linear`, `cubicspline`, `bspline` -- 近似 (補間) 方法を指定します。 `linear` ならば，等高線は曲面から得られた値を区分的に直線で結びます。 `cubicspline` (3 次スプライン) ならば、区分的な直線はいくぶんなめらかな 等高線が得られるように補間されますが、多少波打つ可能性があります。 `bspline` (B-spline) は、より滑らかな曲線を描くことが保証されますが、 これは z の等しい点の位置を近似しているだけです。
`points` -- 最終的には，全ての描画は，区分的な直線で行われます。ここで 指定する数は、`bspline` または `cubicspline` での近似に使われる線分の数 を制御します。実際には cubicspline と bspline の区間 (曲線線分) の数は `points` と線分の数の積に等しくなります。
`order` -- bspline 近似の次数です。この次数が大きくなるにつれて、等高線 はなめらかになります (もちろん、高次の bspline 曲線になるほど、元の区分 的直線からは離れていきます)。このオプションは `bspline` モードでのみ有効 です。指定できる値は、2 (直線) から 10 までの整数です。
`levels` -- 等高線のレベルの数は、`auto` (デフォルト), `discrete`, `incremental` と等高線のレベル数 <n> で制御します。<n> の値は、 plot.h の中で 定義されている (標準では 30) MAX_DISCRETE_LEVELS を上限と しています。
`auto` では、<n> は仮のレベルの数であり、実際のレベルの数は、簡単なラ ベルを生成するように調節されます。曲面の z 座標が zmin から zman の範 囲にあるとき、等高線はその間の dz の整数倍になるように生成されます。 ここで、dz は 10 のあるべき乗の 1, 2, 5 倍、のいずれかです (2 つの目盛 りの間を丁度割り切るように)。
`levels discrete` では、等高線は指定された z = <z1>, <z2> ... に対して 生成されます。指定した個数が等高線のレベルの個数となります。`discrete` モードでは、`set cntrparams levels <n>` という指定は常に無視されます。
`incremental` では、等高線は z = <start> から始まり、<increment> ずつ 増えて行き限界の個数に達するまで書かれます。<end> はその等高線の数を 決定するのに使われますが、これは後の `set cntrparam levels <n>` によっ て常に変更されます。
コマンド cntrparam が引数なしに呼ばれた場合は、次のデフォルトの 値が使われます: linear, 5 points, order 4, 5 auto levels
例:
set cntrparam bspline
set cntrparam points 7
set cntrparam order 10
以下はレベルの基準が合えば 5 個のレベルがに自動的に選択されます:
set cntrparam levels auto 5
以下は .1, .37, .9 にレベルを設定します:
set cntrparam levels discrete .1,1/exp(1),.9
以下は 0 から 4 まで、1 ずつ増やすレベルを設定します:
set cntrparam levels incremental 0,1,4
以下はレベルの数を 10 に設定します (増加の最後の値 (end) または自動で 設定されるレベルの数は変更されます):
set cntrparam levels 10
以下はレベルの数は保持したままレベルの開始値と増分値を設定します:
set cntrparam levels incremental 100,50
等高線を描く場所の制御に関しては contour を、等高線のラベルの書 式と線種の制御に関しては clabel を参照してください。
以下も参照してください。 等高線のデモ (contours.dem) および ユーザ定義レベルの等高線のデモ (discrete.dem).
色の一覧表、すなわち pm3d の palette の min_z から max_z までの滑 らかな色の勾配は、`unset colorbox` が使われていない限りカラーボックス (colorbox) に描かれます。
set colorbox
set colorbox {
{ vertical | horizontal }
{ default | user }
{ origin x, y }
{ size x, y }
{ noborder | bdefault | border [line style] }
}
show colorbox
unset colorbox
カラーボックスの位置は、`default` または `user` で指定でき、後者の場合 その位置や大きさを origin や size コマンドで設定します。
`vertical` と `horizontal` は色勾配の方向を切替えます。
`origin x, y` と `size x, y` は `user` オプションとの組でのみ使用され ます。x, y の値は 0 から 1 までのスクリーン座標 (これ以外の全ての座標 と関係ありません) で与えなければいけません。例えば以下を試してみてくだ さい:
set colorbox horiz user origin .1,.02 size .8,.04
これは水平方向の色勾配をグラフの下の辺りに描画します。 border は境界描画を ON にします (デフォルト) し、`noborder` は境界描 画を OFF にします。border の後ろに正の整数を与えると、それを境界を描 画する時の line style のタグとして使います。例えば:
set style line 2604 linetype -1 linewidth .4
set colorbox border 2604
は line style `2604`、すなわち細い線のデフォルトの境界色 (-1) で境界を 描画します。`bdefault` (デフォルト) は、カラーボックスの境界の描画にデ フォルトの境界の line style を使います。
カラーボックスの軸は `cb` と呼ばれ、通常の軸のコマンドで制御されます。 すなわち `set/unset/show` で cbrange, `[m]cbtics`, `format cb`, `grid [m]cb`, cblabel などが、そして多分 cbdata, `[no]cbdtics`, `[no]cbmtics` なども使えるでしょう。
パラメータ無しの `set colorbox` はデフォルトの位置へ切替えます。 `unset colorbox` はカラーボックスのパラメータをデフォルト値にリセット し、その上でカラーボックスを OFF にします。 pm3d, palette, pm3d, `set style line` の各項目も参照 してください。
コマンド contour は曲面の等高線を引くことを指示します。このオプ ションは `splot` でのみ有効です。
書式:
set contour {base | surface | both}
unset contour
show contour
これらの 3 つのオプションは等高線をどこに引くかを指定します。`base` で は等高線を x/y 軸の刻みのある底面に描かれ、surface では等高線はその 曲面自体の上に描かれ、`both` では底面と曲面上の両方に描かれます。オプ ションが指定されていない場合は `base` であると仮定されます。
等高線の描画に影響を与えるパラメータについては cntrparam を、等 高線のラベルの制御に関しては clabel を参照してください。
等高線のみのグラフが得るために、曲面自身の描画をしないようにすることも できます (surface 参照)。size を使って、グラフを画面一杯に 描画することも可能ですが、そういった出力形式よりも、等高線のデータを ファイルに書き出し、それを再び 2 次元データとして読み込んで描画すれば よりよい制御が可能になります:
unset surface
set contour
set cntrparam ...
set term table
set out 'filename'
splot ...
set out
# contour info now in filename
set term <whatever>
plot 'filename'
等高線を描くためには、データは格子状データ ("grid data") である必要が あります。そのようなファイルでは、一つの y-孤立線上の全ての点が順に 並べられていきます。そして隣の y-孤立線上の点が順に並べられ、そして隣、 と続いていきます。y-孤立線同士を分離するには一行の空行 (空白、復帰、改 行以外の文字を含まない行) を挟みます。`splot datafile` も参照してくだ さい。
非格子上データで等高線を描きたい場合は、格子を生成するために dgrid3d を使用します。詳しいことは dgrid3d の項目を参照してください。 以下も参照してください。 等高線のデモ (contours.dem) および ユーザ定義レベルの等高線のデモ (discrete.dem).
このコマンドの形式は批判されています。`set style data` を参照してくだ さい。
コマンド `set datafile` は、`plot`, `splot`, `fit` コマンドで入力デー タを読む場合に、その列 (field) の解釈の仕方を制御するオプションを持ち ます。現在は、3 つのそのようなオプションが実装されています。
コマンド `set datafile missing` は `gnuplot` に、どのような文字列がデ ータファイル中の欠けたデータ (missing data) を意味するのかを指示します。 実際にその文字列がどのように取り扱われるかは、`plot` や `splot` コマン ドの using 指定子にも依存します。
書式:
set datafile missing {"<string>"}
show datafile missing
unset datafile
例:
# IEEE NaN ("Not a Number") コードを含むエントリを無視する
set datafile missing "NaN"
例:
set datafile missing "?"
set style data lines
plot '-'
1 10
2 20
3 ?
4 40
5 50
e
plot '-' using 1:2
1 10
2 20
3 ?
4 40
5 50
e
plot '-' using 1:($2)
1 10
2 20
3 ?
4 40
5 50
e
最初の `plot` は、"3 ?" の行では最初のデータのみを認識し、そこでは 1 行に 1 つしかデータがなかった場合の規則が適用され、行番号が "x" でデー タが "y" と見なされ、その点は (2,3) に (この場合は誤って) 描画されます。
2 番目の `plot` は、真中の行を正しく無視します。描画される曲線は、 (2,20) と (4,40) が結ばれます。
3 番目の `plot` も真中の行を正しく無視しますが、この場合は (2,20) と (4,40) は結ばれません。
デフォルトの `missing` 用の文字は何も定義されていませんが、多くの場合 数値が期待されるべき所にそれと認識できない文字が見つかったらそれは欠け たデータ (missing data) であると見なされます。
コマンド `set datafile separator "<char>"` は、`gnuplot` に、この後の 入力ファイルのデータ列の分離文字が、空白 (whitespace) でなくて <char> であると指示します。このコマンドの最も一般的な使用例は、表計算ソフトや データベースソフトによって作られた csv (コンマ区切り) ファイルを読む時 でしょう。デフォルトのデータ列の分離文字は空白 (whitespace) です。
書式:
set datafile separator {"<char>" | whitespace}
例:
# タブ区切りのファイルを入力
set datafile separator "\t"
# コンマ区切りのファイルを入力
set datafile separator ","
コマンド `set datafile commentschars` は `gnuplot` に、どの文字がデー タファイル中のコメントを意味するのかを指示します。gnuplot は、指定され た文字の中の一つがデータ行の最初の非空白文字として現われた場合、その文 字以下を無視します。
書式:
set datafile commentschars {"<string>"}
show datafile commentschars
unset commentschars
デフォルトの string は、VMS では "#!" で、それ以外では "#" です。
よって、データファイルの以下の行は完全に無視されます
# 1 2 3 4
が、以下の行
1 # 3 4
は、もし
set datafile missing '#'
が指定されていなければ、予期せぬ結果を生じます。
例:
set datafile commentschars "#!%"
コマンド decimalsign は、目盛りの見出し、あるいは label 文 字列に書かれる数の小数点記号を選択します。
書式:
set decimalsign {<value>}
unset decimalsign
show decimalsign
引数 <value> は、通常の小数点記号に置き換えて使う文字列です。典型的な ものはピリオド '.' やコンマ ',' ですが他にも有用なものがあるでしょう。 引数 <value> を省略すると、小数点の区切りはデフォルト (ピリオド) から 変更されません。unset decimalsign も <value> を省略するのと同じ効果を 持ちます。
例:
多くのヨーロッパ諸国での正しい出力形式を得るには:
set decimalsign ','
コマンド dgrid3d は、非格子状データから格子状データへの写像機能を 有効にし、そのためのパラメータを設定します。
書式:
set dgrid3d {<row_size>} {,{<col_size>} {,<norm>}}
unset dgrid3d
show dgrid3d
デフォルトでは dgrid3d は無効になっています。有効になると、ファイル から読み込まれる 3 次元のデータは「散在した」データ (非格子状データ) であると見なされます。格子は、グラフと等高線の描画のために、散在した データを囲む矩形から得られる寸法と、row_size/col_size で指定される数の 行と列を持つように生成されます。格子は x 方向 (行) と y 方向 (列) に 等間隔です。z の値は散在するデータの z の値の重み付きの平均として計算 されます。
3 番目のパラメータであるノルム (norm) は、重み付けを制御するもので、 各点は格子点からの距離の norm 乗の逆数で重み付けされます。(実際には、 dx, dy を各データ点と格子点との差の成分であるとすると、重みは dx^norm + dy^norm で与えられます。2 のべきのノルム、特に 4, 8, 16 に関しては、 その重みの計算はユークリッド距離を使うことで (dx^2+dy^2)^norm/2 のよう に最適化されてますが、任意の負でない整数を使うことも可能です。)
格子点に近いデータ点程それはその格子点により大きい影響を与え、ノルムの 値が大きい程格子点から離れた点の影響は小さくなります。 dgrid3d オプションは散在するデータから格子状データに変換する簡単な ローパスフィルタです。この問題に対するより洗練された手法が存在します ので、この単純な方法が不十分であれば、`gnuplot` の外でそのような方法 でデータを前処理するべきでしょう。
(z の値は全てのデータ点の重み付けとして求められ、隣接するデータ点を補 間しているのではありません。よって、端の影響が予期しない、望ましくない 結果を引き起こす可能性があります。ある場合では、小さいノルムの値により 局所的な平均ではなくデータ点の距離の平均を反映したような格子点が生成さ れ、一方、大きなノルムの値により、隣接するデータ点を滑らかに変化させる のでなく最も近くのデータ点と同じ値を持つ格子点による階段 ("steps") を 作ってしまいます。格子の領域内部は任意の境界条件に関する補外法により埋 めることができますが、変数は正規化されず、よって x と y の単位が x, y 各方向に関して、点の相対的な重みに影響をおよぼすことになります。)
例:
set dgrid3d 10,10,1 # デフォルト
set dgrid3d ,,4
最初のものは、構成する格子を 10x10 にし、重みの計算のノルムは 1 にします。 2 番目の例はノルムのみ 4 に変更します。 以下も参照 scatter.dem: dgrid3d のデモ
コマンド dummy はデフォルトの仮変数名を変更します。
書式:
set dummy {<dummy-var>} {,<dummy-var>}
show dummy
デフォルトでは、`gnuplot` は `plot` では、媒介変数モード、あるいは極座 標モードでは "t", そうでなければ "x" を独立変数 (仮変数) とし、同様に `splot` では、媒介変数モードでは (`splot` は極座標モードでは使えません) "u" と "v", そうでなければ "x" と "y" を独立変数とします。
仮変数は、物理的に意味のある名前、あるいはより便利な名前として使う方が 便利でしょう。例えば、時間の関数を描画する場合:
set dummy t
plot sin(t), cos(t)
このコマンドでは、少なくとも一つの仮変数が設定される必要があります。 dummy だけだとエラーメッセージが表示されます。
例:
set dummy u,v
set dummy ,s
第二の例は、2 番目の変数を s とします。
コマンド encoding は文字のコード化 (encoding) を選択します。
書式:
set encoding {<value>}
show encoding
有効な値 (value) は以下の通りです。
default - 出力形式にデフォルトのコード化の使用を命令
iso_8859_1 - 多くの Unix ワークステーションや MS-Windows で使用可
能な最も一般的な西ヨーロッパフォント。このコード化は
PostScript の世界で 'ISO-Latin1' として知られているも
のです。
iso_8859_2 - 中央/東ヨーロッパで使用されるフォント
iso_8859_15 - ユーロ記号を含む iso_8859_1 の亜種
cp850 - OS/2 のコードページ
cp437 - MS-DOS のコードページ
koi8r - 良く使われる Unix のキリル文字コード化
一般に、コード化の設定は出力形式の設定の前に行なう必要があります。この コード化はどんな出力形式でもサポートされているとは限らず、そして出力形 式は要求されたどんな非標準文字も生成できなければいけません。PostScript と X11 出力形式はすべてのコード化をサポートしています。OS/2 Presentation Manager は `iso_8859_2` に対しては自動的にコードページ 912 に変更します。
`fit` の設定は、コマンド `fit` がその出力を行うファイルを定義します。 使用している gnuplot が使えるように作られていれば、このコマンドは当て はめのパラメータ誤差を変数に書き出すかどうかも制御できます。
書式:
set fit {logfile {"<filename>"}} {{no}errorvariables}
unset fit
show fit
引数 <filename> は、単一引用符か二重引用符で囲む必要があります。
ファイル名を指定しなかった場合、または `unset fit` を使用した場合は、 ログファイルはデフォルトの値である "fit.log"、または環境変数 `FIT_LOG` の値にリセットされます。
DOS と同様の OS のユーザは、以下のことに注意してください。文字 \ (バッ クスラッシュ) は 2 重引用符内では特別な意味を持つので、別なディレクト リのファイルを指定する場合は単一引用符で囲むか、またはそれぞれの \ を \\ と書く必要があります。または、DOS 上であっても、\ の代わりに / (フ ォワードスラッシュ) を使うこともできます。
与えられたログファイル名が / か \ で終っている場合、それはディレクトリ 名と解釈され、ログファイルはそのディレクトリの "fit.log" となります。
オプション `errorvariables` が ON にされると、`fit` コマンドで計算され たここの当てはめパラメータの誤差が、そのパラメータの名前に "_err" をつ けた名前のユーザ定義変数にコピーされます。これは主に、当てはめ関数とデ ータの描画グラフの上にパラメータとその誤差を参照用に出力するのに使われ ます。例えば:
set fit errorvariables
fit f(x) 'datafile' using 1:2 via a, b
print "error of a is:", a_err
set label 'a=%6.2f', a, '+/- %6.2f', a_err
plot 'datafile' using 1:2, f(x)
書式:
set fontpath {"pathlist1" {"pathlist2"...}}
show fontpath
パス名は単一のディレクトリ名、または複数のパス名のリストとして入力しま す。複数のパスからなるパスリストは OS 固有のパス区切り、例えば Unix で はコロン (':'), DOS//Windows/OS/2/Amiga ではセミコロン (';') 等で区切 ります。fontpath, save, `save set` コマンドは、可搬性のために OS 固有のパス区切りをスペース (' ') で置き換えます。ディレクトリ名がエ クスクラメーションマーク ('!') で終っている場合、そのディレクトリのサ ブディレクトリも検索されます。
環境変数 GNUPLOT_FONTPATH が設定されている場合、その内容は fontpath に追加されますが、それが設定されていない場合システムに依存したデフォル トの値が使用されます。最初にフォントパスを使ったときに、その幾つかのデ ィレクトリが存在するかテストされ、セットされます。よって、一番最初の fontpath, fontpath, fontpath や、埋め込みフォント を使用した場合の `plot`, `splot` は、少し時間がかかります。それを少し でも短くしたければ、環境変数 GNUPLOT_FONTPATH を設定してください。そう すればディレクトリのチェックは OFF になります。デフォルトのフォントパ スが何であるかは、fontpath で見ることができます。
しかし、fontpath は、ユーザ定義の fontpath と環境変数によるシス テム fontpath を別々に表示しますし、save, `save set` コマンドは、可 搬性の目的のためにユーザ定義の fontpath のみを保存します。
gd ライブラリを通じて TrueType フォントにアクセスできる出力ドライバも たくさんあります。これらのドライバに対するフォントの検索パスは、環境変 数 GDFONTPATH で制御されます。
座標軸の刻みの見出しは、コマンド `set format` で書式を設定できます。
書式:
set format {<axes>} {"<format-string>"}
set format {<axes>} {'<format-string>'}
show format
ここで、<axes> (軸) は `x`, `y`, `z`, `cb`, `xy`, `x2`, `y2`、または 何も指定しない (`xy` と同じ) かのいずれかです。刻みの見出しの文字列の 長さ ('printf' で整形された後の) は 100 文字まで、と制限されています。 書式文字列 (<format-string>) を省略した場合、それはデフォルトの "%g" になります。LaTeX ユーザにはよく "$%g$" が好まれます。空の文字列 "" を指定した場合、刻み自身は表示されますが見出しはつきません。すべての 刻みを消すには xtics や ytics を使用してください。
改行文字 (\n) も書式文字列で使えます。それを解釈させるには、単一引用符 (') でなく (") を使ってください。`syntax` の項も参照してください。
デフォルトの書式文字列は両軸とも "%g" ですが、"%.2f" や "%3.0em" など の書式が好まれることも多いでしょう。倍精度小数に対して 'printf' と出力 形式が受けつけることができる書式であればそれは正しく動作するでしょう。 他にもいくつかのオプションが追加されています。書式文字列が浮動小数に対 するもののようであれば `gnuplot` は妥当な文字列に変換しようとします。
"%" が頭につかない文字はそのまま表示されます。よって、書式文字列内に スペースや文字列などを入れることができます。例えば "%g m" とすれば、 数値の後に " m" が表示されます。"%" 自身を表示する場合には "%g %%" の ように 2 つ重ねます。
刻みに関するより詳しい情報については xtics を参照してください。 また、この方法で出力される数字にデフォルト以外の小数分離文字を使うやり 方については decimalsign を参照してください。 以下も参照。 エレクトロン (電子) デモ (electron.dem).
使用可能な書式 (時間/日付モードでない場合) は以下の通りです:
書式 説明
%f 固定小数点表記
%e, %E 指数表記; 指数の前に "e", "E" をつける
%g, %G %e (または %E) と %f の略記
%x, %X 16 進表記
%o, %O 8 進表記
%t 10 進の仮数部
%l 現在の対数尺の底を基数とする仮数部
%s 現在の対数尺の底を基数とする仮数部; 補助単位 (scientific power)
%T 10 進の指数部
%L 現在の対数尺の底を基数とする指数部
%S 補助単位の指数部 (scientific power)
%c 補助単位文字
%P πの倍数
補助単位 ('scientific' power) は、指数が 3 の倍数であるようなものです。 補助単位指数 (`"%c"`) の文字への変換は -18 から +18 までの指数に対して サポートされています。この範囲外の指数の場合、書式は通常の指数形式に 戻ります。
ほかに使うことのできる修飾詞 ("%" と書式指定子の間に書くもの) には、 次のいくつかがあります: "-" は数字を左詰めにし、"+" は正の数にも符号を つけ、"#" は小数点以下の数字が 0 だけであっても小数点をつけ、正の整数は 出力幅を定め、出力幅指定の直前の "0" (文字でなく数字) は先頭に空いた部分 を空白で埋める代わりに 0 で埋め、小数点の後に非負の整数を書いたものは 精度を意味します (整数の場合は最小桁、小数の場合は小数点以下の桁数)。
これらの全ての修飾詞をサポートしていないリリースの 'printf' もあるでし ょうし、逆にこれ以外のものをもサポートする 'printf' もあるでしょう。 疑わしい場合は、適切な資料を調べ、そして実験してみてください。
例:
set format y "%t"; set ytics (5,10) # "5.0" と "1.0"
set format y "%s"; set ytics (500,1000) # "500" と "1.0"
set format y "+-12.3f"; set ytics(12345) # "+12345.000 "
set format y "%.2t*10^%+03T"; set ytic(12345)# "1.23*10^+04"
set format y "%s*10^{%S}"; set ytic(12345) # "12.345*10^{3}"
set format y "%s %cg"; set ytic(12345) # "12.345 kg"
set format y "%.0P pi"; set ytic(6.283185) # "2 pi"
set format y "%.0f%%"; set ytic(50) # "50%"
set log y 2; set format y '%l'; set ytics (1,2,3)
#"1.0", "1.0", "1.5" と表示される (3 は 1.5 * 2^1 なので)
丸めと指数が必要となるような書式で 9.999 の様な数字が書かれる場合は 問題が起こることがあります。
軸のデータ型が日時データ (time/date) の場合、書式文字列は 'strftime' 関数 ('gnuplot' 外。"man strftime" としてみてください) に関する有効な 指定を行う必要があります。使える入力書式指定の一覧に関しては timefmt を参照してください。
日時データモード (time/date mode) では、次の書式が使用できます:
書式 説明
%a 曜日名の省略形 (Sun,Mon,...)
%A 曜日名 (Sunday,Monday,...)
%b, %h 月名の省略形 (Jan,Feb,...)
%B 月名 (January,February,...)
%d 日 (1--31)
%D "%m/%d/%y" の簡略形
%H, %k 時 (0--24)
%I, %l 時 (0--12)
%j その年の通算日 (1--366)
%m 月 (1--12)
%M 分 (0--60)
%p "am" または "pm"
%r "%I:%M:%S %p" の簡略形
%R "%H:%M" の簡略形
%S 秒 (0--60)
%T "%H:%M:%S" の簡略形
%U その年の通算週 (週は日曜日からと数える)
%w 曜日番号 (0--6, 日曜 = 0)
%W その年の通算週 (週は月曜日からと数える)
%y 西暦 (0-99)
%Y 西暦 (4 桁)
数字を表す書式では、これらの指定子 (% の後ろ、指定子の前) に "0" ("オー" でなく "ゼロ") をつけることで、先頭に空白ができる場合に空白の代わりに 0 で埋めることができ、また最小の出力幅を正の整数で指定することもできます (出力される数字を表示するのに指定した幅が足りない場合は無視されます)。 表示する文字の長さは 24 文字まで、という制限があり、長すぎた部分は切り 捨てられます。
例:
日時のデータが "76/12/25 23:11:11" の場合
set format x # デフォルトでは "12/25/76" \n "23:11"
set format x "%A, %d %b %Y" # "Saturday, 25 Dec 1976"
set format x "%r %D" # "11:11:11 pm 12/25/76"
日時のデータが "98/07/06 05:04:03" の場合
set format x "%1y/%2m/%3d %01H:%02M:%03S" # "98/ 7/ 6 5:04:003"
このコマンドの形式は批判されています。`set style function` を参照して ください。
`show functions` コマンドはユーザーが定義した関数とその定義内容を表示 します．
書式:
show functions
`gnuplot` における関数の定義とその使い方については `expressions` の項を 参照してください。 以下も参照 ユーザ定義関数でのスプライン (spline.dem) および 関数と複素変数を翼に使用 (airfoil.dem)。
コマンド `set grid` は格子線を描きます。
書式:
set grid {{no}{m}xtics} {{no}{m}ytics} {{no}{m}ztics}
{{no}{m}x2tics} {{no}{m}y2tics}
{{no}{m}cbtics}
{polar {<angle>}}
{layerdefault | front | back}
{ {linestyle <major_linestyle>}
| {linetype | lt <major_linetype>}
{linewidth | lw <major_linewidth>}
{ , {linestyle | ls <minor_linestyle>}
| {linetype | lt <minor_linetype>}
{linewidth | lw <minor_linewidth>} } }
unset grid
show grid
格子線は任意の軸の任意の主目盛/副目盛に対して有効/無効にでき、その主目 盛りと副目盛りに対する線種、線幅も指定でき、現在の出力装置がサポートす る範囲で、あらかじめ定義したラインスタイルを使用することもできます。
さらに、2 次元の描画では極座標格子も使うことができます -- 定義可能な 区間に対して、選択された目盛りを通る同心円と中心からの放射状の線が描か れます (その区間は angles の設定にしたがって度、またはラジアンで 指定します)。極座標格子は現在は極座標モードでは自動的には生成されない ことに注意してください。
`set grid` が描く前に、必要な目盛りは有効になっていなければなりません。 `gnuplot` は、存在しない目盛りに対する格子の描画の命令は単に無視します。 しかし、後でその目盛りが有効になればそれに対する格子も描きます。
副格子線に対する線種を何も指定しなければ、主格子線と同じ線種が使われま す。デフォルトの極座標の角度は 30 度です。
`front` を指定すると、格子線はグラフのデータの上に描かれます。`back` が指定された場合は格子線はグラフのデータの下に描かれます。`front` を使 えば、密集したデータで格子線が見えなくなることを防ぐことができます。デ フォルトでは `layerdefault` で、これは 2D 描画では `back` と同じです。 3D 描画のデフォルトは、格子とグラフの枠を 2 つの描画単位に分離し、格子 は後ろに、枠は描画データまたは関数の前に書きます。ただし、hidden3d モードでは、それがそれ自身の並び換えをしていますので、格子線の順番のオ プションは全て無視され、格子線も隠線処理にかけられます。これらのオプシ ョンは、実際には格子線だけでなく、border による境界線とその目盛 りの刻み (xtics 参照) にも影響を及ぼします。
z の格子線は描画の底面に描かれます。これは描画の周りに部分的な箱が描画 されている場合にはいいでしょう -- border を参照してください。
書式:
set hidden3d {defaults} |
{ {{offset <offset>} | {nooffset}}
{trianglepattern <bitpattern>}
{{undefined <level>} | {noundefined}}
{{no}altdiagonal}
{{no}bentover} }
unset hidden3d
show hidden3d
gnuplot の通常の表示とは異なり、隠線処理では与えられた関数、またはデー タの格子線を、実際の曲面がその曲面の背後にあって隠されている部分は見せ ないのと同じように処理します。これを可能にするためには、曲面は '格子状' (`splot datafile` 参照) である必要があり、またそれらは `with lines` か `with linespoints` で描かれていなければいけません。 hidden3d が有効なときは、格子線だけでなく、面部分や土台の上の等高線 (contour 参照) も隠されます。複数の面を描画している場合は、各曲 面は自分自身と他の曲面で隠される部分も持ちます。曲面上への等高線の表示 (surface) は機能しません。見出しと矢印は常に表示され、 影響を受けません。 グラフの説明 (key) も曲面に隠されることはありません。
関数値は格子孤立線の交点で評価されます。見ることの出来る線分を求めると きは個々の関数値、あるいはデータ点の間はそのアルゴリズムによって線形補 間されます。これは、hidden3d で描画する場合と `nohidden3d` で描画す る場合で関数の見かけが異なることを意味します。なぜならば、後者の場合関 数値は各標本点で評価されるからです。この違いに関する議論については、 samples と isosamples を参照してください。
曲面の隠される部分を消去するのに使われるアルゴリズムは、このコマンドで 制御されるいくつかの追加オプションを持っています。`defaults` を指定す ればそれらはすべて、以下で述べるようなデフォルトの値に設定されます。 `defaults` が指定されなかった場合には、明示的に指定されたオプションの みが影響を受け、それ以外のものは以前の値が引き継がれます。よって、それ らのオプションの値をいちいち修正することなく、単に `set {no}hidden3d` のみで隠線処理をオン/オフできることになります。
最初のオプション `offset` は '裏側' の線を描画する線の線種に影響を与え ます。通常は曲面の表裏を区別するために、裏側の線種は、表側の線種より一 つ大きい番号の線種が使われます。`offset <offset>` によって、その追加す る値を、デフォルトの 1 とは異なる増分値に変更できます。`nooffset` オプ ションは `offset 0` を意味し、これは表裏で同じ線種を使うことになります。
次のオプションは `trianglepattern <bitpattern>` です。<bitpattern> は 0 から 7 までの数字で、ビットパターンと解釈されます。各曲面は三角形に 分割されますが、このビットパターンの各ビットはそれらの三角形の各辺の表 示を決定します。ビット 0 は格子の水平辺、ビット 1 は格子の垂直辺、ビッ ト 2 は、元々の格子が 2 つの三角形に分割されるときの対角辺です。デフォ ルトのビットパターンは 3 で、これは全ての水平辺と垂直辺を表示し、対角 辺は表示しないことを意味します。対角辺も表示する場合は 7 を指定します。
オプション `undefined <level>` は、定義されていない (欠けているデータ または未定義の関数値) か、または与えられた x,y,z の範囲を超えているデ ータ点に適用させるアルゴリズムを指示します。そのような点は、それでも 表示されてしまうか、または入力データから取り除かれます。取り除かれて しまう点に接する全ての曲面要素は同様に取り除かれ、よって曲面に穴が生 じます。<level> = 3 の場合、これは `noundefined` と同じで、どんな点も 捨てられません。これは他の場所であらゆる種類の問題を引き起こし得るので 使わないべきです。<level> = 2 では未定義の点は捨てられますが、範囲を超 えた点は捨てられません。<level> = 1 では、これがデフォルトですが、範囲 を超えた点も捨てられます。
`noaltdiagonal` を指定すると、`undefined` が有効のとき (すなわち <level> が 3 でない場合) に起こる以下の場合のデフォルトでの取扱いを変更できま す。入力曲面の各格子状の部分は一方の対角線によって 2 つの三角形に分割 されます。通常はそれらの対角線の全てが格子に対して同じ方向を向いていま す。もし、ある格子の 4 つの角のうち一つが `undefined` 処理によりとり除 かれていて、その角が通常の方向の対角線に乗っている場合は、その両方の三 角形が取り除かれてしまいます。しかし、もしデフォルトの設定である `altdiagonal` が有効になっている場合、その格子については他方向の対角線 が代わりに選択され、曲面の穴の大きさが最小になるようにします。
`bentover` オプションは今度は `trianglepattern` とともに起こる別のこと を制御します。かなりしわくちゃの曲面では、下の ASCII 文字絵に書いたよ うに、曲面の 1 つの格子が 2 つに分けられた三角形の表と裏の反対側が見え てしまう場合 (すなわち、元の四角形が折り曲げられている ('bent over') 場合) があります:
C----B
元の 4 角形: A--B 表示される 4 角形: |\ |
("set view 0,0") | /| ("set view 75,75" perhaps) | \ |
|/ | | \ |
C--D | \|
A D
曲面の格子の対角辺が <bitpattern> の 2 bit によって見えるようにはなっ てはいない場合、上の対角辺 CB はどこにも書かれないことになり、それが結 果の表示を理解しにくいものにします。デフォルトで定義される `bentover` オプションは、このような場合それを表示するようにします。もしそうしたく ないなら、`nobentover` を選択してください。 以下も参照 隠線処理のデモ (hidden.dem) および 複雑な隠線のデモ (singulr.dem).
注意: コマンド historysize は、GNU readline ライブラリをリンクし てコンパイルされた場合のみ有効です。
書式:
set historysize <int>
unset historysize
historysize の値は、gnuplot の終了時に history の行を高々その行数まで に切り捨てるために使われます。デフォルトは 500 です。 historysize は history の切捨てを無効にしますので、history フ ァイルに書き出す行数の制限をしません。
関数を面として描画する場合の孤立線 (格子) の密度はコマンド isosamples で変更できます。
書式:
set isosamples <iso_1> {,<iso_2>}
show isosamples
各曲面グラフは <iso_1> 個の u-孤立線と <iso_2> 個の v-孤立線を持ちます。 <iso_1> のみ指定すれば、<iso_2> は <iso_1> と同じ値に設定されます。 デフォルトでは、u, v それぞれ 10 本の標本化が行われます。標本数をもっと 多くすればより正確なグラフが作られますが、時間がかかります。これらの パラメータは、データファイルの描画には何も影響を与えません。
孤立線とは、曲面の一つの媒介変数を固定して、もう一つの媒介変数によって 描かれる曲線のことです。孤立線は、曲面を表示する単純な方法を与えます。 曲面 s(u,v) の媒介変数 u を固定することで u-孤立線 c(v) = s(u0,v) が 作られ、媒介変数 v を固定することで v-孤立線 c(u) = s(u,v0) ができます。
関数の曲面グラフが隠線処理なしで描かれている場合、samples は 各孤立線上で標本化される点の数を制御します。samples と hidden3d も参照してください。等高線描画ルーチンは、関数の点の 標本化は各孤立線の交点で行われると仮定しているので、関数の曲面と等高線の 解像度を変更するときは、isosamples と同じように samples を 変更するのが望ましいでしょう。
コマンド key は描画された曲線の説明や表題を表示することを可能に します。
説明 (key) の内容、すなわち描画される個々のデータ集合や関数につける名 前、およびそれらグラフの曲線とグラフ上の点を表す記号からなるサンプルは、 `plot` (または `splot`) コマンドの `title`, with オプションにより決 定されます。より詳しい情報については `plot title`, with を参照 してください。
書式:
set key {on|off} {default}
{left | right | top | bottom | outside | below | <position>}
{Left | Right} {{no}reverse}
{samplen <sample_length>} {spacing <vertical_spacing>}
{width <width_increment>}
{height <height_increment>}
{{no}autotitles}
{title "<text>"} {{no}enhanced}
{{no}box { {linestyle | ls <line_style>}
| {linetype | lt <line_type>}
{linewidth | lw <line_width>}}}
unset key
show key
デフォルトでは説明 (key) はグラフの右上の角に置かれます。説明をグラフ の他の角、あるいはグラフの外の右や下に配置するために、`left`, `right`, `top`, `bottom`, `outside`, `below` といったキーワードが用意されていま す。これらは単独で、あるいは組み合わせて使います。
`set key off` か key によって説明表示なしに描画することができ ます。
説明中のラベル (名前) の行揃えは `Left`, `Right` (デフォルト) で指示し ます。ラベル文字列と曲線のサンプルは左右入れ替えることができます (`reverse`) し、 全体を枠で囲むこともできます (`box {...}`)。その枠の 線は、線種 (`linetype`), 線幅 (`linewidth`)、あるいは定義済のラインス タイル (`linestyle`) を指定することもできます。ただ、全ての出力装置が 線幅の選択をサポートしているとは限らないことに注意してください。
グラフ曲線のサンプルの線分の長さは `samplen` で指定できます。その長さ は目盛りの長さと、<sample_length>*(文字幅) の和として計算されます。 `sapmlen` は、グラフ上の点のサンプルの位置にも (もしサンプル線分自身が 書かれなくても) 影響を与えています。それは、点の記号はサンプル線分の中 央に書かれるためです。
行間の垂直スペースは、`spacing` で指定できます。その幅は、点のサイズ (pointsize) と垂直な目盛りのサイズと <vertical_spacing> の積になります。 この垂直スペースは、文字の高さよりも小さくはならないことが保証されてい ます。
<width_increment> は、文字列の長さに加えたり減らしたりする幅 (何文字分 か) を表す数値です。これは、説明に外枠を書き、ラベル文字列の文字数を調 節するときには役立つでしょう。`gnuplot` は外枠の幅を計算するときは、ラ ベル文字列の文字数を単純に数えるだけなので、それを修正するのに使えます。
<height_increment> は、説明の箱の高さに加えたり減らしたりする高さ (何 文字分か) を表す数値です。これは主に、説明の回りに箱を描く場合のための ものですが、他に、自動的に設定される説明の位置を <height_increment>/2 だけ垂直方向にずらすのにも使えます。
`plot` や `splot` で描画される全ての曲線は、デフォルトのオプション `autotitles` に従って表題 (title) がつけられます。表題の自動生成は、 `noautotaitle` で抑制できますがその場合、`(s)plot ... title ...` で明 示的に指定された表題のみが描かれることになります。
表題は説明の上につけることもできます (`title "<text>"`) - 単一引用符 (') と二重引用符 (") の違いについては `syntax` を参照してください。説 明の表題の行揃えは、グラフの表題の行揃えと同じものが使われます。
明示的に与えられた表題は、出力形式がサポートする拡張文字列属性を使って 出力されます。詳細は `enhanced text` を参照してください。そのデフォル トの挙動は `noenhanced` オプションで無効にできます。 key のデフォルトは、`on`, `right`, `top`, `Right`, `noreverse`, `samplen 4`, `spacing 1.25`, `title ""`, `nobox` です。説明の枠の線種は デフォルトではグラフ描画の外枠と同じものが使われます。`set key default` とするとデフォルトの設定に戻ります。
説明の位置 (<position>) は、以前のバージョンと同様単に x,y,z を指定し てもいいですが、その最初のサンプル行の座標の座表系を選択するための 4 つのキーワード (`first`, `second`, `graph`, `screen`) を頭につけること もできます。詳細は `coordinates` を参照してください。
説明は、1 行に 1 曲線分ずつの数行のまとまりとして書かれます。各行の右 側には (`reverse` を使っていれば左側には) その曲線と同じ種類の直線のサ ンプルが引かれ、他の側には `plot` コマンドから得られる文字列 (title) が置かれます。これらの行は、架空の直線が説明の左側と右側を分けるかのよ うに垂直に整列されます。コマンド key で指定する座標はこの架空の 線分の上の端の座標です。`plot` では直線の位置を指定するために x と y だけが使われ、`splot` では、x, y, z の値全てを使い、グラフを 2 次元面 へ投影するのと同じ方法を使って、架空の直線の 2 次元画面での位置を生成 します。
場合によってはこの説明の一部または全部が境界の外にはみ出すこともあり ます。この場合見出しなどと重なってしまうこともあり、また出力装置によ ってはエラーを生じることもあります。`outside` や `below` を使って説明 をグラフの外に出す場合は `gnuplot` は説明に余白を空けるためグラフは 多少小さくなります。右の外に出す場合は、その説明の横幅が可能な限り 小さくなるようにし、下の外に出す場合は、横幅が可能な限り大きくなる ようにします (その幅はラベルの長さによります)。そのようにして、可能な 限りグラフからは小さいスペースしか搾取しないようにしています。
TeX, PostScript, またはこれらと同等の、整形情報が文字列に埋め込まれる 出力を使う場合は、`gnuplot` は説明の位置合わせのための文字列の幅を 正しく計算できません。よって説明を左に置く場合は `set key left Left reverse` という組合せを使うのがいいでしょう。そうすれば説明の枠と枠内の すき間は文字列そのままの幅に合わせられます。
`splot` で等高線を書く場合、説明には等高線のラベルも表示されます。 これらのラベルの並び具合がうまくいかない、または別な位置に小数点を 置きたい場合はそのラベルの書式を指定できます。詳細は clabel を 参照してください。
例:
以下はデフォルトの位置に説明を表示します:
set key default
以下は説明を表示しなくします:
unset key
以下はデフォルトの (第一の) 座標系での (2,3.5,2) の位置に説明を表示 します:
set key 2,3.5,2
以下は説明をグラフの下に表示します:
set key below
以下は説明を左下角に表示し、テキストは左に行揃えで、タイトルをつけ、 線種 3 の外枠を書きます:
set key left bottom Left title 'Legend' box 3
書式:
set label {<tag>}
{ {"<label text>"{,<value>}} {, ...}} }
{at <position>}
{left | center | right}
{norotate | rotate {by <degrees>}}
{font "<name>{,<size>}"}
{front | back}
{textcolor <colorspec>}
{point <pointstyle> {offset x, y} | nopoint}
unset label {<tag>}
show label
位置 (<position>) は x,y か x,y,z のどちらかで指定し、座標系を選択する にはその座標の前に `first`, 'second', 'graph', 'screen' をつけるます。 詳細は `coordinates` の項を参照してください。
タグ (<tag>) は見出しを識別するための整数値です。タグを指定しなかった 場合未使用のもので最も小さい値が自動的に割り当てられます。現在の見出し を変更するときはそのタグと変更したい項目を指定して label コマン ドを使います。
<label text> には、そこに printf() で使われるような書式指定子を使うこ とによって、それで置き換えられる数字を入れることも可能です。その数字は その後に続く <value> で指定したものが使われます。同様の書式の柔軟性は、 目盛りの見出し (tic label) にも用意されています。詳細は `format specifiers` を参照してください。一つの見出し内で 2 つ以上の異 なる <value> を表示したければ、<label text> と <value> の幾つかの組を 指定してください。<value> は、定数式として取り扱われることに注意してく ださい。つまり、それが変数を含んでいる場合、その変数が後で変更されても ラベル文字列は変わりません。オプション decimalsign は、それが設 定されていれば、ラベル文字列内の数字の小数点もそれに書き換えられます。
デフォルトでは、指定した点 x,y,z に見出しの文章の左端が来るように配置 されます。x,y,z を見出しのどこに揃えるかを変更するには変数 <justification> を指定します。これには、`left`, `right`, `center` の いずれかが指定でき、それぞれ文章の左、右、真中が指定した点に来るよう に配置さるようになります。描画範囲の外にはみ出るような指定も許されま すが、座標軸の見出しや他の文字列と重なる場合があります。
`rotate` を指定するとラベルは縦書きになります (もちろん出力ドライバが 対応していれば、ですが)。`rotate by <degrees>` が与えられた場合は、そ れに適合している出力ドライバは指定された角度で文字列を書こうとしますが そうでない出力形式では、垂直な文字列として扱われます。
フォントとそのサイズは、出力形式がフォントの設定をサポートしていれば `font "<name>{,<size>}"` で明示的に選択できます。そうでない出力形式で は、デフォルトのフォントが使われます。
`front` が与えられると、見出しはデータのグラフの上に書かれます。`back` が与えられると (デフォルト)、見出しはグラフの下に書かれます。`front` を使うことで、密なデータによって見出しが隠されてしまうことを避けること が出来ます。
`textcolor <colorspec>` は文字列の色を変更します。`<colorspec>` は線種 か、あるいは pm3d カラーパレット (`splot` でのみ有効) への割当 のいず れかです。palette を参照してください。
`textcolor` は、`tc` と省略可能です。
`tc default` は、文字色をデフォルトにします。
`tc lt <n>` は、文字色を線種 <n> と同じものになります。
`tc palette z` は、見出しの z の位置に対応したパレット色になります。
`tc palette cb <val>` は、色見本 (colorbar) の <val> の色になります。
`tc palette fraction <val>` (0<=val<=1) は、[0:1] から palette の
灰色階調/カラーへの写像に対応した色になります。
<pointstyle> がキーワード `lt`, `pt`, `ps` とともに与えられると (style 参照)、与えられたスタイルと、与えられた線種の色で見出し位置に 点 (point) が描画され、見出し文字列は少し移動されます。その移動はデフ ォルトでは pointsize の単位で 1, 1 ですが、これはオプション `offset x, y` で制御できます。例: `offset 2, -3` は、見出し文字列を `position` で与えられた現在の座標位置から、水平方向には 2 * pointsize 垂直方向には -3 * pointsize だけ移動します。点の大きさも pointsize の設定によって変わります。このオプションは `mouse` 拡張された出力形式 でのラベルの配置に、デフォルトで使用されています。見出し文字列近くの点 の描画機能を off (これがデフォルト) にするには、`nopoint` を使用してく ださい。
もし一つ (あるいはそれ以上の) 軸が時間軸である場合、座標は timefmt の 書式にしたがって引用符で囲まれた文字列で与える必要があります。xdata と timefmt を参照してください。
EEPIC, Imagen, LaTeX, TPIC で出力する場合は、\\ を使うことで見出しを 改行させることができます。
例:
(1,2) の位置に "y=x" と書く場合:
set label "y=x" at 1,2
Symbol フォントのサイズ 24 の "シグマ" (Σ) をグラフの真中に書く場合:
set label "S" at graph 0.5,0.5 center font "Symbol,24"
見出し "y=x^2" の右端が (2,3,4) に来るようにし、タグ番号として 3 を使う 場合:
set label 3 "y=x^2" at 2,3,4 right
その見出しを中央揃えにする場合:
set label 3 center
タグ番号 2 の見出しを削除する場合:
unset label 2
全ての見出しを削除する場合:
unset label
全ての見出しをタグ番号順に表示する場合:
show label
x 軸が時間軸であるグラフに見出しを設定する例:
set timefmt "%d/%m/%y,%H:%M"
set label "Harvest" at "25/8/93",1
データと、新たに当てはめられたパラメータによる当てはめ関数を描画したい 場合、`fit` の後でかつ `plot` の前に以下を実行します:
set label 'a = %3.5g',par_a at 30, 15
set label 'b = %s*10^%S',par_b at 30, 20
見出し文字列を小さい点から少しだけ移動する場合:
set label 'origin' at 0,0 point lt 1 pt 2 ps 3 offset 1,-1
pm3d を使った 3 次元のカラー曲面上のある点の位置に、その z の値 (この 場合 5.5) に対応した色を見出し文字列につける場合:
set label 'text' at 0,0,5.5 tc palette z
コマンド lmargin は左の余白のサイズをセットします。詳細は margin を参照してください。
書式:
set loadpath {"pathlist1" {"pathlist2"...}}
show loadpath
パス名は単一のディレクトリ名、または複数のパス名のリストとして入力しま す。複数のパスからなるパスリストは OS 固有のパス区切り、例えば Unix で はコロン (':'), DOS//Windows/OS/2/Amiga ではセミコロン (';') 等で区切 ります。loadpath, save, `save set` コマンドは、可搬性のために OS 固有のパス区切りをスペース (' ') で置き換えます。
環境変数 GNUPLOT_LIB が設定されている場合、その内容は loadpath に追 加されますが、loadpath は、ユーザ定義の loadpath と環境変数によ るシステム loadpath を別々に表示しますし、save, `save set` コマンド は、可搬性の目的のためにユーザ定義の loadpath のみを保存します。
書式:
set locale {"<locale>"}
<locale> にはインストールされたシステムで使うことの出来る任意の言語を 指定できます。可能なオプションについてはシステムのドキュメントを参照し てください。デフォルトの値は環境変数 LANG から決定されます。
対数スケールは，x, y, z, x2, y2 の各軸について設定できます。
書式:
set logscale <axes> <base>
unset logscale <axes>
show logscale
ここで、<axes> (軸) は、`x`, `y`, `z`, `cb` の任意の順序、または `x2`, `y2` による組み合せが可能です。また、<base> は、対数スケールの底です。 <base> が指定されなかった場合は 10 になります。もし、<axes> が指定され なかった場合は、全部が指定されたことになります。logscale は、 指定した軸の対数スケールを解除します。
例:
x, z 両軸について対数スケールを設定する:
set logscale xz
y 軸について底 2 とする対数スケールを設定する:
set logscale y 2
pm3d plot 用に z と色の軸に対数スケールを設定する:
set logscale zcb
z 軸の対数スケールを解除する:
unset logscale z
データが `splot` に球面座標や円柱座標で与えられた場合、mapping コマンドは `gnuplot` にそれをどのように扱うかを指定するのに使われます。
書式:
set mapping {cartesian | spherical | cylindrical}
デフォルトではカーテシアン座標 (通常の x,y,z 座標) が使われます。
球面座標では、データは 2 つか 3 つの列 (またはその個数の using エン トリ) として与えられます。最初の 2 つは、angles で設定された単位 での方位角 (theta) と仰角 (phi) (すなわち "経度" と "緯度") とみなされ ます。半径 r は、もし 3 列目のデータがあればそれが使われ、もしなければ 1 に設定されます。各変数の x,y,z との対応は以下の通りです:
x = r * cos(theta) * cos(phi)
y = r * sin(theta) * cos(phi)
z = r * sin(phi)
これは、"極座標系" というより、むしろ "地学上の座標系" (緯度、経度) に 相当することに注意してください (すなわち、phi は z 軸となす角、という より赤道から計った仰角、になります)。
円柱座標では、データはやはり 2 つか 3 つの列で与えられ、最初の 2 つは theta (`set angle` で指定された単位の) と z と見なされます。半径 r は 球面座標の場合と同様、3 列目のデータがあればそれが、なければ 1 と設定 されます。各変数の x,y,z との対応は以下の通りです:
x = r * cos(theta)
y = r * sin(theta)
z = z
mapping の効果は、`splot` コマンド上の using によるフィルタで実現
することも可能ですが、多くのデータファイルが処理される場合は mapping
の方が便利でしょう。しかし、mapping を使っていても、もしファイルのデ
ータの順番が適切でなかったら結局 using が必要になってしまいます。
mapping は `plot` では何もしません。
world.dem: mapping のデモ。
自動的に計算される周囲の余白 (margin) はコマンド margin で変更で きます。margin は現在の設定を表示します。
書式:
set bmargin {<margin>}
set lmargin {<margin>}
set rmargin {<margin>}
set tmargin {<margin>}
show margin
<margin> の単位には、適切と思われる、文字の高さと幅が使われます。正の 値は余白の絶対的な大きさを定義し、負の値 (または無指定) は `gnuplot` によって自動計算される値を使うことになります。3 次元描画では、今のとこ ろ、左の余白 (lmargin) の設定のみが効力を持ちます。
描画の余白は通常目盛り、目盛りの見出し、軸の見出し、描画のタイトル、 日付、そして境界の外にある場合の key (グラフ見出し) のサイズ等を元に計 算されます。しかし、目盛りの刻みが境界でなく軸の方についている場合 (例 えば `set xtics axis` によって)、目盛りの刻み自身とその見出しは余白の 計算には含まれませんし、余白に書かれる他の文字列の位置の計算にも含まれ ません。これは、軸と境界が非常に近い場合、軸の見出しが他の文字列を上書 きする可能性を示唆します。
コマンド `set mouse` はマウス機能を有効にします。現在、pm, x11, ggi, windows の各出力ドライバがマウス拡張されています。2 種類のマウスモード があります。2 次元グラフモードは、2 次元グラフ、または地図型表示 (すな わち、z の回転角が 0, 90, 180, 270, 360 度の view での splot) で 動作し、グラフ上の位置の追跡、拡大表示、グラフの注釈づけ等を可能にしま す。`splot` による 3 次元グラフに対しては、グラフの視方向 (view) と拡 大縮小の変更が、マウスボタン 1 と 2 (によるドラッグ) で行えます。これ らのボタンにさらに <ctrl> キーを押すと、座標系のみが回転、拡大されます が、これは大きなデータに対して有用でしょう。ボタン 2 の垂直方向のドラ ッグを shift キーと同時に行うと、z 軸の一番下の位置 (ticslevel) を上下 します。
マウスは多重描画 (multiplot) モードでは無効ですが、multiplot で多重描画が無効にされれば、マウス機能は ON になり、直前の描画 (ほぼ replot で描画されるもの) に対して作用します。
書式:
set mouse [doubleclick <ms>] [nodoubleclick] \
[[no]zoomcoordinates] \
[[no]polardistance] \
[format <string>] \
[clipboardformat <int>/<string>] \
[mouseformat <int>/<string>] \
[[no]labels] [labeloptions <string>] \
[[no]zoomjump] [[no]verbose]
unset mouse
ダブルクリックの解像度はミリ秒 (ms) 単位で与えます。これは、ボタン 1 用のもので、現在のマウス位置を `clipboard` にコピーするのに使います。 シングルクリックでそれを行うようにするには、0 ms を指定してください。 デフォルトの値は 300 ms です。
オプション `zoomcoordinates` は、拡大 (zoom) の時に、ズームの枠の端に その座標を書くかどうかを決定し、デフォルトでは ON になっています。
オプション `polardistance` は、定規 (ruler) までの距離を極座標でも表示 するかどうかを決定します。これはデフォルトのキー割り当て '5' に対応し ます。
オプション `format` は、fprintf と似た書式文字列で、ドライバウィンドウ とクリップボード上で実数をどのように表示するかを決定します。デフォルト は "% #g" です。
`clipboardformat` と `mouseformat` は、ボタン 1 とボタン 2 の作用時
-- 座標をクリップボードへコピー、マウス位置に一時的に注釈をつける --
の文字列の書式用に使われます。これは、キー割り当て '1', '2', '3', '4' に対応します (ドライバのヘルプウィンドウ参照)。引数が文字列の場合、そ の文字列は C 言語の書式で、2 つの実数の指定子を含んでいる必要がありま す。例: `set mouse mouseformat "mouse = %5.2g, %10.2f"`。この文字列を 再び OFF にするには `set mouse mouseformat ""` としてください。
以下の書式が組み込まれています (書式 6 は書式文字列が既に指定されてい る場合のみ使用可):
0 カッコ内に実際の座標 例: [1.23, 2.45]
1 カッコ無に実際の座標 例: 1.23, 2.45
2 x == 時間書式 (timefmt) [(timefmt の設定), 2.45]
3 x == 日付 [31. 12. 1999, 2.45]
4 x == 時刻 [23:59, 2.45]
5 x == 日付 / 時刻 [31. 12. 1999 23:59, 2.45]
6 文字列で与えられた代替書式 ""
ボタン 2 の gnuplot のラベルを実際に得るには、オプション `labels` を使 用します (デフォルトでは `nolabels` で、ボタン 2 は 単に一時的な注釈を マウス位置に描画します)。ラベルは現在の `mouseformat` の設定に従って書 かれます。`labeloptions` は、コマンド label にどんなオプションを 渡すかを制御します。デフォルトは "pointstyle 1" で、これはラベル位置に 小さいプラス (`+`) を描画します。その点の大きさは、pointsize コ マンドで与えられることに注意してください。 ラベルは、ラベルの点の上で Ctrl キーを押してボタン 2 をクリックするこ とで消すことができます。実際のラベルの位置にどれ位近くでクリックしなけ ればいけないかの閾値も pointsize で決定されます。
オプション `zoomjump` が ON の場合、ボタン 3 によるズーム領域の選択を 開始すると、マウスポインタは自動的に少しだけずれた位置に移動します。 これは、ごく小さい (または空でさえある) ズーム領域を選択してしまうこと を避けるのに便利でしょう。デフォルトでは `zoomjump` は OFF です。
オプション `verbose` が ON の場合、実行時の報告コマンドが表示されます。 このオプションはドライバウィンドウ上で `6` を打つことで ON/OFF がスイ ッチできます。デフォルトでは `verbose` は OFF になっています。
ドライバウィンドウ上で 'h' を打つと、マウスとキー割当の短い説明が表示 されます。これは、ユーザ定義のキー割当、すなわち bind コマンドによる `hotkeys` (bind 参照) も表示されます。ユーザ定義の `hotkey` はデフォ ルトのキー割当を無効にします。
ドライバウィンドウ上で 'q' を打つと、ウィンドウを閉じます。このキーは bind コマンドでは無効にできません。 bind や label も参照してください。
X11 のマウスサポートは、標準入力が端末 (tty) から来る場合はデフォルト で ON にされますが、標準入力が tty から来てない場合 (例えばパイプの場 合)、マウスサポートは OFF にされます。パイプから gnuplot に入力すると きもマウスサポートを使いたい場合は、X11 ドライバが立ち上がる *前* にマ ウスを ON にしなければいけません。例えば、明示的なコマンド `set mouse` を起動時に指定した直後に X11 ドライバを起動します。注意: UNIX 特有の話 ですが、/dev/null のような特殊な入力デバイスは選択できません; そのよう なデバイスでマウスを ON にすると gnuplot はハングアップするでしょう。
x11 の出力形式のオプション `set term x11 <n>` を使って複数の X11 描画 ウィンドウが開いている場合、マウスコマンドとホットキーの機能をちゃんと 使えるのは現在の描画ウィンドウのみです。しかし、他のウィンドウも左下に マウスの座標を表示位はしてくれるでしょう。
コマンド multiplot は `gnuplot` を多重描画モードにします。これ は複数の描画を同じページ、ウィンドウ、スクリーンに表示するものです。
書式:
set multiplot
unset multiplot
出力形式 (terminal) によっては、コマンド multiplot が与えられ るまで何の描画も表示されないことがあります。この場合このコマンドにより ページ全体の描画が行なわれ、gnuplot は標準の単一描画モードになります。 それ以外の出力形式では、各 `plot` コマンドがそれぞれ描画を行ないますが その間で前の描画が消されてしまうことはありません。
定義済の見出しやベクトルは、各描画において、毎回現在のサイズと原点に従 って書かれます (それらが `screen` 座表系で定義されていない場合)。それ 以外の全ての `set` で定義されるものも各描画すべてに適用されます。もし 1 度の描画にだけ現われて欲しいものを作りたいなら、それが例えば日付 (timestamp) だとしたら、multiplot と multiplot で囲まれ たブロック内の `plot` (または `splot`, replot) 命令の一つを `set time` と `unset time` ではさんでください。
コマンド origin と size 各描画で正しい位置に設定する必要が あります。詳細は origin と size の項目を参照してください。
例:
set size 0.7,0.7
set origin 0.1,0.1
set multiplot
set size 0.4,0.4
set origin 0.1,0.1
plot sin(x)
set size 0.2,0.2
set origin 0.5,0.5
plot cos(x)
unset multiplot
は、cos(x) のグラフを、sin(x) の上に積み重ねて表示します。最初の size と origin に注意してください。これらはなくてもいいのですが それを入れておくことを勧めます。ある種の出力ドライバは、描画が一つでも 作られる前に全体の外枠の情報が参照できることを要求します。そして、上の やり方は、その外枠が最初の描画のための外枠ではなく、描画列全体を含む外 枠であるということを保証しています。 size と origin は全体の描画領域を参照しそれは各描画で利用 されます。描画境界を一列に揃えたいならば、margin コマンドで、境 界の外の余白サイズを同じサイズに揃えることが出来ます。その使用に関して は margin を参照してください。余白サイズは文字サイズ単位の絶対的 な数値単位を使用することに注意してください。よって残ったスペースに描か れるグラフは表示するデバイスの表示サイズに依存します。例えば、プリンタ とディスプレイの表示は多分違ったものになるでしょう。 以下も参照 multiplot のデモ (multiplt.dem)。
x2 (上) 軸の小目盛り刻みの印は mx2tics で制御されます。mxtics を参照してください。
x 軸の小目盛り刻みの印は mxtics で制御されます。mxtics によってそれを表示させなくすることが出来ます。同様の制御コマンドが各軸 毎に用意されています。
書式:
set mxtics {<freq> | default}
unset mxtics
show mxtics
これらの書式は mytics, mztics, mx2tics, my2tics, `mcbtics` に 対しても同じです。
<freq> は大目盛り間の、小目盛りによって分割される区間の数 (小目盛りの 数ではありません) です。通常の線形軸に対してはデフォルトの値は 2 か 5 で、これは大目盛りによって変化します。よって大目盛り間に 1 つ、または 4 つの小目盛りが入ることになります。`default` を指定することによって小 目盛りの数はデフォルトの値に戻ります。
軸が対数軸である場合、分割区間の数はデフォルトでは有意な数にセットされ ます (10 個の長さを元にして)。<freq> が与えられていればそちらが優先さ れます。しかし、対数軸では通常の小目盛り (例えば 1 から 10 までの 2, 3,
..., 8, 9 の刻み) は、9 つの部分区間しかありませんが、<freq> の設定は
10 とすることでそうなります。
小目盛りは大目盛りが一様に配置されている場合にのみ使えます。大目盛りは `set {x|x2|y|y2|z}tics` コマンドによって任意の場所に配置できるので、そ れが明示的に指定された場合には小目盛りは使えないことになります。
デフォルトでは小目盛りの表示は、線形軸ではオフで、対数軸ではオンになっ ています。その設定は、大目盛りに対する `axis|border` と `{no}mirror` の指定を継承します。これらに関する情報については xtics を参照し てください。
y2 (右) 軸の小目盛り刻みの印は my2tics で制御されます。mxtics を参照してください。
y 軸の小目盛り刻みの印は mytics で制御されます。mxtics を 参照してください。
z 軸の小目盛り刻みの印は mztics で制御されます。mxtics を 参照してください。
オフセットは、自動縮尺されたグラフの中のデータの周りに境界を置く仕組み を提供します。
書式:
set offsets <left>, <right>, <top>, <bottom>
unset offsets
show offsets
各オフセットは定数、または数式が使え、それらのデフォルトの値は 0 です。 左右のオフセットは x 軸と同じ単位で指定し、上下のオフセットは y 軸と同 じ単位で指定します。正のオフセットの値はグラフを指定された方向へ伸ばし ます。例えば正の下方向のオフセットは y の最小値をより小さな値にします。 許されている範囲での負のオフセットは、自動縮尺、あるいはクリッピングと の思いもよらぬ結果を生む可能性があります。
オフセットは `splot` では無視されます。
例:
set offsets 0, 0, 2, 2
plot sin(x)
この sin(x) のグラフの y の範囲は [-3:3] になります。それは、関数の y の範囲は [-1:1] に自動縮尺されますが、垂直方向のオフセットがそれぞ れ 2 であるためです。
コマンド origin はスクリーン上で曲面描画の原点を指定 (すなわち、 グラフとその余白) するのに使用します。その座標系はスクリーン座標系 (`screen`) で与えます。この座標系に関する情報については `coordinates` を参照してください。
書式:
set origin <x-origin>,<y-origin>
デフォルトでは、グラフは標準出力に表示されます。コマンド output は その出力を指定されたファイルやデバイスにリダイレクトします。
書式:
set output {"<filename>"}
show output
ファイル名は引用符で囲まなければなりません。ファイル名が省略された場合 は、直前の output で開かれたファイルがクローズされ、新たな出力が 標準出力 (STDOUT) に送られます。(もし、`set output "STDOUT"` とすると 出力は "STDOUT" という名前のファイルに送られるかもしれません ! ["かも しれない" というのは、例えば `x11` などの terminal (出力形式) では output が無視されるからです。])
MSDOS のユーザは次のことに注意すべきです: 文字 '\' は 2 重引用符の中で は特別な意味を持ちます。よって、別のディレクトリにあるファイル名を指定 する場合は単一引用符を用いるべきでしょう。 terminal と output の両方を指定する場合、terminal を 先に指定する方が安全です。それは、ある種の terminal では、OS が必要と するフラグをセットすることがあるからです。例えば、OS がファイルを開く ときに (礼儀良く) ファイルがフォーマットされているかどうかを知る必要が あるような OS などがそれ該当します。
popen 関数を持つようなマシン (Unix 等) では、ファイル名の最初を '|' と することにより、出力をシェルコマンドにパイプで渡すことが可能です。例え ば以下の通りです:
set output "|lpr -Plaser filename"
set output "|lp -dlaser filename"
MSDOS では、`set output "PRN"` とすると標準のプリンタに出力されます。 VMS では出力は任意のスプール可能なデバイスに送ることが出来ます。出力を DECnet 透過なタスクに送ることも可能で、それはある種の柔軟性を与えてく れます。
`set paramaetric` コマンドは `plot` および `splot` の意味を通常の関数描 画から媒介変数表示 (parametric) 関数描画に変更します．`unset parametric` を使えば元の描画モードに戻ります．
書式:
set parametric
unset parametric
show parametric
2 次元グラフにおいては，媒介変数表示関数はひとつの媒介変数に対する 2 つの関数で定められます．例としては plot sin(t),cos(t) とすることによっ て円が描けます (アスペクト比が正しく設定されていれば - size 参 照)．`gnuplot` は、両方の関数が媒介変数による `plot` のために与えられ ていなければエラーメッセージを出します。
3 次元グラフにおいては面は x = f(u,v), y = g(u,v), z = h(u,v) で定め られます．よって 3 つの関数を組で指定する必要があります．例としては， `cos(u)*cos(v),cos(u)*sin(v),sin(u)` とすることによって球面が描け ます．`gnuplot` は、3 つ全部の関数が媒介変数による `splot` のために 与えられていなければエラーメッセージを出します。
これによって表現できる関数群は，単純な f(x) 型の関数群の内包すること になります．なぜならば，2つ(3つ)の関数はx，y (，z)の値を独立に計算す る記述ができるからです．実際， t,f(t) のグラフは，一番目の関数のよう な恒等関数を用いて x の値が計算される場合に f(x) によって生成される グラフと等価です．同様に、3 次元での u,v,f(u,v) の描画は f(x,y) と 等価です。
媒介変数表示関数は、x の関数、y の関数 (、z の関数)の順に指定し、それ らは共通の媒介変数およびその変域で定義されることに留意して下さい。
さらに、`set parametric` の指定は、新しい変数変域を使用することを暗に 宣言します。通常の f(x) や f(x,y) が xrange、yrange (、zrange) を使用 するのに対して、媒介変数モードではそれに加えて、trange, urange, vrange を使用します。これらの変域は trange, urange, vrange によって直接指定することも、`plot` や `splot` で指定することもできます。 現時点では、これらの媒介変数のデフォルトの変域は [-5:5] となっています。 将来的にはこれらのデフォルト値をもっと有意なものに変更する予定です。
コマンド `show plot` は現在の描画コマンド、すなわち replot コマンド で再現される、直前に行われた `plot` や `splot` コマンドを表示します。
さらにコマンド`show plot add2history` は、この現在の描画コマンドを `history` に書き出します。これは、replot を使って直前の描画コマンド に曲線を追加した場合、そしてコマンド行全体をすぐに編集したい場合に便利 です。
pm3d は `splot` の一つのスタイルで、パレットに割り付けられた 3 次元、 4 次元データを、カラー/灰色の色地図/曲面として描画します。これは pm3d アルゴリズムを用いていて、これはデータが格子状であっても、データ走査毎 に点の数が違っているような非格子状のデータであっても、前処理することな く描画できます。
カラー曲面の描画は、palette で指定した色割当による多角形の塗りつぶし をサポートしている出力形式で行えます。現在サポートしている出力形式には 以下のものが含まれます。
画像出力ドライバ:
OS/2 Presentation Manager
X11
Linux VGA (vgagl)
GGI
Windows
AquaTerm (Mac OS X)
画像ファイル出力ドライバ:
PostScript
pslatex, pstex, epslatex
gif, png, jpeg
(x)fig
tgif
cgm
pdf
svg
まず、地図/曲面がどのように描かれるのかについて記述します。入力データ は、関数を評価して得られるかまたは file から得られます。 曲面は、走査 (孤立線) の繰り返しで構成されます。pm3d アルゴリズムでは、 最初の走査で検出された隣り合う 2 点と、次の走査で検出された他の 2 点の 間の領域が、これら 4 点の z の値 (または追加された 'color' 用の列の値、 using 参照) に従って灰色で (または カラーで) 塗られます。デフォルト では 4 つの角の値の平均値が使われますが、それはオプション `corners2color` で変更できます。それなりの曲面を描くためには、隣り合う 2 点の走査が交差してはいけなくて、近接点走査毎の点の数が違いすぎてはい けません。もちろん、最も良いのは走査の点の数が同じことです。他には何も 必要ではありません (例えばデータは格子状である必要もない)。他にもこの pm3d アルゴリズムは、入力された (計測された、あるいは計算された) 領域 の外には何も描かない、という長所があります。
曲面の色づけは、以下のような入力データに関して行われます:
1. 関数、または 1 つか 3 つのデータ列からなるデータの splot: 上に述べ た四辺形の 4 つの角の z 座標の平均値 (または `corners2color`) から、灰 色の範囲 [0:1] を与える zrange または cbrange の範囲 [min_color_z,max_color_z] への対応により、灰色/カラーの値が得られます。 この値は、直接灰色の色地図用の灰色の値として使うことができます。正規化 された灰色の値をカラーに対応させることもできます - 完全な説明は palette 参照。
2. 2 つか 4 つのデータ列からなるデータの splot: 灰色/カラーの値は、z の値の代わりに最後の列の座標を使って得られますので、色と z 座標が独立 なものになります。これは 4 次元データの描画に使うことができます。
他の注意:
1. 物理学者の間では、gnuplot の文書やソースに現われる 'iso_curve' (孤 立線) という言葉よりも、上で言及した '走査 (scan)' という言葉の方が使 われています。1 度の走査と他の走査の記録により色地図を評価する、という のはそういう意味です。
2. 'gray' や 'color' の値 (scale) は、滑らかに変化するカラーパレットへ の、連続な変数の線形写像です。その写像の様子は描画グラフの隣に長方形で 表示されます。この文書ではそれを "カラーボックス (colorbox)" と呼び、 その変数をカラーボックス軸の変数と呼びます。`set colorbox`, cbrange を参照してください。
3. pm3d の色づけを 3 次元曲面ではなく 2 次元描画に使うには、 `set view map` か `set pm3d map` を使用してください。
書式:
set pm3d
set pm3d {
{ at <bst combination> }
{ scansautomatic | scansforward | scansbackward }
{ flush { begin | center | end } }
{ ftriangles | noftriangles }
{ clip1in | clip4in }
{ corners2color { mean|geomean|median|c1|c2|c3|c4 } }
{ hidden3d <linestyle> | nohidden3d }
{ implicit | explicit }
{ map }
}
show pm3d
unset pm3d
オプションなしで pm3d とするとデフォルトの値を設定します。 それ以外の場合、オプションは任意の順に与えることができます。
色の曲面は底面か天井 (この場合は灰色/カラーの平面地図) か曲面上の点の z 座標 (灰色/カラー曲面) に描くことができます。その選択は、オプション `at` に、`b`, `t`, `s` の 6 つまでの組合せの文字列をつけて指定すること で行えます。例えば `at b` は底面のみに描画しますし、`at st` は最初に曲 面に描いて次に天井面に色地図を描きますし、`at bstbst` は ... 真面目な 話、こんなものは使いません。
塗られた四辺形は、次から次へと描画されて行きます。曲面を描画する場合 (`at s`)、後の四辺形が前のものに重なり (上書きし) ます (gnuplot は塗ら れた多角形の網の重なりの相互作用を計算するような仮想現実ツールではあり ません)。
最初に走査されるデータが最初に描くか最後に描くかを切替えるスイッチオプ ション `scansforward` と `scansbackward` を試してみてください。デフォ ルトは `scansautomatic` で、これは gnuplot に走査の順を推測させます。
2 回の連続する走査で点の数が同じでなかった場合、四辺形の点の取り始めを、 両方の走査の最初から (`flush begin`) にするか、最後から (`flush end`) にするか、真中から (`flush center`) にするかを決定しなければいけません。 `flush (center|end)` は `scansautomatic` とは両立せず、よって `flush center` または `flush end` を指定して `scansautomatic` が設定さ れた場合、それは無言で `scansforward` に変更されます。
2 回の連続する走査で点の数が同じでなかった場合、個々の走査で点が足りな い場合に、走査の最後に色三角形を描くかどうかをオプション `ftriangles` は指示します。これは滑らかな色地図の境界を描くのに使われます。
四辺形の x,y 座標に関するクリッピングは 2 つの方法で行われます。 `clip1in`: 各四辺形の全ての 4 点が定義されていなければならず、少なくと もそのうちの 1 点が x, y の範囲におさまっていなければなりません。 `clip4in`: 各四辺形の全ての 4 点が x, y の範囲におさまっていなければな りません。
描画される各 pm3d 四辺形には一つの灰色/カラー値が対応します (4 頂点間 で滑らかなカラー変化は起こりません)。その値は、`corners2color <option>` に従って周囲の角の z 座標から計算されます。<option> は 'mean' (デフォ ルト)、'geomean', 'median' で、曲面のカラーの滑らかさに幾つかの種類を 与えます。これらは鋭敏な、あるいは急激なピーク値を持つようなピクセルイ メージや色地図を作るときには必要ありません。そのような場合には、むしろ オプション 'c1', 'c2', 'c3', 'c4' を使って、四辺形の色の割当にただ一つ の角の z 座標を使うようにすればいいでしょう。どの角が 'c1' に対応する のかを知るためには何回か実験してみる必要があるでしょう。その向きは描画 の方向に依存しています。pm3d アルゴリズムは、カラー曲面を入力データ点 の範囲の外には描かないので、オプション 'c<j>' は、格子の 2 つのへりに 沿ったピクセルが、どの四辺形の色にも寄与しない、という結果をもたらしま す。例えば、pm3d アルゴリズムを 4x4 のデータ点の格子に適用するスクリプ ト `demo/pm3d.dem` (是非見てください) では、(4-1)x(4-1)=9 色しかない長 方形が生成されます。
与えられた節点に対して、その周りの 4 つの節点の平均化された (x,y) 座標 から角を得て四辺形を作って、その四辺形を節点の色で塗る、といったような 他の描画アルゴリズムが将来実装されるかもしれません。
z の値の範囲と曲面の色の値の範囲は、z と cb に関する `set log` 同様、 zrange と cbrange によって独立に調整し得ることに注意して ください。色地図は cb 軸のみで調節されます。`set view map` と `set colorbox` も参照してください。
オプション hidden3d は、線種 (linestyle) を引数に取りますが、それは `set style line ...` で生成しなければなりません (その線種は pm3d の設 定時には存在している必要はありませんが、描画時には必要です)。これが設 定されると、線は隠線処理を考慮に入れながら、指定された線種で描画されま す。これは、hidden3d コマンドを使うよりもはるかに効果的で、これ は実際に隠線処理を計算することはしませんが、塗りつぶされた多角形を正し い順序で描いて行きます。よって、pm3d を使う場合のお勧めの選択は以下の 通りです:
set pm3d at s hidden3d 100
set style line 100 lt 5 lw 0.5
unset hidden3d
unset surf
splot x*x+y*y
従来、このコマンドに {transparent|solid} のオプションが用意されていま したが、現在はそれらはそれぞれ `set grid {front|layerdefault}` で行な うことができます。
`set pm3d map` は `set pm3d at b`; `set view map`; pm3d; pm3d; を省略したものです。これは、`set view map` がな かったころの旧バージョンへの互換性のためのものです。入力データ点をフィ ルタするための zrange、および色の範囲の変更用の cbrange を注意して 適切に使用してください。`set (no)surface` も 効果 (副作用 ?) があるよ うです。
色づけの設定はカラーボックスの描画と同様に palette で決定されま す。一つの描画では一つのパレットのみが存在し得ます。いくつもの曲面を 異なるパレットで描画するには、origin と size を固定して `mutiplot` を使うことで行えます。出力ドライバが利用できる色を使い尽くしてしまう場 合には `set palette maxcolors` を使うことを忘れずに。
オプション `implicit` が ON (デフォルト) の場合、全ての曲面の描画が追 加的にデフォルトの型で行われます。例えば
splot 'fred.dat' with lines, 'lola.dat' with lines
は、両方の描画を追加的に pm3d 曲面で描きます。 オプション `implicit` が OFF (または `explicit` が ON) の場合、属性 pm3d が指定された描画のみが pm3d 曲面として描画されます。例えば
splot 'fred.dat' with lines, 'lola.dat' with pm3d
は、'freq.dat' は線で (線のみで) 描画され、'lola.dat' は pm3d 曲面とし て描かれます。 `explicit` が ON の場合はデフォルトのスタイルを pm3d に変更すること もできます。例:
set style data pm3d
いくつかの描画においては、それらはコマンドラインで与えられた順に描画さ れることに注意してください。これは特に、以前の描画を上書きしてそれで一 部を隠してしまう可能性がある、曲面の塗りつぶしに関して関心を持たれるこ とです。
`splot` コマンドライン上で pm3d が指定されている場合はオプショ ン `at` も使えます。以下の描画は、異なった高さで 3 つのカラー曲面を描き ます:
set border 4095
set pm3d at s
splot 10*x with pm3d at b, x*x-y*y, x*x+y*y with pm3d at t
palette, cbrange, `set colorbox`, pm3d, そしてもちろ
んデモファイル `demo/pm3d.dem` も参考になるでしょう。
パレットは、pm3d で、カラー等高線や多角形、カラーヒストグラム、色勾 配の背景、その他実装されている、あるいは実装されるものの塗りつぶしで使 われる、色の記憶場所です。ここではそれは滑らかで "連続的な" カラーや灰 色階調のパレットを意味しますが、それを単にパレットと呼ぶことにします。
カラーパレットは、多角形の色の塗りつぶしと滑らかな色のパレットをサポー トした出力形式を必要とし、それは現在、pm3d で一覧表示される出力形式 で使用可能です。色の値の範囲は、cbrange と `set log cb` で独立に 調整可能です。カラーパレット全体は `colorbox` 中に表示されます。
書式:
set palette
set palette {
{ gray | color }
{ gamma <gamma> }
{ rgbformulae <r>,<g>,<b>
| defined { ( <gray1> <color1> {, <grayN> <colorN>}... ) }
| file '<filename>' {datafile-modifiers}
| functions <R>,<G>,<B>
}
{ model { RGB | HSV | CMY | YIQ | XYZ } }
{ positive | negative }
{ nops_allcF | ps_allcF }
{ maxcolors <maxcolors> }
}
show palette
show palette palette <n> {{float | int}}
show palette gradient
show palette fit2rgbformulae
show palette rgbformulae
show palette colornames
palette は (すなわちオプションなしでは) デフォルトの値を設定しま
す。それ以外の場合、オプションは任意の順に与えることができます。
palette は、現在のパレットの属性を表示します。
`show palette gradient` は、パレットの勾配 (gradient) の定義が (それが 適切であれば) 表示されます。rgbformulae は、定義済で利 用できる、灰色値からカラーへの変換公式が表示されます。 `show palette colornames` は実装されている色名を表示します。
`show palette palette <n>` は、<n> 個の離散的な色を持つパレットの、現 在のパレットの設定によって計算される RGB の値の組とパレットの表を、画 面、または output で指定されたファイルに書き出します。デフォルト の広い表は、追加のオプション float または int によって、3 列の [0..1] の実数値だけにするか [0..255] の整数値だけにするかをそれぞれ指定できま す。この方法で gnuplot のカラーパレットを、Octave のような他の画像アプ リケーションに渡すことができます。このようなテキスト形式の RGB の一覧 表に加え、palette コマンドにより、グラフィック的に現在のパレッ トの R,G,B の状態を鑑賞することもできます。
以下のオプションは、色付けの属性を決定します。
このパレットを使用する図は、`gray` か `color` になります。例えば、 pm3d カラー曲面では、範囲 [min_z,max_z] が灰色の範囲 [0:1] に対応し ていて、微小曲面四辺形の 4 つの角の z 座標の平均値をこの範囲の中に対応 させることで各微小部分の灰色の値 (gray) が得られます。この値は、灰色階 調の色地図での灰色の値として直接使うことができますし、カラーの色地図で は、その灰色の値から (R,G,B) への変換、すなわち [0:1] から ([0:1],[0:1],[0:1]) への写像が使われます。
基本的に、2 種類の異なる写像方式が利用可能です: 1 つは灰色からカラーへ の解析的な公式、もう一つは離散的な対応表の補間によるものです。 rgbformulae と `functions` が解析的な公式用で、`defined` と file が 補間表用です。rgbformulae は postscript 出力のサイズを小さくすること ができます。
コマンド `show palette fit2rgbformulae` は、現在の palette に最 も良く対応する rgbformulae を見つけ出します。当然、それ は rgbformulae パレット以外に対しても意味を持ちます。このコマンドは主 に、パレットの rgbformulae 定義が gnuplot と同じ物を使っている外部プロ グラム、例えば zimg などにとって有用です。
`set palette gray` は、灰色階調のみのパレットにし、rgbformulae, `defined`, file, `functions` はカラーパレットにします。灰色パレット から直前のカラーパレットへ、`set palette color` で簡単に復帰できます。
`set palette gamma <gamma>` による自動的なガンマ補正は、灰色のパレット (`set palette gray`) のみに行われます。灰色階調への線形写像は gamma=1 に相当します (palette 参照)。カラーパレットに対してはガンマ値は 無視されます。
ほとんどの出力形式は、有限個の色数しかサポートしていません (例えば gif では 256 個)。デフォルトでは、パレットは、gnuplot のデフォルトの線種の 色の宣言の後に残ったものが全て pm3d 用に割り当てられます。よって、出力 形式が利用できる色の場所がなくなってしまった場合、multiplot は失敗し てしまうでしょう。その場合、`set palette maxcolors <maxcolors>` で適当 に小さい値を設定すべきです。このオプションは、z=定数の高低を離散個に分 割し、よって等高線の疑似的な塗りつぶしを行うことにも使えます。デフォル トの値は 0 で、これは出力形式のパレットの残りの全てを割り当てる、ある いは正確な RGB への対応を使用することを意味します。
RGB 色空間が作業を行うのに常にもっとも有用な色空間であるとは限らない、 という理由で、色空間は `model` を使うことで、`RGB`, `HSV`, `CMY`, `YIQ`, `XYZ` のいずれかに変更できます。RGB 以外の色空間では `defined` の表で色名を使うと、それはおかしな色になります。全ての説明は RGB 色空 間用に書いてありますが、それぞれの色空間で、例えば `R` は `H`, `C`, `Y`, `X` のことを意味することに注意してください (`G`, `B` も同様)。
全ての色空間で、全ての値は [0,1] に制限されています。
RGB は赤、緑、青を、CMY は水色 (Cyan)、紫 (Magenta)、黄 (Yellow) を、 HSV は色相 (Hue)、彩度 (Saturation)、明度 (Value) をそれぞれ意味します。 YIQ は 全米商業カラーテレビ放送協会 (the U.S. Commercial Color Television Broadcasting) の使ったカラーモデルで、RGB 記録方式を元にし ていますが、白黒テレビに対する後方互換性を持っています。XYZ は CIE ('Commission Internationale de l'Eclairage'; 国際照明委員会) が定義し た色モデルの 3 つの原刺激値です。 色モデルのより詳しい情報については以下を参照してください: http://www.cs.rit.edu/~ncs/color/glossary.htm および http://cs.fit.edu/wds/classes/cse5255/cse5255/davis/index.html
RGB の色空間では、いくつかの良い割り当て公式があります:
7,5,15 ... 伝統的 pm3d (黒-青-赤-黄)
3,11,6 ... 緑-赤-紫
23,28,3 ... 海 (緑-青-白); 他の組み合わせも試してみてください
21,22,23 ... 温度色 (黒-赤-黄-白)
30,31,32 ... 白黒のカラー表示化 (黒-青-紫-黄-白)
33,13,10 ... 虹 (青-緑-黄-赤)
34,35,36 ... AFM 温度色 (黒-赤-黄-白)
HSV 色空間でのフルカラーパレット:
3,2,2 ... 赤-黄-緑-水色-青-紫-赤
rgbformulae という名前で呼ばれていても、例の通り、それらの関数は実際
には <H>,<S>,<V> または <X>,<Y>,<Z>, ... といった色の成分を決定するか
もしれないということに注意してください。
図の色を反転させるには `positive` や `negative` を使ってください。
他の色体系に対する最も良い rgbformulae の集合は、以下のコマンドで見つ けることができることを覚えておいてください。
show palette fit2rgbformulae
灰色から RGB への対応は `defined` を使うことで手動で設定できます: 色勾 配 (gradient) は RGB の値を与えるために定義され使用されます。勾配は、 [0,1] の灰色値から [0,1]x[0,1]x[0,1] の RGB 空間への、区分的に線形な写 像です。その線形補間に使われる灰色値と RGB 値の組を指定する必要があり ます:
書式:
set palette defined { ( <gray1> <color1> {, <grayN> <colorN>}... ) }
<grayX> は [0,1] に割り当てられるべき灰色値で、<colorX> はそれに対応す る RGB 色です。カラー値は 3 種類の方法で指定することができます:
<color> := { <r> <g> <b> | '<color-name>' | '#rrggbb' }
赤、緑、青に対応する空白で区切られた 3 つの値 (それぞれ [0,1] 内)、引 用符でくくられた色名、または引用符でくくられた X 形式の指定方式、のい ずれかです。勾配の定義では、これらの 3 種の型を自由に組み合わせること ができますが、色空間として RGB でないものが選択された場合色名 "red" は 少し違ったものになるでしょう。使用できる色名は `show palette colornames` でその一覧を見ることができます。
<r> と書いても、HSV 色空間ではそれは <H> 成分を、CIE-XYZ 空間では <X> を、といったように選択されたカラーモデルに依存して意味が違うことに注意 してください。
<gray> の値は実数の昇順に並べる必要があります。その列の値は自動的に [0,1] に変換されます。
カッコつきの勾配の定義なしで `set palette defined` とした場合、RGB 色 空間にし、あらかじめ設定されたフルスペクトル色勾配を使用します。勾配を 表示するには `show palette gradient` を使用してください。
例:
灰色のパレット (役に立たないが教訓的な) を生成するには:
set palette model RGB
set palette defined ( 0 "black", 1 "white" )
青黄赤のパレット (全てが等価の) を生成するには:
set palette defined ( 0 "blue", 1 "yellow", 2 "red" )
set palette defined ( 0 0 0 1, 1 1 1 0, 2 1 0 0 )
set palette defined ( 0 "#0000ff", 1 "#ffff00", 2 "ff0000" )
虹のようなパレットを生成するには:
set palette defined ( 0 "blue", 3 "green", 6 "yellow", 10 "red" )
HSV 色空間でのフルカラースペクトル:
set palette model HSV
set palette defined ( 0 0 1 1, 1 1 1 1 )
set palette defined ( 0 0 1 0, 1 0 1 1, 6 0.8333 1 1, 7 0.8333 0 1)
あまり色を使わないパレットを生成するには:
set palette model RGB maxcolors 4
set palette defined ( 0 "blue", 1 "green", 2 "yellow", 3 "red" )
'交通信号' (滑らかではなく gray = 1/3, 2/3 で跳びを持つ):
set palette model RGB
set palette defined (0 "dark-green", 1 "green", 1 "yellow", \
2 "dark-yellow", 2 "red", 3 "dark-red" )
色の割り当ての R(gray), G(gray), B(gray) の 3 つの関数を与えるには `set palette functions <Rexpr>, <Gexpr>, <Bexpr>` を使ってください。 それらの 3 つの関数の変数は、[0,1] の値を取る変数 `gray` であり、その 値も [0,1] の中に取る必要があります。 <Rexpr> は、HSV 色空間が選択されている場合は、H の値を表す式でなければ いけないことに注意してください (他の式、または他の色空間でも同様です)。
例:
フルカラーパレットを生成するには:
set palette model HSV functions gray, 1, 1
黒から金色への良いパレット:
set palette model XYZ functions gray**0.35, gray**0.5, gray**0.8
ガンマ補正の白黒のパレット:
gamma = 2.2
color(gray) = gray**(1./gamma)
set palette model RGB functions color(gray), color(gray), color(gray)
例によって、<filename> が `'-'` の場合は、データがインライン形式で引き 続いて与えられ、一つの `e` のみの行でそれが終了することを意味します。
勾配 (gradient) を表示するには `show palette gradient` を使用してくだ さい。
例:
RGB のパレットを [0,255] の範囲で読み込む:
set palette file 'some-palette' using ($1/255):($2/255):($3/255)
等距離の虹色 (青-緑-黄-赤) パレット:
set palette model RGB file "-"
0 0 1
0 1 0
1 1 0
1 0 0
e
灰色の配色に対するガンマ補正は `set palatte gamma <gamma>` で ON にで きます。<gamma> のデフォルトは 1.5 で、これは多くの出力形式に適切な値 です。
カラーの配色に対しては gnuplot では自動的なガンマ補正は行いません。し かしガンマ補正は簡単に実装できます。ここに例として、ガンマの値の少し異 なる赤、緑、青の成分に、明示的な関数を与えた灰色階調画像の例を紹介しま す。
例:
set palette model RGB
set palette functions gray**0.64, gray**0.67, gray**0.70
補間された勾配を使ってガンマ補正を行うには、適当なカラーに中間の値を指 定します。
set palette defined ( 0 0 0 0, 1 1 1 1 )
の代わりに例えば以下を指定してください:
set palette defined ( 0 0 0 0, 0.5 .73 .73 .73, 1 1 1 1 )
または、線形補間が "ガンマ補正" の補間に十分良く適合するまでより良い中 間の点を探してください。
postscript ファイルのサイズを小さくする目的で、灰色の輝度値、そして全 てではないいくつかの計算された RGB の輝度値がそのファイル中に書かれま す。成分関数は postscript 言語で直接コード化され、pm3d の描画の直前に ヘッダとしておかれます。/g や /cF の定義を参照してください。通常その定 義をその中に書くことは、3 つの式のみが使われる場合に意味を持ちます。し かし、multiplot やその他の理由で postscript ファイル中のその変換関数を 直接手で編集したいと思うかも知れません。これがデフォルトのオプション `nops_allcF` です。オプション `ps_allcF` を使うと、全ての公式の定義が postscript ファイル中に書かれます。一つのグラフ中で、異なる曲面に異な るパレットを持たせたいという目的で postscript ファイルを編集したい場合 に、このオプションに関心を持つでしょう。その機能は、origin と size を固定して multiplot を使うことで実現できるでしょう。
pm3d 色地図が、格子状、あるいはほぼ規則正しいデータから postscript フ ァイルとして描画された場合、gnuplot と同時に配布される awk スクリプト `pm3dCompress.awk` を使うことで、この postscript ファイルのサイズをほ ぼ 50% 位まで小さくすることができます。このファイルを文書に取り込む場 合、あるいは低速のプリンタに大きなファイルを印刷する前などに、この機能 に関心を持つことでしょう。使用法は以下の通りです:
awk -f pm3dCompress.awk thefile.ps >smallerfile.ps
pm3d 色地図が四角形の格子状データから postscript ファイルとして描画さ れた場合、同時に配布される awk スクリプト `pm3dConvertToImage.awk` を 使うことで、そのサイズを更に小さくすることができます。使用法:
awk -f pm3dConvertToImage.awk <thefile.ps >smallerfile.ps
postscript 出力の灰色階調をカラーへ、またはその逆、そして <maxcolors> の定義などを、手動で変更することができます。
コマンド pointsize は描画で使われる点の大きさを変更します。
書式:
set pointsize <multiplier>
show pointsize
デフォルトは 1.0 倍です。画像データ出力では、大きいポイントサイズの方 が見やすいでしょう。
一つの描画に対するポイントサイズは `plot` コマンドの上でも変更できます。 詳細は with を参照してください。
ポイントサイズの設定は、必ずしも全ての出力形式でサポートされているわけ ではないことに注意してください。
コマンド `set polar` はグラフの描画方法を xy 直交座標系から極座標系に 変更します。
書式:
set polar
unset polar
show polar
version 3.7 では、極座標モードにおいていくつか変更がなされ、よって、 version 3.5 やそれ以前の版用のスクリプトには修正が必要になるでしょう。 主な変更は、仮変数 t が角度として使われるようになったことで、それによ り x と y の値の範囲が独立に制御できるようになりました。その他の変更は 以下の通りです: 1) 目盛りはもう 0 軸に自動的にはつきません - `set xtics axis nomirror`; `set ytics axis nomirror` を使ってください 2) 格子が選択されてもそれは自動的に極座標には従いません - `set grid polar` を使ってください 3) 格子は角度に関してはラベル付けされません - 必要なら label を使ってください
極座標モードでは、仮変数 (t) は角度を表します。t のデフォルトの範囲は [0:2*pi] ですが、単位として度が選択されていれば [0:360] となります (angles 参照)。
コマンド `unset polar` は描画方法をデフォルトの xy 直交座標系に戻しま す。
`set polar` コマンドは `splot` ではサポートされていません。`splot` に 対する同様の機能に関しては mapping を参照してください。
極座標モードでは t の数式の意味は r=f(t) となり、t は回転角となります。 trange は関数の定義域 (角度) を制御し、xrange と yrange はそれぞれグラ フの x,y 方向の範囲を制御することになります。これらの範囲と rrange は 自動的に設定されるか、または明示的に設定できます。これらすべての `set range` コマンドの詳細に関しては xrange の項を参照してくださ い。
例:
set polar
plot t*sin(t)
plot [-2*pi:2*pi] [-3:3] [-3:3] t*sin(t)
最初の `plot` はデフォルトの角度の範囲の 0 から 2*pi を使います。半径 とグラフのサイズは自動的に縮尺されます。2 番目の `plot` は角度の定義域 を拡張し、グラフのサイズを x,y のいずれの方向にも [-3:3] に制限します。
`set size square` とすると `gnuplot` はアスペクト比 (縦横の比) を 1 に するので円が (楕円でなく) 円に見えるようになります。 以下も参照 極座標のデモ (polar.dem) および 極座標データの描画 (poldat.dem)。
コマンド `set print` は `print` コマンドの出力をファイルにリダイレクト します。
書式:
set print
set print "-"
set print "<filename>"
set print "<filename>" append
set print "|<shell_command>"
"<filename>" がない場合は出力は <STDERR> になります。"-" という <filename> は <STDOUT> を意味します。`append` フラグはファイルを追加 (append) モードで開くことを意味します。パイプをサポートするプラットフ ォーム上では、<filename> が "|" で始まっていたら、<shell_command> への パイプが開かれます。
コマンド rmargin は右の余白のサイズをセットします。 詳細は margin を参照してください。
コマンド rrange は極座標モードのグラフの半径方向の範囲を設定しま す。詳細は xrange を参照してください。
関数、またはデータの補間に関するサンプリング数はコマンド samples で変更できます。
書式:
set samples <samples_1> {,<samples_2>}
show samples
デフォルトではサンプル数は 100 点と設定されています。この値を増やすと より正確な描画が出来ますが遅くなります。このパラメータはデータファイル の描画には何の影響も与えませんが、補間/近似のオプションが使われている 場合はその限りではありません。2 次元描画については smooth を、 3 次元描画に関しては dgrid3d を参照してください。
2 次元のグラフ描画が行なわれるときは <samples_1> の値のみが関係します。
隠線処理なしで曲面描画が行なわれるときは、samples の値は孤立線毎に評価 されるサンプル数の指定になります。各 v-孤立線は <samples_1> 個のサンプ ル点を持ち、u-孤立線は <samples_2> 個のサンプル数を持ちます。<samples_1> のみ指定すると、<samples_2> の値は <samples_1> と同じ値に設定されます。 isosamples の項も参照してください。
コマンド size は描画出力の大きさを拡大縮小します。
書式:
set size {{no}square | ratio <r> | noratio} {<xscale>,<yscale>}
show size
<xscale> と <yscale> は描画全体の拡大の倍率で、描画全体とはグラフと余 白の部分を含みます。
`ratio` は、指定した <xscale>, <yscale> の描画範囲内で、グラフのアスペ クト比 (縦横比) を <r> にします (<r> は x 方向の長さに対する y 方向の 長さの比)。
<r> の値を負にするとその意味は違って来ます。<r>=-1のとき，x軸，y軸の双 方の単位(つまり1)の目盛の長さが同一になるよう設定されます．(例えば地理 データ表示に向き)．<r>= -2のとき，y軸の単位目盛の長さはx軸の単位目盛の 長さの2倍に設定されます．<r>が負の値に関して以下同様です．
`gnuplot` が指定されたアスペクト比のグラフをちゃんと書けるかは選択され る出力形式に依存します。グラフの領域は出力の指定された部分にちゃんと収 まり、アスペクト比が <r> であるような最大の長方形となります (もちろん 適当な余白も残しますが)。
`square` は `ratio 1` と同じ意味です。
`noratio` と `nosquare` はいずれもグラフをその出力形式 (terminal) での デフォルトのアスペクト比に戻しますが、<xscale> と <yscale> はそのデフ ォルトの値 (1.0) には戻しません。
`ratio` と `square` は 3 次元描画では意味を持ちません。 size はデフォルトサイズに対する相対的な指定で、デフォルトサイズ は出力形式毎に異なります。`gnuplot` はデフォルトで可能な限り使用可能な 描画領域内一杯を使おうとしますから、size は拡大する、という使い 方でなくて縮小する、という使い方の方が安全です。
出力形式によっては、描画サイズの変更は、テキストの出力位置をおかしくさ せる可能性があります。
例:
通常の大きさに設定します:
set size 1,1
グラフを通常の半分の大きさで正方形にします:
set size square 0.5,0.5
グラフの高さを横幅の 2 倍にします:
set size ratio 2
以下も参照 翼のデモ。
デフォルトの描画スタイルは、`set style data` と `set style function` で設定できます。関数やデータのデフォルトの描画スタイルを個々に変更す る方法については with を参照してください。スタイルの一覧全体は `plotting styles` を参照してください。
書式:
set style function <style>
set style data <style>
show style function
show style data
指定できる描画要素のデフォルトスタイルも設定できます。
set style arrow <n> <arrowstyle>
set style fill <fillstyle>
set style line <n> <linestyle>
各出力形式は矢や点の形のデフォルトの集合を持っていて、それはコマンド test で参照できます。arrow は矢の形、幅、点の形、サイズ を定義し、それらを後で使うときにいちいち同じ情報を繰り返して指定しなく てもインデックスで参照できるようにします。
書式:
set style arrow <index> {nohead | head | heads}
{size <length>,<angle>{,<backangle>}}
{filled | empty | nofilled}
{front | back}
{ {linestyle | ls <line_style>}
| {linetype | lt <line_type>}
{linewidth | lw <line_width} }
unset style arrow
show style arrow
<index> は整数で、それで矢のスタイル (arrowstyle) を特定します。
`nohead` を指定すると、矢先のない矢、すなわち線分が描かれます。これは 線分の描画の別解を与えてくれます。デフォルトでは矢は 1 つの矢先を持ち ますが、`heads` を指定すると矢は線分の両端に矢先を描きます。
矢先のサイズは `size <length>,<angle>` または `size <length>,<angle>,<backangle>` で制御できますが、`<length>` は矢 先の各枝の長さを、`<angle>` は各枝が矢軸となす角度 (単位は度) を意味し ます。`<length>` は x-軸と同じ単位ですが、これは `<length>` の前に `first`, `second`, `graph`, `screen` をつけることで変更できます。個々 の意味については `coordinates` を参照してください。 `<backangle>` は、`filled` か `empty` も使われている場合にのみ効力を持 ち、その場合、`<backangle>` は矢先の後ろの部分の矢軸との切り角 (`<angle>` と同じ方向; 単位は度) になります。 出力形式 fig は、制限された切り角関数を持っていて、それは 3 つの異な る形をサポートしていて、それは 2 つの閾値で決定します: 70 度未満の場合、 矢先はへこんだ切り角を持ち、110 度を超える場合、後ろの部分に尖った角を 持ち、その間の角では、矢先の後ろは直線になります。
`filled` を指定すると矢先は塗りつぶされます (矢先が使われている場合) が、塗りつぶしは多角形の塗りつぶしが行える出力形式でのみサポートされて います。そのリストは pm3d で参照できます。そうでない出力形式では矢先 は閉じられますが塗られません。それと同じ効果 (閉じらるが塗られない) は、 `empty` を指定しても得られます。 なお、塗りつぶしや矢先の枠線描きは、`metafont`, `metapost`, latex, tgif といった、自分自身が持っている矢の描画ルーチンを使って矢を描く 出力形式ではサポートされません。
線のスタイルはユーザが定義した線スタイルリスト (`set style line` 参照) から選択できますし、`<line_type>` (デフォルト線種リスト内の番号) と `<line_width>` (デフォルトの幅に対する倍数) とを、ここで定義することも できます。
しかし、ユーザ定義線スタイルが選択された場合でも、適当なインデックスと `lt` や `lw` で arrow コマンドを発行しても、線スタイルの性 質 (線種と幅) は変更はされない、ということに注意してください。
`front` が指定されると、矢はグラフデータの上に描かれ、`back` が指定さ れると (デフォルト)、矢はグラフデータの下に描かれます。`front` を使う ことで、密なデータによって矢が隠されてしまうことを防ぐことができます。
例:
矢先がなく、倍の幅が矢を描くには:
set style arrow 1 nohead lw 2
set arrow arrowstyle 1
その他の例については arrow を参照してください。
コマンド `set style data` はデータ描画に対するデフォルトの描画スタイル を変更します。
書式:
set style data <plotting-style>
show style data
選択項目については `plotting styles` を参照してください。項目を指定し なかった場合、その一覧が表示されます。`show style data` は現在のデフォ ルトのデータ描画スタイルを表示します。
コマンド `set style fill` は boxes と candlesticks のスタイルの設定に 使われます。
書式:
set style fill {empty | solid {<density>} | pattern {<n>}}
{border {<linetype>} | noborder}
デフォルトの塗りつぶしスタイル (fillstyle) は `empty` です。
オプション `solid` は、出力形式がサポートしている場合、その色でのベタ 塗りを行います。パラメータ <density> は塗りつぶし色の強さを表していて <density> が 0.0 なら箱は空、<density> が 1.0 なら箱はその内部は現在の 線種と完全に同じ色で塗られます。出力形式によっては、この強さを連続的に 変化させられるものもありますが、その他のものは、部分的な塗りつぶしの幾 つかのレベルを実装しているに過ぎません。パラメータ <density> が与えら れなかった場合はデフォルトの 1 になります。
オプション `pattern` は、出力ドライバによって与えられるパターンでの塗 りつぶしを行います。利用できる塗りつぶしパターンの種類と数は出力ドライ バに依存します。塗りつぶしの boxes スタイルで複数のデータ集合を描画す る場合そのパターンは、複数の曲線の描画における線種の周期と同様、有効な パターンを、パターン <n> から始めて周期的に利用します。
オプション `empty` は、箱を塗りつぶしませんが、これがデフォルトです。 これは、オプション `solid` でパラメータ <density> を 0 に設定した場合 と同じです。
デフォルトの border は、現在の線の種類の実線で箱の境界を描きます。 `border <lt>` はその境界が線の種類 (linetype) <lt> で描かれるようにし ます。`noborder` は境界の線が描かれないようにします。
コマンド `set style function` は関数描画に対するデフォルトの描画スタイ ルを変更します。
書式:
set style function <plotting-style>
show style function
選択項目については `plotting styles` を参照してください。項目を指定し なかった場合、その一覧が表示されます。`show style function` は現在のデ フォルトの関数描画スタイルを表示します。
出力装置にはおのおのデフォルトの線種と点種の集合があり、それらはコマン ド test で見ることができます。`set style line` は線種と線幅、点種と 点の大きさを、個々の呼び出しで、それらの情報を全部指定する代わりに、単 なる番号で参照できるようにあらかじめ定義するものです。
書式:
set style line <index> {linetype | lt <line_type>}
{linewidth | lw <line_width>}
{pointtype | pt <point_type>}
{pointsize | ps <point_size>}
{palette}
unset style line
show style line
線種と点種現在の出力装置が持つデフォルトの種類から選ばれます。線幅と点 の大きさはデフォルトの幅、大きさに対する乗数です (しかし、ここでの <point_size> は、pointsize で与えられる乗数には影響を受けないこ とに注意してください)。
線種と線幅のデフォルトの値はそのラインスタイル番号 (index) です。幅と 大きさのデフォルトの大きさはどちらも 1 です。
このようにつくられるラインスタイルは、デフォルトの型 (線種, 点種) を 別なものに置き換えることはしないので、ラインスタイル、デフォルトの型、 どちらも使えます。
全ての出力装置が `linewidth` や pointsize をサポートしているわけでは ありません。もしサポートされていない場合はそれらのオプションは無視され ます。
この機能は完全に実行されるとは限らないことに注意してください。このよう に定義されるラインスタイルは、`plot`, `splot`, replot, arrow などでは使えますが、`set grid` のように、デフォルトの番号 (index) を 使うことが許されているようなコマンドでは使えません。
gnuplot が pm3d をサポートするようにインストールされている場合、splot の `linetype` として特別なキーワード palette も使えます (2 次元の `plot` では palette は無視されます)。この場合線の色は、あらかじめコ マンド palette で定義された滑らかなパレットから選ばれます。色の 値は、splot の z 座標の値 (高さ) に対応しています。
例: 以下では、番号 1, 2, 3 に対するデフォルトの線種をそれぞれ赤、緑、青とし、 デフォルトの点の形をそれぞれ正方形、十字、三角形であるとします。このとき 以下のコマンド
set style line 1 lt 2 lw 2 pt 3 ps 0.5
は、新しいラインスタイルとして、緑でデフォルトの 2 倍の幅の線、および 三角形で半分の幅の点を定義します。また、以下のコマンド
set style function lines
plot f(x) lt 3, g(x) ls 1
は、f(x) はデフォルトの青線で、g(x) はユーザの定義した緑の線で描画しま す。同様に、コマンド
set style function linespoints
plot p(x) lt 1 pt 3, q(x) ls 1
は、p(x) を赤い線で結ばれたデフォルトの三角形で、q(x) は緑の線で結ばれ た小さい三角形で描画します。
splot sin(sqrt(x*x+y*y))/sqrt(x*x+y*y) w l pal
は、palette に従って滑らかな色を使って曲面を描画します。これはそれを サポートした出力形式でしかちゃんとは動作しないことに注意してください。 palette と pm3d も参照してください。
コマンド `set style data` と `set style function` は、その後の `plot` や `splot` コマンドのデフォルトの描画スタイルを変更します。
線 (line) や点 (point) スタイルで使われる種類 (線で言えば実線、点線、 色など、点で言えば丸、四角、バツなど) は、`plot` や `splot` コマンドで 明示的に指定されたものになるか、または使用している出力形式が利用可能な ものから順番に選ばれたものになります。どんなものが使えるかはコマンド test でチェックしてください。
2 列より多くの情報を必要とするスタイル (例えば errorbars や errorlines) はいずれも `splot` や 関数の `plot` には使うことはできま せん。`boxes`, `filledcurves`, およびいくつかある `steps` スタイルは `splot` で使うことはできません。適切でないスタイルが指定された場合、そ れは `points` に変更されます。
2 列より多い 2 次元データに対しては、`gnuplot` は `errobars` か errorlines スタイルを選択しようとしますが、`plot` コマンドのオプショ ン using を使えば、使いたいスタイルにあわせて、適切な列のデータを使 うように設定できます (この議論の中で、"列 (column)" は、データファイル の各行の列と、using リスト中の項目の 2 つの意味で使われています)。
3 列のデータは、`xerrorbars`, `yerrorbars` (または errorbars), `xerrorlines`, `yerrorlines` (または errorlines), `boxes`, `boxerrorbars` のみが扱えます。他の描画スタイルが指定された場合、それ は `yerrorbars` に変更されます。スタイル `boxerrorbars` の箱の横幅は自 動的に計算されます。
4 列のデータは、`xerrorbars`, `yerrorbars` (または errorbars), `xyerrorbars`, `xerrorlines`, `yerrorlines` (または errorlines), `xyerrorlines`, `boxxyerrorbars`, `boxerrorbars` のみが扱えます。不適 切な描画スタイルは `yerrorbars` に変更されます。
5 列のデータは、`boxerrorbars`, `financebars`, `candlesticks` スタイル のみが扱えます。不適切な描画スタイルは、描画の前に `boxerrorbars` に変 更されます。
6 列のデータは、`xyerrorbars`, `xyerrorlines`, `boxxyerrorbars` スタイ ルのみが扱えます。不適切な描画スタイルは、描画の前に `xyerrorbars` に 変更されます。
線を含む/含まない誤差線表示 (error bar) についてのより詳しい情報は、 errorlines と errorbars を参照してください。
-- BOXERRORBARS --
描画スタイル `boxerrorbars` は 2 次元のデータ描画でのみ利用可能です。 これは `boxes` と `yerrorbars` スタイルの組合せです。y の誤差が "ydelta" の形式で与えられて、箱の横幅があらかじめ -2.0 に設定されて (`set boxwidth -2.0`) いなければ、箱の横幅は 4 列目の値で与えられます。 y の誤差が "ylow yhigh" の形式で与えられる場合は箱の横幅は 5 列目の値 で与えられます。特別な場合として、"ylow yhigh" の誤差形式の 4 列のデー タに対する `boxwidth = -2.0` という設定があります。この場合箱の横幅は、 隣接する箱にくっつくように自動的に計算されます。3 列のデータの場合も、 横幅は自動的に計算されます。
箱の高さは、`yerrorbars` スタイル同様に y の誤差の値から決定されます - y-ydelta から y+ydelta まで、あるいは ylow から yhigh まで、これらは何 列のデータが与えられているかによって決まります。 以下も参照 errorbar デモ。
-- BOXES --
`boxes` スタイルは 2 次元描画でのみ利用可能です。これは与えられた x 座 標を中心とし、x 軸から (グラフの境界から、ではありません) 与えられた y 座標までの箱を書きます。箱の幅は 3 つのうち一つの方法で決定されます。 それがデータの描画で、かつファイルが 3 列目のデータを持っている場合は それが箱の幅にセットされます。そうでなくて boxwidth コマンドで箱 の幅がセットされていた場合それが使われます。そのどちらでもない場合、箱 の幅は、隣接する箱がくっつくように自動的に計算されます。
箱の中身は現在の塗りつぶしスタイル (fillstyle) に従って塗りつぶされま す。詳細は `set style fill` を参照してください。新しい塗りつぶしスタイ ルを plot コマンド上で指定することもできます。
塗りつぶしスタイルが `empty` の場合は、箱は背景色で塗りつぶされます。
塗りつぶしスタイルが `solid` の場合は、箱は現在の描画色でベタ塗りされ ます。これには追加オプション <density> があり、それは塗りつぶし密度を 意味し、0 は背景色、1 は描画色そのものになります。
塗りつぶしスタイルが `pattern` の場合は、箱は現在の描画色であるパター ンで塗りつぶされますが、出力ドライバがサポートしている必要があります。
例:
データファイルを塗りつぶした箱で描画し、箱同士を少し垂直方向にスペース を空ける (棒グラフ):
set boxwidth 0.9 relative
set style fill solid 1.0
plot 'file.dat' with boxes
パターンでの塗りつぶしスタイルの箱で sin と cos のグラフを描画:
set style fill pattern
plot sin(x) with boxes, cos(x) with boxes
sin はパターン 0 で、cos はパターン 1 で描画されます。追加される描画は 出力ドライバがサポートするパターンを循環的に使用します。
それぞれのデータ集合で明示的に塗りつぶしスタイルを指定:
plot 'file1' with boxes fs solid 0.25, \
'file2' with boxes fs solid 0.50, \
'file3' with boxes fs solid 0.75, \
'file4' with boxes fill pattern 1, \
'file5' with boxes fill empty
現在、以下の出力ドライバのみが `empty` 以外の塗りつぶしスタイルをサポ ートしています: x11, windows, pm, postscript, fig, pbm, png, gif, hpdj, hppj, hpljii, hp500c, jpeg, nec_cp6, epson_180dpi, epson_60dpi, epson_lx800, okidata, starc, tandy_60dpi。BeOS ドライバ (`be`) はまだテストされていません。
-- FILLEDCURVES --
スタイル `filledcurves` は 2 次元描画でのみ利用可能です。これは曲線を 閉じて塗りつぶすか、または曲線と与えられた軸、または水平、垂直線、また は点との間に作られる領域を現在の描画色で塗りつぶします。
書式:
set style [data | function] filledcurves [option]
plot ... with filledcurves [option]
ここで、オプションは以下の通りです:
[closed | {x1 | x2 | y1 | y2}[=<a>] | xy=<x>,<y>]
塗りつぶされる領域は、曲線と以下のもので囲まれる部分です:
filledcurves closed ... 丁度閉曲線で囲まれる領域
filledcurves x1 ... x1 軸,
filledcurves x2 ... x2 軸, (y1, y2 軸も同様)
filledcurves y1=0 ... (y1 軸での) 直線 y=0 i.e. x1 軸と平行
filledcurves y2=42 ... (y2 軸での) 直線 y=42 i.e. x2 軸と平行
filledcurves xy=10,20 ... x1,y1 軸での点 10,20 (扇型のような形状)
注意: 塗りつぶしは、多角形の塗りつぶしが可能な出力形式のみでサポートさ れます。その一覧は pm3d を参照してください。
データファイルから描かれた曲線の塗りつぶしを拡大すると、何もなくなった り正しくない領域になることがありますが、それは gnuplot が、領域ではな く点や線をクリッピングしているからです。
<a>, <x>, <y> が描画領域の外にある場合、それらはグラフの境界へ移動され ます。よって、オプション xy=<x>,<y> を指定した場合の実際の塗りつぶし領 域は、xrange や yrange に依存します。
-- BOXXYERRORBARS --
`boxxyerrorbars` スタイルは 2 次元のデータ描画でのみ利用可能です。これ は `boxes` と `xyerrorbars` スタイルの組合せです。
箱の幅と高さは `xyerrorbars` スタイル同様 x, y の誤差から決定されます - xlow から xhigh までと ylow から yhigh まで、または x-xdelta から x+xdelta までと y-ydelta から y+ydelta まで。これらは何列のデータが与 えられているかによって決まります。
箱の塗りつぶしが機能する場合、箱の内部は現在の塗りつぶしスタイル (fillstyle) に従って塗られます。詳細は `set style fill` と `boxes` を 参照してください。plot コマンド上で新しい塗りつぶしスタイルを指定する こともできます。
-- CANDLESTICKS --
`candlesticks` スタイルは、金融データの 2 次元のデータ描画、および統計 データのひげ付きの棒グラフを生成するのに使えます。5 列のデータが必要で、 順に x 座標 (多分日付)、開始値、最安値、最高値、終値、となります。記号 は、水平方向には x を中心とし、垂直方向には開始値と終値を境界とする長 方形が使われます。そして、その x 座標のところに、長方形のてっぺんから 最高値までと、長方形の底から最安値までの垂直線が引かれますが、この垂直 線は最高値と最安値が入れ替わっても変更されません。
長方形の幅はコマンド boxwidth で制御できますが、以前の gnuplot への後方互換性として、boxwidth パラメータが設定されていない場合は `set bars <width>` で制御されるようになっています。
デフォルトでは長方形は (開始値)>(終値) の場合は空で、(開始値)<(終値) の場合は 3 本の垂直線が入ります。箱の塗りつぶしが有効である場合、その 長方形は `set style fill <fillstyle>` にしたがって塗りつぶされます。 bars, `financebars` を参照してください。また、以下も参照してくだ さい。 金融データのデモ
注意: 中央値を表すための記号などを追加したい場合、以下の例のように、ひ げ付きの棒グラフに他の描画コマンドを追加する必要があります:
# データ列: X '最小値' '1/4 位の値' '中央値' '3/4 位の値' '最大値'
set bars 4.0
set style fill empty
plot 'stat.dat' using 1:3:2:6:5 with candlesticks title 'Quartiles', \
'' using 1:4:4:4:4 with candlesticks lt -1 notitle
boxwidth と bars, `set style fill` を参照してください。
-- DOTS --
`dots` スタイルは各点に小さなドットを描画します。これはたくさんの点か らなる散布図の描画に便利でしょう。
-- FINANCEBARS --
`financebars` スタイルは金融データの 2 次元のデータ描画でのみ利用可 能です。5 列のデータが必要で、順に x 座標 (多分日付)、開始値、最安値、 最高値、終値、となります。記号は、水平方向にはその x 座標に置かれ、垂 直方向には最高値と最安値を端とする線分が使われます。そして、その線分に 水平左側の刻みが開始値の所に、水平右側の刻みが終り値の所につきます。そ の刻みの長さは bars で変更できます。記号は最高値と最安値が入れ替 わっても変わりません。bars と `candlesticks`、および以下も参照し てください。 金融データデモ。
-- FSTEPS --
`fsteps` スタイルは 2 次元描画でのみ利用可能です。これは 2 本の線分で 隣り合う点をつなぎます: 1 本目は (x1,y1) から (x1,y2) まで、2 本目は (x1,y2) から (x2,y2) まで。 以下も参照 steps デモ。
-- HISTEPS --
`histeps` スタイルは 2 次元描画でのみ利用可能です。これはヒストグラム の描画での利用を意図しています。y の値は、x の値を中心に置くと考え、 x1 での点は ((x0+x1)/2,y1) から ((x1+x2)/2,y1) までの水平線として表現 されます。端の点では、その線はその x 座標が中心になるように延長されま す。隣り合う点同士の水平線の端は、その両者の平均値のところでの鉛直線、 すなわち ((x1+x2)/2,y1) から ((x1+x2)/2,y2) の線分で結ばれます。 autoscale が有効である場合、x の範囲は、その延長された水平線の範囲で はなく、データ点の範囲が選択されます。よって、端の点に関してはその水平 線は半分しか描かれないことになります。 以下も参照 steps デモ。
`histeps` は単なる描画スタイルにすぎず、`gnuplot` には、ヒストグラムの 箱を生成する能力や、データ集合から母集団を決定する能力などはありません。
-- IMPULSES --
`impulses` スタイルは、x 軸 (グラフの境界ではなく) から、`splot` では 格子の土台からの垂直な線分を各点に対して表示します。
-- LINES --
`lines` スタイルは隣接する点を真直な線分で結びます。 `linetype`, `linewidth`, `linestyle` も参照してください。
-- LINESPOINTS --
`linespoints` スタイルは `lines` と `points` の両方を行ないます。すな わち、各点に小さな記号をつけ、そして隣接する点を真直な線分で結びます。 コマンド pointsize を使って点 (point) の記号の大きさを変更できま す。その使い方については pointsize を参照してください。
`linespoints` は `lp` と略すことが出来ます。
-- POINTS --
`points` スタイルは各点に小さな記号を表示します。その記号の大きさを変 更するにはコマンド pointsize が使えます。その使用法については pointsize の項を参照してください。
-- STEPS --
`steps` スタイルは 2 次元描画でのみ利用可能です。これは 2 本の線分で 隣り合う点をつなぎます: 1 本目は (x1,y1) から (x2,y1) まで、2 本目は (x2,y1) から (x2,y2) まで。 以下も参照 steps デモ。
-- VECTORS --
`vectors` スタイルは (x,y) から (x+xdelta,y+ydelta) までのベクトルを書 きます。よって 4 列のデータが必要です。ベクトルの先端には小さな矢先も 書きます。
例:
plot 'file.dat' using 1:2:3:4 with vectors head filled lt 2
`set clip one` と `set clip two` はベクトルの描画に影響を与えます。詳 細は clip と `arrowstyle` を参照してください。
-- XERRORBARS --
`xerrorbars` スタイルは 2 次元のデータ描画のみで利用可能です。 `xerrorbars` は、水平の誤差指示線 (error bar) が表示される以外は `dots` と同じです。各点 (x,y) において (xlow,y) から (xhigh,y) まで、 または (x-xdelta,y) から (x+xdelta,y) までの線分が引かれますが、これら はいくつのデータ列が与えられるかによって変わります。誤差指示線の端には 刻みの印が付けられます (bars が使われていなければ。詳細に関しては bars を参照してください)。
-- XYERRORBARS --
`xyerrorbars` スタイルは 2 次元のデータ描画のみで利用可能です。 `xyerrorbars` は、水平、垂直の誤差指示線 (error bar) も表示される以外 は `dots` と同じです。各点 (x,y) において (x,y-ydelta) から (x,y+ydelta) までと (x-xdelta,y) から (x+xdelta,y) まで、または (x,ylow) から (x,yhigh) までと (xlow,y) から (xhigh,y) までの線分が引かれますが、こ れらはいくつのデータ列が与えられるかによって変わります。誤差指示線の端 には刻みの印が付けられます (bars が使われていなければ。詳細に関し ては bars を参照してください)。
データが、サポートされていない混合型の形式で与えられた場合、`plot` コ マンドの using フィルタを使って適切な形に直さないといけません。例え ばデータが (x,y,xdelta,ylow,yhigh) という形式である場合、以下のように します:
plot 'data' using 1:2:($1-$3):($1+$3):4:5 with xyerrorbars
-- YERRORBARS --
`yerrorbars` (または errorbars) スタイルは 2 次元のデータ描画のみで 利用可能です。`yerrorbars` は、垂直の誤差指示線 (error bar) が表示され る以外は `points` に似ています。各点 (x,y) において (x,y-ydelta) から (x,y+ydelta) まで、または (x,ylow) から (x,yhigh) までの線分が引かれま すが、これらはいくつのデータ列が与えられるかによって変わります。誤差指 示線の端には刻みの印が付けられます (bars が使われていなければ。詳 細に関しては bars を参照してください)。 以下も参照 errorbar デモ。
-- XERRORLINES --
`xerrorlines` スタイルは 2 次元のデータ描画のみで利用可能です。 `xerrorlines` は `linespoints` に似ていますが、水平の誤差線が描かれる ことが違います。各点 (x,y) で、データ列の個数に応じて (xlow,y) から (xhigh,y) まで、または (x-xdelta,y) から (x+xdelta,y) までの線分が描か れ、そして刻の印が誤差線の端に置かれます (bars が使われていない 場合 - 詳細は bars 参照)。
-- XYERRORLINES --
`xyerrorlines` スタイルは 2 次元のデータ描画のみで利用可能です。 `xyerrorlines` は `linespoints` に似ていますが、水平と垂直の誤差線も描 かれることが違います。各点 (x,y) で、データ列の個数に応じて、 (x,y-ydelta) から (x,y+ydelta) までと (x-xdelta,y) から (x+xdelta,y) まで、あるいは (x,ylow) から (x,yhigh) までと (xlow,y) から (xhigh,y) までの線分が描かれ、そして刻の印が誤差線の端に置かれます (bars が使われていない場合 - 詳細は bars 参照)。
データが、サポートされていない混合型の形式で与えられた場合、`plot` コ マンドの using フィルタを使って適切な形に直さないといけません。例え ばデータが (x,y,xdelta,ylow,yhigh) という形式である場合、以下のように します:
plot 'data' using 1:2:($1-$3):($1+$3):4:5 with xyerrorlines
-- YERRORLINES --
`yerrorlines` (または errorlines) スタイルは 2 次元のデータ描画のみ で利用可能です。`yerrorlines` は `linespoints` に似ていますが、垂直の 誤差線が描かれることが違います。各点 (x,y) で、データ列の個数に応じて (x,y-ydelta) から (x,y+ydelta) まで、または (x,ylow) から (x,yhigh) までの線分が描かれ、そして刻の印が誤差線の端に置かれます (bars が使われていない場合 - 詳細は bars 参照)。 以下も参照。 エラーバーのデモ
コマンド surface は `splot` による曲面の表示を制御します。
書式:
set surface
unset surface
show surface
曲面はデータや関数に対して、with で指定されたスタイル、あるいは他の 適切なスタイルで書かれます。 surface が実行されれば `splot` は関数やデータファイルの点に対 する点や線を書きません。その場合でも contour の設定により曲面の 等高線は書かれます。`unset surface; set contour base` は等高線を格子の 土台に表示する際に便利です。contour も参照してください。
`gnuplot` は数多くのグラフィック形式をサポートしています。コマンド terminal を使って `gnuplot` の出力の対象となる形式の種類を選んで ください。出力先をファイル、または出力装置にリダイレクトするには output を使ってください。
書式:
set terminal {<terminal-type> | push | pop}
show terminal
<terminal-type> が省略されると `gnuplot` は利用可能な出力形式の一覧を 表示します。<terminal-type> の指定には短縮形が使えます。 terminal と output の両方を使う場合、terminal を最初 にする方が安全です。それは、OS によっては、それが必要とするフラグをセ ットする出力形式があるからです。
いくつかの出力形式は追加オプションを持ちます。例えば `dump`, `iris4d`, hpljii, `postscript` などの項を参照してください。 各 `<term>` に対し、直前の `set term <term> <options>` で使用されたオ プションは記憶され、その後の `set term <term>` がそれをリセットするこ とはありません。これは例えば印刷時に有用です。幾つかの異なる出力形式を 切替える場合、前のオプションを繰り返し唱える必要はありません。
コマンド `set term push` は、現在の出力形式とその設定を `set term pop` によって復帰するまで記憶しています。これは `save term`, `load term` と ほぼ同等ですが、ファイルシステムへのアクセスは行わず、よって例えばこれ は、印刷後にプラットホームに依存しない形で出力形式を復帰する目的に使え ます。gnuplot の起動後、デフォルト、または `startup` ファイルに書かれ た出力形式が自動的に記憶 (push) されます。よって、明示的に出力形式を記 憶させることなく、任意のプラットフォーム上でデフォルトの出力形式を `set term pop` によって復帰させる、という動作を期待したスクリプトを可 搬性を失わずに書くことが出来ます。
この文書は、インストールされなかったために利用できない出力形式のドライ バについても記述されているかも知れませんし、利用できる出力形式なのにこ こには書かれていないかも知れません。それはドキュメントの出力形態に依存 します。 @c <4 - 全ての出力ドライバの項目は、.trm ファイルから引っ張って来られます。
出力ドライバ `aed512` と aed767 は AED グラフィック端末をサポートし ます。この 2 つのドライバは、水平方向の範囲のみが違っていて、それぞれ 512 ピクセルと 767 ピクセルです。垂直方向はいずれも 575 ピクセルです。 これらのドライバにはオプションはありません。"
Adobe Illustrator 3.0+ ドライバ aifm には、いくつかのオプションを設 定できます。
書式:
set terminal aifm {<color>} {"<fontname>"} {<fontsize>}
<color> は `color` か `monochrome`、"<fontname>" は正式な PostScript フォント名、<fontsize> はフォントサイズを PostScript のポイント数で与 えます。これらは size コマンドでスケール変換される前のものです。 `default` を選択すると、全てのオプションがデフォルトの値: `monochrome`, "Times-Roman", 14pt, に設定されます。
AI は複数のページをサポートしていないので、複数のグラフは直接他のグラ フの上に書かれます。しかし、各グラフは個別にグループ化されていて、AI 上で簡単にそれらを分離することが出来ます (単にそれらを拾い上げて移動 させるだけです)。
例:
set term aifm
set term aifm 22
set size 0.7,1.4; set term aifm color "Times-Roman" 14"
固定サイズのウィンドウが必要ならば、gpr 出力を代わりに使用してくださ い。"
この出力形式は Mac OS X 上の表示に関する AquaTerm.app に依存しています。
書式:
set terminal aqua {<n>} {title "<wintitle>"} {size <x> <y>}
{fname "<fontface>"} {fsize <fontsize>}
<n> は描画するウィンドウの番号 (デフォルトでは 0) <wintitle> はタイトルバーに表示される名前 (デフォルトは "Figure <n>"), <x> <y> は描画サイズ (デフォルトは 846x594 pt = 11.75x8.25 インチ) です。
使用されるフォントは <fontface> で指定し (デフォルトは "Times-Roman")、 フォンサイズは <fontsize> で設定します (デフォルトは 14.0 pt)。"
書式:
set terminal cgm {<mode>} {<color>} {<rotation>} {solid | dashed}
{width <plot_width>} {linewidth <line_width>}
{"<font>"} {<fontsize>}
{<color0> <color1> <color2> ...}
ここで、<mode> は `landscape`, `portrait`, `default` のいずれか; <color> は `color`, `monochrome` のいずれか; <rotation> は `rotate`, `norotate` のいずれか; `solid` は全ての曲線を実線で描き、どんな点線パターンも塗りつぶします; <plot_width> はポイント単位でのグラフの仮定されている幅; <line_width> はポイント単位での線幅 (デフォルトは 1); <font> はフォントの名前; そして <fontsize> はポイント単位でのフォントのサイズ (デフォルトは 12) です。
デフォルトでは cgm は Y 軸の見出しに 90 度回転した文字を使用します。
最初の 6 つのオプションはどの順番で指定しても構いません。`default` を 選択すると、全てのオプションをそのデフォルトの値にします。
各カラー (color) は 'xrrggbb' の形式です。ここで、x は文字 'x' そのも の、'rrggbb' は 16 進数での赤、緑、青の成分です。例えば 'x00ff00' は 緑になります。背景色が最初に設定され、以下は描画色となります。
例:
set terminal cgm landscape color rotate dashed width 432 \\
linewidth 1 'Helvetica Bold' 12 # デフォルト
set terminal cgm linewidth 2 14 # やや広い線とやや大きいフォント
set terminal cgm portrait "Times Italic" 12
set terminal cgm color solid # 面倒な点線など消えてしまえ !
-- FONT --
CGM (Computer Graphics Metafile) ファイルの最初の部分、メタファイルの 記述部分には、フォントリスト (font table) が含まれています。画像の本体 部では、フォントはこのリストにある番号で指定されます。デフォルトではこ のドライバは以下の 35 個のフォントリストを生成し、さらにこのリストの `Helvetica`, `Times`, `Courier` の各フォントの `italic` を `oblique` で置き換えたもの、およびその逆による 6 つの追加のフォントが含まれます (Microsoft Office と Corel Draw CGM の import フィルタは `italic` と `oblique` を同じものとして扱うからです)。
Helvetica
Helvetica Bold
Helvetica Oblique
Helvetica Bold Oblique
Times Roman
Times Bold
Times Italic
Times Bold Italic
Courier
Courier Bold
Courier Oblique
Courier Bold Oblique
Symbol
Hershey/Cartographic_Roman
Hershey/Cartographic_Greek
Hershey/Simplex_Roman
Hershey/Simplex_Greek
Hershey/Simplex_Script
Hershey/Complex_Roman
Hershey/Complex_Greek
Hershey/Complex_Script
Hershey/Complex_Italic
Hershey/Complex_Cyrillic
Hershey/Duplex_Roman
Hershey/Triplex_Roman
Hershey/Triplex_Italic
Hershey/Gothic_German
Hershey/Gothic_English
Hershey/Gothic_Italian
Hershey/Symbol_Set_1
Hershey/Symbol_Set_2
Hershey/Symbol_Math
ZapfDingbats
Script
15
これらのフォントの最初の 13 個は WebCGM で要求されているものです。 Microsoft Office の CGM import フィルタはその 13 個の標準フォントと 'ZapfDingbats' と 'Script' をサポートしています。しかし、そのスクリプ ト (script) フォントは '15' という名前でしかアクセスできません。 Microsoft の import フィルタの font の置き換えに関するより詳しい情報に ついては、
C:\\Program Files\\Microsoft Office\\Office\\Cgmimp32.hlp
のヘルプファイル、または
C:\\Program Files\\Common Files\\Microsoft Shared\\Grphflt\\Cgmimp32.cfg
の設定ファイルなどをチェックしてください。
`set term` コマンドでデフォルトのフォントリストにないフォント名を指定 することも可能です。その場合、その指定したフォントが最初に現われる新 しいフォントリストが作られます。そのフォント名に関して、スペル、単語 の先頭の大文字化やどこにスペースが入るかなどが、作られる CGM ファイル を読むアプリケーションにとって適切なものであるかをちゃんと確認する必要 があります。(gnuplot と任意の MIL-D-28003A 準拠アプリケーションは、フ ォント名の大文字小文字の違いは無視します。) 新しいフォントをいくつも追 加したい場合は、`set term` コマンドを繰り返し使用してください。
例:
set terminal cgm 'Old English'
set terminal cgm 'Tengwar'
set terminal cgm 'Arabic'
set output 'myfile.cgm'
plot ...
set output
label コマンドでは新しいフォントを導入することはできません。
-- FONTSIZE --
フォントは、ページが 6 インチの幅であると仮定して縮尺されます。size コマンドでページの縦横比が変更されていたり、CGM ファイルが異なる幅に変 換されている場合、結果としてフォントのサイズも拡大されたり縮小されたり することになります。仮定されている幅を変更するには、`width` オプション を使用してください。
-- LINEWIDTH --
`linewidth` オプションは線の幅をポイント単位 (pt) で設定します。デフォ ルトの幅は 1 pt です。`fontsize` や `width` オプションのところで説明さ れているように、ページの実際の幅によってその縮尺は影響を受けます。
-- ROTATE --
`norotate` オプションはテキストの回転をしないようにします。例えば Word for Windows 6.0c 用の CGM 入力フィルタは回転された文字列を受け付けます が、Word に付属する DRAW エディタはそれを受け付けることができず、グラ フを編集すると (例えば曲線に見出しをつける)、全ての回転された文字列は 水平方向になって保存されてしまい、Y 軸の見出しはクリップされる境界線を 越えてしまうでしょう。`norotate` オプションを使えば、見栄えの良くない 場所から Y 軸の見出しが始まってしまいますが、編集によってダメージを受 けることはなくなります。`rotate` オプションはデフォルトの挙動を保証し ます。
-- SOLID --
`solid` オプションは描画の点線の線描画スタイルを無効するのに使います。 これは、カラーが有効である場合、また点線にすることでグラフが見にくくな る場合に有用でしょう。`dashed` オプションはデフォルトの挙動を保証し、 この場合個々のグラフに異なる点線のパターンが与えられます。
-- SIZE --
CGM グラフのデフォルトのサイズは、横置き (landscape) では幅 32599, 縦 23457、縦置き (portrait) では幅 23457, 縦 32599 です。
-- WIDTH --
CGM ファイルの全ての長さは抽象的な単位を持ち、そのファイルを読むアプリ ケーションが最終的なグラフのサイズを決定します。デフォルトでは最終的な グラフの幅は 6 インチ (15.24 cm) であると仮定されています。この幅は正 しいフォントサイズを計算するのに使われ、`width` オプションで変更できま す。キーワード `width` の後に幅をポイント単位で指定します。(ここで、ポ イントは PostScript と同様 1/72 インチを意味します。この単位は TeX では "big point" と呼ばれています。) 他の単位から変換するには、gnuplot の数 式が使えます。
例:
set terminal cgm width 432 # デフォルト
set terminal cgm width 6*72 # 上と同じ値
set terminal cgm width 10/2.54*72 # 10 cm の幅
-- NOFONTLIST --
デフォルトのフォントリスト (font table) は WebCGM で勧告されているフォ ントを含んでいて、これは Microsoft Office と Corel Draw の CGM (Computer Graphics Metafile) 入力フィルタに適合しています。他のアプリケーション は異なるフォント、あるいは異なるフォント名を使用するかも知れませんが、 それはマニュアルには書かれていないかも知れません。そのための回避策とし て、オプション `nofontlist` を使用して CGM ファイルからフォントリスト を削除するという方法があります。この場合、読み込んだアプリケーションは デフォルトのフォントリストを使用するでしょう。gnuplot はその場合でも フォント番号の選択のために自分のデフォルトのフォントリストを使用します。 よって、'Helvetica' が 1 番になり、それがあなたの使用するアプリケーシ ョンのデフォルトフォントリストの最初のものになります。'Helvetica Bold' がそのフォントリストの 2 番目のフォントに対応し、他も同様となります。
以前の `winword6` オプションは今は `nofontlist` の同意語に成り下がりま した。`winword6` オプションが回避策として使われていた、色やフォントリ ストに関する問題は、結局 gnuplot のバグであるとわかり、それは今では修 正されています。"
書式:
set terminal corel { default
| {monochrome | color
{"<font>" {<fontsize>
{<xsize> <ysize> {<linewidth> }}}}}
ここで、フォントサイズ (`fontsize`) と線幅 (`linewidth`) はポイント単 位、横幅 (`xsize`) と縦幅 (`ysize`) はインチ単位です。デフォルトの値は それぞれ、monochrome, "SwitzerlandLight", 22, 8.2, 10, 1.2 です。"
このドライバは `gnuplot` のデバッグのために提供されているものです。お そらくソースコードを修正するユーザのみが使用するものでしょう。"
ダム端末 (dumb) ドライバにはサイズの指定と改行制御用のオプションがあ ります。
書式:
set terminal dumb {[no]feed} {<xsize> <ysize>}
{[no]enhanced}
<xsize>, <ysize> はダム端末 のサイズを設定し、デフォルトはそれぞれ 79, 24 となっています。最後の改行は、`feed` オプションが設定されている場合 のみ出力されます。
例:
set term dumb nofeed
set term dumb 79 49 # VGA screen---何故こうしたい人がいるんだろう ?"
このドライバは Roland DXY800A プロッタをサポートします。オプションはあ りません。"
このドライバによる出力は、LaTeX 用の "eepic.sty" マクロパッケージと共 に使われることを仮定しています。それを使うには、"eepic.sty" と "epic.sty"、および "tpic" \\special 命令群をサポートするプリンタドライ バが必要です。もし、あなたの使うプリンタドライバがそれらの "tpic" \\special 命令をサポートしていない場合でも、"eepicemu.sty" を使うことで それらのうちのいくつかを使えるようになります。 dvips と dvipdfm は "tpic" \\special をサポートしています。
書式:
set terminal eepic {color, dashed, rotate, small, tiny, default, <fontsize>}
オプション: オプションは任意の順番で与えることができます。 'color' は gnuplot に \\color{...} コマンドを生成させ、それによりグラフ をカラーにします。このオプションを使用する場合は、latex 文書のプリアン ブルに \\usepackage{color} を入れる必要があります。 'dashed' は線種に点線を使用することを許可します。このオプションを指定 しないと、色々な太さの実線のみが使われます。 'dashed' と 'color' は一方のみが意味を持ち、'color' が指定された場合、 'dashed' は無視されます。 'rotate' は本当に回転 (90 度) された文字列を使用するようになります。指 定しない場合は、1 文字 1 文字、上に積み上げていく方法で回転された文字 列を作ります。このオプションを使う場合は、\\usepackage{graphicx} をプリ アンブルに入れる必要があります。 'small' は point スタイルでのグラフ描画の印として \\scriptsize の記号を 使用します (多分これは TeX ではだめで、LaTeX2e でしか使えないでしょう)。 デフォルトでは標準の数式のサイズを使用します。 'tiny' は、それに \\scriptscriptstyle の記号を使用します。 'default' は全てのオプションをデフォルトの値にリセットします。デフォル トは、color はなし、dashed line はなし、疑似回転 (積み上げ) 文字列の使 用、大きなサイズの記号の使用、です。 <fontsize> は picture 環境内でのフォントサイズを指定する数字です。単位 は pt (ポイント) で、10 pt はほぼ 3.5 mm です。フォントサイズを指定し ない場合、全てのグラフ内の文字は \\footnotesize に設定されます。
注意: 文字 # (およびその他 (La)TeX で特別な意味を持つその他の文字) を \\\\ (バ ックスラッシュ 2 つ) でエスケープすることを忘れないでください。 グラフの角が近すぎると点線は実線のようになります。(これが tpic specials の一般的な問題なのか、eepic.sty や dvips/dvipdfm のバグが原因なのかは私 にはわかりません。) デフォルトの eepic グラフの大きさは 5x3 インチで、これは 'set size a,b' で縮尺可能です。 数ある中で、点 (point) は、LaTeX のコマンド "\\Diamond", "\\Box" などを 使って描かれます。これらのコマンドは現在は LaTeX2e のコアには存在せず latexsym パッケージに含まれていますが、このパッケージ基本配布の一部で あり、よって多くの LaTeX のシステムの一部になっています。このパッケー ジを使うことを忘れないでください。latexsym の代わりに amssymb パッケー ジを使うことも可能です。 LaTeX に関する全てのドライバは文字列の配置の制御に特別な方法を提供しま す: '{' で始まる文字列は、'}' で閉じる必要がありますが、その文字列全体 が水平方向にも垂直方向にもセンタリングされます。'[' で始まる文字列の場 合は、位置の指定をする文字列 (t,b,l,r のうち 2 つまで) が続き、次に ']{'、文字列本体、で最後に '}' としますが、この文字列は LaTeX が LR-box として整形します。'\\rule{}{}' を使えばさらに良い位置合わせが可能でしょ う。
例: set term eepic
は、グラフを picture 環境に含まれた eepic マクロとして出力します。
そのファイルを LaTeX 文書に \\input で取り込んでください。
set term eepic color tiny rotate 8
eepic マクロを \\color マクロ、point 印は \\scripscriptsize の大きさ、
本当に回転された文字の使用、および全ての文字を 8pt にセットして出力
します。
見出しの位置合わせに関して: gnuplot のデフォルト (大抵それなりになるが、そうでないこともある):
set title '\\LaTeX\\ -- $ \\gamma $'
水平方向にも垂直方向にもセンタリング:
set label '{\\LaTeX\\ -- $ \\gamma $}' at 0,0
位置を明示的に指定 (上に合わせる):
set xlabel '[t]{\\LaTeX\\ -- $ \\gamma $}'
他の見出し - 目盛りの長い見出しに対する見積り:
set ylabel '[r]{\\LaTeX\\ -- $ \\gamma $\\rule{7mm}{0pt}}'"
書式:
set terminal emf {<color>} {solid | dashed}
{"<font>"} {<fontsize>}
<color> は `color` (カラー) か `monochrome` (白黒)、 `solid` は全ての線を実線で書き、点線のパターンは塗りつぶします。 <font> はフォント名、 `<fontsize>` はポイント単位でのフォントの大きさです。
最初の 2 つのオプションはどちらが先でも構いません。`default` を選択す ると全てのオプションがそのデフォルトの値になります。
例:
set terminal emf 'Times Roman Italic' 12
set terminal emf color solid # 面倒な点線など消えてしまえ !"
書式:
set terminal epslatex {default}
{color | monochrome} {solid | dashed}
{"<fontname>"} {<fontsize>}
`default` モードは全てのオプションを以下のデフォルトの値に設定します: `monochrome`, `dashed`, "default", 11pt。 グラフのデフォルトのサイズは幅が 5 インチ、高さが 3 インチです。
`solid` は全てのグラフを実線で描き、点線のパターンを塗りつぶします。 `"<fontname>"` はフォントの名前、`<fontsize>` は PostScript ポイント単 位でのフォントの大きさです。フォントの選択はまだサポートされていません。 フォントの大きさの選択は適切なスペーシングの計算に対してのみサポートさ れています。挿入の間際では実際には LaTeX のフォントが使用されるので、 フォントの変更は LaTeX のコマンドを使用してください。例えば LaTeX の文 書で 12pt のフォントを使うのなら、オプションとして '"default" 12' と指 定してください。
LaTeX に関する全てのドライバは文字列の配置の制御に特別な方法を提供しま す: (a) '{' で始まる文字列は、'}' で閉じる必要がありますが、その文字列 全体が LaTeX によって水平方向にも垂直方向にもセンタリングされます。 (b) '[' で始まる文字列の場合は、位置の指定をする文字列 (t,b,l,r のうち 2 つまで) が続き、次に ']{'、文字列本体、で最後に '}' としますが、この 文字列は LaTeX が LR-box として整形します。\\rule{}{} を使えばさらに良 い位置合わせが可能でしょう。 `pslatex` ドライバに関する説明も参照してください。 複数行の見出しを作成するには \\shortstack を使用してください。例えば、
set ylabel '[r]{\\shortstack{first line \\\\ second line}}'
このドライバは 2 つの別のファイルを作ります。1 つは図の eps の部分で、 もう一つは LaTeX の部分です。eps ファイルの名前は、output コマン ドのものが使われ、LaTeX ファイルの名前はその拡張子 (通常 `.eps`) を `.tex` に置き換えたものになります。 出力ファイルを指定しなければ LaTeX 出力は行なわれません ! `gnuplot` を終了する前にその出力ファイルをクローズするのを忘れないでく ださい。
LaTeX の文書で図を取り込むには '\\input{filename}' としてください。 `.eps` ファイルは \\includegraphics{...} コマンドで取り込むので、よって LaTeX のプリアンブルに \\usepackage{graphicx} も入れる必要があります。
この eps ファイルから 'epstopdf' を使って pdf ファイルを作ることもでき ます。graphics パッケージが適切に設定されている場合、その LaTeX のファ イルは、変更なしに pdflatex によっても処理でき、その場合 eps ファイル の代わりに pdf ファイルが取り込まれます。"
このドライバはエプソンプリンタのいくつかとそれに類似するものをサポート します。 epson-180dpi と `epson-60dpi` はそれぞれ 180dpi (ドット/インチ), 60dpi の解像度の Epson LQ 型 24 ピンプリンタ用のドライバです。
`epson-lx800` は Epson LX-800, Star の NL-10 や NX-1000, PROPRINTER な どの適当なプリンタに流用できる、一般的な 9 ピンプリンタドライバです。
`nec-cp6` は NEC CP6 や Epson LQ-800 などのプリンタで使える、一般的な 24 ピンプリンタ用のドライバです。
`okidata` ドライバは 9 ピンの OKIDATA 320/321 標準プリンタをサポートし ます。
`starc` ドライバは Star カラープリンタ用です。
`tandy-60dpi` ドライバは 9 ピン 60dpi の Tandy DMP-130 シリーズ用です。
`nec-cp6` にのみオプションがあります。
書式:
set terminal nec-cp6 {monochrome | colour | draft}
デフォルトでは白黒 (monochrome) です。
これらのドライバのそれぞれで PC 上で印刷する場合はバイナリコピーが必要 です。`print` を使ってはいけません。その代わりに `copy file /b lpt1:` としてください。"
書式:
set terminal fig {monochrome | color}
{landscape | portrait}
{small | big | size <xsize> <ysize>}
{metric | inches}
{pointsmax <max_points>}
{solid | dashed}
{fontsize <fsize>}
{textnormal | {textspecial texthidden textrigid}}
{thickness <units>}
{depth <layer>}
{version <number>}
`monochrome` と `color` は 画像を白黒にするか `color` にするかを決定し ます。`small` と `big` は、デフォルトの `landscape` モードではグラフを 5x3 インチにするか 8x5 インチにするか、`portrait` モードでは 3x5 イン チにするか 5x8 インチにするかを決定します。size は描画範囲を <xsize>*<ysize> に設定 (変更) します。この場合の単位は、`inches` か `metric` かの設定によってそれぞれインチかセンチメートルかになります。 この設定は "xfig" での編集に対するデフォルトの単位としても使われます。
`pointsmax <max_points>` は折れ線の最大点数を設定します。
`solid` は、実線 (solid) の linestyle が全部使われてしまった後で自動的 に使われる点線の使用を抑制し、別な形で表示します。
`fontsize` はテキストフォントのサイズを <fsize> ポイントに設定します。 `textnormal` はテキストフラグの設定をリセットして postscript フォント を選択し、`textspecial` はテキストフラグを LaTeX special に設定し、 `texthidden`, `textrigid` はそれぞれ無表示のテキスト、スケーリングされ ないテキスト用のフラグを設定します。
`depth` は全ての線と文字列に対する、重なりに関するデフォルトの深さ (depth layer) を設定します。デフォルトの深さは 10 で、"xfig" でグラフ の上に何かを上書きするための余地を残しています。 version は生成される fig 出力の書式バージョンを設定します。現在は、 バージョン 3.1 と 3.2 のみがサポートされています。
`tickness` はデフォルトの線の太さを設定し、指定されなければ 1 になりま す。太さの変更は、`plot` コマンドの `linetype` の値に 100 倍の数を加え ることで実現できます。同様に、(デフォルトの深さに対する) 各描画要素の 深さの値は <linetype> に 1000 倍の数を加えることで制御できます。よって その深さは <layer>+<linetype>/1000 になり、線の太さは (<linetype>%1000) /100 となりますが、その値が 0 の場合はデフォルトの線の太さになります。
`plot` コマンドの `point` スタイルによる描画の際の記号を fig ドライ バで追加することもできます。記号の指定は (`pointtype` の値) % 100 の 50 以上の値が使われ、その塗りつぶしの濃さは <pointtype> % 5 の値で制御 し、その輪郭は黒 (<pointtype> % 10 < 5 の場合) または現在の色で書かれ ます。利用可能な記号は以下の通りです。
50 - 59: 円
60 - 69: 正方形
70 - 79: ひし形
80 - 89: 上向きの三角形
90 - 99: 下向きの三角形
これらの記号の大きさはフォントの大きさと関係しています。デフォルトでは 記号の深さは、良いエラーバーを実現するために、線の深さより 1 だけ小さ い値になっています。<pointtype> が 1000 より大きい場合、深さは <layer> +<pointtype>/1000-1 になります。<pointtype>%1000 が 100 より大きい場合 塗りつぶし色は (<pointtype>%1000)/100-1 になります。
有効な塗りつぶし色 (1 から 9) は、黒、青、緑、水色、赤、紫、黄、白、暗 い青 (白黒モードでは 1 から 6 までは黒で 7 から 9 までは白) です。
<linetype> と <pointtype> の詳細については with を参照してくだ さい。
`big` オプションは以前のバージョンの `bfig` ドライバの代用品ですが、こ のドライバは今はもうサポートされていません。
例:
set terminal fig monochrome small pointsmax 1000 # デフォルト
plot 'file.dat' with points linetype 102 pointtype 759
は、黄色で塗りつぶされた円を生成し、それら輪郭は幅 1 の青い線です。
plot 'file.dat' using 1:2:3 with err linetype 1 pointtype 554
は黒い線によるエラーバーと赤で塗りつぶされた円を生成します。この円は線 よりも 1 層だけ上になります (デフォルトでは深さは 9)。
円の上にエラーバーを書くには以下のようにしてください。
plot 'file.dat' using 1:2:3 with err linetype 1 pointtype 2554"
書式:
set terminal png
{{no}transparent} {{no}interlace}
{tiny | small | medium | large | giant}
{font <face> {<pointsize>}}
{size <x>,<y>} {{no}crop}
{{no}enhanced}
{<color0> <color1> <color2> ...}
PNG 画像は libgd によって生成されますが、オプションで libfreetype を使 って TrueType フォントや Adobe Type 1 フォントを使うこともできます。 Version 1.8 以上の libgd が必要です。
`transparent` はドライバに透明化 (transparent) PNG を生成するよう指示 します。この場合最初の指定色が透明化される色になります。デフォルトでは `notransparent` です。
`interlace` はドライバにインターレース GIF を生成するよう指示します。 デフォルトでは `nointerlace` です。
gd library によって次の 5 つの基本フォントが直接サポートされています: `tiny` (5x8 ピクセル), `small` (6x12 ピクセル), `medium`, (7x13 Bold), `large` (8x16), `giant` (9x15 ピクセル)。これらのフォントは大きさを変 更したり回転したり (純粋に水平か垂直な文字列しか使えません) することは できません。
gnuplot が TrueType (*.ttf) フォントか Adobe Type 1 (*.pfa) フォントを サポートするように構築されている場合、オプション `font <face> {<pointsize>}` でそれを選択できます。<face> は、そのフォ ントファイルのフルパス名かフォントフェース名 (font face name) ですが、 後者は、環境変数 GDFONTPATH で指示されるディレクトリ中のファイル名の先 頭部分であると見なされるものです。よって、'set term png font "Face"' は、<あるディレクトリ>/Face.ttf か <あるディレクトリ>/Face.pfa を探そ うとします。TrueType も Adobe Type 1 フォントも自由に大きさを変更でき ますし、任意の角度で回転できます。 フォントを指定しなかった場合、gnuplot はより良いデフォルトフォントを見 つけるために環境変数 GNUPLOT_DEFAULT_GDFONT を参照します。
`enhanced` は拡張テキスト処理機能 (上付き文字、下付き文字、および複数 のフォントの利用) を有効にします。詳細は `enhanced` を参照してください。 PNG/JPEG 出力ドライバは、それ自身拡張処理モードの命令をすべてサポート していますが、これらの機能のうちいくつかは、それが使用している libgd イブラリのバージョンやどのようなフォントが利用可能になっているかに依存 します。
サイズ <x,y> はピクセル単位で与えます。デフォルトは 640x480 です。ピク セル数は size コマンドで縮尺することでも変更できます。 `crop` は完成した描画グラフの端の空白領域を取り除いて、結果として画像 サイズを小さくします。デフォルトは `nocrop` です。
個々の色は 'xrrggbb' の形式で指定します。ここで、x はそのまま文字 'x' を意味し、'rrggbb' は赤、緑、青の 16 進数での成分です。例えば 'x00ff00' は緑を表します。背景色を最初に指定し、その後ろに境界色、X 軸と Y 軸の 色、グラフの描画色、と続きます。色数は最大 256 色まで設定できます。
例:
set terminal png medium size 640,480 \\
xffffff x000000 x404040 \\
xff0000 xffa500 x66cdaa xcdb5cd \\
xadd8e6 x0000ff xdda0dd x9500d3 # デフォルト
この例では透明化されない背景色が白で、境界は黒、軸は灰色、そして描画色 として赤、橙色、青緑色 (midium aquamarine)、アザミ色 (thistle 3)、明青 色 (light blue)、青、かきつばた色 (plum)、暗いすみれ色 (dark violet) の 8 色を使います。
set terminal png font arial 14 size 800,600
これは、環境変数 GDFONTPATH で指定されたディレクトリにある 'arial' と いう名前で 14pt のフォントサイズの TrueType フォントを検索します。
set terminal png transparent xffffff \\
x000000 x202020 x404040 x606060 \\
x808080 xA0A0A0 xC0C0C0 xE0E0E0
これは透明化される背景が白で、境界は黒、軸は暗い灰色、描画色はグレイス ケールで 6 色を使うことになります。
書式:
set terminal ggi [acceleration <integer>] [[mode] {mode}]
X では、ウィンドウマネージャの機能を使ってウィンドウのサイズを変更する ことはできませんが、モードを mode オプションを使って、例えば以下のよう に変更することができます:
- V1024x768
- V800x600
- V640x480
- V320x200
他のモードについては、ggi (libggi) のドキュメントを参照してください。 キーワード `mode` は追加してもしなくても結構です。libggi のマニュアル ページで紹介されているように、環境変数でターゲットを選択することをお勧 めします。X 上で DGA を使うなら、例えば以下のようにしてください。
bash> export GGI_DISPLAY=DGA
csh> setenv GGI_DISPLAY DGA
`acceleration` は、相対的なポインタ動作イベントを発生するターゲット (例えば DGA) でのみ使用され、正の整数で相対的な距離に対する倍率 (積因 子) を表します。デフォルトの acceleration は 7 です。
例:
set term ggi acc 10
set term ggi acc 1 mode V1024x768
set term ggi V1024x768"
>>> この gnuplot は、'set term gif' が選択された場合、GIF <<< >>> 画像の代わりに PNG 画像を生成するように構築されました。 <<<
書式:
set terminal gif {transparent} {interlace}
{tiny | small | medium | large | giant}
{size <x>,<y>}
{<color0> <color1> <color2> ...}
`transparent` はドライバに透明化 (transparent) GIF を生成するよう指示 します。この場合最初の指定色が透明化される色になります。
`interlace` はドライバにインターレース GIF を生成するよう指示します。
フォントは `tiny` (5x8 ピクセル)、`small` (6x12 ピクセル), `medium` (7x13 Bold)、`large` (8x16)、`giant` (9x15 ピクセル) から選択します。
サイズ <x,y> はピクセル単位で与えます。デフォルトは 640x480 です。ピク セル数は size コマンドで縮尺することでも変更できます。
個々の色は 'xrrggbb' の形式で指定します。ここで、x はそのまま文字 'x' を意味し、'rrggbb' は赤、緑、青の 16 進数での成分です。例えば 'x00ff00' は緑を表します。背景色を最初に指定し、その後ろに境界色、X 軸と Y 軸の 色、グラフの描画色、と続きます。色数は最大 256 色まで設定できます。
例:
set terminal gif small size 640,480 \\
xffffff x000000 x404040 \\
xff0000 xffa500 x66cdaa xcdb5cd \\
xadd8e6 x0000ff xdda0dd x9500d3 # デフォルト
この例では透明化されない背景色が白で、境界は黒、軸は灰色、そして描画色 として赤、橙色、青緑色 (midium aquamarine)、アザミ色 (thistle 3)、明青 色 (light blue)、青、かきつばた色 (plum)、暗いすみれ色 (dark violet) の 8 色を使います。
set terminal gif transparent xffffff \\
x000000 x202020 x404040 x606060 \\
x808080 xA0A0A0 xC0C0C0 xE0E0E0
これは透明化される背景が白で、境界は黒、軸は暗い灰色、描画色はグレイス ケールで 6 色を使うことになります。
ページサイズは 640x480 ピクセルです。gif ドライバはカラー、または白 黒の出力を生成しますが、どちらを生成するかの制御はできません。
現在のバージョンの gif ドライバは、アニメーション GIF はサポートして いません。"
`gnugraph` ドライバは、デバイスに依存しない GNU の plot グラフィック言 語の出力を生成します。それを "plot2ps" で PostScript 形式の出力にした 大きさのデフォルトは 5 インチ x 3 インチです。これは size で約 8.25 x 8.25 まで増加させることが可能です。
書式:
set terminal gnugraph {"<fontname>"} {<fontsize>}
{type <pt>} {size "<size>"}
デフォルトは 10 ポイントの "Courier" です。
`type` には以下のオプションが追加できます: `X`, `pnm`, gif, `ai`, `ps`, cgm, fig, `pcl5`, hpgl, `tek`, `meta` (default)。 size オプション (default では a4) は、そのまま直接 plotutils に渡さ れますので、ユーザは正しい値を設定する義務を負います。詳細は plotutils のドキュメントを参照してください。
例:
set terminal gnugraph type hpgl size "a4"
set terminal gnugraph size "a4,xoffset=-5mm,yoffset=2.0cm" type pnm
非 GNU 版の `gnugraph` ドライバもありますが、それは GNU 版のを取り除か ないとコンパイルはされません。"
書式:
set terminal gpic {<x> <y>}
ここで `x` と `y` の単位はインチです。
単純なグラフを整形するには以下のようにします。
groff -p -mpic -Tps file.pic > file.ps
pic からの出力はパイプで eqn に渡すこともできるので、'set label' と `set {x/y}label` コマンドでグラフに複雑な関数の式を入れることも可能で す。例えば、
set ylab '@space 0 int from 0 to x alpha ( t ) roman d t@'
とすれば、以下のコマンドによって y 軸に綺麗な積分が見出し付けされます。
gpic filename.pic | geqn -d@@ -Tps | groff -m[macro-package] -Tps
> filename.ps
このようにして作られた図は文書に綺麗に当てはまるように縮尺することがで きます。pic 言語は簡単に理解できるので、必要なら容易にグラフを直接編集 できます。`gnuplot` で作られる pic ファイルの全ての座標は x+gnuplotx, y+gnuploty の形で与えられます。デフォルトでは x, y の値は 0 です。いく つかのファイルに対してその x,y を 0 と設定している行を削除すれば、以下 のようにして複数のグラフを一つの図の中に入れてしまうこともできます (デ フォルトの大きさは 5.0x3.0 インチ):
.PS 8.0
x=0;y=3
copy "figa.pic"
x=5;y=3
copy "figb.pic"
x=0;y=0
copy "figc.pic"
x=5;y=0
copy "figd.pic"
.PE
これは、横に 2 つ、縦に 2 つずつ並んだ 4 つのグラフからなる、8 インチ の広さの図を生成します。
以下のコマンドでも同じことができます。
set terminal gpic x y
これを例えば以下のように使います。
.PS 6.0
copy "trig.pic"
.PE"
色々なサイズのウィンドウが必要なら、apollo ドライバを代わりに使用し てください。"
書式:
set terminal hp500c {<res>} {<comp>}
ここで `res` は 75, 100, 150, 300 のいずれかの解像度 (DPI; dots per inch) で、`comp` は "rle" か "tiff" です。他の設定をするとそれはデフォ ルトの値になります。デフォルトは 75 dpi で圧縮はなしです。高解像度での ラスタライズはたくさんのメモリを必要とします。"
国際的文字セット ISO-8859-1 と CP850 を `set encoding iso_8859_1` や `set encoding cp850` で認識させることができます (詳細は encoding を参照してください)。
書式:
set terminal hpgl {<number_of_pens>} {eject}
以下の設定
set terminal hpgl 8 eject
は、以前の `hp7550` ドライバと同等で、設定
set terminal hpgl 4
は、以前の `hp7580b` ドライバと同等です。
`pcl5` ドライバは、Hewlett-Packard Designjet 750C、Hewlett-Packard Laserjet III, Hewlett-Packard Laserjet IV のようなプロッタをサポートし ます。これは実際には HPGL-2 を使用しているのですが、装置間で名前の衝突 があります。このドライバにはいくつかのオプションがありますが、それらは 以下に示した順序で指定しなければいけません:
書式:
set terminal pcl5 {mode <mode>} {<plotsize>}
{{color {<number_of_pens>}} | monochrome} {solid | dashed}
{font <font>} {size <fontsize>} {pspoints | nopspoints}
<mode> は `landscape` か `portrait` です。<plotsize> はグラフの物理的 な描画サイズで、それは以下のうちのいずれかです: `letter` は標準の (8 1/2" X 11") 出力、`legal` は (8 1/2" X 14") 出力、`noextended` は (36" X 48") 出力 (letter サイズ比)、`extended` は (36" X 55") 出力 (ほぼ legal サイズ比)。`color` は複数のペン (すなわちカラー) 描画用で <number_of_pens> はカラー出力で使用されるペンの本数 (すなわち色数) で す。`monochrome` は 1 本のペン (例えば黒) の描画です。`solid` は全ての 線を実線で描き、`dashed` は異なる点線や鎖線パターンで線を描き分けます。 <font> は `stick`, `univers`, `cg_times`, `zapf_dingbats`, `antique_olive`, `arial`, `courier`, `garamond_antigua`, `letter_gothic`, `cg_omega`, `albertus`, `times_new_roman`, `clarendon`, `coronet`, `marigold`, `truetype_symbols`, `wingdings` のいずれかです。<fontsize> はポイント 単位でのフォントの大きさです。点の種類 (point type) は、`nopspoints` を 指定することで標準的なデフォルトの設定から選択できるようになりますが、 `pspoints` を指定すると postscript terminal と同じ点の種類の設定から 選択できるようになります。
これらのオプションのいくつかの組み込まれたサポートは、プリンタに依存す ることに注意してください。例えば全てのフォントは恐らく HP Laserjet IV ではサポートされているでしょうが、HP Laserjet III と Designjet 750C で は 2,3 (例えば univers, stick) がサポートされているのみでしょう。 また、laserjet は白黒の出力装置なので、それらではカラーも明らかに使え ません。
デフォルト: landscape, noextended, color (6 pens), solid, univers, 12
point, nopspoints
`pcl5` では国際的文字セットはプリンタで扱われますので、テキスト文字列 に適切な 8-bit 文字コードを入れるだけで、わざわざ encoding で邪 魔をする必要はありません。
HPGL グラフィックは多くのソフトウェアパッケージで取り込むことが可能で す。"
書式:
set terminal hpljii | hpdj {<res>}
ここで `res` は 75, 100, 150, 300 のいずれかの解像度 (DPI; dots per inch) で、デフォルトは 75 です。高解像度でのラスタライズはたくさんのメ モリを必要とします。 hp500c ドライバは `hpdj` とほぼ同じですが、hp500c は加えてカラーと 圧縮もサポートしています。"
書式:
set terminal hppj {FNT5X9 | FNT9X17 | FNT13X25}
中間サイズフォント (FNT9X17) がデフォルトです。"
書式:
set terminal imagen {<fontsize>} {portrait | landscape}
{[<horiz>,<vert>]}
`fontsize` はデフォルトでは 12 ポイントで、レイアウトのデフォルトは `landscape` です。`<horiz>` と `<vert>` はグラフを横方向と縦方向に何列 置くかを指定します。これらのデフォルトは 1 です。
例:
set terminal imagen portrait [2,3]
これは、1 ページに 6 つのグラフを横に 2 列、縦に 3 列、縦置き (portrait) で配置します。"
書式:
set terminal latex | emtex {courier | roman | default} {<fontsize>}
`fontsize` には任意のサイズを指定します。デフォルトは、それを埋め込む 文書のフォントの設定を引き継ぎます。
あなたの DVI ドライバが任意のサイズのフォントを作り出すことができない 場合 (例えば dvips)、標準的な 10, 11, 12 ポイントサイズでなんとかしの いでください。
METAFONT ユーザへの警告: METAFONT は妙なサイズは好みません。
LaTeX に関する全てのドライバは文字列の配置の制御に特別な方法を提供しま す: '{' で始まる文字列は、'}' で閉じる必要がありますが、その文字列全体 が水平方向にも垂直方向にもセンタリングされます。'[' で始まる文字列の場 合は、位置の指定をする文字列 (t,b,l,r のうち 2 つまで) が続き、次に ']{'、文字列本体、で最後に '}' としますが、この文字列は LaTeX が LR-box として整形します。'\\rule{}{}' を使えばさらに良い位置合わせが可能でしょ う。
数ある中で、点 (point) は、LaTeX のコマンド "\\Diamond" と "\\Box" を使 って描かれます。これらのコマンドは現在は LaTeX2e のコアには存在せず、 latexsym パッケージに含まれていますが、このパッケージ基本配布の一部で あり、よって多くの LaTeX のシステムの一部になっています。このパッケー ジを使うことを忘れないでください。
例: 見出しの位置合わせに関して: gnuplot のデフォルト (大抵それなりになるが、そうでないこともある):
set title '\\LaTeX\\ -- $ \\gamma $'
水平方向にも垂直方向にもセンタリング:
set label '{\\LaTeX\\ -- $ \\gamma $}' at 0,0
位置を明示的に指定 (上に合わせる):
set xlabel '[t]{\\LaTeX\\ -- $ \\gamma $}'
他の見出し - 目盛りの長い見出しに対する見積り:
set ylabel '[r]{\\LaTeX\\ -- $ \\gamma $\\rule{7mm}{0pt}}'"
文書中で図を使うには、`gnuplot` の出力するファイルを入力として METAFONT プログラムを実行する必要があります。よって、ユーザはフォントが作られる プロセスと新しく作ったフォントをドキュメントに取り込むための基礎知識が 必要となります。しかし、使用するサイトで METAFONT プログラムが適切に設 定されていれば、経験のないユーザでもそう問題なく操作はできるでしょう。
グラフ中の文字は METAFONT の文字セットに基づいてサポートされます。現状 では Computer Modern Roman フォントセットが入力ですが、ユーザは必要な フォントを何でも自由に選ぶことができます。ただしその選んだフォントの METAFONT ソースファイルが使える状態になっている必要があります。個々の 文字は METAFONT の中で別々のピクチャー変数に保存され、文字が必要になっ たときにこれらの変数が操作 (回転、伸縮等) されます。欠点は、METAFONT プログラムが解釈に要する時間です。ある計算機 (つまり PC) では、ピクチ ャー変数をたくさん使用しすぎることで、使えるメモリの量の限界が問題を起 こすこともあります。 mf ドライバにはオプションはありません。
-- METAFONT INSTRUCTIONS --
- 出力形式 (terminal) を METAFONT にセット:
set terminal mf
- 出力ファイル名を設定。例えば:
set output "myfigures.mf"
- グラフの描画。各グラフは別々の文字を生成し、そのデフォルトの大きさは 5x3 インチですが、この大きさは `set size 0.5,0.5` のようにしてどんなサ イズにでも自由に変更できます。
- `gnuplot` を終了
- `gnuplot` の出力ファイルに対して METAFONT を実行し、TFM ファイルと GF ファイルを作ります。グラフは割と大きい (5x3 インチ) ので、memmax の値が 少なくとも 150000 である METAFONT を使う必要があるでしょう。Unix では、 それは通常 bigmf という名前でインストールされているでしょう。以下では、 virmf コマンドが big 版の METAFONT であると仮定し、実行例を示します:
- METAFONT の立ち上げ:
virmf '&plain'
- 出力装置の選択: METAFONT プロンプト ('*') 上で次のように打ちます:
\\mode:=CanonCX; % あなたの使用するプリンタを指定
- 拡大率 (magnification) の選択 (オプション):
mag:=1; % あなたの好みの値を指定
- `gnuplot` で作ったファイルを入力:
input myfigures.mf
典型的な Unix マシンでは、virmf '&plain' を実行するスクリプト "mf" が あるので、virmf &plain の代わりに mf を使えます。これにより mfput.tfm と mfput.$$$gf ($$$ は出力装置の解像度) の 2 つのファイルが作られます。 上の作業は、すべてをコマンドライン上で簡単に実行することもできます: virmf '&plain' '\\mode:=CanonCX; mag:=1; input myfigures.mf' この場合、作られるファイル名は myfigures.tfm と myfigures.300gf という 名前になります。
- gftopk を使って GF ファイルから PK ファイルを生成:
gftopk myfigures.300gf myfigures.300pk
gftopk が作るファイルの名前はあなたが使用する DVI ドライバに依存します ので、サイトの TeX の管理者にフォント名の規則について聞いてください。 次に TFM ファイルと PK ファイルを適当なディレクトリにインストールするか または環境変数を適切な値に設定します。通常それは、TEXFONTS にカレントデ ィレクトリを含めることと、あなたが使用する DVI ドライバが使用している環 境変数 (標準的な名前はありませんが ...) に対して同じことをやれば済みま す。これは TeX がフォントメトリック (TFM) ファイル を見つけ、DVI ドライ バが PK ファイルを見つけられるようにするために必要な作業です。
- 文書にそのグラフを入れるために TeX にそのフォント名を指示:
\\font\\gnufigs=myfigures
各グラフは、最初のグラフが文字 0、2 番目のグラフが文字 1 というように、 それぞれ一つの文字として保存されています。上記の作業を行なうと、グラフ はその他の文字と同じように使うことができ、例えばグラフ 1 と 2 を文書中 にセンタリングして置くために plain TeX ファイル中ですべきことは:
\\centerline{\\gnufigs\\char0}
\\centerline{\\gnufigs\\char1}
だけです。もちろん LaTeX では picture 環境を使って \\makebox と \\put マ クロで任意の位置にグラフを配置することができます。
このやり方は、一度フォントを生成してしまえば、大幅に時間の節約になりま す: TeX はグラフを文字として使い、それを配置するにはごく少ない時間しか 使用しませんし、グラフよりも文書の方が修正することが多いでしょうから。 そしてこれは TeX のメモリの節約にもなります。METAFONT ドライバを使うも う最後の一つの利点は、生成される DVI ファイルが本来のデバイス非依存な 形になるということです。それは eepic や tpic ドライバのような \\special コマンドを全く使わないからです。"
書式:
set term mp {color | colour | monochrome}
{solid | dashed}
{notex | tex | latex}
{magnification <magsize>}
{psnfss | psnfss-version7 | nopsnfss}
{prologues <value>}
{a4paper}
{amstex}
{"<fontname>"} {<fontsize>}
オプション `color` は線をカラーで書くことを意味し (それをサポートする プリンタやディスプレイ上で)、`monochrome` (または何も指定しない場合) は黒の線が選択されます。オプション `solid` は線を実線で描き、`dashed` (または無指定) は線を異なるパターンの点線で描き分けます。`solid` が指 定されてかつ `color` が指定されなかった場合、ほとんど全ての線が同じも のになりますが、これも何かの場合には有用でしょうから認められています。
オプション `notex` は完全に TeX を迂回しますので、このオプションの元で は見出しには TeX のコードは使うことができません。これは、古いグラフフ ァイル、あるいは TeX では特殊記号として解釈されてしまう `$` や `%` の ような一般的な文字をたくさん使うファイルのために用意されています。
オプション `tex` は、TeX で処理する文字列を出力するように設定します。
オプション latex は、LaTeX で処理する文字列を出力するように設定しま す。これによって TeX では使えないけれど LaTeX では使えるもの、例えば分 数を \\frac で書いたりすることができます。このオプションを使う場合は、 環境変数 TEX に LaTeX の実行プログラム名 (通常は latex) を設定するか、 あるいは `mpost -tex=<LaTeX の実行プログラム名> ...` とすることを忘れ ないでください。そうでないと metapost はテキストの処理に TeX を使おう として失敗してしまうでしょう。
TeX におけるフォントサイズの変更は数式には効果がなく、そのような変更を 行なうとても簡単な方法は、大域的に拡大率 (magnification factor) を設定 する以外にはありません。それがオプション `magnification` の意味です。 その場合は拡大率を後ろに指定する必要があります。全ての文字 (グラフでは なく) はこの率で拡大されます。数式をデフォルトの 10pt 以外の他のサイズ で書きたい場合はこれを使用してください。ただ残念なことに全ての数式が同 じサイズになってしまいますが、しかし、以下の MP 出力の編集に関する説明 を参照してください。`mag` は `notex` の元でも働きますが、それを行なう 意味がないくらい (以下に述べる) フォントサイズオプションはうまく働きま す。
オプション `psnfss` は postscript フォントを LaTeX と組み合わせて使用 します。このオプションは LaTeX が使われる場合のみ意味を持ちますので、 自動的に latex オプションが選択されます。このオプションは以下の LaTeX パッケージを使用します: inputenc(latin1), fontenc(T1), mathptmx, helvet(scaled=09.2), courier, latexsym, textcomp
オプション `psnfss-version7` も postscript フォントを LaTeX と組み合わ せて使用します (latex が自動的に選択されます) が、以下の LaTeX パッ ケージを使用します: inputenc(latin1), fontenc(T1), times, mathptmx, helvet, courier
オプション `nopsnfss` はデフォルトで、標準的なフォント (何も指定されて いなければ cmr10) が使われます。
オプション `prologues` は追加の値を引数に持ち、metapost ファイルに `prologues:=<その値>` という行を追加します。値として `2` を指定すると metapost は eps ファイルを作るように postscript フォントを使用し、それ によりその結果は例えば ghostscript などで参照できるようになります。標 準では metapost は TeX のフォントを使用しますので、それを参照するには (La)TeX のファイルに取り込む必要があります。
オプション `noprologues` はデフォルトで、prologue で指定したいかなる行 も追加されません。
オプション `a4paper` は `[a4paper]` を documentclass に追加します。標 準では letter 用紙 (デフォルト) が使われます。このオプションは LaTeX でのみ使われますので、自動的に latex オプションが選択されます。
オプション `amstex` は、自動的に latex オプションを選択し、以下の LaTeX パッケージを使用します: amsfonts, amsmath(intlimits)。デフォルト ではこれらは使用されません。
引用符で囲まれた名前はフォント名を表し、label や `set title` で 明示的にフォントが与えられない場合はこのフォントが使われます。フォント は TeX が認識できる (TFM ファイルが存在する) ものを使う必要があります。 デフォルトでは `notex` が選択されていなければ "cmr10" が、そうでなけれ ば "pcrr8r" (Courier) が使われます。`notex` の元でも、Metapost には TFM ファイルは必要です。`pcrr8r.tfm` は LaTeX psnfss パッケージの Courier フォント名として与えられています。`notex` のデフォルトからフォ ントを変更する場合は、少なくとも 32-126 のコード範囲は ASCII エンコー ディングに一致するものを選んでください。`cmtt10` もほぼ使えますが、し かしこれはコード 32 (スペース) にスペースではない文字が入っています。
サイズは 5.0 から 99.99 の間の任意の数字を指定でき、省略された場合は 10.0 が使われます。なるべく `magstep` サイズ、つまり 1.2 の整数かまた は 0.5 乗の 10 倍を小数以下 2 桁未満を丸めた値を使用することをお勧め します。それはそれが TeX のシステムで最もよく使われるフォントのサイズ だからです。
全てのオプションは省略可能です。フォントを指定する場合はそれは (必要な らサイズもつけて) 一番最後に指定する必要があります。フォント名にそのサ イズ情報が含まれていたとしても、サイズを変えるにはフォントサイズを指定 する必要があります。例えば `set term mp "cmtt12"` は cmtt12 をデフォル トのサイズである 10 に縮めて使います。それは多分望まないことでしょうし cmtt10 を使う方が良いでしょう。
以下の ascii 文字は、TeX では特別に扱われます:
$, &, #, %, _; |, <, >; ^, ~, \\, {, }
$, #, &, _, % の 5 つは、例えば `\\$` とすることで容易にそれをエスケー プできます。<, >, | の 3 つは、例えば `$<$` のように数式モードに入れて やればうまくいきます。残りのものに関しては少し TeX の回避策が必要にな りますが、適当なよい TeX の本がそれを指導してくれるでしょう。
見出しを二重引用符で囲む場合、TeX コードのバックスラッシュはエスケープ する (2 つ書く) 必要があります。単一引用符を使えばそれを避けることはで きますが、今度は改行として `\\n` を使えなくなります。これを書いている現 在、gnuplot 3.7 は `plot` コマンドで与えられたタイトルは、別な場所で与 えられた場合とは異なる処理をしますし、引用符のスタイルにかかわらず TeX コマンドのバックスラッシュは二重化した方が良さそうです。
Metapost の画像は TeX の文書内で一般に使われています。Metapost はフォ ントを TeX が行なうのと全く同じ方法で扱い、それは他の大抵の文書整形プ ログラムとは異なっています。グラフが LaTeX の文書に graphics パッケー ジで取り込まれ、あるいは epsf.tex を使って plainTeX に取り込まれ、そし て dvips (または他の dvi から ps への変換ソフト) で PostScript に変換 される場合、そのグラフ内の文字は大抵は正しく扱われているでしょう。しか し、Metapost 出力をそのまま PostScript インタプリタに送っても、グラフ 内の文字は出力されないでしょう。
-- METAPOST INSTRUCTIONS --
- まず terminal ドライバを Metapost に設定、例えば:
set terminal mp mono "cmtt12" 12
- 出力ファイルを選択、例えば:
set output "figure.mp"
- グラフを作成。各 plot (または multiplot の各グループ) はそれぞれ別な Metapost beginfig...endfig グループに分けられます。そのデフォルトのサ イズは 5x3 インチですが、それは `set size 0.5,0.5` とか、そうしたいと 思う適当な割合をそのように指定することで変更できます。
- gnuplot を終了。
- gnuplot の出力ファイルに対して Metapost を実行して EPS ファイルを作 成:
mpost figure.mp OR mp figure.mp
Metapost プログラム名はシステムに依存し、Unix では通常 `mpost` で、他 の多くのシステムでは mp です。Metapost は各グラフに対して 1 つずつの EPS ファイルを生成します。
- そのグラフを文書に取り込むには LaTeX graphics パッケージや、plainTeX では epsf.tex を使用:
\\usepackage{graphics} % LaTeX
\\input epsf.tex % plainTeX
TeX DVI 出力を PS に変換するのに、dvips 以外の DVI ドライバを使う場合 は、LaTeX ファイルに以下の行を入れる必要があるかも知れません:
\\DeclareGraphicsRule{*}{eps}{*}{}
作られた各グラフは分離したファイルになっていて、最初のグラフのファイル は、例えば figure.0, 2 つ目は例えば figure.1 のような名前になります。 よって、3 つ目のグラフを文書に取り込むためにあなたがしなければいけない ことは以下のみです:
\\includegraphics{figure.2} % LaTeX
\\epsfbox{figure.2} % plainTeX
mp ドライバの postscript ドライバに代わる利点は、もしあるとすれば、そ れは編集可能な出力であるということでしょう。この出力を可能な限り綺麗に するための、かなりの努力が払われました。Metapost 言語に関するそういっ た知識のおかげで、デフォルトの線種や色は配列 `lt[]` や `col[]` を編集 することで変更できるようになりました。実線/点線、カラー/白黒といった選 択も、真偽値として定義されている `dashedlines` や `colorlines` を変更 することで行なえます。デフォルトの `tex` オプションが有効な場合、ブロ ック `vebatimtex...etex` を編集することで、ラベル文字フォントに対する 大域的な変更が行なえます。特に、もし望むなら LaTeX のプリアンブルを追 加することもでき、その場合 LaTeX の持つサイズ変更コマンドを使えるので 最大の柔軟性を発揮できるでしょう。ただし、Metapost に plainTeX でなく LaTeX を実行させるよう、適切な MP 設定変数を設定することを忘れないでく ださい。"
MIF 3.00 ドライバではいくつかのオプションが設定できます。
書式:
set terminal mif {color | colour | monochrome} {polyline | vectors}
{help | ?}
`colour` は線種 (line type) >= 0 の線をカラー (MIF separation 2-7) で、 `monochrome` は全ての線を黒 (MIF separation 0) で描画します。 `polyline` は曲線を連続曲線として描画し、`vectors` は曲線をベクトルの 集まりとして描画します。 help と `?` はオンラインヘルプを標準エラー出力に表示します。両者はそ の使用法の短い説明を出力し、help は更にオプションも表示します。
例:
set term mif colour polylines # デフォルト
set term mif # デフォルト
set term mif vectors
set term mif help"
書式:
set terminal pbm {<fontsize>} {<mode>}
<fontsize> は `small` か `medium` か `large` で、<mode> は `monochrome` か `gray` か `color` です。デフォルトの描画サイズは 640 ピクセルの幅で 480 ピクセルの高さですが、これは size で変更できます。 pbm ドライバの出力は <mode> によります: `monochrome` は portable bitmap (PBM; 1 ピクセル 1 ビット) を、`gray` は portable graymap (PGM; 1 ピクセル 3 bit) を、`color` は portable pixmap (PPM; 1 ピクセル 4 ビ ット) を出力します。
このドライバの出力は Jef Poskanzer の優れた PBMPLUS パッケージで使うこ とができ、このパッケージは上記の PBMPLUS フォーマットから GIF, TIFF, MacPaint Macintosh PICT, PCX, X11 ビットマップ、その他多くの形式に変換 するプログラムを提供します。PBMPLUS は ftp.x.org から取得できます。フ ァイル名は "netpbm-1mar1994.p1" で始まり、/contrib/utilities にありま す。このパッケージは多分 ftp.x.org の他の多くのミラーサイトからも取得 できるでしょう。
例:
set terminal pbm small monochrome # デフォルト
set size 2,2; set terminal pbm color medium"
このドライバは Adobe PDF (Portable Document Format) 出力を生成し、それ は Acrobat Reader のようなツールで表示、印刷ができます。
書式:
set terminal pdf {fname "<font>"} {fsize <fontsize>}
{{no}enhanced}
<font> はデフォルトで使われるフォント名 (デフォルトでは Helvetica) で <fontsize> はポイント単位でのフォントサイズ (デフォルトでは 12) です。"
オプション `enhanced` は、拡張テキスト処理機能 (下付き文字、上付き文字、 および複数のフォントの利用) を有効にします。詳細は `enhanced` を参照し てください。フォントは PDF の標準的なフォント (core PDF font) のみがサ ポートされています。"
`png` ドライバは PNG (Portable Network Graphics) をサポートします。こ の古い版の png ドライバを使うには公開ライブラリである "libpng" と "zlib" が必要です。より多くの機能を持つ、新しい版の PNG ドライバもあり ますので、libgd の version 1.8 以降を持っているならそちらの方が良いで しょう。
書式:
set terminal png {small | medium | large}
{transparent|notransparent}
{picsize <xsize> <ysize>}
{monochrome | gray | color}
{<color0> <color1> <color2> ...}
`transparent` はドライバに透明化 (transparent) PNG を生成するよう指示 します。この場合最初の指定色が透明化される色になります。
デフォルトは `small` (小さいのフォント) で `color` です。デフォルトの 出力サイズは 640*480 ピクセルですが、それはオプション `picsize` で変更 できます。
個々の色 (<color>) は 'xrrggbb' の形式で指定します。ここで、x はそのま ま文字 'x' を意味し、'rrggbb' は赤、緑、青の 16 進数での成分です。例え ば 'x00ff00' は緑を表します。背景色を最初に指定し、その後ろに境界色、 X 軸と Y 軸の色、グラフの描画色、と続きます。色数は現在のところ最大 99 色まで設定できます。"
`postscript` ドライバではいくつかのオプションが設定できます。
書式:
set terminal postscript {<mode>} {enhanced | noenhanced}
{color | colour | monochrome}
{blacktext | colortext | colourtext}
{solid | dashed} {dashlength | dl <DL>}
{linewidth | lw <LW>}
{<duplexing>}
{rounded | butt}
{fontfile [add | delete] "<filename>"}
{palfuncparam <samples>{,<maxdeviation>}}
{"<fontname>"} {<fontsize>}
<mode> は `landscape` か `portrait` か `eps` か `default` で、 `enhanced` は拡張テキストモード (上付き文字、下付き文字、および複数の フォントの利用) の機能を有効にします。詳細は `enhanced` を参照してくだ さい。 オプション `color` はカラーを有効にし、 `blacktext` は、たとえカラーモードでも全ての文字列を黒で書きます。 `solid` は全てのグラフの点線のパターンを実線で上書きします。 `dashlength` または `dl` は点線の線分の長さを <DL> (0 より大きい実数) に設定し、 `linewidth` または `lw` は全ての線の幅を <LW> に設定します。 <duplexing> は `defaultplex` か `simplex` か `duplex` です (PostScript の "duplexing" はプリンタの 1 ページ両面印刷の機能を有効にします。あな たのプリンタがそれを行なえないなら設定しないでください)。 `rounded` は、線の端や接合部を丸くし、デフォルトの `butt` は尖った端と 角張った接合部を使用します。 `"<fontname>"` は有効な PostScript フォントの名前で、`<fontsize>` は PostScript ポイント単位でのフォントの大きさです。 標準的な postscript フォント以外に、数式を表現するのに便利な oblique Symbol フォント ("Symbol-Oblique") が定義されています。
`default` モードは全てのオプションを以下のデフォルトの値に設定します: `landscape`, `monochrome`, `dashed`, `dl 1.0`, `lw 1.0`, `defaultplex`, `noenhanced`, "Helvetica", 14pt。PostScript のグラフのデフォルトの大き さは、10 インチの幅で 7 インチの高さです。
`palfuncparam` は pm3d を有効にしてコンパイルした場合のみ使用できま す。これは `set palette functions` から出力の傾きをどのようにコード化 するかを制御します。解析的な色の成分関数 (`set palatte functions` で設 定される) は、postscript 出力では傾きの線形補完を用いてコード化されま す: まず色の成分関数が <samples> 個の点で標本化され、そしてそれらの点 は、結果として線形補完との偏差が <maxdeviation> 以内に収まるように削除 されます。ほとんど全ての有効なパレットで、デフォルトの <samples>=2000 と <maxdeviation>=0.003 の値をそのまま使うのが良いでしょう。
`eps` モードは EPS (Encapsulated PostScript) 出力を生成しますが、これ は通常の PostScript に、それを他の多くのアプリケーションで取り込むこと ができるようにいくつかの行を追加したものです (追加される行は PostScript のコメント行なので、よってそれ自身もちゃんと印刷できます)。EPS 出力を 得るには `eps` モードを使用し、1 つのファイルには 1 つのグラフのみ、と してください。`eps` モードではフォントも含めてグラフ全体がデフォルトの 大きさの半分に縮められます。
`fontfile` や `fontfile add` で指定されたフォントは、そのフォントのフ ォント定義を直接 postscript Type 1, TrueType フォントから gnuplot の postscript 出力の中にカプセル化します。よって、その埋め込まれたフォン トは見出し、タイトルなどに使うことができます。詳細は `postscript fontfile` を参照してください。 `fontfile delete` によってフォントファイルを埋め込まれるファイルの一覧 から取り除くことができます。
例:
set terminal postscript default # 以前の postscript
set terminal postscript enhanced # 以前の enhpost
set terminal postscript landscape 22 # 以前の psbig
set terminal postscript eps 14 # 以前の epsf1
set terminal postscript eps 22 # 以前の epsf2
set size 0.7,1.4; set term post portrait color "Times-Roman" 14
set term post "VAGRoundedBT_Regular" 14 fontfile "bvrr8a.pfa"
線の幅と点の大きさは `set style line` で変更できます。
`postscript` ドライバは約 70 種類の異なる点種をサポートしていて、これ は `plot` や `set style line` の `pointtype` オプションで選択できます。
`gnuplot` と Postscript に関する多分有用と思われるファイルが `gnuplot` の配布物、またはその配布サイトの /docs/psdos サブディレクトリ内にいく つか含まれています。そこには "ps_symbols.gpi" (実行すると `postscript` ドライバで使える全ての記号を紹介する "ps_symbols.ps" というファイルを生 成する `gnuplot` のコマンドファイル)、"ps_guide.ps" (拡張された書式に 関する要約と、文字列内で 8 進コードで生成されるもの、symbol フォント等 を含む PostScript ファイル)、"ps_file.doc" (`gnuplot` で作られる PostScript ファイルの構造の説明を含むテキストファイル)、 "ps_fontfile_doc.tex" (数式フォントの文字の一覧と LaTeX のフォントの埋 め込みに関する短い説明を含む LaTeX ファイル) があります。
PostScript ファイルは編集可能で、一度 `gnuplot` でそれを作れば、それを 望むように修正することは自由に行なえます。`editing postscript` の節を 参照すればそのためのヒントがいくつか得られるでしょう。
-- ENHANCED POSTSCRIPT --
いくつかの出力形式では拡張テキストモードをサポートしていて、これはテキ スト文字列中に文書整形情報を追加して埋め込みます。"
制御記号 例 説明
^ a^x 上付き文字
_ a_x 下付き文字
@ @x or a@^b_c 空ボックス (幅がない)
& &{space} 指定した長さのスペースを挿入
~ ~a{.8-} 'a' の上に '-' を、現在のフォントサイズの
.8 倍持ち上げた位置に重ね書き
中カッコは一文字が期待される箇所に複数の文字を書く場合に使われます (例 えば 2^{10})。フォント、およびそのサイズを変更するには、以下の形式を使 ってください: {/[fontname][=fontsize | *fontscale] text} よって、例え ば {/Symbol=20 G} は 20 ポイントのガンマに、{/*0.75 K} は現在の有効な フォントサイズの 3/4 の大きさの K になります (文字 '/' は、必ず '{' の 後ろの最初の文字でなくてはなりません)。 encoding によって文字エンコード系が変更されている場合、'/' の次 に '-' を書くとデフォルトの文字エンコード系が代わりに使われます。しか し、これは Symbol フォントを使う場合は必要ありません。それは /Symbol は自分自身のエンコード系を使い、`gnuplot` は他のエンコーディング系をそ れには適用しないからです。
空ボックス (phantom box) は a@^b_c の上付き文字と下付き文字を揃えると きに有用ですが、文字にアクセント記号を重ねる場合にはうまく働きません (後者を行なうには `set encoding iso_8859_1` で ISO Latin-1 エンコーデ ィング系に変更し、そこに含まれるたくさんの種類のアクセントや他のダイア クリティカルマークのついた文字を利用する方がいいでしょう)。そのボック スはスペーシングが行なわれないので、ボックス内 (つまり @ の後ろ) の上 付き文字や下付き文字を短く出力するのに適しています。
ある文字列と同じ長さのスペースを文字 '&' を使うことで入れることができ ます。すなわち、
'abc&{def}ghi'
は以下を生成します (abc と ghi の間は 3 文字分の空白):
'abc ghi'
文字 '~' は、次の文字、またはカッコで囲まれた文字列に、それに続く文字 またはカッコで囲まれた文字列を重ね書きします。2 番目の文字は最初の文字 にあわせて水平方向にセンタリングされます。よって '~a/' は 'a' を貫くよ うなスラッシュが得られます。2 番目の文字は、その前に数字を置くことで垂 直方向に移動させることができます。その数字は現在のフォントサイズに対す る割合を意味し、それに従って文字が上がったり下がったりします。この場合 数字と文字列は 1 文字より長くなるのでカッコで囲む必要があります。重ね 書きされる文字列が数字から始まっている場合は、垂直にずらす値と文字列と の間にスペースを入れてください ('~{abc}{.5 000}')。それ以外はスペース は不要です ('~{abc}{.5--}')。一方、あるいは両方のフォントを変更するこ ともできます ('~a{.5 /*.2 o}' -- 'a' その 1/5 の大きさの 'o' -- この 場合数字とスラッシュの間のスペースは必要です) が、その文字列が始まった 後で変更することはできません。それぞれの文字列内で、他の特殊な書式を使 うこともできません。もちろん、'~a{\\^}' のように特殊な文字をエスケープ すること (下記参照) は可能です。
\\文字コード (8 進数) を指定することで特殊な記号を指定することができま す。例えば、{/Symbol \\245} は無限大の記号になります。
制御文字は、 \\\\ や \\{ などのように \\ を使ってエスケープできます。
しかし、二重引用符内の文字列は単一引用符内の文字列とは異なって解釈され ることを知っておいてください。主な違いは、二重引用符内の文字列ではバッ クスラッシュは 2 つ重ねる必要があることです。
例 (これらは言葉で説明するのは難しいのでとりあえずやってみてください):
set xlabel 'Time (10^6 {/Symbol m}s)'
set title '{/Symbol=18 \\362@_{/=9.6 0}^{/=12 x}} \\
{/Helvetica e^{-{/Symbol m}^2/2} d}{/Symbol m}'
`gnuplot` ソース配布物内の /docs/psdoc サブディレクトリにあるファイル "ps_guide.ps" に、拡張された書式に関する例が更に載っています。
-- EDITING POSTSCRIPT --
PostScript 言語はとても複雑な言語で、ここで詳細を記述することはとても できません。それでも、`gnuplot` で作られる PostScript ファイルには、致 命的なエラーをそのファイルに導入してしまう危険性のない変更を行なうこと が可能な部分があります。
例えば、PostScript の文 "/Color true def" (`set terminal postscript color` コマンドに答えてファイルに書き込まれます) を変更して、その描画を白黒の ものにする方法はおわかりでしょう。同様に、線の色、文字の色、線の太さ (weight)、記号のサイズも、本当に簡単に書き換えられるでしょう。タイトル や見出しなどの文字列の誤植や、フォントの変更も編集可能でしょう。任意の ものの配置も変更できますし、もちろん、任意のものを追加したり、削除した りもできますが、それらの修正は PostScript 言語の深い知識が必要でしょう。
`gnuplot` によって作られる PostScript ファイルの構成に関しては、gnuplot のソース配布物内の docs/ps ディレクトリのテキストファイル "ps_file.doc" に述べられています。
-- POSTSCRIPT FONTFILE --
オプション `fontfile` または `fontfile add` は 1 つのファイル名を引数 として持ち、そのファイルを postscript 出力内にカプセル化して埋め込み、 それによって様々な文字列要素 (ラベル、目盛り見出し、タイトル等) をその フォントで出力することを可能にします。オプション `fontfile delete` も 1 つのファイル名を引数に持ち、そのファイル名をカプセル化されるファイル のリストから削除します。
postscript 出力ドライバはいくつかのフォントファイル形式を認識します: ASCII 形式の Type 1 フォント (拡張子 ".pfa")、バイナリ形式の Type 1 フ ォント (拡張子 ".pfb")、TrueType フォント (拡張子 ".ttf")。pfa ファイ ルは直接認識されますが、pfb と ttf ファイルは gnuplot の実行中に並行し て変換され、そのために適切な変換ツール (下記参照) がインストールされて いる必要があります。ファイル名は拡張子も含めて完全な形で指定する必要が あります。各 `fontfile` オプションはちょうど一つのフォントファイル名に 対応しますので、複数のフォントファイルを埋め込むためにはこのオプション を複数回使って下さい。
フォントファイルは、作業ディレクトリ、そして fontpath で与えられ るフォントパス一覧の全てのディレクトリが検索されます。さらに、環境変数 GNUPLOT_FONTPATH でフォントパスを設定することもできます。それが設定さ れていない場合はデフォルトの検索リストが使われますが、これはシステムに 依存します。詳細は fontpath を参照して下さい。
埋め込まれたフォントファイルを使うには、フォント名 (通常ファイル名と同 じではありません) を指定する必要があります。対話モードで `fontfile` オ プションを使ってフォントを埋め込んだ場合、フォント名はスクリーンに表示 されます。例:
Font file 'p052004l.pfb' contains the font 'URWPalladioL-Bold'. Location:
/usr/lib/X11/fonts/URW/p052004l.pfb
pfa や pfb フォントでは、フォント名はフォントファイル内に見つけること ができます。フォントファイル中に "/FontName /URWPalladioL-Bold def" の ような行がありますが、この真中の物から / を除いたものがフォント名です。 この例の場合は "URWPalladioL-Bold" となります。 TrueType フォントでは、フォント名はバイナリ形式で保存されているので見 つけるのは容易ではありません。さらに、その名前は多くの場合、Type 1 フ ォント (実行中に TrueType が変換される形式である) ではサポートされてい ない、スペースを含んだ形式になっています。そのため、フォント名はそこか らスペースを取り除いた形に変換されます。gnuplot で使うために生成された フォント名が何であるかを知る最も簡単な方法は、gnuplot を対話モードで起 動して、以下のように入力することです: "set terminal postscript fontfile '<filename.ttf>'".
フォントファイルを pfa 形式に変換するために、フォントファイルを読んで、 そして変換結果を標準出力に吐き出す変換ツールが必要になります。pfb ファ イルに対しては、例えば "pfbtops" が使えます。それがシステムにインスト ールされていれば、実行中の変換はうまく行くはずです。pfb ファイルのカプ セル化をちょっとやってみましょう。もしプログラムの変換時に正しくツール を呼び出していない場合は、どのようにツールを呼び出したら良いかを環境変 数 GNUPLOT_PFBTOPFA に、例えば "pfbtops %s" のように定義して下さい。 `%s` はフォントファイル名を意味しますので、それがその文字列に必ず必要 です。 実行中の変換をしたくなくて、けれども pfa 形式のファイルは必要である場 合、"pfb2pfa" という C で書かれた簡単なツールを使えば良いでしょう。こ れは大抵の C コンパイラでコンパイルでき、たくさんの ftp サーバに置いて あります。例えば ftp://ftp.dante.de/tex-archive/fonts/utilities/ps2mf/ 実際に "pfbtopfa" と "pfb2ps" は同じ作業を行います。"pfbtops" は結果の pfa コードを標準出力に出力しますが、"pfbtopfa" はファイルに出力します。
TrueType フォントは、例えば "ttf2pt1" というツールを使って Type 1 pfa フォーマットに変換できます。これは以下にあります: http://ttf2pt1.sourceforge.net/ もし gnuplot に組み込まれている変換手順がうまく行かない場合、変換コマ ンドは環境変数 GNUPLOT_TTFTOPFA で変更できます。ttf2pt1 を使う場合は、 それを "ttf2pt1 -a -e -W 0 %s - " のように設定して下さい。ここでも `%s` はファイル名を意味します。
特殊な用途のために、パイプも使えるようになっています (パイプをサポート している OS 上で)。ファイル名を "<" で始め、その後にプログラム呼び出し を追加します。そのプログラム出力は標準出力への pfa データでなければい けません。結果として pfa ファイルを、例えば以下のようにしてアクセスで きることになります: `set fontfile "< cat garamond.pfa"`。
Type 1 フォントを取り込むことは、例えば LaTeX 文書中に postscript ファ イルを取り込む場合に使えます。pfb 形式の "european computer modern" フ ォント ("computer modern" フォントの一種) が各地の CTAN サーバに置かれ ています。 ftp://ftp.dante.de/tex-archive/fonts/ps-type1/cm-super/ 例えば、ファイル "sfrm1000.pfb" は、中太、セリフ付き、立体の 10 ポイン トのフォント (フォント名 "SFRM1000") です。computer modern フォントは 今でも数式を書くのに必要ですが、それは以下にあります: ftp://ftp.dante.de/tex-archive/fonts/cm/ps-type1/bluesky これらによって、TeX 用の任意の文字も使えます。しかし、computer modern フォントは少しエンコーディングがおかしくなっています (このため、文字列 には cmr10.pfb の代わりに sfrm1000.pfb を使うべきです)。 TeX フォントの使用法はいくつかのデモの一つで知ることができます。 `gnuplot` のソース配布物の /docs/psdoc に含まれるファイル "ps_fontfile_doc.tex" に TeX 数学フォントの文字の一覧表が含まれていま す。
フォント "CMEX10" (ファイル "cmex10.pfb") を埋め込むと、gnuplot は 追加フォント "CMEX10-Baseline" も定義します。それは、他の文字にあうよ うに垂直方向にずらされたものです (CMEX10 は、記号の天辺にベースライン があります)。"
`pslatex` と `pstex` ドライバは、それぞれ LaTeX と TeX で後処理される 出力を生成する。`pstex` で生成される図は、任意の plain-TeX ベースの TeX (LaTeX もそうです) で取り込むことができます。
書式:
set terminal [pslatex | pstex] {<color>} {<dashed>} {<rotate>}
{auxfile} {<font_size>}
<color> は `color` か `monochrome`、<dashed> は `dashed` か `solid`、 また <rotate> は `rotate` か `norotate` で、それは y-軸の見出しを回転 するかどうかを決定します。<font_size> は希望するフォントの (ポイント単 位での) 大きさです。
`auxfile` が指定されると、ドライバは PostScript コマンドを、LaTeX ファ イルに直接出力する代わりに、補助ファイルに書き出すようになります。これ は、dvips がそれを扱えないくらい大きいグラフである場合に有用です。補助 PostScript ファイルの名前は、output コマンドで与えられる TeX フ ァイルの名前から導かれるもので、それはその最後の `.tex` の部分 (実際の ファイル名の最後の拡張子の部分) を `.ps` で置き換えたもの、または、TeX ファイルに拡張子がないならば `.ps` を最後に付け足したものになります。 `gnuplot` を終了する前に出力ファイルを閉じることを忘れないでください。 `.ps` ファイルは \\special{psfile=...} という命令で `.tex` ファイルに取 り込まれます。むしろ \\includegraphics{...} で取り込まれる方がいいなら、 epslatex 出力形式を使ってください。
LaTeX に関する全てのドライバは文字列の配置の制御に特別な方法を提供しま す: (a) '{' で始まる文字列は、'}' で閉じる必要がありますが、その文字列 全体が LaTeX によって水平方向にも垂直方向にもセンタリングされます。 (b) '[' で始まる文字列の場合は、位置の指定をする文字列 (t,b,l,r のうち 2 つまで) が続き、次に ']{'、文字列本体、で最後に '}' としますが、この 文字列は LaTeX が LR-box として整形します。\\rule{}{} を使えばさらに良 い位置合わせが可能でしょう。
例:
set term pslatex monochrome dashed rotate # デフォルトに設定
PostScript コマンドを "foo.ps" に書き出す:
set term pslatex auxfile
set output "foo.tex"; plot ...; set output
見出しの位置合わせに関して: gnuplot のデフォルト (大抵それなりになるが、そうでないこともある):
set title '\\LaTeX\\ -- $ \\gamma $'
水平方向にも垂直方向にもセンタリング:
set label '{\\LaTeX\\ -- $ \\gamma $}' at 0,0
位置を明示的に指定 (上に合わせる):
set xlabel '[t]{\\LaTeX\\ -- $ \\gamma $}'
他の見出し - 目盛りの長い見出しに対する見積り:
set ylabel '[r]{\\LaTeX\\ -- $ \\gamma $\\rule{7mm}{0pt}}'
線幅と点の大きさは `set style line` で変更できます。"
PSTricks は anonymous ftp で Princeton.EDU の /pub ディレクトリから取 得できます。このドライバは、PSTricks パッケージの全ての能力を使おうと などとは全く考えてはいません。
書式:
set terminal pstricks {hacktext | nohacktext} {unit | nounit}
最初のオプションは、あまり綺麗ではない方法で数字のより良い出力を生成す るもので、2 つ目のオプションはグラフを縮尺する際には必要です。デフォル トでは `hacktext` と `nounit` です。"
書式:
set terminal regis {4 | 16}"
書式:
set terminal rgip | uniplex {portrait | landscape}
{[<horiz>,<vert>]} {<fontsize>}
フォントサイズは 1-8 間での値が許されていて、デフォルトでは 1 です。 デフォルトの方向 (layout) は横置き (landscape) です。グラフはそのペー ジに `horiz`x`vert` 個が格子状に配置されます。デフォルトは [1,1] です。
例:
set terminal uniplex portrait [2,3]
これは 1 ページ 6 つのグラフを横に 2 つ縦に 3 つ並べ、縦置き (portrait) に出力します。"
このドライバは W3C SVG (Scalable Vector Graphics) フォーマットを生成し ます。
書式:
set terminal svg {size <x> <y> {|fixed|dynamic}}
{fname "<font>"} {fsize <fontsize>}
{{no}enhanced} {fontfile <filename>}
ここで <x> と <y> は生成される SVG グラフのサイズですが、`dynamic` は svg ビューワに描画のリサイズを許し、`fixed` は絶対サイズを要求します (デフォルト)。
<font> はデフォルトとして使われるフォント名 (デフォルトでは Arial)、 <fontsize> はポイント単位でのフォントサイズ (デフォルトは 12) です。 ただし、gnuplot は、今のところ出力ファイルへのフォントの埋め込み機能 をサポートしていませんので、svg ビューワソフトはそのファイルの表示の 際には別の代用フォントを使うことになるでしょう。
svg 出力形式は拡張テキスト処理機能 (enhanced) をサポートしています。 これはフォント指定や他の書式命令をラベルや他の文字列内に埋め込むこと を可能にします。拡張テキスト処理モードの書式指定は他の出力形式の場合 と同じです。詳細は `enhanced` を参照してください。
SVG では、SVG 文書中にフォントを直接埋め込むこともできますし、好きな フォントへのハイパーリンクを与えることもできます。`fontfile` オプシ ョンには、結果として出力される SVG ファイルの <defs> セクションの中 にコピーされるローカルファイル名を指定します。このファイルは、それ自 身がフォントを含んでいるか、または期待するフォントを参照するハイパー リンクを生成するための行を含むもののどちらかです。gnuplot は、環境変 数 GNUPLOT_FONTPATH のディレクトリリストから要求されたファイルを探し ます。"
その数字を参照したい場合のために、それをスクリーンに表示したりファイル にセーブしたりすることができます。これは、等高線を生成してそれを後々の ため、恐らくは `plot` で表示するために保存する場合などに有用です。一つ 例がありますので contour を参照してください。同じ方法は、補間デ ータを保存するのにも使われます (samples と dgrid3d を参照 してください)。"
このドライバ群は VT-ライクな端末のいくつかをサポートします。`tek40xx` は Tektronix 4010 とその他ほとんどの TEK エミュレータをサポートします。 `vttek` は VT-ライクな tek40xx 端末エミュレータをサポートします。 `kc-tek40xx` は、カラーの MS-DOS Kermit Tek4010 ターミナルエミュレータ を、`km-tek40xx` はその白黒版をサポートします。`selanar` は Selanar グ ラフィック端末をサポートします。`bitgraph` は BBN Bitgraph 端末をサポ ートします。いずれもオプションはありません。"
数ある中で、点 (point) は、LaTeX のコマンド "\\Diamond", "\\Box" などを 使って描かれます。これらのコマンドは現在は LaTeX2e のコアには存在せず latexsym パッケージに含まれていますが、このパッケージ基本配布の一部で あり、よって多くの LaTeX のシステムの一部になっています。このパッケー ジを使うことを忘れないでください。
オプションはありません。"
Tgif は X11 ベースのドローツールです -- ただし、これは GIF に関して何 かするわけではありません。 tgif ドライバは複数の点の大きさ (pointsize で)、複数の見出し用 のフォント、フォントサイズ (例えば `set label "Hallo" at x,y font "Helvetica,34"`)、そして 1 ページ内の複数のグラフ描画をサポートします。 軸の比率は変更されません。
書式:
set terminal tgif {portrait | landscape} {<[x,y]>}
{solid | dashed}
{"<fontname>"} {<fontsize>}
<[x,y]> にはそのページ内の x 方向、y 方向のグラフの数を指定し、 "<fontname>" には有効な PostScript フォント名、<fontsize> はその PostScript フォントの大きさを指定します。デフォルトでは `portrait`, `[1,1]`, `dashed`, `"Helvetica"`, `18` です。
`solid` オプションは、編集作業中にそうであるように、線がカラーである場 合に普通使われます。ハードコピーは白黒になることが多いので、その場合は `dashed` を選択すべきでしょう。
多重描画 (multiplot) は 2 種類の方法で実装されています。
その一つは、標準的な gnuplot の多重描画のやり方です:
set terminal tgif
set output "file.obj"
set multiplot
set origin x01,y01
set size xs,ys
plot ...
...
set origin x02,y02
plot ...
set nomultiplot
より詳しい情報については multiplot を参照してください。
もう一つの方法はドライバの [x,y] オプションです。この方法の長所は、原 点 (origin) や大きさ (size) の設定をしなくても全てのグラフが自動的に縮 尺され配置されることです。グラフの比 x/y は、自然な比 3/2 (または size で設定されたもの) が保持されます。
両方の多重描画の実装が選択された場合、標準的なやり方の方が選択され、警 告のメッセージが表示されます。
単一描画 (または標準的な多重描画) の例:
set terminal tgif # デフォルト
set terminal tgif "Times-Roman" 24
set terminal tgif landscape
set terminal tgif landscape solid
ドライバの持つ多重描画の仕組みを利用する例:
set terminal tgif portrait [2,4] # 縦置、x-方向に 2 つ、y-方向
# に 4 つのグラフ描画
set terminal tgif [1,2] # 縦置、x-方向に 1 つ、y-方向
# に 2 つのグラフ描画
set terminal tgif landscape [3,3] # 横置、両方の方向に 3 つのグ
# ラフ描画"
このドライバは Tcl/Tk ベース (デフォルト)、または Perl ベースの Tk canvas widget コマンドを生成します。これを使うには、"term.h" のこのド ライバに対応する行のコメント記号を外すか適当な行を書き加えて `gnuplot` を make し直して、以下のように実行します。
gnuplot> set term tkcanvas {perltk} {interactive}
gnuplot> set output 'plot.file'
そして "wish" を起動した後で、以下の Tcl/Tk コマンド列を実行してくださ い:
% source plot.file
% canvas .c
% pack .c
% gnuplot .c
Perl/Tk の場合は以下のようにしてこのプログラムを使います:
use Tk;
my $top = MainWindow->new;
my $c = $top->Canvas->pack;
my $gnuplot = do "plot.pl";
$gnuplot->($c);
MainLoop;
`gnuplot` によって生成されたコードは "gnuplot" と呼ばれる手続きを作り、 それはその引数を canvas の名前とします。その手続きが呼ばれると、それは canvas をクリアし、canvas のサイズを見つけ、その中に丁度収まるようにグ ラフを書きます。
2 次元の描画 (`plot`) では 2 つの手続きが追加されて定義されます: "gnuplot_plotarea" は描画範囲の境界を含むリスト "xleft, xright, ytop, ybot" を canvas スクリーン座標で返し、2 つの対の軸の描画座標での範囲 "x1min, x1max, y1min, y1max, x2min, x2max, y2min, y2max" は手続き "gnuplot_axisranges" を呼べば得られます。"interactive" オプションを指 定すると、canvas の線分上でマウスをクリックするとその線分の中点の座標 が標準出力に出力されるようになります。さらに、"user_gnuplot_coordinates" という手続きを定義することで、それに代わる新たな動作を起こすことも可能 です。その手続きには以下の引数が渡されます: "win id x1s y1s x2s y2s x1e y1e x2e y2e x1m y1m x2m y2m"、これらは、canvas の名前、線分の id、 2 つの座標系でのその線分の開始点の座標、終了点の座標、そして中点の座標 です。中点の座標は対数軸に対してのみ与えられます。 tkcanvas の現在の版では multiplot も replot もサポートしていませ ん。"
書式:
set terminal tpic <pointsize> <linewidth> <interval>
pointsize と `linewidth` は整数でミリインチ単位、`interval` は実数で
単位はインチです。正でない値を指定するとデフォルトの値が使われます。デ
フォルトでは pointsize = 40, linewidth = 6, interval = 0.1 です。
LaTeX に関する全てのドライバは文字列の配置の制御に特別な方法を提供しま す: '{' で始まる文字列は、'}' で閉じる必要がありますが、その文字列全体 が LaTeX によって水平方向にも垂直方向にもセンタリングされます。'[' で 始まる文字列の場合は、位置の指定をする文字列 (t,b,l,r のうち 2 つまで) が続き、次に ']{'、文字列本体、で最後に '}' としますが、この文字列は LaTeX が LR-box として整形します。\\rule{}{} を使えばさらに良い位置合わ せが可能でしょう。
例: 見出しの位置合わせに関して: gnuplot のデフォルト (大抵それなりになるが、そうでないこともある):
set title '\\LaTeX\\ -- $ \\gamma $'
水平方向にも垂直方向にもセンタリング:
set label '{\\LaTeX\\ -- $ \\gamma $}' at 0,0
位置を明示的に指定 (上に合わせる):
set xlabel '[t]{\\LaTeX\\ -- $ \\gamma $}'
他の見出し - 目盛りの長い見出しに対する見積り:
set ylabel '[r]{\\LaTeX\\ -- $ \\gamma $\\rule{7mm}{0pt}}'"
このドライバは、GNU 版の plot を使っている環境ではコンパイルされません。 その場合は代わりに `gnugraph` ドライバ (terminal) を利用してください。"
ドライバ vgagl はマウスと pm3d を完全にサポートした、linux の高速な コンソールドライバです。デフォルトモードの設定には 環境変数 SVGALIB_DEFAULT_MODE を参照しますが、設定されていない場合は 256 色モー ドで有効な解像度のうち最も高いものを選択します。
書式:
set terminal vgagl \\
background [red] [[green] [blue]] \\
[uniform | interpolate] \\
[dump "file"] \\
[mode]
カラーモードは mode オプションで与えることもできます。G1024x768x256 の ような記号的名称や整数で与えることができます。オプション `background` は [0, 255] の範囲の整数 1 つ、または 3 つの組を取ります。整数 1 つの 場合はそれは背景の灰色の値と見なされ、3 つの組の場合はそれに対応した色 が背景に取られます。 相互に排他的なオプション `interpolate` と `uniform` は、三角形の塗りつ ぶしの際に色の補間が行うかどうか (デフォルトでは ON) を制御します。 file はオプション `dump "file"` の指定で行えます。このオ プションが指定されると (すなわちダンプファイル名が空でない場合) キー KP_Delete を押すことでそのファイルにスクリーンダンプが書き出されます。 この機能は復帰することも復帰させることもできません。ファイルは raw ppm (P6) 形式で出力されます。このオプションは `set term` コマンドが発行さ れる度にリセットされます。
高解像度モードを得るには、多分 libvga の設定ファイル (通常 /etc/vga/libvga.conf) を修正する必要があるでしょう。VESA fb を使うのは 良い選択ですが、それはカーネルのコンパイルが必要です。
vgagl ドライバは、以下のリストのうちの *有効な* vga モードの最初のもの を使用します。
- vgagl の設定時に与えられるモード、例えば `set term vgagl G1024x768x256`
は最初に G1024x768x256 モードが有効かどうかチェックします。
- 環境変数 SVGALIB_DEFAULT_MODE
- G1024x768x256
- G800x600x256
- G640x480x256
- G320x200x256
- G1280x1024x256
- G1152x864x256
- G1360x768x256
- G1600x1200x256
`gnuplot` は X サーバを利用する `x11` 出力ドライバを提供します。この出 力形式は、環境変数 `DISPLAY` がセットされているか、環境変数 `TERM` が `xterm` にセットされているか、またはコマンドラインオプションとして `-display` が使われていれば起動時に自動的に選択されます。
書式:
set terminal x11 [reset] <n> [[no]enhanced] [font <fontspec>]
[title "<string>"] [[no]persist] [[no]raise] [close]
複数のグラフ描画ウィンドウをサポートしています。`set terminal x11 <n>` は番号 n の描画ウィンドウに出力します。n>0 の場合、タイトルが明示的に 指定されていなければ、その番号がウィンドウタイトルとしてつけられ、アイ コンには `gplt <n>` とラベル付けされます。現在有効なウィンドウはカーソ ル記号の変化で区別できます (デフォルトカーソルから十字カーソルへ)。
x11 出力形式は、利用可能なフォントの元で拡張テキストモード (`enhanced` 参照) をサポートしています。文字列に埋め込まれ、様々な効果を与えるフォ ントサイズ命令のために、デフォルトの x11 フォントがスケーラブルフォン トである必要があります。よって、以下の最初の例はうまくいくでしょうが、 2 番目のものはそうではないでしょう。
set term x11 enhanced font "arial,15"
set title '{\\=20 Big} Medium {\\=5 Small}'
set term x11 enhanced font "terminal-14"
set title '{\\=20 Big} Medium {\\=5 Small}'
`gnuplot` ドライバが別な出力ドライバに変更されても、描画ウィンドウは開 いたままになります。描画ウィンドウは、そのウィンドウにカーソルを置いて 文字 q を押すか、ウィンドウマネージャのメニューの `close` を選択すれば 閉じることができます。reset を実行すれば全てのウィンドウを一度に閉じ れます。それは実際にウィンドウを管理している子プロセスを終了します (も し `-persist` が指定されていなければ)。コマンド `close` は、個々の描画 ウィンドウを番号を指定して閉じるのに使うことができます。しかし、persist のために残っているような描画ウィンドウは `close` コマンドでは閉じること はできません。番号を省略して `close` した場合には現在有効な描画ウィンド ウを閉じます。
gnuplot の外にあるドライバ gnuplot_x11 は、プログラムのコンパイル時に 選択されたデフォルトの場所が検索されます。これは環境変数 GNUPLOT_DRIVER_DIR を異なる場所と定義することで変更できます。
描画ウィンドウは `-persisit` オプションが与えられていなければ、対話の 終了時に自動的に閉じられます。
オプション `persist` と `raise` はデフォルトでは設定されていませんが、 それは、デフォルトの値 (persist == no で raise == yes) か、コマンドラ インオプション -persist / -raise の指定か、または X のリソース値が使わ れる、ということを意味します。[no]persist か [no]raise が指定されると それはコマンドラインオプションや X リソースの設定よりも優先されます。 これらのオプションの設定は直ちに効力を持ちますので、既に起動しているド ライバの挙動は変更されます。
オプション `title "<title name>"` は現在の描画ウィンドウに、または番号 を指定すればその番号の描画ウィンドウに対するウィンドウタイトル名をつけ ます。そのタイトルが表示される場所、または表示されるかどうかは、使って いる X のウィンドウマネージャに依存します。
描画サイズとアスペクト比は、`gnuplot` のウィンドウをリサイズすることで も変更できます。
線の幅と点のサイズは `gnuplot` の `set linestyle` で変更可能です。
出力ドライバ `x11` に関しては、`gnuplot` は (起動時に)、コマンドライン、 または設定ファイルから、geometry や font, name などの通常の X Toolkit オプションやリソースの指定を受け付けます。それらのオプションについては X(1) マニュアルページ (やそれと同等のもの) を参照してください。
他にも `x11` 出力形式用の多くの `gnuplot` のオプションがあります。これ らは `gnuplot` を呼ぶときにコマンドラインオプションとして指定するか、 または設定ファイル ".Xdefaults" のリソースとして指定できます。これら は起動時に設定されるので、`gnuplot` 実行時には変更できません (`persist` と `raise` 以外は)。
-- X11_FONTS --
初期起動時は、システムの設定か、ユーザの .Xdefaults ファイルの設定か、 コマンドライン指定か、のいずれかによる X11 リソースによってデフォルト のフォントが選択されます。
例:
gnuplot*font: lucidasans-bold-12
新しいデフォルトのフォントを、gnuplot 内部から x11 ドライバに以下のよ うにして指示することもできます:
`set term x11 font "<fontspec>"`
まず x11 ドライバは、例えば `set term x11 font "lucidasans-10"` のよう に与えられたフォントの正式名を X サーバに尋ねます。この問い合わせが失 敗した場合、<fontspec> を "<font>,<size>,<slant>,<weight>" と解釈し、 以下の形の完全な X11 フォント名を生成しようとします:
-*-<font>-<weight>-<s>-*-*-<size>-*-*-*-*-*-<encoding>
<font> はフォントの基本名 (base name) (例: Times, Symbol)
<size> はポイントサイズ (指定がなければデフォルトは 12)
<s> は <slant>=="italic" なら `i`, <slant>=="oblique" なら `o`, その他は
`r`
<weight> は明示的に指定されれば `medium` か `bold`、その他は `*`
<encoding> は現在の文字集合に基づいて設定 (encoding 参照)
よって `set term x11 font "arial,15,italic"` は (デフォルトの encoding だとすれば) -*-arial-*-i-*-*-15-*-*-*-*-*-iso8859-1 に変換されます。 <size>, <slant>, <weight> 指定はいずれも必須ではありません。<slant> や <weight> を指定しなかった場合は、フォントサーバが最初に見つけた、変種 のフォントを取得するかもしれません。 x11 ドライバは、一般的な PostScript フォント名も認識し、それと同等で有 効な X11 フォントか TrueType フォントに置き換えます。 これと同じ手順が、label の要求によるフォントの生成でも使われてい ます。
-- COMMAND-LINE_OPTIONS --
X Toolkit オプションに加え、以下のオプションが gnuplot の立ち上げ時の コマンドラインで、またはユーザのファイル ".Xdefaults" 内のリソースとし て指定できます (`raise` と `persist` は `set term x11 [no]raise [no]persist` によって上書きされることに注意してください):
`-mono` カラーディスプレイ上で強制的に白黒描画
`-gray` グレイスケールまたはカラーディスプレイ上でのグレイスケール描画
(デフォルトではグレイスケールディスプレイは白黒描画を受け付ける)"
,
`-clear` 新しい描画を表示する前に (瞬間的に) 画面を消去
`-tvtwm` geometry オプションによる位置の指定を、仮想ルートウィンドウ中の
現在の表示部分に対する相対的な位置にする
`-raise` 各描画後に描画ウィンドウを最前面へ出す
`-noraise` 各描画後に描画ウィンドウを最前面へ出すことはしない
`-noevents` マウス、キーの入力を処理しない
`-persist` gnuplot プログラム終了後も描画ウィンドウを残す
上記のオプション、はコマンドライン上での指定書式で、".Xdefaults" にリ ソースとして指定するときは異なる書式を使います。
例:
gnuplot*gray: on
`gnuplot` は描画スタイル `points` で描画する点のサイズの制御にも、コマンド ラインオプション (`-pointsize <v>`) とリソース (`gnuplot*pointsize: <v>`) を提供しています。値 `v` は点のサイズの拡大率として使われる実数値 (0 < v <= 10) で、例えば `-pointsize 2` はデフォルトのサイズの 2 倍、 `-pointsize 0.5` は普通のサイズの半分の点が使われます。
`-noevents` はマウス、キーの全ての入力の処理を無効にします (`q` と `<space>` によるウィンドウの終了を除いて)。これは、gnuplot のメインプ ログラムとは独立した形で x11 ドライバを利用するプログラムに有用です。
-- MONOCHROME_OPTIONS --
白黒ディスプレイに対しては `gnuplot` は描画色 (foreground) も背景色 (background) も与えません。デフォルトでは背景は白、描画は黒です。`-rv` や `gnuplot*reverseVideo: on` の場合には背景が黒で描画は白になります。
-- COLOR_RESOURCES --
カラーディスプレイに対しては、`gnuplot` は以下のリソース (ここではその デフォルトの値を示します)、または白黒階調 (greyscale) のリソースを参照 します。リソースの値はシステム上の X11 rgb.txt ファイルに書かれている色 名、または 16 進の色指定 (X11 のマニュアルを参照) か、色名と強度 (0 か ら 1 の間の値) をコンマで区切った値を使用できます。例えば `blue, 0.5` は半分の強度の青、を意味します。
gnuplot*background: white
gnuplot*textColor: black
gnuplot*borderColor: black
gnuplot*axisColor: black
gnuplot*line1Color: red
gnuplot*line2Color: green
gnuplot*line3Color: blue
gnuplot*line4Color: magenta
gnuplot*line5Color: cyan
gnuplot*line6Color: sienna
gnuplot*line7Color: orange
gnuplot*line8Color: coral
これらに関するコマンドラインの書式は、背景 (bacground) に関しては単純で 通常の X11 toolkit オプションの "-bg" に直接対応します。他のものも、 全て一般的なリソースの上書きオプション "-xrm" を使うことで設定できま す。
例: 背景色を変更するには
gnuplot -background coral
線種 1 番目の色を書き換えるには
gnuplot -xrm 'gnuplot*line1Color:blue'
-- GRAYSCALE_RESOURCES --
`-gray` を選択すると、`gnuplot` は、グレイスケールまたはカラーディスプ レイに対して、以下のリソースを参照します (ここではそのデフォルトの値を 示します)。デフォルトの背景色は黒であることに注意してください。
gnuplot*background: black
gnuplot*textGray: white
gnuplot*borderGray: gray50
gnuplot*axisGray: gray50
gnuplot*line1Gray: gray100
gnuplot*line2Gray: gray60
gnuplot*line3Gray: gray80
gnuplot*line4Gray: gray40
gnuplot*line5Gray: gray90
gnuplot*line6Gray: gray50
gnuplot*line7Gray: gray70
gnuplot*line8Gray: gray30
-- LINE_RESOURCES --
`gnuplot` は描画の線の幅 (ピクセル単位) の設定のために以下のリソースを 参照します (ここではそのデフォルトの値を示します)。0 または 1 は最小の 線幅の 1 ピクセル幅を意味します。2 または 3 の値によってグラフの外観を 改善できる場合もあるでしょう。
gnuplot*borderWidth: 2
gnuplot*axisWidth: 0
gnuplot*line1Width: 0
gnuplot*line2Width: 0
gnuplot*line3Width: 0
gnuplot*line4Width: 0
gnuplot*line5Width: 0
gnuplot*line6Width: 0
gnuplot*line7Width: 0
gnuplot*line8Width: 0
`gnuplot` は線描画で使用する点線の形式の設定用に以下のリソースを参照し ます。0 は実線を意味します。2 桁の 10 進数 `jk` (`j` と `k` は 1 から 9 までの値) は、`j` 個のピクセルの描画に `k` 個の空白のピクセルが続く パターンの繰り返しからなる点線を意味します。例えば '16' は 1 個のピク セルの後に 6 つの空白が続くパターンの点線になります。さらに、4 桁の 10 進数でより詳細なピクセルと空白の列のパターンを指定できます。例えば、 '4441' は 4 つのピクセル、4 つの空白、4 つのピクセル、1 つの空白のパタ ーンを意味します。以下のデフォルトのリソース値は、白黒ディスプレイ、あ るいはカラーや白黒階調 (grayscale) ディスプレイ上の白黒描画における値 です。カラーディスプレイではそれらのデフォルトの値はほとんど 0 (実線) で、`axisDashes` のみがデフォルトで '16' の点線となっています。
gnuplot*borderDashes: 0
gnuplot*axisDashes: 16
gnuplot*line1Dashes: 0
gnuplot*line2Dashes: 42
gnuplot*line3Dashes: 13
gnuplot*line4Dashes: 44
gnuplot*line5Dashes: 15
gnuplot*line6Dashes: 4441
gnuplot*line7Dashes: 42
gnuplot*line8Dashes: 13
, "
-- X11 PM3D_RESOURCES --
適切な visual クラスと色数を選択するのは、X11 アプリケーションにとって 苦しく、ちょっと厄介なことです。それは X11 が異なる深度 (depth) の 6 つの visual 型をサポートしているからです。
デフォルトでは `gnuplot` はそのスクリーンのデフォルトの visual を使用 します。割り当てることのできる色数は選択された visual クラスによって変 わります。12bit を超える深度を持つ visual クラス上では、gnuplot は最大 色数である 0x200 (=512) 色で起動します。8bit を超える (12bit 以下で) 深度の visual クラスでは最大色数は 0x100 (=256) 色、8bit 以下のディス プレイでは最大色は 240 (16 色は曲線の色用に取られる) になります。
gnuplot は最初に、上に述べたような最大色を割り当てようと起動します。こ れに失敗するとその色数は、gnuplot がその全部を割り付けることができるま で、1/2 ずつ減らされます。`maxcolors` を繰り返し 2 で割った結果、 `mincolors` よりも小さい数字になった場合、`gnuplot` は private カラー マップを使おうとします。この場合、ウィンドウマネージャは、ポインタが X11 ドライバのウィンドウに入るか出るかでカラーマップを退避 (swapping) させる責任を持つことになります。
`mincolors` のデフォルトの値は maxcolors / (num_colormaps > 1 ? 2 : 8) で、num_colormaps は gnuplot が現在使用しているカラーマップの数で、こ れは、x11 のウィンドウが 1 つだけ開いているような通常の場合は 1 です。
複数の (異なる) visual クラスを、一つのスクリーン上でサポートするよう なシステムもあります。このようなシステムでは、gnuplot に指定した visual クラスを強制的に使わせる必要があります。例えば、デフォルトの visual が 8bit PseudoColor だけれどもスクリーンは 24bit TrueColor を サポートしていてむしろこちらの方を選択すべきであるような場合です。
X サーバの能力に関する情報はプログラム `xdpyinfo` で取得できます。 visual 名は次のうちの一つが選択できます: StaticGray, GrayScale, StaticColor, PseudoColor, TrueColor, DirectColor。その X サーバが要求 された visual 型の異なる複数の深度をサポートしている場合、`gnuplot` は 最も大きい (最深の) 深度の visual クラスを選択します。要求された visual クラスがデフォルトの visual とあっていて、その型の複数のクラス がサポートされている場合は、デフォルトの visual が選択されます。
例: 8bit PseudoColor の visual 上では、`gnuplot*maxcolors: 240`、及び `gnuplot*mincolors: 240` と指定することで強制的に private カラーマップ を使うようにできます。
gnuplot*maxcolors: <整数値>
gnuplot*mincolors: <整数値>
gnuplot*visual: <visual 名>
コマンド `set tics` は目盛りの刻みを外向きに書かれるように変更するのに 使われます。
書式:
set tics {<direction>}
show tics
ここで <direction> は `in` (デフォルト) または `out` です。
大目盛り (ラベルのつく) の他の制御に関しては xtics を、小目盛り の制御に関しては mxtics もそれぞれ参照してください。
`splot` において、ticslevel によって垂直軸 (Z) の相対的な高さを 調整できます。数値引数を与えるとそれは xy 平面から見た目盛りの一番下の 位置 (z の範囲に対する比) を指定したことになります。デフォルトの値は 0.5 です。負の値も許されていますが、そうすると 3 つの軸の目盛りの見出 しが重なる可能性があります。
xy 平面を z 軸の 'pos' の位置に置くには、ticslevel の値を (pos - zmin) / (zmin - zmax) としてください。
書式:
set ticslevel {<level>}
show tics
view も参照してください。
目盛りの刻みの大きさは ticscale で調節できます。
書式:
set ticscale {<major> {<minor>}}
show tics
もし <minor> が指定されなければそれは 0.5*<major> となります。デフォル トの大目盛り (major tics) の刻みのサイズは 1.0 で、小目盛り (minor tics) は 0.5 です。負の値を指定することで、刻みを外側に向けることが可 能であることに注意してください。
コマンド timestamp は描画の日付と時刻を左の余白に表示します。
書式:
set timestamp {"<format>"} {top|bottom} {{no}rotate}
{<xoff>}{,<yoff>} {"<font>"}
unset timestamp
show timestamp
書式文字列 (format) を使って、書かれる日付と時刻の書式を選択することが できます。デフォルトは asctime() が使用する "%a %b %d %H:%M:%S %Y" で す (曜日、月名、日、時、分、秒、4 桁の西暦)。`top` と `bottom` を使っ て日付を左の余白の上に配置するか、下に配置するかを選択できます (デフォ ルトは下)。`rotate` は、もし出力形式がサポートしていればですが、日付を 垂直方向の文字列にします。定数 <xoff>、<yoff> は文字スクリーン座標系で の、デフォルトの位置からのずれを表します。<font> は日付が書かれるフォ ントを指定します。 timestamp の代わりに省略名 `time` を使っても構いません。
例:
set timestamp "%d/%m/%y %H:%M" 80,-2 "Helvetica"
日付の書式文字列に関する詳しい情報については timefmt を参照して ください。
このコマンドは、データが日時の形式になっている場合に、その時系列データ に適用されます。これはコマンド `set xdata time` も与えられていないと意 味がありません。
書式:
set timefmt "<format string>"
show timefmt
文字列引数 (<format string>) は `gnuplot` に日時データをデータファイル からどのように読むかを指示します。有効な書式は以下の通りです:
書式 説明
%d 何日, 1--31
%m 何月, 1--12
%y 何年, 0--99
%Y 何年, 4-digit
%j 1 年の何日目, 1--365
%H 何時, 0--24
%M 何分, 0--60
%s Unix epoch (1970-01-01, 00:00 UTC) からの秒数
%S 何秒, 0--60
%b 月名 (英語) の 3 文字省略形
%B 月名 (英語)
任意の文字を文字列中で使用できますが、規則に従っている必要があります。 \t (タブ) は認識されます。バックスラッシュ + 8 進数列 (\nnn) はそれが 示す文字に変換されます。日時要素の中に分離文字がない場合、%d, %m, %y, %H, %M, %S はそれぞれ 2 桁の数字を読み込み、%Y は 4 桁、%j は 3 桁の数 字を読み込みます。%b は 3 文字を、%B は必要な分だけの文字を要求します。
空白 (スペース) の扱いはやや違います。書式文字列中の 1 つの空白は、フ ァイル中の 0 個、あるいは 1 つ以上の空白文字列を表します。すなわち、 "%H %M" は "1220" や "12 20" を "12 20" と同じように読みます。
データ中の非空白文字の集まりそれぞれは、`using n:n` 指定の一つ一つの列 とカウントされます。よって `11:11 25/12/76 21.0` は 3 列のデータと認 識されます。混乱を避けるために、日時データが含まれる場合 `gnuplot` は、 あなたの using 指定が完璧なものであると仮定します。
`gnuplot` は数字でない文字列を読めないので、日付データが曜日、月の名前 を含んでいる場合、書式文字列でそれを排除しなければいけません。しかし、 "%a", "%A", "%b", "%B" でそれらを表示することはできます: これら、及び 日時データの出力の他のオプションの詳細に関しては `set format` を参照し てください (`gnuplot` は数値から月や曜日を正しく求めます)。
他の情報については xdata と `Time/date` の項も参照してください。
例:
set timefmt "%d/%m/%Y\t%H:%M"
は、`gnuplot` に日付と時間がタブで分離していることを教えます (ただし、 あなたのデータをよーく見てください。タブだったものがどこかで複数のスペ ースに変換されていませんか ? 書式文字列はファイル中に実際にある物と一 致していなければなりません)。 以下も参照 時系列データ (time data) デモ。
コマンド `set title` は、描画の上の真中に書かれる描画タイトルを生成し ます。`set title` は label の特殊なもの、とみなせます。
書式:
set title {"<title-text>"} {<xoff>}{,<yoff>} {"<font>{,<size>}"}
{{textcolor | tc} {lt <line_type> | default}}
show title
定数 <xoff>, <yoff> を指定することで、タイトルを <xoff>, <yoff> 文字ス クリーン座標だけ動かすことができます (グラフ座標ではありません)。例え ば "`set title ,-1`" は、タイトルの y 方向の位置のみ変更し、大ざっぱに 言って 1 文字分の高さだけタイトルを下に下げます。
<font> はタイトルが書かれるフォントを指定するのに使われます。<size> の 単位は、どの出力形式 (terminal) を使っているかによって変わります。
`textcolor lt <n>` は文字の色を線種 (line type) <n> と同じものにします。
`set title` をパラメータなしで使うとタイトルを消去します。
バックスラッシュ文字列の作用、及び文字列を囲む単一引用符と二重引用符の 違いについては `syntax` を参照してください。
コマンド tmargin は上の余白のサイズをセットします。詳細は margin を参照してください。
コマンド trange は、媒介変数モード、あるいは極座標モードでの x, y の 値を計算するのに使われる媒介変数の範囲を設定します。詳細は xrange を 参照してください。
書式:
show variables
コマンド version は現在起動している gnuplot のバージョン、最終 修正日、著作権者と、FAQ や info-gnuplot メーリングリスト、バグレポート 先のメールアドレスを表示します。対話的にプログラムが呼ばれているときは スクリーン上にその情報を表示します。
書式:
show version {long}
`long` オプションを与えると、さらにオペレーティングシステム、`gnuplot` インストール時のコンパイルオプション、ヘルプファイルの置き場所、そして (再び) 有用なメールアドレスを表示します。
コマンド view は `splot` の視線の角度を設定します。これは、グラ フ描画の 3 次元座標をどのように 2 次元の画面 (screen) に投影するかを制 御します。これは、描画されたデータの回転と拡大縮小の制御を与えてくれま すが、正射影しかサポートしていません。3 次元射影、および 2 次元描画的 地図上への 2 次元直交射影がサポートされています。
書式:
set view { <rot_x>{,{<rot_z>}{,{<scale>}{,<scale_z>}}} | map }
show view
ここで <rot_x> と <rot_z> は、画面に投影される仮想的な 3 次元座標系の 回転角 (単位は度) の制御で、最初は (すなわち回転が行なわれる前は) 画面内の水平軸は x, 画面内の垂直軸は y, 画面自身に垂直な軸が z となっ ています。最初は x 軸の周りに <rot_x> だけ回転されます。次に、新しい z 軸の周りに <rot_z> だけ回転されます。
コマンド `set view map` は、描画を地図として表示するのに使います。これ は等高線 (contour) の描画、およびカラー表示 (pm3d) の色地図に使え ます。後者に関しては、入力データ点のフィルタ用の zrange の設定、およ び色の範囲の縮尺に関する cbrange の設定を適切に行うことに注意してく ださい。
<rot_x> は [0:180] の範囲に制限されていて、デフォルトでは 60 度です。 <rot_y> は [0:360] の範囲に制限されていて、デフォルトでは 30 度です。 <scale> は `splot` 全体の拡大縮小率を制御し、<scale_z> は z 軸の拡大縮 小のみを行ないます。スケールのデフォルトはどちらも 1.0 です。
例:
set view 60, 30, 1, 1
set view ,,0.5
最初の例は 4 つの全てをデフォルトの値にしています。2 つめの例は縮小率 のみを 0.5 に変更しています。 ticslevel も参照してください。
コマンド urange と vrange は、`splot` の媒介変数 (パラメー タ) モードで x, y, z の値を計算するのに使われる媒介変数の範囲を設定し ます。 詳細は xrange を参照してください。
コマンド x2data は x2 (上) 軸のデータを時系列 (日時) 形式に設定 します。詳細は xdata を参照してください。
コマンド x2dtics は x2 (上) 軸の目盛りを曜日に変更します。詳細は xdtics を参照してください。
コマンド x2label は x2 (上) 軸の見出しを設定します。詳細は xlabel を参照してください。
コマンド x2mtics は、x2 (上) 軸を 1 年の各月に設定します。詳細は xmtics を参照してください。
コマンド x2range は x2 (上) 軸の表示される水平範囲を設定します。 詳細は xrange を参照してください。
コマンド x2tics は x2 (上) 軸の、見出し付けされる大目盛りの制御 を行ないます。詳細は xtics を参照してください。
コマンド x2zeroaxis は、原点を通る x2 (上) 軸 (y2 = 0) を描きま す。詳細は zeroaxis を参照してください。
このコマンドは x 軸のデータ形式を日時データにセットします。同様のコマ ンドが他の軸それぞれに用意されています。
書式:
set xdata {time}
show xdata
ydata, zdata, x2data, y2data, cbdata にも同じ書式が当てはま
ります。
`time` オプションはデータが日時データであることを伝えます。オプション をつけない場合、データ型は通常のものに戻ります。
gnuplot にどのように日時データを読みこませるかについては、timefmt を参照してください。日時データは今世紀の始まり (訳注: 厳密には 2000 年 1 月 1 日の始まり) からの秒数に変換されます。時間書式 (timefmt) は現在 はただ一つだけしか使えません。それは、全ての日時データ項目がこの書式に 一致しなければならないことを意味します。また、範囲の指定は、日時指定が 数式と解釈されるのを避けるために、その書式に従った文字列を引用符で囲ん で指定すべきです。
目盛り刻みの見出し (label) を表示するのには関数 'strftime' (unix でそ れを調べるには "man strftime" とタイプしてください) が使われます。`set format x "string"` で、10 進数の書式ではなさそうなもの (2 つ以上の '%'、 または %f でも %g でもないもの) が与えられていなければ、`gnuplot` はこ れを適当に意味のある書式で計算して表示します。
他の情報については `Time/date` も参照してください。
コマンド xdtics は x 軸の目盛りの刻みを曜日に変換します (0=Sun, 6=Sat)。6 を越える場合は 7 による余りが使われます。xdtics は その見出しをデフォルトの形式に戻します。他の軸にも同じことを行なう同 様のコマンドが用意されています。
書式:
set xdtics
unset xdtics
show xdtics
ydtics, zdtics, x2dtics, y2dtics, cbdtics にも同じ書式が当て
はまります。
`set format` コマンドも参照してください。
コマンド xlabel は x 軸の見出しを設定します。他の軸にも見出しを 設定する同様のコマンドがあります。
書式:
set xlabel {"<label>"} {<xoff>}{,<yoff>} {font "<font>{,<size>}"}
{{textcolor | tc} {lt <line_type> | default}}
show xlabel
同じ書式が x2label, ylabel, y2label, zlabel, cblabel にも適 用されます。
見出しの追加のずれを表す定数 <xoff>, <yoff> を指定すると、見出しを <xoff> の文字幅、または <yoff> の文字の高さ分だけずらします。例えば "` set set xlabel -1`" は xlabel の x の位置だけ変更し、大ざっぱに言っ て 1 文字分の文字幅だけ左に移動します。文字のサイズは、フォントと使用 する出力形式 (terminal) に依存します。
<font> は見出しが書かれるフォントを指定するのに使われます。フォントの <size> (大きさ) の単位は、どんな出力形式を使うかに依存します。
`textcolor lt <n>` は、見出し文字列を線種 <n> の色にします。
見出しを消去するには、オプションをつけずに実行します。例: "y2label"
軸の見出しのデフォルトの位置は以下の通りです:
xlabel: x 軸の見出しは下の軸の下の真中
ylabel: y 軸の見出しは出力形式依存で、以下の 3 つのいずれか:
1. 水平方向の文字列で描画の左上に左端に合わせて配置されます。文字列の 回転を行なえない出力形式では多分これが選択されます。x2tics が同 時に使われている場合、ylabel は x2 軸の見出しの左端と重なるかも知れま せん。これは ylabel の位置か左の余白を調整することで対処できるでしょ う。
2. 垂直方向の文字列で、描画の左で垂直方向に中央揃えされます。文字列を 回転できる出力形式では多分これが選択されます。
3. 水平方向の文字列で、描画の左で垂直方向に中央揃えされます。LaTeX, TPIC ドライバではこれが選択されます。EEPIC ドライバでは、描画に重なら ないような、文字の積み重ねを生成しますが、その他のドライバ (LaTeX や TPIC のような) では、ylabel が描画に上書きするのを避けるために、\\ を 使って改行を入れる必要があるかもしれません。
zlabel: z 軸の見出しは軸の表示範囲より上で、見出しの真中が z 軸の真上
cblabel: 色見本 (color box) の軸の見出しは箱に沿って中央揃えされ、箱の 向きが水平なら下に、垂直なら右
y2label: y2 軸の見出しは y2 軸の右。その位置は、出力形式依存で y 軸と 同様の規則で決定。
x2label: x2 軸の見出しは上の軸の上で、描画タイトルよりは下。これは、 改行文字を使えば、それによる複数の行からなる描画タイトルで x2 軸の見 出しを生成することも可能。例:
set title "This is the title\n\nThis is the x2label"
これは二重引用符を使うべきであることに注意してください。この場合、もち ろん 2 つの行で同じフォントが使われます。
もし軸の位置のデフォルトの位置が気に入らないならば、代わりに label を使ってください。このコマンドは文字列をどこに配置するかをもっと自由に 制御できます。
バックスラッシュ文字列の作用、及び文字列を囲む単一引用符と二重引用符の 違いに関するより詳しい情報については `syntax` を参照してください。
コマンド xmtics は x 軸の目盛りの見出しを月に変換します。1=Jan (1 月)、12=Dec (12 月) となります。12 を越えた数字は、12 で割ったあまりの 月に変換されます。xmtics で目盛りはデフォルトの見出しに戻ります。 他の軸に対しても同じ役割をする同様のコマンドが用意されています。
書式:
set xmtics
unset xmtics
show xmtics
x2mtics, ymtics, y2mtics, zmtics, cbmtics にも同じ書式が適用
されます。
コマンド `set format` も参照してください。
コマンド xrange は表示される水平方向の範囲を指定します。他の軸 にも同様のコマンドが存在しますし、極座標での半径 r, 媒介変数 t, u, v にも存在します。
書式:
set xrange { [{{<min>}:{<max>}}] {{no}reverse} {{no}writeback} }
| restore
show xrange
ここで <min> と <max> には定数、数式、または '*' で、'*' は自動縮尺機 能を意味します。日時データの場合、範囲は timefmt の書式に従った 文字列を引用符で囲む必要があります。省略された値は変更されません。 yrange, zrange, x2range, y2range, cbrange, rrange, trange, urange, vrange は同じ書式を使用します。
オプション `reverse` は軸の方向を逆にします。例えば `set xrange [0:1] reverse` は、1 が左、0 が右であるような軸にします。これは、もちろん `set xrange [1:0]` と同じですが、`reverse` は主に自動縮尺 (autoscale) で用いられることを意図しています。
オプション `writeback` は、xrange で占められているバッファの中に 自動縮尺機能により作られた範囲を保存します。これは、いくつかの関数を同 時に表示し、しかしその範囲はそのうちのいくつかのものから決定させたい場 合に便利です。`writeback` の作用は、`plot` の実行中に機能するので、その コマンドの前に指定する必要があります。最後に保存した水平方向の範囲は `set xrange restore` で復元できます。例を上げます。
set xrange [-10:10]
set yrange [] writeback
plot sin(x)
set yrange restore
replot x/2
この場合、y の範囲 (yrange) は sin(x) の値域として作られた [-1:1] の方 になり、x/2 の値域 [-5:5] は無視されます。上記のそれぞれのコマンドの後 に yrange を実行すれば、上で何が行なわれているかを理解する助け になるでしょう。
2 次元描画において、xrange と yrange は軸の範囲を決定し、trange は、媒介変数モードの媒介変数の範囲、あるいは極座標モードの角度の範囲を 決定します。同様に 3 次元媒介変数モードでは、xrange, yrange, zrange が軸の範囲を管理し、urange と yrange が媒介変数の範囲を管理します。
極座標モードでは、rrange は描画される半径の範囲を決定します。<rmin> は半径への追加の定数として作用し、一方 <rmax> は半径を切り捨てる (clip) ように作用し、<rmax> を越えた半径に対する点は描画されません。xrange と yrange は影響されます。これらの範囲は、グラフが r(t)-rmin のグラ フで、目盛りの見出しにはそれぞれ rmin を加えたようなものであるかのよう にセットされます。
全ての範囲は部分的に、または全体的に自動縮尺されますが、データの描画で なければ、パラメータ変数の自動縮尺機能は意味がないでしょう。
範囲は `plot` のコマンドライン上でも指定できます。コマンドライン上で与 えられた範囲は単にその `plot` コマンドでだけ使われ、`set` コマンドで設 定された範囲はその後の描画で、コマンドラインで範囲を指定していないもの 全てで使われます。これは `splot` も同じです。
例:
x の範囲をデフォルトの値にします:
set xrange [-10:10]
y の範囲が下方へ増加するようにします:
set yrange [10:-10]
z の最小値には影響を与えずに (自動縮尺されたまま)、最大値のみ 10 に設 定します:
set zrange [:10]
x の最小値は自動縮尺とし、最大値は変更しません:
set xrange [*:]
x 軸の (見出しのつく) 大目盛りは コマンド xtics で制御できます。 目盛りは xtics で消え、xtics で (デフォルトの状態の) 目 盛りがつきます。y,z,x2,y2 軸の大目盛りの制御を行なう同様のコマンドがあ ります。
書式:
set xtics {axis | border} {{no}mirror} {{no}rotate {by <ang>}}
{ autofreq
| <incr>
| <start>, <incr> {,<end>}
| ({"<label>"} <pos> {<level} {,{"<label>"}...) }
{ font "name{,<size>}" }
{ textcolor <colorspec> }
unset xtics
show xtics
同じ書式が ytics, ztics, x2tics, y2tics, cbtics にも適用され ます。
`axis` と border は `gnuplot` に目盛り (目盛りの刻自身とその見出し) を、それぞれ軸につけるのか、境界につけるのかを指示します。軸が境界にと ても近い場合、`axis` を使用すると目盛りの見出し文字を境界の外に出して しまうでしょう。この場合自動的なレイアウトアルゴリズムによる余白設定は 大抵よくないものとなってしまいます。
`mirror` は `gnuplot` に反対側の境界の同じ位置に、見出しのない目盛りを 出力するよう指示します。`nomirror` は、あなたが思っている通りのことを 行ないます。
`rotate` は、文字列を 90 度回転させて出力させようとします。これは、文 字列の回転をサポートしている出力ドライバ (terminal) では実行されます。 `norotate` はこれをキャンセルします。`rotate by <ang>` は角度 <ang> の 回転を行ないますが、これはいくつかの出力形式 (terminal) でサポートされ ています。
x と y 軸の大目盛りのデフォルトは `border mirror norotate` で、x2, y2 軸は `border nomirror norotate` がデフォルトです。z 軸には、`{axis | border}` オプションは無効で、デフォルトは `nomirror` です。z 軸の目盛 りをミラー化したいなら、多分 border でそのための空間をあける必要 があるでしょう。
オプションなしで xtics を実行すると、目盛りが表示される状態であ れば、それはデフォルトの境界、または軸を復元し、そうでなければ何もしま せん。その前に指定した目盛りの間隔、位置 (と見出し) は保持されます。
目盛りの位置は、デフォルト、またはオプション `autofreq` が指定されてい れば自動的に計算されます。そうでなければ、次の 2 つの形式で指定されま す:
暗示的な <start>, <incr>, <end> 形式は、目盛りの列を <start> から <end> の間を <incr> の間隔で表示します。<end> を指定しなければ、それは無限大 とみなされます。<incr> は負の値も可能です。<start> と <end> の両方が指 定されていない場合、<start> は -∞、<end> は +∞とみなされ、目盛りは <incr> の整数倍の位置に表示されます。軸が対数軸の場合、目盛りの間隔 (増分) は、積因子として使用されます。
`set grid` のオプション 'front', 'back', 'layerdefault' も、x 軸の目盛 りの描画の順序に影響します。
例:
目盛りを 0, 0.5, 1, 1.5, ..., 9.5, 10 の位置に生成
set xtics 0,.5,10
目盛りを ..., -10, -5, 0, 5, 10, ... に生成
set xtics 5
目盛りを 1, 100, 1e4, 1e6, 1e8 に生成
set logscale x; set xtics 1,100,1e8
明示的な ("<label>" <pos> <level>, ...) の形式は、任意の目盛りの位置、 あるいは数字でない見出しの生成も可能にします。この形式では、目盛りは位 置の数字の順に与える必要はありません。各目盛りは位置 (pos) と見出し (label) を持ちますが、見出しは必須ではありません。見出しは二重引用符で 囲まれた文字列であることに注意してください。それは、"hello" のような固 定文字列でも構いませんし、"%3f clients" のようにその位置を数字に変換す る書式文字列を含んでも構いませんし、空文字列 "" でも構いません。より詳 しい情報については `set format` を参照してください。もし、文字列が与え られなければ、デフォルトの数字の見出しが使用されます。
明示的な形式では 3 つ目のパラメータとして "レベル" (level) を与えるこ とができます。デフォルトのレベルは 0 で、これは大目盛りを意味し、レベ ルが 1 の場合小目盛りが生成されます。レベルが指定する場合はラベルも必 ず指定する必要があります。
例:
set xtics ("low" 0, "medium" 50, "high" 100)
set xtics (1,2,4,8,16,32,64,128,256,512,1024)
set ytics ("bottom" 0, "" 10, "top" 20)
set ytics ("bottom" 0, "" 10 1, "top" 20)
2 番目の例では、全ての目盛りが見出し付けされます。3 番目の例では、端の ものだけが見出し付けされます。4 番目の例の、見出しのない目盛りは小目盛 りになります。
しかし指定しても、表示されるのはあくまで描画範囲のものだけです。
目盛りの見出しの書式 (または省略) は `set format` で制御されます。ただ しそれは `set xtics (`<label>`)` の形式の明示的な見出し文字列が含まれ ていない場合だけです。
(見出し付けされない) 小目盛りは mxtics コマンドで追加することが 出来ます。
時系列データの場合、位置の値は timefmt の書式にしたがった日付、また は時刻を引用符で囲んで与えなければいけません。<start>, <incr>, <end> 形式を使う場合、<start> と <end> は timefmt に従って与えますが、 <incr> は秒単位で与える必要があります。その時刻は実際には `set format` で与えた書式に従って表示されます。
例:
set xdata time
set timefmt "%d/%m"
set format x "%b %d"
set xrange ["01/12":"06/12"]
set xtics "01/12", 172800, "05/12"
set xdata time
set timefmt "%d/%m"
set format x "%b %d"
set xrange ["01/12":"06/12"]
set xtics ("01/12", "" "03/12", "05/12")
これらは両方とも "Dec 1", "Dec 3", "Dec 5", の目盛りを生成しますが、2 番目の例 "Dec 3" の目盛りは見出し付けされません。
コマンド xzeroaxis は y = 0 の直線を描きます。詳細に関しては、 zeroaxis を参照してください。
コマンド y2data は y2 (右) 軸のデータを時系列 (日時) 形式に設定 します。詳細は xdata を参照してください。
コマンド y2dtics は y2 (右) 軸の目盛りを曜日に変更します。詳細は xdtics を参照してください。
コマンド y2label は y2 (右) 軸の見出しを設定します。詳細は xlabel を参照してください。
コマンド y2mtics は y2 (右) 軸の目盛りを 1 年の各月に変更します。 詳細は xmtics を参照してください。
コマンド y2range は y2 (右) 軸の表示される垂直範囲を設定します。 詳細は xrange を参照してください。
コマンド y2tics は y2 (右) 軸の、見出し付けされる大目盛りの制御 を行ないます。詳細は xtics を参照してください。
コマンド y2zeroaxis は、原点を通る y2 (右) 軸 (x2 = 0) を描きま す。詳細は zeroaxis を参照してください。
コマンド ydata は y 軸のデータを時系列 (日時) 形式に設定します。 xdata を参照してください。
コマンド ydtics は y 軸の目盛りを曜日に変更します。詳細は xdtics を参照してください。
このコマンドは y 軸の見出しを設定します。xlabel を参照してください。
コマンド ymtics は、y 軸の目盛りを月に変更します。詳細は xmtics を参照してください。
コマンド yrange は、y 方向の垂直範囲を設定します。詳細は xrange を参照してください。
コマンド ytics は y 軸の (見出し付けされる) 大目盛りを制御します。 詳細は xtics を参照してください。
コマンド yzeroaxis は x = 0 の直線 (y 軸) を書きます。詳細は zeroaxis を参照してください。
コマンド zdata は z 軸のデータを時系列 (日時) 形式に設定します。 xdata を参照してください。
コマンド zdtics は z 軸の目盛りを曜日に変更します。詳細は xdtics を参照してください。
このコマンドはカラーボックス軸のデータを時系列 (日時) 形式に式に設定し ます。xdata を参照してください。
コマンド cbdtics はカラーボックス軸の目盛りの刻みを曜日に変換します。 詳細は xdtics を参照してください。
`zero` の値は、0.0 に近いデフォルトの閾値を表します。
書式:
set zero <expression>
show zero
`gnuplot` は、(複素数値を持つ点の描画においては) その値の虚数部分の絶 対値が `zero` 閾値より大きい場合 (つまり実数でない値を持つ点) は、その 点を描画しません。この閾値は `gnuplot` の他の様々な部分においてその (大まかな) 数値誤差の閾値としても使われています。デフォルトの `zero` の 値は 1e-8 です。1e-3 (= 典型的なビットマップディスプレイの解像度の逆数) より大きい `zero` の値は設定すべきではないでしょうが、`zero` を 0.0 と 設定するのは意味のないことではありません。
x 軸は xzeroaxis によって描かれ、xzeroaxis によって削除 されます。同様の y, x2, y2 軸用のコマンドが同様の働きをします。
書式:
set {x|x2|y|y2|}zeroaxis { {linestyle | ls <line_style>}
| { linetype | lt <line_type>}
{ linewidth | lw <line_width>}}
unset {x|x2|y|y2|}zeroaxis
show {x|y|}zeroaxis
デフォルトでは、これらのオプションはオフになっています。選択された 0 の軸は <line_type> の線の型と<line_width> の線の幅 (現在使用している 出力形式がサポートしていれば) で、あるいはあらかじめ定義された <line_style> のスタイルで描かれます。
線の型を指定しなければ、軸は通常の軸の線の型 (型 0) で描かれます。 zeroaxis は yzeroaxis と同等で、 zeroaxis は yzeroaxis と同等です。
例:
y=0 の軸を見えるように簡単に書く場合:
set xzeroaxis
太い線にして、違った色、または点線パターンにしたい場合:
set xzeroaxis linetype 3 linewidth 2.5
このコマンドは z 軸の見出しを設定します。xlabel を参照してくださ い。
コマンド zmtics は z 軸の目盛りを月に変更します。詳細は xmtics を参照してください。
コマンド zrange は z 軸方向に表示される範囲を設定します。この コマンドは `splot` にのみ有効で、`plot` では無視されます。詳細は xrange を参照してください。
コマンド ztics は z 軸の (見出し付けされる) 大目盛りを制御します。 詳細は ztics を参照してください。
このコマンドはカラーボックス軸の見出しを設定します。xlabel を参 照してください。
コマンド cbmtics はカラーボックス軸の目盛りの見出しを月に変換し ます。詳細は xmtics を参照してください。
コマンド cbrange は `splot` の pm3d 機能で色づけされる z の値 の範囲を設定します。カラーボックス軸 (cb-軸) が自動縮尺されている場合 は pm3d / palette の範囲は zrange が使われます。 cbrange の書式に関する詳細は xrange を参照してください。
コマンド cbtics はカラーボックス軸の (見出し付けされる) 大目盛り を制御します。詳細は xtics を参照してください。
シェルコマンドを実行する方法は 2 つあります: コマンド system を使う か `!` (VMS では $) を使うか。前者は、コマンド文字列をパラメータとして 取るので、他の gnuplot コマンドのどこでも使うことができますが、後者の 書式は、その行にそのコマンドただ一つであることを要求します。これらの場 合コマンドが終了するとすぐに制御は `gnuplot` に戻ってきます。例えば AmigaDOS, MS-DOS, OS/2 では、
! dir
または
system "dir"
とするとディレクトリの一覧を表示して `gnuplot` に戻ってきます。 system を使う他の例:
system "date"; set time; plot "a.dat"
print=1; if (print) replot; set out; system "lpr x.ps"
Atari では、`!` コマンドは、最初にシェルが既にロードされているか調べて、 有効ならばそれを使います。例えば、`gnuplot` が `gulam` から起動されて いる場合に、これは実用的です。
`splot` は 3 次元描画のためのコマンドです (もちろんご存知でしょうが、 実際にはその 2 次元への射影です)。それは関数、またはデータファイルか ら、`plot` コマンドととても良く似た方法でその描画を作ります。
`plot` コマンドと共通の仕様については `plot` を参照して下さい。ここでは それと異なるものだけ詳細に取り上げます。なお、binary や matrix オプ ションは ("datafile-modifiers" 以下で取り上げます) `plot` にはなく、 `plot` の `axes` オプションは `splot` では使えないことに特に注意して下 さい。
書式:
splot {<ranges>}
<function> | "<datafile>" {datafile-modifiers}}
{<title-spec>} {with <style>}
{, {definitions,} <function> ...}
ここで、関数 <function>、またはクォートでくくられたデータファイル名の どちらかが必要です。関数は、一本の数式、あるいは媒介変数モードでは 3 つの数式の組です。
デフォルトでは、`splot` は描画されるデータの下に完全な xy 面を描きます。 z の一番下の目盛りと xy 平面の位置関係は ticslevel で変更できます。 `splot` の射影の向きは view で制御できます。詳細は view, ticslevel を参照して下さい。
`splot` コマンドの範囲の指定の書式は `plot` の場合と同じです。媒介変数 モードでなければ範囲は xrange, yrange, zrange の順であり、媒介変 数モードでは urange, vrange, xrange, yrange, zrange の順です。
`title` オプションも `plot` と同じです。with も `plot` とほぼ同じ ですが、`splot` では利用可能な描画スタイルは `lines`, `points`, `linespoints`, `dots`, `impulses` に限られています。`plot` で使える エラーバーの機能は `splot` にはありません。
`datafile` オプションにはさらに違いがあります。
`show plot` も参照してください。
`plot` と同じように、ファイルに含まれる離散的なデータは、そのファイル 名をクォートで囲んで指定することで描画できます。
書式:
splot '<file_name>' {binary | matrix}
{index <index list>}
{every <every list>}
{using <using list>}
`""` や `"-"` といった特別なファイル名も `plot` のときと同様に許されます。
手短にいうと、binary や matrix はそのデータが特別な形であることを、 index は多重データ集合ファイルからどのデータ集合を選んで描画するかを、 every は各データ集合からどのデータ行 (部分集合) を選んで描画するかを、 using は各データ行からどのように列を選ぶかを指定します。 index と every オプションは `plot` の場合と同じように振舞います。 using も、using のリストが 2 つでなく 3 つ必要であるということを 除いては同様です。 thru や smooth といった `plot` のオプションは `splot` では利用でき ません。しかし、cntrparam や dgrid3d が、制限されてはいますが平滑化 のために用意されています。
データファイルの形式は、各点が (x,y,z) の 3 つ組である以外は、本質的に `plot` と同じです。もし一つの値だけが与えられれば、それは z として使われ、 データブロック番号が y として、そして x はそのデータブロック内での番号が 使われます。もし 2 つ、あるいは 4 つの値が与えられれば、`gnuplot` はその 最後の値を pm3d plot での色の計算に使います。3 つの値は (x,y,z) の組と見 なされます。他に値があれば、それは一般に誤差と見なされます。それは `fit` で使うことが可能です。
`splot` のデータファイルでは、1 行の空行はデータブロックの分離子です。 `splot` は個々のデータブロックを、関数の y-孤立線と同じものとして扱い ます。1 行の空行で分離されている点同士は線分で結ばれることはありません。 全てのデータブロックが全く同じ点の数を持つ場合、`gnuplot` はデータ ブロックを横断し、対応する点同士を結ぶ孤立線を描きます。これは "grid data" と呼ばれ、曲面の描画、等高線の描画 (contour)、隠線処理 (hidden3d) では、この形のデータであることが必要となります。 grid_data も参照して下さい。
3 列の `splot` データにおいては、媒介変数モード (`parametric`) を指定 することはもはや不要です。
`splot` はある特別なフォーマットで書かれたバイナリファイルを (そして バイナリファイルの表現に互換性を持つシステムの上で) 読むことができます。
以前のバージョンでは、`gnuplot` は動的にバイナリデータかどうかを判断 していましたが、現在は、ファイル名の後ろに binary キーワードを直接 指定することが必要です。
単精度浮動小数の数値が次のように保存されています:
<N+1> <y0> <y1> <y2> ... <yN>
<x0> <z0,0> <z0,1> <z0,2> ... <z0,N>
<x1> <z1,0> <z1,1> <z1,2> ... <z1,N>
: : : : ... :
これらは以下のような 3 つの数字の組に変換されます:
<x0> <y0> <z0,0>
<x0> <y1> <z0,1>
<x0> <y2> <z0,2>
: : :
<x0> <yN> <z0,N>
<x1> <y0> <z1,0>
<x1> <y1> <z1,1>
: : :
そして、これらの 3 つの数字の組は `gnuplot` の孤立線に変換され、その後 `gnuplot` が通常の方法で描画の残りを行います。
行列やベクトルの操作のサブルーチン (C による) が `binary.c` に用意され ています。バイナリデータを書くルーチンは
int fwrite_matrix(file,m,nrl,nrl,ncl,nch,row_title,column_title)
です。これらのサブルーチンを使う例が `bf_test.c` として用意されていて、 これはデモファイル `demo/binary.dem` 用に複数のバイナリファイルを生成 します。 index キーワードは、ファイルフォーマットが 1 つのファイルにつき 1 つ の曲面しか許さないため、サポートされません。every や using フィルタ はサポートされます。using は、データがあたかも上の 3 つ組の形で読まれ たかのように働きます。 以下も参照。 バイナリファイルの splot のデモ。
以下は3 次元データファイルの描画の単純な一つの例です。
splot 'datafile.dat'
ここで、"datafile.dat" は以下を含むとします:
# The valley of the Gnu.
0 0 10
0 1 10
0 2 10
1 0 10
1 1 5
1 2 10
2 0 10
2 1 1
2 2 10
3 0 10
3 1 0
3 2 10
この "datafile.dat" は 4*3 の格子 (それぞれ 3 点からなるブロックの 4 つの行) を定義することに注意して下さい。行 (データブロック) は 1 行の 空行で区切られます。
x の値はそれぞれのデータブロックの中で定数になっていることに注意して下 さい。もし y を定数の値とし、隠線処理が有効な状態で描画すると、その曲面は 裏返しで書かれることになります。
格子状データ (grid data) に対して、個々のデータブロック内で x の値を定 数としておく必要はありませんし、同じ場所の y の値を同じ値に揃えておく 必要もありません。`gnuplot` は個々のデータブロック内の点の数が等しいと いうことを必要としているだけです。
しかし、等高線を導くのに用いられる曲面の網目は、対応する点を列的に選んで 結ぶため、不揃いの格子データに対する曲面の描画への影響は予想できません。 それはケースバイケースの原理でテストすべきでしょう。
z11 z12 z13 z14 ...
z21 z22 z23 z24 ...
z31 z32 z33 z34 ...
など。その行や列の番号は、x や y の値として使われます。
空行、またはコメント行は配列データを終了させ、新たな曲面の網 (mesh) を 開始します。いつものことですが、`splot` コマンド の index オプション を使ってファイル内の網を自由に選択できます。
3 次元描画のためのルーチンは、個々の網目の格子においては一つの標本点と 一つのデータ点がある、という形の格子状データ用に設計されています。各 データ点は、関数の値を評価すること (`set isosample` 参照)、またはデータ ファイルを読み込むこと (`splot datafile` 参照) によって生成されます。 "孤立線" という言葉は関数に対しても、データに対してもその網目の線を表す ものとして用いられます。網目は、必ずしも x, y に関する長方形でなくても よく、u,v で媒介変数表示されても構わないことに注意して下さい。 isosamples を参照して下さい。
しかし、`gnuplot` はそのような形式を必ずしも必要とはしません。例えば 関数の場合は、samples は isosamples と違っていても構いません。 すなわち、x-孤立線のうち、1 本の y-孤立線と交わないものがいくつかある ことがあります。データファイルの場合は、個々のデータブロックのばらつい た点の個数が全て同じであれば、"孤立線は" はデータブロックの点を結び、 "横断孤立線" は各データブロックの対応する点同士を結び、"曲面" を作ろう とします。どちらの場合でも、等高線、および隠線処理モードは点が意図した フォーマットであった場合とは違った描画を与えることになります。ばらつき のあるデータは dgrid3d によって{異なる}格子状データに変換すること ができます。
等高線に関するコードは、y-孤立線の点と、それに対応する隣の y-孤立線上 の点の間の線分に沿っての z の張力を計測します。よって、x-孤立線に、 y-孤立線との交点とはならないような標本点があるような曲面に対しては、 `splot` の等高線はそのような標本点を無視することになります。以下を試して みて下さい:
set xrange [-pi/2:pi/2]; set yrange [-pi/2:pi/2]
set style function lp
set contour
set isosamples 10,10; set samples 10,10;
splot cos(x)*cos(y)
set samples 4,10; replot
set samples 10,4; replot
`splot` は点の集まりとして、あるいは、それらの点を結ぶことによって曲面 を表示することができます。`plot` と同様に、点はデータファイルから読む こともできますし、指定された区間で関数の値を評価して得ることもできます。 isosamples を参照して下さい。曲面は、各点を線分で結ぶことで近似的 に作られます。surface を参照して下さい。そしてその場合曲面は hidden3d で不透明にもできます。3 次元曲面を眺める向きは、view で変更できます。
さらに、格子上のデータ点に対しては、`splot` は同じ高さを持つ点を補間す ることができ (contour 参照)、そしてそれらを結んで等高線を描くこ とができます。さらに、その結び方には真直な線分や滑らかな線を使うことが できます (cntrparam 参照)。関数は、常に isosamples と samples で決定される格子状データとして評価されます。一方、ファイ ルのデータは、`data-file` に書かれているような格子状データフォーマット にするか、あるいは格子データを生成する (dgrid3d 参照) ということ をしなければそうはなりません。
等高線は曲面の上に表示することもできるし、底面に射影することもできる。 底面への射影は、ファイルに書き出すこともでき、そしてそれを `plot` で 再び読み込んで `plot` のより強い整形能力を生かすこともできる。
このコマンドは、出力形式やパレットでどのような出力が行なえるかを画像で テストし表示します。
書式:
test {terminal | palette [rgb|rbg|grb|gbr|brg|bgr]}
test または terminal は、現在使用中の出力形式 (terminal) で
使える線の種類、点の種類、または有用なそして利用可能なその他の描画を生
成します。
palette は、現在のカラーパレット (palette) で計算した R(z),
G(z),B(z) (0<=z<=1) の状態を画像で描画します。それは実際には、本来あな
たが `show palette palette 256 float` として得るべき綺麗な描画です。
追加のパラメータは、r,g,b の文字の組合せで、それにより描画する順番が
決定されます。`set palette gray` で色々試してみてください。デフォルト
の順番は rgb です。
コマンド `set` で設定したオプションは、それに対応した unset コマンド を使うことで、そのデフォルトの値に戻すことが可能です。
例:
set xtics mirror rotate by -45 0,10,100
...
unset xtics
このコマンドは当てはめ (fit) のパラメータの現在の値を、初期値のファイ ルの形式で (`fit` の項で説明されている)、与えられたファイルに書き出し ます。これは、現在の値を、後で使うために、あるいは終了/中断した当ては めを再実行するために保存しておくのに有用です。
書式:
update <filename> {<filename>}
2 番目のファイル名を指定すると、元のパラメータファイルは変更せずに 2 番目のファイルの方に更新された値を書き出します。
そうでなければ、指定したファイルが存在すれば `gnuplot` はそのファイル 名に `.old` をつけてファイル名を変更し、指定したファイル名のファイルを 新たに開き直します。つまり、"`update 'fred'`" とすると、それは "`!rename fred fred.old; update 'fred.old' 'fred'`" としたことと同じこ とになります。["filename.ext" の 12 文字しか使えない DOS や他のシステ ムでは、"ext" が "`old`" になって "filename" は最初のファイルに関係す るもの (多分どれかがすぐに分かるでしょう) が使われます。VMS では、ファ イルのバージョン管理システムが使われるため、名前の変更は行なわれません。]
より詳しい情報に関しては `fit` を参照してください。
`gnuplot` のために色々なグラフィカルユーザインターフェースが書かれてき ました。その win32 用の物はこの配布版に含まれています。そして、 Macintosh に対するインターフェースは http://feff.phys.washington.edu/~ravel/software/gnuplot-mode/ に置いてあります。
X11 に対するインターフェースも幾つかあります。 xgfe と呼ばれるものがその一つで、Qt ライブラリを使用します。これは以下 にあります。 http://www.flash.net/~dmishee/xgfe/xgfe.html
さらに、通常の Tcl/Tk の配布 場所に置かれている、3 つの Tcl/Tk プログ ラムがあります。
Bruce Ravel (ravel@phys.washington.edu) は、Gershon Elber による gnuplot.el を元に、GNU emacs と XEmacs に対する新しい版の gnuplot-mode を書きました。gnuplot の CVS リポジトリにはそのコピーが含まれているが、 このパッケージの最新版は以下にもあります。 http://feff.phys.washington.edu/~ravel/gnuplot
浮動小数計算例外 (浮動小数値が大きすぎる (または小さすぎる) 場合、0 で 割算した場合など) は、ユーザ定義関数において時折発生します。特に、いく つかのデモで、浮動小数の範囲を越える数値を生成することが起こるようです。 システムがそのような例外を無視する (`gnuplot` はそのような点を定義でき ないもの、と見なします) か、または `gnuplot` の実行を中止するかは、コ ンパイル時 (あるいは実行時) の環境によります。
ベッセル関数は複素数引数に対しては動作しません。
ガンマ関数は複素数引数に対しては動作しません。
`gnuplot` の現在のバージョン 3.7 では、全ての開発は ANSI C コンパイラ が使われています。現在のオペレーティングシステム、コンパイラ、ライブラ リ、バージョン 3.5 のドキュメントに上げられた各 OS 毎のバグに関しては、 ここではなく、今は `old_bugs` の方にあげられています。
現在の版以降に関するバグの報告、及び古い報告は以下の公式配布サイトに置 かれます。 http://www.gnuplot.info
全てのバグに関しては、bug-gnuplot メーリングリスト (Seeking-assistance 参照) に e-mail してください。
古い Sun の OS (SunOS Sys4-3.2) には、標準入出力 (stdio) ライブラリに バグがあります。'printf' の書式 "%g" は時々正しくない表示を行ないます (例えば "2" を 200000.0 と表示する)。よって、目盛りの見出しは、Sun4 上 の `gnuplot` では不正になる場合があります。回避方法としては、データの スケール変換 (定数倍する) を行なうこと、あるいはコマンド `set format` で目盛りの見出しの書式を "%7.0f" などの適当な物に変えることなどがあり ます。これは SunOS 4.0 では修正されているようです。
他のバグ: Sun3 上の SunOS 4.0, Sun4 上の Sys4-3.2 と SunOS 4.0 で、 'sscanf' ルーチンが、書式 "%f %f" で "00 12" を不正に解釈し、0 と 12 ではなく、0 と 0 のように読んでしまいます。これはデータの入力に影響を 与えます。もし、データファイルが x 座標として '00' や '000' のように書 かれたゼロを含んでいる場合、y の値は不正なものとなるでしょう。データフ ァイルをチェックするか SunOS をバージョンアップしてください。これは SunOS 4.1.1 では修正されているようです。
Sun は、大きな x に対する exp(-x) の計算で桁溢れを起こすようで、よって `gnuplot` は未定義値を取得することになります。一つの回避策は、ユーザ定 義関数として e(x) = x<-500 ? 0 : exp(x) のようなものを使うことです。こ れは、例えばガウス関数 (exp(-x*x)) の描画に影響を与えます。x*x は非常 に早く大きくなるからです。
Microsoft C 5.1 では 'printf' の %g 書式に関するひどいバグがあります。 "%.2g", "%.1g", "%.0g", "%.g" のような書式を使うと、'printf' は 1e-4 から 1e-1 の間の不正な数値を表示するでしょう。%e の書式で表示されるべ き数値は、 %f では小数点の後に間違った数のゼロがついた不正な数値になり ます。この問題を回避するには、%e や %f の書式を明示的に使用してくださ い。
Microsoft C でコンパイルされた `gnuplot` は、テストでは 2 つの VGA デ ィスプレイで正しく動作しませんでした。多分 CGA, EGA, VGA ドライバは Microsoft C グラフィックライブラリを使うように書き直すべきでしょう。 Borland C++ でコンパイルされた `gnuplot` は Turbo C グラフィックドライ バを使用し、これは VGA ディスプレイでちゃんと動作します。
VAX/VMS 4.7 C コンパイラ (release 2.4) の 'printf' の書式 %g の実装は 貧弱です。数は数値としては正しく表示されますが、要求した書式でないもの になり得ます。K&R 第 2 版には、書式 %g は、指数部が -4 より小さい場合、 あるいは指定精度以上になる場合は %e を使う、と書いてあります。しかし VAX は指数部が -1 より小さい場合に %e を使います。VAX では、1 より小さ い数に対して、%e と %f のどちらを使うのかを決定するときに精度が評価さ れていないようです。この問題を回避するには、%e, %f を明示的に使ってく ださい。VAX C 2.4 のリリースノートより: e,E,f,F,g,G の結果は常に小数点 を含みます。g と G に対しては、末尾のゼロは取り除かれません。
VAX/VMS 5.2 C コンパイラ (release 3.0) は release 2.4 よりも多少ましな 書式 %g の実装を持ちますが、さほどではありません。末尾の小数点は取り除 かれるようになりましたが、末尾のゼロは相変わらず %g の指数表記の数から は取り除かれていません。
これらの問題はコンパイラの問題ではなく、実際にはライブラリの問題です。 よって、DEC コンパイラ、または他のもの (例えば最新の gcc) を使って `gnuplot` をコンパイルしてももこの問題は起こるでしょう。
ULTRIX X11R3 は、X11 ドライバがグラフを "一つおき" に表示する、という ことを引き起こすバグがあります。このバグは、DEC の X11R4 では修正され たようで、新しいリリースの ULTRIX ではこの問題を起こさないようです。古 いサイトでの解決策は、X11 ライブラリをバージョンアップする (DEC から、 あるいは MIT から直接) か、または x11.trm ファイルのコンパイル時に ULTRIX_KLUDGE を定義してください。しかし、kludge は理想的な回避策では ないことに注意してください。
NeXT OS 2.0 では、定数 HUGE が不正な値に定義されています。HUGE は plot.h で 1e38 にセットされるのが正しいです。このエラーは NeXT OS の バージョン 2.1 では修正されています。
HP プロッタの古いモデルの中にはページの排出コマンド 'PG' を持たないも のがあります。現在の HPGL ドライバはこのコマンドを HPGL_reset で使用し ていますが、そのようなプロッタには、このコマンドを取り除く必要があるで しょう。現在の PCL5 ドライバは、グラフィックと同様にテキストにも HPGL/2 を使用しています。これはスケーラブル PCL フォントを使うように修 正されるべきでしょう。
Atari 版では、プリンタに直接出力を送れません (出力ファイルを `/dev/lp` としては)。それはバイナリ出力の LF (改行) に CR (復帰) が追加されるか らです。回避策としては、出力をファイルに書き出し、それをその後でシェル コマンドを使ってプリンタにコピーしてください。
AIX 4 では、データファイル中の文字 'NaNq' は、内部の '未定義' フラグと しては処理されず、内部の特殊な `非数値` として保存されてしまいます。回 避するには `set datafile missing 'NaNq'` を使ってください。
abs: abs
acos: acos
acosh: acosh
arg: arg
asin: asin
asinh: asinh
atan: atan
atan2: atan2
atanh: atanh
besj0: besj0
besj1: besj1
besy0: besy0
besy1: besy1
ceil: ceil
column: column
cos: cos
cosh: cosh
defined: defined_
erf: erf
erfc: erfc
exp: exp
floor: floor
gamma: gamma
ibeta: ibeta
igamma: igamma
imag: imag
int: int
inverf: inverf
invnorm: invnorm
lambertw: lambertw
lgamma: lgamma
log: log
log10: log10
norm: norm
rand: rand
real: real
sgn: sgn
sin: sin
sinh: sinh
sqrt: sqrt
tan: tan
tanh: tanh
tm_hour: tm_hour
tm_mday: tm_mday
tm_min: tm_min
tm_mon: tm_mon
tm_sec: tm_sec
tm_wday: tm_wday
tm_yday: tm_yday
tm_year: tm_year
valid: valid