6 非推奨な書式 (Deprecated syntax)

以前の版で使われていたいくつかの書式は gnuplot 4 で非推奨となりました が、後方互換性を持たせるためのコンパイル時のオプションが用意されていま す。古い書式のサポートは現在は削除されています。

gnuplot 4 では非推奨で、バージョン 5 では削除:

     set title "Old" 0,-1
     set data linespoints
     plot 'file' thru f(x)
     plot 1 2 4               # y=1 での水平線
     update

現在の同等の機能:

     TITLE = "New"
     set title TITLE offset char 0, char -1
     set style data linespoints
     plot 'file' using 1:(f(column(2)))
     plot 1 linetype 2 pointtype 4

バージョン 5.0 では非推奨:

     if (defined(VARNAME)) ...
     set style increment user
     call 'script' 1.23 ABC
        (in script:  print $0, "$1", "number of args = $#")
     set fontpath
     set clabel
     fit control variables FIT_*

現在の同等の機能:

     if (exists("VARNAME")) ...
     set linetype
     call 'script' 1.23 "ABC"
        (in script:  print ARG1, ARG2, "number of args = ", ARGC
     set cntrlabel
     set fit <option> <value>

バージョン 5.4 では非推奨:

     # 繰り返しを行うために `reread` を含むファイルを使用
     N = 0;  load "file-containing-reread";
     file content:
         N = N+1
         plot func(N,x)
         pause -1
         if (N<5) reread

現在の同等の機能:

     do for [N=1:5] {
         plot func(N, x)
         pause -1
     }