![[*]](crossref.gif)
)。
gnuplot-info@lists.sourceforge.net
gnuplot-bugs@lists.sourceforge.net
http://sourceforge.net/projects/gnuplot
Copyright (C) 1986 - 1993, 1998, 2004, 2007 Thomas Williams, Colin Kelley
Permission to use, copy, and distribute this software and its documentation for any purpose with or without fee is hereby granted, provided that the above copyright notice appear in all copies and that both that copyright notice and this permission notice appear in supporting documentation.
Permission to modify the software is granted, but not the right to
distribute the complete modified source code. Modifications are to
be distributed as patches to the released version. Permission to
distribute binaries produced by compiling modified sources is granted,
provided you
1. distribute the corresponding source modifications from the released version in the form of a patch file along with the binaries, 2. add special version identification to distinguish your version in addition to the base release version number, 3. provide your name and address as the primary contact for the support of your modified version, and 4. retain our contact information in regard to use of the base software.
This software is provided "as is" without express or implied warranty to the extent permitted by applicable law.
AUTHORS
Original Software:
Thomas Williams, Colin Kelley.
Gnuplot 2.0 additions:
Russell Lang, Dave Kotz, John Campbell.
Gnuplot 3.0 additions:
Gershon Elber and many others.
Gnuplot 4.0 and 5.0 additions:
See list of contributors at head of this document.
(以下おおまかな訳; 訳は正しくないかも知れませんので詳しくは上記の原文を当たってください。訳者は責任を持ちません。)
Copyright (C) 1986 - 1993, 1998, 2004, 2007 Thomas Williams, Colin Kelley
このソフトウェアとその付属文書の使用、複製、配布の許可は、上記の著作権(copyright) 表示が、全ての複製物に書かれていること、および著作権表示と この許諾文の両方がその支援文書に書かれていることを条件とした上で、この 文書により保証されます。
このソフトウェアの修正も認められています。しかし、修正を含む全ソースコ
ードの配布の権利は認められません。修正はリリース版に対するパッチの形で
配布しなければなりません。修正されたソースをコンパイルして作られたバイ
ナリの配布は、以下の条件の元で認められます:
1. リリース版からのソースの修正部分を、パッチの形でバイナリと共に配
布すること
2. ベースとなるリリース版と区別するために、そのバージョン番号に特別
なバージョン指定子を付加すること
3. その修正版のサポート用に、あなたの名前とアクセス可能なアドレスと
を提供すること
4. ベースとなるソフトウェアの使用に関しては、我々の連絡情報を保持し
続けること
このソフトウェアは "あるがまま" 提供され、適用可能な法律で許められる範 囲の保証を表明あるいは暗示していはいません。
著者
オリジナルソフトウェア:
Thomas Williams, Colin Kelley.
Gnuplot 2.0 追加:
Russell Lang, Dave Kotz, John Campbell.
Gnuplot 3.0 追加:
Gershon Elber とその他の人々。
Gnuplot 4.0, 5.0 追加:
この文書の先頭の寄与者 (contributors) の一覧参照。
gnuplot は、2 次元、または 3 次元の、多くの種類のグラフをサポートして います: 折線グラフ、点グラフ、棒グラフ、等高線、ベクトル場描画、曲面、 そしてそれらに関連するさまざまな文字列等。そしてさらにいくつかの特別な 描画型もサポートしています。
gnuplot は多くの異なる出力をサポートしています: 対話型スクリーン出力形 式 (マウスやホットキー入力も可能)、ペンプロッタや現在のプリンタへの直 接出力、または多くのファイル形式への出力 (eps, emf, fig, jpeg, LaTeX, pdf, png, postscript, ...)。gnuplot は、容易に新しい出力形式を追加する よう拡張することができます。最近追加された対話型出力形式には、 wxWidgets (複数のプラットホームで利用可能), Qt を元にしたものがありま す。svg や HTML5 canvas 出力形式を利用すれば、グラフを Web ページ内に マウス利用可能な形で埋め込んだ出力を生成することもできます。
gnuplot のコマンド言語は大文字小文字を区別します。すなわち、小文字で 書かれたコマンドや関数名は、それらを大文字で書いたものとは同じではあり ません。いずれのコマンドも、あいまいさの無い限りにおいて省略することが できます。1 行中にはセミコロン (;) で区切って複数のコマンドを書くこと ができます。文字列は単一引用符、あるいは二重引用符のどちらかで書き始め ますが、両者には微妙な違いがあります (詳細は、以下参照: syntax (27))。例:
set title "My First Plot"; plot 'data'; print "all done!"
コマンドは、複数行にまたがることができます。その場合は、最終行以外の全ての行の行末にバックスラッシュ ( \ ) を書く必要があります。バックスラ ッシュは必ず各行 *最後* の文字でなくてはなりません。その結果としてバッ クスラッシュと、それに続く改行文字が存在しなかったかのように扱われます。 つまり、改行文字がスペースの役をすることもありませんし、改行によってコ メントが終了することもありません。ですから複数行にまたがる行の先頭をコ メントアウトすると、そのコマンド全体がコメントアウトされることになりま す (以下参照: comments (10))。なお注意しますが、もし、複数行のコマンドの どこかでエラーが起きたとき、パーサはその場所を正確には指示することがで きませんし、また、正しい行に指示する必要もないでしょう。
このドキュメントにおいて、中括弧 ({}) は省略可能な引数を表すものとし、 縦棒 (| ) は、互いに排他的な引数を区切るものとします。gnuplot のキー ワードや help における項目名は、逆引用符 (｀)、または可能な場合には boldface (太字) で表します。角括弧 (< > ) は、それに対応するものに置き 換えられるべきものを表します。多くの場合、オプションの引数には、それが 省略されるとデフォルトの値が使用されます。しかし、これらの場合、必ずし も角括弧が中括弧で囲まれて書かれているわけではありません。
ある項目についてのヘルプが必要なときには、help に続けてその項目名を 入力して下さい。または単に help ? でもヘルプの項目のメニューが現われ ます。
大量のグラフサンプルが、以下の Web ページにあります。
コマンドラインから起動するときは、以下の書式が使えます。
gnuplot {OPTIONS} file1 file2 ...
gnuplot {X11OPTIONS} {OPTIONS} file1 file2 ...
gnuplot に与えるオプションは、コマンド行のどこに置いても構いません。フ
ァイルは指定した順に実行され、同様に -e オプションで任意のコマンドを与
えることもできます。例:
gnuplot file1.in -e "reset" file2.in
特別なファイル名 "-" は、標準入力から読ませるのに使います。gnuplot
は最後のファイルを処理し終わると終了します。読み込ませるファイルを一つ
も指定しない場合は、gnuplot は標準入力からの対話入力を取ります。詳細
は、以下参照: batch/interactive (7)。gnuplot 用のオプションについては、
以下のようにして一覧を見ることができます:
gnuplot --help
対話型描画ウィンドウでの作業中は、'h' を打つとホットキー (hotkeys) とマウス機能 (mousing) に関するヘルプを見ることができます。 seeking-assistance のセクションは、さらなる情報やヘルプ、FAQ を探す 手掛りを与えてくれるでしょう。
助けを求める前に、ファイル FAQ.pdf か、または上の Web サイトの
FAQ (度々聞かれる質問; Frequently Asked Questions) の一覧
をチェックしてください。
gnuplot ユーザとしての手助けが必要なら、以下のニュースグループを利用してください。
comp.graphics.apps.gnuplot
gnuplot メーリングリストへの投稿の方法に関しては、SouceForge にある gnuplot の開発 Web サイト
http://sourceforge.net/projects/gnuplot
を参照してください。
gnuplot メーリングリストにメールを書く前に、最初にそのメーリングリスト に参加する必要があることに注意してください。これは、スパムの量を減らす ことを維持するために必要です。
メーリングリストメンバーへのメールアドレス:
gnuplot-info@lists.sourceforge.net
バグリポート、ソースの改良等は以下の trackers に upload してください:
http://sourceforge.net/projects/gnuplot/support
開発版に関するメーリングリスト:
gnuplot-beta@lists.sourceforge.net
何か質問を投稿するときは、あなたが使用している gnuplot のバージョン、 出力形式、オペレーティングシステム、といった全ての情報を含むようにして ください。その問題を引き起こす「小さい」スクリプトがあればなお良いです。 その場合、データファイルのプロットよりも関数のプロットの方がより良いで す。
* 線の点線/破線パターンは、現在は線の他の属性と独立に指定できます。以下参照: dashtype (19.2), set dashtype (88.18), set linetype (88.37)。
* 文字の書式制御は、下付き、上付き、フォントサイズ、その他以前有効だったものに加え、今は太字体 (bold) と斜体 (italic) フォント設定もサポート しています。このモード (拡張文字処理) は、現在はデフォルトで有効となっ ています。以下参照: enhanced text (13)。
* 対話型出力形式は、ハイパーテキストラベルをサポートしていますが、これ はマウスがそのラベルのリンク点上にあるときにのみ現れるものです。
* 新しい座標系 (度、分、秒)。以下参照: set xtics geographic (88.104.2)。
* 軸の見出しのデフォルト書式用の "% h" (LaTeX 系出力形式では "$%h$")。
この書式は C の標準書式の %g に似ていますが、指数部分がある場合には、
それが上付き文字として書かれることが違います。例えば、1.2E05 でなく、
1.2 x 10^5 となります。
* スクリプト内で、インラインデータを名前付きのデータブロックとして保存 し繰り返し描画できるように。以下参照: inline data (77.3.4)。
* 32-bit のアルファ値 + RGB 色表記 (#AARRGGBB) をサポート。以下参照:colorspec (19.1)。
* hsv2rgb(H,S,V) という変換関数により HSV 色空間をサポート。
* 第 2 軸 (x2, y2) は、対応関数により、第 1 軸に固定できます。最も単純 なのは、これにより第 1 軸と 2 軸の軸の範囲を一致させることです。より一 般に、これにより非線形な軸を定義できるようになりますが、これまではその ようなことは対数軸しかできませんでした。以下参照: set link (88.38)。
* plot コマンドの各関数にオプションとして描画範囲を前置指定できます。
これは、plot 全体の範囲には影響せず、その関数のデータをサンプリングす
る範囲でしかありません。以下参照: plot (77), piecewise.dem ()。
* 外部ライブラリ libcerf が利用可能であれば、それは複素数学関数 cerf, cdawson, erfi, faddeeva, および Voigt プロファイル VP(x,sigma,gamma) を提供するのに使われます。
* コマンド import は、外部共有オブジェクト (サポートはオペレーティン グシステム依存) が提供する関数にユーザ定義関数名を割り当てます。適当な 外部共有オブジェクトを作るためのテンプレートヘッダファイル、サンプルソ ース、makefile などが demo の中にあります。
* 対話作業の履歴一覧内の直前のコマンドは、番号で再実行できます。例えば history !5 は、history の一覧内の 5 番のコマンドを再実行します。
* ビットシフト演算子 > > と < < 。
* 新しい描画スタイル with parallelaxes、with table、および等高線の ラベル付け。
* gnuplot のシェル呼び出しで gnuplot スクリプトにパラメータを渡せます。 gnuplot -c scriptfile.gp ARG1 ARG2 ARG3 ...
import f(x) from "plugin.so" # 共有ライブラリから関数を読み込み
set history {quiet|numers} {full|trim} # history コマンド出力の制御
history !N # 以前のコマンドを番号で再実行
plot <datafile> skip N # テキストデータ先頭数行をスキップ
plot ... smooth mcsplines # データに沿う単調 3 次スプライン
reset session # 現在の作業の初期状態を復帰
set arrow <tag> from <start> length <len> angle <ang>
set colorsequence default|classic|podo # 以後の描画要素で使用する色
set monochrome # 線種の別な設定法
set dashtype <tag> <dash-spec> # ユーザ定義破線パターン
set link x2 via f(x) inverse g(x) # 非線形軸スケールを可能に
set fit quiet|results|brief|verbose # fit 出力量の制御
set contours; splot ... with labels # 数値での等高線のラベル
set style textbox # 文字列要素に外枠をつける
set view map {scale} # 3D 射影描画のリサイズが可能に
set multiplot {next|previous} # 自動レイアウト格子内での移動
* NaN や、正しくないデータ列数、または他の予期しないものを含む入力デー タの処理の改良。例 (や図) については、以下参照: missing (88.20.3)。
* 時間座標は、標準的な Unix エポック (1970 年 1 月 1 日) からの秒数と して内部で保存します。以前の版の gnuplot では、別のエポック (2000 年1 月 1 日) を内部で使用していました。この変更は、gnuplot の外で作られ た秒単位のデータによって矛盾がもたらされる問題を解決します。インストー ルされている個々の gnuplot がどちらのエポックを使用しているかについて は、コマンド print strftime("%F",0) で知ることができます。現在は、時 間は少なくともミリ秒の精度で保存されます。
* 関数 timecolumn(N,"timeformat") は、現在は 2 つの引数を持ちます。 新しい 2 つ目の引数はどのデータ軸とも関連しておらず、よってこれにより 関数 timecolumn を、x や y 軸に指定するのとは違う形式の日時データの 読み込みに使えるようになります。この機能は、次のコマンド列に取って変わ ります: set xdata time; set timefmt "timeformat"。これは、複数のファ イルから異なる書式の日時データを読んで、それらを組み合わせて 1 つのグ ラフにすることを可能にします。
* コマンド set [axis]range のキーワード reverse は、自動縮尺 (autoscaling) にのみ影響し、set xrange [0:1] のようなコマンドの意味 を逆にしたり他の変更を行ったりはしません。このような場合に x 軸の方向 を逆向きにしたければ、代わりに set xrange [1:0] としてください。
* コマンド call は、変数群 ARGC, ARG0, ..., ARG9 を提供するよう実装 されています。ARG0 は、実行するスクリプト名を指します。ARG1 から ARG9 は文字列変数になるので、直接参照するか、または例えば @ARG1 のようにマ クロ展開させたものを参照することができます。call の古いパラメータ参照 形式 $0 ... $9 は現在は非推奨です。
* オプション smooth の kdensity の、bandwidth の追加指定では、データ列 からでなく 1 つのキーワードとして値を取ります。以下参照:smooth kdensity (77.3.6.11)。
* unset xrange (および他の軸の範囲も) は、元のデフォルトの範囲を復帰 します。
* unset terminal は、gnuplot 開始時の出力形式を復帰します。
gnuplot 4 では非推奨で、バージョン 5 では削除:
set title "Old" 0,-1
set data linespoints
plot 1 2 4 # y=1 での水平線
TITLE = "New"
set title TITLE offset char 0, char -1
set style data linespoints
plot 1 linetype 2 pointtype 4
if (defined(VARNAME)) ...
set style increment user
plot 'file' thru f(x)
call 'script' 1.23 ABC
(in script: print $0, "$1", "number of args = $#")
if (exists("VARNAME")) ...
set linetype
plot 'file' using 1:(f(column(2)))
call 'script' 1.23 "ABC"
(in script: print ARG1, ARG2, "number of args = ", ARGC
コマンドライン引数は、プログラムへのオプション (文字 - で始まる) か、 gnuplot コマンドを含むファイルの名前であると解釈されます。 -e "command" の形式のオプションは、gnuplot コマンドを強制的に実行させ、 各ファイルとこのコマンド文字列は、指定された順に実行されます。特別なフ ァイル名 "-" は、コマンドを標準入力から読み込むことを意味します。最後 のファイルを実行した後に gnuplot は終了します。読み込ませるファイル、 およびコマンド文字列を指定しなかった場合は、gnuplot は標準入力からの 対話型の入力を受け付けます。
exit と quit はどちらも現在のコマンドファイルを終了し、まだ全ての ファイルが終っていなければ、次のファイルを load するのに使われます。
例:
対話を開始する:
gnuplot
2 つのコマンドファイル "input1", "input2" を使ってバッチ処理を行なう:
gnuplot input1 input2
初期化ファイル "header" の後、対話型モードを起動し、その後別のコマンド
ファイル "tailer" を実行する:
gnuplot header - trailer
コマンドラインから gnuplot コマンドを直接与え、終了後にスクリーン上
にグラフが残るようにオプション "-persist" を使う:
gnuplot -persist -e "set title 'Sine curve'; plot sin(x)"
ファイルのコマンドを実行する前に、ユーザ定義変数 a と s をセットする:
gnuplot -e "a=2; s='file.png'" input.gpl
gnuplot の以前の版では、set size の値を、出力する描画領域 (キャンバス) のサイズを制御するのにも使っていた出力形式もありましたが、すべての 出力形式がそうだったわけではありませんでした。この目的のために set size を使用することはバージョン 4.2 で非推奨となり、現在はほとん どの出力形式が以下のルールに従います:
set term < terminal_type> size < XX> , < YY> は、出力ファイルのサイズ、 または "キャンバス" のサイズを制御します。デフォルトでは、グラフはその キャンバス全体に描画されます。
set size < XX> , < YY> は、描画自体をキャンバスのサイズに対して相対的に 伸縮させます。1 より小さい伸縮値を指定すると、グラフはキャンバス全体を 埋めず、1 より大きい伸縮値を指定すると、グラフの一部分のみがキャンバス 全体に合うように描画されます。1 より大きい伸縮値を指定すると、ある出力 形式では問題が起こるかもしれないことに注意してください。
このルールに沿わない主な例外は PostScript ドライバで、デフォルトでは以前の版のと同じ振舞いをしますが、将来は PostScript ドライバも同様にデフォルトの振舞いを変更することになるでしょう。
例:
set size 0.5, 0.5
set term png size 600, 400
set output "figure.png"
plot "data" with lines
このコマンドは、幅 600 ピクセル、高さ 400 ピクセルの出力ファイル "figure.png" を生成します。グラフはキャンバスの中の左下に置かれます。 これは、multiplot モードが常に行ってきた方法と矛盾しません。
組み込みの readline 版の場合の編集コマンドは以下の通りですが、DEL キーに関する動作はシステムに依存することに注意してください。GNU readline ライブラリと BSD libedit ライブラリに関しては、それ自身のドキュメント を参照してください。
| コマンド行編集コマンド | |
| 文字 | 機能 |
| 行編集 | |
^B |
1 文字前へ戻す |
^F |
1 文字先へ進める |
^A |
行の先頭へ移動 |
^E |
行の最後へ移動 |
^H |
直前の文字を削除 |
DEL |
現在の文字を削除 |
^D |
現在位置の文字を削除、空行なら EOF |
^K |
現在位置から行末まで削除 |
^L, ^R |
壊れた表示の行を再表示 |
^U |
行全体の削除 |
^W |
直前の単語を削除 |
| 履歴 | |
^P |
前の履歴へ移動 |
^N |
次の履歴へ移動 |
データファイルに対するコメント文字の指定については、以下参照:set datafile commentschars (88.20.5)。
{<system>} <x>, {<system>} <y> {,{<system>} <z>}
各座標系指定 < system> には、first, second, graph, screen, character のいずれかが入ります。
first は左と下の軸で定義される x,y (3D の場合は z も) の座標系を使用 します。second は x2, y2 軸 (上と右の軸) を使用します。graph はグ ラフ描画領域内の相対的位置を指定し、左下が 0,0 で 右上が 1,1 (splot の 場合はグラフ描画領域内の左下が 0,0,0 で、土台の位置は負の z の値を使用 します。以下参照: set xyplane (88.105)) となります。screen は表示範囲内 (範 囲全体であり、set size で選択される一部分ではありません) を指定し、 左下が 0,0 で 右上が 1,1 となります。character は、画面領域の左下 (screen 0,0) からの、文字の幅、文字の高さでの位置を与えます。よって、 character 座標は、選択されたフォントのサイズに依存します。
x の座標系が指定されていない場合は first が使われます。y の座標系が 指定されていない場合は x に対する座標系が使用されます。
与える座標が絶対的な位置ではなくて相対的な値である場合もあります (例え ば set arrow ... rto の 2 番目の数値)。そのほとんどが、与えられた 数値を最初の位置に対する差として使います。与えられた座標が対数軸内にあ る場合は、その相対的な値は倍率として解釈されます。例えば
set logscale x
set arrow 100,5 rto 10,2
は、x 軸が対数軸で y 軸が線形の軸なので、100,5 の位置から 1000,7 の位 置への矢印を書くことになります。
一つ (あるいはそれ以上) の軸が時間軸である場合、timefmt の書式文字列に従って、引用符で囲まれた時間文字列で適切な座標を指定する必要があります。以下参照: set xdata (88.99), set timefmt (88.83)。また、gnuplot は整数表記も 認めていて、その場合その整数は 1970 年 1 月 1 日からの秒数と解釈されま す。
1.000 2.000 "Third column is all of this text" 4.00
テキスト部分は 2 次元や 3 次元描画内で例えば以下のように使用されます:
plot 'datafile' using 1:2:4 with labels splot 'datafile' using 1:2:3:4 with labels
テキスト部分の列データは 1 つ、または複数の描画軸の目盛りのラベルとし て使用できます。次の例は、入力データの 3 列目と 4 列目を (X,Y) 座標と して取り出し、それらの点の列を結ぶ線分を描画します。しかしこの場合 gnuplot は、x 軸に沿って標準的に間の空いた数字ラベルのついた目盛り刻み をつけるのではなく、入力データファイルの 1 行目の X 座標の位置に、目盛 り刻みと文字列を x 軸に沿ってつけて行きます。
set xtics plot 'datafile' using 3:4:xticlabels(1) with linespoints
入力データの列の最初のエントリ (すなわち列の見出し) をテキスト部分と解 釈するもう一つのオプションがあり、それはテキスト部分を、その描画した列 のデータの凡例 (key) のタイトル部分として使用します。次の例は、先頭の 行の 2 列目の部分を凡例ボックス内のタイトルを生成するのに使用し、その 後の列の 2,4 列目は要求された曲線を描画するのに処理されます:
plot 'datafile' using 1:(f($2)/$4) with lines title columnhead(2)
別の例:
plot for [i=2:6] 'datafile' using i title "Results for ".columnhead(i)
以下参照: labels (45), using xticlabels (77.3.9.3), plot title (77.11), using (77.3.9)。
^2"
は x の自乗を、通常我々が見る上付きの 2 がついた形で書き出します。この
モードは、出力形式の設定時にデフォルトとして選択されますが、その後で
"set termoption [no]enhanced" を使ってその機能を有効/無効にもできます
し、"set label 'x_2' noenhanced" のように個々の文字列に適用することも
できます。
| 拡張文字列制御記号 | |||
| 制御記号 | 例 | 結果 | 説明 |
^ |
a^x |
ax | 上付き文字 |
_ |
a_x |
ax | 下付き文字 |
@ |
a@^b_{cd} |
abcd | 空ボックス (幅がない) |
& |
d&{space}b |
d b |
指定した長さのスペースを挿入 |
~ |
~a{.8-} |
|
'a' の上に '-' を、現在のフォントサ |
|
|
イズの .8 倍持ち上げた位置に重ね書き | |
|
{/Times abc} |
abc | Times フォント、今のサイズで abc を出力 |
|
{/Times*2 abc} |
abc | Times フォント、今の倍のサイズで abc |
|
{/Times:Italic abc} |
abc | Times フォント、イタリック体で abc |
|
{/Arial:Bold=20 abc} |
abc | Arial フォント、太字、サイズ 20 で abc |
書式制御文字は、それに続く 1 文字、または中カッコで囲まれたものに適用
されます。中カッコ内には、例えば 2^{10} のような追加の書式文字列のない文字列か、またはフォントの属性を変更する追加制御文字列を入れることができます。以下の例はその中カッコの入れ子を示していて、ボールド体の A にイタリック体の下付きの添字 i がついたものが、いずれも現在のフォントで描かれます。この例の :Normal を取ると、下付きの添字はボールド体でかつ
イタリック体になります。
{/:Bold A_{/:Normal{/:Italic i}}}
空ボックス (phantom box) は a@^b_c の上付き文字と下付き文字を揃えると
きに有用ですが、文字にアクセント記号を重ねる場合にはうまく働きません。
後者の目的のためには、色々なアクセントやその他のダイアクリティカルマ
ークのある多くの文字を持つエンコード (例えば iso_8859_1 や utf8) を使
用する方がいいでしょう。以下参照: set encoding (88.24)。そのボックスはスペー
シングが行なわれないので、ボックス内 (つまり @ の後ろ) の上付き文字や
下付き文字を短く出力するのに適しています。
ある文字列と同じ長さのスペースを文字 '&' を使うことで入れることができ
ます。すなわち、
'abc&{def}ghi'
'abc ghi'
文字 '~ ' は、次の文字、またはカッコで囲まれた文字列に、それに続く文字
またはカッコで囲まれた文字列を重ね書きします。2 番目の文字は最初の文字
にあわせて水平方向にセンタリングされます。よって '~ a/' は 'a' を貫くよ
うなスラッシュが得られます。2 番目の文字は、その前に数字を置くことで垂
直方向に移動させることができます。その数字は現在のフォントサイズに対す
る割合を意味し、それに従って文字が上がったり下がったりします。この場合
数字と文字列は 1 文字より長くなるのでカッコで囲む必要があります。重ね
書きされる文字列が数字から始まっている場合は、垂直にずらす値と文字列と
の間にスペースを入れてください ('~ {abc}{.5 000}')。それ以外はスペースは不要です ('~ {abc}{.5 -- }')。一方、あるいは両方のフォントを変更するこ
ともできます ('~ a{.5 /*.2 o}'; 'a' その 1/5 の大きさの 'o'、この場合数
字とスラッシュの間のスペースは必要です) が、その文字列が始まった後で変
更することはできません。それぞれの文字列内で、他の特殊な書式を使うこと
もできません。もちろん、'~ a{
\
^}' のように特殊な文字をエスケープするこ
と (下記参照) は可能です。
特殊記号は、8 進文字コードを与えることで数字で指定できます。例えば、 {/Symbol \ 245} は、Adobe Symbol フォントの無限大の記号です。しかし、こ れは、 UTF-8 のようなマルチバイトエンコーディングではうまくいきません。 UTF-8 環境では、タイプ打ち、そうでなければあなたが望む文字を選ぶような 方法で、マルチバイト列を間接的に入力できるようにすべきです。
制御文字は、 \ \ や \ { などのように \ を使ってエスケープできます。
二重引用符内の文字列は単一引用符内の文字列とは異なって解釈されることに 注意してください。主な違いは、二重引用符内の文字列ではバックスラッシュ は 2 つ重ねる必要があることです。
gnuplot ソース配布物内の /docs/psdoc サブディレクトリにあるファイル "ps_guide.ps" に、拡張された書式に関する例が載っています。同様のものが デモ
にもあります。
GNUTERM は、それが定義されていれば、起動時のデフォルト出力形式として使 われます。これは、~ /.gnuplot (またはそれに相当する) 初期化ファイル (以下参照: startup (24)) による指定や、もちろんその後の明示的な set term コマンドによる指定で変更できます。
GNUHELP にヘルプファイル (gnuplot.gih) のパス名を定義しておくことがで きます。
VMS では、論理名 GNUPLOT$HELP を gnuplot のヘルプライブラリの名前と して定義します。gnuplot のヘルプは任意の VMS システムのヘルプライブ ラリに入れることができます。
Unix においては、カレントディレクトリに .gnuplot というファイルがない 場合には、HOME に定義されたディレクトリを探します。MS-DOS, Windows, OS/2 では GNUPLOT がその役割に使われます。Windows では、NT 専用の変数 USERPROFILE も参照されます。VMS では SYS$LOGIN です。help startup と打ってみてください。
Unix においては、PAGER がヘルプメッセージの出力用のフィルタとして使わ れます。
Unix では、SHELL が shell コマンドの際に使われます。MS-DOS, OS/2 で は COMSPEC が shell コマンドの際に使われます。
FIT_SCRIPT は、当てはめ (fit) が中断されたときに実行する gnuplot コマンドの指定に使われます。以下参照: fit (68)。FIT_LOG は当てはめによ るログファイルのデフォルトのファイル名の指定に使われます。
GNUPLOT_LIB は、データやコマンドファイルの検索ディレクトリを追加定義す るのに使われます。その変数は、一つのディレクトリ名かまたは複数のディレ クトリ名を書くことができますが、ディレクトリの区切りはプラットホーム毎 に違います。例えば Unix では ':' で、MS-DOS, Windows, OS/2 では ';' で す。GNUPLOT_LIB の値は変数 loadpath に追加されますが、それは save や save set コマンドでは保存されません。
出力ドライバの中には gd ライブラリ経由で TrueType フォントを扱えるもの もいくつかあります。これらのドライバのフォント検索パスは、環境変数 GDFONTPATH で制御できます。さらに、それらのドライバでのデフォルトのフ ォントは環境変数 GNUPLOT_DEFAULT_GDFONT で制御できます。
postscript 出力ドライバは自分で持っているフォント検索パスを使いますが、 それは環境変数 GNUPLOT_FONTPATH で制御できます。書式は GNUPLOT_LIB と 同じです。GNUPLOT_FONTPATH の値は変数 fontpath に追加されますが、そ れは save や save set コマンドでは保存されません。
PostScript ドライバは、外部 (組み込まれていない) 定義ファイルを探すた めに環境変数 GNUPLOT_PS_DIR を利用します。インストール時の作業により、 gnuplot にはそれらのファイルのコピーが組み込まれているか、またはデフォ ルトのパスが埋め込まれています。この変数は、postscript 出力形式でデフ ォルトのファイルの代わりにカスタマイズした prologue ファイルを使用する のに利用できます。以下参照: postscript prologue (98.48.3)。
複素数の定数は {< real> ,< imag> } と表現します。ここで < real> と < imag> (実部、虚部) は数値定数である必要があります。例えば {3,2} は 3 + 2i を あらわし、{0,1} は 'i' 自身を表します。これらには明示的に中カッコを使 う必要があります。
整数定数は、C の strtoll() ライブラリルーチンを使って解釈しますが、こ れは、"0" で始まる定数は 8 進数と、また "0x" か "0X" で始まる定数は 16 進数とみなすことを意味します。
実数 (浮動小数) 定数は、C の atof() ライブラリルーチンを使って解釈しま す。
gnuplot は "実数" と "整数" 演算を FORTRAN や C のように扱うということ に注意してください。"1", "-10" などは整数と見なされ、"1.0", "-10.0", "1e1", 3.5e-1 などは実数と見なされます。 これら 2 つのもっとも重要な違 いは割算です。整数の割算は切り捨てられます: 5/2 = 2。実数はそうではあ りません: 5.0/2.0 = 2.5。それらが混在した式の場合、計算の前に整数は実 数に "拡張" されます: 5/2e0 = 2.5。負の整数を正の整数で割る場合、その 値はコンパイラによって変わります。"print -5/2" として、あなたのシステ ムが -2 と -3 のどちらを答えとするかを確認してください。
数式 "1/0" は "未定義値 (undefined)" フラグを生成し、それによりその点 を無視します。あるいは、あらかじめ定義されている値 NaN を使っても同じ ことになります。例については、以下参照: using (77.3.9)。
複素数表現の実数部分、虚数部分は、どんな形で入力されても常に実数です: {3,2} の "3" と "2" は実数であり、整数ではありません。
gnuplot は文字列に対する単純な演算、および文字列変数も利用できます。例 えば式 ("A" . "B" eq "AB") は真と評価されますが、これは文字列の結合演 算子と文字列の等号演算子を意味しています。
数としての値を含む文字列は、それが数式で利用された場合は、対応する整数 や実数に変換されます。よって、("3" + "4" == 7) や (6.78 == "6.78") は どちらも真になります。整数は、それが文字列結合演算子で使われた場合は文 字列に変換されますが、実数や複素数はダメです。典型的な例は、ファイル名 や他の文字列内に整数を使う場合でしょう: 例えば ("file" . 4 eq "file4") は真です。
後置指定する範囲記述子 [beg:end] によって、部分文字列を指定することが できます。例えば、"ABCDEF"[3:4] == "CD" で、"ABCDEF"[4:*] == "DEF" で す。書式 "string"[beg:end] は、文字列値の組み込み関数 substr("strings",beg,end) を呼ぶこととほぼ同じですが、関数呼び出しでは beg, end は省略することはできません。
関数 EllipticE(k) は、第 2 種完全楕円積分、すなわち、関数 (1-(k*sin(p))**2)**0.5 の 0 からπ/2 までの範囲の広義積分の値を返し ます。k の定義域は -1 から 1 です (両端も含む)。
関数 EllipticPi(n,k) は、第 3 種完全楕円積分、すなわち関数 (1-(k*sin(p))**2)**(-0.5)/(1-n*sin(p)**2) の 0 からπ/2 までの範囲の 広義積分の値を返します。パラメータ n は 1 より小さく、k は -1 と 1 の間 (両端は含まない) でなければいけません。定義より、すべての正の k に対し EllipticPi(0,k) == EllipticK(k) であることに注意してください。
(n, k)
x
0
t-ne-xt dt
x
dt
e-z2erfi(z)
G(x
;
rand(0) 内部に持つ 2 つの 32bit の種 (seed) の現在の値から生
成される [0:1] 区間内の疑似乱数値を返す
rand(-1) 2 つの種の値を標準値に戻す
rand(x) 0 < x < 2^31-1 の整数なら種の両方を x に設定する
rand({x,y}) 0 < x,y < 2^31-1 の整数なら seed1 を x に seed2 を y
に設定する
words("string") は、文字列 (string) の単語数を返します。例えば、 words(" a b c d") は 4 を返します。
関数 word と words は、単一引用符、二重引用符で囲まれた文字列も、
限定的ですがサポートしています:
print words("\"double quotes\" or 'single quotes'") # 3
print words("Alexis' phone doesn't work") # 4
s = "Keep \"'single quotes'\" or '\"double quotes\"'"
print word(s, 2) # 'single quotes'
print word(s, 4) # "double quotes"
演算の評価の順序を変更するにはかっこを使います。
| 単項演算子 | ||
| 記号 | 例 | 説明 |
- |
-a |
マイナス符号 |
+ |
+a |
プラス符号 (何もしない) |
~ |
~a |
* 1 の補数 (ビット反転) |
! |
!a |
* 論理的否定 |
! |
a! |
* 階乗 |
$ |
$3 |
* `using` 内での引数/列指定 |
説明に星印 (*) のついた演算子の引数は整数でなければなりません。
演算子の優先順位は Fortran や C と同じです。それらの言語同様、演算の評 価される順序を変えるためにかっこが使われます。よって -2**2 = -4 で、 (-2)**2 = 4 です。
階乗演算子は、大きな値を返せるように実数を返します。
| 二項演算子 | ||
| 記号 | 例 | 説明 |
** |
a**b |
累乗 |
* |
a*b |
積 |
/ |
a/b |
商 |
% |
a%b |
* 余り |
+ |
a+b |
和 |
- |
a-b |
差 |
== |
a==b |
等しい |
!= |
a!=b |
等しくない |
< |
a<b |
より小さい |
<= |
a<=b |
以下 |
> |
a>b |
より大きい |
>= |
a>=b |
以上 |
<< |
0xff<<1 |
符号なし左シフト |
>> |
0xff>>1 |
符号なし右シフト |
& |
a&b |
* ビット積 (AND) |
^ |
a^b |
* ビット排他的論理和 (XOR) |
| |
a|b |
* ビット和 (OR) |
&& |
a&&b |
* 論理的 AND |
|| |
a||b |
* 論理的 OR |
= |
a = b |
代入 |
, |
(a,b) |
累次評価 |
. |
A.B |
文字列の連結 |
eq |
A eq B |
文字列が等しい |
ne |
A ne B |
文字列が等しくない |
説明に星印 (*) のついた演算子の引数は整数でなければなりません。 大文字の A,B は演算子が文字列引数を要求することを意味します。
論理演算子の AND (&&) と OR (| | ) は C 言語同様に必要最小限の評価しかし ません。すなわち、&& の第 2 引数は、第 1 引数が偽ならば評価されませ んし、| | の第 2 引数は、第 1 引数が真ならば評価されません。
累次評価 (,) は、カッコの中でのみ評価され、左から右へ順に実行すること が保証され、最も右の式の値が返されます。
| 三項演算子 | ||
| 記号 | 例 | 説明 |
?: |
a?b:c |
三項演算子 |
三項演算子は C のものと同じ働きをします。最初の引数 (a) は整数でなけれ ばいけません。この値が評価され、それが真 (ゼロでない) ならば 2 番目の 引数 (b) が評価されその値が返され、そうでなければ 3 番目の引数 (c) が 評価され、その値が返されます。
三項演算子は、区分的に定義された関数や、ある条件が満たされた場合にのみ 点を描画する、といったことを行なう場合に有用です。
例:
0 <
= x <
1 では sin(x) に、1 <
= x <
2 では 1/x に等しくて、それ以外のx では定義されない関数を描画:
f(x) = 0<=x && x<1 ? sin(x) : 1<=x && x<2 ? 1/x : 1/0
plot f(x)
ファイル 'file' のデータで、4 列目のデータが負でないときだけ、1 列目の データに関する 2 列目と 3 列目のデータの平均値を描画:
plot 'file' using 1:( $4<0 ? 1/0 : ($2+$3)/2 )
using の書式の説明に関しては、以下参照: plot datafile using (77.3.9)。
sum [<var> = <start> : <end>] <expression>
print sum [i=1:10] i
55.
# 以下は plot 'data' using 1:($2+$3+$4+$5+$6+...) と同等
plot 'data' using 1 : (sum [col=2:MAXCOL] column(col))
例: 点 [X,Y] のスクリーン比での座標を計算する方法
GRAPH_X = (X - GPVAL_X_MIN) / (GPVAL_X_MAX - GPVAL_X_MIN)
GRAPH_Y = (Y - GPVAL_Y_MIN) / (GPVAL_Y_MAX - GPVAL_Y_MIN)
SCREEN_X = GPVAL_TERM_XMIN + GRAPH_X * (GPVAL_TERM_XMAX - GPVAL_TERM_XMIN)
SCREEN_Y = GPVAL_TERM_YMIN + GRAPH_Y * (GPVAL_TERM_YMAX - GPVAL_TERM_YMIN)
FRAC_X = SCREEN_X * GPVAL_TERM_SCALE / GPVAL_TERM_XSIZE
FRAC_Y = SCREEN_Y * GPVAL_TERM_SCALE / GPVAL_TERM_YSIZE
読み出し専用変数 GPVAL_ERRNO は、任意の gnuplot コマンドがあるエラーの ために早く終わってしまった場合に 0 でない値にセットされ、直前のエラー メッセージは文字列変数 GPVAL_ERRMSG に保存されます。GPVAL_ERRNO と GPVAL_ERRMSG は、コマンド reset errors を使ってクリアできます。
mouse 機能が使える対話型入出力形式は、"MOUSE_" で始まる読み出し専用 変数をいくつか持っています。詳細は、以下参照: mouse variables (21.2)。
fit 機能は、"FIT_" で始まるいくつかの変数を使用しますので、そのよう な名前を使うのは避けるべきでしょう。set fit errorvariables を使用す ると、各当てはめ変数のエラーは、そのパラメータ名に "_err" を追加した変 数に保存されます。詳細は、以下参照: fit (68)。
以下も参照: user-defined variables (15.5), reset errors (86),mouse variables (21.2), fit (68)。
ユーザ定義関数書式:
<func-name>( <dummy1> {,<dummy2>} ... {,<dummy12>} ) = <expression>
ここで < expression> は仮変数 < dummy1> から < dummy12> で表される数式です。
ユーザ定義変数書式:
<variable-name> = <constant-expression>
例:
w = 2
q = floor(tan(pi/2 - 0.1))
f(x) = sin(w*x)
sinc(x) = sin(pi*x)/(pi*x)
delta(t) = (t == 0)
ramp(t) = (t > 0) ? t : 0
min(a,b) = (a < b) ? a : b
comb(n,k) = n!/(k!*(n-k)!)
len3d(x,y,z) = sqrt(x*x+y*y+z*z)
plot f(x) = sin(x*a), a = 0.2, f(x), a = 0.4, f(x)
file = "mydata.inp"
file(n) = sprintf("run_%d.dat",n)
最後の 2 行の例は、ユーザ定義文字列変数と、ユーザ定義文字列関数を意味 しています。
変数 pi (3.14159...) と NaN (IEEE 非数 ("Not a Number")) はあらか じめ定義されています。これらが必要なければ、他のものに再定義することも 可能ですし、以下のようにして元の値に復帰することもできます:
NaN = GPVAL_NaN
pi = GPVAL_pi
他にもいくつかの変数が、例えば対話型入出力形式でのマウス操作や当てはめ (fit) などの gnuplot の動作状態に応じて定義されます。詳細は 以下参照: gnuplot-defined variables (15.4)。
ある変数 V が既に定義されているかどうかは、式 exists("V") でチェックで
きます。例:
a = 10
if (exists("a")) print "a is defined"
if (!exists("b")) print "b is not defined"
変数名や関数名の命名規則は、大抵のプログラミング言語と同じで、先頭はア ルファベットで、その後の文字はアルファベット、数字、"_" が使えます。
各関数の定義式は、'GPFUN_' という接頭辞を持つ特別な文字列値変数として 利用できます。
例:
set label GPFUN_sinc at graph .05,.95
以下参照: show functions (88.29), functions (77.6), gnuplot-defined variables (15.4),macros (26.2), value (15.1.3)。
一時的に、例えば Adobe Symbol フォントのような特別なフォントに切り替え ることでアルファベットではない記号を入れることも可能ですが、現在は、 UTF-8 エンコーディングを使用して、必要な記号を指す Unicode エントリを 指定するという方法があります。以下参照: encoding (88.24), locale (88.41)。
を参照してください。これは、gnuplot で一般的な名前やサイズでフォントを
要求することを可能にし、必要ならば fontconfig に同等のフォントを代用さ
せることもできるので、通常はこれで十分でしょう。以下は、多分いずれも機能します:
set term pdfcairo font "sans,12"
set term pdfcairo font "Times,12"
set term pdfcairo font "Times-New-Roman,12"
set term png tiny
多くのシステムで、libgd は Adobe Type 1 フォント (*.pfa) と TrueType
フォントへのアクセスも提供します。その場合フォント自身の名前ではなく、
フォントファイルの名前を、"<
face>
{,<
pointsize>
}" の形式で与えます。
ここで、<
face>
はフォントファイルのフルパス名か、または環境変数
GDFONTPATH で指示されるディレクトリの一つの中のファイル名の先頭部分、
のいずれかです。よって、'set term png font "Face"' は、
<
あるディレクトリ>
/Face.ttf か <
あるディレクトリ>
/Face.pfa というファ
イル名のフォントを探そうとします。例えば、GDFONTPATH に
/usr/local/fonts/ttf:/usr/local/fonts/pfa が含まれている場合は、以下のコマンドの 2 つずつはいずれも同じことになります:
set term png font "arial"
set term png font "/usr/local/fonts/ttf/arial.ttf"
set term png font "Helvetica"
set term png font "/usr/local/fonts/pfa/Helvetica.pfa"
set term png font "arial,11"
TrueType と Adobe Type 1 フォントは、完全に大きさの変更や回転が可能で す。"set term" コマンドでフォントを指定しなかった場合、gnuplot は別の デフォルトフォントの設定があるかどうかを調べるために環境変数 GNUPLOT_DEFAULT_GDFONT を参照します。
PostScript プリンタや表示ソフトはすべて、標準的な Adobe フォントセット Times-Roman, Helvetica, Courier, Symbol は知っているはずです。 多分その他にも多くのフォントが使えるようになっていると思いますが、それ ら特定のフォントセットはあなたのシステムやプリンタの設定に依存します。 gnuplot は、それは知りませんし気にもしません。gnuplot が作成した *.ps や *.eps 出力は、あなたの要求したフォント名を単に持っているだけです。
よって、
set term postscript eps font "Times-Roman,12"
一方、
set term postscript eps font "Garamond-Premier-Pro-Italic"
しかし、指定したフォントを出力ファイル中に埋め込んで、どんなプリンタで もそれを使うようにすることも可能です。これには、あなたのシステムに適切 なフォント記述ファイルがあることが必要となります。この方法でフォントを 埋め込む場合、特定のライセンスが必要となるフォントファイルもあることに 注意してください。より詳細な説明や例については、以下参照:postscript fontfile (98.48.2)。
"ページ (page)"、"表示画面 (screen)"、"キャンバス (canvas)" は、 gnuplot がアクセス可能な領域全体を指します。デスクトップではそれはウ ィンドウ全体を指し、プロッタでは、一枚の紙全体、svga モードでは、モニ タスクリーン全体を指します。
表示画面は、一つ、またはそれ以上の "グラフ描画 (plot)" を含みます。グ ラフ描画は一つの横座標と一つの縦座標で定義されますが、余白 (margin) や その中に書かれる文字列 (text) 同様、それらは実際にその上に表示されてい る必要はありません。
グラフ描画は一つの "グラフ" を含みます。グラフは一つの横座標と一つの縦 座標で定義されますが、これらは実際にその上に表示されている必要はありま せん。
グラフは一つまたはそれ以上の "曲線 (line)" を含みます。曲線は一つの関 数、またはデータ集合です。用語 "line" は描画スタイルとしても使われます。 さらにこの用語は "文字列の一行 (a line of text)" のように使われること もあります。多分文脈からそれらは区別できるでしょう。
一つのグラフ上の複数の曲線はそれぞれ名前を持ちます。その名前は、その曲 線の表現に使われる描画スタイルのサンプルとともに "凡例 (key)" 内に一覧 表示されます。凡例は、時には "表題 (legend)" とも呼ばれます。
用語 "タイトル (title)" は gnuplot では複数の意味で使われます。この ドキュメントではそれらを区別するために、形容詞として "描画の (plot)"、 "曲線の (line)"、"凡例の (key)" を頭につけたりもします。 2 次元のグラフは 4 つまでの見出し付けされる軸を持つことができます。こ れら 4 つの軸の名前はそれぞれ、グラフ描画の下の境界に沿う軸である "x"、 左の境界に沿う軸 "y"、上の境界に沿う軸 "x2"、右の境界に沿う軸 "y2" と なっています。以下参照: axes (77.1)。
3 次元のグラフは 3 つまでの見出し付けされる軸 (axes) "x","y","z" を 持つことができます。どの特定の軸に関してもそれがグラフ上でどこに書かれ るかを述べることはできません。それは、set view でグラフを見る方向を 変更できるからです。
データファイルに関する議論では、用語 "行 (record)" を復活し、ファイル の一行の文字列、すなわち、改行文字や行末文字同士の間の文字列、を指し示 すのに使います。"点 (point)" は行から取り出した一つのデータです。"デー タブロック (datablock)" は、空行で区切られた連続した複数の行からなる点 の集合です。データファイルの議論の中で "line" が参照される場合は、これ はデータブロックの部分集合を指します。"データブロック (datablock)" と いう言葉は、名前付きインラインデータブロックでも使われています。以下参照: datablocks (77.3.4)。
(訳注: この日本語訳の中ではここに書かれているような用語の統一は考慮さ れてはおらず、よって混乱を引き起こす可能性があります。厳密には原文を参 照すべきでしょう。)
set multiplot layout 2,2
fourier(k, x) = sin(3./2*k)/k * 2./3*cos(k*x)
do for [power = 0:3] {
TERMS = 10**power
set title sprintf("%g term Fourier series",TERMS)
plot 0.5 + sum [k=1:TERMS] fourier(k,x) notitle
}
unset multiplot
線種 (linetype) の属性の並びは、対話的か初期化ファイルのいずれかによっ てさらにカスタマイズ可能です。以下参照: set linetype (88.37)。配布パッケージ に初期化ファイルのサンプルがいくつか用意されています。
特定の出力形式に対する線種の属性の現在の状態は、その出力形式を設定した あとで test コマンドを実行することで確認できます。
一つの描画コマンド内での関数やデータファイルの連続する並びには、現在の デフォルトの線種列から線種が順番に割り当てられます。個々の関数、データ ファイル、またはその他の描画要素に対する線種は、その描画コマンド上で明 示的に線の属性を指定することで上書きできます。
例:
plot "foo", "bar" # 線種 1, 2 で 2 ファイルを描画
plot sin(x) linetype 4 # 線種色 4 を使用
一般に、色の指定は、色の名前か、RGB (赤、緑、青) 成分か、HSV (色相、彩 度、明度) 成分か、現在の pm3d パレットに沿った座標で行います。
例:
plot sin(x) lt rgb "violet" # gnuplot の持つ色名の一つ
plot sin(x) lt rgb "#FF00FF" # 明示的な 16 進 RGB 3 つ組
plot sin(x) lt palette cb -45 # 現在のパレットの cbrange の
# -45 に対応する色
plot sin(x) lt palette frac 0.3 # パレットに対応する小数値
以下参照: colorspec (19.1), show colornames (88.16), hsv (15.1), set palette (88.62),cbrange (88.134)。以下も参照: monochrome (88.46)。
線種 (linetype) には、点線/破線のパターンも結びつけられていますが、す べての出力形式でそれが使えるわけではありません。gnuplot バージョン 5 では、線色とは独立に点線/破線パターンを指定できます。以下参照:dashtype (19.2)。
書式:
... {linecolor | lc} {"colorname" | <colorspec> | <n>}
... {textcolor | tc} {<colorspec> | {linetype | lt} <n>}
< colorspec> は以下の形式のいずれかです:
rgbcolor "colorname" # 例: "blue"
rgbcolor "0xRRGGBB" # 16 進数値の定数文字列
rgbcolor "0xAARRGGBB" # 16 進数値の定数文字列
rgbcolor "#RRGGBB" # x11 形式の 16 進数文字列
rgbcolor "#AARRGGBB" # x11 形式の 16 進数文字列
rgbcolor <integer val> # AARRGGBB を表す整数値
rgbcolor variable # 入力ファイルから整数値を読み込む
palette frac <val> # <val> は 0 から 1 の値
palette cb <value> # <val> は cbrange の範囲の値
palette z
variable # 入力ファイルから色番号を読み込む
bgnd # 背景色
black
< n> は、その線種 (linetype) 番号が使う色を意味します。以下参照:test (93)。
"colorname" は gnuplot が内部に持っている色の名前のうちの一つを指定し ます。有効な名前の一覧に関しては、以下参照: show colornames (88.16)。
16 進定数は、引用符付きで "#RRGGBB" や "0xRRGGBB" の形で与えることがで きます。RRGGBB は、色の赤、緑、青の成分を意味し、それぞれ 00 から FF までの範囲内でなければいけません。例えば、マゼンタ (紫) は、最も明るい 赤 + 最も明るい青、なので "0xFF00FF" と表され、これは 16 進数で (255 < < 16) + (0 < < 8) + (255) を意味しています。
"#AARRGGBB" は、RGB 色の上位ビットにアルファ値 (透過性) がついているこ とを意味します。アルファ値 0 は完全に不透明色であることを意味し、よっ て "#00RRGGBB" は "#RRGGBB" と同じになります。アルファ値の 255 (FF) は 完全に透明であることを意味します。注意: この指定法のアルファ値の位置 は、以前の版の gnuplot の画像描画モード "with rgbalpha" による指定の場合の反対になっています。
カラーパレットとは、色の線型な勾配で、単一の数値を特定の色に滑らかに対 応づけます。常にそのような 2 つの対応付けが効力を持ちます。 palette frac は 0 から 1 までの小数値を、カラーパレットの全範囲に対 応付けるもので、palette cb は、色軸の範囲を同じカラーパレットへ割り 当てるものです。以下参照: set cbrange (88.134), set colorbox (88.15)。これらの対応 付けのどちらかを使って、現在のパレットから定数色を選び出すことができま す。
"palette z" は、各描画線分や描画要素の z の値を、パレットへ対応づけら れている cbrange の範囲に対応づけます。これにより、3 次元の曲線や曲面 に沿って色を滑らかに変化させることができます。これは、2 次元描画で、パ レット値を追加の列データから読み込ませて色付けするのにも使えます (すべ ての 2 次元描画スタイルがこの追加列を認識するわけではありません)。 特殊な色指定が 2 つあります。背景色の bgnd と、black です。
# 以下はキャンバスの一部分を背景色で上書きすることで消去します。
set term wxt background rgb "gray75"
set object 1 rectangle from x0,y0 to x1,y1 fillstyle solid fillcolor bgnd
# 以下は x 軸に沿った「見えない」線を描きます。
plot 0 lt bgnd
例:
# データの 3 列目を、個々の点に色を割り当てるのに使用
plot 'data' using 1:2:3 with points lc variable
# 一つのデータファイルには複数のデータ集合を入れることが可能で、
# それらは 2 行の空行で分離されています。個々のデータ集合には
# index 値が割り当てられていて (以下参照: `index`)、using 指定の
# column(-2) で取得できます。以下参照: `pseudocolumns`。以下の例
# は -2 の column 値を使って、個々のデータ集合を異なる線色で描画
# します。
plot 'data' using 1:2:(column(-2)) with lines lc variable
例:
# 3 次元描画で、各 x,y,z 座標に対応した赤、緑、青の成分を持つ色
# のついた点を配置
rgb(r,g,b) = 65536 * int(r) + 256 * int(g) + int(b)
splot "data" using 1:2:3:(rgb($1,$2,$3)) with points lc rgb variable
すべての線は、ほかに指定しなければ、dashtype solid という属性を持ち ますが、このデフォルト値をコマンド set linetype で特定の線種に変更し その後のコマンドで使えるようにできます。または、plot や他のコマンド の一部分として使用したい点線/破線の型を指定できます。
書式:
dashtype N # 定義済み点線/破線型を番号で呼び出し
dashtype "pattern" # 点 (.) 横線 (-) 下線 (_) と空白の組み合わ
# せ文字列による指定
dashtype (s1,e1,s2,e2,s3,e3,s4,e4) # 1~4 個の <実線長>,<空白長>
# の組による点線/破線パターン指定
例:
# 2 つの関数が線種 1 を使うが dashtype で区別
plot f1(x) with lines lt 1 dt solid, f2(x) with lines lt 1 dt 3
いくつかの出力形式は、それが提供する定義済み点線/破線パターンに、ユー ザ定義パターンを追加することをサポートしています。
例:
plot f(x) dt 3 # 出力形式の持つパターン 3 を使用
plot f(x) dt ".. " # 一時的なパターンを作成
plot f(x) dt (2,5,2,15) # 同じパターンを数値で表現
set dashtype 11 (2,4,4,7) # 新パターンを番号で呼び出せるよう定義
plot f(x) dt 11 # 新パターンを使って描画
点線/破線パターンを文字列で指定した場合、gnuplot はそれを < 実線長> , < 空白長> の組の列に変換します。その場合、コマンド show dashtype は、 元の文字列と変換後の数値の列の両方を表示します。
例:
# 新しいラインスタイルを、出力形式に依存しない色 cyan、線幅が 3、
# 点種 6 (丸の中に点) と定義
set style line 5 lt rgb "cyan" lw 3 pt 6
plot sin(x) with linespoints ls 5 # 定義スタイル 5 で
set object 1 rectangle from graph 0,0 to graph 1,1 fc rgb "gray" behind
behind
back
グラフ自体
グラフの表題 (`key`)
front
番号順のオブジェクト (rectangle, circle, ellipse, polygon)
番号順のラベル (label)
番号順の矢印 (arrow)
bind {allwindows} [<key-sequence>] ["<gnuplot commands>"]
bind <key-sequence> ""
reset bind
bind は、ホットキーの定義、再定義に使用します。ホットキーとは、入力 カーソルがドライバのウィンドウ内にあるときに、あるキー、または複数のキ ーを押すことで、gnuplot のコマンド列を実行させる機能のことを言います。 bind は、gnuplot が mouse をサポートするようにコンパイルされていて かつマウスが有効な出力形式上で使われてる場合にのみ有効であることに注意 してください。ユーザ指定のキー割当 (binding) は、組み込み (builtin) キ ー割当を置き換えますが、< space> と 'q' は通常は再定義はできません。そ の唯一の例外については、以下参照: bind space (21.1.1)。
マウスボタンは、ボタン 1 のみ、2 次元描画用にのみ定義可能です。
ホットキーの一覧を得るには show bind, または bind とタイプするか、 グラフウィンドウ上でホットキー 'h' を入力してください。
キー定義は、reset bind でデフォルトの状態に復帰できます。
修飾キーを含む複数のキーの定義は引用符で囲む必要があることに注意してく ださい。
標準ではホットキーは現在の描画ウィンドウ上に入力カーソルがある場合のみ 認識されます。bind allwindows < key> ... (bind all < key> ... と省略 可) は、< key> の割当を、それが現在の有効なものか否かに関わらず、すべて の gnuplot の描画ウィンドウ上で可能にします。この場合、gnuplot 変数 MOUSE_KEY_WINDOW にそれが行なわれたウィンドウの ID が保存されるのでそ れをキーに割り当てたコマンドで使用することができます。
例:
- キー割当の設定:
bind a "replot" bind "ctrl-a" "plot x*x" bind "ctrl-alt-a" 'print "great"' bind Home "set view 60,30; replot" bind all Home 'print "This is window ",MOUSE_KEY_WINDOW'
- キー割当を表示:
bind "ctrl-a" # ctrl-a に対するキー割当を表示 bind # 全てのキー定義を表示 show bind # 全てのキー定義を表示
- キー割当を削除:
bind "ctrl-alt-a" "" # ctrl-alt-a のキー割当を削除
(組み込みキー定義は削除されません)
reset bind # デフォルト (組み込み) のキー定義を導入
- トグルスイッチ形式にキー割当:
v=0 bind "ctrl-r" "v=v+1;if(v%2)set term x11 noraise; else set term x11 raise"
修飾キー (ctrl / alt) は大文字小文字の区別はありませんが、キーはそうで
はありません:
ctrl-alt-a == CtRl-alT-a ctrl-alt-a != ctrl-alt-A
修飾キー (alt == meta) の一覧:
ctrl, alt
サポートされている特殊キーの一覧:
"BackSpace", "Tab", "Linefeed", "Clear", "Return", "Pause", "Scroll_Lock", "Sys_Req", "Escape", "Delete", "Home", "Left", "Up", "Right", "Down", "PageUp", "PageDown", "End", "Begin",
"KP_Space", "KP_Tab", "KP_Enter", "KP_F1", "KP_F2", "KP_F3", "KP_F4", "KP_Home", "KP_Left", "KP_Up", "KP_Right", "KP_Down", "KP_PageUp", "KP_PageDown", "KP_End", "KP_Begin", "KP_Insert", "KP_Delete", "KP_Equal", "KP_Multiply", "KP_Add", "KP_Separator", "KP_Subtract", "KP_Decimal", "KP_Divide",
"KP_1" - "KP_9", "F1" - "F12"
以下は、実際のキーではなく、ウィンドウに関するイベントです:
"Button1" "Close"
以下も参照: mouse (88.47)。
plot 'something'
pause mouse
if (exists("MOUSE_BUTTON")) call 'something_else'; \
else print "No mouse click."
描画ウィンドウ上での一連のキー入力を追跡することも、マウスコードを使う ことで可能となります。
plot 'something'
pause mouse keypress
print "Keystroke ", MOUSE_KEY, " at ", MOUSE_X, " ", MOUSE_Y
pause mouse keypress が、キー入力で終了した場合は MOUSE_KEY には押さ れたキーの ASCII コードが保存されます。MOUSE_CHAR にはその文字自身が文 字列値として保存されます。pause コマンドが (例えば ctrl-C や描画ウィン ドウが外部から閉じられるなどして) 異常終了した場合は MOUSE_KEY は -1 になります。
マウスによる拡大の後の新しい描画範囲は、GPVAL_X_MIN, GPVAL_X_MAX, GPVAL_Y_MIN, GPVAL_Y_MAX で参照できることに注意してください。 以下参照: gnuplot-defined variables (15.4)。
gnuplot -persist -e 'plot [-5:5] sinh(x)'
gnuplot は、表示ウィンドウを開き、その中にグラフを描き、そして終了し、 表示ウィンドウはグラフをその中に持ったままスクリーンに残ります。出力形 式によっては、その残ったウィンドウ上でも多少のマウス操作が可能な場合も あります。しかし、グラフの再描画を要求するズーム (とその逆) のような操 作は、既にプログラムが終了しているので一般的には無理です。
新しい出力形式を設定するときにも persist や nopersist を指定できま す。例:
set term qt persist size 700,500
描画に関する一般的な情報の大半は、plot に関する項で見つかります。3 次元描画に固有の情報は splot の項にあります。
plot は xy 直交座標系と極座標系が使えます。以下参照: set polar (88.65)。 splot は xyz 直交座標が使えますが、3 次元極座標、円柱座標データも入 力できます。以下参照: set mapping (88.44)。 plot では、4 つの境界 x (下), x2 (上), y (左), y2 (右) をそれぞれ独 立な軸として扱うこともできます。オプション axes で、与えられた関数や データ集合をどの軸のペアで表示させるかを選べます。また、各軸の縮尺や見 出しづけを完全に制御するために十分な補佐となる set コマンド群が存在 します。いくつかのコマンドは、set xlabel のように軸の名前をその中に 持っていますし、それ以外のものは set logscale xy のように、1 つ、または複数の軸の名前をオプションとしてとります。z 軸を制御するオプション やコマンドは 2 次元グラフには効力を持ちません。
splot は、点や線に加えて曲面や等高線を書くことができます。3 次元の関 数の格子定義に関する情報については、以下参照: set isosamples (88.34)。3 次元 データのファイルに必要な形態については、以下参照: splot datafile (90.1)。等 高線に関する情報については、以下参照: set contour (88.17), set cntrlabel (88.13),set cntrparam (88.14)。
splot での縮尺や見出し付けの制御は、z 軸にも有効であること、および x2 軸、y2 軸のラベル付けが set view map を使って作られる疑似的な 2 次元描画にのみ可能であることを除けば plot と全く同じです。
four = "4"
graph4 = "Title for plot #4"
graph(n) = sprintf("Title for plot #%d",n)
plot 'data.4' title "Title for plot #4"
plot 'data.4' title graph4
plot 'data.4' title "Title for plot #".four
plot 'data.4' title graph(4)
整数は、それが文字列結合演算子によって作用された場合は、文字列に変換さ れますので、以下の例も上と同様に動作します:
N = 4
plot 'data.'.N title "Title for plot #".N
一般に、コマンドラインの各要素は、それらが標準的な gnuplot への命令文 法の一部分と認識されるもの以外は、有効な文字列変数としての評価のみが行なわれます。よって、以下のコマンド列は、恐らくは混乱を引き起こさないように避けられるべきですが、文法的には間違ってはいません:
plot = "my_datafile.dat"
title = "My Title"
plot plot title title
次の 3 つの二項演算子は文字列に作用します: 文字列の結合演算子 ".", 文 字列の等号演算子 "eq", および文字列の不等号演算子 "ne" です。以下の例では TRUE が表示されます。
if ("A"."B" eq "AB") print "TRUE"
以下も参照: 2 つの文字列書式関数 gprintf (88.27.1), sprintf (15.1)。
任意の文字列、文字列変数、文字列値関数に、範囲指定子をつけることにより 部分文字列を指定できます。範囲指定子は [begin:end] の形で、begin は部 分文字列の先頭位置、end は最後の位置です。位置指定は、最初の文字を 1 番目と見ます。先頭の位置、最後の位置は空、あるいは '*' でも構いません。 その場合、それは元の文字列自体の先頭、あるいは最後を意味します。例えば、 str[:] や str[*:*] はどちらも str の文字列全体を意味します。
コマンド置換は、単一引用符内の文字列以外は、gnuplot のコマンドライン中、どこででも使用可能です。
例:
以下の例は、leastsq というプログラムを実行し、その出力結果で、leastsq を (まわりの引用符こみで) 置き換えます:
f(x) = `leastsq`
ただし VMS では、
f(x) = `run leastsq`
以下は現在の日付とユーザー名のラベルを生成します:
set label "generated on `date +%Y-%m-%d` by `whoami`" at 1,1
set timestamp "generated on %Y-%m-%d by `whoami`"
style1 = "lines lt 4 lw 2"
style2 = "points lt 3 pt 5 ps 2"
range1 = "using 1:3"
range2 = "using 1:5"
plot "foo" @range1 with @style1, "bar" @range2 with @style2
この @ 記号を含む行は、その入力時に展開され、それが実際に実行されると きには次のように全部打ち込んだ場合と同じことになります。
plot "foo" using 1:3 with lines lt 4 lw 2, \
"bar" using 1:5 with points lt 3 pt 5 ps 2
関数 exists() はマクロの評価に関して有用でしょう。以下の例は、C が安全にユーザ定義変数の名前に展開できるかどうかをチェックします。
C = "pi"
if (exists(C)) print C," = ", @C
マクロの展開は、単一引用符内、または二重引用符内では行なわれませんが、 逆引用符 (｀) 内ではマクロ展開されます。
マクロの展開は、gnuplot が新しいコマンド行を見たときに非常に早い段階で gnuplot が処理し、そしてただ一度だけそれを行います。よって、
A = "c=1"
@A
のようなコードは正しく実行しますが、以下のような行はだめです。それは、 マクロの定義が同じ行にあるため展開に間に合わないからです。
A = "c=1"; @A # will not expand to c=1
コマンドを完成させて実行するには、コマンド evaluate も有用でしょう。
filename = "mydata.inp"
lines = ` wc --lines @filename | sed "s/ .*//" `
は、mydata.ipn の行数を整数変数 lines に保存することになります。また、 二重引用符は逆引用符の置換を妨げないので、
mycomputer = "`uname -n`"
は、システムコマンド uname -n の返す文字列を文字列変数 mycomputer に 保存することになります。
しかし、マクロ置換は二重引用符内では機能しないので、システムコマンドを マクロとして定義してそれをマクロとして利用しかつ逆引用符置換を行なうこ とはでできません。
machine_id = "uname -n"
mycomputer = "`@machine_id`" # うまくいかない !
この失敗は、二重引用符が @machine_id をマクロとして解釈することを妨げ ているからです。システムコマンドをマクロとして保存し、その後それを実行 するには、逆引用符自体もマクロ内に含める必要があります。これは以下のようにマクロを定義することで実現できます。sprintf の書式には 3 種類の引 用符全てが入れ子になっていることに注意してください。
machine_id = sprintf('"`uname -n`"')
mycomputer = @machine_id
コンマは以下の区切りで使用されます。set コマンドの arrow, key, label の座標; 当てはめ (fit) られる変数のリスト (コマンド fit のキ ーワード via に続くリスト); コマンド set cntrparam で指定されると びとびの等高線の値やそのループパラメータのリスト; set コマンドの dgrid3d dummy, isosamples, offsets, origin, samples, size, time, view の引数; 目盛りの位置やそのループパラメータのリ スト; タイトルや軸の見出しの位置; plot, replot, splot コマンドの x,y,z 座標の計算に使われる媒介変数関数のリスト; plot, replot, splot コマンドの複数の描画 (データ、または関数) のそれぞれの一連のキ ーワードのリスト。
(丸) カッコは、目盛りの見出しを (ループパラメータではなく) 明示的に集 合与える場合の区切りとして、または fit, plot, replot, splot コ マンドの using フィルタでの計算を指示するために使われます。
(カッコやコンマは通常の関数の表記でも使われます。)
かぎかっこは、set, plot, splot コマンドでは範囲を区切るのに使わ れます。
コロンは range (範囲) 指定 (set, plot, splot コマンドで使われ る) の両端の値を区切るのに、または plot, replot, splot, fit コ マンドの using フィルタの各エントリを区切るのに使われます。
セミコロン (;) は、一行のコマンド行内で与えられる複数のコマンドを区切 るのに使われます。
中カッコ ({}) は、拡張文字列処理モード (enhanced text mode) の記述や、 if/then/else 文のブロックの区切りとして使われますし、または複素数を記 述するのにも使われます: {3,2} = 3 + 2i となります。
EEPIC, Imagen, Uniplex, LaTeX, TPIC の各出力形式では、単一引用符内の \ \ または二重引用符内の \ \ \ \ で改行を示すことが可能です。
ファイル名は単一引用符、あるいは二重引用符内で囲みます。このマニュアル では一般にコマンドの例示では、わかりやすくするためにファイル名は単一引 用符でくくり、他の文字列は二重引用符でくくります。
見出し (label)、タイトル (title)、またはその他の描画要素で使用される文 字列定数や複数行文字列は単一引用符、あるいは二重引用符内で囲みます。引 用符で囲まれた文字列のさらなる処理の結果は、どの引用符記号を選ぶかによ って変わります。
\ n (改行) や \ 345 (8 進表記の文字コード) のようなバックスラッシュ ( \ ) による特殊文字表現は、2 重引用符内の文字列では効力を持ちます。単一引用 符内では、バックスラッシュ自体が通常の文字と見なされます。単一引用符 内の文字列で単一引用符自体 (ASCII コード 39 番) を使うには、それを重ね て書く必要があります。つまり、文字列 "d \ " s' b \ \ " と、'd" s'' b \ ' は完 全に同じものとなります。
1 つの複数行文字列に関する位置合わせは各行に同等に働きます。よって、中
央に位置合わせされた文字列
"This is the first line of text.\nThis is the second line."
This is the first line of text.
This is the second line.
'This is the first line of text.\nThis is the second line.'
This is the first line of text.\nThis is the second line.
拡張文字列処理 (enhanced text processing) は二重引用符に対しても単一引 用符に対しても機能します。しかし、そのモードをサポートしている出力形式 でのみ働きます。以下参照: enhanced text (13)。
逆引用符は,コマンドライン中の置換のためにシステムコマンドを囲むのに使 います。以下参照: substitution (26)。
内部では全ての時間/日付は 1970 年からの秒数に変換されます。コマンド set timefmt は全ての入力に対するデフォルトの書式を定義します。データ ファイル、範囲、軸の目盛りの見出し、ラベルの位置と、日時データ値を受け 入れるすべてのものへの入力の書式が、デフォルトでこれになります。一時に は一つのデフォルト入力書式のみが有効です。よって、ファイル内の x と y の両方が時間/日付データである場合は、デフォルトではそれは同じ書式と解 釈されます。しかし、このデフォルトは、using 指定で関数 timecolumn を用いて、それに対応する特定のファイルや列からデータを読みこむことによ り、変えることが可能です。
秒数へ (秒数から) の変換は国際標準時 (UT; グリニッジ標準時 (GMT) と同 じ) が使われます。各国標準時や夏時間への変換の機能は何も持ち合わせてい ません。もしデータがすべて同じ標準時間帯に従っているなら (そして全てが 夏時間か、そうでないかのどちらか一方にのみ従うなら) これに関して何も心 配することはありません。しかし、あなたが使用するアプリケーションで絶対 的な時刻を厳密に考察しなければいけない場合は、あなた自身が UT に変換す べきでしょう。
show xrange のようなコマンドは、その整数値を timefmt に従って解釈 し直します。timefmt を変更してもう一度 show でその値を表示させると、 それは新しい timefmt に従って表示されます。このため、(set xdata な どにより) その軸に対するデータ型をリセットすると、その値は整数値として 表示されることになります。
コマンド set format または set tics format は、指定された軸に対す る入力が時間/日付であるなしに関わらず目盛りの見出しに使われる書式を定 義します。
時間/日付情報がファイルから描画される場合、plot, splot コマンドで は using オプションを「必ず」使う必要があります。plot, splot で は各行のデータ列の分離にスペースを使いますが、時間/日付データはその中 にスペースを含み得るからです。もしタブ区切りを使用しているのなら、あな たのシステムがそれをどう扱うか確かめるために何度もテストする必要がある でしょう。
関数 time は、現在のシステム時刻を得るのに使えます。この値は、 strftime 関数で日時文字列に変換できますし、timecolumn と組み合わせ て相対的な日時グラフを作成するのにも使えます。引数の型はそれが返すもの を決定します。引数が整数の場合は time() は現在の時刻を 1970 年 1 月 1 日からの整数として返し、引数が実数 (または複素数) ならば同様の値を実数 として返しますが、小数 (秒以下) 部分の精度は、オペレーティングシステム に依存します。引数が文字列ならば、それを書式文字列であるとみなし、書式化された日時文字列を提供するようそれを strftime に渡します。
次の例は時間/日付データの描画の例です。
ファイル "data" は以下のような行からなるとします:
03/21/95 10:00 6.02e23
このファイルは以下のようにして表示されます:
set xdata time
set timefmt "%m/%d/%y"
set xrange ["03/21/95":"03/22/95"]
set format x "%m/%d"
set timefmt "%m/%d/%y %H:%M"
plot "data" using 1:3
ここで、x 軸の目盛りの見出しは "03/21" のように表示されます。
現在の gnuplot は、時刻をミリ秒精度で追跡し、時刻のフォーマットもそれ
に伴って変更されています。
例: 現在の時刻をミリ秒精度で表示
print strftime("%H:%M:%.3S %d-%b-%Y",time(0.0))
18:15:04.253 16-Apr-2011
以下参照: time_specifiers (88.27.3)。
gnuplot では、たくさんの描画スタイルが利用できます。 それらは、アルファベット順に以下に紹介されています。 コマンド set style data と set style function は、それ以降のplot や splot コマンドに対してデフォルトの描画スタイルを変更します。
描画スタイルは、コマンド plot や splot の一部分として、明示的にオ プション指定することもできます。一つの描画の中で、複数の描画スタイルを 組み合わせたい場合は、各要素に対して描画スタイルを指定する必要がありま す。
例:
plot 'data' with boxes, sin(x) with lines
各描画スタイルは、それ自体がデータファイルからのいくつかのデータの組 を期待します。例えば、デフォルトでは lines スタイルは、y の値だけの 1 列のデータ (x の値は暗黙に順番に取られる)、または最初が x, 次が y の 2 つの列を期待しています。ファイルの何列のデータを描画データと解釈させ るうまい方法に関する情報については、以下参照: using (77.3.9)。
3 列: x y ydelta
4 列: x y ydelta xdelta # 箱の幅 != -2
4 列: x y ylow yhigh # 箱の幅 == -2
5 列: x y ylow yhigh xdelta
箱の高さは、yerrorbars スタイル同様に y の誤差の値から決定されます。 y-ydelta から y+ydelta まで、あるいは ylow から yhigh まで、これらは何 列のデータが与えられているかによって決まります。
2 列: x y
3 列: x y x_width
箱の中身は現在の塗りつぶしスタイル (fillstyle) に従って塗りつぶされま す。詳細は、以下参照: set style fill (88.74.4)。新しい塗りつぶしスタイルを plot コマンド上で指定することもできます。 塗りつぶしスタイルが empty の場合は、箱は塗りつぶされません。 塗りつぶしスタイルが solid の場合は、箱は現在の描画色でベタ塗りされ ますが、fillstyle パラメータを追加することで塗りつぶし密度を制御できま す。0 は背景色、1 は描画色そのものになります。 塗りつぶしスタイルが pattern の場合は、箱は現在の描画色で、あるパタ ーンで塗りつぶします。
例:
データファイルを塗りつぶした箱で描画し、箱同士を少し垂直方向にスペース を空ける (棒グラフ):
set boxwidth 0.9 relative
set style fill solid 1.0
plot 'file.dat' with boxes
パターンでの塗りつぶしスタイルの箱で sin と cos のグラフを描画:
set style fill pattern
plot sin(x) with boxes, cos(x) with boxes
sin はパターン 0 で、cos はパターン 1 で描画されます。追加される描画は 出力ドライバがサポートするパターンを循環的に使用します。
それぞれのデータ集合で明示的に塗りつぶしスタイルを指定:
plot 'file1' with boxes fs solid 0.25, \
'file2' with boxes fs solid 0.50, \
'file3' with boxes fs solid 0.75, \
'file4' with boxes fill pattern 1, \
'file5' with boxes fill empty
例:
# x 座標は 1.0、y は 5 列目の値のところに boxplot を配置 plot 'data' using (1.0):5
# 上と同じだが、範囲外の点は隠し、boxplot の幅を 0.3 にする set style boxplot nooutliers plot 'data' using (1.0):5:(0.3)
デフォルトでは、using 指定による 2 列目の y のすべての値に対する boxplot を 1 つだけ生成します。しかし、追加の (4 つ目の) 列を指定する と、その列の値をある因子変数の離散的なレベル値であると見なし、その離散 値のレベルの値の数だけの boxplot を描画します。それらの boxplot の間隔 はデフォルトでは 1.0 ですが、これは set style boxplot separation で 変更できます。デフォルトでは、因子変数の値は、各 boxplot の下 (または 上) の目盛りのラベルに表示します。
例
# 'data' の 2 列目は "control" か "treatment" のいずれかの文字列で # 以下の例は、その因子毎の 2 つの boxplot を生成する plot 'data' using (1.0):5:(0):2
その箱のデフォルトの幅は set boxwidth < width> で設定できますが、plot コマンドの using による 3 番目のオプション列でも指定できます。1 番目 と 3 番目の列 (x 座標と幅) は通常データ列ではなく定数として与えます。
デフォルトでは、箱ひげは箱の端から、y の値が四分位範囲の 1.5 倍の中に 収まっていて最も離れているような点まで延長されます。デフォルトでは、範 囲外の点 (outlier) は円 (pointtype 7) で描かれます。箱ひげの端の棒の幅 は set bars を使って制御できます。
これらのデフォルトの性質は set style boxplot コマンドで変更できます。 以下参照: set style boxplot (88.74.2), bars (88.4), boxwidth (88.8), fillstyle (88.74.4),candlesticks (33)。
4 列: x y xdelta ydelta
6 列: x y xlow xhigh ylow yhigh
箱の幅と高さは xyerrorbars スタイル同様 x, y の誤差から決定されます つまり、xlow から xhigh までと ylow から yhigh まで、または x-xdelta から x+xdelta までと y-ydelta から y+ydelta まで。これらは何列のデータ が与えられているかによって決まります。
入力列を追加 (5,7 列目) すると、それらは各データ点毎の variable color 情報 (以下参照: linecolor (19.1), rgbcolor variable (19.1.3)) であるとして使われま す。
箱の内部は現在の塗りつぶしスタイル (fillstyle) に従って塗られます。詳 細は、以下参照: set style fill (88.74.4), boxes (30)。plot コマンド上で新しい塗り つぶしスタイルを指定することもできます。
基本的に 5 列のデータが必要です:
金融データ: date open low high close
箱ひげ描画: x box_min whisker_min whisker_high box_high
長方形の幅はコマンド set boxwidth で制御できますが、以前の gnuplotへの後方互換性として、boxwidth パラメータが設定されていない場合はset bars < width> で制御されるようになっています。
これの代わりに、箱ひげ (box-and-whisker) のグループ化に関する明示的な 幅の指定を、追加の 6 番目のデータで指定できます。その幅は、x 座標と同 じ単位で与えなければいけません。
入力列を追加 (6 列目、または 6 列目がデータの幅として使れる場合は 7 列 目) すると、それらは各データ点毎の variable color 情報 (以下参照:linecolor (19.1), rgbcolor variable (19.1.3)) として使われます。
デフォルトでは、鉛直線分のてっぺんと底には垂直に交わる水平線は引かれま せん。それを引きたい場合、例えば典型的な例は箱ひげ図 (box-and-whisker plot) での使用ですが、描画コマンドにキーワード whiskerbars を追加し てください。デフォルトでは、水平線は箱 (candlestick) の水平幅一杯に引 かれますが、それは全体の幅に対する割合を指定することで変更できます。
金融データの通常の慣習では、(開始値) < (終値) の場合は長方形は空で、 (終値) < (開始値) の場合は塗り潰されます。現在の fillstyle に "empty" をセットしている場合は、実際にこうなります。以下参照: fillstyle (88.74.4)。 fillstyle に塗り潰し、またはパターンをセットしている場合は、開始値、終 値に関係なく、すべての箱にそれが使われます。以下参照: set bars (88.4),financebars (38)。また、以下も参照してください。
と
のデモ。
注意: 中央値を表すための記号などを追加したい場合、以下の例のように、ひげ付きの棒グラフに他の描画コマンドを追加する必要があります:
# データ列: X '最小値' '1/4 位の値' '中央値' '3/4 位の値' '最大値'
set bars 4.0
set style fill empty
plot 'stat.dat' using 1:3:2:6:5 with candlesticks title 'Quartiles', \
'' using 1:4:4:4:4 with candlesticks lt -1 notitle
# ひげの上に水平線を伴う描画で、水平線の幅を全体幅の 50% にする plot 'stat.dat' using 1:3:2:6:5 with candlesticks whiskerbars 0.5
以下参照: set boxwidth (88.8), set bars (88.4), set style fill (88.74.4), boxplot (31)。
デフォルトでは完全な円を描画しますが、4 列目、5 列目に開始角、終了角を 指定することで扇形を描画することもできます。4 列目、あるいは 6 列目の データを追加して部分円の色を指定することもできます。扇形の開始角、終了 角の単位は度で指定する必要があります。以下参照: set style circle (88.74.8),set style fill (88.74.4)。
例:
# 面積が 3 列目の値に比例するような円を描画
set style fill transparent solid 0.2 noborder
plot 'data' using 1:2:(sqrt($3)) with circles, \
'data' using 1:2 with linespoints
# 円の代わりにパックマンを描画 plot 'data' using 1:2:(10):(40):(320) with circles
# インランデータで円グラフを描画 set xrange [-15:15] set style fill transparent solid 0.9 noborder plot '-' using 1:2:3:4:5:6 with circles lc var 0 0 5 0 30 1 0 0 5 30 70 2 0 0 5 70 120 3 0 0 5 120 230 4 0 0 5 230 360 5 e
これは、pointstyle 7 で点のサイズを variable とした points による描 画と似ていますが、circles は x 軸の範囲で伸縮される点が異なります。以下も参照: set object circle (88.54.3), fillstyle (88.74.4)。
2 列: x y
3 列: x y major_diam
4 列: x y major_diam minor_diam
5 列: x y major_diam minor_diam angle
2 列のデータのみが与えられた場合は、それらは中心の座標とみなされ、楕円 はデフォルトの大きさで描画されます (以下参照: set style ellipse (88.74.10))。楕 円の向きは、主軸と x 軸のなす角で定義されますが、それもデフォルトの ellipse のスタイルから取られます (以下参照: set style ellipse (88.74.10))。 3 列のデータが与えられた場合は、3 列目は主、副両軸の直径 (幅) として使 われます。向きはデフォルトで 0 になります。 4 列のデータが与えられた場合は、それらは中心の座標、主軸直径 (幅)、副 軸直径として使わわれます。これらは直径であり、半径でないことに注意して ください。 5 列のデータが与えられた場合は、5 列目の値は度単位の向きの角度の指定と して使われます。 楕円は、3,4,5 列の値は負の値として指定することで、それらのデフォルトの 値を利用して楕円を書かせることもできます。
上のすべての場合で、variable color データを最後の列 (3,4,5,6 列目) と して追加できます。詳細は以下参照: colorspec (19.1)。
デフォルトでは、主軸直径は水平軸 (x または x2) の単位、副軸直径は垂直 軸 (y または y2) の単位であるとみなされます。これは、x 軸と y 軸の縮尺 が異なる場合、主軸と副軸の比は回転後には正しくはならない、ということを 意味しています。しかしこの挙動は、キーワード units で変更できます。
これに関しては、3 種類の代用品があります: units xy が描画指定に含まれている場合、その軸は上に述べたように縮尺 されます。units xx とすると、直径は両軸とも x 軸の単位で計算され、 units yy は両軸とも y 軸の単位で計算されます。後の 2 つは、描画のサ イズを変更しても、楕円は正しいアスペクト比を持ちます。
units を省略した場合は、デフォルトの設定が使用され、units xy とな りますが、これは、set style ellipse で再定義可能です。
例 (楕円を有効な線種を周期的に使用して描画):
plot 'data' using 1:2:3:4:(0):0 with ellipses
以下も参照: set object ellipse (88.54.2), set style ellipse (88.74.10), fillstyle (88.74.4)。
出力形式によっては (post, pdf など)、ドットの大きさは linewidth を変更 することで制御できることもあります。
1 列: y # x は行番号
2 列: x y
3 列: x y z # 3D のみ (splot)
書式:
plot ... with filledcurves [option]
ここで、オプションは以下のうちのいずれかです:
[closed | {above | below}
{x1 | x2 | y | r}[=<a>] | xy=<x>,<y>]
最初のものは closed で、これは曲線それ自身を閉多角形と見なします。入 力データが 2 列の場合にはこれがデフォルトです。
2 種類目は指定された軸、あるいは水平線、垂直線、与えられた点などと、曲 線との間に作られる領域を塗りつぶします。
filledcurves closed ... 丁度閉曲線で囲まれる領域 filledcurves x1 ... x1 軸 filledcurves x2 ... x2 軸 (y1, y2 軸も同様) filledcurves y=42 ... 直線 y=42, すなわち x 軸と平行 filledcurves xy=10,20 ... x1,y1 軸での点 10,20 (扇型のような形状) filledcurves above r=1.5 極座標での動径軸の 1.5 の外側の領域
3 種類目は 3 列の入力データを必要とし、それらは x 座標と、それに対する 2 つの y 座標からなり、それらは同じ x 座標の集合に対する 2 つの曲線の y 座標に対応します。そしてその 2 つの曲線の間の領域が塗りつぶされます。 入力データが 3 列以上の場合にはこれがデフォルトです。
3 列: x y1 y2
入力された 2 つの曲線の間の領域の塗りつぶしの例:
plot 'data' using 1:2:3 with filledcurves
above と below オプションは
... filledcurves above {x1|x2|y|r}=<val>
... using 1:2:3 with filledcurves below
注意: この描画モードは全ての出力形式でサポートされるとは限りません。
3 列のデータ描画では、x= と y= のキーワードは無視します。
データファイルから描かれた曲線の塗りつぶしを拡大すると、何もなくなった り正しくない領域になることがありますが、それは gnuplot が、領域ではな く点や線をクリッピングしているからです。
< a> , < x> , < y> が描画領域の外にある場合、それらはグラフの境界へ移動され ます。よって、オプション xy=< x> ,< y> を指定した場合の実際の塗りつぶし領 域は、xrange や yrange に依存します。
5 列: date open low high close
入力列を追加 (6 列目) すると、それらは各行毎の variable color 情報 (以下参照: linecolor (19.1), rgbcolor variable (19.1.3)) として使われます。
以下も参照
autoscale が有効である場合、x の範囲は、その延長された水平線の範囲で はなく、データ点の範囲が選択されます。よって、端の点に関してはその水平 線は半分しか描かれないことになります。 以下も参照
set style histogram clustered {gap <gapsize>}
set style histogram errorbars {gap <gapsize>} {<linewidth>}
set style histogram rowstacked
set style histogram columnstacked
set style histogram {title font "name,size" tc <colorspec>}
デフォルトのスタイルは set style histogram clustered gap 2 に対応し ています。このスタイルでは、並列に指定されたデータの値の集合は、選択さ れたデータ列のそのそれぞれの序列 (行番号) に対応する x 座標の場所に、 各々箱のグループとして固められて置かれます。よって、< n> 個のデータ列を 並列に指定した場合、最初の固まりは x=1 を中心とする < n> 個の箱の固まり からなり、その各々の高さは、その < n> データ列各々の最初 (1 行目) の値 が取られます。その後に少し空白 (gap) が空けられ、次に各データ列の次 (2 行目) の値に対応する箱の固まりが x=2 を中心として置かれます。以下同様です。デフォルトの空白 (gap) 幅の 2 は、箱の固まり同士の間の空白が、箱 2 つの幅に等しいことを意味します。同じ列に対する箱は全て同じ色または同 じパターンで与えられます (以下参照: set style fill (88.74.4))。
箱の固まりそれぞれは、データファイルの 1 つの行から得られます。そのよ うな入力ファイルの各行の最初の項目が見出し (ラベル) でることは良くある ことです。その列にある見出し (ラベル) は、using に xticlabels オプ ションをつけることで、それに対応する箱の固まりの真下の x 軸に沿ったと ころに置くことができます。
errorbars スタイル は、各エントリに対して追加の入力列を必要とする以外は clustered スタイルにとても良く似ています。最初の列は、
clustered スタイルの場合と全く同様に箱の高さ (y の値) として保持され
ます。
2 列: y yerr # 線は y-yerr から y+err へ伸びる
3 列: y ymin ymax # 線は ymin から ymax へ伸びる
積み上げ型のヒストグラムも 2 つの形式がサポートされています。それらは コマンド set style histogram {rowstacked| columnstacked} で選択できま す。これらのスタイルにおいて、選択された列のデータの値は積み上げられた 箱として集められます。正の値は、y=0 から上の方へ積み上げられ、負の値は 下へ向かって積み上げられます。正の値と負の値が混じってい場合は、上向き と下向きの両方の積み上げが生成されます。デフォルトの積み上げモードは rowstacked です。
スタイル rowstacked は、まず最初に選択された列の各行の値を x 軸のそ れぞれの位置に配置します: 1 行目の値は x=1 の箱、2 行目のは x=2、以下同様となります。2 番目以降に選択された列に対応する箱は、それらの上に積み重ねられて行きます。そして結果として、x=1 にできる箱の積み重ねは、各 列の最初の値 (1 行目の値) からなり、x=2 の箱の積み重ねは各列の 2 行目 の値、などのようになります。同じ列に対する箱は全て同じ色または同じパタ ーンで与えられます (以下参照: set style fill (88.74.4))。
スタイル columnstacked も同様ですが、こちらは各箱の積み上げは (各行 のデータからではなく) 各列のデータからなります。最初に指定された列の各 行のデータが x=1 の箱の積み上げを生成し、2 番目に指定した列の各行のデ ータが x=2 の箱の積み上げ、などのようになります。このスタイルでは、各 箱の色は、各データ項目の (列番号ではなく) 行番号から決定されます。
箱の幅はコマンド set boxwidth で変更できます。 箱の塗りつぶしスタイルはコマンド set style fill で設定できます。
histograms は x 軸は常に x1 軸を使いますが、y 軸に関しては y1 軸か y2 軸かを選択できます。plot 命令が、histograms と他のスタイルの描画の両方 を含む場合、histogram でない方は、x1 軸を使うか x2 軸を使うかを選択で きます。
例:
set boxwidth 0.9 relative
set style data histograms
set style histogram cluster
set style fill solid 1.0 border lt -1
plot for [COL=2:4:2] 'file.dat' using COL
これは、x 軸上の各整数値を中心とするそれぞれ 2 つの箱 (鉛直な棒) 毎の 固まりによる描画を生成します。入力ファイルの最初の列にラベルが含まれて いるならそれを、以下の少し変更したコマンドで x 軸に沿って配置できます。
plot for [COL=2:4:2] 'file.dat' using COL:xticlabels(1)
set bars fullwidth
set style fill solid 1 border lt -1
set style histogram errorbars gap 2 lw 2
plot for [COL=2:4:2] 'file.dat' using COL:COL+1
以下は、同じデータを行毎の積み上げ型 (rowstacked) のヒストグラムで描画 する方法を示しています。これまでとは違い、以下の例では繰り返しを使うのでなく、明示的に別々の列を指定します。
set style histogram rowstacked
plot 'file.dat' using 2, '' using 4:xtic(1)
最後に以下のコマンド
set style histogram columnstacked
plot 'file.dat' using 2, '' using 4
これは、gnuplot の通常の入力の縦、横の解釈を入れ換えることになりますの で、凡例のタイトルや x 軸の目盛りの見出しの指定も変更する必要がありま す。以下のコメント部分を参照してください。
set style histogram columnstacked
plot '' u 5:key(1) # 1 列目を凡例タイトルに使用
plot '' u 5 title columnhead #
この 2 つの例は、全く同じデータ値を与えているのですが、異なる書式であ ることに注意してください。
newhistogram {"<title>" {font "name,size"} {tc <colorspec>}}
{lt <linetype>} {fs <fillstyle>} {at <x-coord>}
一回の描画に 2 つ以上のヒストグラムの組を作ることもできます。この場合 コマンド newhistogram を使うことで、それらを強制的に分離し、またそれ ぞれのラベルを分離することができます。 例:
set style histogram cluster
plot newhistogram "Set A", 'a' using 1, '' using 2, '' using 3, \
newhistogram "Set B", 'b' using 1, '' using 2, '' using 3
ラベル "Set A" と "Set B" は、それぞれのヒストグラムの組の下、x 軸の全 てのラベルの下の位置に現われます。
コマンド newhistogram は、ヒストグラムの色付けを強制的に指定した色
(linetype) で始めるのにも使えます。デフォルトでは、色の番号はヒストグ
ラムの境界をまたいでさえも連続的に増加し続けます。次の例は、複数のヒス
トグラムに同じ色付けを施します。
plot newhistogram "Set A" lt 4, 'a' using 1, '' using 2, '' using 3, \
newhistogram "Set B" lt 4, 'b' using 1, '' using 2, '' using 3
同様に、次のヒストグラムを指定した fillstyle で始めさせることが可能で す。その fillstyle を pattern にセットした場合、塗り潰しに使用される パターン番号は自動的に増加されていきます。
set style histogram cluster
set style data histogram
set style fill solid 1.0 border -1
set xtic 1 offset character 0,0.3
plot newhistogram "Set A", \
'file.dat' u 1 t 1, '' u 2 t 2, \
newhistogram "Set B" at 8, \
'file.dat' u 2 t 2, '' u 2 t 2
この場合、2 つ目のヒストグラムの位置は x=8 から始まります。
set style histogram columnstacked
plot for [i=3:8] "datafile" using i title columnhead
plot '-' matrix with image
5 4 3 1 0
2 2 0 0 1
0 0 0 1 0
0 1 2 4 3
e
e
スタイル image は、グレイスケール (灰色階調)、またはカラーパレット値 を含んでいるピクセルの入力を処理します。よって 2 次元描画 (plot コマ ンド) では 3 列のデータ (x,y,value) を、3 次元描画 (splot コマンド) では 4 列のデータ (x,y,z,value) が必要になります。
スタイル rgbimage は、赤、緑、青の 3 つの色成分 (RGB) で記述されたピ クセルの入力を処理します。よって plot では 5 次元データ (x,y,r,g,b) が、splot では 6 次元データ (x,y,z,r,g,b) が必要になります。赤、緑、 青の各成分は [0:255] の範囲内にあると仮定されます。
スタイル rgbalpha は、赤、緑、青の RGB 成分に加えて、アルファ値 (透 過パラメータ) の情報も含んだピクセルの入力を処理します。よって、plot では 6 次元データ (x,y,r,g,b,a) が、splot では 7 次元データ (x,y,z,r,g,b,a) が必要になります。赤、緑、青、およびアルファの各成分は [0:255] の範囲内にあると仮定されます。
plot 'data' with image pixels
1 列: y
2 列: x y # [x,0] から [x,y] への線 (2D)
3 列: x y z # [x,y,0] から [x,y,z] への線 (3D)
3 列: x y string # 2 次元版
4 列: x y z string # 3 次元版
フォント、色、回転角やその他の描画テキストの属性は追加オプションとして 指定可能です (以下参照: set label (88.36))。次の例は、入力ファイルの 1 列目 から取った市の名前から作られる文字列を、4, 5 列目から取った地図座標に 描画します。フォントサイズは、3 列目の値から計算していて、この場合はそ れは人口を意味しています。
CityName(String,Size) = sprintf("{/=%d %s}", Scale(Size), String)
plot 'cities.dat' using 5:4:(CityName(stringcolumn(1),$3)) with labels
フォントサイズを、個々の市の名前に対して異なるサイズに合わせなくていい ならば、コマンドはもっと簡単です:
plot 'cities.dat' using 5:4:1 with labels font "Times,8"
labels に hypertext がついている場合、その文字列はマウスがそれに対応 する点の上に来たときにだけ現われます。以下参照: hypertext (88.36.2)。この場合 ハイパーテキストの置き場所として機能する点を作るためにそのラベルの point 属性を有効にする必要があります:
plot 'cities.dat' using 5:4:1 with labels hypertext point pt 7
set encoding utf8 symbol(z) = "<UTF-8 文字列>"[int(z):int(z)] splot 'file' using 1:2:(symbol($3)) with labels
以下も参照: datastrings (12), set style data (88.74.3)。
2 次元の場合
1 列: y # 行番号による暗黙の x
2 列: x y
1 列: z # x は暗黙の行番号、y は index から
3 列: x y z
以下も参照: linetype (88.37), linewidth (88.74.7), linestyle (88.74.7)。
線種 (linetype) の属性である pointinterval (省略形 pi) で、グラフ のすべての点を与えた記号にするかどうかを制御できます。例えば、 with lp pi 3 は、すべてのデータ点間に線分を引きますが、点の記号は 3 つおきにしか書きません。pointinterval を負の値にした場合は、記号の下 の線分の部分を消します。消す部分のサイズは set pointintervalbox で制 御できます。
平行軸の最大個数は、gnuplot のコンパイル時に固定され、その最大値は、 show version long で表示されます。
最初の 8 つの点種は、すべての出力形式で共通ですが、より多くの点種を個 別にサポートする出力形式もあります。現在の出力形式がどのような点種を持 っているかを見るには、コマンド test を使用してください。また、以下の例のようにして、任意の印字可能文字を点種の代わりに使用することもできます。より長い文字列は、描画スタイル points ではなく labels を使えば 出力できます。
4 列: x y xdelta ydelta
6 列: x y z xdelta ydelta zdelta
両方の場合で、入力列を追加 (2D では 5 列目、3D では 7 列目) すると、そ れらは各データ点毎の variable color 情報 (以下参照: linecolor (19.1),rgbcolor variable (19.1.3)) として使われます。
vectors スタイルを使っての splot は set mapping cartesian のみでサポ ートされています。
キーワード "with vectors" は、その後ろに、インラインの arrow スタイル 指定や、あらかじめ定義されている arrow スタイルの参照、あるいは列から 各ベクトルに対する必要な arrow スタイルのインデックスを読むような指定 を伴うことができます。注意: "arrowstyle variable" を使用する場合、対応 するベクトルが描画される際にはそれが arrow の属性値すべてを埋めるので その plot コマンド内に他の線属性や arrow スタイル指定をこのキーワード と混在させることはできません。
plot ... with vectors filled heads
plot ... with vectors arrowstyle 3
plot ... using 1:2:3:4:5 with vectors arrowstyle variable
例:
plot 'file.dat' using 1:2:3:4 with vectors head filled lt 2
splot 'file.dat' using 1:2:3:(1):(1):(1) with vectors filled head lw 2
set clip one と set clip two は 2 次元のベクトルの描画に影響を与え ます。以下参照: set clip (88.12), arrowstyle (88.74.1)。
3 列: x y xdelta
4 列: x y xlow xhigh
入力列を追加 (4,5 列目) すると、それらは点の variable color 情報として 使われます。
4 列: x y xdelta ydelta
6 列: x y xlow xhigh ylow yhigh
データが、サポートされていない混合型の形式で与えられた場合、plot コ マンドの using フィルタを使って適切な形に直さないといけません。例え ばデータが (x,y,xdelta,ylow,yhigh) という形式である場合、以下のようにします:
plot 'data' using 1:2:($1-$3):($1+$3):4:5 with xyerrorbars
入力列を追加 (5,7 列目) すると、それらは各データ点毎の variable color 情報として使われます。
2 列: [暗黙の x] y ydelta
3 列: x y ydelta
4 列: x y ylow yhigh
入力列を追加 (4,5 列目) すると、それらは点の variable color 情報として 使われます。
以下も参照
3 列: x y xdelta
4 列: x y xlow xhigh
入力列を追加 (4,5 列目) すると、それらは点の variable color 情報として 使われます。
4 列: x y xdelta ydelta
6 列: x y xlow xhigh ylow yhigh
データが、サポートされていない混合型の形式で与えられた場合、plot コ マンドの using フィルタを使って適切な形に直さないといけません。例え ばデータが (x,y,xdelta,ylow,yhigh) という形式である場合、以下のようにします:
plot 'data' using 1:2:($1-$3):($1+$3):4:5 with xyerrorlines
入力列を追加 (5,7 列目) すると、それらは各データ点毎の variable color 情報として使われます。
3 列: x y ydelta
4 列: x y ylow yhigh
入力列を追加 (4,5 列目) すると、それらは点の variable color 情報として 使われます。
以下も参照。
ほとんどの場合、コマンド名とそのオプションは、紛らわしくない範囲で省略 することが可能です。すなわち、"plot f(x) with lines" の代わりに "p f(x) w li" とすることができます。
書式の記述において、中カッコ ({}) は追加指定できる引数を意味し、 縦棒 (| ) は互いに排他的な引数を区切るものとします。
書式:
cd '<ディレクトリ名>'
ディレクトリ名は引用符に囲まれていなければなりません。
例:
cd 'subdir'
cd '..'
バックスラッシュ (
\
) は二重引用符内 (") では特別な意味を持ってしまうた
めにエスケープする必要がありますので、Windows ユーザには単一引用符を使
うことを勧めます。例えば、
cd "c:\newdata"
cd 'c:\newdata'
cd "c:\\newdata"
call "inputfile" <param-1> <param-2> <param-3> ... <param-9>
gnuplot の以前のバージョンでは、そのパラメータ文字列の内容を、特別な記号 $0, $1, ..., $9 をマクロのように置換することで表現していました。こ の仕組みは、現在は非推奨です (以下参照: call old-style (63.2))。
現在の gnuplot は、文字列変数 ARG0, ARG1, ..., ARG9 と、整数変数 ARGC を提供します。call コマンドを実行すると、ARG0 には入力ファイル名が、 ARGC にはパラメータ数が設定され、ARG1 から ARG9 にはコマンドラインに並 べられたパラメータの値が読み込まれます。
通常パラメータは文字列値として保存されるので、それをマクロ展開して参照 することもできます (古い形式の書式の類似)。しかし、多くの場合、それらは 他の変数と同様に利用する方がより自然でしょう。
以下を call すると:
MYFILE = "script1.gp"
FUNC = "sin(x)"
call MYFILE FUNC 1.23 "This is a plot title"
呼び出されたスクリプト内では以下のようになり:
ARG0 は "script1.gp"
ARG1 は文字列値 "sin(x)"
ARG2 は文字列値 "1.23"
ARG3 は文字列値 "This is a plot title"
ARGC は 3
そのスクリプト内では以下のようなものを実行できる:
plot @ARG1 with lines title ARG3
print ARG2 * 4.56, @ARG2 * 4.56
print "This plot produced by script ", ARG0
この例の ARG1 はマクロとして参照しなければいけませんが、ARG2 はマクロ 参照でも (数値定数になる)、変数のままでも (文字列 "1.23" が実数値に自 動的に変換された後の同じ数値になる) 構わないことに注意してください。
シェルスクリプトで gnuplot をコマンドラインオプション -c つきで実行 することで、これと同じことを直接行うこともできます:
gnuplot -persist -c "script1.gp" "sin(x)" 1.23 "This is a plot title"
call "<input-file>" <param-0> <param-1> ... <param-9>
入力ファイル名は引用符で囲まなければなりません。入力ファイルの各行を読 み込む際に、以下の特別な文字列を走査します: $0 $1 $2 $3 $4 $5 $6 $7 $8 $9 $#。それが見つかったら、「$+数字」の列は call コマンドラインの 対応するパラメータに置き換えます。引用符はコピーせず、文字列変数置換は 行いません。文字列 $# はパラメータ数に置き換えます。その他の文字が後 ろについている $ は、エスケープシーケンスとして処理します。例えば 1 個 の $ を使うには $$ とします。
例:
ファイル 'calltest.gp' は以下の行を含んでいるとすると:
print "argc=$# p0=$0 p1=$1 p2=$2 p3=$3 p4=$4 p5=$5 p6=$6 p7=x$7x"
次の行を入力すると:
call 'calltest.gp' "abcd" 1.2 + "'quoted'" -- "$2"
以下のように表示されるでしょう:
argc=7 p0=abcd p1=1.2 p2=+ p3='quoted' p4=- p5=- p6=$2 p7=xx
注意: 文字 $ は、gnuplot 自身のデータ列用の書式とぶつかりますし、 Unix 系のシェルの環境変数を参照する $ ともぶつかります。特別な文字列 $# は、gnuplot のバージョン 4.5 から 4.6.3 までは、間違えてコメント 文字列の区切り文字として解釈されていました。文字列置換では引用符は無視 されるので、文字列定数は簡単に壊れてしまいます。
いくつかの出力装置は clear コマンドでは set size で定義された描画 領域のみを消去します。そのため、set multiplot とともに使用することで 挿入図を一つ作ることができます。
例:
set multiplot
plot sin(x)
set origin 0.5,0.5
set size 0.4,0.4
clear
plot cos(x)
unset multiplot
これらのコマンドの詳細については、以下参照: set multiplot (88.48),set size (88.73), set origin (88.56)。
do for <iteration-spec> {
<commands>
<commands>
}
set multiplot layout 2,2
do for [name in "A B C D"] {
filename = name . ".dat"
set title sprintf("Condition %s",name)
plot filename title name
}
unset multiplot
書式:
eval <string expression>
これは、特に同様のコマンドの繰り返しに有用です。
例:
set_label(x, y, text) \
= sprintf("set label '%s' at %f, %f point pt 5", text, x, y)
eval set_label(1., 1., 'one/one')
eval set_label(2., 1., 'two/one')
eval set_label(1., 2., 'one/two')
文字列からコマンドを実行する別の方法に関しては、以下参照:substitution macros (26.2)。
コマンド exit gnuplot は、直ちに、無条件に、そして例え入力ストリーム が多段階にネストされていても、gnuplot を終了させます。その場合、開かれ ていた全ての出力ファイルはきれいに完全な形では閉じられない可能性があり ます。使用例:
bind "ctrl-x" "unset output; exit gnuplot"
コマンド exit error "error message" は、疑似プログラムエラーを行いま す。対話型モードでは、そのエラーメッセージを表示し、すべのネストされた ループや call を中断してコマンドラインに帰ります。非対話型モードでは、 プログラムを終了します。
詳細は、以下参照: batch/interactive (7)。
fit の最も基本的な使用法は、以下の単純な例が示しています:
f(x) = a + b*x + c*x**2
fit f(x) 'measured.dat' using 1:2 via a,b,c
plot 'measured.dat' u 1:2, f(x)
書式:
fit {<ranges>} <expression>
'<datafile>' {datafile-modifiers}
{{unitweights} | {y|xy|z}error | errors <var1>{,<var2>,...}}
via '<parameter file>' | <var1>{,<var2>,...}
範囲 (xrange, yrange 等) は、当てはめに使用するデータを制限する目的で
使うことができ、その範囲を超えたデータは無視します。その書式は plot
コマンド同様
[{dummy_variable=}{<min>}{:<max>}],
< expression> は、通常はあらかじめユーザ定義された f(x) または f(x,y) の形の関数ですが、gnuplot で有効などんな数式でも指定できます。ただし 実数値関数でなければいけません。 独立変数の名前は、コマンド set dummy で設定するか、fit の範囲指定部 分 (< rangse> ) で設定します (以下を参照)。デフォルトでは、最初の 2 つは x, y となります。 さらに、その数式は、当てはめの作業により決定する値を持つ 1 つ以上の変数 (パラメータ) に依存すべきです。
< datafile> は plot コマンドと同様に扱われます。plot datafile の修 飾子 (using, every,...) は、smooth を除いて、全て fit に使うこ とができます。以下参照:plot datafile (77.3)。
データファイルの内容は、plot コマンドに使用するのと同じ using 指定を 使うことで柔軟に解釈させることができます。例えば、独立変数 x を2 列目 と 3 列目の和として生成し、z の値を 6 列目から取り、重みを 1 としたい 場合は以下のようにします:
fit ... using ($2+$3):6
using 指定がない場合、fit は暗黙に独立変数は 1 つだけと仮定します。 ファイル自身、または using 指定が 1 列だけのデータを持つ場合、その行番 号を独立変数値として使用します。 using 指定を与えた場合、最大 12 個 (指定してコンパイルしていればさら にそれ以上) の独立変数を利用できます。
オプション unitweights (これがデフォルト) は、すべてのデータ点が等し い重みを持つとみなします。これは、キーワード error を使用することで 変更でき、これはデータファイルから 1 つ以上の変数の誤差評価を読み込み、その誤差評価を対応する変数値の標準偏差 s とみなし、各データに 1/s**2の重みを計算するのに使用します。
独立変数の誤差評価において、その重みには、"有効分散法" (effective variance method; Jay Orear, Am. J. Phys., Vol. 50, 1982) に従って、さ らに当てはめ関数の微分係数をかけます。
キーワード errors には、その後ろに、入力がどの変数の誤差であるのかを 示すコンマ区切りの 1 つ以上の変数名のリストが付きます。従属変数 z は常にその中になければいけませんが、独立変数は必須ではありません。 そのリストの各変数に対し、ファイルからその分の、各変数の誤差評価を持つ 追加の列を読み込みます。繰り返しになりますが、using 指定により柔軟な 解釈が可能になります。 よって、独立変数の数は暗黙に、using 指定内の列の数から 1 を引いて (従属変数分)、さらに errors 指定内の変数の個数を引いた数になることに 注意してください。
例として、2 つの独立変数があり、そして 1 つ目の独立変数と従属変数の誤差データがある場合は、errors x,z 指定と 5 列の using 指定を使うことになりますが、それは x:y:z:sx:sz のように解釈されます (x, y は独立変数、z が従属変数、sx, sz は x, z の標準偏差)。
errors 指定のちょっとした略記法も 2,3 用意されています: yerrors (独立変数が 1 列ある当てはめ用)、 zerrors (より一般の場合) は、いずれも errors z と同値で、1 列だけ 追加の従属変数用の誤差列があることを意味しています。
xyerrors は、独立変数は 1 列で、その独立変数と従属変数の両方の 2 列の誤差列が追加されることを意味します。この場合、x と y の誤差は Orear の有効分散法 (effective variance method) で処理されます。
yerror と xyerror の形式および解釈は、それぞれ 2 次元描画スタイル の yerrorlines と xyerrorlines に同等であることに注意してください。
コマンド set fit v4 を使用すると、fit のコマンド書式は gnuplot バ ージョン 4 以前と互換の書式になります。その場合、using には、独立変 数が 2 つ以上ならば、独立変数の数より 2 つ (z と s) 多い指定が必要で、 gnuplot は、using 指定で与えられた列の数に応じて、以下の書式に従います:
z # 独立変数は 1 つ (行番号)
x:z # 独立変数は 1 つ (第 1 列)
x:z:s # 独立変数は 1 つ (全部で 3 列)
x:y:z:s # 独立変数は 2 つ (全部で 4 列)
x1:x2:x3:z:s # 独立変数は 3 つ (全部で 5 列)
x1:x2:x3:...:xN:z:s # 独立変数は N 個 (全部で N+2 列)
これは、2 つ以上の独立変数で fit をする場合、z-誤差 s を与える必要があることを意味することに注意してください。重みを 1 にしたい場合は、それ を、例えば x:y:z:(1) のような書式を using に指定することで明示的に与え る必要があります。
仮変数名は、下で紹介するように範囲指定で指定することで変更できます。最 初の範囲は using 指定の最初のものに対応し、以下同様です。従属変数である z の範囲指定もできますが、それは、f(x,...) の値をその範囲外にして しまうようなデータ点が、残差を最小化することには寄与しない場合に有効で す。
複数のデータ集合も複数の 1 変数関数に同時に当てはめることも、y を '仮 変数' とすれば可能です。例えばデータ行番号を使い、2 変数関数への当ては め、とすればいいでしょう。以下参照: fit multi-branch (68.5)。
via 指定子は、パラメータの最適化を、直接行うか、またはパラメータファ イルを参照することによって行うかを指定します。
例:
f(x) = a*x**2 + b*x + c
g(x,y) = a*x**2 + b*y**2 + c*x*y
set fit limit 1e-6
fit f(x) 'measured.dat' via 'start.par'
fit f(x) 'measured.dat' using 3:($7-5) via 'start.par'
fit f(x) './data/trash.dat' using 1:2:3 yerror via a, b, c
fit g(x,y) 'surface.dat' using 1:2:3 via a, b, c
fit a0 + a1*x/(1 + a2*x/(1 + a3*x)) 'measured.dat' via a0,a1,a2,a3
fit a*x + b*y 'surface.dat' using 1:2:3 via a,b
fit [*:*][yaks=*:*] a*x+b*yaks 'surface.dat' u 1:2:3 via a,b
fit [][][t=*:*] a*x + b*y + c*t 'foo.dat' using 1:2:3:4 via a,b,c
set dummy x1, x2, x3, x4, x5
h(x1,x2,x3,x4,s5) = a*x1 + b*x2 + c*x3 + d*x4 + e*x5
fit h(x1,x2,x3,x4,x5) 'foo.dat' using 1:2:3:4:5:6 via a,b,c,d,e
反復の個々のステップの後で、当てはめの現在の状態についての詳細な情報が 画面に表示されます。そし最初と最後の状態に関する同じ情報が "fit.log" というログファイルにも書き出されます。このファイルは前の当てはめの履歴 を消さないように常に追加されていきます。これは望むなら削除、あるいは別 な名前にできます。コマンド set fit logfile を使ってログファイルの名 前を変更することもできます。
set fit errorvariables を使用した場合、各当てはめパラメータの誤差は そのパラメータと似た名前 ("_err" が追加された名前) の変数に保存されま すので、その誤差をその後の計算の入力として使用することができます。
set fit prescale とした場合、当てはめパラメータを、それらの初期値か らスケール変換します。これにより、個々のパラメータの大きさにかなり違い があるような場合でも、Marquardt-Levenberg ルーチンがより早く、より信頼 性のある値に収束させられるようになります。
当てはめの反復は Ctrl-C (wgnuplot では Ctrl-Break) を押すことで中断で きます。現在の反復が正常に終了した後、以下のいずれかを選ぶことができます:(1) 当てはめを止めて現在のパラメータの値を採用する (2) 当てはめを続行する (3) set fit script か、環境変数 FIT_SCRIPT で指定した gnuplot コ マンドを実行する。そのデフォルトは replot で、もしデータと当てはめ関 数を一つのグラフにあらかじめ描画してあれば、現在の当てはめの状態を表示 することができます。
fit が終了した後は、最後のパラメータの値を保存するのに update コマ ンドを使います。その値は再びパラメータの値として使うことができます。 詳細は、以下参照: update (96)。
調整するパラメータは、via キーワードの後ろにコンマで区切られた変数名 のリストを書くことで指定できます。定義されていない変数は初期値 1.0 と して作られます。しかし当てはめは、変数の初期値があらかじめ適切な値に設 定されている方が多分速く収束するでしょう。
パラメータファイルは個々のパラメータを、個別に 1 行に一つずつ、初期値を
次のような形で指定して書きます。
変数名 = 初期値
'#' で始まるコメント行や空行も許されます。特別な形式として
変数名 = 初期値 # FIXED
は、この変数が固定されたパラメータであることを意味し、それはこのファイ ルで初期化されますが、調節はされません。これは、fit でレポートされる 変数の中で、どれが固定された変数であるかを明示するのに有用でしょう。な お、# FIXED と言うキーワードは厳密にこの形でなくてはなりません。
これが、(非線形) 最小自乗当てはめ法と呼ばれるゆえんです。非線形 が 何を意味しているのかを見るための例を紹介しますが、その前にいくつかの 仮定について述べておきます。ここでは簡単のため、1 変数のユーザー定義 関数は z=f(x), 2 変数の関数は z=f(x,y) のようにし、いずれも従属変数として z を用いることにします。パラメータとは fit が調整して適切な値を 決定するユーザ定義変数で、関数の定義式中の未知数です。ここで言う、線形 性/非線形性とは、従属変数 z と fit が調整するパラメータとの関係に対するものであり、z と独立変数 x (または x と y) との関係のことではあり ません (数学的に述べると、線形最小自乗問題では、当てはめ関数のパラメー タによる 2 階 (そして更に高階の) 導関数は 0、ということになります)。
線形最小自乗法 (LLS) では、ユーザ定義関数は単純な関数の和であり、それ
ぞれは一つのパラメータの定数倍で他のパラメータを含まない項になります。
非線形最小自乗法 (NLLS) ではより複雑な関数を扱い、パラメータは色んな
使われ方をされます。フーリエ級数は線形と非線形の最小自乗法の違いを表す
一つの例です。フーリエ級数では一つの項は
z=a*sin(c*x) + b*cos(c*x).
線形の場合、パラメータの値は比較的簡単な線形代数の直接法によって決定で きます。しかしそのような LLS は特殊な場合であり、'gnuplot' が使用する 反復法は、もちろんそれも含めて、より一般的な NLLS 問題を解くことができ ます。fit は検索を行うことで最小値を探そうとします。反復の各ステップ は、パラメータの新しい値の組に対して WSSR を計算します。Marquardt- Levenberg のアルゴリズムは次のステップのパラメータの値を選択します。そ してそれはあらかじめ与えた基準、すなわち、(1) 当てはめが "収束した" (WSSR の相対誤差がある限界値より小さくなった場合。以下参照:set fit limit (88.25))、または (2) あらかじめ設定された反復数の限界に達した 場合 (以下参照: set fit maxiter (88.25))、のいずれかを満たすまで続けられます。 キーボードからその当てはめの反復は中断できますし、それに続いて中止する こともできます (以下参照: fit (68))。ユーザ変数 FIT_CONVERGED は、 直前の fit コマンドが収束により終了した場合は 1 を持ち、それ以外の理由で中断した場合は 0 を持ちます。FIT_NITER は、直前の当てはめで行われた繰り返 しの回数を持ちます。
当てはめに使われる関数はしばしばあるモデル (またはある理論) を元にして いて、それはデータの振舞を記述したり、あるいは予測しようとします。よっ て fit は、データがそのモデルにどれくらいうまく当てはまっているのかを 決定するため、そして個々のパラメータの誤差の範囲を評価するために、モデ ルの自由なパラメータの値を求めるのに使われます。以下参照:fit error_estimates (68.3)。
そうでなければ、曲線による当てはめにおける関数は、モデルとは無関係に選 ばれています (それは十分な表現力と最も少ない数のパラメータを持ち、デー タの傾向を記述しそうな関数として経験に基づいて選ばれるでしょう)。
しかし、もしあなたが全てのデータ点を通るような滑らかな曲線を欲しいなら fit ではなく、むしろ plot の smooth オプションでそれを行うべきで しょう。
データ誤差は、平方残差の重み付きの和 WSSR、すなわちχ自乗を決定する際 個々のデータ点の相対的な重みを計算するのに用いられます。それらはパラメ ータの評価に影響を与えます。それは、それらが、当てはめられた関数からの 個々のデータ点の偏差が最終的な値に与える影響の大きさを決定することによ ります。正確なデータ誤差評価が与えられている場合には、パラメータの誤差 評価等の fit が出力する情報はより役に立つでしょう。
statistical overview では fit の出力のいくつかを説明し、 'practical guidelines' に対する背景を述べています。
分散 = 総計である数え上げ統計学同様、母集団の標準偏差が定数でない場合、 各点は観測される偏差の和と期待される偏差の和を比較するときに個別に重み づけされるべきです。
最終段階で fit は 'stdfit'、すなわち残差の RMS (自乗平均平方根) で求
められる当てはめの標準偏差と、データ点が重みづけられている場合に '減ら
されたχ自乗' とも呼ばれる残差の分散をレポートします。自由度 (データ点
の数から当てはめパラメータの数を引いたもの) はこれらの評価で使用されま
す。なぜなら、データ点の残差の計算で使われるパラメータは同じデータから
得られるものだからです。データ点が重みを持つ場合、gnuplot はいわゆる
p-値を計算します。それはその自由度と結果のχ自乗値に対するχ自乗分布の
累積分布関数値を 1 から引いた値です。以下参照: practical_guidelines (68.3.2)。
これらの値は以下の変数に代入されます:
FIT_NDF = 自由度の数
FIT_WSSR = 重みつき残差の自乗和
FIT_STDFIT = sqrt(WSSR/NDF)
FIT_P = p-値
パラメータに関する信頼レベルを評価することで、当てはめから得られる最小 のχ自乗と、要求する信頼レベルのχ自乗の値を決定するためのχ自乗の統計 を用いることが出来ます。しかし、そのような値を生成するパラメータの組を 決定するには、相当のさらなる計算が必要となるでしょう。
fit は信頼区間の決定よりむしろ、最後の反復後の分散-共分散行列から直 ちに得られるパラメータの誤差評価を報告します。これらの評価は、標準偏差 として計算される量の指定に関する統計上の条件が、一般には非線形最小自乗 問題では保証されないのですが、線形最小自乗問題での標準誤差 (各パラメー タの標準偏差) と同じ方法で計算されます。そしてそのため慣例により、これ らは "標準誤差" とか "漸近標準誤差" と呼ばれています。漸近標準誤差は一 般に楽観過ぎ、信頼レベルの決定には使うべきではありませんが、定性的な指 標としては役に立つでしょう。
最終的な解は、解の範囲におけるパラメータの相関を示す相関行列も生成しま す: その主対角要素、すなわち自己相関は常に 1 で、全てのパラメータが独 立ならば非対角要素はすべて 0 に近い値になります。完全に他を補いあう 2 つの変数は、大きさが 1 で、関係が正の相関か負の相関かによって正か負に なる符号を持つ非対角要素を持ちます。非対角要素の大きさが小さいほど、各 パラメータの標準偏差の評価は、漸近標準誤差に近くなります。
データの重み付けは、最後の反復後の fit の追加出力に対する解釈の基礎 を与えます。各点に同等に重み付けを行なうにしても、重み 1 を使うことよ りもむしろ平均標準偏差を評価することが、χ自乗が定義によりそうであるよ うに、WSSR を 無次元変数とすることになります。
当てはめ反復の各段階で、当てはめの進行の評価に使うことが出来る情報が表 示されます ('*' はより小さい WSSR を見つけられなかったこと、そして再試 行していることを意味します)。'sum of squares of residuals' (残差の自乗 和) は、'chisquare' (χ自乗) とも呼ばれますが、これはデータと当てはめ 関数との間の WSSR を意味していて、fit はこれを最小化しようとします。 この段階で、重み付けされたデータによって、χ自乗の値は自由度 (= データ 点の数 - パラメータの数) に近付くことが期待されます。WSSR は補正された χ自乗値 (WSSR/ndf; ndf = 自由度)、または当てはめ標準偏差 (stdfit = sqrt(WSSR/ndf)) を計算するのに使われます。それらは最終的な WSSR に対し てレポートされます。
データが重み付けされていなければ、stdfit は、ユーザの単位での、データ と当てはめ関数の偏差の RMS (自乗平均平方根) になります。
もし妥当なデータ誤差を与え、データ点が十分多く、モデルが正しければ、 補正χ自乗値はほぼ 1 になります (詳細は、適当な統計学の本の 'χ自乗分 布' の項を参照してください)。この場合、この概要に書かれていること以外に、モデルがデータにどれくらい良く当てまっているかを決定するための追加の試験方法がいくつかあります。
補正χ自乗が 1 よりはるかに大きくなったら、それは不正なデータ誤差評価、 正規分布しないデータ誤差、システム上の測定誤差、孤立した標本値 (outliers)、または良くないモデル関数などのためでしょう。例えば plot 'datafile' using 1:($2-f($1)) などとして残差を描画することは、 それらのシステム的な傾向を知るための手がかりとなります。データ点と関数 の両者を描画することは、他のモデルを考えための手がかりとなるでしょう。
同様に、1.0 より小さい補正χ自乗は、WSSR が、正規分布する誤差を持つラ ンダムなサンプルと関数に対して期待されるものよりも小さいことを意味しま す。データ誤差評価が大きすぎるのか、統計的な仮定が正しくないのか、また はモデル関数が一般的すぎて、内在的傾向に加えて特殊なサンプルによる変動 の当てはめになっているのでしょう。最後の場合は、よりシンプルな関数にす ればうまく行くでしょう。
当てはめの p-値は、自由度と結果のχ自乗値に対するχ自乗分布の累積分布 関数値を 1 から引いた値です。これは、当てはめの良さのものさしを提供し ます。p-値の範囲は 0 から 1 までで、p-値がとても小さい、あるいはとても 大きい場合は、モデルがデータとその誤差をちゃんと記述していないことを意 味します。上で述べたように、これはデータに問題があるか、誤差かモデルに 問題がある、またはそれらの組み合わせなのだろうと思います。p-値が小さい ことは、誤差が過小評価されているので、よって最終的なパラメータ誤差をス ケール変換すべきだろうということを意味するでしょう。以下も参照:set fit errorscaling (88.25)。
標準的なエラーを、パラメータの不確定性に関する、あるより現実的な評価に 関係付けること、および相関行列の重要性を評価することができるようになる 前に、あなたは fit と、それを適用しようとするある種の問題に慣れてお く必要があるでしょう。
fit は、大抵の非線形最小自乗法の実装では共通して、距離の自乗 (y-f(x))**2 の重み付きの和を最小化しようとすることに注意してください。 それは、x の値の "誤差" を計算に関してはどんな方法も与えてはおらず、単 に y に関する評価のみです。また、"孤立点" (正規分布のモデルのから外れ ているデータ点) は常に解を悪化させる可能性があります。
gnuplot の起動前に fit に影響を与えるように定義できる多くの環境変 数があります。以下参照: fit control environment (68.4.2)。
デフォルトのもっとも小さい数字の限界 (1e-5) は、変数
FIT_LIMIT
反復数の最大値は変数
FIT_MAXITER
更にそのアルゴリズムを制御したい場合で、かつ Marquardt-Levenberg アル
ゴリズムを良く知っている場合は、さらにそれに影響を与える変数があります。
lambda (λ) の最初の値は、通常 ML 行列から自動的に計算されますが、も
しそれをあらかじめ用意した値にセットしたければ
FIT_START_LAMBDA
FIT_LAMBDA_FACTOR
fit には FIT_ から始まる変数が他にもありますから、ユーザ定義変数とし てはそのような名前で始まる変数は使わないようにするのが安全でしょう。
変数 FIT_SKIP と FIT_INDEX は、以前の版の gnuplot の、gnufit と呼ばれていた fit パッチで使われていたもので、現在は使用されていません。 FIT_SKIP の機能はデータファイルに対する every 指定子で用意されていま す。FIT_INDEX は複数当てはめ法 (multi-branch fitting) で使われていたも のですが、1 変数の複数当てはめ法は、今では 疑似 3 次元当てはめとして行 なわれていて、そこでは枝の指定には 2 変数と using が使われています。 以下参照: fit multi-branch (68.5)。
FIT_LOG
FIT_SCRIPT
例: 2 つの指数減衰形 z=f(x) が与えられていて、それぞれ異なるデータ集合
を記述しているが、共通した減衰時間を持ち、そのパラメータの値を評価する。
データファイルが x:z:s の形式であったとすると、この場合以下のようにすればよい。
f(x,y) = (y==0) ? a*exp(-x/tau) : b*exp(-x/tau)
fit f(x,y) 'datafile' using 1:-2:2:3 via a, b, tau
より複雑な例については、デモファイル "fit.dem" で使われる "hexa.fnc" を参照してください。
もし従属変数のスケールに差がある場合、単位の重み付けでは 1 つの枝が支配してしまう可能性があるので、適当な重み付けが必要になります。各枝をバ ラバラに当てはめるのに複数当てはめ法の解を初期値として用いるのは、全体 を合わせた解の各枝に対する相対的な影響に関する表示を与えることになるで しょう。
fit は、解から遠くから始めると失敗するかも知れませんし、しばしばそれ は起こり得ます。遠くというのは、SSR が大きく、パラメータの変化に対して その変化が小さい、あるいは数値的に不安定な領域 (例えば数値が大きすぎて 浮動小数の桁あふれを起こす) に到達してしまって、その結果 "未定義値 (undefined value)" のメッセージか gnuplot の停止を引き起こしてしまう ような場合を意味します。
大域的な最適値を見つける可能性を改善するには、最初の値をその解に少なく ともほぼ近くに取るべきでしょう。例えば、もし可能ならば一桁分の大きさの 範囲内で。最初の値が解に近いほど他の解で終了してしまう可能性は低くなり ます。最初の値を見つける一つの方法は、データと当てはめ関数を同じグラフ の上に描画して適当な近さに達するまで、パラメータの値を変更して replot することを繰り返すことです。その描画は、よくない当てはめの極小値で当て はめが終了したかどうかをチェックするのにも有用です。
もちろん、適度に良い当てはめが、"それよりよい" 当てはめ (ある改良され た当てはめの良さの基準によって特徴付けられた統計学的な意味で、あるいは そのモデルのより適切な解である、という物理的な意味で) が存在しないこと の証明にはなりません。問題によっては、各パラメータの意味のある範囲をカ バーするような様々な初期値の集合に対して fit することが望ましいかも 知れません。
fit の引数の via には、2 つの大きく異なる目的のための 2 つの形式が あります。via "file" の形式は、バッチ処理 (非対話型での実行が可能) で最も良く使われ、そのファイルで初期値を与え、またその後で結果を他の (または 同じ) パラメータファイルにコピーするために update を使うこ とも出来ます。
via var1, var2, ... の形式は対話型の実行で良く使われ、コマンドヒスト リの機構が使ってパラメータリストの編集を行い、当てはめを実行したり、あ るいは新しい初期値を与えて次の実行を行なったりします。これは難しい問題 に対しては特に有用で、全てのパラメータに対して 1 度だけ当てはめを直接 実行しても、良い初期値でなければうまくいかないことが起こり得るからです。 それを見つけるには、いくつかのパラメータのみに対して何回か反復を行ない、 最終的には全てのパラメータに対する 1 度の当てはめがうまくいくところに 十分近くなるまでそれを繰り返すことです。
当てはめを行なう関数のパラメータ間に共通の依存関係がないことは確認して おいてください。例えば、a*exp(x+b) を当てはめに使ってはいけません。そ れは a*exp(x+b)=a*exp(b)*exp(x) だからです。よってこの場合は a*exp(x) または exp(x+b) を使ってください。
技術的なお話: 絶対値が最も大きいパラメータと最も小さいパラメータの比が 大きい程当てはめの収束は遅くなります。その比が、マシンの浮動小数の精度 の逆数に近いか、またはそれ以上ならば、ほぼずっと収束しないか収束する前に実行が中断するでしょう。よってそのような場合は、その関数の定義で例え ば 'parameter' を '1e9*parameter' にするとか、最初の値を 1e9 で割ると かしてこれを避けるように改良するか、または set fit prescale でパラメ ータの初期値に従ってそのスケール変換を内部でやらせる機能を用いるか、の いずれかが必要でしょう。
もし、関数を、当てはめるパラメータを係数とする、単純な関数の線形結合で 書けるなら、それはとてもいいので是非そうしてください。何故なら、問題が もはや非線形ではないので、反復は少ない回数で収束するでしょう。もしかし たらたった一回ですむかもしれません。
実際の実験の講義ではデータ解析に対するいくつかの指示が与えられ、それで データへの最初の関数の当てはめが行なわれます。もしかすると、基礎理論の 複数の側面にひとつずつ対応する複数回のプロセスが必要かも知れませんが、 そしてそれらの関数の当てはめのパラメータから本当に欲しかった情報を取り 出すでしょう。しかし、fit を使えば、求めるパラメータの視点から直接モ デル関数を書くことにより、それはしばしば 1 回で済むのです。時々はより 難しい当てはめ問題の計算コストがかかりますが、データ変換もかなりの割合 で避けることが出来ます。もしこれが、当てはめ関数の単純化に関して、前の 段落と矛盾してると思うなら、それは正解です。
"singular matrix" のメッセージは、この Marquardt-Levenberg アルゴリズ ムのルーチンが、次の反復に対するパラメータの値の計算が出来ないことを意 味します。この場合、別な初期値から始めるか、関数を別な形で書き直すか、 より簡単な関数にしてみてください。
最後に、他の当てはめパッケージ (fudgit) のマニュアルから、これらの文書 を要約するようないい引用を上げます: "Nonlinear fitting is an art! (非 線形当てはめ法は芸術だ !)"
help {<項目名>}
もし < 項目名> が指定されなかった場合は、gnuplot についての簡単な説明 が表示されます。指定した項目についての説明が表示された後、それに対する 細目のメニューが表示され、その細目名を入力することで細目に対するヘルプ を続けることができます。そして、その細目の説明が表示された後に、さらな る細目名の入力を要求されるか、または 1 つ前の項目のレベルへ戻ります。 これを繰り返すとやがて、gnuplot のコマンドラインへと戻ります。
また、疑問符 (?) を項目として指定すると、現在のレベルの項目のリストが 表示されます。
例:
history # 履歴全体を表示
history 5 # 履歴内の直前の 5 つを表示
history quiet 5 # エントリ番号なしで直前の 5 つを表示
history "hist.gp" # 履歴全体をファイル hist.gp に書き出す
history "hist.gp" append # 履歴全体をファイル hist.gp に追加する
history 10 "hist.gp" # 直前の 10 個をファイル hist.gp に出力
history 10 "|head -5 >>diary.gp" # パイプで履歴を 5 つ書き出す
history ?load # 履歴内の "load" で始まるものすべてを表示
history ?"set c" # 上と同様 (複数の語は引用符で囲む)
hi !reread # "reread" で始まる最も新しい行を実行
hist !"set xr" # 上と同様 (複数の語は引用符で囲む)
hist !55 # 55 番目の履歴項目のコマンドを再実行
if (<condition>) { <commands>;
<commands>
<commands>
} else {
<commands>
}
if (<条件>) <コマンド行> [; else if (<条件>) ...; else ...]
このバージョンの gnuplot は、if/else のブロック形式をサポートしていま す。キーワード if, else の後ろに開始カッコ "{" が続く場合、"}" で 終了するブロックまでのすべての文 (複数の入力行も可) に条件的な実行が適 用されます。if コマンドは入れ子にすることもできます。
古い形式の 1 行の if/else 文もまだサポートされていますが、新しいブロッ ク形式の書式とは混ぜてはいけません。以下参照: if-old (71.1)。
キーワード if が "{" をともなわない場合は、< 条件> が真 (ゼロでない) ならば < コマンド行> のコマンド (複数も可) が実行され、偽 (ゼロ) ならば スキップされます。いずれの場合も入力行の最後になるか、else が現れる ところまでそれが行われます。; を使うと同じ行に複数のコマンド置くこと が可能ですが、条件付きのコマンド (if の構文自体) はそこでは終らない ことに注意してください。
例:
pi=3
if (pi!=acos(-1)) print "?Fixing pi!"; pi=acos(-1); print pi
?Fixing pi!
3.14159265358979
if (1==2) print "Never see this"; print "Or this either"
その他:
v=0
v=v+1; if (v%2) print "2" ; else if (v%3) print "3" ; else print "fred"
for [intvar = start:end{:increment}]
for [stringvar in "A B C D"]
例:
plot for [filename in "A.dat B.dat C.dat"] filename using 1:2 with lines
plot for [basename in "A B C"] basename.".dat" using 1:2 with lines
set for [i = 1:10] style line i lc rgb "blue"
unset for [tag = 100:200] label tag
繰り返しの入れ子もサポートしています:
set for [i=1:9] for [j=1:9] label i*10+j sprintf("%d",i*10+j) at i,j
さらなる説明については、以下参照: iteration (18), do (65)。
書式:
import func(x[,y,z,...]) from "sharedobj[:symbol]"
例:
# 関数 myfun を "mylib.so" か "mylib.dll" から取り込んで作成する
# gnuplot では描画、または数値計算で利用可能
import myfun(x) from "mylib"
import myfun(x) from "mylib:myfun" # 上と同様
# "theirlib.so" か "theirlib.dll" で定義済の関数 theirfun を作成
# 異なる名前で利用可能
import myfun(x,y,z) from "theirlib:theirfun"
プログラムは共有オブジェクトとして与えられた名前に、オペレーティングシ ステムに従って ".so" か ".dll" を追加し、まずそれをフルパス名として検 索し、次にカレントディレクトリからの相対パス名として検索します。オペレ ーティングシステム自体も LD_LIBRARY_PATH か DYLD_LIBRARY_PATH の任意の ディレクトリを検索します。
書式:
load "<入力ファイル名>"
入力ファイル名は引用符で囲まなければなりません。
load コマンドは、標準入力からのコマンドの入力のために、特別なファイ ル名 "-" を用意しています。これは、gnuplot のコマンドファイルが、い くつかのコマンドを標準入力から受け付けることを意味します。詳細について は、以下参照: batch/interactive (7)。
Unix のように popen 関数をサポートするようなシステムでは、'< ' で始まる ファイル名にすることで、入力ファイルをパイプから読み込むことができます。
例:
load 'work.gnu'
load "func.dat"
load "< loadfile_generator.sh"
gnuplot への引数として与えられたファイル名は、暗黙のうちに load コ マンドによって実行されます。これらは、指定された順にロードされ、その後 gnuplot は終了します。
lower {plot_window_nb}
コマンド lower (raise の反対) は、pm, win, wxt, x11 等の gnuplot の対話型出力形式の実行中に、描画ウィンドウを下 (背後) に下げま す。描画ウィンドウを、デスクトップ上のウィンドウマネージャの z 方向の ウィンドウの重なりの下に置きます。
x11 や wxt のように複数の描画ウィンドウをサポートしている場合、デ フォルトではこのコマンドはそれらの複数のウィンドウを降順に下げ、最初に 作られたウィンドウを一番下に、最後に作られたウィンドウを一番上に並べま す。オプション引数の描画番号が与えられた場合、それに対応する描画ウィン ドウが存在すればそれのみが下げられます。
オプション引数は、単一の描画ウィンドウの出力形式、すなわち pm と win では無視されます。
書式:
pause <time> {"<string>"}
pause mouse {<endcondition>}{, <endcondition>} {"<string>"}
< time> は、任意の定数または式です。-1 を指定すると改行キーが押されるま で待ちます。0 を指定すると一切待たず、正の数を指定するとその秒数だけ待 ちます。実行環境が秒以下の時間指定をサポートしていない場合、その時間は整数の秒数に丸められます。pause 0 は print と同じです。
使用している出力形式が mousing (マウス機能) をサポートしている場合、 pause mouse は、マウスクリックがあるか ctrl-C が押されるまで待つよう になります。そうでない出力形式、またはマウス機能が有効になってない場合 pause mouse は pause -1 と同じです。
一つ、あるいは複数の終了条件 (endcondition) が pause mouse の後に与 えられた場合、そのうちのどの一つでも pause は終了します。指定できる終 了条件は、keypress, button1, button2, button3, close, any のいずれかです。pause がキー入力によって終了した場合、押されたキーの ASCII コードは MOUSE_KEY に保存され、文字それ自身は、1 文字の文字列値 として MOUSE_CHAR に返されます。keypress が終了条件の一つであれば、 ホットキー (キー割り当てコマンド) は無効になります。buttons3 が終了 条件の一つであれば、拡大機能は無効になります。
どの場合でもマウスの座標は変数 MOUSE_X, MOUSE_Y, MOUSE_X2, MOUSE_Y2 に 保存されます。以下参照: mouse variables (21.2)。
注意: pause コマンドは OS へのコマンドであり描画の一部ではないので、 異なる出力装置では異なる動作をする可能性があります。(これは、テキスト とグラフィックスが、どのように混在するかによります。)
例:
pause -1 # 改行キーが押されるまで待つ
pause 3 # 3 秒待つ
pause -1 "続けるには return を打ってください"
pause 10 "これは美しくないですか ? 3 次の spline です"
pause mouse "選択したデータ点上で任意のボタンをクリックしてください"
pause mouse keypress "有効なウィンドウ内で A-F の文字を入力してください"
pause mouse button1,keypress
pause mouse any "任意のキー、ボタンで終了します"
亜種である "pause mouse key" は、有効な描画ウィンドウ内での任意のキー 入力によって再開されます。特別なキー入力まで待つようにしたい場合は、以下のような reread によるループを使うことができます:
print "描画ウィンドウ内で Tab キーを打つと復帰します。"
load "wait_for_tab"
ファイル "wait_for_tab" は以下のようなものです:
pause mouse key
if (MOUSE_KEY != 9) reread
書式:
plot {<ranges>} <plot-element> {, <plot-element>, <plot-element>}
各描画要素 (plot-element) は、定義 (definition) か関数 (function) かデ
ータ (data source) のいずれか 1 つに、オプションの属性、修正子などがつ
いたものです:
描画要素 (plot-element):
{<iteration>}
<definition> | {sampling-range} <function> | <data source>
{axes <axes>} {<title-spec>}
{with <style>}
各描画要素のグラフ表現形式は、例えば with lines や with boxplot な どのようにキーワード with で決定します。以下参照: plotting styles (II)。
描画するデータは、1 つの関数から生成されるもの (媒介変数モード (parametric) では 2 つの関数から)、または一つのデータファイルから読み 込まれるもの、または事前に定義された名前付きデータブロックから読み込ま れるもの、のいずれかです。コンマで区切ることで、複数のデータファイル、 データブロック、関数などを 1 つの plot コマンドで描画できます。以下参照: data (77.3), inline data (77.3.4), functions (77.6)。
関数、変数の定義の描画要素は、画像出力を生成しません。下の 3 つ目の例 を参照してください。
例:
plot sin(x)
plot sin(x), cos(x)
plot f(x) = sin(x*a), a = .2, f(x), a = .4, f(x)
plot "datafile.1" with lines, "datafile.2" with points
plot [t=1:10] [-pi:pi*2] tan(t), \
"data.1" using (tan($2)):($3/$4) smooth csplines \
axes x1y2 notitle with lines 5
plot for [datafile in "spinach.dat broccoli.dat"] datafile
以下参照: show plot (88.60)。
ファイル名の後ろに binary のキーワードを与えなければいけません。ファ イル形式に関する十分詳細な情報は、ユーザがコマンドラインから与えるか、 またはサポートしている filetype のバイナリ形式のファイルそれ自身から 抜き出されるかする必要があります。バイナリファイルには、大きく 2 つの 形式、binary matrix 形式と binary general 形式があります。
binary matrix 形式は、32 ビット IEEE 規格の浮動小数値 (float) が 2 次元配列の形で並び、それらの座標値を表す行と列が追加されています。plot コマンドの using 指定において、1 番目 (column(1)) は行列の行の座標を 参照し、2 番目 (column(2)) は列の座標を参照し、3 番目 (column(3)) は、 配列のそれらの座標の場所に保存されている値を参照します。
binary general 形式は、任意個の列のデータを含み、それらの情報はコマ ンドラインで指定する必要があります。例えば array, record, format, using などでサイズや形式、データの次元を指定できます。他にも、ファイ ルヘッダ読み飛ばしたり、エンディアン (endian) を変更するための有用なコ マンドがありますし、配置、データの変換を行なうコマンドの組があります。 それは、一様に標本化されたデータの場合、その座標がファイルには含まれな いことが良くあるからです。matrix バイナリファイルやテキストデータから の入力と違うところですが、general バイナリは 1,2,3 といった using リ ストで生成される列番号を使わず、代わりに 1 列目はファイルの 1 列目、あ るいは format リストで指定されたもの、になります。
さまざまな binary オプションに対する大域的なデフォルトの設定も可能で、 それは (s)plot < filename> binary ... コマンドに与えるオプションと全 く同じ書式で指定できます。その書式は set datafile binary ... です。 一般的な規則として、デフォルトのパラメータはファイルから抜き出されたパ ラメータで上書きされ、それはコマンドラインで指定された共通なパラメータ で上書きされます。
例えば array, record, format, filetype の binary general 形 式を特定するようなキーワードが何もついていなければ、デフォルトのバイナ リ形式は binary matrix です。
general バイナリデータは、特別なファイル名 '-' を使ってコマンドライン から入力することもできます。しかし、これはキーボードからの入力を意図し たものではなく、パイプを使ってプログラムにバイナリ形式を変換させるため のものです。バイナリデータには最後を表す記号がありませんので、gnuplot はパイプからデータを読み込む場合、array 指定子で指定した数の点数にな るまでデータを読み込み続けます。詳細に関しては、以下参照:binary matrix (90.1.1), binary general (77.2.1)。
index キーワードは、ファイルフォーマットが 1 つのファイルにつき 1 つ の曲面しか許さないため、サポートされません。every や using フィルタ はサポートされます。using は、データがあたかも上の 3 つ組の形で読まれ たかのように働きます。
書式:
plot '<file_name>' {binary <binary list>} ...
splot '<file_name>' {binary <binary list>} ...
general バイナリ形式は、ファイル構造に関する情報に関連するキーワード、 すなわち array, record, format, filetype などを < binary list> 内に与えることで有効になります。それ以外の場合は、非一様な matrix バイナリ形式と見なします。(詳細に関しては、以下参照: binary matrix (90.1.1)。)
注意: 以前の版の gnuplot では、バイナリデータ用のキーワードの解釈に、plot と splot では少し違いがありました。その意味の違う箇所は、今後 の版の gnuplot では、その一方あるいは両方が変更される可能性があります。
gnuplot は、例えば PNG 画像のように完全に自己記述される標準的なバイナ リファイル形式の読み込み方法をいくつか知っています。その一覧は、対話画 面で show datafile binary と入力することで参照できます。それら以外のものについては、概念上はバイナリデータはテキストデータと同様に考えることができます。各点には、using 指定で選択される情報の列があります。 format 文字列を指定しなかった場合、gnuplot はバイナリ数値の数を < using list> で与えられる最大の列番号に等しく取ります。例えば、 using 1:3 とすると 3 列ずつデータが読み取られ、2 番目のものは無視し ます。各描画スタイルにはデフォルトの using 指定があります。例えば with image はデフォルトで using 1 を、with rgbimage はデフォルト で using 1:2:3 を使います。
注意: gnuplot バージョン 4.2 では array=(128,128) という書式で
はなく、array=128x128 という書式を使用していました。古い
書式は推奨されていません。
plot '<file_name>' binary skip=1024 ...
plot '<file_name> binary record=356:356:356 skip=512:256:256 ...
さらに using 指定同様、* 文字がついた読み捨てる列を書式に指定する こともできますし、繰り返しフィールドへの回数指定によって暗黙の繰り返し を指定することもできます。例えば、format="%*2int%3float" は、3 つの 実数データを読む前に、2 つの整数データを読み捨てます。使用できる変数サ イズの一覧は、show datafile binary datasizes で見ることができます。 それらは、それぞれのコンパイルによってそのバイトサイズとともにマシンに 依存する変数名のグループと、マシンに依存しない変数名のグループに分かれ ています。
little: 小さい桁から大きな桁へ並ぶ
big: 大きな桁から小さな桁へ並ぶ
default: compiler と同じエンディアンと見なす
swap (swab): エンディアンを変更する (おかしいようならこれを
使ってみてください)
gnuplot は、コンパイル時にオプションが指定されていれば、"middle" (や "pdp") エンディアンもサポートできます。
特別なファイル形式として auto があり、この場合 gnuplot はバイナリフ ァイルの拡張子が、サポートされている形式の標準的な拡張子であるかをチェ ックします。
コマンドラインキーワードはファイルから読み取る設定を上書きするのに使わ れ、ファイルから読み取る設定はデフォルトの設定を上書きします。以下参照:set datafile binary (88.20.6)。
http://www.edfplus.info/specs
plot 'file.png' binary filetype=png
set datafile binary filetype=auto
描画モードが plot の場合、指定には x と y の 2 つの文字を使うことが でき、splot に対しては x, y, z の 3 つの文字を使うことができます。
割り当てに関しては、点/線/面から直交座標方向へのみに制限する内部事情は 別にありません。この理由で、円柱座標への割り当てのための指定子も用意さ れていて、それらは直交座標の x, y, z に類似した形で t (角度), r, z と なっています。
以下のキーワードも座標の生成時にのみ適用されます。しかし、以下のものはmatrix バイナリファイルにも使われます。
配列をグラフのその他の場所に配置したい場合、origin キーワードで指定 した場所に gnuplot は配列の左下の点を合わせます。その指定は、plot で は 2 つの座標の組、splot では 3 つの座標の組を指定してください。例え ば origin=(100,100):(100,200) は、一つのファイルに含まれる 2 つのデ ータに対する指定で、2 次元の描画に対する指定です。2 つ目の例として origin=(0,0,3.5) をあげると、これは 3 次元描画用の指定です。
キーワード rotate は, plot, splot の両方で、2 次元面に対して適用 されます。回転は座標平面の正の角度に関して行なわれます。
角度は、ラジアン単位ですが、pi や degrees の倍数としてのラジアンでも表 現できます。例えば、rotate=1.5708, rotate=0.5pi, rotate=90deg は すべて同じ意味です。
origin が指定された場合、回転は平行移動の前に左下の点を中心にして行 なわれます。それ以外では回転は配列の中心 (center) に関して行なわれま す。
まず最初に 2 次元の回転が行なわれ、その次に 3 次元の回転が行なわれます。 つまり、R' をある角による 2 x 2 の回転行列とし、P を (0,0,1) を (xp,yp,zp) へ子午線方向に回転させる 3 x 3 の行列とし、R' を左上の部分 行列として持ち 3,3 成分が 1 でその他の成分が 0 であるような行列 (つま り z 軸周りの回転行列) とすれば、この変換を表す行列による関係式は v' = P R v となります。ここで、v はデータファイルから読み込まれた 3 x 1 の位置ベクトルです。ファイルのデータが 3 次元的なものでない場合 は、論理的なルールが適用されて 3 次元空間内のデータと見なされます (例 えば、通常は z 座標は 0 とされ、xy 平面内の 2 次元データと見なされます)。
書式:
plot '<file_name>' {binary <binary list>}
{{nonuniform} matrix}
{index <index list> | index "<name>"}
{every <every list>}
{skip <number-of-lines>}
{using <using list>}
{smooth <option>}
{volatile} {noautoscale}
修正子の binary, index, every, skip, using, smooth は、そ れぞれに分けて説明します。簡単に言うと、binary はデータ列をバイナリ ファイルから取得できるようにし、index はマルチデータ集合ファイルから どのデータ集合を表示するのかを選び、every が、一つのデータ集合からど の点を表示するのかを選び、using は一行からどの列を解釈するのかを決定 し、そして smooth が、単純な補間と近似を行います。splot もよく似た 書式を使いますが、smooth オプションはサポートしていません。
キーワード noautoscale は、自動的に軸の範囲が決定される機能が有効で ある場合に、この描画を構成するデータ点については、それを無視させる (自 動縮尺機能の計算対象から外す) ようにします。
テキストデータファイル:
データファイルは、一行につき少なくとも一つのデータ点を含む必要がありま す (using は一行から一つのデータポイントを選ぶことができます)。# (VMS では !) で始まる行は、コメントとして扱われ、無視されます。各デ ータ点は、(x,y) の組を表します。エラーバー、または折れ線表示付エラーバ ーの plot では (以下参照: errorbars (77.4), errorlines (77.5))、各データ点は、 (x,y,ydelta), (x,y,ylow,yhigh), (x,y,xdelta), (x,y,xlow,xhigh), (x,y,xlow,xhigh,ylow,yhigh) のいずれかを意味します。
どんな場合でも、書式の指定子が using オプションによって与えられてい
なければ、データファイルの各行の数字は、ホワイトスペース (一つまたは複
数の空白かタブ) によって区切られている必要があります。このホワイトスペ
ースは、各行を列の項目に区切ります。ただし、二重引用符で囲まれたホワイ
トスペースは列の勘定では無視され、よって次のようなデータ行は 3 列、と
見なされます:
1.0 "second column" 3.0
データは、指数部に e, E の文字をつけた指数表記で書かれていても構いませ ん。コマンド set datafile fortran が有効な場合は、fortran の指数指定 子 d, D, q, Q も使えます。
必要であるのはただ一つの列 (y の値) のみです。もし x の値が省略された ら、gnuplot はそれを 0 で始まる整数値として用意します。
データファイルにおいて、ブランク行 (空白と改行、復帰以外に文字を含まない行) は重要です。
1 行のブランク行は、plot に不連続を指示します; ブランク行によって区 切られた点は線で結ばれることはありません (line style で書かれている場 合には)。
2 行のブランク行は、別々のデータ集合間の区切りを示します。以下参照:index (77.3.3)。
もし autoscale の状態であれば (以下参照: set autoscale (88.3))、軸は全ての データポイントを含むように自動的に引き伸ばされて、目盛りが書かれる状態 ならば全ての目盛りがマークされます。これは、2 つの結果を引き起こします: i) splot では、曲面の角は底面の角に一致していないことがあります。こ の場合、縦の線は書かれることはありません。ii) 2 種類の軸での、同じ x の範囲のデータの表示の際、もし x2 の軸に対する目盛りが書かれていない場 合は、x 座標があっていないことがあります。これは x 軸 (x1) は全ての目 盛りにまで自動的に引き延ばされるのに対し、x2 軸はそうではないからです。 次の例でその問題を見ることができます:
reset; plot '-', '-' axes x2y1
1 1
19 19
e
1 1
19 19
e
これを避けるには、set autoscale コマンドの fixmin/fixmax オプシ ョンを使うことができます。これは、次の目盛りの刻みに合うように軸の範囲 を自動的に拡張する機能を無効にします。
ラベルの座標と文字列もデータファイルから読み込むことができます (以下参照: labels (45))。
ここでは 「ポイント」はファイル中の 1 つの行によって定義されるデータと し、ここでの「ブロック」は「データ・ブロック」(以下参照: glossary (17)) と同じものを意味することとします。
書式:
plot 'file' every {<ポイント増分>}
{:{<ブロック増分>}
{:{<開始ポイント>}
{:{<開始ブロック>}
{:{<終了ポイント>}
{:<終了ブロック>}}}}}
描画するデータポイントは、< 開始ポイント> から < 終了ポイント> まで < ポ イント増分> の増加で選び、ブロックは < 開始ブロック> から < 終了ブロック> まで < ブロック増分> の増加で選びます。
各ブロックの最初のデータは、ファイル中の最初のブロックと同じように、 「0 番」と数えます。
プロットできない情報を含む行もカウントすることに注意して下さい。
いくつかの数字は省略できます; 増分のデフォルトは 1 、開始の値は最初の ポイントか最初のブロック、そして終了の値は最後のポイントか最後のブロッ クに設定します。every のオプションが ':' で終わるのは許されていませ ん。every を指定しなければ、全ての行の全てのポイントをプロットします。
例:
every :::3::3 # 4 番目のブロックだけ選びます (0 番が最初)
every :::::9 # 最初の 10 ブロックを選びます
every 2:2 # 1 つおきのブロックで 1 つおきのポイントを選び
# ます
every ::5::15 # それぞれのブロックでポイント 5 から 15 までを
# 選びます
参照:
,
,
。
pop(x) = 103*exp((1965-x)/10)
set xrange [1960:1990]
plot 'population.dat', pop(x)
ファイル "population.dat" は次のようなファイルです。
# Gnu population in Antarctica since 1965
1965 103
1970 55
1975 34
1980 24
1985 10
# 2 つの float の値を選択し (2 つ目の値は無意味)、一方を読み捨て、
# 一つおきの float 値を無限に長く続く 1 次元データとして使用
plot '<file_name>' binary format="%float%*float" using 1:2 with lines
# データファイルから座標を生成するのに必要な情報をすべてそのヘッ
# ダに含んでいる EDF ファイルの場合
plot '<file_name>' binary filetype=edf with image
plot '<file_name>.edf' binary filetype=auto with image
# 3 つの符号なし文字型整数値 (unsigned char) を生の RGB 画像の色
# 成分として選択し、y 方向は反転させ画像の方向を座標平面上で変更
# する (左上が原点になるように)。ピクセルの間隔も指定し、ファイ
# ルには 2 つの画像が含まれていて、そのうち一つは origin で平行
# 移動する。
plot '<file_name>' binary array=(512,1024):(1024,512) format='%uchar' \
dx=2:1 dy=1:2 origin=(0,0):(1024,1024) flipy u 1:2:3 w rgbimage
# 4 つの別のデータからなり、座標情報もデータファイルに含まれてい
# る。ファイルは gnuplot が実行されているシステムとは異なるエン
# ディアンで生成されている。
splot '<file_name>' binary record=30:30:29:26 endian=swap u 1:2:3
# 同じ入力ファイルで、今回は 1 番目と 3 番目のレコードをスキップ
splot '<file_name>' binary record=30:26 skip=360:348 endian=swap u 1:2:3
以下参照: binary matrix (90.1.1)。
書式:
plot 'file' index { <m>{:<n>{:<p>}} | "<name>" }
データ集合は 2 行の空白で分離されています。index < m> は < m> 番目の集 合だけを選択します; index < m> :< n> は < m> から < n> までのデータ集合の 選択; index < m> :< n> :< p> は、< m> , < m> +< p> , < m> +2< p> , など、< p> おきの 集合を選択し、集合 < n> で終了します。C 言語の添字 (index) の付け方に従 い、index 0 はそのファイルの最初のデータ集合を意味します。大きすぎる index の指定にはエラーメッセージが返されます。< p> を指定し、< n> を空欄 にした場合、< p> 毎のデータをファイルの最後まで読み込みます。index を 指定しない場合は、ファイルのデータ全体を単一のデータ集合として描画しま す。
例:
plot 'file' index 4:5
ファイルの各点に対して、それが含まれるデータ集合の index 値は、疑似列 column(-2) で利用できます。これは、以下に見るように、そのファイル内の個々のデータ集合を区別する別の方法を提供します。これは、描画用に 1 つのデータ集合の選択しかしない場合は index コマンドよりも不恰好です が、個々のデータ集合に異なる属性を割り当てたい場合にはとても便利です。 以下参照: pseudocolumns (77.3.9.2), lc variable (19.1.2)。
例:
plot 'file' using 1:(column(-2)==4 ? $2 : NaN) # とても不恰好
plot 'file' using 1:2:(column(-2)) linecolor variable # とても便利 !
index '< name> ' は、データ集合を名前 '< name> ' で選択します。名前はコ メント行に書いてデータ集合に割り当てます。コメント文字とそれに続く空白 をそのコメント行から取り除いて、その結果が < name> から始まっていれば、 それに続くデータ集合に < name> という名前がつけられて、それを指定できま す。
例:
plot 'file' index 'Population'
< name> で始まるすべてのコメントがそれに続くデータ集合の名前になること に注意してください。問題を避けるために、例えば '== Popolation ==' や '[Population]' などの命名法を選択すると便利でしょう。
もう一つは、ヒアドキュメントとして名前付きのデータブロックを定義する方
法です。その名前付きのデータは残るので、複数の plot コマンドで参照でき
ます。例:
$Mydata << EOD
11 22 33 first line of data
44 55 66 second line of data
# データファイル同様コメントも機能する
77 88 99
EOD
stats $Mydata using 1:3
plot $Mydata using 1:3 with points, $Mydata using 1:2 with impulses
データブロック名は、他の変数と区別するために、最初の文字を $ にする必 要があります。データの終わりの区切り (上の例では EOD) は、任意のアルフ ァベット、数字からなる文字列で構いません。
コマンド undefine を使えば、保存した名前付きデータブロックを削除でき ます。undefine $* は、すべての名前付きデータブロックを一度に削除しま す。
書式:
smooth {unique | frequency | cumulative | cnormal | kdensity {bandwidth}
| csplines | acsplines | mcsplines | bezier | sbezier
| unwrap}
unique, frequency, cumulative, cnormal は、データを単調に揃え た後でそれらを plot します。unwrap は、データがπより大きなジャンプ をしないように、2πの整数倍を加える操作をします。他のルーチンはいずれ も、データの両端の点の間を結ぶ、ある連続曲線の係数を決定するためにデー タを使います。この曲線は、関数として同じ方法で描画されます。すなわち、 それらの値は x 座標に沿う同じ幅の区間ごとに選ばれ (以下参照:set samples (88.72))、それらの点を線分でつなぐことにより (もし line style が 選ばれているのならば) 描画されます。
もし autoscale の状態であれば、描画範囲はグラフの境界線の中に曲線が 収まるように計算されます。
もし autoscale の状態でなく、smooth のオプションが acsplines か csplines であれば、生成する曲線の標本化は、入力データを含むような x の範囲と、set xrange などで定義される固定された横座標の範囲の共通部 分の上で行なわれます。
選択されたオプションを適用するのにデータの点数が少なすぎる場合は、エ ラーメッセージが表示されます。その最小のデータ数は unique と frequency では 1 つ、acsplines では 4 つ、他のオプションでは 3 つ です。
smooth オプションは、関数の描画のときには無視されます。
plot 'data-file' using 1:2:(1.0) smooth acsplines
性質上、重みの絶対的な大きさは、曲線を構成するのに使われる区分の数を決 定します。もし重みが大きければ、個々のデータの影響は大きくなり、そして その曲線は、隣り合う点同志を自然 3 次スプラインでつないで得られるもの に近づきます。もし重みが小さければ、その曲線はより少ない区分で構成され、 それによってより平滑的になります。その最も極端な場合はただ 1 つの区分 からなる場合であり、それは全てのデータに重みの付き線形最小 2 乗近似に よって作られます。誤差の立場から言えば、平滑さの重みは、その曲線に対す る「平滑化因子」によって分割された各点への、統計的な重みと見ることがで きます。それにより、そのファイル中の (標準的な) 誤差は平滑さの重みとし て使うことができます。
例:
sw(x,S)=1/(x*x*S)
plot 'data_file' using 1:2:(sw($3,100)) smooth acsplines
binwidth = <適当な値> # x の値の各階級幅
bin(val) = binwidth * floor(val/binwidth)
plot "datafile" using (bin(column(1))):(1.0) smooth frequency
default_bandwidth = sigma * (4/3N) ** (0.2)
plot $DATA smooth kdensity bandwidth <value> with boxes
空のファイル名 '' は、同じ plot コマンド上で、直前の入力ファイルを再び 使用することを gnuplot に指示します。よって、同じ入力ファイルの 2 つの データ列を描画するには以下のようにします:
plot 'filename' using 1:2, '' using 1:3
この filename は、この後の plot コマンドでも '' で再利用できますが、 その場合に save すると、コメントとしてその名前を記録するのみです。
'+' と '++' という特別なファイル名は、using 指定の全体と描画スタイル にインライン関数を使えるようにするための仕組みです。通常、関数描画はサ ンプル点毎に単一の y (または z) の値しか持てません。しかし疑似ファイル '+' はそれがあたかも実際の入力ファイルであるように、using 指定による 1 列目の値を標本点として扱い、さらに追加の列の値を指定することも可能で す。標本点は、デフォルトでは set xrange で設定した範囲全体に渡り、 set samples で制御する標本化に従って取られます。
plot '+' using ($1):(sin($1)):(sin($1)**2) with filledcurves
'+' の直前に、独立な標本範囲を指定することもできます。通常の関数描画の ように、独立変数に名前を割り当てることもできます。plot の最初の要素に 与える場合、標本範囲にはそれを明示するキーワード sample を前置する必 要があります (以下も参照: plot sampling (77.9))。
plot sample [beta=0:2*pi] '+' using (sin(beta)):(cos(beta)) with lines
同様に、疑似ファイル '++' は、x 方向は set samples で制御される点の 数、y 方向は set isosamples で制御される点の数の、標準的な [x,y] 座 標の格子を生成する 2 列のデータを返します。媒介変数モードではサンプル 点は x と y に関してではなく、u と v に関して取られます。'++' の描画の 前に、xrange と yrange (または urange と vrange) を設定する必要があり ます。例:
splot '++' using 1:2:(sin($1)*sin($2)) with pm3d
plot '++' using 1:2:(sin($1)*sin($2)) with image
'-' という特別なファイル名は、データがインラインであることを指示し ます。すなわち、データをコマンドの後に続けて指定します。このときはデ ータのみがコマンドに続き得ます。よって、plot コマンドに対するフィル ター、タイトル、ラインスタイルといったオプションは、plot のコマンド ラインの方に書かないといけません。これは、unix シェルスクリプトにおけ る < < (ヒアドキュメント)、あるいは VMS DCL における $DECK と同様です。 そのデータは、それらがファイルから読み込まれたかのように、1 行につき 1 つずつのデータ点が入力されます。そしてデータの終りは、1 列目の始めに 文字 "e" を置くことで指示します。using オプションをこれらのデータに 適用することは可能です。ある関数を通しデータをフィルターすることに使う のは意味があるでしょうが、列を選ぶのに使うことは多分意味がないでしょう。
'-' は、データとコマンドを一緒に持つことが有用である場合のためにあ ります。例えば、gnuplot があるフロントアプリケーションのサブプロセ スとして起動される場合などがこれにあたります。例として、デモンストレ ーションでこの機能を使うものがあるでしょう。index や every のよう な plot のオプションが与えられていると、それらはあなたに使われるこ とのないデータを入力する事を強要します。次の例を見てください。
plot '-' index 0, '-' index 1
2
4
6
10
12
14
e
2
4
6
10
12
14
e
これは、実際に動作しますが、
plot '-' , '-'
2
4
6
e
10
12
14
e
とタイプする方が楽でしょう。
もし、replot コマンドで '-' を使うなら、あなたは 1 度以上データを入力する必要があるでしょう。以下参照: replot (84), refresh (83)。
空のファイル名 ('') は、直前のファイル名が再び使われることを指示しま す。これは、
plot 'ある/とても/長い/ファイル名' using 1:2, '' using 1:3, '' using 1:4
のようなときに便利です。(もし同じ plot コマンド上で、'-' と '' の 両方を使用すると、上の例にあるように、インラインデータの 2 つの集合を 与える必要があります。)
popen 関数を持っているシステム上では、データファイルは、'< ' で始まるフ ァイル名によって、シェルコマンドからパイプ入力することができます。例え ば
pop(x) = 103*exp(-x/10)
plot "< awk '{print $1-1965, $2}' population.dat", pop(x)
は、最初の人口の例と同じ情報を描画します。ただし、x 座標は 1965 年か らの経過年を表すようになります。この例を実行するときは、上のデータフ ァイルのコメント行をすべて削除しなければなりませんが、または上のコマ ンドの最初の部分を次のように変えることもできます (コンマに続く部分):
plot "< awk '$0 !~ /^#/ {print $1-1965, $2}' population.dat"
このアプローチは最も柔軟性がありますが、using キーワードを用いた単純 なフィルタリングで行うことも可能です。
fdopen() 関数を持つシステムでは、データを、ファイルかパイプに結びつけ られた任意のファイルデスクリプタから読み込むことができます。n 番のフ ァイルデスクリプタから読み込むには、'< &n' としてください。これにより、 1 回の POSIX shell からの呼び出しの中で、複数のデータファイルからのパ イプ入力が容易に行えるようになります:
$ gnuplot -p -e "plot '<&3', '<&4'" 3<data-3 4<data-4
$ ./gnuplot 5< <(myprogram -with -options)
gnuplot> plot '<&5'
古い書式:
plot 'file' thru f(x)
現在の書式:
plot 'file' using 1:(f($2))
書式:
plot 'file' using <entry> {:<entry> {:<entry> ...}} {'format'}
format を指定すると、それを C ライブラリ関数 'scanf' に適用してデータ ファイルの各行を読みます。そうでなければ、各行はホワイトスペース (スペ ースやタブ) で区切られたデータの列 (フィールド) からなるとみなしますが 以下も参照: datafile separator (88.20.4)。
各 < entry> は、入力ファイルの一つのフィールドを選択するための単なる列 の番号か、一つのデータ集合の最初の行の列のラベルに一致する文字列、カッ コで囲まれた数式、xticlabels(2) のようにカッコで囲まない特別な関数、の いずれかです。
そのエントリがカッコで囲まれた数式の場合、N 列目の値を指定するのに関数
column(N) を使用できます。つまり、column(1) は読み込まれた最初の項目を
参照し、column(2) は次の項目、といった具合です。column(1), column(2),
... の略記として、特別な記号 $1, $2, ... を使用できます。関数
valid(N) で、N 番目の列が有効な数字であるかどうかテストできます。
入力ファイルの最初の行の各列に、データの値ではなくラベルを持っている場
合、このラベルを入力列の特定や plot タイトルに使用できます。関数
column() は、列番号以外にラベルで入力列を選択できます。例えば、データ
ファイルが以下のような場合:
Height Weight Age
val1 val1 val1
... ... ...
plot 'datafile' using 3:1, '' using 3:2
plot 'datafile' using (column("Age")):(column(1)), \
'' using (column("Age")):(column(2))
plot 'datafile' using "Age":"Height", '' using "Age":"Weight"
指定文字列が完全に一致する必要がありますし、大文字小文字も区別します。 列のラベルを plot タイトルに使うには、set key autotitle columnhead としてください。
入力データファイルの 1...N という実際の列に加えて、gnuplot は管理情報 を持ついくつかの "疑似列" を提供します。例えば、$0 または column(0) は、 データ集合内のそのデータ行の行番号を返します。以下参照:pseudocolumns (77.3.9.2)。
< entry> に何も書かなければ、そのエントリのリストの順にデフォルトの値が 使われます。例えば using ::4 は、using 1:2:4 と解釈されます。
using にただ一つのエントリを指定した場合は、その < entry> は y の値と して使われ、データ点の番号 (疑似列 $0) が x として使われます。例えば "plot 'file' using 1" は "plot 'file' using 0:1" と同じ意味です。 using に 2 つのエントリを与えた場合、それらは x, y として使われます。 さらにエントリを追加して、入力からのデータを利用するような描画スタイル の詳細については、以下参照: set style (88.74), fit (68)。
'scanf' 関数では色々なデータ形式の数値入力が使えますが、gnuplot は全 ての入力データを倍精度浮動小数とみなしますから、gnuplot では %lf が本質的に唯一の数値入力指定、ということになります。 書式文字列には、少なくとも一つ、そして 7 つ以下の、そのような入力指定子を入れる必要があります。 'scanf' は数と数の間にホワイトスペース、すなわち空白、タブ (" \ t")、改行 (" \ n")、または改ページ (" \ f") があると期待します。それ以外の入力は明示的にスキップされるべきです。
" \ t", " \ n", " \ f" を使うときは単一引用符よりむしろ二重引用符を使うべき であることに注意してください。
plot 'file' using 1:($2+$3) '%lf,%lf,%lf'
次の例は、より複雑な書式指定でデータをファイル "MyData" から読み込み
ます。
plot 'MyData' using "%*lf%lf%*20[^\n]%lf"
この書式指定の意味は以下の通りです:
%*lf 数値を無視
%lf 倍精度浮動小数を読み込む (デフォルトでは x の値)
%*20[^\n] 20 個の改行以外の文字を無視
%lf 倍精度浮動小数を読み込む (デフォルトでは y の値)
3 項演算子 ?: を使ってデータをフィルタする一つの芸当を紹介します。
plot 'file' using 1:($3>10 ? $2 : 1/0)
これは、1 列目のデータに対して、3 列目のデータが 10 以上であるような2 列目のデータを plot します。1/0 は未定義値であり、gnuplot は未定 義の点を無視するので、よって適切でない点は隠されることになります。 または、あらかじめ定義されている値 NaN を使っても同じことになります。
カッコで始まっていない限りは定数式を列番号として使うことができます。 例えば using 0+(複雑な式) の様なことができます。そして、その数式は、 カッコでスタートしていなければ数式の値が一度評価され、カッコでスタート していれば個々のデータ点を読み込むためにその値が一度評価される、という 点が重要です。
時系列フォーマットデータを使っている場合、その時間のデータは複数の列に 渡らせることができます。その場合、他のデータの開始位置を計算するとき、 時間のデータに空白が含まれていることに注意してください。例えば、データ 行の最初の要素がスペースが埋め込まれた時間データであるならば、y の値は 3 列目の値として指定されるべきです。
plot 'file' と plot 'file' using 1:2、そして plot 'file' using ($1):($2) には微妙な違いがあることに注意してくださ い。1) file が 1 列と 2 列のデータを持つ行をそれぞれ含んでいるとする と、データが 1 列のみの行に対しては、最初のものは x の値を作り出し、2 番目のものはその行は無視し、3 番目のものはそれを未定義の値として保存し ます (折れ線で plot している場合 (plot with lines)、その未定義の点を通 過する線を結ばないように)。2) 1 列目に文字列を含んでいるような行がある 場合、最初のものはエラーとして plot を中止しますが、2 番目と 3 番目の ものはその不要な行を読みとばします。
実際、最初に単に
plot 'file' using 1:2
と指定することで、大抵の場合どんなにゴミのデータを含む行を持つファイル をも plot することが可能になります。しかし、どうしてもデータファイルに 文字列を残しておきたいならば、そのテキスト行の第一列にコメント文字 (#) を置く方がより安全でしょう。
column(0) データ集合内での各点の順番。順番は 0 から始まり、2
行のブランク行でリセットされます。略記 $0 も使用可。
column(-1) この番号は 0 から始まり、1 行のブランク行でリセット
されます。これは、行列、または格子状データ内のデータ
行に対応します。
column(-2) 複数のデータ集合を持つファイル内の、現在のデータ集合
の index 番号。以下参照: `index`。
plot 'datafile' using <xcol>:<ycol>:xticlabels(3) with <plotstyle>
軸の目盛りの見出しは、任意の描画軸 x,x2,y,y2,z 用に生成できます。 ticlabels(< labelcol> ) 指定は、using 指定の中で、そのデータの座標指 定が全て済んだ後に行う必要があります。有効な X,Y[,Z] 座標の組を持つ各 データ点に対して、xticlabels() に与える文字列値は、それに対応する点の x 座標と同じ場所の x 軸の見出しのリストに追加されます。xticlabels() は xtic() と省略することもでき、他の軸に関しても同様です。
例:
splot "data" using 2:4:6:xtic(1):ytic(3):ztic(6)
この例では、x 軸、y 軸の見出しは x,y 座標値とは別の列から取り出されま すが、z 軸の見出しは、対応する点の z 座標値から生成されます。
例:
plot "data" using 1:2:xtic( $3 > 10. ? "A" : "B" )
この例は、x 軸の見出しの生成に文字列値関数を使用したもので、データファ イルの各点の x 軸の刻みの見出しは、3 列目の値によって "A" か "B" かの いずれかとなります。
デフォルトでは、gnuplot はデータファイルの各行に以下のような 3 つ、4 つ、あるいは 6 つの列があることを期待しています:
(x, y, ydelta),
(x, y, ylow, yhigh),
(x, y, xdelta),
(x, y, xlow, xhigh),
(x, y, xdelta, ydelta),
(x, y, xlow, xhigh, ylow, yhigh)
x 座標は必ず指定しなければいけません。各数値を書く順序も上で挙げた通りで なくてはなりません。ただ、using 修飾子を使えばその順序を操作できますし、 欠けている列の値も補うことは可能ですが。例えば、
plot 'file' with errorbars
plot 'file' using 1:2:(sqrt($1)) with xerrorbars
plot 'file' using 1:2:($1-$3):($1+$3):4:5 with xyerrorbars
最後の例は、相対的な x の誤差と絶対的な y の誤差、という、サポートされて いない組のファイルに対するものです。using エントリが相対的な x の誤差 から絶対的な x の最小値と最大値を生成しています。
y のエラーバーは、(x, ylow) から (x, yhigh) への鉛直な線として描かれます。 ylow と yhigh の代わりに ydelta が指定されたときは、ylow = y - ydelta, yhigh = y + ydelta となります。ある行にデータが 2 つしかなければ、ylow と yhight はともに y となります。x エラーバーは同様に計算された水平線です。 データの各点を結ぶ折れ線を引きたい場合は、with errorbars と with lines を 指定して、同じデータファイルを 2 回 plot して下さい (ただし、キーの中に 2 つのエントリを作らないように、その一方には notitle オプションを使う ことを忘れないで下さい)。他の選択肢として、errorlines コマンドもあります (以下参照: errorlines (77.5))。
エラーバーには、もし set bars を使っていなければ、そのそれぞれの端に垂直な 線分がつきます (詳細は、以下参照: set bars (88.4))。
自動範囲指定が有効であれば、その描画範囲はエラーバーも含むように調整 されます。
以下も参照
更なる情報に関しては、以下参照: plot using (77.3.9), plot with (77.12), set style (88.74)。
デフォルトの状態では、gnuplot は、データファイルの各行に 3 個、4 個、 6 個のいずれかの個数のデータがあることを期待し、それぞれ以下のいずれかに対応します。
(x, y, ydelta),
(x, y, ylow, yhigh),
(x, y, xdelta),
(x, y, xlow, xhigh),
(x, y, xdelta, ydelta),
(x, y, xlow, xhigh, ylow, yhigh)
x 座標は指定する必要がありますし、データの順番も上の形式である必要があ りますが、using 修飾子でその順番を操作したり、欠けている列に対する値 を与えたりすることができます。例えば
plot 'file' with errorlines
plot 'file' using 1:2:(sqrt($1)) with xerrorlines
plot 'file' using 1:2:($1-$3):($1+$3):4:5 with xyerrorlines
最後の例は、相対的な x の誤差と絶対的な y の誤差、というサポートされて いない組合せのデータのファイルに対するもので、using で相対的な誤差か ら絶対的な x の最小値と最大値を生成しています。
y 誤差線は (x, ylow) から (x, yhigh) へ描画される縦線です。ylow, yhigh 代わりに ydelta が指定された場合は、ylow = y - ydelta, yhigh = y + ydelta と扱われます。ある行に 2 つのデータしかない場合、yhigh, ylow は両方と も y になります。x 誤差線は同様の方法で計算される水平線です。
誤差線には、set bars が指定されていない場合、その両端で垂直に交わる 線分が付きます (詳細は、以下参照: set bars (88.4))。
自動縮尺 (autoscaling) が ON の場合、描画範囲は誤差線が入るように調整 されます。
更なる情報については、以下参照: plot using (77.3.9), plot with (77.12), set style (88.74)。
例:
approx(ang) = ang - ang**3 / (3*2)
plot sin(x) title "sin(x)", approx(x) title "approximation"
関数のデフォルトの描画スタイルを設定する方法については、以下参照:set style function (88.74.5)。組み込み関数の情報については、以下参照:expressions functions (15.1)。自前で関数を定義する方法については、以下参照:user-defined (15.5)。
例:
plot sin(t),t**2
splot cos(u)*cos(v),cos(u)*sin(v),sin(u)
データファイルは前と同じように描画されます。ただし、データファイルが 描画のために与えられる前に、任意の媒介変数関数が先に完全に指定された 場合を除いてです。言い換えると、x の媒介変数関数 (上の例では sin(t)) と y の媒介変数関数 (上の例では t**2) との間に、他の修飾子やデータ 関数をはさみこんではいけません。そのようなことをすると、構文エラーにな り、媒介変数関数が完全には指定されていない、と表示されます。
with や title のような他の修飾子は、媒介変数関数の指定が完了した 後に指定しなければいけません。
plot sin(t),t**2 title 'Parametric example' with linespoints
以下も参照
書式:
[{<dummy-var>=}{{<min>}:{<max>}}]
[{{<min>}:{<max>}}]
1 つ目の形式の範囲指定は独立変数の範囲 (xrange、または媒介変数モード での trange) 用で、2 つ目の形式は従属変数の範囲用です。オプションの < dummy-var> で独立変数の新しい名前を利用できます (デフォルトの変数名は set dummy で変更できます)。
媒介変数モード (parametric) でなければ、範囲指定は以下の順に与えなければいけません:
plot [<xrange>][<yrange>][<x2range>][<y2range>] ...
媒介変数モード (parametric) では、範囲指定は以下の順に与えなければいけません:
plot [<trange>][<xrange>][<yrange>][<x2range>][<y2range>] ...
plot [-pi:pi] [-1.3:1.3] [-1:1] sin(t),t**2
* は、min (最小値) や max (最大値) に自動範囲指定 (autoscale) の機能 を使うことを可能にします。指定順番のためだけに必要な範囲指定には、空の 範囲 [] を使ってください。
plot や splot のコマンド行で指定された範囲はそのグラフ一つにのみ影 響を及ぼします。よって、その後のグラフのデフォルトの範囲を変更するには set xrange や set yrange を使用してください。
時間データに対しては、範囲は、データファイルから読み込むのに使用するの と同じ書式で、引用符で囲んで指定する必要があります。以下参照:set timefmt (88.83)。
例:
以下は現在の範囲を使用します:
plot cos(x)
以下は x の範囲のみの指定です:
plot [-10:30] sin(pi*x)/(pi*x)
以下は上と同じですが、仮変数として t を使います:
plot [t = -10 :30] sin(pi*t)/(pi*t)
以下は x と y の両方の範囲の指定です:
plot [-pi:pi] [-3:3] tan(x), 1/x
以下は、y の範囲のみの指定です:
plot [ ] [-2:sin(5)*-8] sin(x)**besj0(x)
以下は x の最大値と y の最小値のみの指定です。
plot [:200] [-pi:] $mydata using 1:2
以下は x の範囲を時系列データとして指定しています:
set timefmt "%d/%m/%y %H:%M"
plot ["1/6/93 12:00":"5/6/93 12:00"] 'timedata.dat'
例:
以下は、x 全体の範囲を 0 から 1000 としてファイルのデータを描画し、2つの関数を全体の範囲の一部分だけそれぞれ描画します:
plot [0:1000] 'datafile', [0:200] func1(x), [200:500] func2(x)
以下は、上とほぼ同様ですが、全体の範囲はデータファイルの内容によって決定します。この場合、標本化される関数は、全体がグラフ内に収まるかもしれ
ませんし、収まらないかもしれません:
set autoscale x
plot 'datafile', [0:200] func1(x), [200:500] func2(x)
以下のコマンドにはあいまいさが含まれます。先頭の範囲は、多分最初の関数
の標本化のみに向けたのだと思いますが、実際はそうではなく、すべての描画
要素に適用するように解釈されます:
plot [0:10] f(x), [10:20] g(x), [20:30] h(x)
以下のコマンドは、上の例のあいまいさを除くためにキーワード sample を追加したもので、その範囲指定を plot 全体に適用しないようにしています:
plot sample [0:10] f(x), [10:20] g(x), [20:30] h(x)
以下の例は、3 次元グラフにらせんの曲線を描く一つの方法を提示します:
splot [-2:2][-2:2] sample [h=1:10] '+' using (cos(h)):(sin(h)):(h)
書式:
plot for [<variable> = <start> : <end> {:<increment>}]
plot for [<variable> in "string of words"]
繰り返しの適用範囲 (scope) は、次のコンマ (,) かコマンドの終わり、のい
ずれか先に現れたところまでです。ただし、描画する項目の前に定義式 (複数
も可) が並んでいる場合は、コンマが間に入っていてもその例外となります。
繰り返しは媒介変数モード (parametric) では機能しないことに注意してく
例:
plot for [j=1:3] sin(j*x)
例:
plot for [dataset in "apples bananas"] dataset."dat" title dataset
この例では、繰り返しはファイル名と対応するタイトルの生成の両方で使われ ています。
例:
file(n) = sprintf("dataset_%d.dat",n)
splot for [i=1:10] file(i) title sprintf("dataset %d",i)
この例は、ファイル名で生成される文字列値関数を定義し、そのような 10 個 のファイルを同時に描画します。繰り返しの変数 (この例では 'i') は一つの 整数として扱われ、それを 2 度以上使用できます。
例:
set key left
plot for [n=1:4] x**n sprintf("%d",n)
この例は、関数の組を描画します。
例:
list = "apple banana cabbage daikon eggplant"
item(n) = word(list,n)
plot for [i=1:words(list)] item(i).".dat" title item(i)
list = "new stuff"
replot
この例では、リストに従って各ステップが進行し、その各項目に対して一つの 描画が行われます。この各項目は動的に取得されますので、そのリストを変更 し、そのまま replot することができます。
例:
list = "apple banana cabbage daikon eggplant"
plot for [i in list] i.".dat" title i
list = "new stuff"
replot
この例は、整数の繰り返し変数ではなく、文字列の繰り返し変数形式を用いて いること以外は前の例と全く同じです。
< end> の整数の代わりに記号 * を使用すれば、繰り返しはすべての有効なデ ータがなくなるまでの繰り返しとなります。これは、各行に含まれるすべての 列の処理、あるいはファイル内のすべてのデータセット (2 行の空行で区切ら れる) の処理、指定に当てはまるすべてのファイルなどを一度に処理するのに 便利です。
例:
plot for [i=2:*] 'datafile' using 1:i with histogram
splot for [i=0:*] 'datafile' index i using 1:2:3 with lines
plot for [i=1:*] file=sprintf("File_%03d.dat",i) file using 2 title file
書式:
title <text> | notitle [<ignored text>]
title columnheader | title columnheader(N)
{at {beginning|end}}
ここで < text> は、引用符で囲まれた文字列か、文字列と評価される式のいず れかです。引用符はキーには表示されません。
入力データの列の最初の項目 (すなわち列の先頭) を文字列フィールドと解釈 し、それをキータイトルとして利用するオプションもあります。以下参照:datastrings (12)。これは、set key autotitle columnhead を指定すればデフ ォルトの挙動となります。
曲線タイトルとサンプルは予約語 notitle を使うことでキーから削除でき ます。何もないタイトル (title '') は notitle と同じ意味を持ちます。 サンプルだけが欲しいときは、一つ以上の空白をタイトルの後ろに入れてください (tilte ' ')。notilte の後ろに文字列をつけた場合、その文字列 は無視されます。
key autotitles が設定されて (デフォルト)、かつ title も notitle も指定されなかった場合、曲線のタイトルは plot コマンド上にある関数名 かデータファイル名になります。ファイル名の場合は、指定される任意のデー タファイル修飾子もそのデフォルトタイトルに含まれます。
位置やタイトルの位置揃えなどの凡例のレイアウトは、set key で制御でき ます。詳細は、以下参照: set key (88.35)。
描画する曲線のタイトルを、グラフの曲線自身の直前、あるいは直後に置くに は、at {beginning| end} を使用します。このオプションは、with lines で描画する場合は有用ですが、他の描画スタイルでは意味がない場合もありま す。
例:
以下は y=x をタイトル 'x' で表示します:
plot x
以下は、x の 2 乗をタイトル "x^2" で、ファイル "data.1" をタイトル"measured data" で表示します:
plot x**2 title "x^2", 'data.1' t "measured data"
以下は、極座標グラフの周りに円形の境界を書き、タイトルなしで表示します:
set polar; plot my_function(t), 1 notitle
以下は、ファイルの先頭行の各列にタイトルを含む複数列のデータを描画します。各タイトルは、独立した凡例ではなく、対応する曲線の後ろに置きます:
unset key
set offset 0, graph 0.1
plot for [i=1:4] 'data' using i with lines title columnhead at end
書式:
with <style> { {linestyle | ls <line_style>}
| {{linetype | lt <line_type>}
{linewidth | lw <line_width>}
{linecolor | lc <colorspec>}
{pointtype | pt <point_type>}
{pointsize | ps <point_size>}
{fill | fs <fillstyle>}
{nohidden3d} {nocontours} {nosurface}
{palette}}
}
ここで、< style> は以下のいずれか:
lines dots steps errorbars xerrorbar xyerrorlines
points impulses fsteps errorlines xerrorlines yerrorbars
linespoints labels histeps financebars xyerrorbars yerrorlines
surface vectors parallelaxes
boxes boxplot ellipses image
boxerrorbars candlesticks filledcurves rgbimage
boxxyerrorbars circles histograms rgbalpha pm3d
table
最初のグループのスタイルは、線、点、文字の属性を持ち、第 2 のグループ のスタイルは、さらに塗り潰し属性も持っています。以下参照: fillstyle (88.74.4)。 さらにサブスタイルを持つスタイルもあります。個々のスタイルの詳細につい ては、以下参照: plotting styles (II)。 スタイル table は、グラフの代わりに表形式の出力を生成します。以下参照: set table (88.76)。
デフォルトのスタイルは、set style function と set style data で選 択できます。
デフォルトでは、それぞれの関数やデータファイルは、使うことができる型の 最大数に達するまで異なる線種、点種を使います。すべての端末用ドライバは 最低 6 つの異なる点種をサポートしていて、もしたくさん要求された場合、 それらを順に再利用していきます。使用中の出力形式での線種、点種の集合全 体を見たければ、test としてください。
一つの描画で線種や点種を選びたいならば、< line_type> や < point_type> を 指定してください。これらの値は、その描画で使われる線種や点種を指定する 正の整定数 (または数式) です。使用する端末で使える線種、点種を表示する には test コマンドを使ってください。
描画の線の幅や点の大きさは < line_width> や < point_size> で変更できます。 これらはその各々の端末のデフォルトの値に対する相対的な値として指定しま す。点の大きさは全体に通用するように変更できます。詳細は、以下参照:set pointsize (88.64)。しかし、ここでセットされる < point_size> と、 set pointsize でセットされる大きさは、いずれもデフォルトのポイントサ イズに掛けられることに注意してください。すなわち、それらの効果は累積は しません。例えば、set pointsize 2; plot x w p ps 3 は、デフォルトの サイズの 3 倍であって、6 倍ではありません。
ラインスタイルの一部分、あるいは各 plot において pointsize variable という指定も可能です。この場合、入力には追加の 1 列が要求されます。例 えば 2D 描画では 3 列、3D 描画では 4 列のデータが必要になります。個々 の点のサイズは、全体を通しての pointsize に、データファイルからの入力 による値をかけたものとして決定されます。
set style line を使って線種/線幅、点種/点幅の組を定義すれば、そのス タイルの番号を < line_style> にセットすることでそれらを使うことができま す。
gnuplot が pm3d をサポートするようにインストールされているならば、 splots において lines, points, dots の色を滑らかに変化させるための特 別なキーワード palette が使えます。その色は、コマンド set palette であらかじめ設定された滑らかに変化するカラーパレットから選択します。色 の値は、点の z 座標の値か、または using で 4 番目のパラメータとして 指定される色座標に対応します。2 次元、3 次元の描画 (plot と splot コマンド) の両方で、パレット色を小数値かまたはカラーボックスの範囲へ対 応づけられた値のいずれかで指定することができます。パレット色の値は、 using 指定で明示的に指定された入力列から読み込むことも可能です。 以下参照: colors (19), set palette (88.62), linetype (88.37)。
キーワード nohidden3d は、splot コマンドで生成される描画にのみ適用 されます。通常、グローバルなオプション set hidden3d はグラフ上の全て の描画に適用されますが、各々の描画に nohidden3d オプションをつけるこ とで、それを hidden3d の処理から除外することができます。nohidden3d がマークされた曲面以外の個々の描画要素 (線分、点、ラベル等) は、通常は 他の何らかの描画要素で隠されてしまう場合も全て描画されます。
同様に、キーワード nocontours は、グローバルに set contour 指定が 有効な場合でも、個別の plot に対する等高線描画機能をオフにします。
同様に、キーワード nosurface は、グローバルに set surface 指定が有 効な場合でも、個別の plot に対する 3 次元曲面描画をオフにします。
キーワードは暗示するような形で省略可能です。
linewidth, pointsize, palette オプションは全ての端末装置でサポー トされているわけではないことに注意してください。
例:
以下は、sin(x) を鉛直線で描画します:
plot sin(x) with impulses
以下は、x を点で描画し、x**2 をデフォルトの方式で描画します:
plot x w points, x**2
以下は、tan(x) を関数のデフォルトの方式で、"data.1" を折れ線で描画します:
plot [ ] [-2:5] tan(x), 'data.1' with l
以下は、"leastsq.dat" を鉛直線で描画します:
plot 'leastsq.dat' w i
以下は、データファイル "population" を矩形で描画します:
plot 'population' with boxes
以下は、"exper.dat" をエラーバー付きの折れ線で描画します (エラーバーは3 列、あるいは 4 列のデータを必要とします):
plot 'exper.dat' w lines, 'exper.dat' notitle w errorbars
もう一つの "exper.dat" のエラーバー付きの折れ線 (errorlines) での描画
方法 (エラーバーは 3 列、あるいは 4 列のデータが必要):
plot 'exper.dat' w errorlines
以下は、sin(x) と cos(x) をマーカー付きの折れ線で描画します。折れ線は
同じ線種ですが、マーカーは異なったものを使います:
plot sin(x) with linesp lt 1 pt 3, cos(x) with linesp lt 1 pt 4
以下は、"data" を点種 3 で、点の大きさを通常の 2 倍で描画します:
plot 'data' with points pointtype 3 pointsize 2
以下は、"data" を描画しますが、4 列目から読んだデータを pointsize の値として使用します:
plot 'data' using 1:2:4 with points pt 5 pointsize variable
以下は、2 つのデータ集合に対して、幅のみ異なる線を用いて描画します:
plot 'd1' t "good" w l lt 2 lw 3, 'd2' t "bad" w l lt 2 lw 1
以下は、x*x の曲線の内部の塗りつぶしと色の帯を描画します:
plot x*x with filledcurve closed, 40 with filledcurve y=10
以下は、x*x の曲線と色の箱を描画します:
plot x*x, (x>=-5 && x<=5 ? 40 : 1/0) with filledcurve y=10 lt 8
以下は、滑らかに変化する色の線で曲面を描画します:
splot x*x-y*y with line palette
以下は、2 つの色のついた曲面を、異なる高さで表示します:
splot x*x-y*y with pm3d, x*x+y*y with pm3d at t
書式:
print <式> {, <式>, ...}
以下参照: expressions (15)。出力ファイルは set print で設定できます。 以下も参照: printerr (79)。
カレントディレクトリを文字列変数に保存したり、文字式の中で使いたい場合 は、変数 GPVAL_PWD を使うことができることに注意してください。以下参照:show variables all (88.88)。
raise {plot_window_nb}
コマンド raise (lower の反対) は、pm, win, wxt, x11 等の gnuplot の対話型出力形式の実行中に、描画ウィンドウを上 (前面) に上げま す。描画ウィンドウを、デスクトップ上のウィンドウマネージャの z 方向の ウィンドウの重なりの前 (上) に置きます。
x11 や wxt のように複数の描画ウィンドウをサポートしている場合、デ フォルトではこのコマンドはそれらの複数のウィンドウを降順に上げ、最初に 作られたウィンドウを一番下に、最後に作られたウィンドウを一番上に並べま す。オプション引数の描画番号が与えられた場合、それに対応する描画ウィン ドウが存在すればそれのみが上げられます。
オプション引数は、単一の描画ウィンドウの出力形式、すなわち pm と win では無視されます。
ウィンドウが X11 で前面に出ない場合、もしかすると描画ウィンドウは、異 なる X11 セッションで動作している (例えば telnet や ssh セッションなど によって) か、または前面に出すことがウィンドウマネージャの設定によって 防害されている可能性があります。
マウス操作、特にズームインとズームアウトでは、適切な場合は replot の 代わりにむしろ refresh を使用します。例:
plot 'datafile' volatile with lines, '-' with labels
100 200 "Special point"
e
# 色んなマウス操作をここで実行
set title "Zoomed in view"
set term post
set output 'zoom.ps'
refresh
replot コマンドに対する引数は最後に実行した plot または splot コマンドの引数に (暗黙の ',' と共に) 追加され、それから再実行されます。 replot は、範囲 (range) を除いては、plot や splot と同じ引数を とることができます。よって、直前のコマンドが splot ではなく plot の場合は、関数をもう一つの軸刻みでプロットするのに replot を使うこと ができます。
注意:
plot '-' ; ... ; replot
という使い方は推奨されません。それは、これがあなたに再び同じデータすべ ての入力を要求することになるからです。たいていの場合、代わりにコマンド refresh を使えます。これは、以前に読み込んだデータを使ってグラフを再描画します。
multiplot モードでは、replot コマンドはすべての plot ではなく、直 前の plot 部分だけしか再実行しないことに注意してください。
最後に実行した plot (splot) コマンドの内容を修正する方法については 以下も参照: command-line-editing (9)。
直前の描画コマンドの全体を表示させることや、それを history の中に コピーする方法については、以下も参照: show plot (88.60)。
例:
ファイル "looper" が次のようなファイルで
a=a+1
plot sin(x*a)
pause -1
if(a<5) reread
a=0
load 'looper'
ファイル "data" が、各行に、0 から 10 までの範囲 (yrange) の 6 つのデ
ータ を持ち、最初が x 座標で、その他は 5 つの異なる関数の、その x での
値であるとします。そして、ファイル "plotter" が
c_p = c_p+1
plot "$0" using 1:c_p with lines linetype c_p
if(c_p < n_p) reread
n_p=6
c_p=1
unset key
set yrange [0:10]
set multiplot
call 'plotter' 'data'
unset multiplot
以下のものは、reset の影響を受けません。
`set term` `set output` `set loadpath` `set fontpath` `set linetype`
`set encoding` `set decimalsign` `set locale` `set psdir` `set fit`
reset は、必ずしもプログラム立ち上がった初期状態には戻さないことに注 意してください。それは、初期設定ファイル gnuplotrc や $HOME/.gnuplot 内のコマンドでデフォルトの値を変更した場合は、それもリセットされてしま うからです。しかし reset session とすれば、それらのコマンドも再実行 します。
reset session は、ユーザ定義変数、ユーザ定義関数すべてを削除し、デフ ォルトの設定を復帰し、システム全体の初期設定ファイル gnuplotrc と個人 用の初期設定ファイル $HOME/.gnuplot を再実行します。以下参照:initialization (24)。
reset errors は、エラー状態変数 GPVAL_ERRNO と GPVAL_ERRMSG のみをク リアします。
reset bind は、キー定義をデフォルトの状態に復帰します。
書式:
save {<オプション>} '<ファイル名>'
ここで、< オプション> は、functions, variables, terminal, set のいずれかです。どれも指定されなかった場合には、gnuplot は、ユーザ定 義関数、変数、set で設定するオプション、最後に実行した plot (または splot) コマンドの全てを保存します。
save は、テキスト形式で出力します。また、このファイルは load コマ ンドで読み込むことができます。set オプション付き、または何もオプショ ンをつけずに save を実行した場合、terminal の選択と output のフ ァイル名はコメント記号つきで書き出されます。これはその出力ファイルを 他の環境にインストールされた gnuplot 上で動かす場合に、修正なしに使え るようにする、あるいはうっかりファイルを上書きしてしまったりする危険性 を避ける、といった意味があります。
save terminal は、terminal の状態を、コメント記号をつけずに書き出 します。これは主に、ちょっとの間だけ terminal の設定を入れ替え、その 後保存しておいた terminal の状態を読み込むことで以前の terminal の設定に戻す場合などに役立ちます。ただ、単一の gnuplot セッションでは、現 在の terminal を保存/復元する他の方法であるコマンド set term push と set term pop を使う方がむしろいいかもしれません。以下参照:set term (88.77)。
ファイル名は引用符に囲われていなければなりません。
特別なファイル名 "-" により save コマンドに標準出力に出力させること ができます。popen 関数をサポートするようなシステム (Unix など) では、 save の出力をパイプ経由で他の外部プログラムに渡すことができます。その 場合、ファイル名としてコマンド名の先頭に '| ' をつけたものを使います。 これは、gnuplot とパイプを通して通信するプログラムに、gnuplot の内 部設定に関する首尾一貫したインターフェースを提供します。詳細は、以下参照: batch/interactive (7)。
例:
save 'work.gnu'
save functions 'func.dat'
save var 'var.dat'
save set 'options.dat'
save term 'myterm.gnu'
save '-'
save '|grep title >t.gp'
show コマンドはそれらの設定値を表示します。show all でそれら全て を表示します。
set コマンドで変更されたオプションは、それに対応する unset コマン ドを実行することでデフォルトの状態に戻すことができます。以下も参照:reset (86)。これは全てのパラメータの設定をデフォルトの値に戻します。
set と unset コマンドには繰り返し節も利用できます。以下参照:plot for (77.10)。
書式:
set angles {degrees | radians}
show angles
set grid polar で指定される角度も、set angles で指定した単位で読まれ 表示されます。
set angles は組み込み関数 sin(x), cos(x), tan(x) の引数や asin(x), acos(x), atan8x), atan2(x), arg(x) の出力にも影響を与えます。双曲線関 数や、ベッセル関数の引数には影響を与えません。しかし、複素数を引数とす る逆双曲線関数の出力には影響が出ます。それらの関数が使われるときは、 set angles radians は入出力の引数の間に一貫性を持った管理を実現して いなければなりません。
x={1.0,0.1}
set angles radians
y=sinh(x)
print y #{1.16933, 0.154051} と表示
print asinh(y) #{1.0, 0.1} と表示
set angles degrees
y=sinh(x)
print y #{1.16933, 0.154051} と表示
print asinh(y) #{57.29578, 5.729578} と表示
poldat.dem: set angles を用いた極座標描画のデモ
書式:
set arrow {<tag>} from <position> to <position>
set arrow {<tag>} from <position> rto <position>
set arrow {<tag>} from <position> length <coord> angle <ang>
set arrow <tag> arrowstyle | as <arrow_style>
set arrow <tag> {nohead | head | backhead | heads}
{size <headlength>,<headangle>{,<backangle>}}
{filled | empty | nofilled | noborder}
{front | back}
{linestyle <line_style>}
{linetype <line_type>} {linewidth <line_width>}
{linecolor <colorspec>} {dashtype <dashtype>}
unset arrow {<tag>}
show arrow {<tag>}
タグ < tag> は各矢印を識別する整数です。タグを指定しない場合は、その時 点で未使用の最も小さい数が自動的に割り当てられます。タグを使うことで、 特定の矢印を変更したり、削除したりできます。既に存在する矢印の属性を変 更する場合は、タグを明示した set arrow コマンドで変更箇所を指定して ください。
矢印の最初の端点の位置は、常に "from" で指定しますが、もう一つの端点は 以下で説明する 3 つの異なる仕組みのいずれかで指定できます。< position> は x,y あるいは x,y,z で指定します。そしてその前に座標系を選択するた めに first, second, graph, screen, character を置くことがで きます。座標を指定しなければデフォルトでは 0 と見なされます。詳細は以下参照: coordinates (11)。最初の端点に対する座標指定子は、2 番目の端点に は影響しません。
1) "to < position> " は、もう一つの端点の絶対座標を指定します。
2) "rto < position> " は、"from" の位置からのずれを指定します。この場合、 線形軸 (非対数軸)、および graph, screen 座標に対しては、始点と終点 の距離が与えられた相対的な値に対応します。一方、対数軸に対しては、与え られた相対的な値は、始点から終点への倍数に対応します。よって、対数軸の 場合、相対的な値として 0 や負の値を与えることは許されません。
3) "length < coordinate> angle < angle> " は、グラフ平面内での矢印の方向 を指定します。length には任意の座標系を適用できます。angle の単位は常 に度になっています。
矢印の他の属性も、あらかじめ定義した矢のスタイルで、またはコマンド set arrow でそれぞれ与えることが可能です。矢印の他の属性の詳細につい ては以下参照: arrowstyle (88.74.1)。
例:
原点から (1,2) への矢印をユーザ定義済のラインスタイル 5 で描くには:
set arrow to 1,2 ls 5
描画領域の左下角から (-5,5,3) へタグ番号 3 の矢印を描くには:
set arrow 3 from graph 0,0 to -5,5,3
矢印の端を 1,1,1 に変更し、矢先を外して幅を 2 にするには:
set arrow 3 to 1,1,1 nohead lw 2
x=3 の所へグラフの下から上まで鉛直線を描くには:
set arrow from 3, graph 0 to 3, graph 1 nohead
T 字型の矢先を両端に持つ鉛直方向の矢を描くには:
set arrow 3 from 0,-5 to 0,5 heads size screen 0.1,90
始点からの相対的な距離をグラフ座標で与えて矢を描くには:
set arrow from 0,-5 rto graph 0.1,0.1
x の対数軸に相対的な終点を指定して矢を描く場合:
set logscale x
set arrow from 100,-5 rto 10,10
2 番の矢印を消すには:
unset arrow 2
全ての矢印を消すには:
unset arrow
全ての矢印の情報を (タグの順に) 見るには:
show arrow
書式:
set autoscale {<axes>{|min|max|fixmin|fixmax|fix} | fix | keepfix}
set autoscale noextend
unset autoscale {<axes>}
show autoscale
ここで、< axes> (軸) は x, y, z, cb, x2, y2, xy のいずれ かです。min または max を軸に追加指定すると (xy では使えませんが) それは gnuplot にその軸の最小値、または最大値のみを自動縮尺させるこ とになります。軸も何も指定されていない場合は全ての軸が対象となります。
デフォルトでは、自動縮尺機能は軸の範囲の限界を、描画データ全体を含む、
最も近い目盛りラベル位置に設定します。キーワード fixmin, fixmax,
fix, noextend は、次の目盛り位置までの範囲の自動拡大を gnuplot に
行わせないようにします。その場合軸の範囲の限界は、一番端にあるデータ点
の座標値に完全に一致します。set autoscale noextend は、
set autscale fix と同じです。軸の範囲指定コマンドの後ろにキーワード
noextend を追加すれば、一つの軸の範囲の延長機能だけ無効にすることも
できます。例:
set yrange [0:*] noextend
set autoscale keepfix は、fix の設定を変更せずに残したまま、すべての 軸を自動縮尺にします。
自動縮尺機能を使うときは、描画範囲は自動的に割り出され、従属変数軸(plot のときは y 軸、splot のときは z 軸) は、関数やデータの値域が 収まるように設定されます。
従属変数軸 (y または z) の自動縮尺機能が指定されていない場合は、現在の y や z の描画範囲がそのまま使われます。
独立変数軸 (plot のときは x 軸、splot のときは x,y 軸) の自動縮尺 機能が指定されている場合は、描画される全てのデータファイルの点が収まる ように定義域をとるようになります。データファイルが 1 つも指定されてい ない場合は、自動縮尺機能はなんの効果もありません。つまり、関数のみが 指定されていてデーターファイルを使わない場合は、x 軸の描画範囲 (z = f(x,y) を描画しているときは y 軸も) は影響をうけません。
範囲に関するより詳しい情報に関しては、以下参照: set xrange (88.103)。
媒介変数モード (parametric) でも自動縮尺機能は有効です (以下参照:set parametric (88.58))。この場合、より多くの従属変数があるので、x, y, z 各軸に関して、より多くの制御が行われます。媒介変数モードでの独立変数 (仮 変数) は plot では t で splot では u, v です。そして媒介変数モード では、自動縮尺機能は (t, u, v, x, y, z) の全ての描画範囲を制御し、x, y, z の範囲の自動設定を完全に行います。
自動縮尺機能は、極座標モード (polar mode) でも plot の媒介変数モード と同様に機能しますが、極座標モードでは set dummy で独立変数を t から 変更するできる (以下参照: set dummy (88.23)) という拡張があります。
目盛りが第 2 の軸に表示され、しかもこれらの軸に対する描画が行われなか った場合には、x2range と y2range は xrange と yrange の値を受け継ぎま す。これは、範囲のずらしの実行や、範囲を整数個の目盛り幅に自動伸縮する 「前」に行いますので、場合によって予期しない結果をもたらす可能性があり ます。これを避けるのに、第 2 軸の範囲を第 1 軸の範囲に明示的にリンク (link) する方法があります。以下参照: set link (88.38)。
例:
以下は y 軸の自動縮尺機能を指定します (他の軸には影響を与えません):
set autoscale y
以下は y 軸の最小値に対してのみ自動縮尺機能を指定します (y 軸の最大値、および他の軸には影響を与えません):
set autoscale ymin
以下は x2 軸の隣の目盛りへの自動範囲拡大機能を無効にし、よって描画データ内、または関数に対する丁度の描画範囲を維持します:
set autoscale x2fixmin
set autoscale x2fixmax
以下は x, y 両軸の自動縮尺機能を指定します:
set autoscale xy
以下は x, y, z, x2, y2 全軸の自動縮尺機能を指定します:
set autoscale
以下は x, y, z, x2, y2 全軸の自動縮尺機能を禁止します:
unset autoscale
以下は z 軸のみについて自動縮尺機能を禁止します:
unset autoscale z
データファイルは媒介変数モードでもそうでない状態でも同様に描画され ます。しかし、データファイルと関数が混在している場合には、違いがあ ります: 媒介変数モードでなければ、x の自動縮尺機能は、関数の範囲を データの描画範囲に合わせます。しかし媒介変数モードではデータの範囲 は関数の範囲に影響しません。
それには、片手落ちにならないように set autoscale t というコマンド も用意されています。しかしその効果は非常に小さいものです。自動縮尺 機能が設定されていると、gnuplot が t の範囲が無くなってしまうと 判断した場合に範囲を少し調整します。自動縮尺機能が設定されていないと このようなときにはエラーとなります。このような動作は実はあまり意味が なく、よって set autoscale t というコマンドは存在意義に疑問があり ます。
splot では上記の発想の元に拡張されています。自動縮尺機能が設定され ている場合、x, y, z の各描画範囲は計算結果が収まるように設定され縮尺 調整されます。
1 つ、あるいは 2 つの範囲は明示的に設定してその他のものを指定しない場合は 予期しない結果を引き起こすかも知れません。 以下も参照
書式:
set bars {small | large | fullwidth | <size>} {front | back}
unset bars
show bars
small は 0.0, large は 1.0 と同じです。サイズを指定しなければデフォ ルトの値は 1.0 です。
キーワード fullwidth は、errorbar を伴う boxplot と histograms にの み関連します。これは errorbar の両端の幅を、対応する箱の幅と同じに設定 しますが、箱の幅自体を変更することはありません。
キーワード front, back は、塗り潰し長方形のついた errorbar のみに 関連します (boxes, candlesticks, histograms)。
書式:
set border {<integer>}
{front | back | behind} {linewidth | lw <line_width>}
{{linestyle | ls <line_style>} | {linetype | lt <line_type>}}
unset border
show border
set view 56,103 のように任意の方向で表示されうる splot では、 x-y 平面上の 4 つの角は 手前 (front), 後ろ (back) , 左 (left), 右 (right) のように呼ばれます。もちろんこの同じ 4 つの角は天井の面にも あります。よって、例えば x-y 平面上の後ろと右の角をつなぐ境界を "底の右後ろ (bottom right back)" と言い、底と天井の手前の角をつなぐ境 界を "鉛直手前 (front vertical)" と呼ぶことにします (この命名法は、読 者が下の表を理解するためだけに使われます)。
枠は、12 ビットの整数に符号化されています: 下位 4 ビットは plot に対 する外枠、splot に対しては底面の外枠、次の 4 ビットは splot の鉛直 な外枠、そして上位 4 ビットは splot の天井面の外枠を制御します。よっ て外枠の設定は、次の表の対応する項目の数字の和になります:
| グラフ境界の符号化 | ||
| ビット | plot | splot |
| 1 | 下 | 底の左手前 |
| 2 | 左 | 底の左後ろ |
| 4 | 上 | 底の右手前 |
| 8 | 右 | 底の右後ろ |
| 16 | 効果なし | 鉛直左 |
| 32 | 効果なし | 鉛直後ろ |
| 64 | 効果なし | 鉛直右 |
| 128 | 効果なし | 鉛直の手前 |
| 256 | 効果なし | 天井の左後ろ |
| 512 | 効果なし | 天井の右後ろ |
| 1024 | 効果なし | 天井の左手前 |
| 2048 | 効果なし | 天井の右手前 |
デフォルトの設定値は 31 で、これは plot では 4 方向の外枠全て、 splot では底面の枠線全部と z 軸を描くことを意味します。
2 次元描画では境界はすべての描画要素の一番上に描かれます (front)。 もし境界を描画要素の下に描かせたい場合は、set border back としてくだ さい。
3 次元隠線処理 (hidden3d) 描画では、通常は境界を構成する線も描画要素と 同様に隠線処理の対象になります。set border behind とするとこのデフォ ルトの挙動が変わります。
< line_style> , < line_type> , < line_width> を指定して、枠線の描画にそれ らを反映させることができます (現在の出力装置がサポートするものに限定 されます)。
plot では、第 2 軸を有効にすることで、下と左以外の境界に目盛りを描くことができます。詳細は、以下参照: xtics (88.104)。
"unset surface; set contour base" などによって splot で底面にのみ 描画する場合、鉛直線や天井はそれらが指定されていても描画されません。
set grid のオプション 'back', 'front', 'layerdefault' でも、描画出力 の境界線を書く順番を制御できます。
例:
以下は、デフォルトの枠線を描きます:
set border
以下は、plot では左と下、splot では底面の左手前と左後ろの枠線を描きます:
set border 3
以下は、splot で周りに完全な箱を描きます:
set border 4095
以下は、手前の鉛直面と天井のない箱を描きます:
set border 127+256+512 # または set border 1023-128
以下は、plot に対して上と右枠線のみを描き、それらを軸として目盛りづけします:
unset xtics; unset ytics; set x2tics; set y2tics; set border 12
書式:
set boxwidth {<width>} {absolute|relative}
show boxwidth
デフォルトでは、隣り合う棒が接するように各々の棒の幅が広げられます。そ れとは異なるデフォルトの幅を設定するには set boxwidth コマンドを使用 します。relative の場合の幅は、デフォルトの幅に対する比であると解釈 されます。
修飾子 relative を指定しなかった場合、棒の幅 (boxwidth) として指定さ れた明示的な値は、現在の x 軸の単位での数字 (absolute) であると解釈 されます。x 軸が対数軸 (以下参照: set log (88.42)) である場合、boxwidth の値 は実際には x=1 でのみ "絶対的" となり、その物理的な長さが軸全体を通じ て保持されます (すなわち、棒は x 座標の増加にともなって狭くなったりは しません)。対数軸の x 軸の範囲が x=1 から離れている場合は、適切な幅を 見出すには何度か試してみる必要があるかも知れません。
デフォルトの値は、boxes や boxerrorbars スタイルの幅指定用の追加の データ列の明示的な値があればそれによって置き換えられます。4 列のデータ の場合、第 4 列目の値が棒の幅として使われます。ただし、その幅が -2.0 の場合には棒の幅は自動計算されます。詳細は、以下参照: style boxes (30),style boxerrorbars (29)。
棒の幅を自動的にセットするには
set boxwidth
とする、あるいは 4 列のデータに対しては以下のようにします。
set boxwidth -2
plot のキーワード using を使っても同じ効果を得ることができます:
plot 'file' using 1:2:3:4:(-2)
棒の幅を自動的な値の半分にするには
set boxwidth 0.5 relative
棒の幅を絶対的な値 2 にするには
set boxwidth 2 absolute
set colorsequence {default|classic|podo}
set colorsequence default は、出力形式に依存しない 8 色の巡回列を選 択します。以下参照: set linetype (88.37), colors (19)。
set colorsequence classic は、出力形式別にそのドライバが用意する線色の列を選択します。色の種類は、4 色から 100 色超まで幅がありますが、そ の多くは、赤、緑、青、紫、水色、黄色、で始まります。これが以前の版のgnuplot のデフォルトの挙動です。
set colorsequence podo は、Wong (2011) [Nature Methods 8:441] で推奨 されている、P 型、D 型 (Protanopia, Deuteranopia) の色弱者が容易に区別 できる 8 色の組を選択します。
いずれの場合でも、色列の長さとその色についてはさらにカスタマイズできま す。以下参照: set linetype (88.37), colors (19)。
set clip {points|one|two}
unset clip {points|one|two}
show clip
デフォルトの状態:
unset clip points
set clip one
unset clip two
グラフ領域の境界内に中心があるデータ点は、その点を表す記号のサイズがそ の記号を境界線の外にはみだしてしまうような場合でも、通常は描画します。 set clip points は、2 次元描画でそのような点の中心がグラフ領域内にあ る場合でも、そのような点をクリッピングします (つまり描画しません)。点 の中心がグラフ領域外にあるようなデータ点は、決して描画しません。
線分については、その一方の端点が描画範囲 (xrange と yrange) の外にある 場合は、通常その線分は描画しません。 set clip one は、一方の端点が描画範囲の外にある線分の範囲内の部分を 描画するように gnuplot に指示します。 set clip two は、両方の端点が描画範囲の外にある線分の範囲内の部分を 描画するように gnuplot に指示します。 線分全体が描画範囲外であるような線分は決して描画しません。
注意:
* set clip は、描画スタイル lines, linespoints, points, vectors で生成される点、線分のみに影響します。
* pm3d の 2 次元射影や曲面で使用する色長方形のクリッピングは、 set pm3d clip1in と set pm3d clip4in で行います。
* オブジェクトのクリッピングは、個々のオブジェクト (object) の {clip| noclip} 属性で制御します。
set cntrlabel {format "format"} {font "font"}
set cntrlabel {start <int>} {interval <int>}
set contrlabel onecolor
set cntrlabel は、凡例内 (デフォルト) か、splot ... with labels の
際のグラフ上の等高線のラベルを制御します。後者の場合、ラベルはラベル記
述属性の "pointinterval" に従って各等高線に沿って配置されます。デフォ
ルトではラベルは等高線を構成する 5 番目の線分の上に置かれ、20 個の線分
毎に繰り返されます。
このデフォルトは、以下と同じです:
set cntrlabel start 5 interval 20
set contours; splot $FOO with labels point pointinterval -1
凡例 (key) には、等高線ラベルをそれぞれの線種 (linetype) を使用して書 きます。デフォルトでは、線種自身が各等高線のレベルを与えるので、それぞ れに対する別々のラベルが現れます。コマンド set cntrlabel onecolor は すべての等高線を同じ線種で描画するので、凡例には一つのラベルのみを書き ます。このコマンドは、古いコマンド unset clabel を置き換えるものです。
書式:
set cntrparam { { linear
| cubicspline
| bspline
| points <n>
| order <n>
| levels { auto {<n>} | <n>
| discrete <z1> {,<z2>{,<z3>...}}
| incremental <start>, <incr> {,<end>}
}
}
}
show contour
このコマンドは 2 つの機能を持っています。一つは等高線上の点 (データ点 の線形補間、あるいは関数の標本化 (isosample) による点) での z の値の設 定で、もう一つは、そのように決定された z が等しい点同士を等高線で結ぶ 方法の制御です。< n> は整数型の定数式、< z1> , < z2> ... は任意の定数式で す。各オプション変数の意味は次の通りです:
linear, cubicspline, bspline -- 近似 (補間) 方法を指定します。 linear ならば、等高線は曲面から得られた値を区分的に直線で結びます。 cubicspline (3 次スプライン) ならば、区分的な直線はいくぶんなめらか な等高線が得られるように補間されますが、多少波打つ可能性があります。 bspline (B-spline) は、より滑らかな曲線を描くことが保証されますが、 これは z の等しい点の位置を近似しているだけです。
points -- 最終的には、全ての描画は、区分的な直線で行われます。ここ で指定する数は、bspline または cubicspline での近似に使われる線分 の数を制御します。実際には cubicspline と bspline の区間 (曲線線分) の 数は points と線分の数の積に等しくなります。
order -- bspline 近似の次数です。この次数が大きくなるにつれて、等高 線はなめらかになります (もちろん、高次の bspline 曲線になるほど、元の 区分的直線からは離れていきます)。このオプションは bspline モードでの み有効です。指定できる値は、2 (直線) から 10 までの整数です。
levels -- 等高線のレベルの数は、auto (デフォルト), discrete, incremental と等高線のレベル数 < n> で制御します。
auto では、< n> は仮のレベルの数であり、実際のレベルの数は、簡単なラ ベルを生成するように調節されます。曲面の z 座標が zmin から zman の範 囲にあるとき、等高線はその間の dz の整数倍になるように生成されます。こ こで、dz は 10 のあるべき乗の 1, 2, 5 倍、のいずれかです (2 つの目盛り の間を丁度割り切るように)。
levels discrete では、等高線は指定された z = < z1> , < z2> ... に対して 生成されます。指定した個数が等高線のレベルの個数となります。discrete モードでは、set cntrparams levels < n> という指定は常に無視されます。
incremental では、等高線は z = < start> から始まり、< increment> ずつ 増えて行き限界の個数に達するまで書かれます。< end> はその等高線の数を決 定するのに使われますが、これは後の set cntrparam levels < n> によって 常に変更されます。z 軸が対数軸の場合、set ztics の場合と同様に、 < increment> は倍数として解釈されます。
コマンド set cntrparam が引数なしに呼ばれた場合は、次のデフォルトの 値が使われます: linear, 5 points, order 4, 5 auto levels
例:
set cntrparam bspline
set cntrparam points 7
set cntrparam order 10
以下はレベルの基準が合えば 5 個のレベルがに自動的に選択されます:
set cntrparam levels auto 5
以下は .1, .37, .9 にレベルを設定します:
set cntrparam levels discrete .1,1/exp(1),.9
以下は 0 から 4 まで、1 ずつ増やすレベルを設定します:
set cntrparam levels incremental 0,1,4
以下はレベルの数を 10 に設定します (増加の最後の値 (end) または自動で
設定されるレベルの数は変更されます):
set cntrparam levels 10
以下はレベルの数は保持したままレベルの開始値と増分値を設定します:
set cntrparam levels incremental 100,50
等高線を描く場所の制御に関しては、以下参照: set contour (88.17)。等高線のラ ベルの書式と線種の制御に関しては、以下参照: set cntrlabel (88.13)。
以下も参照してください。
および
ユーザ定義レベルの等高線のデモ (discrete.dem).
色の一覧表、すなわち pm3d の palette の min_z から max_z までの滑 らかな色の勾配は、unset colorbox が使われていない限りカラーボックス (colorbox) に描かれます。
set colorbox
set colorbox {
{ vertical | horizontal }
{ default | user }
{ origin x, y }
{ size x, y }
{ front | back }
{ noborder | bdefault | border [line style] }
}
show colorbox
unset colorbox
カラーボックスの位置は、default または user で指定でき、後者の場合 その位置や大きさを origin や size コマンドで設定します。カラーボッ クスは、グラフや曲面の後 (front) あるいは先 (back) に描画させるこ ともできます。
色勾配の方向は、オプション vertical と horizontal で切替えることが 可能です。
origin x, y と size x, y は user オプションとの組でのみ使用され
ます。x, y の値は、デフォルトではスクリーン座標と解釈されますが、これ
は 3 次元描画用のかしこまったオプションに過ぎません。set view map に
よる splot を含む 2 次元描画では、任意の座標系での指定が可能です。例え
ば以下を試してみてください:
set colorbox horiz user origin .1,.02 size .8,.04
border は境界描画を ON にします (デフォルト) し、noborder は境界描
画を OFF にします。border の後ろに正の整数を与えると、それを境界を描
画する時の line style のタグとして使います。例えば:
set style line 2604 linetype -1 linewidth .4 set colorbox border 2604
カラーボックスの軸は cb と呼ばれ、通常の軸のコマンドで制御されます。 すなわち set/unset/show で cbrange, [m]cbtics, format cb, grid [m]cb, cblabel などが、そして多分 cbdata, [no]cbdtics, [no]cbmtics なども使えるでしょう。
パラメータ無しの set colorbox はデフォルトの位置へ切替えます。 unset colorbox はカラーボックスのパラメータをデフォルト値にリセット し、その上でカラーボックスを OFF にします。
以下も参照: set pm3d (88.61), set palette (88.62), x11 pm3d (98.68.6), set style line (88.74.7)。
set style line 1 linecolor "sea-green"
書式:
set contour {base | surface | both}
unset contour
show contour
これらの 3 つのオプションは等高線をどこに引くかを指定します。base で は等高線を x/y 軸の刻みのある底面に描かれ、surface では等高線はその 曲面自体の上に描かれ、both では底面と曲面上の両方に描かれます。オプ ションが指定されていない場合は base であると仮定されます。
等高線の描画に影響を与えるパラメータについては、以下参照:set cntrparam (88.14)。等高線のラベルの制御に関しては、以下参照:set cntrlabel (88.13)。
等高線のみのグラフを得るために、曲面自身の描画をしないようにすることも できます (以下参照: unset surface (88.75))。set size を使って、グラフを画 面一杯に描画することも可能ですが、そういった出力形式よりも、等高線のデ ータをデータブロックに書き出し、それを再び 2 次元データとして読み込ん で描画すればよりよい制御が可能になります:
unset surface
set contour
set cntrparam ...
set table $datablock
splot ...
unset table
# 等高線の情報は今 $datablock の中にある
set term <whatever>
plot $datablock
等高線を描くためには、データは格子状データ ("grid data") である必要が あります。そのようなファイルでは、一つの y-孤立線上の全ての点が順に 並べられていきます。そして隣の y-孤立線上の点が順に並べられ、そして隣、 と続いていきます。y-孤立線同士を分離するには一行の空行 (空白、復帰、改 行以外の文字を含まない行) を挟みます。以下参照: splot datafile (90.1)。
以下も参照してください。
および
ユーザ定義レベルの等高線のデモ (discrete.dem).
set dashtype 5 (2,4,2,6) # 5 番の dashtype を定義または再定義
plot f1(x) dt 5 # その dashtype を使って plot
plot f1(x) dt (2,4,2,6) # 上と全く同じグラフ
set linetype 5 dt 5 # このパターンを linetype 5 で常に使う
set dashtype 66 "..-" # 文字列で新しい dashtype を定義
書式:
set datafile missing "<string>"
show datafile missing
unset datafile
注意: このバージョンの gnuplot では、ある場合の処理の方法が変更され ています。以下の例でその違いを示します。
set style data linespoints
plot '-' title "(a)"
1 10
2 20
3 ?
4 40
5 50
e
set datafile missing "?"
plot '-' title "(b)"
1 10
2 20
3 ?
4 40
5 50
e
plot '-' using 1:2 title "(c)"
1 10
2 20
3 NaN
4 40
5 50
e
plot '-' using 1:($2) title "(d)"
1 10
2 20
3 NaN
4 40
5 50
e
(a) のグラフは、3 行目に 1 つ無効値があるため、バージョン間の違いがあ ります。古い版の gnuplot では、そこに 1 行に 1 つしかデータがなかった 場合の規則を適用し、行番号を "x" に、データを "y" と見なし、誤ってその 点を (2,3) に描画していました。
文字 '?' が欠損データを意味するものとして指定されている (b) では、古い 版の gnuplot でも新しい版でも同じデータを正しく処理します。
(c), (d) のグラフに見られるように、古い gnuplot では NaN を using の指 定の仕方によって異なった処理をしていました。現在は、gnuplot は入力列と して N と指定されていても ($N) と指定されていても NaN に対しては同じ処 理を行います。以下のデモも参照してください。
書式:
set datafile separator {whitespace | tab | comma | "<chars>"}
例:
# タブ区切りのファイルを入力
set datafile separator "\t"
# コンマ区切りのファイルを入力
set datafile separator comma
# 入力ファイルが * か | のいずれかで区切られた列を持つ場合
set datafile separator "*|"
書式:
set datafile commentschars {"<string>"}
show datafile commentschars
unset commentschars
よって、データファイルの以下の行は完全に無視されます:
# 1 2 3 4
1 # 3 4
set datafile missing '#'
例:
set datafile commentschars "#!%"
書式:
set datafile binary <binary list>
show datafile binary
show datafile
unset datafile
例:
set datafile binary filetype=auto
set datafile binary array=(512,512) format="%uchar"
show datafile binary # 現在の設定の一覧表示
書式:
set decimalsign {<value> | locale {"<locale>"}}
unset decimalsign
show decimalsign
引数 < value> は、通常の小数点記号に置き換えて使う文字列です。典型的な ものはピリオド '.' やコンマ ',' ですが他にも有用なものがあるでしょう。 引数 < value> を省略すると、小数点の区切りはデフォルト (ピリオド) から 変更されません。unset decimalsign も < value> を省略するのと同じ効果を 持ちます。
例:
多くのヨーロッパ諸国での正しい出力形式を得るには:
set decimalsign ','
次のことに注意してください: 明示的な文字列を設定した場合、これは軸の目 盛りなどの gnuplot の gprintf() 書式関数で出力される数値のみに影響し、 入力データの書式指定や sprintf() 書式関数で出力される数値には影響しま せん。それらの入力や出力の形式の挙動も変更したい場合は、代わりに以下を使用してください:
set decimalsign locale
これは、gnuplot に、入力と出力の書式を、環境変数 LC_ALL, LC_NUMERIC, LANG の現在の設定に従ったものを使わせるようにします。
set decimalsign locale "foo"
これは、gnuplot に、入力と出力の書式を、ロケール "foo" に従ったものに しますが、そのロケールがインストールされている必要があります。もしロケ ール "foo" が見つからなかった場合、エラーメッセージが出力され、小数点 の設定は変更されません。linux システム上では、そこにインストールされて いるロケールの一覧は "locale -a" で見ることができます。linux のロケー ル文字列はだいたい "sl_SI.UTF-8" のような形式をしていますが、Windows のロケール文字列は "Slovenian_Slovenia.1250"、または "slovenian" のよ うな形式です。ロケール文字列の解釈は、C のランタイムライブラリが行うこ とに注意してください。古い C ライブラリでは、ロケール設定のサポート (例えば数字の 3 桁毎の区切り文字など) を部分的にしか提供していないかも しれません。
set decimalsign locale; set decimalsign "."
これは、現在のロケールに合ったどんな小数点でも、全ての入出力に対して使 用するように設定しますが、gnuplot の内部関数 gprintf() を使って書式化 する数値は明示的に指定された '.' になります (上書き)。
書式:
set dgrid3d {<rows>} {,{<cols>}}
{ splines |
qnorm {<norm>} |
(gauss | cauchy | exp | box | hann)
{kdensity} {<dx>} {,<dy>} }
unset dgrid3d
show dgrid3d
デフォルトでは dgrid3d は無効になっています。有効になると、ファイル から読み込まれる 3 次元のデータは「散在した」データ (非格子状データ) であると見なされます。格子は、グラフと等高線の描画のために、散在したデ ータを囲む矩形から得られる寸法と、row_size/col_size で指定される数の行 と列を持つように生成されます。格子は x 方向 (行) と y 方向 (列) に等間 隔です。z の値は散在するデータの z の値の重み付きの平均、またはスプラ イン補間として計算されます。言い変えれば、規則的な間隔の格子が生成され、 全ての格子点で元のデータの滑かな近似値が評価されます。元のデータの代わ りにこの近似値が描画されます。
デフォルトの列の数は行の数に等しく、そのデフォルトの値は 10 です。
元のデータから近似値を計算するためのいくつかのアルゴリズムが用意されて いて、追加のパラメータを指定できるものもあります。これらの補間は、格子 点に近いデータ点ほど、その格子点に対してより強い影響を与えます。
splines アルゴリズムは、"薄いつぎ板" を元にした補間計算を行います。 これは追加パラメータを取りません。
qnorm アルゴリズムは各格子点で入力データの重み付き平均を計算します。
各点は格子点からの距離の norm 乗の逆数で重み付けされます。(実際には、
dx, dy を各データ点と格子点との差の成分であるとすると、重みは dx^norm
+ dy^norm で与えられます。2 のべきのノルム、特に 4, 8, 16 に関しては、
その重みの計算はユークリッド距離を使うことで (dx^2+dy^2)^norm/2 のよう
に最適化されてますが、任意の負でない整数を使うことも可能です。) ノルム
のべきの値をただ一つの追加パラメータとして指定できます。このアルゴリズ
ムがデフォルトになっています。
最後に、重み付き平均の計算用に、いくつかの平滑化重み付け関数 (kernel) が用意されています: z = Sum_i w(d_i) * z_i / Sum_i w(d_i), ここで z_i は i 番目のデータの値で、d_i は現在の格子点と i 番目のデータ点の位置と の距離です。すべての重み付け関数が、現在の格子点に近い方のデータ点には 大きな重み、遠い方のデータ点には小さい重みを付けます。
以下の重み付け関数が使用できます:
gauss : w(d) = exp(-d*d)
cauchy : w(d) = 1/(1 + d*d)
exp : w(d) = exp(-d)
box : w(d) = 1 d<1 の場合
= 0 その他
hann : w(d) = 0.5*(1-cos(2*pi*d)) d<1 の場合
w(d) = 0 その他
これら 5 つの平滑化重み付け関数のうち一つを使用する場合、2 つまでの追 加パラメータ dx と dy を指定できます。これらは、距離の計算時に座標の違 いをスケール変換するのに使えます: d_i = sqrt( ((x-x_i)/dx)**2 + ((y-y_i)/dy)**2 ), ここで、x,y は現在の 格子点の座標で、x_i,y_i は i 番目のデータ点の座標です。dy のデフォルト の値は dx で、そのデフォルトの値は 1 になっています。パラメータ dx と dy は、データ点が格子点へ「データそれ自身の単位で」の寄与を行う範囲の 制御を可能にします。
オプションキーワード kdensity は、重み付け関数名の後ろで (オプション の) スケール変換のパラメータの前に置くもので、これはアルゴリズムを変更 して、格子点用に計算する値を重みの和 ( z = Sum_i w(d_i) * z_i ) では割 らないようにします。z_i がすべて定数の場合、これは事実上 2 変数の重み 付け評価を描画します: (上の 5 つのうちの一つの) 重み付け関数が各データ 点に置かれ、それらの重みの和がすべての格子点で評価され、そして元のデー タの代わりにこの滑らかな曲面が描画されます。これは、1 次元のデータ集合 に対する smooth kdensity オプションが行うこととおおまかには同じです (使用例は kdensity2d.dem を参照してください)。
後方互換性のために、わずかに異なる書式もサポートされています。どのアル ゴリズムも明示的に選択しなかった場合、qnorm アルゴリズムが仮定され、 3 つ以下の、コンマ (,) 区切りのオプションパラメータを指定した場合は、 それらをそれぞれ行数、列数、そして norm 値であると解釈します。
オプション dgrid3d は、散在するデータを重み付き平均で規則的な格子に 置き変える単純な仕組みに過ぎません。この問題に対するより洗練された手法 が存在しますので、この単純な方法が不十分であれば、gnuplot の外でその ような方法でデータを前処理するべきでしょう。
以下も参照
および
書式:
set dummy {<dummy-var>} {,<dummy-var>}
show dummy
デフォルトでは、gnuplot は plot では、媒介変数モード、あるいは極座 標モードでは "t", そうでなければ "x" を独立変数 (仮変数) とし、同様に splot では、媒介変数モードでは (splot は極座標モードでは使えません) "u" と "v", そうでなければ "x" と "y" を独立変数とします。
仮変数は、物理的に意味のある名前、あるいはより便利な名前として使う方が 便利でしょう。例えば、時間の関数を描画する場合:
set dummy t
plot sin(t), cos(t)
例:
set dummy u,v
set dummy ,s
第二の例は、2 番目の変数を s とします。仮変数名をデフォルトの値に戻す には以下のようにしてください。
unset dummy
書式:
set encoding {<value>}
set encoding locale
show encoding
有効な値 (value) は以下の通りです。
default - 出力形式にデフォルトのエンコードの使用を命令
iso_8859_1 - 多くの Unix ワークステーションや MS-Windows で使用可
能な最も一般的な西ヨーロッパエンコード。このエンコー
ドは PostScript の世界で 'ISO-Latin1' として知られて
いるものです。
iso_8859_15 - ユーロ記号を含む iso_8859_1 の亜種
iso_8859_2 - 中央/東ヨーロッパで使用されるエンコード
iso_8859_9 - (Latin5 として知られる) トルコで使用されるエンコード
koi8r - 良く使われる Unix のキリル文字エンコード
koi8u - Unix のウクライナ地方のキリル文字エンコード
cp437 - MS-DOS のコードページ
cp850 - 西ヨーロッパの OS/2 のコードページ
cp852 - 中央/東ヨーロッパの OS/2 のコードページ
cp950 - MS 版の Big5 (emf terminal のみ)
cp1250 - 中央/東ヨーロッパの MS Windows のコードページ
cp1251 - ロシア、セルビア、ブルガリア、マケドニア語 (8 ビット)
cp1252 - 西ヨーロッパの MS Windows のコードページ
cp1254 - トルコの MS Windows のコードページ (Latin5 の拡張)
sjis - Shift_JIS 日本語エンコード
utf8 - 各文字の Unicode エントリポイントの、可変長 (マルチバ
イト) 表現
コマンド set encoding locale は、他のオプションとは違い、これは現在 のロカールを実行時の環境から決定しようとします。たいていのシステムでは これは環境変数 LC_ALL, LC_CTYPE, LANG のいずれかによって制御されます。 この仕組みは、例えば wxt, cairopdf 出力形式で、UTF-8 や EUC-JP のよう なマルチバイト文字エンコードを通すために必要です。このコマンドは日付や 数字などのロカール特有の表現には影響を与えません。 以下も参照: set locale (88.41), set decimalsign (88.21)。
一般に、エンコードの設定は出力形式の設定の前に行なう必要があります。こ のエンコードはどんな出力形式でもサポートされているとは限らず、そして出 力形式は要求されたどんな非標準文字も生成できなければいけません。
書式:
set fit {nolog | logfile {"<filename>"|default}}
{{no}quiet|results|brief|verbose}
{{no}errorvariables}
{{no}covariancevariables}
{{no}errorscaling}
{{no}prescale}
{maxiter <value>|default}
{limit <epsilon>|default}
{limit_abs <epsilon_abs>}
{start-lambda <value>|default}
{lambda-factor <value>|default}
{script {"<command>"|default}}
{v4 | v5}
unset fit
show fit
オプション logfile は、fit コマンドがその出力を書き出す場所を定義 します。 引数 < filename> は、単一引用符か二重引用符で囲む必要がありま す。ファイル名を指定しなかった場合、または unset fit を使用した場合 は、ログファイルはデフォルトの値である "fit.log"、または環境変数 FIT_LOG の値にリセットされます。与えられたログファイル名が / か \ で 終っている場合、それはディレクトリ名と解釈され、ログファイルはそのディ レクトリの "fit.log" となります。
デフォルトでは、そのログファイルに書かれる情報は、対話型出力にも出力し ます。set fit quiet はその対話型出力をオフにし、results は最終結果 のみを出力します。brief は、追加で fit のすべての繰り返しに関して 1 行の要約を提供します。verbose は、バージョン 5 以前でデフォルトだった、詳細な繰り返しの報告を行います。
オプション errorvariables を ON にすると、fit コマンドで計算された 個々の当てはめパラメータの誤差が、そのパラメータの名前に "_err" をつけ た名前のユーザ定義変数にコピーされます。これは主に、当てはめ関数とデー タの描画グラフの上にパラメータとその誤差を参照用に出力するのに使われま す。例:
set fit errorvariables
fit f(x) 'datafile' using 1:2 via a, b
print "error of a is:", a_err
set label 1 sprintf("a=%6.2f +/- %6.2f", a, a_err)
plot 'datafile' using 1:2, f(x)
オプション errorscaling を指定すると (デフォルト)、パラメータの計算 誤差を補正χ自乗 (reduced χ-square) で伸縮します。これは、結果として 補正χ自乗値になる、当てはめ計算の標準偏差 (FIT_STDFIT) に等しいデータ 誤差を提供することと同等になります。オプション noerrorscaling では、 評価誤差は、伸縮されない当てはめパラメータの標準偏差になります。 データの重みを指定しなければ、パラメータの誤差は常に伸縮されます。
オプション prescale をオンにすると、Marquardt-Levenberg ルーチンに渡 す前に、各パラメータの値をそれらの初期値に従って事前にスケール変換しま す。これは、各パラメータの大きさにかなり大きな違いがある場合に、大変有 効です。ただし、初期値が完全に 0 の当てはめパラメータには、決してこの スケール変換は行いません。
反復数の限界値は、オプション maxiter で制限できます。それを 0 か default とすると、それは限界がないことを意味します。
オプション limit は、収束を検出するためのもっとも小さい数字の限界 (1e-5) のデフォルトの値を変更するのに使えます。自乗残差の和がこの数値 未満の比率の変化しかしない場合は、当てはめは「収束した」と判断されます。
オプション limit_abs は、自乗残差の和の変化の限界 (絶対値) を追加し ます。デフォルトは 0 です。
アルゴリズムに関する別の制御をしたい場合、そして Marquardt-Levenberg アルゴリズムを良く知っている場合、それに影響を与える以下のオプションが利用できます: lambda の初期値は、通常自動的に ML-行列から計算されますが、必要ならばオプション start_lambda を使ってそれを与えることができます。それを default とすると、再び自動設定が有効になります。オプ ション lambda_factor は、対象とする関数のχ自乗値が意味ありげに増加 する/減少するときは常に lambda を増加させる/減少させる因子を設定しま す。それを default とすると、デフォルトの因子である 10.0 にします。
オプション script は、fit を中断したときに実行する gnuplot コマン ドを指定するものです。以下参照: fit (68)。この設定はデフォルトの replot や環境変数 FIT_SCRIPT よりも優先順位は上です。
オプション covariancevariables をオンにすると、最終的なパラメータ間 の共分散をユーザ定義変数に保存します。各パラメータの組に対してその共分 散を保存する変数名は、"FIT_COV_" に最初のパラメータ名と "_" と 2 つ目 のパラメータをつなげた名前になります。例えばパラメータ "a" と "b" に対 しては、その共分散変数名は "FIT_COV_a_b" となります。
バージョン 5 では、コマンド fit の書式は変更され、キーワード error が指定されていない場合は単位重み (unitweights) がデフォルトになりま した。オプション v4 で gnuplot バージョン 4 のデフォルトの挙動に戻り ます。以下も参照: fit (68)。
書式:
set fontpath {"pathlist1" {"pathlist2"...}}
show fontpath
パス名は単一のディレクトリ名、または複数のパス名のリストとして入力しま す。複数のパスからなるパスリストは OS 固有のパス区切り、例えば Unix で はコロン (':'), MS-DOS, Windows, OS/2 ではセミコロン (';') 等で区切り ます。show fontpath, save, save set コマンドは、可搬性のために OS 固有のパス区切りをスペース (' ') で置き換えます。ディレクトリ名がエ クスクラメーションマーク ('!') で終っている場合、そのディレクトリのサ ブディレクトリも検索されます。
環境変数 GNUPLOT_FONTPATH が設定されている場合、その内容は fontpath に追加されますが、それが設定されていない場合システムに依存したデフォル トの値が使用されます。最初にフォントパスを使ったときに、その幾つかのデ ィレクトリが存在するかテストされ、セットされます。よって、一番最初の set fontpath, show fontpath, save fontpath や、埋め込みフォント を使用した場合の plot, splot は、少し時間がかかります。それを少し でも短くしたければ、環境変数 GNUPLOT_FONTPATH を設定してください。そう すればディレクトリのチェックは OFF になります。デフォルトのフォントパ スが何であるかは、show fontpath で見ることができます。
show fontpath は、ユーザ定義の fontpath とシステムの fontpath を別々 に表示しますが、save, save set コマンドは、ユーザ定義の fontpath のみを保存します。
gd ライブラリを通じてファイル名でフォントにアクセスする出力ドライバに 関しては、フォント検索パスは環境変数 GDFONTPATH で制御されます。
書式:
set format {<axes>} {"<format-string>"} {numeric|timedate|geographic}
show format
ここで、<
axes>
(軸) は x, y, xy, x2, y2, z, cb、または何
も指定しないか (その場合その書式はすべての軸に適用されます) のいずれか
です。以下の 2 つのコマンドは全く同等です:
set format y "%.2f"
set ytics format "%.2f"
書式文字列の長さは 100 文字まで、と制限されています。デフォルトの書式 文字列は "% h" で、LaTeX 系の出力形式では "$%h$" です。他に "%.2f" や "%3.0em" のような書式が好まれることも多いでしょう。"set format" の後ろ に何もつけずに実行すると、デフォルトに戻します。
空文字列 "" を指定した場合、刻み自身は表示しますが見出しはつけません。 刻み自身を消すには、 unset xtics または set tics scale 0 を使用し てください。
書式文字列では、改行文字 ( \ n) や拡張文字列処理 (enhanced text) 用のマ ークアップも使えます。 この場合は、単一引用符 (') でなく (") を使って ください。以下も参照: syntax (27)。 "%" が頭につかない文字はそのまま表示されます。よって、書式文字列内にスペースや文字列などを入れることができます。例えば "%g m" とすれば、 数値の後に " m" が表示されます。"%" 自身を表示する場合には "%g %%" の ように 2 つ重ねます。
刻みに関するより詳しい情報については、以下も参照: set xtics (88.104)。また、 この方法で出力される数字にデフォルト以外の小数分離文字を使うやり方については、以下参照: set decimalsign (88.21)。 以下も参照。
エレクトロン (電子) デモ (electron.dem).
| 目盛りラベルの数値書式指定子 | |
| 書式 | 説明 |
%f |
固定小数点表記 |
%e, %E |
指数表記; 指数の前に "e", "E" をつける |
%g, %G |
%e (または %E) と %f の略記 |
%h, %H |
%g に "e%S" でなく "x10^{%S}" か "*10^{%S}" をつける |
%x, %X |
16 進表記 |
%o, %O |
8 進表記 |
%t |
10 進の仮数部 |
%l |
現在の対数尺の底を基数とする仮数部 |
%s |
現在の対数尺の底を基数とする仮数部; 補助単位 (scientific power) |
%T |
10 進の指数部 |
%L |
現在の対数尺の底を基数とする指数部 |
%S |
補助単位の指数部 (scientific power) |
%c |
補助単位文字 |
%b |
ISO/IEC 80000 記法 (ki, Mi, Gi, Ti, Pi, Ei, Zi, Yi) の仮数部 |
%B |
ISO/IEC 80000 記法 (ki, Mi, Gi, Ti, Pi, Ei, Zi, Yi) の接頭辞 |
%P |
πの倍数 |
補助単位 ('scientific' power) は、指数が 3 の倍数であるようなものです。 補助単位指数 ("%c") の文字への変換は -18 から +18 までの指数に対して サポートされています。この範囲外の指数の場合、書式は通常の指数形式に 戻ります。
ほかに使うことのできる修飾詞 ("%" と書式指定子の間に書くもの) には、 次のいくつかがあります: "-" は数字を左詰めにし、"+" は正の数にも符号を つけ、" " (空白一つ) は負の数に "-" をつけるべき場所に正の数の場合に空 白を一つつけ、"#" は小数点以下の数字が 0 だけであっても小数点をつけ、正の整数は出力幅を定め、出力幅指定の直前の "0" (文字でなく数字) は先頭 に空いた部分を空白で埋める代わりに 0 で埋め、小数点の後に非負の整数を 書いたものは精度を意味します (整数の場合は最小桁、小数の場合は小数点以下の桁数)。
これらの全ての修飾詞をサポートしていない OS もあるでしょうし、逆にこれ 以外のものをもサポートする OS もあるでしょう。疑わしい場合は、適切な資 料を調べ、そして実験してみてください。
例:
set format y "%t"; set ytics (5,10) # "5.0" と "1.0"
set format y "%s"; set ytics (500,1000) # "500" と "1.0"
set format y "%+-12.3f"; set ytics(12345) # "+12345.000 "
set format y "%.2t*10^%+03T"; set ytic(12345)# "1.23*10^+04"
set format y "%s*10^{%S}"; set ytic(12345) # "12.345*10^{3}"
set format y "%s %cg"; set ytic(12345) # "12.345 kg"
set format y "%.0P pi"; set ytic(6.283185) # "2 pi"
set format y "%.0f%%"; set ytic(50) # "50%"
set log y 2; set format y '%l'; set ytics (1,2,3)
#"1.0", "1.0", "1.5" と表示される (3 は 1.5 * 2^1 なので)
丸めと指数が必要となるような書式で 9.999 の様な数字が書かれる場合は 問題が起こることがあります。
軸のデータ型が日時データ (time/date) の場合、書式文字列は 'strftime'関数 ('gnuplot' 外。"man strftime" としてみてください) に関する有効な 指定を行う必要があります。使える入力書式指定の一覧に関しては、以下参照:set timefmt (88.83)。
| 日付指定子 | |
| 書式 | 説明 |
%a |
曜日名の省略形 (Sun,Mon,...) |
%A |
曜日名 (Sunday,Monday,...) |
%b, %h |
月名の省略形 (Jan,Feb,...) |
%B |
月名 (January,February,...) |
%d |
日 (01-31) |
%D |
"%m/%d/%y" の簡略形 (出力のみ) |
%F |
"%Y-%m-%d" の簡略形 (出力のみ) |
%k |
時 (0-23; 1 桁または 2 桁) |
%H |
時 (00-23; 常に 2 桁) |
%l |
時 (1-12; 1 桁または 2 桁) |
%I |
時 (01-12; 常に 2 桁) |
%j |
その年の通算日 (001-366) |
%m |
月 (01-12) |
%M |
分 (00-60) |
%p |
"am" または "pm" |
%r |
"%I:%M:%S %p" の簡略形 (出力のみ) |
%R |
"%H:%M" の簡略形 (出力のみ) |
%S |
秒 (出力では 00-60 の整数、入力では実数) |
%s |
1970 年最初からの秒数 |
%T |
"%H:%M:%S" の簡略形 (出力のみ) |
%U |
その年の通算週 (週は日曜日からと数える) |
%w |
曜日番号 (0-6, 日曜 = 0) |
%W |
その年の通算週 (週は月曜日からと数える) |
%y |
西暦 (0-99、1969-2068 年の下 2 桁) |
%Y |
西暦 (4 桁) |
数字を表す書式には、先頭に 0 を埋めるために "0" (ゼロ) を前につけるこ とができ、また最小の出力幅を指定するために正の整数を前につけることもで きます。書式 %S と %t は精度指定も受けつけるので、小数の時/分/秒を書く こともできます。
| 時刻指定子 | |
| 書式 | 説明 |
%tH |
エポック時への相対的な正負の時 (24 での巻戻しなし) |
%tM |
エポック時への相対的な正負の分 |
%tS |
直前の tH, tM 項目に対応する正負の秒数 |
日付書式の例:
x の値が、1976 年 12 月 25 日の深夜少し前の時刻に対応する秒数であると 仮定します。この位置の軸の刻みラベル文字列は、以下のようになります:
set format x # デフォルトでは "12/25/76 \n 23:11"
set format x "%A, %d %b %Y" # "Saturday, 25 Dec 1976"
set format x "%r %D" # "11:11:11 pm 12/25/76"
時刻書式の例:
日付書式指定は、秒数での時間の値を、ある特定の日の時計の時刻にエンコー ドします。よって、時は 0 から 23 まで、分は 0 から 59 までのみを動きま すが、それらの負の値は、エポック (1970 年 1 月 1 日) より前の日付に対 応します。秒数での時間の値を、時間 0 に対する相対的な時/分/秒の数値と して出力させるには、時間書式 %tH %tM %tS を使用します。-3672.50 秒の値 は以下のように出力されます。
set format x # デフォルトでは "12/31/69 \n 22:58"
set format x "%tH:%tM:%tS" # "-01:01:12"
set format x "%.2tH hours" # "-1.02 hours"
set format x "%tM:%.2tS" # "-61:12.50"
書式:
show functions
gnuplot における関数の定義とその使い方については、以下参照:expressions (15)。 以下も参照
および
書式:
set grid {{no}{m}xtics} {{no}{m}ytics} {{no}{m}ztics}
{{no}{m}x2tics} {{no}{m}y2tics}
{{no}{m}cbtics}
{polar {<angle>}}
{layerdefault | front | back}
{ {linestyle <major_linestyle>}
| {linetype | lt <major_linetype>}
{linewidth | lw <major_linewidth>}
{ , {linestyle | ls <minor_linestyle>}
| {linetype | lt <minor_linetype>}
{linewidth | lw <minor_linewidth>} } }
unset grid
show grid
格子線は任意の軸の任意の大目盛り/小目盛りに対して有効/無効にでき、その 大目盛りと小目盛りに対する線種、線幅も指定でき、現在の出力装置がサポー トする範囲で、あらかじめ定義したラインスタイルを使用することもできます。
さらに、2 次元の描画では極座標格子も使うことができます。定義可能な区間 に対して、選択された目盛りを通る同心円と中心からの放射状の線が描かれま す (その区間は set angles の設定にしたがって度、またはラジアンで指定 します)。極座標格子は現在は極座標モードでは自動的には生成されないこと に注意してください。
set grid が描く前に、必要な目盛りは有効になっていなければなりません。 gnuplot は、存在しない目盛りに対する格子の描画の命令は単に無視します。 しかし、後でその目盛りが有効になればそれに対する格子も描きます。
小格子線に対する線種を何も指定しなければ、大格子線と同じ線種が使われま す。デフォルトの極座標の角度は 30 度です。
front を指定すると、格子線はグラフのデータの上に描かれます。back が指定された場合は格子線はグラフのデータの下に描かれます。front を使 えば、密集したデータで格子線が見えなくなることを防ぐことができます。デ フォルトでは layerdefault で、これは 2D 描画では back と同じです。 3D 描画のデフォルトは、格子とグラフの枠を 2 つの描画単位に分離し、格子 は後ろに、枠は描画データまたは関数の前に書きます。ただし、hidden3d モードでは、それがそれ自身の並び換えをしていますので、格子線の順番のオ プションは全て無視され、格子線も隠線処理にかけられます。これらのオプシ ョンは、実際には格子線だけでなく、set border による境界線とその目盛 りの刻み (以下参照: set xtics (88.104)) にも影響を及ぼします。
z の格子線は描画の底面に描かれます。これは描画の周りに部分的な箱が描画 されている場合にはいいでしょう。以下参照: set border (88.7)。
書式:
set hidden3d {defaults} |
{ {front|back}
{{offset <offset>} | {nooffset}}
{trianglepattern <bitpattern>}
{{undefined <level>} | {noundefined}}
{{no}altdiagonal}
{{no}bentover} }
unset hidden3d
show hidden3d
gnuplot の通常の表示とは異なり、隠線処理では与えられた関数、またはデー タの格子線を、実際の曲面がその曲面の背後にあって隠されている描画要素は 見せないのと同じように処理します。これが機能するためには、その曲面が '格子状' (以下参照: splot datafile (90.1)) である必要があり、またそれらは with lines か with linespoints で描かれていなければいけません。
hidden3d が有効なときは、格子線だけでなく、面部分や土台の上の等高線 (以下参照: set contour (88.17)) も隠されます。複数の面を描画している場合は、 各曲面は自分自身と他の曲面で隠される部分も持ちます。曲面上への等高線の 表示 (set contour surface) は機能しません。
gnuplot バージョン 4.6 では、グラフ上に曲面が一つもない状態でも、 hidden3d は points, labels, vectors, impulses の 3 次元の描画 スタイルに影響を与えます。vectors は、隠されない部分は線分 (矢先なし) として表示されます。グラフ内の各々の描画をこの処理から明示的に除外した いときは、with 指定に特別のオプション nohidden3d を追加してくださ い。
hidden3d は、pm3d モードで描画された、塗り潰された曲面には影響を与えま せん。pm3d の曲面に対して同様の効果を純粋に得たいならば、これの代わり に set pm3d depthorder を使ってください。複数の pm3d 曲面に通常の hidden3d 処理を組み合わせるには、オプション set hidden3d front を 使用してください。これは、hidden3d 処理の全ての要素を、pm3d 曲面を含む 残りの他の描画要素の後に強制的に描画するものです。
関数値は格子孤立線の交点で評価されます。見ることの出来る線分を求めると きは個々の関数値、あるいはデータ点の間はそのアルゴリズムによって線形補 間されます。これは、hidden3d で描画する場合と nohidden3d で描画す る場合で関数の見かけが異なることを意味します。なぜならば、後者の場合関 数値は各標本点で評価されるからです。この違いに関する議論については、 以下参照: set samples (88.72), set isosamples (88.34)。
曲面の隠される部分を消去するのに使われるアルゴリズムは、このコマンドで 制御されるいくつかの追加オプションを持っています。defaults を指定す ればそれらはすべて、以下で述べるようなデフォルトの値に設定されます。 defaults が指定されなかった場合には、明示的に指定されたオプションの みが影響を受け、それ以外のものは以前の値が引き継がれます。よって、それ らのオプションの値をいちいち修正することなく、単に set {no}hidden3d のみで隠線処理をオン/オフできることになります。
最初のオプション offset は '裏側' の線を描画する線の線種に影響を与え ます。通常は曲面の表裏を区別するために、裏側の線種は、表側の線種より一 つ大きい番号の線種が使われます。offset < offset> によって、その追加す る値を、デフォルトの 1 とは異なる増分値に変更できます。nooffset オプ ションは offset 0 を意味し、これは表裏で同じ線種を使うことになります。
次のオプションは trianglepattern < bitpattern> です。< bitpattern> は 0 から 7 までの数字で、ビットパターンと解釈されます。各曲面は三角形に 分割されますが、このビットパターンの各ビットはそれらの三角形の各辺の表 示を決定します。ビット 0 は格子の水平辺、ビット 1 は格子の垂直辺、ビッ ト 2 は、元々の格子が 2 つの三角形に分割されるときの対角辺です。デフォ ルトのビットパターンは 3 で、これは全ての水平辺と垂直辺を表示し、対角 辺は表示しないことを意味します。対角辺も表示する場合は 7 を指定します。
オプション undefined < level> は、定義されていない (欠けているデータ または未定義の関数値) か、または与えられた x,y,z の範囲を超えているデ ータ点に適用させるアルゴリズムを指示します。そのような点は、それでも 表示されてしまうか、または入力データから取り除かれます。取り除かれて しまう点に接する全ての曲面要素は同様に取り除かれ、よって曲面に穴が生 じます。< level> = 3 の場合、これは noundefined と同じで、どんな点も 捨てられません。これは他の場所であらゆる種類の問題を引き起こし得るので 使わないべきです。< level> = 2 では未定義の点は捨てられますが、範囲を超 えた点は捨てられません。< level> = 1 では、これがデフォルトですが、範囲 を超えた点も捨てられます。
noaltdiagonal を指定すると、undefined が有効のとき (すなわち < level> が 3 でない場合) に起こる以下の場合のデフォルトでの取扱いを変更できます。入力曲面の各格子状の部分は一方の対角線によって 2 つの三角形に分割 されます。通常はそれらの対角線の全てが格子に対して同じ方向を向いていま す。もし、ある格子の 4 つの角のうち一つが undefined 処理によりとり除 かれていて、その角が通常の方向の対角線に乗っている場合は、その両方の三 角形が取り除かれてしまいます。しかし、もしデフォルトの設定である altdiagonal が有効になっている場合、その格子については他方向の対角線 が代わりに選択され、曲面の穴の大きさが最小になるようにします。
bentover オプションは今度は trianglepattern とともに起こる別のこと を制御します。かなりしわくちゃの曲面では、下の ASCII 文字絵に書いたよ うに、曲面の 1 つの格子が 2 つに分けられた三角形の表と裏の反対側が見え てしまう場合 (すなわち、元の四角形が折り曲げられている ('bent over') 場合) があります:
C----B
元の 4 角形: A--B 表示される 4 角形: |\ |
("set view 0,0") | /| ("set view 75,75" perhaps) | \ |
|/ | | \ |
C--D | \|
A D
曲面の格子の対角辺が < bitpattern> の 2 bit によって見えるようにはなっ てはいない場合、上の対角辺 CB はどこにも書かれないことになり、それが結 果の表示を理解しにくいものにします。デフォルトで定義される bentover オプションは、このような場合それを表示するようにします。もしそうしたく ないなら、nobentover を選択してください。 以下も参照
および
set history {size <N>} {quiet|numbers} {full|trim} {default}
gnuplot の終了時にヒストリファイルに保存する行数を、history size の値 に制限します。set history size -1 とすると、ヒストリファイルに書き出 す行数の制限がなくなります。
デフォルトでは、コマンド history は各コマンドの前に行番号を出力しま す。history quiet は、今回の実行に対してのみ番号を省略しますが、 set history quiet は、今後のすべての history の番号を省略します。
オプション trim は、現在のコマンドに対する前の同じものを削除すること で、コマンド履歴内の重複する行の数を減らします。gnuplot のバージョン 5 以前では、これがデフォルトの挙動でした。
デフォルトの設定: set history size 500 numbers trim
書式:
set isosamples <iso_1> {,<iso_2>}
show isosamples
各曲面グラフは < iso_1> 個の u-孤立線と < iso_2> 個の v-孤立線を持ちます。 < iso_1> のみ指定すれば、< iso_2> は < iso_1> と同じ値に設定されます。 デフォルトでは、u, v それぞれ 10 本の標本化が行われます。標本数をもっと 多くすればより正確なグラフが作られますが、時間がかかります。これらの パラメータは、データファイルの描画には何も影響を与えません。
孤立線とは、曲面の一つの媒介変数を固定して、もう一つの媒介変数によって 描かれる曲線のことです。孤立線は、曲面を表示する単純な方法を与えます。 曲面 s(u,v) の媒介変数 u を固定することで u-孤立線 c(v) = s(u0,v) が 作られ、媒介変数 v を固定することで v-孤立線 c(u) = s(u,v0) ができます。
関数の曲面グラフが隠線処理なしで描かれている場合、set samples は 各孤立線上で標本化される点の数を制御します。以下参照: set samples (88.72),set hidden3d (88.31)。等高線描画ルーチンは、関数の点の標本化は各孤立線の交点 で行われると仮定しているので、関数の曲面と等高線の解像度を変更するとき は、isosamples と同じように samples を変更するのが望ましいでしょう。
書式:
set key {on|off} {default}
{{inside | outside} | {lmargin | rmargin | tmargin | bmargin}
| {at <position>}}
{left | right | center} {top | bottom | center}
{vertical | horizontal} {Left | Right}
{{no}opaque}
{{no}reverse} {{no}invert}
{samplen <sample_length>} {spacing <vertical_spacing>}
{width <width_increment>} {height <height_increment>}
{{no}autotitle {columnheader}}
{title "<text>"} {{no}enhanced}
{font "<face>,<size>"} {textcolor <colorspec>}
{{no}box {linestyle <style> | linetype <type> | linewidth <width>}}
{maxcols {<max no. of columns> | auto}}
{maxrows {<max no. of rows> | auto}}
unset key
show key
キー内の各要素は vertical (縦) または horizontal (横) に従って重ね られます。vertical の場合、凡例は可能ならば 2,3 個の縦の列を使います。 すなわち、各要素は垂直スペースがなくなるまでは 1 つの列に整列されます が、そこから新しい列が開始されます。垂直スペースは、maxrows を使って 制限できます。horizontal の場合は、凡例は横の行をできるだけ少なく使 おうとします。水平方向のスペースは maxcols により制限できます。
デフォルトでは、凡例はグラフ領域の内側の右上の角に置かれます。キーワー ド left, right, top, bottom, center, inside, outside, lmargin, rmargin, tmargin, bmargin (, above, over, below, under) は、グラフ領域の他の場所への自動的な配置のために使用します。 凡例の描画をどこに置くかをより詳しく指示するための at < position> も あります。この場合、キーワード left, right, top, bottom, center が同様の基準点合わせの設定の目的で使われます。 より詳しくは、以下参照: key placement (88.35.1)。
グラフのタイトルの行揃えは Left, Right (デフォルト) で指示し ます。ラベル文字列と曲線のサンプルは左右入れ替えることができます (reverse) し、 全体を枠で囲むこともできます (box {...})。その枠の 線は、線種 (linetype), 線幅 (linewidth)、あるいは定義済のラインス タイル (linestyle) を指定することもできます。
デフォルトでは、凡例は一つのグラフと同時に作られます。すなわち、凡例の 記号とタイトルは、それに対応するグラフと同時に描かれます。それは、新し いグラフが時には凡例の上に要素をかぶせて配置しうることを意味します。 set key opaque は、凡例をすべてのグラフの描画が終った後に生成させま す。この場合、凡例の領域は背景色で塗りつぶされて凡例の記号とタイトルが 描かれます。よって、凡例自身はいくつかの描画要素を覆い隠してしまい得る ことになります。set key noopaque でデフォルトに復帰できます。
デフォルトでは、最初の描画のラベルが凡例の一番上に現われ、それに続くラ ベルがその下に並んで行きます。オプション invert は、最初のラベルを凡 例の一番下に置き、それに続くラベルをその上に並べて行きます。このオプシ ョンは、凡例のラベルの縦の並びの順番を、積み上げ形式のヒストグラム (histograms) の箱の順番に合わせるときに便利でしょう。
< height_increment> は、凡例の箱の高さに加えたり減らしたりする高さ (何 文字分か) を表す数値です。これは主に、凡例の回りに箱を描く場合で、凡例 の並びの回りの境界線をより大きくしたい場合のものです。
plot や splot で描画される全ての曲線は、デフォルトのオプション autotitles に従ってタイトルがつけられます。タイトルの自動生成は、 noautotaitle で抑制できますがその場合、(s)plot ... title ... で明 示的に指定されたタイトルのみが描かれることになります。
コマンド set key autotitle columnheader は、各入力データの先頭行の各 列のエントリをテキスト文字列と解釈し、対応する描画グラフのタイトルとし て使用します。描画される量が、複数の列データの関数である場合は、 gnuplot はどの列をタイトルの描画に使えばいいのかわかりませんので、その ような場合、plot コマンド上で、例えば以下のように明示的にタイトルの列を指定する必要があります。
plot "datafile" using (($2+$3)/$4) title columnhead(3) with lines
全体に渡るタイトルを凡例の上につけることもできます (title "< text> ")。 単一引用符 (') と二重引用符 (") の違いについては、以下も参照: syntax (27)。
set key のデフォルトは、on, right, top, vertical, Right, noreverse, noinvert, samplen 4, spacing 1.25, title "", nobox です。凡例の枠の線種はデフォルトではグラフ描画の外枠と同じもの が使われます。set key default とするとデフォルトの設定に戻ります。
凡例は、1 行に 1 曲線分ずつの数行のまとまりとして書かれます。各行の右 側には (reverse を使っていれば左側には) その曲線と同じ種類の直線のサ ンプルが引かれ、他の側には plot コマンドから得られる文字列 (title) が置かれます。これらの行は、架空の直線が凡例の左側と右側を分けるかのよ うに垂直に整列されます。コマンド set key で指定する座標はこの架空の 線分の上の端の座標です。plot では直線の位置を指定するために x と y だけが使われ、splot では、x, y, z の値全てを使い、グラフを 2 次元面 へ投影するのと同じ方法を使って、架空の直線の 2 次元画面での位置を生成 します。
TeX, LaTeX 系の出力形式や、整形情報が文字列に埋め込まれる出力形式を使 う場合は、gnuplot は凡例の位置決めのための文字列の幅を評価することし かできません。よって凡例を左に置く場合は、set key left Left reverse という組合せを使うのがいいでしょう。
splot で等高線を書く場合、デフォルトでは凡例に等高線のラベルも表示し ます。その表示は set cntrlabel format で調整できます。
例:
以下はデフォルトの位置に凡例を表示します:
set key default
以下は凡例を表示しなくします:
unset key
以下はデフォルトの (第一の) 座標系での (2,3.5,2) の位置に凡例を表示
します:
set key at 2,3.5,2
以下は凡例をグラフの下に表示します:
set key below
以下は凡例を左下角に表示し、テキストは左に行揃えで、タイトルをつけ、線種 3 の外枠を書きます:
set key left bottom Left title 'Legend' box 3
モード inside では、凡例はキーワード left (l), right (r), top (t), bottom (b), center (c) によって以下の図のように描画領域の境界に向かって出力されます:
t/l t/c t/r
c/l c c/r
b/l b/c b/r
モード outside でも上と同様に自動的に配置されますが、グラフ領域の境 界に対して、というよりもむしろ見た目に対して、というべきでしょう。すな わち、グラフの境界は、グラフ領域の外の凡例の場所を作るために、内側に移 動することになります。しかし、これは他のラベルの邪魔をしますし、もしか したら出力デバイスによってはエラーを引き起こすかもしれません。凡例の出 力に合わせてどの描画境界が移動するかは、上に述べた凡例の位置、および重 ね上げの方向に依存します。4 方向の中心揃えのオプション (center) に関 しては、どの境界が動くのかに関するあいまいさはありませんが、角への出力 のオプションについては、重ね上げ方向が vertical の場合は左または右の 境界が、horizontal の場合は上または下の境界が、それぞれ内側に適切に 移動します。
余白 (margin) の書き方は、重ね上げの方向にかかわない自動的な配置を可能 にしています。lmargin (lm), rmargin (rm), tmargin (tm), bmargin (bm) のうちの一つを、矛盾しない 1 方向のキーワードと組み合わ せて使用した場合、以下の図に示した場所に凡例が配置されます:
l/tm c/tm r/tm
t/lm t/rm
c/lm c/rm
b/lm b/rm
l/bm c/bm r/bm
キーワード above と over は tmargin と同じ意味です。以前のバージョンとの互換性のために、above と over は l/c/r や重ね上げ方向のキーワードなしで使用すると、center で horizontal を使います。キーワ ード below と under は bmargin と同じ意味です。互換性のために、 below と under は l/c/r や重ね上げ方向のキーワードなしで使用すると center で horizontal を使います。さらに、outside も互換性のため に t/b/c や重ね上げ方向のキーワードがなければ、top, right, vertical (つまり上の t/rm と同じ) を使用します。
凡例の位置 (< position> ) は、以前のバージョンと同様単に x,y,z を指定してもいいですが、その最初のサンプル行の座標の座表系を選択するための 5つのキーワード (first, second, graph, screen, character) を 頭につけることもできます。詳細は、以下参照: coordinates (11)。< position> が与えられた場合の left, right, top, bottom, center の効果は、 label コマンドで配置される文字列の場合と同じように基準位置の位置合わせ に使用されます。すなわち、left は凡例が < position> の右に置かれて左 合わせで出力されます。他の場合も同様です。
グラフ曲線のサンプルの線分の長さは samplen で指定できます。その長さ は目盛りの長さと、< sample_length> *(文字幅) の和として計算されます。 sapmlen は、グラフ上の点のサンプルの位置にも (もしサンプル線分自身が 書かれなくても) 影響を与えています。それは、点の記号はサンプル線分の中 央に書かれるためです。
行間の垂直スペースは、spacing で指定できます。その幅は、点のサイズ (pointsize) と垂直な目盛りのサイズと < vertical_spacing> の積になります。 この垂直スペースは、文字の高さよりも小さくはならないことが保証されてい ます。
< width_increment> は、文字列の長さに加えたり減らしたりする幅 (何文字分 か) を表す数値です。これは、凡例に外枠を書き、文字列に制御文字を使う場 合にだけ有用でしょう。gnuplot は外枠の幅を計算するときは、ラベル文字 列の文字数を単純に数えるだけなので、それを修正するのに使えます。
書式:
set label {<tag>} {"<label text>"} {at <position>}
{left | center | right}
{norotate | rotate {by <degrees>}}
{font "<name>{,<size>}"}
{noenhanced}
{front | back}
{textcolor <colorspec>}
{point <pointstyle> | nopoint}
{offset <offset>}
{boxed}
{hypertext}
unset label {<tag>}
show label
位置 (< position> ) は x,y か x,y,z のどちらかで指定し、座標系を選択する にはその座標の前に first, second, graph, screen, character をつけます。詳細は、以下参照: coordinates (11)。
タグ (< tag> ) は見出しを識別するための整数値です。タグを指定しなかった 場合未使用のもので最も小さい値が自動的に割り当てられます。現在の見出し を変更するときはそのタグと変更したい項目を指定して set label コマン ドを使います。
< label text> は文字列定数でも構いませんし、文字列変数、または文字列の 値を持つ式でも構いません。以下参照: strings (25), sprintf (15.1), gprintf (88.27.1)。
デフォルトでは、指定した点 x,y,z に見出しの文章の左端が来るように配置 されます。x,y,z を見出しのどこに揃えるかを変更するには変数 < justification> を指定します。これには、left, right, center の いずれかが指定でき、それぞれ文章の左、右、真中が指定した点に来るよう に配置さるようになります。描画範囲の外にはみ出るような指定も許されま すが、座標軸の見出しや他の文字列と重なる場合があります。
箱内に入れるラベルをサポートする出力形式もあります。以下参照:set style textbox (88.74.11)。注意: 今のところ、箱内のラベルは、回転しない文字 列に制限されています。
rotate を指定するとラベルは縦書きになります (もちろん出力ドライバが 対応していれば、ですが)。rotate by < degrees> が与えられた場合は、そ れに適合している出力ドライバは指定された角度で文字列を書こうとしますが そうでない出力形式では、垂直な文字列として扱われます。
フォントとそのサイズは、出力形式がフォントの設定をサポートしていれば font "< name> {,< size> }" で明示的に選択できます。そうでない出力形式で は、デフォルトのフォントが使われます。
通常は、現在の出力形式がサポートしていれば、ラベル文字列の全ての文字列 に拡張文字列処理モード (enhanced text mode) が使用されます。 noenhanced を使用することで、特定のラベルを拡張文字列処理から外すこ とができます。これは、ラベルが例えばアンダースコア (_) を含んでいる場 合などに有用です。以下参照: enhanced text (13)。
front が与えられると、見出しはデータのグラフの上に書かれます。back が与えられると (デフォルト)、見出しはグラフの下に書かれます。front を使うことで、密なデータによって見出しが隠されてしまうことを避けること が出来ます。
textcolor <
colorspec>
は見出し文字列の色を変更します。<
colorspec>
は
線種、rgb 色、またはパレットへの割当のいずれかが指定できます。
以下参照: colorspec (19.1), palette (88.62)。textcolor は、tc と省略可能です。
`tc default` は、文字色をデフォルトにします。
`tc lt <n>` は、文字色を線種 <n> (line type)と同じものにします。
`tc ls <n>` は、文字色を line style <n> と同じものにします。
`tc palette z` は、見出しの z の位置に対応したパレット色になります。
`tc palette cb <val>` は、色見本 (colorbar) の <val> の色になります。
`tc palette fraction <val>` (0<=val<=1) は、[0:1] から `palette` の
灰色階調/カラーへの写像に対応した色になります。
`tc rgb "#RRGGBB"`, `tc rgb "0xRRGGBB"` は、任意の 24-bit RGB 色を
設定します。
`tc rgb 0xRRGGBB` も同じです (16 進定数値には引用符は不要)。
< pointstyle> がキーワード lt, pt, ps とともに与えられると (以下参照: style (77.12))、与えられたスタイルと、与えられた線種の色で見出し位置に 点 (point) が描画され、見出し文字列は少し移動されます。このオプション は mouse 拡張された出力形式でのラベルの配置に、デフォルトで使用され ています。見出し文字列近くの点の描画機能を off (これがデフォルト) にす るには、nopoint を使用してください。
その移動は、デフォルトでは、< pointstyle> が与えられれば pointsize の 単位で 1,1 で、< pointstyle> が与えられていなければ 0,0 です。移動は、 追加の offset < offset> でも制御できます。ここで、< offset> は x,y か または x,y,z の形式ですが、それに座標系を選択して、その前に first, second, graph, screen, character のいずれかをつけることもでき ます。詳細は、以下参照: coordinates (11)。
もし一つ (あるいはそれ以上の) 軸が時間軸である場合、座標は timefmt の書式にしたがって引用符で囲まれた文字列で与える必要があります。以下参照: set xdata (88.99), set timefmt (88.83)。
set label に関して有効なオプションは、描画スタイル labels でも有効 です。以下参照: labels (45)。
(1,2) の位置に "y=x" と書く場合:
set label "y=x" at 1,2
Symbol フォントのサイズ 24 の "シグマ" (Σ) をグラフの真中に書く場合:
set label "S" at graph 0.5,0.5 center font "Symbol,24"
見出し "y=x^2" の右端が (2,3,4) に来るようにし、タグ番号として 3 を使う
場合:
set label 3 "y=x^2" at 2,3,4 right
その見出しを中央揃えにする場合:
set label 3 center
タグ番号 2 の見出しを削除する場合:
unset label 2
全ての見出しを削除する場合:
unset label
全ての見出しをタグ番号順に表示する場合:
show label
x 軸が時間軸であるグラフに見出しを設定する例:
set timefmt "%d/%m/%y,%H:%M"
set label "Harvest" at "25/8/93",1
データと、新たに当てはめられたパラメータによる当てはめ関数を描画したい
場合、fit の後でかつ plot の前に以下を実行します:
set label sprintf("a = %3.5g",par_a) at 30,15
bfit = gprintf("b = %s*10^%S",par_b)
set label bfit at 30,20
当てはめられるパラメータのついた関数の定義式を表示したい場合:
f(x)=a+b*x
fit f(x) 'datafile' via a,b
set label GPFUN_f at graph .05,.95
set label sprintf("a = %g", a) at graph .05,.90
set label sprintf("b = %g", b) at graph .05,.85
見出し文字列を小さい点から少しだけ移動する場合:
set label 'origin' at 0,0 point lt 1 pt 2 ps 3 offset 1,-1
pm3d を使った 3 次元のカラー曲面上のある点の位置に、その z の値 (この
場合 5.5) に対応した色を見出し文字列につける場合:
set label 'text' at 0,0,5.5 tc palette z
set label at 0,0 "Plot origin" hypertext point pt 1
plot 'data' using 1:2:0 with labels hypertext point pt 7 \
title 'mouse over point to see its order in data set'
例えば、線種の 1 と 2 はデフォルトでは赤と緑です。それを以下のように再定義します:
set linetype 1 lw 2 lc rgb "blue" pointtype 6
set linetype 2 lw 2 lc rgb "forest-green" pointtype 8
すると lt 1 を使用しているすべてのものが、細い赤線 (lt 1 の以前のデフォルト) か太い青線になります。この性質は、lt 1 に基づいて作られた一時 的なラインスタイルの定義のようなものも含んでいます。
注意: このコマンドは gnuplot バージョン 4.6 で新たに導入されたもので、 以前のあいまいなコマンド "set style increment user" に置き換わるものです。古いコマンドは現在は非推奨です。
この仕組みは、gnuplot で使用する線種列に対する個人的な好みを設定するの にも使えます。それを行うには、実行時初期化ファイル ~ /.gnuplot に、例え ば以下のようなそれ用のコマンド列を追加することをお勧めします:
set linetype 1 lc rgb "dark-violet" lw 2 pt 1
set linetype 2 lc rgb "sea-green" lw 2 pt 7
set linetype 3 lc rgb "cyan" lw 2 pt 6 pi -1
set linetype 4 lc rgb "dark-red" lw 2 pt 5 pi -1
set linetype 5 lc rgb "blue" lw 2 pt 8
set linetype 6 lc rgb "dark-orange" lw 2 pt 3
set linetype 7 lc rgb "black" lw 2 pt 11
set linetype 8 lc rgb "goldenrod" lw 2
set linetype cycle 8
こうすると、あなたが gnuplot を実行する度に線種はこれらの値に初期化さ れます。線種はあなたが好む数だけ初期化できます。再定義しない場合は、そ れはデフォルトの属性を持ち続けます。例えば線種 3 を再定義から外せば、 それは青で pt 3, lw 1 となります。なお、サンプルスクリプトの最初の 2,3 の行は、古いバージョンの gnuplot ではスキップさせるための保険です。
同様のスクリプトファイルで、テーマベースの色選択の定義を行ったり、特定 の描画タイプ、あるいは特定の出力形式用に色をカスタマイズしたりすること も可能です。
コマンド set linetype cycle 8 は、大きな番号の線種に対しては色や線幅 に関するこれらの定義を再利用することを gnuplot に伝えます。すなわち、 線種 (linetype) 9-16, 17-24 等に対しては、これと同じ色、幅の列を使用し ます。ただし、点の属性 (pointtype, pointsize, pointinterval) は、この コマンドの影響は受けません。unset linetype cycle はこの機能を無効に します。大きな線種番号の線の属性を明示的に定義した場合は、それは小さい 番号の線種の属性の再利用よりも優先されます。
set link {x2 | y2} {via <expression1> inverse <expression2>}
unset link
コマンド set link は、x 軸と x2 軸、または y 軸と y2 軸の間の対応を 設定します。< expression1> は、第 1 軸の座標を第 2 軸に写像する数式です が、< expression2> は第 2 軸の座標を第 1 軸に写像する数式です。
例:
set link x
これは、このコマンドの最も単純な形式で、x2 軸を範囲 (range) も伸縮 (scale) も方向も x 軸と全く同じにします。set xrange や set auto x などのコマンドは、この場合 x 軸にも x2 軸にも作用します。set x2range などのコマンドは、このリンクが有効な間は無視されます。
set link x2 via x**2 inverse sqrt(x)
plot "sqrt_data" using 1:2 axes x2y1, "linear_data" using 1:2 axes x1y1
このコマンドは、x 軸と x2 軸の、順方向と逆方向の対応を設定しています。 順方向の対応は、x2 軸の刻みラベルと、マウスの x2 座標を生成するのに使 い、逆方向の対応は、x2 軸系で指定された座標を描画するのに使います。こ の対応は、非負の x 座標にのみ有効であることに注意してください。y2 軸に 対応させた場合、< expression1> と < expression2> には仮変数として y を使 う必要があります。
書式:
set loadpath {"pathlist1" {"pathlist2"...}}
show loadpath
パス名は単一のディレクトリ名、または複数のパス名のリストとして入力しま す。複数のパスからなるパスリストは OS 固有のパス区切り、例えば Unix で はコロン (':'), MS-DOS, Windows, OS/2 ではセミコロン (';') 等で区切り ます。show loadpath, save, save set コマンドは、OS 固有のパス区 切りをスペース (' ') で置き換えます。
環境変数 GNUPLOT_LIB が設定されている場合、その内容は loadpath に追 加されますが、show loadpath は、set loadpath と GNUPLOT_LIB の値を 別々に表示しますし、save, save set コマンドは、GNUPLOT_LIB の値の 方は無視します。
書式:
set locale {"<locale>"}
< locale> にはインストールされたシステムで使うことの出来る任意の言語を 指定できます。可能なオプションについてはシステムのドキュメントを参照し てください。コマンド set locale "" は、環境変数 LC_TIME, LC_ALL, ま たは LANG からロカールの値を決定しようとします。
小数点に関する locale を変更したい場合は、以下参照: set decimalsign (88.21)。 文字エンコードを現在のロカールのものに変更したい場合は、以下参照:set encoding (88.24)。
set logscale <axes> {<base>}
unset logscale <axes>
show logscale
ここで、< axes> (軸) は、x, x2, y, y2, z, cb, r の任意の 順序の組み合せが可能です。< base> は、対数目盛りの底です (デフォルトの 底は 10)。軸を指定しなかった場合は、r 以外のすべての軸が対象となります。コマンド unset logscale は、すべての軸の対数目盛りを解除します。 対数軸に対してつけられる目盛りの刻みは、等間隔ではないことに注意してく ださい。以下参照: set xtics (88.104)。
例:
x, z 両軸について対数目盛りを設定する:
set logscale xz
y 軸について底 2 とする対数目盛りを設定する:
set logscale y 2
pm3d plot 用に z と色の軸に対数目盛りを設定する:
set logscale zcb
z 軸の対数目盛りを解除する:
unset logscale z
書式:
set mapping {cartesian | spherical | cylindrical}
デフォルトではカーテシアン座標 (通常の x,y,z 座標) が使われます。
球面座標では、データは 2 つか 3 つの列 (またはその個数の using エン トリ) として与えられます。最初の 2 つは、set angles で設定された単位 での方位角 (theta) と仰角 (phi) (すなわち "経度" と "緯度") とみなされ ます。半径 r は、もし 3 列目のデータがあればそれが使われ、もしなければ 1 に設定されます。各変数の x,y,z との対応は以下の通りです:
x = r * cos(theta) * cos(phi)
y = r * sin(theta) * cos(phi)
z = r * sin(phi)
これは、"極座標系" というより、むしろ "地学上の座標系" (緯度、経度) に 相当することに注意してください (すなわち、phi は z 軸となす角、という より赤道から計った仰角、になります)。
円柱座標では、データはやはり 2 つか 3 つの列で与えられ、最初の 2 つは theta (set angle で指定された単位の) と z と見なされます。半径 r は 球面座標の場合と同様、3 列目のデータがあればそれが、なければ 1 と設定 されます。各変数の x,y,z との対応は以下の通りです:
x = r * cos(theta)
y = r * sin(theta)
z = z
mapping の効果は、splot コマンド上の using によるフィルタで実現 することも可能ですが、多くのデータファイルが処理される場合は mapping の方が便利でしょう。しかし、mapping を使っていても、もしファイルのデ ータの順番が適切でなかったら結局 using が必要になってしまいます。
mapping は plot では何もしません。
書式:
set lmargin {{at screen} <margin>}
set rmargin {{at screen} <margin>}
set tmargin {{at screen} <margin>}
set bmargin {{at screen} <margin>}
set margins <left>, <right>, <bottom>, <top>
show margin
< margin> のデフォルトの単位には、適切と思われる、文字の高さと幅が使わ れます。正の値は余白の絶対的な大きさを定義し、負の値 (または無指定) は gnuplot によって自動計算される値を使うことになります。3 次元描画では 左の余白 (lmargin) のみが文字の大きさを単位として設定できます。
キーワード at screen は、その余白の指定が全体の描画領域に対する割合 であることを意味します。これは、多重描画 (multiplot) モードでの 2D, 3D グラフの角を正確に揃えるのに使えます。この配置は現在の set origin や や set size の値を無視するようになっていて、それは多重描画内のグラフ の配置の別の方法として使われることを意図しています。
描画の余白は通常目盛り、目盛りの見出し、軸の見出し、描画のタイトル、 日付、そして境界の外にある場合の凡例 (key) のサイズ等を元に計算されま す。しかし、目盛りの刻みが境界でなく軸の方についている場合 (例えば set xtics axis によって)、目盛りの刻み自身とその見出しは余白の計算に は含まれませんし、余白に書かれる他の文字列の位置の計算にも含まれません。 これは、軸と境界が非常に近い場合、軸の見出しが他の文字列を上書きする可 能性を示唆します。
set monochrome {linetype N <linetype properties>}
コマンド set monochrome は、線種群の別の設定法を選択しますが、それは
色の違いではなく、点線/破線パターンや線幅の違いによるものです。このコ
マンドは、gnuplot の以前のバージョンのある出力形式で monochrome オプションとして提供していたものに置き換わるもので、後方互換性のため、それらの出力形式で "mono" オプションを指定すると、暗黙で set monochrome を呼び出します。
例えば、
set terminal pdf mono
set terminal pdf
set mono
白黒モード (monochrome) の選択は、明示的な RGB 色、パレット色を使用し てのカラーの線の描画を妨げるものではありませんが、以下も参照:set palette gray (88.62.4)。 デフォルトでは 6 つの白黒線種が定義されていますが、それらの属性を変更 したり、白黒線種を追加することは、フル形式でそのコマンドを使用すること でできます。白黒線種にほどこされた変更は、カラーの線種には影響を与えま せんし、その逆も同様です。カラー線種に復帰するには、unset monochrome か、set color としてください。
マウスモードは 2 種類用意されています。2 次元モードは、plot コマンド と splot の 2 次元射影 (すなわち、z の回転角が 0, 90, 180, 270, 360 度の set view、および set view map) で動作します。このモードでは、 マウス位置が追跡され、マウスボタンや矢印キーを使って拡大したり視点移動 したりできます。グラフに対応する凡例のタイトルや別なウィジェットアイコ ンなどをクリックすることで、個々のグラフの描画をオン/オフに切り替える ことをサポートする出力形式もあります。
splot による 3 次元グラフに対しては、グラフの視方向 (view) と縮尺の 変更が、それぞれマウスボタン 1 と 2 (によるドラッグ) で行えます。ボタ ン 2 の垂直方向のドラッグを shift キーと同時に行うと、z 軸の一番下の位 置 (xyplane) を上下します。これらのボタンにさらに < ctrl> キーを押す と、座標軸は表示されますが、データの表示は消えます。これは大きなデータ に対して有用でしょう。
マウスは多重描画 (multiplot) モード内では無効ですが、unset multiplot で多重描画が完結すれば、マウス機能は ON になります。ただし、その作用は multiplot 内の最後の描画 (replot で描画されるようなもの) に対してのみ です。
書式:
set mouse {doubleclick <ms>} {nodoubleclick}
{{no}zoomcoordinates}
{zoomfactors <xmultiplier>, <ymultiplier>}
{noruler | ruler {at x,y}}
{polardistance{deg|tan} | nopolardistance}
{format <string>}
{mouseformat <int>/<string>}
{{no}labels {"labeloptions"}}
{{no}zoomjump} {{no}verbose}
unset mouse
オプション noruler と ruler は、定規 (ruler) 機能を off, on にしま す。ruler には座標を与えて原点を設定することもできます。ruler が on の間、ruler の原点からマウスまでのユーザ単位での距離が連続的に表示 されます。デフォルトでは、ruler のトグルスイッチは 'r' にキー割り当て されています。
オプション polardistance は、マウスカーソルから定規 (ruler) までの距 離を極座標でも表示 (距離、および角度または傾き) するかどうかを決定しま す。これはデフォルトのキー割り当て '5' に対応します。
ボタン 2 の gnuplot の永続的なラベルを定義するには、オプション labels を使用します。デフォルトは nolabels で、ボタン 2 は単に一時 的なラベルをマウス位置に描画します。ラベルは現在の mouseformat の設 定に従って書かれます。labeloptions 文字列は、コマンド set label コ マンドに渡されます。そのデフォルトは "point pointstyle 1" で、これはラ ベル位置に小さいプラス (+) を描画します。一時的なラベルは、その次の replot、またはマウスズーム操作では現れません。永続的なラベルは、ラベ ルの点の上で Ctrl キーを押してボタン 2 をクリックすることで消すことが できます。実際のラベルの位置にどれ位近くでクリックしなければいけないか の閾値も pointsize で決定されます。
オプション verbose が ON の場合、実行時の報告コマンドが表示されます。 このオプションはドライバウィンドウ上で 6 を打つことで ON/OFF がスイ ッチできます。デフォルトでは verbose は OFF になっています。
ドライバウィンドウ上で 'h' を打つと、マウスとキー割当の短い説明が表示 されます。これは、ユーザ定義のキー割当、すなわち bind コマンドによる hotkeys (以下参照: bind (21.1)) も表示されます。ユーザ定義の hotkeys は デフォルトのキー割当を無効にします。 以下も参照: bind (21.1), label (88.36)。
set mouse mouseformat は、ボタン 1 とボタン 2 の作用時 (座標をクリッ
プボードへコピーし、マウス位置に一時的に注釈をつける) の文字列の書式用
に使われます。引数が整数の場合、以下の表にある書式オプションの一つを選択します。引数が文字列の場合は、書式オプション 6 の sprintf() の書式文字列として使われますので、2 つの実数の指定子を含む必要があります。例:
`set mouse mouseformat "mouse x,y = %5.2g, %10.3f"`.
以下の書式が利用可能です:
0 デフォルト (1 と同じ) 1 軸の座標 1.23, 2.45 2 グラフ座標 (0 から 1 まで) /0.00, 1.00/ 3 x = timefmt y = 軸座標 [(`set timefmt` の設定), 2.45] 4 x = 日付 y = 軸座標 [31. 12. 1999, 2.45] 5 x = 時刻 y = 軸座標 [23:59, 2.45] 6 x = 日付/時刻 y = 軸座標 [31. 12. 1999 23:59, 2.45] 7 `set mouse mouseformat` による書式、例: "mouse x,y = 1.23, 2.450"
オプション zoomcoordinates は、拡大の際に、拡大の枠の端にその座標を 書くかどうかを決定し、デフォルトでは ON になっています。
オプション zoomjump が ON の場合、ボタン 3 による拡大範囲の選択を開 始すると、マウスポインタは自動的に少しだけずれた位置に移動します。これ は、ごく小さい (または空でさえある) 拡大範囲を選択してしまうことを避け るのに便利でしょう。デフォルトでは zoomjump は OFF です。
書式:
set multiplot
{ title <page title> {font <fontspec>} {enhanced|noenhanced} }
{ layout <rows>,<cols>
{rowsfirst|columnsfirst} {downwards|upwards}
{scale <xscale>{,<yscale>}} {offset <xoff>{,<yoff>}}
{margins <left>,<right>,<bottom>,<top>}
{spacing <xspacing>{,<yspacing>}}
}
set multiplot {next|previous}
unset multiplot
出力形式 (terminal) によっては、コマンド unset multiplot が与えられ るまで何の描画も表示されないことがあります。この場合このコマンドにより ページ全体の描画が行なわれ、gnuplot は標準の単一描画モードになります。 それ以外の出力形式では、各 plot コマンドがそれぞれ表示を更新します。
コマンド clear は、次の描画に使う長方形領域を消すのに使えます。典型 的には、グラフを "挿入" するような場合に必要です。
定義済の見出しやベクトルは、各描画において、毎回現在のサイズと原点に従 って書かれます (それらが screen 座表系で定義されていない場合)。それ 以外の全ての set で定義されるものも各描画すべてに適用されます。もし 1 度の描画にだけ現われて欲しいものを作りたいなら、それが例えば日付 (timestamp) だとしたら、set multiplot と unset multiplot で囲まれ たブロック内の plot (または splot, replot) 命令の一つを set time と unset time ではさんでください。
multiplot のタイトルは、個々の描画タイトルがあったとしても、それとは別 のもので、ページの上部にそのためのキャンバス全体の幅にわたるスペースが 確保されます。
layout が指定されていない場合、あるいはより良い位置合わせをしたい場合 は、コマンド set origin と set size 各描画で正しい位置に設定する必 要があります。詳細は、以下参照: set origin (88.56), set size (88.73)。
例:
set multiplot
set size 0.4,0.4
set origin 0.1,0.1
plot sin(x)
set size 0.2,0.2
set origin 0.5,0.5
plot cos(x)
unset multiplot
これは、cos(x) のグラフを、sin(x) の上に積み重ねて表示します。
set size と set origin は全体の描画領域を参照し、それは各描画で利 用されます。以下も参照: set term size (8)。描画境界を一列に揃えたいなら ば、set margin コマンドで、境界の外の余白サイズを同じサイズに揃える ことが出来ます。その使用に関しては、以下参照: set margin (88.45)。余白サイズ は文字サイズ単位の絶対的な数値単位を使用することに注意してください。よ って残ったスペースに描かれるグラフは表示するデバイスの表示サイズに依存 します。例えば、プリンタとディスプレイの表示は多分違ったものになるでし ょう。
オプション layout により、各描画の前にそれぞれ与えていた set size や set origin コマンドなしに、単純な複数グラフの描画を作成できます。 それらの設定は自動的に行なわれ、いつでもその設定を変更できます。 layout では表示は < rows> 行と < cols> 列の格子に分割され、各格子は、 その後に続く対応する名前のオプションによって行 (rowsfirst)、あるいは列 (columnsfirst) が先に埋められて行きます。描画グラフの積み上げは下方向 (downwards) に、または上方向 (upwards) に伸びるようにできます。デ フォルトは rowsfirst で downwards です。 コマンド set multiplot next と set multiplot previous は、レイアウ トオプションを使用している場合のみに関係します。next は、格子内の次 の位置をスキップし、空白を残します。prev は、直前に描画した位置の直 前の格子位置に戻ります。
各描画は scale で伸縮を、offset で位置の平行移動を行なうことができ ます。scale や offset の y の値が省略された場合は、x の値がそれに使用 されます。unset multiplot により自動配置機能はオフになり、そして set size と set origin の値は set multiplot layout の前の状態に 復帰されます。
例:
set size 1,1
set origin 0,0
set multiplot layout 3,2 columnsfirst scale 1.1,0.9
[ ここには 6 つまでの描画コマンド ]
unset multiplot
上の例では 6 つの描画が 2 列の中に上から下へ、左から右へと埋められて行 きます。各描画は水平サイズが 1.1/2、垂直サイズが 0.9/3 となります。
他にも、そのレイアウト内のすべてのグラフに一様なマージンをオプション layout margins と spacing で設定することができますが、これは一緒に 使う必要があります。margins は、格子配置の複数グラフ全体の外側に対す るマージンを設定します。
spacing は、隣接する部分グラフ間の隙間を与えますが、character か screen 単位で指定することもできます。単一の値を指定すると、それは x, y の両方の方向に使用されますが、2 つの異なる値を指定することもできます。
一つの値に単位がなければ、直前のマージン設定のものを使用します。
例:
set multiplot layout 2,2 margins 0.1, 0.9, 0.1, 0.9 spacing 0.0
この場合、左にあるグラフの左の境界は、スクリーン座標の 0.1 に置かれ、 右にあるグラフの右の境界はスクリーン座標 0.9 の場所に置かれる、等とな ります。各グラフの隙間は 0 に指定しているので、内側の境界線は重なりま す。
例:
set multiplot layout 2,2 margins char 5,1,1,2 spacing screen 0, char 2
これは、左のグラフの境界は、キャンバスの左端から 5 文字幅の場所に、右 のグラフの右の境界は、キャンバスの端から 1 文字幅の場所にあるようなレ イアウトを生成します。下のマージンは 1 文字分の高さ、上のマージンは 2 文字分の高さになります。グラフ間の水平方向の隙間はありませんが、縦方向 には 2 文字分の高さに等しい隙間があります。
例:
set multiplot layout 2,2 columnsfirst margins 0.1,0.9,0.1,0.9 spacing 0.1
set ylabel 'ylabel'
plot sin(x)
set xlabel 'xlabel'
plot cos(x)
unset ylabel
unset xlabel
plot sin(2*x)
set xlabel 'xlabel'
plot cos(2*x)
unset multiplot
以下も参照
書式:
set mxtics {<freq> | default}
unset mxtics
show mxtics
これらの書式は mytics, mztics, mx2tics, my2tics, mrtics, mcbtics に対しても同じです。
< freq> は大目盛り間の、小目盛りによって分割される区間の数 (小目盛りの 数ではありません) です。通常の線形軸に対してはデフォルトの値は 2 か 5 で、これは大目盛りによって変化します。よって大目盛り間に 1 つ、または 4 つの小目盛りが入ることになります。default を指定することによって小 目盛りの数はデフォルトの値に戻ります。
軸が対数軸である場合、分割区間の数はデフォルトでは有意な数にセットされ ます (10 個の長さを元にして)。< freq> が与えられていればそちらが優先さ れます。しかし、対数軸では通常の小目盛り (例えば 1 から 10 までの 2, 3, ..., 8, 9 の刻み) は、9 つの部分区間しかありませんが、< freq> の設定は 10 とすることでそうなります。
小目盛りを任意の位置に設定するには、("< label> " < pos> < level> , ...) の 形式を set {x| x2| y| y2| z}tics で使用してください。ただし、< label> は 空 ("") で、< level> を 1 にします。
コマンド set m{x| x2| y| y2| z}tics は、大目盛りが一様の間隔の場合にのみ 働きます。もし全ての大目盛りが set {x| x2| y| y2| z}tics によって手動で 配置された場合は、この小目盛りのコマンドは無視されます。自動的な大目盛 りの配置と手動の小目盛りの配置は、set {x| x2| y| y2| z}tics と set {x| x2| y| y2| z}tics add とを使うことで共存できます。
例:
set xtics 0, 5, 10
set xtics add (7.5)
set mxtics 5
set logscale y
set ytics format ""
set ytics 1e-6, 10, 1
set ytics add ("1" 1, ".1" 0.1, ".01" 0.01, "10^-3" 0.001, \
"10^-4" 0.0001)
set mytics 10
デフォルトでは小目盛りの表示は、線形軸ではオフで、対数軸ではオンになっ ています。その設定は、大目盛りに対する axis| border と {no}mirror の指定を継承します。これらに関する情報については、以下参照:set xtics (88.104)。
書式:
set object <index>
<object-type> <object-properties>
{front|back|behind} {clip|noclip}
{fc|fillcolor <colorspec>} {fs <fillstyle>}
{default} {lw|linewidth <width>} {dt|dashtype <dashtype>}
unset object <index>
< object-type> は、rectangle, ellipse, circle, polygon のいずれ かです。個々のオブジェクトの型は、その型に特有の性質もいくつか持ってい ます。
front を指定すると、オブジェクトはすべての描画要素の前 (上) に描画さ
れますが、front と指定されたラベルよりは後ろ (下) になります。back
を指定すると、すべての描画要素、すべてのラベルの後ろに配置されます。
behind は、軸や back の長方形を含むすべてのものの後ろに配置されま
す。よって、
set object rectangle from screen 0,0 to screen 1,1 behind
デフォルトでは、オブジェクトは、少なくとも 1 つの頂点がスクリーン座標 で与えられていない限り、グラフ境界でクリッピングされます。noclip と 設定すると、グラフ境界でのクリッピングは無効になりますが、スクリーンサ イズに対するクリッピングは行われます。
オブジェクトの塗り潰しの色は < colorspec> で指定します。fillcolor は fc と省略できます。塗り潰しスタイルは < fillstyle> で指定します。詳細 は、以下参照: colorspec (19.1), fillstyle (88.74.4)。キーワード default を指定す ると、これらの属性は描画が実際に行われるときのデフォルトの設定を受け継 ぎます。以下参照: set style rectangle (88.74.9)。
set object <index> rectangle
{from <position> {to|rto} <position> |
center <position> size <w>,<h> |
at <position> size <w>,<h>}
長方形の位置は、対角に向かい合う 2 つの頂点 (左下と右上) の位置、ある いは中心点の位置と横幅 (< w> ) と縦幅 (< h> ) で指定できます。いずれの場合 も点の位置は、軸の座標 (first, second)、グラフ領域内の相対座標 (graph)、スクリーン座標 (screen) のいずれかを使用できます (以下参照: coordinates (11))。オプション at と center は同じ意味です。
例:
# 座標軸で囲まれた領域全体の背景を水色に set object 1 rect from graph 0, graph 0 to graph 1, graph 1 back set object 1 rect fc rgb "cyan" fillstyle solid 1.0
# 左下角が 0,0, 右上角が 2,3 の赤い四角を一つ置く set object 2 rect from 0,0 to 2,3 fc lt 1
# 青い境界の空 (塗り潰さない) 長方形を置く set object 3 rect from 0,0 to 2,3 fs empty border rgb "blue"
# 頂点は移動しないまま、塗り潰しと色をデフォルトに変更 set object 2 rect default
スクリーン座標で長方形の角を指定すると、それは現在のグラフ領域の端を越 えることも可能ですが、その他の場合は長方形はグラフ内に収まるようにクリ ッピングされます。
set object <index> ellipse {at|center} <position> size <w>,<h>
{angle <orientation>} {units xy|xx|yy}
{<other-object-properties>}
楕円の位置は、中心を指定し、その後ろに幅と高さ (主軸と副軸) を指定しま す。キーワード at と center は同じ意味です。中心の位置の指定には、 軸の座標 (first, second)、グラフ領域内の相対座標 (graph)、スクリ ーン座標 (screen) のいずれかを使用できます (以下参照: coordinates (11))。 主軸と副軸の長さは、軸の座標で与えなければいけません。楕円の向き (orientation) は、水平軸と楕円の主軸との間の角度で指定します。角度を与 えなければ、デフォルトの楕円の向きが代わりに使われます (以下参照:set style ellipse (88.74.10))。キーワード units は、楕円の軸の縮尺の制御に使 用します。units xy は、主軸は x 軸の単位で、副軸は y 軸の単位で計算 しますが、units xx は両軸とも x 軸の単位で縮尺し、units yy は両軸 とも y 軸の単位になります。 デフォルトは xy ですが、set style ellipse units の設定でいつでも変 更できます。
注意: x 軸と y 軸の縮尺が等しくない場合 (そして units xy の場合)、回 転後の主軸と副軸の比は正しくはなりません。
set object ellipse size < 2r> ,< 2r> と set object circle < r> とは、 一般には同じことにはならないことに注意してください。circle の半径は常 に x 軸の単位で計られ、よって x 軸と y 軸の縮尺が違ったり、描画のアス ペクト比が 1 でなくても、常に円が生成されます。units が xy に設定 されていれば、'set object ellipse' では、最初の < 2r> は x 軸の単位で、 後ろの < 2r> は y 軸の単位で計られますが、これは x 軸と y 軸の縮尺が同 じで、かつ描画のアスペクト比が 1 である場合のみ円を生成することを意味 します。しかし、units を xx や yy にセットすれば、コマンド set object で指定した直径は同じ単位で計算されるので、楕円は正しいア スペクト比を持ち、描画をリサイズしてもそのアスペクト比は保持されます。
set object <index> circle {at|center} <position> size <radius>
{arc [<begin>:<end>]}
{<other-object-properties>}
円の位置は、中心を指定し、その後ろに半径を指定します。キーワード at と center は同じ意味です。その位置と半径には、x 軸の座標、グラフ領域 内の相対座標 (graph)、スクリーン座標 (screen) のいずれかを使用でき ます (以下参照: coordinates (11))。そのいずれの場合でも、半径は軸、グラフ、 スクリーンの水平方向の縮尺に対して計られ、水平方向と垂直方向の縮尺にず れがあっても、結果が常に正しく円になるように直されます。円をグラフの座 標で描きたい (つまり水平軸と垂直軸のスケールが違う場合にはそれが楕円と して表示されるようにしたい) 場合は、代わりに set object ellipse を使 ってください。
デフォルトでは、完全な円が描画されます。オプションの arc に開始角と 終了角を度を単位として指定すると円弧を描画します。円弧は、常に反時計回 りに描かれます。
以下も参照: set object ellipse (88.54.2)。
set object <index> polygon
from <position> to <position> ... {to <position>}
from <position> rto <position> ... {rto <position>}
多角形の位置は、頂点の位置の列を与えることで指定できます。それらは、軸 の座標 (first, second)、グラフ領域内の相対座標 (graph)、スクリー ン座標 (screen) のいずれかを使用できます。相対的な座標 (rto) を指定 する場合は、その座標系は前の頂点と同じ座標系でなければいけません。以下参照: coordinates (11)。
例:
set object 1 polygon from 0,0 to 1,1 to 2,0 set object 1 fc rgb "cyan" fillstyle solid 1.0 border lt -1
書式:
set offsets <left>, <right>, <top>, <bottom>
unset offsets
show offsets
各オフセットは定数、または数式が使え、それらのデフォルトの値は 0 です。 デフォルトでは、左右のオフセットは x1 軸と同じ単位で指定し、上下のオフ セットは y1 軸と同じ単位で指定しますが、キーワード "graph" を用いるこ とで軸の全範囲に対する割合としてオフセットを指定することもできます。正 のオフセットの値は、軸の範囲を指定された方向へ伸ばします。例えば正の下 方向のオフセットは y の最小値をより小さな値にします。許されている範囲 での負のオフセットは、自動縮尺、あるいはクリッピングとの思いもよらぬ結 果を生む可能性があります。自動縮尺機能から軸の範囲の調節を守りたい場合 は、"set auto fix" も指定するといいでしょう。
例:
set auto fix
set offsets graph 0.05, 0, 2, 2
plot sin(x)
この sin(x) のグラフの y の範囲は [-3:3] になります。それは、関数の y の範囲は [-1:1] に自動縮尺されますが、垂直方向のオフセットがそれぞ れ 2 であるためです。x の範囲は [-11:10] になりますが、これはデフォ ルトが [-10:10] でその全範囲が左に 0.05 の割合だけ伸ばされるためです。
書式:
set origin <x-origin>,<y-origin>
書式:
set output {"<filename>"}
show output
ファイル名は引用符で囲まなければなりません。ファイル名が省略された場合 は、直前の set output で開かれたファイルがクローズされ、新たな出力が 標準出力 (STDOUT) に送られます。(もし、set output "STDOUT" とすると 出力は "STDOUT" という名前のファイルに送られるかもしれません ! ["かも しれない" というのは、例えば x11 や wxt などの terminal (出力形式) では set output が無視されるからです。])
set terminal と set output の両方を指定する場合、set terminal を 先に指定する方が安全です。それは、ある種の terminal では、OS が必要と するフラグをセットすることがあるからです。例えば、バイナリファイルに対 して別々の open コマンドを必要とするような OS などがそれに該当します。
パイプをサポートする環境では、パイプ出力も有用です。例えば以下の通りです:
set output "|lpr -Plaser filename"
set term png; set output "|display png:-"
MS-DOS では、set output "PRN" とすると標準のプリンタに出力されます。 VMS では出力は任意のスプール可能なデバイスに送ることが出来ます。
書式:
set parametric
unset parametric
show parametric
2 次元グラフにおいては、媒介変数表示関数はひとつの媒介変数に対する 2 つの関数で定められます。例としては plot sin(t),cos(t) とすることによっ て円が描けます (アスペクト比が正しく設定されていれば。以下参照:set size (88.73))。gnuplot は、両方の関数が媒介変数による plot のために 与えられていなければエラーメッセージを出します。
3 次元グラフにおいては面は x = f(u,v), y = g(u,v), z = h(u,v) で定め られます。よって 3 つの関数を組で指定する必要があります。例としては、 cos(u)*cos(v),cos(u)*sin(v),sin(u) とすることによって球面が描けます。 gnuplot は、3 つ全部の関数が媒介変数による splot のために与えられ ていなければエラーメッセージを出します。
これによって表現できる関数群は、単純な f(x) 型の関数群の内包することに なります。なぜならば、2 つ (3 つ) の関数は x, y (, z) の値を独立に計算 する記述ができるからです。実際、t,f(t) のグラフは、一番目の関数のよう な恒等関数を用いて x の値が計算される場合に f(x) によって生成されるグ ラフと等価です。同様に、3 次元での u,v,f(u,v) の描画は、f(x,y) と等価 です。
媒介変数表示関数は、x の関数、y の関数 (、z の関数)の順に指定し、それ らは共通の媒介変数およびその変域で定義されることに留意して下さい。
さらに、set parametric の指定は、新しい変数変域を使用することを暗に 宣言します。通常の f(x) や f(x,y) が xrange、yrange (、zrange) を使用 するのに対して、媒介変数モードではそれに加えて、trange, urange, vrange を使用します。これらの変域は set trange, set urange, set vrange によって直接指定することも、plot や splot で指定することもできます。 現時点では、これらの媒介変数のデフォルトの変域は [-5:5] となっています。 将来的にはこれらのデフォルト値をもっと有意なものに変更する予定です。
set paxis <axisno> {range <range-options> | tics <tic-options>}
show paxis <axisno> {range | tics}
さらにコマンドshow plot add2history は、この現在の描画コマンドを history に書き出します。これは、replot を使って直前の描画コマンド に曲線を追加した場合、そしてコマンド行全体をすぐに編集したい場合に便利 です。
書式 (オプションは任意の順で与えることができます):
set pm3d
set pm3d {
{ at <position> }
{ interpolate <steps/points in scan, between scans> }
{ scansautomatic | scansforward | scansbackward | depthorder }
{ flush { begin | center | end } }
{ ftriangles | noftriangles }
{ clip1in | clip4in }
{ corners2color
{ mean|geomean|harmean|rms|median|min|max|c1|c2|c3|c4 }
}
{ hidden3d {<linestyle>} | nohidden3d }
{ implicit | explicit }
{ map }
}
show pm3d
unset pm3d
splot コマンドで with pm3d を指定した場合、またはデータや関数描画ス
タイル (style) が大域的に pm3d にセットされている場合、あるいは、
pm3d モードが set pm3d implicit となっている場合は、pm3d のカラー曲
面が描画されます。後の 2 つの場合は、plot コマンドで指定したスタイルで
生成される網目に p3md 曲面を追加する形で描画します。例えば、
splot 'fred.dat' with lines, 'lola.dat' with lines
splot 'fred.dat' with lines, 'lola.dat' with pm3d
gnuplot の起動時はそのモードは explicit になっています。歴史的、そし て互換性のために、コマンド set pm3d; (すなわちオプションを指定しない 場合) と set pm3d at X ... (すなわち at が最初のオプションの場合) はモードを implicit に変更します。コマンド set pm3d; は、その他の オプションをそれらのデフォルトの状態に設定します。
デフォルトのデータ/関数の描画スタイルを pm3d にしたい場合は、例えば
set style data pm3d
いくつかの描画においては、それらはコマンドラインで与えられた順に描画さ れることに注意してください。これは特に、以前の描画を上書きしてそれでその一部を隠してしまう可能性があるような曲面の塗りつぶしの際に関心を持たれるでしょう。
p3md の色付けは、3 つの異なる位置 top, bottom, surface のいずれ
か、またはすべてに行えます。以下参照: pm3d position (88.61.2)。以下のコマンドは、異なった高さで 3 つの色付きの曲面を描きます:
set border 4095
set pm3d at s
splot 10*x with pm3d at b, x*x-y*y, x*x+y*y with pm3d at t
以下も参照: set palette (88.62), set cbrange (88.134), set colorbox (88.15)。そしてもちろ んデモファイル demo/pm3d.dem も参考になるでしょう。
まず、地図/曲面がどのように描かれるのかについて記述します。入力データ は、関数を評価して得られるかまたは splot data file から得られます。 曲面は、走査 (孤立線) の繰り返しで構成されます。pm3d アルゴリズムでは、 最初の走査で検出された隣り合う 2 点と、次の走査で検出された他の 2 点の 間の領域が、これら 4 点の z の値 (または追加された 'color' 用の列の値、 以下参照: using (77.3.9)) に従って灰色で (または カラーで) 塗られます。デフォ ルトでは 4 つの角の値の平均値が使われますが、それはオプション corners2color で変更できます。それなりの曲面を描くためには、隣り合う 2 点の走査が交差してはいけなくて、近接点走査毎の点の数が違いすぎてはい けません。もちろん、最も良いのは走査の点の数が同じことです。他には何も 必要ではありません (例えばデータは格子状である必要もない)。他にもこの pm3d アルゴリズムは、入力された (計測された、あるいは計算された) 領域 の外には何も描かない、という長所があります。
曲面の色づけは、以下のような入力データに関して行われます:
1. 関数、または 1 つか 3 つのデータ列からなるデータの splot: 上に述べ た四角形の 4 つの角の z 座標の平均値 (または corners2color) から、灰 色の範囲 [0:1] を与える zrange または cbrange の範囲 [min_color_z,max_color_z] への対応により、灰色/カラーの値が得られます。 この値は、直接灰色の色地図用の灰色の値として使うことができます。正規化 された灰色の値をカラーに対応させることもできます。完全な説明は、以下参照: set palette (88.62)。
2. 2 つか 4 つのデータ列からなるデータの splot: 灰色/カラーの値は、z の値の代わりに最後の列の座標を使って得られますので、色と z 座標が独立 なものになります。これは 4 次元データの描画に使うことができます。
他の注意:
1. 物理学者の間では、gnuplot の文書やソースに現われる 'iso_curve' (孤 立線) という言葉よりも、上で言及した '走査 (scan)' という言葉の方が使 われています。1 度の走査と他の走査の記録により色地図を評価する、という のはそういう意味です。
2. 'gray' や 'color' の値 (scale) は、滑らかに変化するカラーパレットへ の、連続な変数の線形写像です。その写像の様子は描画グラフの隣に長方形で 表示されます。この文書ではそれを "カラーボックス (colorbox)" と呼び、 その変数をカラーボックス軸の変数と呼びます。以下参照: set colorbox (88.15),set cbrange (88.134)。
塗られた四角形は、次から次へと描画されて行きます。曲面を描画する場合 (at s)、後の四角形が前のものに重なり (上書きし) ます (gnuplot は塗ら れた多角形の網の重なりの相互作用を計算するような仮想現実ツールではあり ません)。 最初に走査されるデータを最初に描くか最後に描くかを切替えるス イッチオプション scansforward と scansbackward を試してみてくださ い。デフォルトは scansautomatic で、これは gnuplot 自身に走査の順を 推測させます。一方で、オプション depthorder は四角形の順序を完全に再 構成します。塗りつぶしは深さ順に並び変えされた後で行われ、これによりか なり複雑な曲面でも視覚的なものにすることができます。詳細は、以下参照:pm3d depthorder (88.61.3)。
2 回の連続する走査で点の数が同じでなかった場合、四角形の点の取り始めを、 両方の走査の最初から (flush begin) にするか、最後から (flush end) にするか、真中から (flush center) にするかを決定しなければいけません。 flush (center| end) は scansautomatic とは両立せず、よって flush center または flush end を指定して scansautomatic が設定さ れた場合、それは無言で scansforward に変更されます。
2 回の連続する走査で点の数が同じでなかった場合、個々の走査で点が足りな い場合に、走査の最後に色三角形を描くかどうかをオプション ftriangles は指示します。これは滑らかな色地図の境界を描くのに使われます。
gnuplot は、曲面の塗り潰しにおいては、本当の隠面処理は行いませんが、た
いていは遠い方から近い方へ順に四角形要素を塗り潰すことで十分なできあが
りになります。このモードは、以下のオプションを使うことで選択できます:
set pm3d depthorder hidden3d
色づけの設定はカラーボックスの描画と同様に set palette で決定されま す。一つの描画では一つのパレットのみが存在し得ます。いくつもの曲面を異 なるパレットで描画するには、origin と size を固定して mutiplot を使うことで行えます。出力ドライバが利用できる色を使い尽くしてしまう場 合には set palette maxcolors を使うことを忘れずに。
描画される各 pm3d 四角形には一つの灰色/カラー値が対応します (それは色 勾配ではなく無地の色です)。その値は、corners2color < option> に従って 4 つの角の z 座標から計算されます。 4 列のデータ (x,y,z,color) の場合:
4 列目にデータを与えた場合、それを通常は別にパレットに割り当てる灰色階 調値とみなします。個々の四角形の彩色は上と同様に行いますが、色の値は z の値とは切り離されます。別の彩色オプションにより、4 列目のデータに RGB 色を与えることもできます。以下参照: rgbcolor variable (19.1.3)。この場合、描 画コマンドは以下のようにする必要があります:
splot ... using 1:2:3:4 with pm3d lc rgb variable
与えられた節点に対して、その周りの 4 つの節点の平均化された (x,y) 座標 から角を得て四角形を作って、その四角形を節点の色で塗る、といったような 他の描画アルゴリズムが将来実装されるかもしれません。 これは、イメージの描画 (2 次元の格子) に対しては image と rgbimage スタイルによって既に行なわれています。
z の値の範囲と曲面の色の値の範囲は、z と cb に関する set log 同様、 set zrange と set cbrange によって独立に調整し得ることに注意して ください。色地図は cb 軸のみで調節されます。以下も参照: set view map (88.90),set colorbox (88.15)。
推奨する使用例:
set pm3d at s depthorder border lw 0.2 lt black
unset hidden3d
unset surf
splot x*x+y*y linecolor rgb "blue" # こうしないと黒
注: 非推奨のオプション set pm3d hidden3d N もまだ使えますが、これは set pm3d border ls N と同じです。
正の m, n に対しては各四角形、または三角形は、それぞれの方向に m 回、 n 回補間されます。負の m, n では補間の頻度は、少なくとも | m| , | n| 点が 描画されるように選択されます。これは特別な格子関数と見なすことができま す。
注意: interpolate 0,0 は、自動的に最適な補間曲面点数を選択します。
注意: corners2color で幾何平均 (geomean) のような非線形評価が設定され ていたとしても、現在の色の補間は常に線形補間で行われます。
旧式のコマンド set pm3d map は以下の一連のものと同値です:set pm3d at b; set view map scale 1.0; set style data pm3d;set style func pm3d;
カラーパレットは、多角形の色の塗りつぶしと滑らかな色のパレットをサポー トした出力形式を必要とし、それは現在、pm3d で一覧表示される出力形式 で使用可能です。色の値の範囲は、set cbrange と set log cb で独立に 調整可能です。カラーパレット全体は colorbox 中に表示されます。
書式:
set palette
set palette {
{ gray | color }
{ gamma <gamma> }
{ rgbformulae <r>,<g>,<b>
| defined { ( <gray1> <color1> {, <grayN> <colorN>}... ) }
| file '<filename>' {datafile-modifiers}
| functions <R>,<G>,<B>
}
{ cubehelix {start <val>} {cycles <val>} {saturation <val>} }
{ model { RGB | HSV | CMY | YIQ | XYZ } }
{ positive | negative }
{ nops_allcF | ps_allcF }
{ maxcolors <maxcolors> }
}
show palette
show palette palette <n> {{float | int}}
show palette gradient
show palette fit2rgbformulae
show palette rgbformulae
show colornames
set palette は (すなわちオプションなしでは) デフォルトの値を設定しま す。それ以外の場合、オプションは任意の順に与えることができます。 show palette は、現在のパレットの属性を表示します。
show palette gradient は、パレットの勾配 (gradient) の定義が (それが 適切であれば) 表示されます。show palette rgbformulae は、定義済で利 用できる、灰色値からカラーへの変換公式が表示されます。 show colornames は、認識できる色名を表示します。
show palette palette < n> は、< n> 個の離散的な色を持つパレットの、現 在のパレットの設定によって計算される RGB の値の組とパレットの表を、画 面、または set print で指定されたファイルに書き出します。デフォルト の広い表は、追加のオプション float または int によって、3 列の [0..1] の実数値だけにするか [0..255] の整数値だけにするかをそれぞれ指定できま す。この方法で gnuplot のカラーパレットを、Octave のような他の画像アプ リケーションに渡すことができます。この他にも、コマンド test palette で、現在のパレットの R,G,B 成分の対応状態 (profile) を描画しその値をデ ータブロック $PALETTE に残させることもできます。
以下のオプションは、色付けの属性を決定します。
このパレットを使用する図は、gray か color になります。例えば、 pm3d カラー曲面では、範囲 [min_z,max_z] が灰色の範囲 [0:1] に対応し ていて、微小曲面四角形の 4 つの角の z 座標の平均値をこの範囲の中に対応 させることで各微小部分の灰色の値 (gray) が得られます。この値は、灰色階 調の色地図での灰色の値として直接使うことができますし、カラーの色地図で は、その灰色の値から (R,G,B) への変換、すなわち [0:1] から ([0:1],[0:1],[0:1]) への写像が使われます。
基本的に、2 種類の異なる写像方式が利用可能です: 1 つは灰色からカラーへ の解析的な公式、もう一つは離散的な対応表の補間によるものです。 palette rgbformulae と palette functions が解析的な公式用で、 palette defined と palette file が補間表用です。palette rgbformulae は postscript 出力のサイズを小さくすることができます。
コマンド show palette fit2rgbformulae は、現在の set palette に最 も良く対応する set palette rgbformulae を見つけ出します。当然、それ は rgbformulae パレット以外に対しても意味を持ちます。このコマンドは主 に、パレットの rgbformulae 定義が gnuplot と同じ物を使っている外部プロ グラム、例えば zimg などにとって有用です (
)。
set palette gray は、灰色階調のみのパレットにし、 set palette rgbformulae, set palette defined, set palette file, set palette functions はカラーパレットにします。灰色パレットから直前 のカラーパレットへ、set palette color で簡単に復帰できます。
set palette gamma < gamma> による自動的なガンマ補正は、灰色のパレット (set palette gray) と、cubehelix カラーパレット形式に行われます。 gamma = 1 の場合は、線形の光度勾配を生成します。以下参照:test palette (93)。
出力形式の多くは、有限個の色数しかサポートしていません (例えば gif で は 256 個)。デフォルトの gnuplot の線種色を割り当てた後の残りの有効な 色領域は、デフォルトでは pm3d 用に保存されます。よって、複数のパレット を使用するような multiplot は、最初のパレットがすべての有効な色の配置 として使用されてるので、失敗してしまうでしょう。このような制限は、十分 小さい値 N で set palette maxcolors < N> を使うことで緩和できます。こ のオプションは、N 個の離散的な色を、連続的なパレットから等間隔なサンプ リングで選択します。不等間隔な N 個の離散色を使いたい場合は、一つの連 続的なパレットの代わりに set palette defined を使用してください。
RGB 色空間が作業を行うのに常にもっとも有用な色空間であるとは限らない、 という理由で、色空間は model を使うことで、RGB, HSV, CMY, YIQ, XYZ のいずれかに変更できます。RGB 以外の色空間ではset palette defined の表で色名を使うと、それはおかしな色になります。 全ての説明は RGB 色空間用に書いてありますが、それぞれの色空間で、例え ば R は H, C, Y, X のことを意味することに注意してください (G, B も同様)。
全ての色空間で、全ての値は [0,1] に制限されています。
RGB は赤、緑、青を、CMY は水色 (Cyan)、紫 (Magenta)、黄 (Yellow) を、 HSV は色相 (Hue)、彩度 (Saturation)、明度 (Value) をそれぞれ意味します。 YIQ は 全米商業カラーテレビ放送協会 (the U.S. Commercial Color Television Broadcasting) の使ったカラーモデルで、RGB 記録方式を元にし ていますが、白黒テレビに対する後方互換性を持っています。XYZ は CIE ('Commission Internationale de l'Eclairage'; 国際照明委員会) が定義し た色モデルの 3 つの原刺激値です。 色モデルのより詳しい情報については以下を参照してください:
http://en.wikipedia.org/wiki/Color_space
RGB の色空間では、いくつかの良い割り当て公式があります:
7,5,15 ... 伝統的 pm3d (黒-青-赤-黄) 3,11,6 ... 緑-赤-紫 23,28,3 ... 海 (緑-青-白); 他の組み合わせも試してみてください 21,22,23 ... 温度色 (黒-赤-黄-白) 30,31,32 ... 白黒のカラー表示化 (黒-青-紫-黄-白) 33,13,10 ... 虹 (青-緑-黄-赤) 34,35,36 ... AFM 温度色 (黒-赤-黄-白)
HSV 色空間でのフルカラーパレット:
3,2,2 ... 赤-黄-緑-水色-青-紫-赤
rgbformulae という名前で呼ばれていても、例の通り、それらの関数は実際 には < H> ,< S> ,< V> または < X> ,< Y> ,< Z> , ... といった色の成分を決定するか もしれないということに注意してください。
図の色を反転させるには positive や negative を使ってください。
他の色体系に対する最も良い rgbformulae の集合は、以下のコマンドで見つけることができることを覚えておいてください。
show palette fit2rgbformulae
書式:
set palette defined { ( <gray1> <color1> {, <grayN> <colorN>}... ) }
< grayX> は [0,1] に割り当てられるべき灰色値で、< colorX> はそれに対応す る RGB 色です。カラー値は 3 種類の方法で指定することができます:
<color> := { <r> <g> <b> | '<color-name>' | '#rrggbb' }
赤、緑、青に対応する空白で区切られた 3 つの値 (それぞれ [0,1] 内)、引 用符でくくられた色名、または引用符でくくられた X 形式の指定方式、のい ずれかです。勾配の定義では、これらの 3 種の型を自由に組み合わせること ができますが、色空間として RGB でないものが選択された場合色名 "red" は 少し違ったものになるでしょう。使用できる色名は show colornames でそ の一覧を見ることができます。
< r> と書いても、HSV 色空間ではそれは < H> 成分を、CIE-XYZ 空間では < X> を、といったように選択されたカラーモデルに依存して意味が違うことに注意 してください。
< gray> の値は実数の昇順に並べる必要があります。その列の値は自動的に [0,1] に変換されます。
カッコつきの勾配の定義なしで set palette defined とした場合、RGB 色 空間にし、あらかじめ設定されたフルスペクトル色勾配を使用します。勾配を 表示するには show palette gradient を使用してください。
例:
灰色のパレット (役に立たないが教訓的な) を生成するには:
set palette model RGB
set palette defined ( 0 "black", 1 "white" )
青黄赤のパレット (全てが等価の) を生成するには:
set palette defined ( 0 "blue", 1 "yellow", 2 "red" )
set palette defined ( 0 0 0 1, 1 1 1 0, 2 1 0 0 )
set palette defined ( 0 "#0000ff", 1 "#ffff00", 2 "#ff0000" )
虹のようなパレットを生成するには:
set palette defined ( 0 "blue", 3 "green", 6 "yellow", 10 "red" )
HSV 色空間でのフルカラースペクトル:
set palette model HSV
set palette defined ( 0 0 1 1, 1 1 1 1 )
set palette defined ( 0 0 1 0, 1 0 1 1, 6 0.8333 1 1, 7 0.8333 0 1)
MATLAB で使われるデフォルトパレットの近似:
set pal defined (1 '#00008f', 8 '#0000ff', 24 '#00ffff', \
40 '#ffff00', 56 '#ff0000', 64 '#800000')
等間隔な少しの色だけのパレットを生成するには:
set palette model RGB maxcolors 4
set palette defined ( 0 "yellow", 1 "red" )
'交通信号' (滑らかではなく gray = 1/3, 2/3 で跳びを持つ):
set palette model RGB
set palette defined (0 "dark-green", 1 "green", \
1 "yellow", 2 "dark-yellow", \
2 "red", 3 "dark-red" )
例:
フルカラーパレットを生成するには:
set palette model HSV functions gray, 1, 1
黒から金色への良いパレット:
set palette model XYZ functions gray**0.35, gray**0.5, gray**0.8
ガンマ補正の白黒のパレット:
gamma = 2.2
color(gray) = gray**(1./gamma)
set palette model RGB functions color(gray), color(gray), color(gray)
D A Green (2011) http://arxiv.org/abs/1108.5083
set palette cubehelix start 0.5 cycles -1.5 saturation 1
set palette gamma 1.5
例によって、< filename> が '-' の場合は、データがインライン形式で引き 続いて与えられ、一つの e のみの行でそれが終了することを意味します。
勾配 (gradient) を表示するには show palette gradient を使用してくだ さい。
例:
RGB のパレットを [0,255] の範囲で読み込む:
set palette file 'some-palette' using ($1/255):($2/255):($3/255)
等距離の虹色 (青-緑-黄-赤) パレット:
set palette model RGB file "-"
0 0 1
0 1 0
1 1 0
1 0 0
e
バイナリパレットファイルも同様にサポートされています。以下参照:binary general (77.2.1)。R,G,B の double のデータの 64 個の 3 つ組をファイル
palette.bin に出力し、それを読み込む例:
set palette file "palette.bin" binary record=64 using 1:2:3
ガンマ補正は、cubehelix カラーパレット形式には適用されますが、他の色形 式には適用されません。しかし、明示的な色関数にガンマ補正を実装するのは 難しくありません。
例:
set palette model RGB
set palette functions gray**0.64, gray**0.67, gray**0.70
補間された勾配を使ってガンマ補正を行うには、適当なカラーに中間の値を指 定します。
set palette defined ( 0 0 0 0, 1 1 1 1 )
の代わりに例えば以下を指定してください:
set palette defined ( 0 0 0 0, 0.5 .73 .73 .73, 1 1 1 1 )
または、線形補間が "ガンマ補正" の補間に十分良く適合するまでより良い中 間の点を探してください。
pm3d 曲面を PostScript ファイルへ書いている場合、gnuplot に付属する
awk スクリプト pm3dCompress.awk を使うことで、そのファイルサイズを
50% まで小さくできるかもしれません。データが四角形の格子状になっている
場合は、スクリプト pm3dConvertToImage.awk を使うことでより大きな圧縮
率が得られる可能性があります。
使用法:
awk -f pm3dCompress.awk thefile.ps >smallerfile.ps awk -f pm3dConvertToImage.awk thefile.ps >smallerfile.ps
書式:
set pointsize <multiplier>
show pointsize
デフォルトは 1.0 倍です。画像データ出力では、大きいポイントサイズの方 が見やすいでしょう。
一つの描画に対するポイントサイズは plot コマンドの上でも変更できます。 詳細は、以下参照: plot with (77.12)。
ポイントサイズの設定は、必ずしも全ての出力形式でサポートされているわけ ではないことに注意してください。
書式:
set polar
unset polar
show polar
極座標モードでは、仮変数 (t) は角度を表します。t のデフォルトの範囲は [0:2*pi] ですが、単位として度が選択されていれば [0:360] となります (以下参照: set angles (88.1))。
コマンド unset polar は描画方法をデフォルトの xy 直交座標系に戻しま す。
set polar コマンドは splot ではサポートされていません。splot に 対する同様の機能に関しては、以下参照: set mapping (88.44)。
極座標モードでは t の数式の意味は r=f(t) となり、t は回転角となります。 trange は関数の定義域 (角度) を制御し、rrange, xrange, yrange はそれぞ れグラフの x,y 方向の範囲を制御することになります。これらの範囲と rrange は自動的に設定されるか、または明示的に設定できます。詳細に関し ては、以下参照: set rrange (88.70), set xrange (88.103)。
例:
set polar
plot t*sin(t)
set trange [-2*pi:2*pi]
set rrange [0:3]
plot t*sin(t)
最初の plot はデフォルトの角度の範囲の 0 から 2*pi を使います。動径 方向とグラフのサイズは自動的に伸縮されます。2 番目の plot は角度の定 義域を拡張し、グラフのサイズを原点から 3 の幅に制限します。これは x,y のそれぞれの方向を [-3:3] に制限することになります。
set size square とすると gnuplot はアスペクト比 (縦横の比) を 1 に するので円が (楕円でなく) 円に見えるようになります。 以下も参照
および
書式:
set print
set print "-"
set print "<filename>" [append]
set print "|<shell_command>"
set print $datablock [append]
パラメータなしの set print は、出力を < STDERR> に復帰させます。"-" という < filename> は < STDOUT> を意味します。append フラグはファイル を追加 (append) モードで開くことを意味します。パイプをサポートするプラ ットホーム上では、< filename> が "| " で始まっていたら、< shell_command> へのパイプが開かれます。
コマンド print の対象は名前付きデータブロックでも構いません。データ ブロック名は '$' で始まります。以下参照: inline data (77.3.4)。
1) `set psdir` を指定した場合はそのディレクトリ
2) 環境変数 GNUPLOT_PS_DIR で指定したディレクトリ
3) 組み込まれたヘッダー、またはデフォルトのシステムディレクトリ
4) `set loadpath` で指定したディレクトリ
書式:
set samples <samples_1> {,<samples_2>}
show samples
デフォルトではサンプル数は 100 点と設定されています。この値を増やすと より正確な描画が出来ますが遅くなります。このパラメータはデータファイル の描画には何の影響も与えませんが、補間/近似のオプションが使われている 場合はその限りではありません。2 次元描画については plot smooth を、 3 次元描画に関しては、以下参照: set dgrid3d (88.22)。
2 次元のグラフ描画が行なわれるときは < samples_1> の値のみが関係します。
隠線処理なしで曲面描画が行なわれるときは、samples の値は孤立線毎に評価 されるサンプル数の指定になります。各 v-孤立線は < samples_1> 個のサンプ ル点を持ち、u-孤立線は < samples_2> 個のサンプル数を持ちます。< samples_1> のみ指定すると、< samples_2> の値は < samples_1> と同じ値に設定されます。 以下も参照: set isosamples (88.34)。
set size {{no}square | ratio <r> | noratio} {<xscale>,<yscale>}
show size
< xscale> と < yscale> は描画全体の拡大の倍率で、描画全体とはグラフとラ ベルと余白の部分を含みます。
重要な注意:
gnuplot の以前の版では、`set size` の値を、出力する描画領域
(キャンバス) のサイズを制御するのにも使っていた出力形式もありま
したが、すべての出力形式がそうだったわけではありませんでした。
現在は、ほとんどの出力形式が以下のルールに従います:
set term < terminal_type> size < XX> , < YY> は、出力ファイルのサイズ、 または "キャンバス" のサイズを制御します。サイズパラメータの有効な値に ついては、個々の出力形式のヘルプを参照してください。デフォルトでは、グ ラフはそのキャンバス全体に描画されます。
set size < XX> , < YY> は、描画自体をキャンバスのサイズに対して相対的に 伸縮させます。1 より小さい伸縮値を指定すると、グラフはキャンバス全体を 埋めず、1 より大きい伸縮値を指定すると、グラフの一部分のみがキャンバス 全体に合うように描画されます。1 より大きい伸縮値を指定すると、ある出力 形式では問題が起こるかもしれないことに注意してください。
ratio は、指定した < xscale> , < yscale> の描画範囲内で、グラフのアスペ クト比 (縦横比) を < r> にします (< r> は x 方向の長さに対する y 方向の 長さの比)。
< r> の値を負にするとその意味は違って来ます。< r> =-1 のとき、x 軸、y 軸 の双方の単位 (つまり 1) の目盛りの長さが同一になるよう設定されます。こ れは set view equal xy と同じです。以下参照: set view equal (88.90.1)。 < r> =-2 のとき、y 軸の単位目盛りの長さは x 軸の単位目盛りの長さの 2 倍 に設定されます。< r> が負の値に関して以下同様です。
gnuplot が指定されたアスペクト比のグラフをちゃんと書けるかは選択され る出力形式に依存します。グラフの領域は出力の指定された部分にちゃんと収 まり、アスペクト比が < r> であるような最大の長方形となります (もちろん 適当な余白も残しますが)。
set size square は set size ratio 1 と同じ意味です。
noratio と nosquare はいずれもグラフをその出力形式 (terminal) での デフォルトのアスペクト比に戻しますが、< xscale> と < yscale> はそのデフ ォルトの値 (1.0) には戻しません。
ratio と square は 3 次元描画では意味を持ちませんが、set view map を使用した 3 次元描画の 2 次元射影には影響を与えます。 以下も参照:set view equal (88.90.1)。これは、3 次元の x 軸と y 軸を強制的に同じスケールに します。
例:
グラフが現在のキャンバスを埋めるような大きさに設定します:
set size 1,1
グラフを通常の半分の大きさで正方形にします:
set size square 0.5,0.5
グラフの高さを横幅の 2 倍にします:
set size ratio 2
書式:
set style function <style>
set style data <style>
show style function
show style data
指定できる描画要素のデフォルトスタイルも設定できます。
書式:
set style arrow <n> <arrowstyle>
set style boxplot <boxplot style options>
set style circle radius <size> {clip|noclip}
set style ellipse size <size> units {xy|xx|yy} {clip|noclip}
set style fill <fillstyle>
set style histogram <histogram style options>
set style line <n> <linestyle>
set style rectangle <object options> <linestyle> <fillstyle>
set style textbox {opaque|transparent} {{no}border}
書式:
set style arrow <index> default
set style arrow <index> {nohead | head | heads}
{size <length>,<angle>{,<backangle>} {fixed}}
{filled | empty | nofilled | noborder}
{front | back}
{ {linestyle | ls <line_style>}
| {linetype | lt <line_type>}
{linewidth | lw <line_width}
{linecolor | lc <colorspec>}
{dashtype | dt <dashtype>} }
unset style arrow
show style arrow
< index> は整数で、それで矢のスタイル (arrowstyle) を特定します。
default を指定すると、全ての arrow スタイルパラメータはそのデフォル トの値になります。
< index> の arrowstyle が既に存在する場合、他の全ては保存されたまま、与 えられたパラメータのみが変更されます。< index> が存在しなければ、指定さ れなかった値はデフォルトの値になります。
nohead を指定することで、矢先のない矢、すなわち線分を書くこともでき ます。これは描画の上に線分を描く別な方法を与えます。デフォルトでは 1 つの矢先がついています。heads の指定で線分の両端に矢先が描かれます。
矢先の大きさは size < length> ,< angle> または size < length> ,< angle> ,< backangle> で制御できます。< length> は矢先 の各枝の長さで、< angle> は矢先の枝と矢軸がなす角度 (単位は度) です。 < length> の単位は x 軸と同じですが、それは < length> の前に first, second, graph, screen, character をつけることで変更できます。 詳細は、以下参照: coordinates (11)。
デフォルトでは、とても短い矢の矢先は小さくしますが、これは、size コ マンドの後ろに fixed を使うことで無効にできます。
< backangle> は、矢先の後ろの部分の矢軸との切り角 (< angle> と同じ方 向、単位は度) になりますが、スタイルが nofilled の場合はこれを無視し ます。
filled を指定すると、矢先の回りの線 (境界線) を描き、矢先を塗りつぶ します。noborder を指定すると、矢先は塗りつぶしますが、境界線は描き ません。この場合、矢先の先端がベクトルの終点ピッタリの場所に置かれ、そ の矢先は全体として少し小さくなります。点線で矢を描く場合は、点線の境界 線は汚いので、常に noborder を使うべきです。矢先の塗りつぶしは、すべ ての出力形式がサポートしているとは限りません。
線種はユーザの定義したラインスタイルのリストから選ぶこともできますし (以下参照: set style line (88.74.7))、用意されている < line_type> の値 (デフ ォルトのラインスタイルのリストの番号) そして < linewidth> (デフォルト の幅の倍数) を使ってここで定義することもできます。
しかし、ユーザー定義済のラインスタイルが選択された場合、その属性 (線種、 幅) は、単に他の set style arrow コマンドで適当な番号や lt, lw などを指定しても、変更はできないことに注意して下さい。
front を指定すると、矢はグラフのデータの上に描かれます。back が指 定された場合 (デフォルト) は矢はグラフのデータの下に描かれます。front を使えば、密集したデータで矢が見えなくなることを防ぐことができます。
例:
矢先がなく、倍の幅が矢を描くには:
set style arrow 1 nohead lw 2
set arrow arrowstyle 1
その他の例については、以下参照: set arrow (88.2)。
書式:
set style boxplot {range <r> | fraction <f>}
{{no}outliers} {pointtype <p>}
{candlesticks | financebars}
{separation <x>}
{labels off | auto | x | x2}
{sorted | unsorted}
boxplot の箱は、常にデータ点の第一四分位から第三四分位の値の範囲にかか
っています。箱から延長される箱ひげの限界は、2 つの異なる方法で制御でき
ます。デフォルトでは、箱ひげは、その箱のそれぞれの端から、四分位範囲の
1.5 倍 (すなわち、その箱の厳密な垂直方向の高さ) に等しい範囲にまで延長
されます。箱ひげそれぞれは、データ集合のある点に属する y の値で終了す
るように、メジアンに向かって切り捨てられます。四分位範囲の丁度 1.5 倍
の値の点がない場合もありますから、箱ひげはその名目上の範囲よりも短くな
る場合もあります。このデフォルトは以下に対応します。
set style boxplot range 1.5
もう一つの方法として、箱ひげがかかる点の総数の割合 (fraction) を指定す
ることができます。この場合、その範囲はメジアン値から、データ集合の指定
した分を囲い込むまで、対称に延長されます。このときも、個々の箱ひげはデ
ータ集合内の点の端までに制限されます。データ集合の 95% の点をはるには
以下のようにします。
set style boxplot fraction 0.95
箱ひげの範囲の外にある任意の点は、outliers と見なされます。デフォルト ではそれらはひとつひとつ円 (pointtype 7) で描かれますが、オプション nooutliers はこれを無効にします。
デフォルトでは boxplot は candlesticks と似たスタイルで描画しますが、 financebars と似たスタイルで描画するためのオプションもあります。
boxplot の using 指定が 4 列目を持つ場合、その列の値はある因子変数の離 散的なレベル値であると見なします。この場合、その因子変数のレベルの数と 同じだけの複数の boxplot が描かれます。それらの boxplot の隣り合うもの 同士の距離はデフォルトでは 1.0 (x 軸の単位で) ですが、この間隔はオプシ ョン separation で変更できます。
オプション labels は、これらの boxplot (それぞれデータ集合のある部分 に対応する) のどこに、どのようにラベルをつけるかを決定します。デフォル トでは因子の値を水平軸 (x か x2 のいずれか plot で使われている方) の目 盛ラベルに出力します。これはオプションの labels auto に対応します。 オプション labels x, labels x2 によって、強制的に x 軸、x2 軸にそ れぞれ出力させることもできますし、labels off でオフにすることもでき ます。
デフォルトでは、因子変数の異なるレベルに対応する boxplot は整列化はせ ず、データファイルにそのレベルが現れる順番に描画します。この挙動はオプ ションの unsorted に対応しますが、オプション sorted を使用すると、 まずレベルを辞書順にソートし、その順に boxplot を描画します。
オプション separation, labels, sorted, unsorted は、plot に 4 列目の指定を与えた場合のみ効力を持ちます。
以下参照: boxplot (31), candlesticks (33), financebars (38)。
書式:
set style data <plotting-style>
show style data
選択項目については、以下参照: plotting styles (II)。show style data は 現在のデフォルトのデータ描画スタイルを表示します。
書式:
set style fill {empty
| {transparent} solid {<density>}
| {transparent} pattern {<n>}}
{border {lt} {lc <colorspec>} | noborder}
デフォルトの塗りつぶしスタイル (fillstyle) は empty です。
オプション solid は、出力形式がサポートしている場合、その色でのベタ 塗りを行います。パラメータ < density> は塗りつぶし色の強さを表していて < density> が 0.0 なら箱は空、< density> が 1.0 なら箱はその内部は現在の 線種と完全に同じ色で塗られます。出力形式によっては、この強さを連続的に 変化させられるものもありますが、その他のものは、部分的な塗りつぶしの幾 つかのレベルを実装しているに過ぎません。パラメータ < density> が与えら れなかった場合はデフォルトの 1 になります。
オプション pattern は、出力ドライバによって与えられるパターンでの塗 りつぶしを行います。利用できる塗りつぶしパターンの種類と数は出力ドライ バに依存します。塗りつぶしの boxes スタイルで複数のデータ集合を描画す る場合そのパターンは、複数の曲線の描画における線種の周期と同様、有効な パターンを、パターン < n> から始めて周期的に利用します。
オプション empty は、箱を塗りつぶしませんが、これがデフォルトです。
デフォルトの border は、現在の線の種類の実線で箱の境界を描きます。 border < colorspec> で境界の色を変更することができます。noborder は 境界の線が描かれないようにします。
| 出力形式 | solid | pattern | pm3d |
| gif | no | yes | no |
| jpeg | yes | no | yes |
| yes | yes | yes | |
| png | TrueColor | index | yes |
| post | no | yes | no |
| svg | yes | no | yes |
| win | yes | yes | yes |
| wxt | yes | yes | yes |
| x11 | no | yes | no |
透明な塗りつぶし領域を含むグラフを見たり作ったりするのには、別な制限が ありうることに注意してください。例えば、png 出力形式では、"truecolor" オプションが指定されている場合にのみ透明化の塗り潰しが利用できます。 PDF ファイルには透明化領域が正しく記述されていても、PDF の表示ソフトに よってはそれを正しく表示できないこともありえます。実際に PostScript プ リンタでは問題はないのに、Ghostscript/gv ではパターン塗りつぶし領域を 正しく表示できません。
書式:
set style function <plotting-style>
show style function
書式:
set style increment {default|userstyles}
show style increment
デフォルトでは、同じグラフ上の次の描画は、現在の出力形式でデフォルトで 定義されている線種の次のもので行われます。 しかし、set style increment user を選択すると、デフォルトの線種では なく、ユーザ定義ラインスタイル番号のものを使用させることができます。
例:
set style line 1 lw 2 lc rgb "gold"
set style line 2 lw 2 lc rgb "purple"
set style line 4 lw 1 lc rgb "sea-green"
set style increment user
plot f1(x), f2(x), f3(x), f4(x)
これは、関数 f1, f2, f4 は新たにユーザ定義されたラインスタイルで描画さ れます。ユーザ定義ラインスタイルが見つからない場合は、代わりにそれに対 応するデフォルトの線種が利用されます。例えば、上の例では、f3(x) はデフ ォルトの線種 3 で描画されます。
書式:
set style line <index> default
set style line <index> {{linetype | lt} <line_type> | <colorspec>}
{{linecolor | lc} <colorspec>}
{{linewidth | lw} <line_width>}
{{pointtype | pt} <point_type>}
{{pointsize | ps} <point_size>}
{{pointinterval | pi} <interval>}
{palette}
unset style line
show style line
default は、全てのラインスタイルパラメータをそれと同じ index を持つ 線種 (linetype) に設定します。
< index> の linestyle が既に存在する場合、他の全ては保存されたまま、与 えられたパラメータのみが変更されます。< index> が存在しなければ、指定さ れなかった値はデフォルトの値になります。
このようにつくられるラインスタイルは、デフォルトの型 (線種, 点種) を 別なものに置き換えることはしないので、ラインスタイル、デフォルトの型、 どちらも使えます。ラインスタイルは一時的なもので、コマンド reset を 実行すればいつでもそれらは消え去ります。線種自体を再定義したい場合は、 以下参照: set linetype (88.37)。
線種と点種は、その index 値をデフォルトとします。その index 値に対する 実際の記号の形は、出力形式によって異なり得ます。
線幅と点の大きさは、現在の出力形式のデフォルトの幅、大きさに対する乗数 です (しかし、ここでの < point_size> は、コマンド set pointsize で与 えられる乗数には影響を受けないことに注意してください)。
pointinterval は、スタイル linespoints でグラフ中に描かれる点の間 隔を制御します。デフォルトは 0 です (すべての点が描画される)。例えば、 set style line N pi 3 は、点種が N、点の大きさと線幅は現在の出力形式 のデフォルトで、with linespoints での描画では点は 3 番目毎に描画され るようなラインスタイルを定義します。その間隔を負の値にすると、それは間 隔は正の値の場合と同じですが、点の記号の下になる線を書かないようにしま す (出力形式によっては)。
全ての出力装置が linewidth や pointsize をサポートしているわけでは ありません。もしサポートされていない場合はそれらのオプションは無視され ます。
出力形式に依存しない色を linecolor < colorspec> か linetype < colorspec> (省略形は lc, lt) のいずれかを使って割り当てることができます。この 場合、色は RGB の 3 つ組で与えるか、gnuplot の持つパレットの色名、現在 のパレットに対する小数指定、または cbrange への現在のパレットの対応に 対する定数値、のいずれかで与えます。以下参照: colors (19), colorspec (19.1),set palette (88.62), colornames (88.16), cbrange (88.134)。
set style line < n> linetype < lt> は、出力形式に依存した点線/破線のパ ターンと色の両方をセットします。set style line < n> linecolor < colorspec> や set style line < n> linetype < colorspec> は、現在の点線/破線のパタ ーンを変更せずに新しい線色を設定します。
3 次元モード(splot コマンド) では、"linetype palette z" の省略形とし て特別にキーワード palette を使うことも許されています。その色の値は、 splot の z 座標 (高さ) に対応し、曲線、あるいは曲面に沿って滑らかに変 化します。
例: 以下では、番号 1, 2, 3 に対するデフォルトの線種をそれぞれ赤、緑、青とし、デフォルトの点の形をそれぞれ正方形、十字、三角形であるとします。このとき 以下のコマンド
set style line 1 lt 2 lw 2 pt 3 ps 0.5
は、新しいラインスタイルとして、緑でデフォルトの 2 倍の幅の線、および 三角形で半分の幅の点を定義します。また、以下のコマンド
set style function lines
plot f(x) lt 3, g(x) ls 1
は、f(x) はデフォルトの青線で、g(x) はユーザの定義した緑の線で描画しま す。同様に、コマンド
set style function linespoints
plot p(x) lt 1 pt 3, q(x) ls 1
は、p(x) を赤い線で結ばれたデフォルトの三角形で、q(x) は緑の線で結ばれ た小さい三角形で描画します。
splot sin(sqrt(x*x+y*y))/sqrt(x*x+y*y) w l pal
は、palette に従って滑らかな色を使って曲面を描画します。これはそれを サポートした出力形式でしかちゃんとは動作しないことに注意してください。 以下も参照: set palette (88.62), set pm3d (88.61)。
set style line 10 linetype 1 linecolor rgb "cyan"
は、RGB カラーをサポートするすべての出力形式で、ラインスタイル 10 に実 線の水色を割り当てます。
書式:
set style circle {radius {graph|screen} <R>}
{{no}wedge}
{clip|noclip}
このコマンドは、描画スタイル "with circles" で使われるデフォルトの半径 を設定します。これは、データ描画で 2 列のデータ (x,y) しか与えなかった 場合、あるいは関数描画のときに適用されます。デフォルトは、以下のようになっています: "set style circle radius graph 0.02"。nowedge は、扇形 の円弧部分から中心に向かう 2 本の半径を描かないようにしますが、デフォ ルトは wedge です。このパラメータは完全な円に対しては何もしません。 clip は円を描画境界でクリッピングしますが、noclip はこれを無効にし ます。デフォルトは clip です。
コマンド set object で定義された長方形には別々のスタイルを設定できま す。しかし、個別のスタイル指定をしなければ、そのオブジェクトはコマンド set style rectangle によるデフォルトを受け継ぎます。
書式:
set style rectangle {front|back} {lw|linewidth <lw>}
{fillcolor <colorspec>} {fs <fillstyle>}
以下参照: colorspec (19.1), fillstyle (88.74.4)。fillcolor は fc と省略できます。
例:
set style rectangle back fc rgb "white" fs solid 1.0 border lt -1 set style rectangle fc linsestyle 3 fs pattern 2 noborder
デフォルトの設定は、背景色での塗り潰しで、境界は黒になっています。
書式:
set style ellipse {units xx|xy|yy}
{size {graph|screen} <a>, {{graph|screen} <b>}}
{angle <angle>}
{clip|noclip}
このコマンドは、楕円の直径を同じ単位で計算するかどうかを制御します。 デフォルトは xy で、これは楕円の主軸 (第 1 軸) の直径は x (または x2) 軸と同じ単位で計算し、副軸 (第 2 軸) の直径は y (または y2) 軸の単位で 計算します。このモードでは、楕円の両軸の比は、描画軸のアスペクト比に依 存します。xx か yy に設定すれば、すべての楕円の両軸は同じ単位で計 算されます。これは、描画される楕円の両軸の比は、回転しても正しいままで すが、水平方向か垂直方向の一方の縮尺の変更により正しくなくなることを意 味します。
これは、object として定義された楕円、コマンド plot によって描画され る楕円の両方に影響を与える全体的な設定ですが、units の値は、描画毎、 オブジェクト毎に設定を再定義できます。
楕円のデフォルトのサイズも、キーワード size で設定できます。デフォル トのサイズは、2 列のみのデータ、または関数の plot 命令で適用されます。 2 つの値は、楕円の (2 つの主軸、2 つの副軸に向かい合う) 主軸直径と副軸 直径として使用されます。
デフォルトは、"set style ellipse size graph 0.05,0.03" です。
最後になりますが、デフォルトの向きをキーワード angle で設定もできま す。向きは、楕円の主軸とグラフの x 軸の方向となす角で、単位は度で与え る必要があります。
clip は楕円を描画境界でクリッピングしますが、noclip はこれを無効に します。デフォルトは clip です。
楕円の object の定義に関しては以下も参照: set object ellipse (88.54.2)。2 次元 の描画スタイルに関しては以下参照: ellipses (35)。
書式: set style textbox {opaque| transparent}{{no}border}
このコマンドは、属性 boxed による label の表示を制御します。箱付き文 字列をサポートしない出力形式はこのスタイルを無視します。
書式:
set surface {implicit|explicit}
unset surface
show surface
unset surface により splot は、関数やデータファイルの点に対するど んな点や線も描かなくなります。これは主に、等高線を作る曲面を描く代わり に等高線のみを描く場合に有用です。その場合でも set contour の設定に よりますが、曲面上に等高線が描かれます。他のものは通常のままで、ある一 つの関数やデータファイルの曲面のみをオフにするには、splot コマンド上 でキーワード nosurface を指定してください。等高線を格子の土台に表示 したい場合は unset surface; set contour base という組が便利でしょう。 以下も参照: set contour (88.17)。
3 次元データの組が網目 (格子線) と認識されると、gnuplot はデフォルトで は格子曲面を要求しているものとして、暗黙に with lines の描画スタイル を用います。以下参照: grid_data (90.2)。コマンド set surface explicit は この機能を抑制し、入力ファイルの分離されたデータブロックで記述される孤 立線のみを描画します。この場合でも、splot で明示的に with surface と すれば格子曲面が描画されます。
書式:
set table {"outfile" | $datablock}
plot <whatever>
unset table
表形式の出力は、指定したファイルに書き出しますが、指定がない場合は現在 の set output が指定するものに出力します。他に、表形式出力を名前付き データブロックにリダイレクトすることもできます。データブロック名は '$' で始まります。以下も参照: inline data (77.3.4)。現在の出力形式の標準的な描画 に戻すには、unset table を明示的に行なう必要があります。
入力データのスタイル依存の処理 (平滑化、誤差線、2 軸範囲のチェック等) を避けるため、あるいは表出力する列を増やすには、通常の描画スタイルの代 わりに "table" キーワードを使うことができます。例:
set table
plot <file> using 1:2:3:4:5:6:7:8:9:10 with table
書式:
set terminal {<terminal-type> | push | pop}
show terminal
< terminal-type> が省略されると gnuplot は利用可能な出力形式の一覧を 表示します。< terminal-type> の指定には短縮形が使えます。
set terminal と set output の両方を使う場合、set terminal を最初 にする方が安全です。それは、OS によっては、それが必要とするフラグをセ ットする出力形式があるからです。
いくつかの出力形式はたくさんの追加オプションを持ちます。 各 < term> に対し、直前の set term < term> < options> で使用されたオ プションは記憶され、その後の set term < term> がそれをリセットするこ とはありません。これは例えば印刷時に有用です。幾つかの異なる出力形式を 切替える場合、前のオプションを繰り返し唱える必要はありません。
コマンド set term push は、現在の出力形式とその設定を set term pop によって復帰するまで記憶しています。これは save term, load term と ほぼ同等ですが、ファイルシステムへのアクセスは行わず、よって例えばこれ は、印刷後にプラットホームに依存しない形で出力形式を復帰する目的に使え ます。gnuplot の起動後、デフォルト、または startup ファイルに書かれ た出力形式が自動的に記憶 (push) されます。よって、明示的に出力形式を記 憶させることなく、任意のプラットホーム上でデフォルトの出力形式を set term pop によって復帰させる、という動作を期待したスクリプトを可 搬性を失わずに書くことが出来ます。
詳細は、以下参照: complete list of terminals (98)。
set termoption {no}enhanced
set termoption font "<fontname>{,<fontsize>}"
set termoption fontscale <scale>
set termoption {solid|dashed}
set termoption {linewidth <lw>}{lw <lw>}
目盛りは unset tics で消え、set tics で目盛りがつきます (デフォル ト)。個々の軸の目盛りは、これとは別のコマンド set xtics, set ztics などを使って制御できます。
書式:
set tics {axis | border} {{no}mirror}
{in | out} {front | back}
{{no}rotate {by <ang>}} {offset <offset> | nooffset}
{left | right | center | autojustify}
{format "formatstring"} {font "name{,<size>}"} {{no}enhanced}
{ textcolor <colorspec> }
set tics scale {default | <major> {,<minor>}}
unset tics
show tics
オプションは、個々の軸 (x, y, z, x2, y2, cb) にも適用できます。例:
set xtics rotate by -90
unset cbtics
軸の刻みの線属性は、すべてグラフの境界 (以下参照: set border (88.7)) と同じ ものを使って描かれます。
tics の front または back の設定は、2D 描画 (splot は不可) にのみ すべての軸に 1 度適用されます。これは、目盛りと描画要素が重なった場合 に目盛りを描画要素の前面に出すか、奥に置くかを制御します。
axis と border は gnuplot に目盛り (目盛りの刻み自身とその見出し) を、それぞれ軸につけるのか、境界につけるのかを指示します。軸が境界にと ても近い場合、axis を使用すると境界が表示されていれば (以下参照:set border (88.7)) 目盛りの見出し文字を境界の外に出してしまうでしょう。この 場合自動的なレイアウトアルゴリズムによる余白設定は大抵よくないものとな ってしまいます。
mirror は gnuplot に反対側の境界の同じ位置に、見出しのない目盛りを 出力するよう指示します。nomirror は、あなたが想像している通りのこと を行ないます。
in と out は目盛りの刻みを内側に描くか外側に描くかを切り変えます。
set tics scale は、目盛りの刻みの大きさを制御します。最初の < major> の値には、自動的に生成され、またユーザも指定できる大目盛り (レベル 0) を指定し、2 つ目の < minor> の値には、自動的に生成され、またユーザも指 定できる小目盛り (レベル 1) を指定します。< major> のデフォルトは 1.0 で、< minor> のデフォルトは < major> /2 です。さらに値を追加すれば、レベ ル 2, 3, ... の目盛りの大きさになります。set tics scale default でデ フォルトの目盛りの大きさに復帰します。
rotate は、文字列を 90 度回転させて出力させようとします。これは、文 字列の回転をサポートしている出力ドライバ (terminal) では実行されます。 norotate はこれをキャンセルします。rotate by < ang> は角度 < ang> の 回転を行ないますが、これはいくつかの出力形式 (terminal) でサポートされ ています。
x と y 軸の大目盛りのデフォルトは border mirror norotate で、x2, y2 軸は border nomirror norotate がデフォルトです。z 軸のデフォルトは nomirror です。
< offset> は x,y かまたは x,y,z の形式ですが、それに座標系を選択して、 その前に first, second, graph, screen, character のいずれか をつけることもできます。< offset> は、目盛りの見出し文字列のデフォルト の位置からのずらし位置で、そのデフォルトの単位系は character です。 詳細は、以下参照: coordinates (11)。nooffset は offset を OFF にします。
デフォルトでは見出しラベルは、美しい結果を生むように、軸と回転角に依存 した位置に自動的に位置合わせされます。それが気にいらなければ、明示的に left, right, center のキーワードにより位置合わせを変更できます。 autojustify でデフォルトの挙動に復帰します。
オプションなしの set tics は、目盛りの刻みを内側にしますが、その他の 全てのオプションは直前の値を保持します。
大目盛り (ラベルのつく) の他の制御に関しては、以下参照: set xtics (88.104)。 小目盛りの制御に関しては、以下参照: set mxtics (88.50)。これらのコマンドは、 各軸の独立な制御を提供します。
書式:
set timestamp {"<format>"} {top|bottom} {{no}rotate}
{offset <xoff>{,<yoff>}} {font "<fontspec>"}
{textcolor <colorspec>}
unset timestamp
show timestamp
書式文字列 (format) を使って、書かれる日付と時刻の書式を選択することが できます。デフォルトは asctime() が使用する "%a %b %d %H:%M:%S %Y" で す (曜日、月名、日、時、分、秒、4 桁の西暦)。top と bottom を使っ て日付を左の余白の上に配置するか、下に配置するかを選択できます (デフォ ルトは下)。rotate は、もし出力形式がサポートしていればですが、日付を 垂直方向の文字列にします。定数 < xoff> 、< yoff> はずれ (offset) を意味し、 これによってより適切な位置合わせが行えます。< font> は日付が書かれるフ ォントを指定します。
timestamp の代わりに省略名 time を使っても構いません。
例:
set timestamp "%d/%m/%y %H:%M" offset 80,-2 font "Helvetica"
日付の書式文字列に関する詳しい情報については、以下参照: set timefmt (88.83)。
書式:
set timefmt "<format string>"
show timefmt
文字列引数 (< format string> ) は gnuplot に日時データをデータファイル からどのように読むかを指示します。有効な書式は以下の通りです:
| 時系列データ書式指定子 | |
| 書式 | 説明 |
%d |
何日, 1-31 |
%m |
何月, 1-12 |
%y |
何年, 0-99 |
%Y |
何年, 4 桁 |
%j |
1 年の何日目, 1-365 |
%H |
何時, 0-24 |
%M |
何分, 0-60 |
%s |
Unix epoch (1970-01-01, 00:00 UTC) からの秒数 |
%S |
何秒 (出力では 0-60 の整数、入力では実数) |
%b |
月名 (英語) の 3 文字省略形 |
%B |
月名 (英語) |
任意の文字を文字列中で使用できますが、規則に従っている必要があります。 \ t (タブ) は認識されます。バックスラッシュ + 8 進数列 ( \ nnn) はそれが 示す文字に変換されます。日時要素の中に分離文字がない場合、%d, %m, %y, %H, %M, %S はそれぞれ 2 桁の数字を読み込みます。%S での読み込みで小数 点がそのフィールドについている場合は、その小数点つきの数を小数の秒指定 だと解釈します。%Y は 4 桁、%j は 3 桁の数字を読み込みます。%b は 3 文 字を、%B は必要な分だけの文字を要求します。
空白 (スペース) の扱いはやや違います。書式文字列中の 1 つの空白は、ファイル中の 0 個、あるいは 1 つ以上の空白文字列を表します。すなわち、 "%H %M" は "1220" や "12 20" を "12 20" と同じように読みます。
データ中の非空白文字の集まりそれぞれは、using n:n 指定の一つ一つの列 とカウントされます。よって 11:11 25/12/76 21.0 は 3 列のデータと認 識されます。混乱を避けるために、日時データが含まれる場合 gnuplot は、 あなたの using 指定が完璧なものであると仮定します。
日付データが曜日、月の名前を含んでいる場合、書式文字列でそれを排除しなければいけませんが、"%a", "%A", "%b", "%B" でそれらを表示することはできます。gnuplot は数値から月や曜日を正しく求めます。これら、及び日時 データの出力の他のオプションの詳細に関しては、以下参照: set format (88.27)。
2 桁の西暦を %y で読む場合、69-99 は 2000 年未満、00-68 は 2000 年以後と見なします。注意: これは、UNIX98 の仕様に合わせたものですが、この慣 例はあちこちで違いがあるので、2 桁の西暦値は本質的にあいまいです。
他の情報については、以下も参照: set xdata (88.99), time/date (28)。
例:
set timefmt "%d/%m/%Y\t%H:%M"
書式:
set title {"<title-text>"} {offset <offset>} {font "<font>{,<size>}"}
{{textcolor | tc} {<colorspec> | default}} {{no}enhanced}
show title
< offset> を x,y かまたは x,y,z の形式で指定した場合は、タイトルは与え られた値だけ移動されます。それに座標系を選択して、その前に first, second, graph, screen, character のいずれかをつけることもでき ます。詳細は、以下参照: coordinates (11)。デフォルトでは character 座標 系が使われます。例えば、"set title offset 0,-1" はタイトルの y 方向 の位置のみ変更し、大ざっぱに言って 1 文字分の高さだけタイトルを下に下 げます。1 文字の大きさは、フォントと出力形式の両方に依存します。
< font> はタイトルが書かれるフォントを指定するのに使われます。< size> の 単位は、どの出力形式 (terminal) を使っているかによって変わります。
textcolor < colorspec> は、文字の色を変更します。< colorspec> は、線 種、rgb 色、またはパレットへの割当のいずれかが指定できます。以下参照:colorspec (19.1), palette (88.62)。
noenhanced は、拡張文字列処理 (enhanced text) モードが有効になってい る場合でも、タイトルを拡張文字列処理させないようにします。
set title をパラメータなしで使うとタイトルを消去します。
バックスラッシュ文字列の作用、及び文字列を囲む単一引用符と二重引用符の 違いについては、以下参照: syntax (27)。
書式:
show variables # GPVAL_ で始まるもの以外の変数を表示
show variables all # GPVAL_ で始まるものも含め全ての変数を表示
show variables NAME # NAME で始まる変数のみを表示
書式:
show version {long}
long オプションを与えると、さらにオペレーティングシステム、gnuplot インストール時のコンパイルオプション、ヘルプファイルの置き場所、そして (再び) 有用なメールアドレスを表示します。
書式:
set view <rot_x>{,{<rot_z>}{,{<scale>}{,<scale_z>}}}
set view map {scale <scale>}
set view {no}equal {xy|xyz}
show view
ここで < rot_x> と < rot_z> は、画面に投影される仮想的な 3 次元座標系の 回転角 (単位は度) の制御で、最初は (すなわち回転が行なわれる前は) 画面内の水平軸は x, 画面内の垂直軸は y, 画面自身に垂直な軸が z となっ ています。最初は x 軸の周りに < rot_x> だけ回転されます。次に、新しい z 軸の周りに < rot_z> だけ回転されます。
コマンド set view map は、グラフを地図のように表示するのに使います。 これは等高線 (contour) のグラフや、pm3d モードによる 2 次元温度分布 などで with image よりもむしろ有用です。後者では、入力データ点のフィ ルタ用の zrange の設定、および色の範囲の縮尺に関する cbrange の設 定を適切に行うことに注意してください。
< rot_x> は [0:180] の範囲に制限されていて、デフォルトでは 60 度です。 < rot_z> は [0:360] の範囲に制限されていて、デフォルトでは 30 度です。 < scale> は splot 全体の伸縮率を制御し、< scale_z> は z 軸の伸縮のみを 行ないます。伸縮率のデフォルトはどちらも 1.0 です。
例:
set view 60, 30, 1, 1
set view ,,0.5
最初の例は 4 つの全てをデフォルトの値にしています。2 つめの例は縮小率 のみを 0.5 に変更しています。
以下も参照: set xyplane (88.105)。
書式:
set xdata time
show xdata
ydata, zdata, x2data, y2data, cbdata にも同じ書式が当てはま ります。
time オプションはデータが秒単位の日時データであることを伝えます。現 在の gnuplot は時刻をミリ秒の精度保存します。
オプションなしの場合は、データの解釈方法を通常の形式に戻します。
日時データの入力と出力の解釈には、別々の書式機構があります。ファイルか らの入力データは、全体に通用する timefmt を使うか、または plot コマ ンド内で timecolumn() 関数を使って読み込みます。この入力機構は、軸の範 囲 (range) を設定するときに時間の値を使用する際にも適用されます。以下参照: set timefmt (88.83), timecolumn (15.1)。
例:
set xdata time
set timefmt "%d-%b-%Y"
set xrange ["01-Jan-2013" : "31-Dec-2014"]
plot DATA using 1:2
plot DATA using (timecolumn(1,"%d-%b-%Y")):2
出力、すなわち軸に沿った目盛りのラベルや、マウス操作での座標出力につい ては、デフォルトでは、秒での内部時刻から日時を表現する文字列への変換に は、関数 'strftime' (unix でそれを調べるには "man strftime" とタイプし てください) を使います。gnuplot はこれを適当に意味のある書式で表示し ようとしますが、set format x か set xtics format のいずれかを使っ てカスタマイズすることもできます。 特別な時間書式指定子に関しては、以下参照: time_specifiers (88.27.3)。他の情報 については、以下も参照: time/date (28)。
書式:
set xdtics
unset xdtics
show xdtics
ydtics, zdtics, x2dtics, y2dtics, cbdtics にも同じ書式が当て はまります。
以下も参照: set format (88.27)。
書式:
set xlabel {"<label>"} {offset <offset>} {font "<font>{,<size>}"}
{textcolor <colorspec>} {{no}enhanced}
{rotate by <degrees> | rotate parallel | norotate}
show xlabel
同じ書式が x2label, ylabel, y2label, zlabel, cblabel にも適 用されます。
< offset> を x,y かまたは x,y,z の形式で指定した場合は、見出しは与えら れた値だけ移動されます。それに座標系を選択して、その前に first, second, graph, screen, character のいずれかをつけることもでき ます。詳細は、以下参照: coordinates (11)。デフォルトでは character 座標 系が使われます。例えば、"set xlabel offset -1,0" は見出しの x 方向の 位置のみ変更し、大ざっぱに言って 1 文字分の幅だけ見出しを左にずらしま す。1 文字の大きさは、フォントと出力形式の両方に依存します。
< font> は見出しが書かれるフォントを指定するのに使われます。フォントの < size> (大きさ) の単位は、どんな出力形式を使うかに依存します。
noenhanced は、拡張文字列処理 (enhanced text) モードが有効になってい る場合でも、ラベル文字列を拡張文字列処理させないようにします。
見出しを消去するには、オプションをつけずに実行します。例: "set y2label"
軸の見出しのデフォルトの位置は以下の通りです:
xlabel: x 軸の見出しはグラフの下の真中
ylabel: y 軸の見出しはグラフの左の真中で、水平方向に書かれるか垂直方向 になるかは出力形式依存
zlabel: z 軸の見出しは軸の表示範囲より上で、見出しの真中が z 軸の真上
cblabel: 色見本 (color box) の軸の見出しは箱に沿って中央揃えされ、箱の 向きが水平なら下に、垂直なら右に
y2label: y2 軸の見出しは y2 軸の右。その位置は、出力形式依存で y 軸と 同様の規則で決定。
x2label: x2 軸の見出しはグラフの上で、タイトルよりは下。これは、 改行 文字を使えば、それによる複数の行からなる描画タイトルで x2 軸の見出しを 生成することも可能。例:
set title "This is the title\n\nThis is the x2label"
これは二重引用符を使うべきであることに注意してください。この場合、もち ろん 2 つの行で同じフォントが使われます。
2 次元描画の場合の x, x2, y, y2 軸のラベルの方向 (回転角) は、 rotate by < 角度> を指定することで変更できます。3 次元描画の x, y 軸 のラベルの方向はデフォルトでは水平方向になっていますが、 rotate parallel を指定することで軸に平行にすることができます。
もし軸の位置のデフォルトの位置が気に入らないならば、代わりに set label を使ってください。このコマンドは文字列をどこに配置するかをもっと自由に 制御できます。
バックスラッシュ文字列の作用、及び文字列を囲む単一引用符と二重引用符の 違いに関するより詳しい情報については、以下参照: syntax (27)。
書式:
set xmtics
unset xmtics
show xmtics
x2mtics, ymtics, y2mtics, zmtics, cbmtics にも同じ書式が適用 されます。
以下も参照: コマンド set format (88.27)。
書式:
set xrange [{{<min>}:{<max>}}] {{no}reverse} {{no}writeback} {{no}extend}
| restore
show xrange
ここで < min> と < max> は定数、数式、または '*' で、'*' は自動縮尺機能 を意味します。日時データの場合、範囲は set timefmt の書式に従った文 字列を引用符で囲む必要があります。< min> や < max> を省略した場合は、現 在の値を変更しません。自動縮尺機能に関する詳細は下に述べます。以下も参照: noextend (88.3)。
yrange, zrange, x2range, y2range, cbrange, rrange, trange, urange, vrange は同じ書式を使用します。
x と x2 軸、あるいは y と y2 軸の範囲をリンクするオプションについては 以下参照: set link (88.38)。
オプション reverse は、自動縮尺の軸の方向を逆にします。例えば、デー タ値の範囲が 10 から 100 であるとき、これは、set xrange [100:10] とし たのと同じように自動縮尺します。reverse は、自動縮尺ではない軸に対し ては機能しません。注意: この変更は、バージョン 4.7 で導入されました。
自動縮尺機能: <
min>
(同様のことが <
max>
にも適用されます) がアスタリス
ク "*" の場合は自動縮尺機能がオンになります。その場合のその値に、下限
<
lb>
、または上限 <
ub>
、またはその両方の制限を与えられます。書式は以下の通りです。
{ <lb> < } * { < <ub> }
0 < * < 200
オプション writeback は、set xrange で占められているバッファの中に 自動縮尺機能により作られた範囲を保存します。これは、いくつかの関数を同 時に表示し、しかしその範囲はそのうちのいくつかのものから決定させたい場 合に便利です。writeback の作用は、plot の実行中に機能するので、その コマンドの前に指定する必要があります。最後に保存した水平方向の範囲は set xrange restore で復元できます。例を上げます。
set xrange [-10:10]
set yrange [] writeback
plot sin(x)
set yrange restore
replot x/2
この場合、y の範囲 (yrange) は sin(x) の値域として作られた [-1:1] の方 になり、x/2 の値域 [-5:5] は無視されます。上記のそれぞれのコマンドの後 に show yrange を実行すれば、上で何が行なわれているかを理解する助け になるでしょう。
2 次元描画において、xrange と yrange は軸の範囲を決定し、trange は、媒介変数モードの媒介変数の範囲、あるいは極座標モードの角度の範囲を 決定します。同様に 3 次元媒介変数モードでは、xrange, yrange, zrange が軸の範囲を管理し、urange と yrange が媒介変数の範囲を管理します。
極座標モードでは、rrange は描画される動径の範囲を決定します。< rmin> は動径への追加の定数として作用し、一方 < rmax> は動径を切り捨てる (clip) ように作用し、< rmax> を越えた動径に対する点は描画されません。xrange と yrange は影響されます。これらの範囲は、グラフが r(t)-rmin のグラ フで、目盛りの見出しにはそれぞれ rmin を加えたようなものであるかのよう にセットされます。
全ての範囲は部分的に、または全体的に自動縮尺されますが、データの描画で なければ、パラメータ変数の自動縮尺機能は意味がないでしょう。
範囲は plot のコマンドライン上でも指定できます。コマンドライン上で与 えられた範囲は単にその plot コマンドでだけ使われ、set コマンドで設 定された範囲はその後の描画で、コマンドラインで範囲を指定していないもの 全てで使われます。これは splot も同じです。
例:
x の範囲をデフォルトの値にします:
set xrange [-10:10]
y の範囲が下方へ増加するようにします:
set yrange [10:-10]
z の最小値には影響を与えずに (自動縮尺されたまま)、最大値のみ 10 に設
定します:
set zrange [:10]
x の最小値は自動縮尺とし、最大値は変更しません:
set xrange [*:]
x の最小値を自動縮尺としますが、その最小値は 0 以上にします。
set xrange [0<*:]
x の範囲を自動縮尺としますが、小さくても 10 から 50 の範囲を保持します
(実際はそれより大きくなるでしょう):
set xrange [*<10:50<*]
自動縮尺で最大範囲を -1000 から 1000、すなわち [-1000:1000] 内で自動縮
尺します:
set xrange [-1000<*:*<1000]
x の最小値を -200 から 100 の間のどこかにします:
set xrange [-200<*<100:]
書式:
set xtics {axis | border} {{no}mirror}
{in | out} {scale {default | <major> {,<minor>}}}
{{no}rotate {by <ang>}} {offset <offset> | nooffset}
{left | right | center | autojustify}
{add}
{ autofreq
| <incr>
| <start>, <incr> {,<end>}
| ({"<label>"} <pos> {<level>} {,{"<label>"}...) }
{format "formatstring"} {font "name{,<size>}"} {{no}enhanced}
{ numeric | timedate | geographic }
{ rangelimited }
{ textcolor <colorspec> }
unset xtics
show xtics
同じ書式が ytics, ztics, x2tics, y2tics, cbtics にも適用され ます。
axis と border は gnuplot に目盛り (目盛りの刻み自身とその見出し) を、それぞれ軸につけるのか、境界につけるのかを指示します。軸が境界にと ても近い場合、axis を使用すると目盛りの見出し文字を境界の外に出して しまうでしょう。この場合自動的なレイアウトアルゴリズムによる余白設定は 大抵よくないものとなってしまいます。
mirror は gnuplot に反対側の境界の同じ位置に、見出しのない目盛りを 出力するよう指示します。nomirror は、あなたが想像している通りのこと を行ないます。
in と out は目盛りの刻みを内側に描くか外側に描くかを切り変えます。
目盛りの刻みのサイズは scale で調整できます。< minor> の指定が省略さ れた場合は、それは 0.5*< major> になります。デフォルトのサイズは、大目 盛りが 1.0 で小目盛りが 0.5 で、これは scale default で呼びだせます。
rotate は、文字列を 90 度回転させて出力させようとします。これは、文 字列の回転をサポートしている出力ドライバ (terminal) では実行されます。 norotate はこれをキャンセルします。rotate by < ang> は角度 < ang> の 回転を行ないますが、これはいくつかの出力形式 (terminal) でサポートされ ています。
x と y 軸の大目盛りのデフォルトは border mirror norotate で、x2, y2 軸は border nomirror norotate がデフォルトです。z 軸には、 {axis | border} オプションは無効で、デフォルトは nomirror です。z 軸の目盛りをミラー化したいなら、多分 set border でそのための空間をあ ける必要があるでしょう。
< offset> は x,y かまたは x,y,z の形式で指定しますが、それに座標系を選 択して、その前に first, second, graph, screen, character の いずれかをつけることもできます。< offset> は刻み文字のデフォルトの位置 からのずれを表し、デフォルトの座標系は character です。詳細は、以下参照: coordinates (11)。nooffset はずらしを無効にします。
例:
xtics をより描画に近づける:
set xtics offset 0,graph 0.05
デフォルトでは見出しラベルは、美しい結果を生むように、軸と回転角に依存 した位置に自動的に位置合わせされます。それが気にいらなければ、明示的に left, right, center のキーワードにより位置合わせを変更できます。 autojustify でデフォルトの挙動に復帰します。
オプションなしで set xtics を実行すると、目盛りが表示される状態であ れば、それはデフォルトの境界、または軸を復元し、そうでなければ何もしま せん。その前に指定した目盛りの間隔、位置 (と見出し) は保持されます。
目盛りの位置は、デフォルト、またはオプション autofreq が指定されてい れば自動的に計算されます。そうでなければ、次の 2 つの形式で指定されま す:
暗示的な < start> , < incr> , < end> 形式は、目盛りの列を < start> から < end> の間を < incr> の間隔で表示します。< end> を指定しなければ、それは無限大 とみなされます。< incr> は負の値も可能です。< start> と < end> の両方が指 定されていない場合、< start> は -∞、< end> は +∞とみなされ、目盛りは < incr> の整数倍の位置に表示されます。軸が対数軸の場合、目盛りの間隔 (増分) は、倍数として使用されます。
負の < start> や < incr> を、数値の後ろに指定すると (例えば rotate by < angle> とか offset < offset> の後ろ)、gnuplot の構文解析 器は、その値からその負の < start> や < incr> の値の引き算を行おうとする 間違いを犯します。これを回避するには、そのような場合は、0-< start> や 0-< incr> のように指定してください。
例:
set xtics border offset 0,0.5 -5,1,5
set xtics border offset 0,0.5 0-5,1,5
set xtics offset 0,0.5 border -5,1,5
set grid のオプション 'front', 'back', 'layerdefault' も、x 軸の目盛 りの描画の順序に影響します。
例:
目盛りを 0, 0.5, 1, 1.5, ..., 9.5, 10 の位置に生成
set xtics 0,.5,10
目盛りを ..., -10, -5, 0, 5, 10, ... に生成
set xtics 5
目盛りを 1, 100, 1e4, 1e6, 1e8 に生成
set logscale x; set xtics 1,100,1e8
明示的な ("< label> " < pos> < level> , ...) の形式は、任意の目盛りの位置、 あるいは数字でない見出しの生成も可能にします。この形式では、目盛りは位 置の数字の順に与える必要はありません。各目盛りは位置 (pos) と見出し (label) を持ちますが、見出しは必須ではありません。見出しは二重引用符で 囲まれた文字列であることに注意してください。それは、"hello" のような固 定文字列でも構いませんし、"%3f clients" のようにその位置を数字に変換す る書式文字列を含んでも構いませんし、空文字列 "" でも構いません。より詳 しい情報については、以下参照: set format (88.27)。もし、文字列が与えられなけ れば、デフォルトの数字の見出しが使用されます。
明示的な形式では 3 つ目のパラメータとしてレベルを指定できます。デフォ ルトのレベルは 0 で、これは大目盛りを意味し、レベル 1 の場合は小目盛り を生成します。ラベルは、小目盛りには決して付きません。大目盛りと小目盛 りは gnuplot が自動的に生成しますが、ユーザが明示的に指定もできます。 レベルが 2 以上の目盛りは、ユーザが明示的に指定しなければならず、自動生成の目盛りよりも高い優先度を持ちます。各レベルの目盛りの刻みの大きさ は、set tics scale で制御します。
例:
set xtics ("low" 0, "medium" 50, "high" 100)
set xtics (1,2,4,8,16,32,64,128,256,512,1024)
set ytics ("bottom" 0, "" 10, "top" 20)
set ytics ("bottom" 0, "" 10 1, "top" 20)
2 番目の例では、全ての目盛りが見出し付けされます。3 番目の例では、端の ものだけが見出し付けされます。4 番目の例の、見出しのない目盛りは小目盛 りになります。
通常明示的な (手動の) 目盛り位置が与えられた場合、自動的に生成される目 盛りは使われません。逆に、set xtics auto のようなものが指定された場 合は、以前に手動で設定した目盛りは消されてしまします。この手動の目盛り と自動的な目盛りを共存させるにはキーワード add を使用してください。 これは追加する目盛りのスタイルの前に書かなければいけません。
例:
set xtics 0,.5,10
set xtics add ("Pi" 3.14159)
これは自動的に目盛りの刻みを x 軸に 0.5 間隔でつけますが、πのところに 明示的な見出しも追加します。
しかし指定しても、表示されるのはあくまで描画範囲のものだけです。
目盛りの見出しの書式 (または省略) は set format で制御されます。ただ しそれは set xtics (< label> ) の形式の明示的な見出し文字列が含まれ ていない場合だけです。
(見出し付けされない) 小目盛りは、set mxtics コマンドで自動的に追加す るか、または位置を手動で set xtics ("" < pos> 1, ...) の形式で与える こともできます。
入力: 非数値の日時値は、入力時に timefmt で指定した書式を用いて秒数 に変換します。軸に対する位置や軸の範囲も timefmt で解釈される日時で、 引用符で囲んで与えます。 < start> , < incr> , < end> 形式を使う場合、< incr> は秒単位で与えなければい けません。入力データの解釈には timefmt を使ってください。軸の範囲と 目盛りの位置は、set xdata time で変更されます。
出力: 軸の目盛りラベルは、set format か set xtics format のいずれ かで指定された、別の書式を使って生成します。デフォルトでは、それは通常 の数値書式指定であると認識しますが (set xtics numeric)、他に、地理座 標 (set xtics geographic) や、日時データ (set xtics time) のオプシ ョンがあります。
注意: 以前の版の gnuplot との互換性のため、コマンド set xdata timeも暗黙に set xtics time を実行しますし、set xdata や unset xdataは暗黙に set xtics numeric へリセットします。しかし、これはその後に set xtics を呼び出すことで変更できます。
例:
set xdata time # 入力データの解釈の制御
set timefmt "%d/%m" # 入力データの読み込みの書式
set xtics timedate # 出力書式の解釈の制御
set xtics format "%b %d" # 目盛りラベルで使う書式
set xrange ["01/12":"06/12"]
set xtics "01/12", 172800, "05/12"
set xdata time
set timefmt "%d/%m"
set xtics format "%b %d" time
set xrange ["01/12":"06/12"]
set xtics ("01/12", "" "03/12", "05/12")
%D = 度の整数表示
%<width.precision>d = 度の浮動小数表示
%M = 分の整数表示
%<width.precision>m = 分の浮動小数表示
%S = 秒の整数表示
%<width.precision>s = 秒の浮動小数表示
%E = +/- でなく E/W のラベル
%N = +/- でなく N/S のラベル
xtics がデフォルトの状態のまま (set xtics numeric) の場合は、座標は 10 進数の度で表示し、format も上の特別な記号ではなく、通常の数値書式 が使われているとみなされます。
set border 3
set yrange [0:10]
set ytics nomirror rangelimited
plot "file.dat"
書式:
set xyplane at <zvalue>
set xyplane relative <frac>
set ticslevel <frac> # set xyplane relative と同等
show xyplane
set xyplane relative < frac> は、xy 平面を Z 軸の範囲のどこに置くかを 決定します。< frac> には、xy 平面と z の一番下の位置との差の、z 軸の範 囲全体に対する割合を与えます。デフォルトの値は 0.5 です。負の値も許さ れていますが、そうすると 3 つの軸の目盛りの見出しが重なる可能性があり ます。
もう一つの形式である set xyplane at < zvalue> は、現在の z の範囲を気 にすることなく、指定した z の値の位置に xy 平面を固定します。よって、 x,y,z 軸を共通の原点を通るようにするには、set xyplane at 0 とすれば いいことになります。
以下も参照: set view (88.90), set zeroaxis (88.127)。
書式:
set zero <expression>
show zero
gnuplot は、(複素数値を持つ点の描画においては) その値の虚数部分の絶 対値が zero 閾値より大きい場合 (つまり実数でない値を持つ点) は、その 点を描画しません。この閾値は gnuplot の他の様々な部分においてその (大まかな) 数値誤差の閾値としても使われています。デフォルトの zero の 値は 1e-8 です。1e-3 (= 典型的なビットマップディスプレイの解像度の逆数) より大きい zero の値は設定すべきではないでしょうが、zero を 0.0 と 設定するのは意味のないことではありません。
書式:
set {x|x2|y|y2|z}zeroaxis { {linestyle | ls <line_style>}
| { linetype | lt <line_type>}
{ linewidth | lw <line_width>}}
unset {x|x2|y|y2|z}zeroaxis
show {x|y|z}zeroaxis
デフォルトでは、これらのオプションはオフになっています。選択された 0 の軸は < line_type> の線の型と< line_width> の線の幅 (現在使用している 出力形式がサポートしていれば) で、あるいはあらかじめ定義された < line_style> のスタイルで描かれます。
線の型を指定しなければ、軸は通常の軸の線の型 (型 0) で描かれます。
例:
y=0 の軸を見えるように簡単に書く場合:
set xzeroaxis
太い線にして、違った色、または点線パターンにしたい場合:
set xzeroaxis linetype 3 linewidth 2.5
カラーボックス軸 (cb-軸) が splot で自動縮尺されている場合は、その カラーボックスの範囲は zrange が使われます。splot ... pm3d| palette で描画される点は、異なる zrange と cbrange を使うことでフィルタリ ングできます。
set cbrange の書式に関する詳細は、以下参照: set xrange (88.103)。以下も参照:set palette (88.62), set colorbox (88.15)。
シェルコマンドを実行する方法は 2 つあります: コマンド system を使う か ! (VMS では $) を使うか。前者は、コマンド文字列をパラメータとして 取るので、他の gnuplot コマンドのどこでも使うことができますが、後者の 書式は、その行にそのコマンドただ一つであることを要求します。これらの場 合コマンドが終了するとすぐに制御は gnuplot に戻ってきます。例えば MS-DOS, OS/2 では、
! dir
system "dir"
とするとディレクトリの一覧を表示して gnuplot に戻ってきます。
system を使う他の例:
system "date"; set time; plot "a.dat"
print=1; if (print) replot; set out; system "lpr x.ps"
2 次元と 3 次元描画の両方で使える多くのオプションについては、以下参照:plot (77)。
書式:
splot {<ranges>}
{<iteration>}
<function> | {{<file name> | <data block name>}
{datafile-modifiers}}
{<title-spec>} {with <style>}
{, {definitions{,}} <function> ...}
コマンド splot は、関数から生成されたデータ、またはデータファイルか ら読み込んだデータ、または事前に保存された名前付きデータブロックのデー タを処理します。データファイル名は、通常引用符で囲んだ文字列として与え ます。関数は 1 本の数式ですが、媒介変数モード (parametric) では 3 つの 数式の組として与えます。
デフォルトでは、splot は描画されるデータの下に完全な xy 面を描きます。 z の一番下の目盛りと xy 平面の位置関係は set xyplane で変更できます。 splot の射影の向きは set view で制御できます。詳細は、以下参照:set view (88.90), set xyplane (88.105)。
splot コマンドの範囲の指定の書式は plot の場合と同じです。媒介変数
モード (parametric) でなければ、範囲指定は以下の順で、
splot [<xrange>][<yrange>][<zrange>] ...
splot [<urange>][<vrange>][<xrange>][<yrange>][<zrange>] ...
title オプションも plot と同じです。with も plot とほぼ同じで すが、2 次元の描画スタイル全部が使えるわけではありません。
datafile オプションにはさらに違いがあります。
媒介変数モード (parametric) や関数を利用して曲面を描く別の方法に、疑似 ファイル '++' を利用して xy 平面の格子の上に標本点を生成するやり方があ ります。
以下も参照: show plot (88.60), set view map (88.90), sampling (77.9)。
書式:
splot '<file_name>' {binary <binary list>}
{{nonuniform} matrix}
{index <index list>}
{every <every list>}
{using <using list>}
"" や "-" といった特別なファイル名も plot と同様に許されます。以下参照: special-filenames (77.3.7)。
手短にいうと、binary や matrix はそのデータが特別な形であることを、 index は多重データ集合ファイルからどのデータ集合を選んで描画するかを、 every は各データ集合からどのデータ行 (部分集合) を選んで描画するかを、 using は各データ行からどのように列を選ぶかを指定します。
index と every オプションは plot の場合と同じように振舞います。 using も、using のリストが 2 つでなく 3 つ必要であるということを 除いては同様です。
plot のオプションである smooth は splot では利用できません。しか し、cntrparam や dgrid3d が、制限されてはいますが平滑化のために用 意されています。
データファイルの形式は、各点が (x,y,z) の 3 つ組である以外は、本質的にplot と同じです。もし一つの値だけが与えられれば、それは z として使われ、 データブロック番号が y として、そして x はそのデータブロック内での番号が 使われます。もし 2 つ、あるいは 4 つの値が与えられれば、gnuplot はその 最後の値を pm3d plot での色の計算に使います。3 つの値は (x,y,z) の組と見 なされます。他に値があれば、それは一般に誤差と見なされます。それは fit で使うことが可能です。
splot のデータファイルでは、1 行の空行はデータブロックの分離子です。 splot は個々のデータブロックを、関数の y-孤立線と同じものとして扱い ます。1 行の空行で分離されている点同士は線分で結ばれることはありません。 全てのデータブロックが全く同じ点の数を持つ場合、gnuplot はデータ ブロックを横断し、対応する点同士を結ぶ孤立線を描きます。これは "grid data" と呼ばれ、曲面の描画、等高線の描画 (set contour)、隠線処理 (set hidden3d) では、この形のデータであることが必要となります。以下も参照: splot grid_data (90.2)。
3 列の splot データにおいては、媒介変数モード (parametric) を指定 することはもはや不要です。
その 1 つは、x, y の座標が一様であると仮定して、その値をこの一様な格子 の matrix のそれぞれの要素 M[i,j] に割り当てる方法です。 割り当てられる x 座標は [0:NCOLS-1] の範囲の整数です。 割り当てられる y 座標は [0:NROWS-1] の範囲の整数です。 これは、テキストデータに対してはデフォルトですが、バイナリデータに対し てはそうではありません。 例や追加キーワードについては以下参照: matrix uniform (90.1.1.1)。
2 つ目の形式は、非一様な格子で、x, y 座標は明示していると仮定するもの で、入力データの最初の行を y 座標、最初の列を x 座標とみなします。 バイナリデータに対しては、1 行目の最初の要素は、列数でなければいけませ ん。これは、binary matrix 入力ではデフォルトですが、テキスト入力デー タに対しては追加キーワード nonuniform が必要になります。 例に関しては以下参照: matrix nonuniform (90.1.1.2)。
splot 'file' matrix using 1:2:3 # テキストデータ
splot 'file' binary general using 1:2:3 # バイナリデータ
一様な格子の matrix データでは、各ブロックの z の値は一行で一度に読ま
れます。すなわち、
z11 z12 z13 z14 ... z21 z22 z23 z24 ... z31 z32 z33 z34 ...
テキストデータに対しては、1 行目がデータでなく列ラベルを持つ場合、追加
キーワード columnheaders を使ってください。同様に、各行の最初の要素
がデータでなくラベルである場合は、追加キーワード rowheaders を使用し
てください。以下は、その両方を使用する例です:
$DATA << EOD xxx A B C D aa z11 z12 z13 z14 bb z21 z22 z23 z24 cc z31 z32 z33 z34 EOD plot $DATA matrix columnheaders rowheaders with image
テキストデータでは、空行やコメント行は配列データを終了させ、新たな曲面 の網 (mesh) を開始します。いつものことですが、splot コマンドの index オプションを使ってファイル内の網を自由に選択できます。
非一様な matrix データを描画するコマンドの例:
splot 'file' nonuniform matrix using 1:2:3 # テキストデータ
splot 'file' binary matrix using 1:2:3 # バイナリデータ
よって、非一様な matrix データの構造は以下のようになります:
<N+1> <x0> <x1> <x2> ... <xN>
<y0> <z0,0> <z0,1> <z0,2> ... <z0,N>
<y1> <z1,0> <z1,1> <z1,2> ... <z1,N>
: : : : ... :
これらは以下のような 3 つの数字の組に変換されます:
<x0> <y0> <z0,0>
<x0> <y1> <z0,1>
<x0> <y2> <z0,2>
: : :
<x0> <yN> <z0,N>
<x1> <y0> <z1,0>
<x1> <y1> <z1,1>
: : :
そして、これらの 3 つの数字の組は gnuplot の孤立線に変換され、その後 gnuplot が通常の方法で描画の残りを行います。
int fwrite_matrix(file,m,nrl,nrl,ncl,nch,row_title,column_title)
です。これらのサブルーチンを使う例が bf_test.c として用意されていて、 これはデモファイル demo/binary.dem 用に複数のバイナリファイルを生成 します。
plot での使用法:
plot `a.dat` matrix
plot `a.dat` matrix using 1:3
plot 'a.gpbin' {matrix} binary using 1:3
例 - テキストデータファイルの配列の軸の拡大:
splot `a.dat` matrix using (1+$1):(1+$2*10):3
例 - テキストデータファイルの配列の第 3 行の描画:
plot 'a.dat' matrix using 1:3 every 1:999:1:2
Gnuplot は、array, record, format, filetype などの general バ イナリ形式を特定するようなキーワードをつけずにオプション binary を使 うことで、matrix バイナリファイルを読み込むことができます。その他の変換 用の general バイナリキーワードは、matrix バイナリファイルにも適用でき るでしょう。(詳細は、以下参照: binary general (77.2.1)。)
splot 'datafile.dat'
ここで、"datafile.dat" は以下を含むとします:
# The valley of the Gnu.
0 0 10
0 1 10
0 2 10
1 0 10
1 1 5
1 2 10
2 0 10
2 1 1
2 2 10
3 0 10
3 1 0
3 2 10
この "datafile.dat" は 4*3 の格子 (それぞれ 3 点からなるブロックの 4 つの行) を定義することに注意して下さい。行 (データブロック) は 1 行の 空行で区切られます。
x の値はそれぞれのデータブロックの中で定数になっていることに注意して下 さい。もし y を定数の値とし、隠線処理が有効な状態で描画すると、その曲面は 裏返しで書かれることになります。
格子状データ (grid data) に対して、個々のデータブロック内で x の値を定 数としておく必要はありませんし、同じ場所の y の値を同じ値に揃えておく 必要もありません。gnuplot は個々のデータブロック内の点の数が等しいと いうことを必要としているだけです。しかし、等高線を導くのに用いられる曲 面の網目は、対応する点を列的に選んで結ぶため、不揃いの格子データに対す る曲面の描画への影響は予想できません。それはケースバイケースの原理でテ ストすべきでしょう。
しかし、gnuplot はそのような形式を必ずしも必要とはしません。例えば 関数の場合は、samples は isosamples と違っていても構いません。 すなわち、x-孤立線のうち、1 本の y-孤立線と交わないものがいくつかある ことがあります。データファイルの場合は、個々のデータブロックのばらつい た点の個数が全て同じであれば、"孤立線は" はデータブロックの点を結び、 "横断孤立線" は各データブロックの対応する点同士を結び、"曲面" を作ろう とします。どちらの場合でも、等高線、および隠線処理モードは点が意図した フォーマットであった場合とは違った描画を与えることになります。ばらつき のあるデータは set dgrid3d によって{異なる}格子状データに変換すること ができます。
等高線に関するコードは、y-孤立線の点と、それに対応する隣の y-孤立線上
の点の間の線分に沿っての z の張力を計測します。よって、x-孤立線に、
y-孤立線との交点とはならないような標本点があるような曲面に対しては、
splot の等高線はそのような標本点を無視することになります。以下を試してみて下さい:
set xrange [-pi/2:pi/2]; set yrange [-pi/2:pi/2]
set style function lp
set contour
set isosamples 10,10; set samples 10,10;
splot cos(x)*cos(y)
set samples 4,10; replot
set samples 10,4; replot
さらに、格子状のデータ点に対しては、splot は同じ高さを持つ点を補間す ることができ (以下参照: set contour (88.17))、そしてそれらを結んで等高線を描 くことができます。さらに、その結び方には真直な線分や滑らかな線を使うこ とができます (以下参照: set cntrparam (88.14))。関数は、常に set isosamples と set samples で決定される格子状データとして評価されます。一方、フ ァイルのデータは、data-file に書かれているような格子状データフォーマ ットにするか、あるいは格子データを生成する (以下参照: set dgrid3d (88.22)) ということをしなければそうはなりません。
等高線は曲面の上に表示することもできますし、底面に射影することもできま す。底面への射影は、ファイルに書き出すこともでき、そしてそれを plot で再び読み込んで plot のより強い整形能力を生かすこともできます。
stats {<ranges>} 'filename' {matrix | using N{:M}} {name 'prefix'}
{{no}output}
このコマンドは、ファイルの 1 列、または 2 列のデータの簡単な統計情報を 提供します。using 指定子は、plot コマンドと同じ形で解釈されますが、 index, every, using 指定に関する詳細については以下参照: plot (77)。 データ点は、その解析の前に xrange, yrange に従ってフィルタにかけられま す。以下参照: set xrange (88.103)。その情報はデフォルトではスクリーンに出力さ れますが、コマンド set print を先に使うことで出力をファイルにリダイ レクトしたり、オプション nooutput を使うことで出力しないようにするこ ともできます。
画面出力に加え、gnuplot は個々の統計情報を 3 つの変数グループに保存し ます。 1 番目の変数グループは、どんなデータが並んでいるかを示します:
STATS_records |
N | 範囲内のデータ行の総数 |
STATS_outofrange |
範囲外として除かれた行数 | |
STATS_invalid |
無効/不完全/欠損データ行の総数 | |
STATS_blank |
空行の総数 | |
STATS_blocks |
ファイル内の index データブロック数 | |
STATS_columns |
データ先頭行の列数 |
2 番目の変数グループは、1 つの列の、範囲内のデータの性質を示します。こ の列は y の値として扱われます。y 軸が自動縮尺の場合は、対象とする範囲 に限界はありませんが、そうでなければ範囲 [ymin:ymax] 内の値のみを対象 とします。
2 つの列を同時に 1 回の stats コマンドで解析する場合は、各変数名に "_x", "_y" という接尾辞を追加します。例えば STATS_min_x は、1 つ目の列 のデータの最小値で、STATS_min_y は 2 つ目の列のデータの最小値を意味し ます。この場合、点は xrange と yrange の両方で検査することでふるいにか けます。
STATS_min |
min(y) | 範囲内のデータ点の最小値 | |
STATS_max |
max(y) | 範囲内のデータ点の最大値 | |
STATS_index_min |
i | yi = min(y) | data[i] == STATS_min となる添字 i | |
STATS_index_max |
i | yi = max(y) | data[i] == STATS_max となる添字 i | |
STATS_mean |
 =
|
  y
|
範囲内のデータ点の平均値 |
STATS_stddev |
 =
|
|
範囲内のデータ点の標本標準偏差 |
STATS_ssd |
sy = |
|
範囲内のデータ点の不偏標準偏差 |
STATS_lo_quartile |
第一 (下の) 四分位境界値 | ||
STATS_median |
メジアン値 (第二四分位境界値) | ||
STATS_up_quartile |
第三 (上の) 四分位境界値 | ||
STATS_sum |
y
|
和 | |
STATS_sumsq |
y2
|
平方和 | |
STATS_skewness |
 (y-)3
|
範囲内のデータ点の歪度 | |
STATS_kurtosis |
 (y-)4
|
範囲内のデータ点の尖度 | |
STATS_adev |
| y-|
|
範囲内のデータ点の平均絶対偏差 | |
STATS_mean_err |
/
|
平均値の標準誤差 | |
STATS_stddev_err |
/
|
標準偏差の標準誤差 | |
STATS_skewness_err |
|
歪度の標準誤差 | |
STATS_kurtosis_err |
|
尖度の標準誤差 |
3 番目の変数グループは、2 つの列のデータの解析専用です。
STATS_correlation |
x と y の不偏相関係数 | |
STATS_slope |
回帰直線 y = Ax + B の係数 A | |
STATS_slope_err |
A の不確かさ | |
STATS_intercept |
回帰直線 y = Ax + B の係数 B | |
STATS_intercept_err |
B の不確かさ | |
STATS_sumxy |
積和 (x*y の和) | |
STATS_pos_min_y |
y の最小値を与える x 座標 | |
STATS_pos_max_y |
y の最大値を与える x 座標 |
matrix が指定されると、全ての行列要素がその解析の対象になります。そ の行列のサイズは、変数 STATS_size_x と STATS_size_y に保存されます。
同時に 2 つ以上のファイルからの統計情報を使うことができれば便利でしょうから、変数のデフォルトの接頭辞である "STATS" をオプション name でユーザが指定する文字列に置き換えることができるようになっています。例え
ば、異なる 2 つのファイルのそれぞれの 2 列目のデータの平均値は以下のようにして比較できます:
stats "file1.dat" using 2 name "A"
stats "file2.dat" using 2 name "B"
if (A_mean < B_mean) {...}
STATS_index_xxx で示される添字の値は、plot コマンドの第 0 疑似列 ($0) の値に対応し、最初の点は添字は 0、最後の点の添字は N-1 となります。
メジアンと四分位境界値を探す際はデータの値をソートし、点の総数 N が奇 数の場合は、その (N+1)/2 番目の値をメジアン値とし、N が偶数の場合は、 N/2 番目と (N+2)/2 番目の値の平均値をメジアン値とします。四分位境界値 も同様に処理します。
その後の描画に注釈をつけるためにコマンド stats を利用した例について は、以下を参照してください。
現在の実装では、X 軸と Y 軸の一方が対数軸の場合は解析できません。この 制限は今後のバージョンでは解消されるでしょう。
これは、gnuplot スクリプト内に外部関数を取り込むのに使えます:
f(x) = real(system(sprintf("somecommand %f", x)))
書式:
test {terminal | palette}
test または test terminal は、現在使用中の出力形式 (terminal) で 使える線の種類、点の種類、または利用可能なその他の描画を生成します。
test palette は、R(z),G(z),B(z) (0< =z< =1) の状態を描画します。これら は現在のカラーパレット (palette) の RGB 成分を示します。また、RGB を 灰色階調に写像する NTSC 係数を用いて計算された視光度も描画します。この 対応関係は、$PALETTE という名前のデータブロックにも取り込まれます。
変数名には、最後の文字としてワイルドカード文字 * を使うことができま す。ワイルドカード文字が見つかると、それより前の部分で始まるすべての変 数を削除します。これは、共通の接頭語を使っている複数の変数を削除するの に便利でしょう。ただし、ワイルドカード文字は変数名の最後にしか使えない ことに注意してください。undefine にワイルドカード文字のみを引数とし て与えた場合は何もしません。
例:
undefine foo foo1 foo2
if (!exists("foo")) load "initialize.gp"
bar = 1; bar1 = 2; bar2 = 3
undefine bar* # 3 つの変数を全部削除
例:
set xtics mirror rotate by -45 0,10,100
...
unset xtics
# 番号 100 から 200 までのラベルを unset
unset for [i=100:200] label i
unset linetype N
その名前のファイルが存在しない場合、現在定義されているすべてのユーザ変 数を含む新しいファイルを作成しますが、最後の fit 内で使用しなかった変 数にはすべて "#FIXED" と印をつけています。これは、fit 変数の現在の値を 後で使うために、あるいは終了/中断した当てはめを再実行するために保存し ておくのに有用です。
書式:
update <filename> {<filename>}
2 番目のファイル名を指定すると、元のパラメータファイルは変更せずに 2 番目のファイルの方に更新された値を書き出します。
そうでなければ、指定したファイルが存在すれば gnuplot はそのファイル 名に .old をつけてファイル名を変更し、指定したファイル名のファイルを 新たに開き直します。つまり、"update 'fred'" とすると、それは "!rename fred fred.old; update 'fred.old' 'fred'" としたことと同じこ とになります。ファイルが既に存在するために名前の変更ができない場合は、 update はエラーメッセージを出力して失敗します。[VMS では、ファイルのバ ージョン管理システムが使われるため、名前の変更は行なわれません。]
より詳しい情報に関しては、以下参照: fit (68)。
while (<expr>) {
<commands>
}
この文書は、あなたのシステム上で初期設定およびインストールがなされなか ったために利用できない出力形式についても記述されているかも知れません。 インストールされた個々の gnuplot で、どの出力形式が有効なのかの一覧を 見るには、オプションを何もつけずに 'set terminal' と打ってください。
(訳注: この日本語訳に含まれる terminal のマニュアルは、その一覧にはな い出力形式のものも含まれているかもしれませんし、逆にその一覧内の出力形 式でマニュアルがないものもあるかもしれません。)
注意: 時代遅れの出力形式、元々は Adobe Illustrator 3.0+ 用。Adobe Illustrator はレベル 1 の PostScriptファイルを直接認識するので、これの 代わりに set terminal post level1 使うべきでしょう。
書式:
set terminal aifm {color|monochrome} {"<fontname>"} {<fontsize>}
書式:
set terminal aqua {<n>} {title "<wintitle>"} {size <x> <y>}
{font "<fontname>{,<fontsize>}"}
{{no}enhanced} {solid|dashed} {dl <dashlength>}}
< n> は描画するウィンドウの番号 (デフォルトでは 0) < wintitle> はタイトルバーに表示される名前 (デフォルトは "Figure < n> "), < x> < y> は描画サイズ (デフォルトは 846x594 pt = 11.75x8.25 インチ) です。
使用するフォントは < fontname> で指定し (デフォルトは "Times-Roman")、 フォントサイズは < fontsize> で指定します (デフォルトは 14.0 pt)。
aqua 出力形式は、拡張文字列処理モード (enhanced text mode; 以下参照:enhanced (13)) を、重ね書き以外はサポートしてます。フォントの使用はシステ ムで有効なフォントに制限されています。文字エンコーディングは、 set encoding で選択できますが、現在は iso_latin_1, iso_latin_2, cp1250 と UTF8 (default) をサポートしています。
曲線は、実線か点線 (デフォルトは実線) のいずれかで描画でき、点線の間隔は 倍率 < dashlength> (> 0) で変更できます。
書式:
set terminal be {reset} {<n>}
複数のグラフ描画ウィンドウをサポートしています。set terminal be < n> は番号 n のウィンドウに出力します。n> 0 の場合、その番号はウィンドウタ イトルとアイコン名に gplt < n> として付けられます。現在のウィンドウは カーソル記号の変化で区別できます (デフォルトカーソルから十字カーソルへ)。
gnuplot ドライバが別な出力ドライバに変更されても、描画ウィンドウは開 いたままになります。描画ウィンドウは、そのウィンドウにカーソルを置いて 文字 q を押すか、ウィンドウマネージャのメニューの close を選択すれば 閉じることができます。reset を実行すれば全てのウィンドウを一度に閉じ れます。それは実際にウィンドウを管理している子プロセスを終了します (も し -persist が指定されていなければ)。
描画ウィンドウは -persisit オプションが与えられていなければ、対話の 終了時に自動的に閉じられます。
描画サイズとアスペクト比は、gnuplot のウィンドウをリサイズすることで も変更できます。
線の幅と点のサイズは gnuplot の set linestyle で変更可能です。
出力ドライバ be に関しては、gnuplot は (起動時に)、コマンドライン、 または設定ファイルから、geometry や font, name などの通常の X Toolkit オプションやリソースの指定を受け付けます。それらのオプションについては X(1) マニュアルページ (やそれと同等のもの) を参照してください。
他にも be 出力形式用の多くの gnuplot のオプションがあります。これ らは gnuplot を呼ぶときにコマンドラインオプションとして指定するか、 または設定ファイル ".Xdefaults" のリソースとして指定できます。これらは 起動時に設定されるので、gnuplot 実行時には変更できません。
| `-mono` | カラーディスプレイ上で強制的に白黒描画 |
| `-gray` | グレイスケールまたはカラーディスプレイ上でのグレイスケール描画 |
| (デフォルトではグレイスケールディスプレイは白黒描画を受け付ける) | |
| `-clear` | 新しい描画を表示する前に (瞬間的に) 画面を消去 |
| `-raise` | 各描画後に描画ウィンドウを最前面へ出す |
| `-noraise` | 各描画後に描画ウィンドウを最前面へ出すことはしない |
| `-persist` | gnuplot プログラム終了後も描画ウィンドウを残す |
例:
gnuplot*gray: on
gnuplot は描画スタイル points で描画する点のサイズの制御にも、コマンド ラインオプション (-pointsize < v> ) とリソース (gnuplot*pointsize: < v> ) を提供しています。値 v は点のサイズの拡大率として使われる実数値 (0 < v < = 10) で、例えば -pointsize 2 はデフォルトのサイズの 2 倍、 -pointsize 0.5 は普通のサイズの半分の点が使われます。
| gnuplot*background: white | |
| gnuplot*textColor: black | |
| gnuplot*borderColor: black | |
| gnuplot*axisColor: black | |
| gnuplot*line1Color: red | |
| gnuplot*line2Color: green | |
| gnuplot*line3Color: blue | |
| gnuplot*line4Color: magenta | |
| gnuplot*line5Color: cyan | |
| gnuplot*line6Color: sienna | |
| gnuplot*line7Color: orange | |
| gnuplot*line8Color: coral |
これらに関するコマンドラインの書式は、例えば以下の通りです。
例:
gnuplot -background coral
| gnuplot*background: black | |
| gnuplot*textGray: white | |
| gnuplot*borderGray: gray50 | |
| gnuplot*axisGray: gray50 | |
| gnuplot*line1Gray: gray100 | |
| gnuplot*line2Gray: gray60 | |
| gnuplot*line3Gray: gray80 | |
| gnuplot*line4Gray: gray40 | |
| gnuplot*line5Gray: gray90 | |
| gnuplot*line6Gray: gray50 | |
| gnuplot*line7Gray: gray70 | |
| gnuplot*line8Gray: gray30 |
| gnuplot*borderWidth: 2 | |
| gnuplot*axisWidth: 0 | |
| gnuplot*line1Width: 0 | |
| gnuplot*line2Width: 0 | |
| gnuplot*line3Width: 0 | |
| gnuplot*line4Width: 0 | |
| gnuplot*line5Width: 0 | |
| gnuplot*line6Width: 0 | |
| gnuplot*line7Width: 0 | |
| gnuplot*line8Width: 0 |
gnuplot は線描画で使用する点線の形式の設定用に以下のリソースを参照します。0 は実線を意味します。2 桁の 10 進数 jk (j と k は 1 から 9 までの値) は、j 個のピクセルの描画に k 個の空白のピクセルが続く パターンの繰り返しからなる点線を意味します。例えば '16' は 1 個のピク セルの後に 6 つの空白が続くパターンの点線になります。さらに、4 桁の 10 進数でより詳細なピクセルと空白の列のパターンを指定できます。例えば、 '4441' は 4 つのピクセル、4 つの空白、4 つのピクセル、1 つの空白のパタ ーンを意味します。以下のデフォルトのリソース値は、白黒ディスプレイ、あるいはカラーや白黒階調 (grayscale) ディスプレイ上の白黒描画における値 です。カラーディスプレイではそれらのデフォルトの値はほとんど 0 (実線) で、axisDashes のみがデフォルトで '16' の点線となっています。
| gnuplot*borderDashes: 0 | |
| gnuplot*axisDashes: 16 | |
| gnuplot*line1Dashes: 0 | |
| gnuplot*line2Dashes: 42 | |
| gnuplot*line3Dashes: 13 | |
| gnuplot*line4Dashes: 44 | |
| gnuplot*line5Dashes: 15 | |
| gnuplot*line6Dashes: 4441 | |
| gnuplot*line7Dashes: 42 | |
| gnuplot*line8Dashes: 13 |
書式:
set terminal cairolatex
{eps | pdf}
{standalone | input}
{blacktext | colortext | colourtext}
{header <header> | noheader}
{mono|color}
{{no}transparent} {{no}crop} {background <rgbcolor>}
{font <font>} {fontscale <scale>}
{linewidth <lw>} {rounded|butt|square} {dashlength <dl>}
{size <XX>{unit},<YY>{unit}}
cairolatex 出力形式は、epscairo 出力形式 (termnal epscairo) や pdfcairo 出力形式 (terminal pdfcairo) と同等のグラフを出力しますが、 テキスト文字列はグラフの中に入れるのではなく、LaTeX に渡します。以下で触れないオプションについては、以下参照: pdfcairo (98.44)。
eps と pdf は、グラフ出力の形式を選択します。latex/dvips 用には eps を、pdflatex 用には pdf を使用してください。
blacktext は、カラーモードでもすべての文字列を黒で書くようにします。
cairolatex 出力ドライバは、文字列の位置の特別な制御方法を提供します:
(a) '{' で始まるすべての文字列は、'}' もその文字列の最後に必要ですが、
その文字列全体を LaTeX で横にも縦にもセンタリングします。
(b) '[' で始まる文字列は、その次に位置指定文字 (t,b,l,r,c のうち 2 つま
で)、']{'、対象文字列、と続き最後に '}' で閉じますが、この文字列は、
LaTeX が LR-box として処理できるものならなんでも構いません。位置合わせ
を完全に行うには、
\
rule{}{} も有用でしょう。以下も参照: pslatex (98.49)。
複数行に渡るラベルを生成する場合、
\
shortstack を使用してください。例:
set ylabel '[r]{\shortstack{first line \\ second line}}'
コマンド set label のオプション back は、他の出力形式とはやや異なる 方法で処理します。back を使用したラベルは、他のすべての描画要素の後ろ に印字し、front を使用したラベルは、他のすべての上に印字します。
このドライバは 2 つの異なるファイルを作成します。一つは図の eps かまた は pdf 部分で、もう一つは LaTeX 部分です。その LaTeX ファイルの名前は、 コマンド set output のものを使用し、eps/pdf ファイルの名前は、その拡 張子 (通常は '.tex') を '.eps' か '.pdf' に置き換えたものを使用します。 出力ファイルを指定しなかった場合は、LaTeX 出力はしません。multiplot モード以外では、次の plot を行う前に出力ファイルを閉じるのを忘れないでください。
この画像をあなたの LaTeX 文書に取り込むには、' \ input{filename}' を使用 してください。'.eps' や '.pdf' ファイルは、 \ includegraphics{...} コマ ンドで取り込むので、LaTeX 文書のプリアンブルに \ usepackage{graphicx} を入れる必要があります。色付きの文字 (オプション colourtext) を使用 する場合は、プリアンブルに \ usepackage{color} も入れる必要があります。
フォント選択に関する挙動は、ヘッダーモードに依存します。いずれの場合で も、与えられたフォントサイズは適切な大きさを計算するのに使われます。 standalone モードを使っていない場合は、それを読みこんだところで実際に LaTeX が使用しているフォントとフォントサイズが使われるので、フォントを 変更するには LaTeX のコマンドを使用してください。LaTeX 文書の方で 12pt のフォントサイズを使っていれば、オプションとして '", 12"' を指定して ください。フォント名は無視されます。'standalone' の場合は、与えられたフ ォントとフォントサイズを使用します。詳細は以下を参照してください。
文字列を色付けして印字するかどうかは、TeX のブール変数
\
ifGPcolor と
\
ifGPblacktext で制御できます。
\
ifGPcolor が true で
\
ifGPblacktext
が false のときのみ文字列が色付けされます。これらの変更は、生成された
TeX ファイル中で行うか、または大域的にあなたの TeX ファイルのプリアンブ
ルで、例えば以下のようにして設定できます:
\newif\ifGPblacktext \GPblacktexttrue
出力形式 cairolatex を使う場合は、コマンド set output で TeX ファイル 設定する際にファイルの拡張子 (通常は ",tex") をつけてください。 グラフのファイル名は、その拡張子を置きかえることで作られます。
standalone モードを使う場合、LaTeX ファイルに完全な LaTeX のヘッダが 追加され、グラフファイルのファイル名には "-inc" が追加されます。 standalone モードは、dvips, pdfTeX, VTeX を使う場合に正しいサイズの出 力を作る TeX ファイルを生成します。デフォルトでは input で、これは LaTeX 文書から \ input コマンドで取り込まれる必要があるファイルを生成し ます。
"" や "default" 以外のフォントを与えた場合、それは LaTeX のフォント名であるとみなされます。それは ',' 区切りで最大 3 つの部分からなる、 'fontname,fontseries,fontshape' の形式です。デフォルトの fontshape や fontseries を使いたい場合は、それらは省略できます。よって、フォント名の 実際の書式は、'{fontname}{,fontseries}{,fontshape}' となります。(訳注: より gnuplot 風に言えば '{< fontname> }{,{< fontseries> }{,< fontshape> }}') 名前の各部分の指定法は、LaTeX のフォント系の慣習に従う必要があります。 フォント名 (fontname) は 3 から 4 文字の長さで、以下のようになっています: 最初の文字はフォントの供給者、次の 2 つの文字はフォント名用、オプションとして特別なフォント用に 1 文字追加できます。例えば、'j' は古いスタ イルの数字用のフォント、'x' はエキスパートフォント用です。多くのフォン ト名が以下に記述されています:
http://www.tug.org/fontname/fontname.pdf
例えば、'cmr' は Computer Modern Roman を、'ptm' は Times-Roman, 'phv' は Helvetica を意味しています。font series は、グリフの太さを表し、多く の場合は、'm' が標準 ("medium")、'bx' か 'b' が太字 (bold) のフォント を意味します。font shape は、一般的には 'n' が立体 (upright)、'it' がイ タリック (italic)、'sl' が斜体 (slanted)、'sc' がスモールキャピタル (small caps) を意味します。異なる series や shapes を提供するフォントも あります。
例:
Times-Roman のボールド体 (周りの文字列と同じ形状) を使うには:
set terminal cairolatex font 'ptm,bx'
set terminal cairolatex font 'phv,bx,it'
set terminal cairolatex font ',,sl'
set terminal cairolatex font ',,sc'
この方法では、テキストフォントだけが変更されます。数式フォントも変更し たい場合は、ファイル "gnuplot.cfg" か、または以下で説明するオプションheader を使う必要があります。
standalone モードでは、フォントサイズはコマンド set terminal で指定 したフォントサイズを取ります。指定したフォントサイズを使うためにはファ イル "size< size> .clo" が LaTeX の検索パスにある必要があります。デフォ ルトでは 10pt, 11pt, 12pt をサポートしています。パッケージ "extsizes" がインストールされていれば、8pt, 9pt, 14pt, 17pt, 20pt も追加されます。
オプション header は一つの文字列を引数として取り、その文字列を生成す る LaTeX ファイルに書き出します。standalone モードでは、それはプリア ンブルの \ begin{document} の直前に書きますが、input モードでは、それ はグラフに関するすべての設定を局所化するための \ begingroup コマンドの の直後に書きます。
例:
T1 フォントエンコーディングを使い、テキストフォントと数式フォントを
Times-Roman に、sans-serif フォントを Helvetica に変えるには:
set terminal cairolatex standalone header \
"\\usepackage[T1]{fontenc}\n\\usepackage{mathptmx}\n\\usepackage{helvet}"
set terminal cairolatex input header "\\bfseries"
LaTeX がファイル "gnuplot.cfg" を見つけると、standalone モードでは
それをプリアンブルに取り込みます。これは、さらに設定を追加するのに使え
ます。例: 文書のフォントを、数式フォント ("mathptmx.sty" が処理) も合
わせて Times-Roman, Helvetica, Courier にするには:
\usepackage{mathptmx}
\usepackage[scaled=0.92]{helvet}
\usepackage{courier}
出力形式 canvas は、HTML5 の canvas 要素上に描画する javascript コマ
ンドの集合を生成します。
書式:
set terminal canvas {size <xsize>, <ysize>} {background <rgb_color>}
{font {<fontname>}{,<fontsize>}} | {fsize <fontsize>}
{{no}enhanced} {linewidth <lw>}
{rounded | butt | square}
{dashlength <dl>}
{standalone {mousing} | name '<funcname>'}
{jsdir 'URL/for/javascripts'}
{title '<some string>'}
< xsize> と < ysize> は描画領域のピクセル単位でのサイズを設定します。 standalone モードでのデフォルトのサイズは、600x400 ピクセルです。 デフォルトのフォントサイズは 10 です。
注: ファイル canvastext.js で提供している Hershey simplex Roman フォン トのアスキー部分のフォント一つだけが利用できます。これは、ファイル canvasmath.js で置き換えることもでき、そこには UTF-8 エンコードされた Hershey simplex Greek と math symbols も含まれています。他の出力形式に 合わせて、font "name,size" の形式も使えるようになっています。今の ところ name のフォント名部分は無視されますが、そのうちにブラウザが名 前付きフォントをサポートしだすでしょう。
デフォルトの standalone モードは、HTML 5 の canvas 要素を使用してグ ラフを描画するような javascript コードを含む HTML ページを生成します。 その HTML ページは、2 つの必要な javascript ファイル 'canvastext.js'、 'gnuplot_common.js' にリンクします。点線をサポートするためにはさらに追 加ファイル 'gnuplot_dashedlines.js' が必要です。デフォルトではそれらは ローカルファイルへのリンクで、Unix 互換のシステムでは通常はそれらディ レクトリ /usr/local/share/gnuplot/< version> /js にあります。他の環境に ついては、インストールに関する注意を参照してください。この設定は、オプ ション jsdir に別のローカルディレクトリ、あるいは一般的な URL を指定 することで変更できます。グラフをリモートクライアントのマシンで見れるよ うにする場合は、通常は後者の設定が適切でしょう。
canvas 出力形式で生成される描画はすべてマウス操作可能です。キーワード mousing を追加すると、standalone モードのグラフの下にマウストラッ キングボックスをつけます。これは、canvastext.js が置かれているのと同 じローカルディレクトリ、または URL 内の、'gnuplot_mouse.js' という javascript ファイルへのリンクと 'gnuplot_mouse.css' というマウスボック スに関するスタイルシートも追加します。
オプション name は、javascript のみを含むファイルを一つ生成します。
それが含む javascript 関数と、それが描画する canvas 要素の id の両方は、
以下の文字列パラメータから取られます。例えば以下のコマンド
set term canvas name 'fishplot'
set output 'fishplot.js'
<html>
<head>
<script src="canvastext.js"></script>
<script src="gnuplot_common.js"></script>
</head>
<body onload="fishplot();">
<script src="fishplot.js"></script>
<canvas id="fishplot" width=600 height=400>
<div id="err_msg">No support for HTML 5 canvas element</div>
</canvas>
</body>
</html>
このキャンバス上に描かれるそれぞれのグラフの名前は、fishplot_plot_1, fishplot_plot_2 等となります。外部の javascript ルーチンでそれらを参照 することもできます。例: gnuplot.toggle_visibility("fishplot_plot_2")
書式:
set terminal cgm {color | monochrome} {solid | dashed} {{no}rotate}
{<mode>} {width <plot_width>} {linewidth <line_width>}
{font "<fontname>,<fontsize>"}
{background <rgb_color>}
[deprecated] {<color0> <color1> <color2> ...}
solid は全ての曲線を実線で描き、どんな点線パターンも塗りつぶします; < mode> は landscape, portrait, default のいずれか; < plot_width> はポイント単位でのグラフの仮定されている幅; < line_width> はポイント単位での線幅 (デフォルトは 1); < fontname> はフォントの名前 (以下のフォント一覧参照); そして < fontsize> はポイント単位でのフォントのサイズ (デフォルトは 12) です。
最初の 6 つのオプションはどの順番で指定しても構いません。default を 選択すると、全てのオプションをそのデフォルトの値にします。
線の色を set term コマンドで設定する仕組みは、今は非推奨です。代わり に、背景色は分離されたキーワード background で、線の色は set linetype で設定すべきでしょう。この非推奨の仕組みでは色は 'xrrggbb' の形式で受け つけますが、x は文字 'x' そのもの、'rrggbb' は 16 進数での赤、緑、青の 成分です。最初の色を背景色として使い、その後に続く色指定を順次線の色と として割り当てていました。
例:
set terminal cgm landscape color rotate dashed width 432 \
linewidth 1 'Helvetica Bold' 12 # デフォルト
set terminal cgm linewidth 2 14 # やや広い線とやや大きいフォント
set terminal cgm portrait "Times Italic" 12
set terminal cgm color solid # 面倒な点線など消えてしまえ !
| CGM fonts | ||
| Helvetica | Hershey/Cartographic_Roman | |
| Helvetica Bold | Hershey/Cartographic_Greek | |
| Helvetica Oblique | Hershey/Simplex_Roman | |
| Helvetica Bold Oblique | Hershey/Simplex_Greek | |
| Times Roman | Hershey/Simplex_Script | |
| Times Bold | Hershey/Complex_Roman | |
| Times Italic | Hershey/Complex_Greek | |
| Times Bold Italic | Hershey/Complex_Italic | |
| Courier | Hershey/Complex_Cyrillic | |
| Courier Bold | Hershey/Duplex_Roman | |
| Courier Oblique | Hershey/Triplex_Roman | |
| Courier Bold Oblique | Hershey/Triplex_Italic | |
| Symbol | Hershey/Gothic_German | |
| ZapfDingbats | Hershey/Gothic_English | |
| Script | Hershey/Gothic_Italian | |
| 15 | Hershey/Symbol_Set_1 | |
| Hershey/Symbol_Set_2 | ||
| Hershey/Symbol_Math | ||
C:\Program Files\Microsoft Office\Office\Cgmimp32.hlp
C:\Program Files\Common Files\Microsoft Shared\Grphflt\Cgmimp32.cfg
set term コマンドでデフォルトのフォントリストにないフォント名を指定 することも可能です。その場合、その指定したフォントが最初に現われる新 しいフォントリストが作られます。そのフォント名に関して、スペル、単語 の先頭の大文字化やどこにスペースが入るかなどが、作られる CGM ファイル を読むアプリケーションにとって適切なものであるかをちゃんと確認する必要 があります。(gnuplot と任意の MIL-D-28003A 準拠アプリケーションは、フ ォント名の大文字小文字の違いは無視します。) 新しいフォントをいくつも追 加したい場合は、set term コマンドを繰り返し使用してください。
例:
set terminal cgm 'Old English'
set terminal cgm 'Tengwar'
set terminal cgm 'Arabic'
set output 'myfile.cgm'
plot ...
set output
set label コマンドでは新しいフォントを導入することはできません。
例:
set terminal cgm width 432 # デフォルト
set terminal cgm width 6*72 # 上と同じ値
set terminal cgm width 10/2.54*72 # 10 cm の幅
ConTeXt + gnuplot モジュールの平均的なユーザには、このページを読むより も、Using ConTeXt を参照するか、ConTeXt の gnuplot モジュールのマニュ アルを参照することを推奨します。
出力形式 context は、以下のオプションをサポートしています:
書式:
set term context {default}
{defaultsize | size <scale> | size <xsize>{in|cm}, <ysize>{in|cm}}
{input | standalone}
{timestamp | notimestamp}
{noheader | header "<header>"}
{color | colour | monochrome}
{rounded | mitered | beveled} {round | butt | squared}
{dashed | solid} {dashlength | dl <dl>}
{linewidth | lw <lw>}
{fontscale <fontscale>}
{mppoints | texpoints}
{inlineimages | externalimages}
{defaultfont | font "{<fontname>}{,<fontsize>}"}
standalone でないグラフ (input) では、オプションはグラフサイズを選択 する size、すべてのラベルを倍率 < fontscale> で伸縮する fontscasle、 および font サイズのみ意味を持ち、他のオプションは警告なく無視されるの みで、それらはそのグラフィックを読み込む .tex ファイルの方で設定してく ださい。元の文書のフォントが 12pt ではない場合は、適切なフォントサイズ を指定することを強く推奨します。それにより、gnuplot がラベル用にどれく らいの大きさのスペースを確保すればいいかを知ることができまず。
default は、すべてのオプションをデフォルトの値にリセットします。
defaultsize は、描画サイズを 5in x 3in に設定します。 size < scale> は、描画サイズをデフォルトサイズの < scale> 倍にしますが 引数を ',' 区切りで 2 つ与えた場合は、最初のものは横のサイズを、2 つ目 のものは垂直サイズを設定します。それらのサイズには、単位としてインチ ('in'), センチ ('cm') が使えますが、省略した場合はデフォルト値に対する 比であるとみなします。
input (デフォルト) は、他の ConTeXt 文書から取り込めるグラフを生成し ます。 standalone は、それに数行追加し、それ自身がそのままコンパイルできるよ うにします。その場合、header オプションが必要になるかもしれません。
standalone のグラフに設定/定義/マクロを追加したい場合は header を使用 してください。デフォルトは noheader です。
notimestamp は、コメント部分の日時の出力を抑制します (バージョン管理 システムを使っている場合、日付だけ違うものを新しいバージョンとして登録 したくはないでしょう)。
color (デフォルト) は、カラー描画を生成しますが、monochrome は一切 special を入れません。白黒プリンタ用には、その挙動をこんな風に変えた方 がもっと良くなるというアイデアを持っている人は、是非提案してください。
rounded (デフォルト) と mitered, beveled は、線分の接合部の形状を 制御し、round (default) と butt, squared は、線分の端の形状を制御 します。詳細は、PostScript か PDF のリファレンスマニュアルを参照してく ださい。激しく変化する関数と太い線用には、線分の接合部での尖った角を避 けるようにrounded と round を使うといいでしょう。 (これに関する一般的な仕組みは、このオプションを各描画スタイル毎に別々に 指定できるよう gnuplot がサポートすべきだと思います。)
dashed (デフォルト) は、異なる線種に異なる点線パターンを使い、solid は、すべての描画に実線を使用します。
dashlength (または dl) は、点線の線分の長さを < dl> 倍します。 linewidth (または lw) は、すべての線幅を < lw> 倍します。 (lw 1 は 0.5bp を意味し、これは Metapost の描画のデフォルトの線幅です) fontscale は、テキストラベルをデフォルトの文書フォントの < fontscale> 倍に拡大します。
mppoints は、Metapost で描画された定義済みの点の形状を使用します。
texpoints は、簡単に設定できる記号セットを使用します。これは、以下のようにして ConTeXt で定義できます:
\defineconversion[my own points][+,{\ss x},\mathematics{\circ}]
\setupGNUPLOTterminal[context][points=tex,pointset=my own points]
inlineimages は、バイナリ画像を文字列として書き出しますが、これは ConTeXt MKIV のみで機能します。 externalimages は、PNG ファイルを外部出力し、これは ConTeXt MKII で機 能します。これが動作するためには、gnuplot が PNG 画像出力をサポートして いる必要があります。
standalone のグラフでは、font でフォント名とサイズを設定できます。
standalone でないモード (input) では、テキストラベルに十分なスペース
を割り当てるためにフォントサイズのみが意味を持ちます
コマンド
set term context font "myfont,ss,10"
\setupbodyfont[myfont,ss,10pt]
set label ... font "myfont,12"
適当なタイプスクリプトフォント (とヘッダー) を用意するのは自分で行って
さもなくばフォントの切り替えは効果を持ちません。ConTeXt MKII (pdfTeX)
の標準フォントは、以下のようにして使えます:
set terminal context standalone header '\usetypescript[iwona][ec]' \
font "iwona,ss,11"
例:
set terminal context size 10cm, 5cm # 10cm, 5cm
set terminal context size 4in, 3in # 4in, 3in
set terminal context standalone header '\enableregime[utf-8]'
http://ctan.org/pkg/context-gnuplot
と、最新の ConTeXt が必要です。 そこから gnuplot を呼び出すには、write18 を可能にする必要があります。 ほとんどの TeX 配付物では、これは texmf.cnf で shell_escape=t とするこ とで設定できます。
この出力形式とより詳しいヘルプと例に関しては以下も参照してください:
http://wiki.contextgarden.net/Gnuplot
\usemodule[gnuplot]
\starttext
\title{How to draw nice plots with {\sc gnuplot}?}
\startGNUPLOTscript[sin]
set format y "%.1f"
plot sin(x) t '$\sin(x)$'
\stopGNUPLOTscript
\useGNUPLOTgraphic[sin]
\stoptext
書式:
set terminal corel { default
| {monochrome | color
{"<font>" {<fontsize>
{<xsize> <ysize> {<linewidth> }}}}}
ここで、フォントサイズ (fontsize) と線幅 (linewidth) はポイント単 位、横幅 (xsize) と縦幅 (ysize) はインチ単位です。デフォルトの値は それぞれ、monochrome, "SwitzerlandLight", 22, 8.2, 10, 1.2 です。
書式:
set terminal dumb {size <xchars>,<ychars>} {[no]feed}
{aspect <htic>{,<vtic>}}
{[no]enhanced}
< xchars> , < ychars> はテキスト領域のサイズを設定し、デフォルトは 79 x 24 となっています。最後の改行は、feed オプションが設定されている場合のみ 出力されます。
オプション aspect は、グラフのアスペクト比の制御に使用します。これは 水平軸、垂直軸の目盛り刻みの長さを設定します。整数の指定のみが許されて いて、デフォルトは 2,1 で、これは共通のスクリーンフォントのアスペクト比 に対応します。
例:
set term dumb size 60,15 aspect 1
set tics nomirror scale 0.5
plot [-5:6.5] sin(x) with impulse ls -1
1 +-------------------------------------------------+
0.8 +|||++ ++||||++ |
0.6 +|||||+ ++|||||||+ sin(x) +----+ |
0.4 +||||||+ ++|||||||||+ |
0.2 +|||||||+ ++|||||||||||+ +|
0 ++++++++++++++++++++++++++++++++++++++++++++++++++|
-0.2 + +|||||||||||+ +|||||||||||+ |
-0.4 + +|||||||||+ +|||||||||+ |
-0.6 + +|||||||+ +|||||||+ |
-0.8 + ++||||+ ++||||+ |
-1 +---+--------+--------+-------+--------+--------+-+
-4 -2 0 2 4 6
このドライバによる出力は、LaTeX 用の "eepic.sty" マクロパッケージと共 に使われることを仮定しています。それを使うには、"eepic.sty" と "epic.sty"、および "tpic" \ special 命令群をサポートするプリンタドライ バが必要です。もし、あなたの使うプリンタドライバがそれらの "tpic" \ special 命令をサポートしていない場合でも、"eepicemu.sty" を使うことで それらのうちのいくつかを使えるようになります。 dvips と dvipdfm は "tpic" \ special をサポートしています。
書式:
set terminal eepic {default} {color|dashed} {rotate} {size XX,YY}
{small|tiny|<fontsize>}
オプション: オプションは任意の順番で与えることができます。 'color' は gnuplot に \ color{...} コマンドを生成させ、それによりグラフ をカラーにします。このオプションを使用する場合は、latex 文書のプリアン ブルに \ usepackage{color} を入れる必要があります。 'dashed' は線種に点線を使用することを許可します。このオプションを指定 しないと、色々な太さの実線のみが使われます。 'dashed' と 'color' は一方のみが意味を持ち、'color' が指定された場合、 'dashed' は無視されます。 'rotate' は本当に回転 (90 度) された文字列を使用するようになります。指 定しない場合は、1 文字 1 文字、上に積み上げていく方法で回転された文字 列を作ります。このオプションを使う場合は、 \ usepackage{graphicx} をプリ アンブルに入れる必要があります。 'small' は point スタイルでのグラフ描画の印として \ scriptsize の記号を 使用します (多分これは TeX ではだめで、LaTeX2e でしか使えないでしょう)。 デフォルトでは標準の数式のサイズを使用します。 'tiny' は、それに \ scriptscriptstyle の記号を使用します。 'default' は全てのオプションをデフォルトの値にリセットします。デフォル トは、color はなし、dashed line はなし、疑似回転 (積み上げ) 文字列の使 用、大きなサイズの記号の使用、です。 < fontsize> は picture 環境内でのフォントサイズを指定する数字です。単位 は pt (ポイント) で、10 pt はほぼ 3.5 mm です。フォントサイズを指定し ない場合、全てのグラフ内の文字は \ footnotesize に設定されます。
注意: 文字 # (およびその他 (La)TeX で特別な意味を持つその他の文字) を \ \ (バ ックスラッシュ 2 つ) でエスケープすることを忘れないでください。 グラフの角が近すぎると点線は実線のようになります。(これが tpic specials の一般的な問題なのか、eepic.sty や dvips/dvipdfm のバグが原因なのかは私 にはわかりません。) デフォルトの eepic グラフの大きさは 5x3 インチで、これは teminal オプシ ョンの size で変更可能です。 数ある中で、点 (point) は、LaTeX のコマンド " \ Diamond", " \ Box" などを 使って描かれます。これらのコマンドは現在は LaTeX2e のコアには存在せず latexsym パッケージに含まれていますが、このパッケージ基本配布の一部で あり、よって多くの LaTeX のシステムの一部になっています。このパッケー ジを使うことを忘れないでください。latexsym の代わりに amssymb パッケー ジを使うことも可能です。 LaTeX に関する全てのドライバは文字列の配置の制御に特別な方法を提供しま す: '{' で始まる文字列は、'}' で閉じる必要がありますが、その文字列全体 が水平方向にも垂直方向にもセンタリングされます。'[' で始まる文字列の場 合は、位置の指定をする文字列 (t,b,l,r のうち 2 つまで) が続き、次に ']{'、文字列本体、で最後に '}' としますが、この文字列は LaTeX が LR-box として整形します。' \ rule{}{}' を使えばさらに良い位置合わせが可能でしょ う。
例:
set term eepic
は、グラフを picture 環境に含まれた eepic マクロとして出力します。 そのファイルを LaTeX 文書に \input で取り込んでください。
eepic マクロを \color マクロ、point 印は \scripscriptsize の大きさ、 本当に回転された文字の使用、および全ての文字を 8pt にセットして出力 します。
見出しの位置合わせに関して:
gnuplot のデフォルト (大抵それなりになるが、そうでないこともある):
set title '\LaTeX\ -- $ \gamma $'
set label '{\LaTeX\ -- $ \gamma $}' at 0,0
set xlabel '[t]{\LaTeX\ -- $ \gamma $}'
set ylabel '[r]{\LaTeX\ -- $ \gamma $\rule{7mm}{0pt}}'
書式:
set terminal emf {color | monochrome}
{enhanced {noproportional}}
{rounded | butt}
{linewidth <LW>} {dashlength <DL>}
{size XX,YY} {background <rgb_color>}
{font "<fontname>{,<fontsize>}"}
{fontscale <scale>}
monochorome モードは折れ線を点線のパターンを循環させて打ち出します。 linewidth < factor> は全ての線幅をここで指定する値倍にします。 dashlength < factor> は、太い線には便利でしょう。 < fontname> はフォント名、 < fontsize> はポイント単位でのフォントの大きさです。
出力画像の形式的な (名ばかりの) サイズは、デフォルトでは適当な単位での 1024x768 になっています。オプション size を使って別な形式的なサイズ を指定できます。
拡張文字列処理モード (enhanced text mode) は、プロポーショナル文字間隔 を近似しようとします。モノスペースフォントを使う場合、あるいはこの近似 を好まない場合、オプション noproportional を使うことでこの補正をオフ にできます。
デフォルトの設定は、color font "Arial,12" size 1024,768 で、 default を選択すると全てのオプションがそのデフォルトの値になります。
例:
set terminal emf 'Times Roman Italic, 12'
書式:
set terminal emxvga
set terminal emxvesa {vesa-mode}
set terminal vgal
唯一のオプションは emxvesa に対する vesa のモードで、デフォルトでは それは G640x480x256 となっています。
詳細は、pdfcairo 出力形式のヘルプを参照してください。
書式:
set terminal epslatex {default}
set terminal epslatex {standalone | input}
{oldstyle | newstyle}
{level1 | leveldefault | level3}
{color | colour | monochrome}
{background <rgbcolor> | nobackground}
{dashlength | dl <DL>}
{linewidth | lw <LW>}
{rounded | butt}
{clip | noclip}
{palfuncparam <samples>{,<maxdeviation>}}
{size <XX>{unit},<YY>{unit}}
{header <header> | noheader}
{blacktext | colortext | colourtext}
{{font} "fontname{,fontsize}" {<fontsize>}}
{fontscale <scale>}
epslatex 出力形式は、文字列を PostScript コードに含ませる代わりに LaTeX ファイルに移すことを除けば terminal postscript eps 同様に描画します。 よって、postscript terminal と多くのオプションが共通です。
version 4.0 から 4.2 の間に、postscript 出力形式とのより良い互換性の ために epslatex 出力は変更されました。描画サイズは 5 x 3 インチから 5 x 3.5 インチへと変更され、文字幅は従来はフォントサイズの 50% と見 なしていましたが、現在は 60% と評価しています。より多くの Postscript の線種や記号も使われます。以前の状態にほぼ等しい状態にするにはオプション oldstyle を指定してください。(実際にはごくわずかな違いが残ります: 記号のサイズがわずかに違い、目盛刻み (tics) は従来の半分になっています がそれは set tics scale で変更できます。そして矢 (arrow) に関しては postscript 出力形式で使える全ての機能が利用できます。)
以下のようなエラーメッセージが出た場合:
"Can't find PostScript prologue file ... "
オプション color はカラーを有効にし、monochrome は各要素を黒と白 描画します。さらに、monochrome は灰色の palette も使用しますが、 これは、明示的に colorspec で指定された部品の色を変更しません。
dashlength または dl は点線の線分の長さを < DL> (0 より大きい実数) に設定し、 linewidth または lw は全ての線の幅を < LW> に設定します。
デフォルトでは、生成される PostScript コードは、特にフィルタリングや filledcurves のようなでこぼこな領域のパターン塗りつぶしにおいて、 PostScript Level 2 として紹介されている言語機能を使います。PostScript Level 2 の機能は条件的に保護されていて、PostScript Level 1 のインター プリタがエラーを出さず、むしろメッセージか PostScript Level 1 による 近似であることを表示するようになっています。level1 オプションは、こ れらの機能を近似する PostScript Level1 で代用し、PostScript Level 2 コードを一切使用しません。これは古いプリンタや、Adobe Illustrator の 古いバージョンなどで必要になるかもしれません。このフラグ level1 は 出力された PostScript ファイルのある一行を手で編集することで、後から 強制的に PostScript Level 1 機能を ON/OFF にすることもできます。level 2 のコードが含まれている場合、上の機能は現われないか、このフラグがセ ットされた場合、あるいは PostScript インタプリタプログラムが level 2 以上の PostScript を解釈するとは言わなかった場合に警告文に置き換わります。level3 オプションは、ビットマップ画像の PNG 化の機能を有効に します。それにより出力サイズをかなり削減できます。
rounded は、線の端や接合部を丸くし、デフォルトの butt は尖った端と 角張った接合部を使用します。
clip は、PostScript にすべての出力を BoundingBox (PostScript の外枠) でクリップすることを指示します; デフォルトは noclip です。
palfuncparam は set palette functions から出力の傾きをどのようにコ ード化するかを制御します。解析的な色の成分関数 (set palatte functions で設定される) は、postscript 出力では傾きの線形補完を用いてコード化さ れます: まず色の成分関数が < samples> 個の点で標本化され、そしてそれら の点は、結果として線形補完との偏差が < maxdeviation> 以内に収まるように削除されます。ほとんど全ての有効なパレットで、デフォルトの < samples> =2000 と < maxdeviation> =0.003 の値をそのまま使うのが良いでしょう。
PostScript 出力のデフォルトの大きさは 10 インチ x 7 インチです。EPS 出力のデフォルトの大きさは 5 x 3.5 インチです。オプション size は これらをユーザが指定したものに変更します。デフォルトでは X と Y のサ イズの単位はインチとみなされますが、他の単位 (現在は cm のみ) も使う ことはできます。描画の BoundingBox (PostScript ファイルの外枠) は、 サイズが変更された画像を丁度含むように正しく設定されます。 スクリーン座標は、オプション size で指定された描画枠の全体が 0.0 から 1.0 になります。 注意: これは、以前は、出力形式での設定よりも、コマンド set size で設定した方がいい、と言っていたことの変更を意味します。以前の方法では BoundingBox は変更されずに残ってしまい、スクリーン座標が実際の描画の限界に対応していませんでした。
blacktext は、たとえカラーモードでも全ての文字列を黒で書きます。
epslatex ドライバは文字列の配置の制御に特別な方法を提供します:
(a) '{' で始まる文字列は、'}' で閉じる必要がありますが、その文字列全体
が LaTeX によって水平方向にも垂直方向にもセンタリングされます。
(b) '[' で始まる文字列の場合は、位置の指定をする文字列 (t,b,l,r,c のう
ち 2 つまで) が続き、次に ']{'、文字列本体、で最後に '}' としますが、
この文字列は LaTeX が LR-box として整形します。
\
rule{}{} を使えばさ
らに良い位置合わせが可能でしょう。以下も参照: ドライバ pslatex (98.49) に関する説明。
複数行の見出しを作成するには
\
shortstack を使用してください。例えば、
set ylabel '[r]{\shortstack{first line \\ second line}}'
set label コマンドのオプション back は使えますが、他の出力形式のも のとは少し違っています。front の場合の見出しが他の全ての要素の上に出 力されるのに対して、back を使った見出しは他の全ての要素の下に出力され ます。
このドライバは 2 つの別のファイルを作ります。1 つは図の eps の部分で、 もう一つは LaTeX の部分です。LaTeX ファイルの名前は、set output コマ ンドのものが使われ、eps ファイルの名前はその拡張子 (通常 .tex) を .eps に置き換えたものになります。 出力ファイルを指定しなければ LaTeX 出力は行なわれません ! multiplot モード以外では、次の描画を行なう前にその出力ファイルをクローズするのを忘れないでください。
LaTeX の文書で図を取り込むには ' \ input{filename}' としてください。 .eps ファイルは \ includegraphics{...} コマンドで取り込むので、よって LaTeX のプリアンブルに \ usepackage{graphicx} も入れる必要があります。 textcolour オプションで色付きの文字列を使用している場合は、LaTeX の プリアンブルに \ usepackage{color} も入れる必要があります。
この eps ファイルから 'epstopdf' を使って pdf ファイルを作ることもでき ます。graphics パッケージが適切に設定されている場合、その LaTeX のファ イルは、変更なしに pdflatex によっても処理でき、その場合 eps ファイル の代わりに pdf ファイルが取り込まれます。
フォントの選択に関する挙動はヘッダーモードに依存します。 どの場合でも、与えられたフォントサイズはスペースの計算にちゃんと使用さ れます。standalone モードが使われなかった場合は、include される場所で の実際の LaTeX フォントとフォントサイズが使われるので、よってフォントの 変更には LaTeX コマンドを使ってください。例えばフォントサイズとして LaTeX 文書中で 12pt を使う場合は、オプション '"" 12' を使います。この 場合フォント名は無視されます。standalone を使う場合は、与えられたフォ ントとフォントサイズが使われます。詳細は下記を参照してください。
文字列がカラーで表示されるかどうかは TeX の Bool 値変数
\
ifGPcolor と
\
ifGPblacktext で制御します。
\
ifGPcolor が true で
\
ifGPblacktext が
false の場合のみ文字列はカラーで表示されます。それらは生成される TeX フ
ァイルを変更するか、またはあなたの TeX ファイルで大域的に与えてください。
例えば
\newif\ifGPblacktext \GPblacktexttrue
epslatex 出力形式を使う場合、set output コマンドで TeX ファイルの名前 を拡張子付き (通常 ".tex") で与えてください。eps ファイルの名前はその 拡張子を ".eps" に置き換えた名前になります。
standalone モードを使う場合、その LaTeX ファイルに完全な LaTeX のヘッ
ダが付加され、eps ファイルのファイル名には "-inc" が追加されます。
standalone モードは、dvips, pdfTeX, VTeX を使う場合に正しいサイズで出
力されるような TeX ファイルを作ります。
デフォルトは input モードで、これは
\
input コマンドを使って、別の
LaTeX ファイルから読み込まれるようなファイルを生成します。
"" か "default" 以外のフォント名が与えられた場合、それは LaTeX のフォント名と解釈されます。それは、'fontname,fontseries,fontshape' の、コ ンマで区切られた 3 つ以下の部分からなります。デフォルトのフォントシェイ プ、フォントシリーズが使いたい場合はそれらは省略できます。つまり、フォ ント名に対する正式な書式は、'[fontname][,fontseries][,fontshape]' とな ります。そのいずれの部分も名前に関しては LaTeX のフォント体系の慣習に従 います。fontname は 3 から 4 文字の長さで、次のような規則で作られていま す: 1 つ目がフォントの製造元を表し、次の 2 つがフォント名、オプションで 追加される 1 つは特別なフォントを意味し、例えば 'j' は旧式の数字を持つ フォント、'x' は expert フォント等となっています。以下には、多くのフォントの名前について書かれています。
http://www.tug.org/fontname/fontname.pdf
例えば 'cmr' は Computer Modern Roman フォント、'ptm' は Times-Roman, 'phv' は Helvetica 等を表します。フォントシリーズは文字の線の太さを意味 し、大半は 'm' で普通 ("medium")、'bx' または 'b' が太字 (bold) フォ ントを意味します。フォントシェイプは一般に 'n' が立体 (upright)、'it' はイタリック、'sl' は斜体 (slanted)、'sc' は小さい大文字 (small caps) となります。これらとは異なるフォントシリーズやフォントシェイプで与えら れるフォントも存在します。
例:
Times-Roman で太字 (シェイプは周りの文字列と同じもの) を使う場合:
set terminal epslatex 'ptm,bx'
set terminal epslatex 'phv,bx,it'
set terminal epslatex ',,sl'
set terminal epslatex ',,sc'
この方法では文字列のフォントのみが変更されます。数式のフォントも変更し たい場合は、"gnuplot.cfg" ファイルかまたは header オプションを使う 必要がありますが、これについては以下に書きます。
standalone モードでは、フォントサイズは set terminal コマンドで与えら れたフォントサイズが使われます。指定したフォントサイズが使えるためには LaTeX の検索パスに "size< size> .clo" というファイルが存在しなければな りません。デフォルトでは 10pt, 11pt, 12pt がサポートされています。パッ ケージ "extsizes" がインストールされていれば、8pt, 9pt, 14pt, 17pt, 20pt も追加されます。
オプション header は文字列引数を取ります。その文字列は、生成される LaTeX ファイルに書き込まれます。standalone モードを使う場合、その文字 列はプリアンブルの \ begin{document} コマンドの直前に書き込まれます。 input モードでは、その文字列は \ begingroup コマンドの直後に置かれ、 描画への設定がすべて局所的になるようにします。
例:
T1 フォントエンコーディングを使い、文字列、数式フォントを Times-Roman
とし、サンセリフフォントを Helvetica と変更する場合:
set terminal epslatex standalone header \
"\\usepackage[T1]{fontenc}\n\\usepackage{mathptmx}\n\\usepackage{helvet}"
set terminal epslatex input header "\\bfseries"
ファイル "gnuplot.cfg" が LaTeX によって見つけられると、standalone
モードを使っている場合は、それは生成される LaTeX 文書のプリアンブルに取
り込まれます。それは追加の設定を行なうのに使えます。例えば、文書のフォ
ントを TImes-Roman, Helvetica, Courier と変更し、("mathptmx.sty" で扱
われている) 数式フォントを入れる場合:
\usepackage{mathptmx}
\usepackage[scaled=0.92]{helvet}
\usepackage{courier}
epson_180dpi と epson_60dpi はそれぞれ 180dpi (ドット/インチ), 60dpi の解像度の Epson LQ 型 24 ピンプリンタ用のドライバです。
epson_lx800 は Epson LX-800, Star の NL-10 や NX-1000, PROPRINTER な どの適当なプリンタに流用できる、一般的な 9 ピンプリンタドライバです。
nec_cp6 は NEC CP6 や Epson LQ-800 などのプリンタで使える、一般的な 24 ピンプリンタ用のドライバです。
okidata ドライバは 9 ピンの OKIDATA 320/321 標準プリンタをサポートし ます。
starc ドライバは Star カラープリンタ用です。
tandy_60dpi ドライバは 9 ピン 60dpi の Tandy DMP-130 シリーズ用です。
dpu414 ドライバは Seiko DPU-414 感熱プリンタ用です。
nec_cp6 にはオプションがあります:
書式:
set terminal nec_cp6 {monochrome | colour | draft}
デフォルトでは白黒 (monochrome) です。
dpu414 にはオプションがあります:
書式:
set terminal dpu414 {small | medium | large} {normal | draft}
デフォルトは medium (= フォントサイズ) で normal です。 おすすめの組み合わせは、medium normal か small draft です。
書式:
set terminal fig {monochrome | color}
{landscape | portrait}
{small | big | size <xsize> <ysize>}
{metric | inches}
{pointsmax <max_points>}
{solid | dashed}
{font "<fontname>{,<fontsize>}"}
{textnormal | {textspecial texthidden textrigid}}
{{thickness|linewidth} <units>}
{depth <layer>}
{version <number>}
monochrome と color は 画像を白黒にするか color にするかを決定し ます。small と big は、デフォルトの landscape モードではグラフを 5x3 インチにするか 8x5 インチにするか、portrait モードでは 3x5 イン チにするか 5x8 インチにするかを決定します。size は描画範囲を < xsize> *< ysize> に設定 (変更) します。この場合の単位は、inches か metric かの設定によってそれぞれインチかセンチメートルかになります。 この設定は "xfig" での編集に対するデフォルトの単位としても使われます。
pointsmax < max_points> は折れ線の最大点数を設定します。
solid は、実線 (solid) の linestyle が全部使われてしまった後で自動的 に使われる点線の使用を抑制し、別な形で表示します。
font は、テキストフォントフェース名を < fontname> に、フォントサイズを < fontsize> ポイントに設定します。textnormal はテキストフラグの設定を リセットして postscript フォントを選択し、textspecial はテキストフラ グを LaTeX special に設定し、texthidden, textrigid はそれぞれ無表示 のテキスト、スケーリングされないテキスト用のフラグを設定します。
depth は全ての線と文字列に対する、重なりに関するデフォルトの深さ (depth layer) を設定します。デフォルトの深さは 10 で、"xfig" でグラフ の上に何かを上書きするための余地を残しています。
version は生成される fig 出力の書式バージョンを設定します。現在は、 バージョン 3.1 と 3.2 のみがサポートされています。
thickness はデフォルトの線の太さを設定し、指定されなければ 1 になりま す。太さの変更は、plot コマンドの linetype の値に 100 倍の数を加え ることで実現できます。同様に、(デフォルトの深さに対する) 各描画要素の 深さの値は < linetype> に 1000 倍の数を加えることで制御できます。よって その深さは < layer> +< linetype> /1000 になり、線の太さは (< linetype> %1000) /100 となりますが、その値が 0 の場合はデフォルトの線の太さになります。 linewidth は thickness と同義です。
plot コマンドの point スタイルによる描画の際の記号を fig ドライ
バで追加することもできます。記号の指定は (pointtype の値) % 100 の
50 以上の値が使われ、その塗りつぶしの濃さは <
pointtype>
% 5 の値で制御し、その輪郭は黒 (<
pointtype>
% 10 <
5 の場合) または現在の色で書かれ
ます。利用可能な記号は以下の通りです。
50 - 59: 円
60 - 69: 正方形
70 - 79: ひし形
80 - 89: 上向きの三角形
90 - 99: 下向きの三角形
有効な塗りつぶし色 (1 から 9) は、黒、青、緑、水色、赤、紫、黄、白、暗 い青 (白黒モードでは 1 から 6 までは黒で 7 から 9 までは白) です。
< linetype> と < pointtype> の詳細については、以下参照: plot with (77.12)。
big オプションは以前のバージョンの bfig ドライバの代用品ですが、このドライバは今はもうサポートされていません。
例:
set terminal fig monochrome small pointsmax 1000 # デフォルト
plot 'file.dat' with points linetype 102 pointtype 759
plot 'file.dat' using 1:2:3 with err linetype 1 pointtype 554
円の上にエラーバーを書くには以下のようにしてください。
plot 'file.dat' using 1:2:3 with err linetype 1 pointtype 2554
書式:
set terminal ggi [acceleration <integer>] [[mode] {mode}]
X では、ウィンドウマネージャの機能を使ってウィンドウのサイズを変更する
ことはできませんが、モードを mode オプションを使って、例えば以下のように変更することができます:
- V1024x768 - V800x600 - V640x480 - V320x200
bash> export GGI_DISPLAY=DGA csh> setenv GGI_DISPLAY DGA
acceleration は、相対的なポインタ動作イベントを発生するターゲット (例えば DGA) でのみ使用され、正の整数で相対的な距離に対する倍率 (積因 子) を表します。デフォルトの acceleration は 7 です。
例:
set term ggi acc 10 set term ggi acc 1 mode V1024x768 set term ggi V1024x768
set terminal gif
{{no}enhanced}
{{no}transparent} {rounded|butt}
{linewidth <lw>} {dashlength <dl>}
{tiny | small | medium | large | giant}
{font "<face> {,<pointsize>}"} {fontscale <scale>}
{size <x>,<y>} {{no}crop}
{animate {delay <d>} {loop <n>} {{no}optimize}}
{background <rgb_color>}
PNG, JPEG, GIF 画像は、外部ライブラリ libgd を使って生成されます。GIF
の描画は、ImageMagick パッケージのソフト 'display' にその出力を以下のようにパイプで渡すことで対話的に表示させることができます:
set term gif
set output '| display gif:-'
transparent は、ドライバに背景色の透明化 (transparent) を行うよう指 示します。デフォルトは notransparent です。
オプション linewidth と dashlength は拡大率で、描画されるすべての 線に影響を与えます。すなわち、これらは様々な描画コマンドで要求される値 に掛算されます。
butt は線分の描画で、その端の点でのはみだしを起こさない描画メソッド を使うようドライバに指示します。この設定は、線幅が 1 より大きい場合に のみ有効です。この設定は、水平線、垂直線の描画の場合に有用でしょう。 デフォルトは rounded (丸め) です。
フォントの選択の詳細は、やや複雑です。
以下に同じ意味を持つ簡単な例を示します:
set term gif font arial 11
set term gif font "arial,11"
オプション animate はあなたの手元にある gd ライブラリがアニメーショ ン gif の作成をサポートする場合にのみ有効です。作成される画像の表示間 隔は、1/100 秒単位で指定できます (デフォルトは 5)。ただし実際の表示間 隔は、使用する表示ソフトによって変化します。 アニメーションの繰り返し回数も指定できますが、デフォルトは 0 でそれは 無限の繰り返しを意味します。 アニメーション画像列は、次の set output か set term コマンドによっ て終了します。オプション optimize は、アニメーションに関する 2 つの 効果を持ちます。
1) アニメーション全体を通じて単一のカラーマップが使用されます。これは アニメーションの全てのフレームで使用される全ての色が最初のフレームで 定義されている必要があります。
2) 可能ならば、個々のフレームで一つ前のフレームと違う部分のみがアニメ ーションファイルに保存されます。これはファイルサイズを小さくしてくれ ますが、透明化機能を使用している場合には働かないかもしれません。
これら両方の最適化はより小さいサイズの出力ファイルを作ろうとするもの ですが、多分その減少量は、長いアニメーションかまたはフレームサイズが とても小さな場合にのみ意味がある程度でしょう。 オプション nooptimize はこれらの効果をいずれも無効にします。各フレ ームは、個々のカラーマップ (プライベートカラーマップ) を使い、丸ごと 保存されていきます。一つ注意しておきますが、最適化されていないアニメ ーションファイルは外部ユーティリティを使って後処理することができます し、その後処理によって gnuplot の最適化よりも小さなファイルが作られ るかもしれません。 デフォルトでは nooptimize です。
出力描画サイズ < x,y> はピクセル単位で与えます。デフォルトは 640x480 で す。以下も参照: canvas (8), set size (88.73)。 描画終了後の端の余白は、オプション crop で取り除くことができ、その結 果としてその画像サイズは小さくなります。デフォルトは nocrop です。
set terminal gif medium size 640,480 background '#ffffff'
この例は medium サイズの、大きさ変更不能で回転できない組み込みフォント を使用し、透明化されない背景色として白 (16 進数の 24bit RGB) を使用しま す。
set terminal gif font arial 14 enhanced
これは、'arial' というフェース名のスケーラブルフォントを検索し、フォン トサイズを 14pt に設定します。フォントの検索がどのように行われるかにつ いては以下参照: fonts (16)。これはスケーラブルフォントなので、拡張文字列 処理モードが使用できます。
set term gif animate transparent opt delay 10 size 200,200
load "animate2.dem"
これは、アニメーション GIF ファイルの作成用に gif 出力形式を開きます。 アニメーション列の個々のフレームは、標準デモファイル集にあるスクリプト ファイル animate2.dem によって生成されます。
書式:
set terminal gpic {<x> <y>}
ここで x と y の単位はインチです。
単純なグラフを整形するには以下のようにします。
groff -p -mpic -Tps file.pic > file.ps
pic からの出力はパイプで eqn に渡すこともできるので、'set label' と set {x/y}label コマンドでグラフに複雑な関数の式を入れることも可能で す。例えば、
set ylab '@space 0 int from 0 to x alpha ( t ) roman d t@'
とすれば、以下のコマンドによって y 軸に綺麗な積分が見出し付けされます。
gpic filename.pic | geqn -d@@ -Tps | groff -m[macro-package] -Tps
> filename.ps
このようにして作られた図は文書に綺麗に当てはまるように伸縮することがで きます。pic 言語は簡単に理解できるので、必要なら容易にグラフを直接編集 できます。gnuplot で作られる pic ファイルの全ての座標は x+gnuplotx, y+gnuploty の形で与えられます。デフォルトでは x, y の値は 0 です。いく つかのファイルに対してその x,y を 0 と設定している行を削除すれば、以下のようにして複数のグラフを一つの図の中に入れてしまうこともできます (デフォルトの大きさは 5.0x3.0 インチ):
.PS 8.0
x=0;y=3
copy "figa.pic"
x=5;y=3
copy "figb.pic"
x=0;y=0
copy "figc.pic"
x=5;y=0
copy "figd.pic"
.PE
これは、横に 2 つ、縦に 2 つずつ並んだ 4 つのグラフからなる、8 インチ の広さの図を生成します。
以下のように x, y を指定することでも同じことができます。
set terminal gpic x y
書式:
set terminal hp500c {<res>} {<comp>}
ここで res は 75, 100, 150, 300 のいずれかの解像度 (DPI; dots per inch) で、comp は "rle" か "tiff" です。他の設定をするとそれはデフォ ルトの値になります。デフォルトは 75 dpi で圧縮はなしです。高解像度での ラスタライズはたくさんのメモリを必要とします。
国際的文字セット ISO-8859-1 と CP850 を set encoding iso_8859_1 や set encoding cp850 で認識させることができます (詳細は、以下参照:set encoding (88.24))。
書式:
set terminal hpgl {<number_of_pens>} {eject}
以下の設定
set terminal hpgl 8 eject
は、以前の hp7550 ドライバと同等で、設定
set terminal hpgl 4
は、以前の hp7580b ドライバと同等です。
pcl5 ドライバは、Hewlett-Packard Designjet 750C、Hewlett-Packard Laserjet III, Hewlett-Packard Laserjet IV のようなプロッタをサポートし ます。これは実際には HPGL-2 を使用しているのですが、装置間で名前の衝突 があります。このドライバにはいくつかのオプションがありますが、それらは 以下に示した順序で指定しなければいけません:
書式:
set terminal pcl5 {mode <mode>} {<plotsize>}
{{color {<number_of_pens>}} | monochrome} {solid | dashed}
{font <font>} {size <fontsize>} {pspoints | nopspoints}
< mode> は landscape か portrait です。< plotsize> はグラフの物理的 な描画サイズで、それは以下のうちのいずれかです: letter は標準の(8 1/2" X 11") 出力、legal は (8 1/2" X 14") 出力、noextended は (36" X 48") 出力 (letter サイズ比)、extended は (36" X 55") 出力 (ほぼ legal サイズ比)。color は複数のペン (すなわちカラー) 描画用で < number_of_pens> はカラー出力で使用されるペンの本数 (すなわち色数) で す。monochrome は 1 本のペン (例えば黒) の描画です。solid は全ての 線を実線で描き、dashed は異なる点線や鎖線パターンで線を描き分けます。 < font> は stick, univers, cg_times, zapf_dingbats, antique_olive, arial, courier, garamond_antigua, letter_gothic, cg_omega, albertus, times_new_roman, clarendon, coronet, marigold, truetype_symbols, wingdings のいずれかです。< fontsize> はポイント 単位でのフォントの大きさです。点の種類 (point type) は、nopspoints を 指定することで標準的なデフォルトの設定から選択できるようになりますが、 pspoints を指定すると postscript terminal と同じ点の種類の設定から 選択できるようになります。
これらのオプションのいくつかの組み込まれたサポートは、プリンタに依存す ることに注意してください。例えば全てのフォントは恐らく HP Laserjet IV ではサポートされているでしょうが、HP Laserjet III と Designjet 750C で は 2,3 (例えば univers, stick) がサポートされているのみでしょう。 また、laserjet は白黒の出力装置なので、それらではカラーも明らかに使え ません。
デフォルト: landscape, noextended, color (6 pens), solid, univers, 12
point, nopspoints
pcl5 では国際的文字セットはプリンタで扱われますので、テキスト文字列 に適切な 8-bit 文字コードを入れるだけで、わざわざ set encoding で邪 魔をする必要はありません。
HPGL グラフィックは多くのソフトウェアパッケージで取り込むことが可能で す。
書式:
set terminal hpljii | hpdj {<res>}
ここで res は 75, 100, 150, 300 のいずれかの解像度 (DPI; dots per inch) で、デフォルトは 75 です。高解像度でのラスタライズはたくさんのメ モリを必要とします。
hp500c ドライバは hpdj とほぼ同じですが、hp500c は加えてカラーと 圧縮もサポートしています。
書式:
set terminal hppj {FNT5X9 | FNT9X17 | FNT13X25}
中間サイズフォント (FNT9X17) がデフォルトです。
書式:
set terminal imagen {<fontsize>} {portrait | landscape}
{[<horiz>,<vert>]}
fontsize はデフォルトでは 12 ポイントで、レイアウトのデフォルトは landscape です。< horiz> と < vert> はグラフを横方向と縦方向に何列 置くかを指定します。これらのデフォルトは 1 です。
例:
set terminal imagen portrait [2,3]
これは、1 ページに 6 つのグラフを横に 2 列、縦に 3 列、縦置き (portrait) で配置します。
set terminal jpeg
{{no}enhanced}
{{no}interlace}
{linewidth <lw>} {dashlength <dl>} {rounded|butt}
{tiny | small | medium | large | giant}
{font "<face> {,<pointsize>}"} {fontscale <scale>}
{size <x>,<y>} {{no}crop}
{background <rgb_color>}
PNG, JPEG, GIF 画像は、外部ライブラリ libgd を使って生成されます。大抵 の場合、単一の描画なら PNG の方が向いていて、GIF はアニメーション用で す。それらは損失の少ない画像形式で、損失のある JPEG 形式よりも上質の画 像を生成します。これは、特にベタ塗り潰した背景でのカラーの実線、つまり まさに gnuplot が生成する典型的な画像に対しては注意すべきことです。
オプション interlace は、プログレッシブ JPEG 画像を生成します。デフ ォルトは nointerlace です。
オプション linewidth と dashlength は拡大率で、描画されるすべての 線に影響を与えます。すなわち、これらは様々な描画コマンドで要求される値 に掛算されます。
butt は線分の描画で、その端の点でのはみだしを起こさない描画メソッド を使うようドライバに指示します。この設定は、線幅が 1 より大きい場合に のみ有効です。この設定は、水平線、垂直線の描画の場合に有用でしょう。 デフォルトは rounded (丸め) です。
フォントの選択の詳細は、やや複雑です。
以下に同じ意味を持つ簡単な例を示します:
set term jpeg font arial 11
set term jpeg font "arial,11"
出力描画サイズ < x,y> はピクセル単位で与えます。デフォルトは 640x480 で す。以下も参照: canvas (8), set size (88.73)。 描画終了後の端の余白は、オプション crop で取り除くことができ、その結 果としてその画像サイズは小さくなります。デフォルトは nocrop です。
set terminal {latex | emtex} {default | {courier|roman} {<fontsize>}}
{size <XX>{unit}, <YY>{unit}} {rotate | norotate}
デフォルトでは、それを埋め込む文書のフォントの設定を引き継ぎますが、代 わりに Courier (cmtt) か Roman (cmr) フォントのいずれかにするオプショ ンが使えます。その際はフォントサイズも指定できます。 あなたの DVI ドライバが任意のサイズのフォントを作り出すことができない 場合 (例えば dvips)、標準的な 10, 11, 12 ポイントサイズでなんとかしの いでください。
METAFONT ユーザへの警告: METAFONT は妙なサイズは好みません。
LaTeX に関する全てのドライバは文字列の配置の制御に特別な方法を提供しま す: '{' で始まる文字列は、'}' で閉じる必要がありますが、その文字列全体 が水平方向にも垂直方向にもセンタリングされます。'[' で始まる文字列の場 合は、位置の指定をする文字列 (t,b,l,r のうち 2 つまで) が続き、次に ']{'、文字列本体、で最後に '}' としますが、この文字列は LaTeX が LR-box として整形します。' \ rule{}{}' を使えばさらに良い位置合わせが可能でしょ う。
数ある中で、点 (point) は、LaTeX のコマンド " \ Diamond" と " \ Box" を使 って描かれます。これらのコマンドは現在は LaTeX2e のコアには存在せず、 latexsym パッケージに含まれていますが、このパッケージ基本配布の一部で あり、よって多くの LaTeX のシステムの一部になっています。このパッケー ジを使うことを忘れないでください。 他の点種は、amssymb パッケージの記号を使用します。
デフォルトの描画サイズは 5 inch × 3 inch ですが、オプション size で これをユーザの希望するものに変更できます。また、デフォルトでは X と Y のサイズの単位は inch ですが、他の単位を使うことも可能です (現在は cm のみ)。
'rotate' を指定すると、文字列の回転、特に y 軸のラベルの回転が可能にな ります (graphics か graphicx パッケージが必要)。その場合、y 軸ラベルを '積み上げ型' にする仕組みは停止されます。
例:
見出しの位置合わせに関して:
gnuplot のデフォルト (大抵それなりになるが、そうでないこともある):
set title '\LaTeX\ -- $ \gamma $'
set label '{\LaTeX\ -- $ \gamma $}' at 0,0
set xlabel '[t]{\LaTeX\ -- $ \gamma $}'
set ylabel '[r]{\LaTeX\ -- $ \gamma $\rule{7mm}{0pt}}'
Lua に関する情報は、http://www.lua.org で参照できます。
書式:
set terminal lua <target name> | "<file name>"
{<script_args> ...}
{help}
スクリプト用に 'target name'、または引用符付きの 'file name' が必須で す。スクリプトの 'target name' を与えた場合は、この出力形式は、 "gnuplot-< target name> .lua" をまずローカルディレクトリで探し、それに 失敗すると環境変数 GNUPLOT_LUA_DIR を探します。
その他のすべての引数は、選択したスクリプトに評価させるように与えられま す。例えば、'set term lua tikz help' は、スクリプトそれ自身に、スクリ プト用のオプションと選択に関する追加のヘルプを表示させます。
書式:
set terminal lua tikz
{latex | tex | context}
{color | monochrome}
{nooriginreset | originreset}
{nogparrows | gparrows}
{nogppoints | gppoints}
{picenvironment | nopicenvironment}
{noclip | clip}
{notightboundingbox | tightboundingbox}
{background "<colorpec>"}
{size <x>{unit},<y>{unit}}
{scale <x>,<y>}
{plotsize <x>{unit},<y>{unit}}
{charsize <x>{unit},<y>{unit}}
{font "<fontdesc>"}
{{fontscale | textscale} <scale>}
{dashlength | dl <DL>}
{linewidth | lw <LW>}
{nofulldoc | nostandalone | fulldoc | standalone}
{{preamble | header} "<preamble_string>"}
{tikzplot <ltn>,...}
{notikzarrows | tikzarrows}
{rgbimages | cmykimages}
{noexternalimages|externalimages}
{bitmap | nobitmap}
{providevars <var name>,...}
{createstyle}
{help}
引数として長さを必要とするオプションについては、単位が指定されていなけ ればそのデフォルトは 'cm' となります。すべての長さには、以下の単位を使用できます: 'cm', 'mm', 'in' または 'inch', 'pt', 'pc', 'bp', 'dd','cc' (訳注: in はインチ (1in=2.54cm), pt はポイント (72.27pt=1in), pc はパイカ (1pc=12pt), bp はビッグポイント (72bp=1in), dd は Didot ポイ ント (26.6dd=1cm), cc は Cicero (1cc=12dd))。数値と単位の間に空白を入 れてはいけません。
'monochrome' は、線の色付けを無効にし、塗り潰しを灰色階調に切り替えま す。
'originreset' は、TikZ 画の原点を、描画の左下角へ移動します。これはい くつかの描画を一つの tikzpicture 環境内に整列するのに使用できます。こ れは、multiplot、pm3d 描画では十分にはテストされていません。
'gparrows' は、TikZ が提供する矢 (arrow) の代わりに、gnuplot 内部の矢 (arrow) の描画関数を使用します。
'gppoints' は、TikZ が提供する描画記号の代わりに、gnuplot 内部の記号描 画関数を使用します。
'nopicenvironment' は、'tikzpicture' 環境の宣言を手動で行うようにする ためにそれを省略します。これにより、描画の前後に、ある PGF/TikZ コード を直接入れることができます。
'clip' は、描画を定義されたキャンバスサイズでクリッピングします。デフォ ルトは 'noclip' で、これはキャンバスサイズを含む最小の矩形外枠のみを設 定します。オプション 'plotsize' か 'tightboundingbox' を使用した場合は 矩形外枠もクリッピングの箱もいずれも設定しません。
'tightboundingbox' を設定すると、オプション 'clip' は無視され、最終的な 矩形外枠は tikz が計算する自然な外枠になります。
'background' は、背景色を引数 < colorspec> で指定した値に設定します。 < colorspec> は有効な色名か、'#' の後に 16 進数を置く 3 バイトの RGB コ ード (例えば '#ff0000' は真赤) のいずれかでなければいけません。省略した 場合は背景は透明になります。
オプション 'size' は、キャンバスサイズの 2 つの長さ < x> , < y> を必要と します。デフォルトのキャンバスサイズは 12.5cm x 8.75cm です。
オプション 'scale' は、オプション 'size' と同等の機能ですが、この < x> , < y> は長さではなく、拡大率になります。
オプション 'plotsize' は、キャンバスサイズの代わりに描画領域のサイズの 設定を行いますが、それが通常の gnuplot の挙動です。このオプションを使 用すると、わずかに非対称な刻み幅を作るかもしれません。'originreset' の ように、このオプションを multiplot や pm3d 描画で使用すると、不都合な 結果を招く恐れがあります。それに代わる方法として、すべての margin を 0 と設定した上でオプション 'noclip' を使用する、という手もあります。この 場合は、描画領域は与えたキャンバスサイズの大きさになります。
オプション 'charsize' は、使用するフォントの水平サイズと垂直サイズの平 均値を必要とします。あなたの TeX 文書内でこれをどのように使用するかに ついては、サンプルとして生成されるスタイルファイルを見てください。
オプション 'fontscale', 'textscale' には、縮尺比パラメータが必要です。 グラフ内のすべての文字列がその縮尺比で伸縮されます。
オプション 'dashlength' または 'dl' は、点線-破線部分の長さを < DL> 倍し ますが、これは正の実数です。'linewidth' または 'lw' は、すべての線幅を < LW> 倍します。
オプション 'tex', 'latex', 'context' は、TeX 出力形式の選択です。デフォ
ルトは LaTeX です。そのスタイルファイルを読み込むには、あなたの文書ファ
イルの先頭に対応する行を入れてください:
\input gnuplot-lua-tikz.tex % (plain TeX の場合)
\usepackage{gnuplot-lua-tikz} % (LaTeX の場合)
\usemodule[gnuplot-lua-tikz] % (ConTeXt の場合)
'createstyle' は、そのスクリプトから TeX/LaTeX/ConTeXt スタイルファイル を導き出し、それらを適切なファイルに書き出します。
'fulldoc' または 'standalone' は、そのままコンパイルできるような完全な LaTeX 文書を生成します。
'preamble' または 'header' は、standalone モードのドキュメントのプリア ンブルに追加 LaTeX コードを出力するのに使います。
オプション 'tikzplot' では、コマンド ' \ path' の代わりに ' \ path plot' を使用します。それに続く線種 (linetype) の数値のリスト (< ltn> ,...) は それに影響される描画線を定義します。すべての線種に対し、一つの描画スタ イルが存在します。1 以上のすべての線種に対して、デフォルトの描画スタイルは 'smooth' です。
オプション 'tikzarrows' を使用すると、ユーザの定義した gnuplot の矢 (arrow) のスタイルを TikZ の矢のスタイルに割り当てます。これは、矢の定 義の角の値を '誤って使用する' ことでなされています。例えば、角 '7' に よる矢のスタイルは TikZ スタイル 'gp arrow 7' に割り当てられ、他に与え られた値はすべて無視されます。デフォルトでは、TikZ 出力形式はすべての 矢に対してステルス形の矢先を使用します。デフォルトの gnuplot のように するには、オプション 'gparrows' を使用してください。
'cmykimages' では、インライン画像データに対して RGB カラーモデルの代わ りに CMYK モデルを使用しますが、他のすべての色 (線の色など) は、それら が、例えば xcolors パッケージで処理されるので、このオプションの影響を受 けません。このオプションは、画像がインライン画像でなく外部データである 場合は無視されます。
オプション 'externalimages' を使用すると、すべてのビットマップ画像を外 部の PNG 画像として書き出し、それらが文書のコンパイル時に読み込まれるよ うになります。DVI ファイル、およびその後の PostScript ファイルを生成す るには、PNG ファイルを EPS ファイルに、別に変換する必要があります。これ は例えば ImageMagick の convert で行えます。透明化ビットマップ画像は 常に外部 PNG 画像として生成します。
オプション 'nobitmap' は、ネイティブの PS, PDF インライン画像形式の代 わりに、画像を塗り潰された長方形としてレンダリングします。このオプショ ンは、画像がインライン画像でなく外部データである場合は無視されます。
オプション 'providevars' は、gnuplot の内部変数、ユーザ変数を、TeX ス クリプト内でもコマンド ' \ gpgetvar{< var name> }' を使用することで利用可 能にさせます。利用できる変数の一覧を見るには、'show variables all' コ マンドを使用してください。
文字列 < fontdesc> には、例えば ' \ small' のような TeX/LaTeX/ConTeXt で 有効なフォントコマンドを入れることもでき、それは、"font=< fontdesc> " の形式のノードパラメータとして直接渡されます。これは、あるノードにコー ドを追加するのに「わざと間違えて」使えます。例えば ' \ small,yshift=1ex' も有効ですが、',yshift=1ex' も有効で、こちらは現在のフォント設定を変更 しません。しかしリストの第 2 引数は例外です。それが < 数値> {単位} の形式 の数値の場合、それは他の出力形式でそうであるようにフォントサイズと解釈 され、第 1 引数に追加されてしまいます。単位が省略された値は 'pt' 単位と 解釈されます。例えば、' \ sffamily,12,fill=red' は、背景色が赤で 12pt の LaTeX sans serif フォントを設定します。 同じことが ConTeXt にも言えます。例えば、' \ switchtobodyfont[iwona],10' はフォントを 10pt サイズの Iwona に変更します。 Plain TeX ユーザは、フォントサイズの変更は最初の引数で明示的に行わなけ ればいけません。テキストボックスの縮尺を正しく取得するよう、2 つ目も同 じ値に設定すべきです。
文字列は単一、あるいは二重引用符内に入れる必要があります。二重引用符で くくられた文字列には、改行の ' \ n' などの特別な文字を入れることができ ます。
文書中で図を使うには、gnuplot の出力するファイルを入力として METAFONT プログラムを実行する必要があります。よって、ユーザはフォントが作られる プロセスと新しく作ったフォントをドキュメントに取り込むための基礎知識が 必要となります。しかし、使用するサイトで METAFONT プログラムが適切に設 定されていれば、経験のないユーザでもそう問題なく操作はできるでしょう。
グラフ中の文字は METAFONT の文字セットに基づいてサポートされます。現状 では Computer Modern Roman フォントセットが入力ですが、ユーザは必要な フォントを何でも自由に選ぶことができます。ただしその選んだフォントの METAFONT ソースファイルが使える状態になっている必要があります。個々の 文字は METAFONT の中で別々のピクチャー変数に保存され、文字が必要になっ たときにこれらの変数が操作 (回転、伸縮等) されます。欠点は、METAFONT プログラムが解釈に要する時間です。ある計算機 (つまり PC) では、ピクチ ャー変数をたくさん使用しすぎることで、使えるメモリの量の限界が問題を起 こすこともあります。
mf ドライバにはオプションはありません。
- 出力形式 (terminal) を METAFONT にセット:
set terminal mf
set output "myfigures.mf"
- gnuplot を終了
- gnuplot の出力ファイルに対して METAFONT を実行し、TFM ファイルと GF ファイルを作ります。グラフは割と大きい (5x3 インチ) ので、memmax の値が 少なくとも 150000 である METAFONT を使う必要があるでしょう。Unix では、 それは通常 bigmf という名前でインストールされているでしょう。以下では、virmf コマンドが big 版の METAFONT であると仮定し、実行例を示します:
- METAFONT の立ち上げ:
virmf '&plain'
\mode:=CanonCX; % あなたの使用するプリンタを指定
mag:=1; % あなたの好みの値を指定
input myfigures.mf
- gftopk を使って GF ファイルから PK ファイルを生成:
gftopk myfigures.300gf myfigures.300pk
- 文書にそのグラフを入れるために TeX にそのフォント名を指示:
\font\gnufigs=myfigures
\centerline{\gnufigs\char0}
\centerline{\gnufigs\char1}
このやり方は、一度フォントを生成してしまえば、大幅に時間の節約になりま す: TeX はグラフを文字として使い、それを配置するにはごく少ない時間しか 使用しませんし、グラフよりも文書の方が修正することが多いでしょうから。 そしてこれは TeX のメモリの節約にもなります。METAFONT ドライバを使うも う最後の一つの利点は、生成される DVI ファイルが本来のデバイス非依存な 形になるということです。それは eepic や tpic ドライバのような \ special コマンドを全く使わないからです。
MIF 3.00 ドライバではいくつかのオプションが設定できます。
書式:
set terminal mif {color | colour | monochrome} {polyline | vectors}
{help | ?}
colour は線種 (line type) > = 0 の線をカラー (MIF separation 2-7) で、 monochrome は全ての線を黒 (MIF separation 0) で描画します。 polyline は曲線を連続曲線として描画し、vectors は曲線をベクトルの 集まりとして描画します。 help と ? はオンラインヘルプを標準エラー出力に表示します。両者はそ の使用法の短い説明を出力し、help は更にオプションも表示します。
例:
set term mif colour polylines # デフォルト
set term mif # デフォルト
set term mif vectors
set term mif help
mp ドライバは Metapost プログラムへ入力することを意図した出力を生成 し、そのファイルに対して Metapost を実行するとグラフを含む EPS ファイ ルが作られます。デフォルトでは Metapost は全ての文字列を TeX に通しま す。これはタイトルや見出しに任意の TeX の記号を本質的に使うことができ る、という利点を持つことを意味します。
書式:
set term mp {color | colour | monochrome}
{solid | dashed}
{notex | tex | latex}
{magnification <magsize>}
{psnfss | psnfss-version7 | nopsnfss}
{prologues <value>}
{a4paper}
{amstex}
{"<fontname> {,<fontsize>}"}
オプション color は線をカラーで書くことを意味し (それをサポートする プリンタやディスプレイ上で)、monochrome (または何も指定しない場合) は黒の線が選択されます。オプション solid は線を実線で描き、dashed (または無指定) は線を異なるパターンの点線で描き分けます。solid が指 定されてかつ color が指定されなかった場合、ほとんど全ての線が同じも のになりますが、これも何かの場合には有用でしょうから認められています。
オプション notex は完全に TeX を迂回しますので、このオプションの元で は見出しには TeX のコードは使うことができません。これは、古いグラフフ ァイル、あるいは TeX では特殊記号として解釈されてしまう $ や % の ような一般的な文字をたくさん使うファイルのために用意されています。
オプション tex は、TeX で処理する文字列を出力するように設定します。
オプション latex は、LaTeX で処理する文字列を出力するように設定しま す。これによって TeX では使えないけれど LaTeX では使えるもの、例えば分 数を \ frac で書いたりすることができます。このオプションを使う場合は、 環境変数 TEX に LaTeX の実行プログラム名 (通常は latex) を設定するか、 あるいは mpost -tex=< LaTeX の実行プログラム名> ... とすることを忘れ ないでください。そうでないと metapost はテキストの処理に TeX を使おう として失敗してしまうでしょう。
TeX におけるフォントサイズの変更は数式には効果がなく、そのような変更を 行なうとても簡単な方法は、大域的に拡大率 (magnification factor) を設定 する以外にはありません。それがオプション magnification の意味です。 その場合は拡大率を後ろに指定する必要があります。全ての文字 (グラフでは なく) はこの率で拡大されます。数式をデフォルトの 10pt 以外の他のサイズで書きたい場合はこれを使用してください。ただ残念なことに全ての数式が同 じサイズになってしまいますが、しかし、以下の MP 出力の編集に関する説明を参照してください。mag は notex の元でも働きますが、それを行なう 意味がないくらい (以下に述べる) フォントサイズオプションはうまく働きま す。
オプション psnfss は postscript フォントを LaTeX と組み合わせて使用 します。このオプションは LaTeX が使われる場合のみ意味を持ちますので、 自動的に latex オプションが選択されます。このオプションは以下のLaTeX パッケージを使用します:inputenc(latin1), fontenc(T1), mathptmx, helvet(scaled=09.2), courier, latexsym, textcomp
オプション psnfss-version7 も postscript フォントを LaTeX と組み合わ せて使用します (latex が自動的に選択されます) が、以下の LaTeX パッケージを使用します:inputenc(latin1), fontenc(T1), times, mathptmx, helvet, courier
オプション nopsnfss はデフォルトで、標準的なフォント (何も指定されて いなければ cmr10) が使われます。
オプション prologues は追加の値を引数に持ち、metapost ファイルに prologues:=< その値> という行を追加します。値として 2 を指定すると metapost は eps ファイルを作るように postscript フォントを使用し、それ によりその結果は例えば ghostscript などで参照できるようになります。標 準では metapost は TeX のフォントを使用しますので、それを参照するには (La)TeX のファイルに取り込む必要があります。
オプション noprologues はデフォルトで、prologue で指定したいかなる行 も追加されません。
オプション a4paper は [a4paper] を documentclass に追加します。標 準では letter 用紙 (デフォルト) が使われます。このオプションは LaTeX でのみ使われますので、自動的に latex オプションが選択されます。
オプション amstex は、自動的に latex オプションを選択し、以下のLaTeX パッケージを使用します: amsfonts, amsmath(intlimits)。デフォルト ではこれらは使用されません。
引用符で囲まれた名前はフォント名を表し、set label や set title で 明示的にフォントが与えられない場合はこのフォントが使われます。フォント は TeX が認識できる (TFM ファイルが存在する) ものを使う必要があります。 デフォルトでは notex が選択されていなければ "cmr10" が、そうでなけれ ば "pcrr8r" (Courier) が使われます。notex の元でも、Metapost には TFM ファイルは必要です。pcrr8r.tfm は LaTeX psnfss パッケージの Courier フォント名として与えられています。notex のデフォルトからフォ ントを変更する場合は、少なくとも 32-126 のコード範囲は ASCII エンコー ディングに一致するものを選んでください。cmtt10 もほぼ使えますが、し かしこれはコード 32 (スペース) にスペースではない文字が入っています。
サイズは 5.0 から 99.99 の間の任意の数字を指定でき、省略された場合は 10.0 が使われます。なるべく magstep サイズ、つまり 1.2 の整数かまた は 0.5 乗の 10 倍を小数以下 2 桁未満を丸めた値を使用することをお勧めします。それはそれが TeX のシステムで最もよく使われるフォントのサイズ だからです。
全てのオプションは省略可能です。フォントを指定する場合はそれは (必要な らサイズもつけて) 一番最後に指定する必要があります。フォント名にそのサ イズ情報が含まれていたとしても、サイズを変えるにはフォントサイズを指定 する必要があります。例えば set term mp "cmtt12" は cmtt12 をデフォル トのサイズである 10 に縮めて使います。それは多分望まないことでしょうし cmtt10 を使う方が良いでしょう。
以下の ascii 文字は、TeX では特別に扱われます:
$, &, #, %, _; |, <, >; ^, ~, \, {, }
見出しを二重引用符で囲む場合、TeX コードのバックスラッシュはエスケープ する (2 つ書く) 必要があります。単一引用符を使えばそれを避けることはで きますが、今度は改行として \ n を使えなくなります。これを書いている現 在、gnuplot 3.7 は plot コマンドで与えられたタイトルは、別な場所で与 えられた場合とは異なる処理をしますし、引用符のスタイルにかかわらず TeX コマンドのバックスラッシュは二重化した方が良さそうです。
Metapost の画像は TeX の文書内で一般に使われています。Metapost はフォ ントを TeX が行なうのと全く同じ方法で扱い、それは他の大抵の文書整形プ ログラムとは異なっています。グラフが LaTeX の文書に graphics パッケー ジで取り込まれ、あるいは epsf.tex を使って plainTeX に取り込まれ、そし て dvips (または他の dvi から ps への変換ソフト) で PostScript に変換 される場合、そのグラフ内の文字は大抵は正しく扱われているでしょう。しか し、Metapost 出力をそのまま PostScript インタプリタに送っても、グラフ 内の文字は出力されないでしょう。
- まず terminal ドライバを Metapost に設定、例えば:
set terminal mp mono "cmtt12" 12
- 出力ファイルを選択、例えば:
set output "figure.mp"
- グラフを作成。各 plot (または multiplot の各グループ) はそれぞれ別な Metapost beginfig...endfig グループに分けられます。そのデフォルトのサ イズは 5x3 インチですが、それは set size 0.5,0.5 とか、そうしたいと 思う適当な割合をそのように指定することで変更できます。
- gnuplot を終了。
- gnuplot の出力ファイルに対して Metapost を実行して EPS ファイルを作
成:
mpost figure.mp OR mp figure.mp
- そのグラフを文書に取り込むには LaTeX graphics パッケージや、plainTeX
では epsf.tex を使用:
\usepackage{graphics} % LaTeX
\input epsf.tex % plainTeX
\DeclareGraphicsRule{*}{eps}{*}{}
\includegraphics{figure.2} % LaTeX
\epsfbox{figure.2} % plainTeX
mp ドライバの postscript ドライバに代わる利点は、もしあるとすれば、そ れは編集可能な出力であるということでしょう。この出力を可能な限り綺麗に するための、かなりの努力が払われました。Metapost 言語に関するそういっ た知識のおかげで、デフォルトの線種や色は配列 lt[] や col[] を編集 することで変更できるようになりました。実線/点線、カラー/白黒といった選 択も、真偽値として定義されている dashedlines や colorlines を変更 することで行なえます。デフォルトの tex オプションが有効な場合、ブロ ック vebatimtex...etex を編集することで、ラベル文字フォントに対する 大域的な変更が行なえます。特に、もし望むなら LaTeX のプリアンブルを追 加することもでき、その場合 LaTeX の持つサイズ変更コマンドを使えるので 最大の柔軟性を発揮できるでしょう。ただし、Metapost に plainTeX でなく LaTeX を実行させるよう、適切な MP 設定変数を設定することを忘れないでく ださい。
書式:
set terminal next {<mode>} {<type> } {<color>} {<dashed>}
{"<fontname>"} {<fontsize>} title {"<newtitle>"}
< mode> は default のみ指定でき、その場合全てのオプションがデフォルト になります。< type> は new か old で、old は古い単一ウィンドウを 要求します。< color> は color (カラー) か monochrome (白黒)、 < dashed> は solid (実線のみ) か dashed (点線が有効)、"< fontname> " は有効な PostScript フォントの名前を、< fontsize> は PostScript ポイン ト単位でのフォントのサイズを、< title> は GnuTerm ウィンドウのタイトル をそれぞれ設定します。デフォルトは new, monochrome, dashed, "Helvetica", 14pt です。
例:
set term next default
set term next 22
set term next color "Times-Roman" 14
set term next color "Helvetica" 12 title "MyPlot"
set term next old
点の大きさは set linestyle で変更できます。
書式:
set terminal openstep {<mode>} {<type> } {<color>} {<dashed>}
{"<fontname>"} {<fontsize>} title {"<newtitle>"}
< mode> は default のみ指定でき、その場合全てのオプションがデフォルト になります。< type> は new か old で、old は古い単一ウィンドウを 要求します。< color> は color (カラー) か monochrome (白黒)、 < dashed> は solid (実線のみ) か dashed (点線が有効)、"< fontname> " は有効な PostScript フォントの名前を、< fontsize> は PostScript ポイン ト単位でのフォントのサイズを、< title> は GnuTerm ウィンドウのタイトル をそれぞれ設定します。デフォルトは new, monochrome, dashed, "Helvetica", 14pt です。
例:
set term openstep default
set term openstep 22
set term openstep color "Times-Roman" 14
set term openstep color "Helvetica" 12 title "MyPlot"
set term openstep old
点の大きさは set linestyle で変更できます。
set terminal pbm {<fontsize>} {<mode>} {size <x>,<y>}
< fontsize> は small か medium か large で、< mode> は monochrome か gray か color です。デフォルトの描画サイズは 640 ピクセルの幅で 480 ピクセルの高さです。出力サイズは、x と y の両方を 8 ピクセル倍した ものに最も近くなるように空白が追加されます。必要であれば、この空白部分 は後で取り除くことができます。
pbm ドライバの出力は < mode> によります: monochrome は portable bitmap (PBM; 1 ピクセル 1 ビット) を、gray は portable graymap (PGM; 1 ピクセル 3 bit) を、color は portable pixmap (PPM; 1 ピクセル 4 ビ ット) を出力します。
このドライバの出力は、NETPBM によって提供される様々な画像変換、画像処 理ツールで使うことができます。 Jef Poskanzer の PBMPLUS パッケージに基 づく NETPBM は、上記の PBM 形式から GIF, TIFF, MacPaint, Macintosh PICT, PCX, X11 ビットマップ、その他多くの形式に変換するプログラムを提 供します。完全な情報は http://netpbm.sourceforge.net/ にあります。
例:
set terminal pbm small monochrome # デフォルト
set terminal pbm color medium size 800,600
set output '| pnmrotate 45 | pnmtopng > tilted.png' # NETPBM を利用
書式:
set terminal pdf {monochrome|color|colour}
{{no}enhanced}
{fname "<font>"} {fsize <fontsize>}
{font "<fontname>{,<fontsize>}"} {fontscale <scale>}
{linewidth <lw>} {rounded|butt}
{dl <dashlength>}
{size <XX>{unit},<YY>{unit}}
デフォルトでは、個々の線種に対して異なる色を用います。monochrome を選 択すると全ての線種を黒で描きますが、モノクロモードでも塗りつぶし領域や ラインスタイルでは明示的に色を使用することができます。
< font> はデフォルトで使われるフォント名 (デフォルトでは Helvetica) で < fontsize> はポイント単位でのフォントサイズ (デフォルトでは 12) です。 どのようなフォントが使えて、新しいフォントをインストールするには、とい ったことに関しては、ローカルにインストールされている pdflib のドキュメ ントを参照してください。
オプション enhanced は、拡張文字列処理機能 (下付き文字、上付き文字、 および複数のフォントの利用) を有効にします。以下参照: enhanced (13)。
描画における全ての線の幅は linewidth で指定する因子 < n> で増加するこ とができます。同様に、dashlength はデフォルトの点線の空白部分に対する 積因子です。
rounded は、線の端や接合部を丸くし、デフォルトの butt は尖った端と 角張った接合部を使用します。
PDF 出力のデフォルトのサイズは、5inch x 3inch です。オプション size は、これをユーザの指定するものへ変更します。デフォルトの X, Y サイズの 単位はインチですが、他の単位も使用可能です (現在は cm のみ)。
書式:
set term pdfcairo
{{no}enhanced} {mono|color}
{font <font>} {fontscale <scale>}
{linewidth <lw>} {rounded|butt|square} {dashlength <dl>}
{background <rgbcolor>
{size <XX>{unit},<YY>{unit}}
この出力形式は、拡張文字列処理モード (enhanced text mode) をサポートし ていて、フォントや書式コマンド (上付、下付など) をラベルや他の文字列に 埋め込むことができます。拡張文字列処理モードの書式は他の gnuplot の出 力形式と共通です。詳細は、以下参照: enhanced (13)。
描画における全ての線の幅は、linewidth で指定する因子 < lw> で変更でき ます。デフォルトの線幅は 0.5 ポイントです。(1 "PostScript" ポイント= 1/72 インチ = 0.353 mm)
rounded は、線の端や接合部を丸くします。 デフォルトの butt は尖った端と角張った接合部を使用します。
PDF 出力のデフォルトのサイズは、5inch x 3inch です。オプション size は、これをユーザの指定するものへ変更します。デフォルトの X, Y サイズの 単位はインチですが、他の単位も使用可能です (現在は cm のみ)。size オ プションで指定されたことによる描画の端から端までの領域は、常にスクリー ン座標の 0.0 から 1.0 に対応します。
<
font>
は、"FontFace,FontSize" の書式、つまりフォント名とサイズをカ
ンマで区切った一つの文字列として表記します。FontFace は、'Arial' の
ような通常のフォント名です。フォント名を与えない場合、pdfcairo 出力形
式では'Sans' が使用されます。FontSize はポイント単位でのフォントサイ
ズです。指定しない場合は、pdfcairo 出力形式では 12 ポイントサイズの標
準フォントが使用されます。しかし、この出力形式のパラメータ fontscale
のデフォルトは 0.5 なので、見かけのフォントサイズは、PDF 出力をフルサ
イズで見た場合よりも小さくなるでしょう。
例 :
set term pdfcairo font "Arial,12"
set term pdfcairo font "Arial" # フォント名のみ変更
set term pdfcairo font ",12" # フォントサイズのみ変更
set term pdfcairo font "" # フォント名とサイズをリセット
フォントは、通常のフォント処理機構により取得されます。Windows では、フ ォントはコントロールパネルの "フォント" の項目で構成され見つけられる もので、UNIX では、フォントは "fontconfig" で処理されます。
文字列のレイアウトに使用されるライブラリ Pango は、utf-8 に基づいてい ますので、pdfcairo 出力形式では、文字コードを utf-8 に変換する必要があ ります。デフォルトの入力文字コードは、あなたが使用している 'locale' に基づきます。他の文字コードにしたい場合は、あなたがどの文字コードを使 っているのかを確実に gnuplot がわかるようにしてください。詳細について は、以下参照: encoding (88.24)。
pango は、unicode マッピングでないフォントに対しては予期せぬ結果を与え るかもしれません。例えば Symbol フォントに対しては、pdfcairo 出力形式 は、文字コードを unicode に変換するために http://www.unicode.org/ で提 供されるマッピングを利用します。なお、"the Symbol font" は、Acrobat Reader と一緒に "SY______.PFB" として配布されている Adobe Symbol フ ォントであると解釈されることに注意してください。この代わりに、 OpenOffice.org と一緒に "opens___.ttf" として配布される OpenSymbol フォントが同じ文字を提供しています。Microsoft も Symbol フォント ("symbol.ttf") を配布していますが、これは異なる文字セットになってい て、いくつかは欠けていますし、いくつかは数式記号に変わってしまっていま す。あなたのデフォルトの設定でなんらかの問題が起きた場合 (例えばデモス クリプト enhancedtext.dem がちゃんと表示されないといった場合) は、 Adobe か OpenOffice の Symbol フォントをインストールして、Microsoft の Symbol フォントを削除しないといけないかもしれません。"windings" のよ うな他の非標準のフォントでも動作することが報告されています。
描画のレンダリングは、今のところ変更できません。出力をより良くするため にこのレンダリングは、アンチエイリアス、オーバーサンプリングの 2 つの 機構を持っています。 アンチエイリアスは、水平や垂直でない線を滑らかに表示します。 オーバーサンプリングは、アンチエイリアスと組でピクセルよりも小さいサイ ズでの精度を提供し、gnuplot が非整数座標の直線を書けるようになります。 これは、対角方向の直線 (例えば 'plot x') が左右に揺れるのを避けます。
書式:
set terminal pm {server {n}} {persist} {widelines} {enhanced} {"title"}
persist を指定すると、各グラフはそれぞれ自身のウィンドウを持ち、その すべてのウィンドウは gnuplot が終了した後も開いたままになります。 server を指定すると、全てのグラフは同じウィンドウ内に現われ、それは gnuplot 終了後も開いたままになります。このオプションは、さらに追加の 数引数を取り、その数字はサーバプロセスのインスタンスになります。よって 同時に複数のサーバウィンドウを使うことができます。
widelines を指定すると、全てのグラフは幅の広い線で描かれます。 enhanced を指定すると、上付き文字や下付き文字、複数のフォントを使う ことができます (詳細は、以下参照: enhanced text (13))。コア PostScript フ ォントのフォント名は 1 文字に省略できます (T/H/C/S はそれぞれ Times/Helvetica/Courier/Symbol を意味します)。
title を指定すると、それは描画ウィンドウのタイトルとして使われます。 それはサーバインスタンス名としても使われ、それは追加の数引数を上書きし ます。
線の幅は set linestyle で変更できます。
set terminal png
{{no}enhanced}
{{no}transparent} {{no}interlace}
{{no}truecolor} {rounded|butt}
{linewidth <lw>} {dashlength <dl>}
{tiny | small | medium | large | giant}
{font "<face> {,<pointsize>}"} {fontscale <scale>}
{size <x>,<y>} {{no}crop}
{background <rgb_color>}
PNG, JPEG, GIF 画像は、外部ライブラリ libgd を使って生成されます。PNG
の描画は、ImageMagick パッケージのソフト 'display' にその出力を以下のようにパイプで渡すことで対話的に表示させることができます:
set term png
set output '| display png:-'
transparent は、ドライバに背景色の透明化 (transparent) を行うよう指 示します。デフォルトは notransparent です。
interlace は、ドライバにインターレース GIF を生成するよう指示します。 デフォルトは nointerlace です。
オプション linewidth と dashlength は拡大率で、描画されるすべての 線に影響を与えます。すなわち、これらは様々な描画コマンドで要求される値 に掛算されます。
デフォルトでは、出力される PNG 画像は 256 個に番号付けられた色を使用し ます。代わりにオプション truecolor を使えば、24 ビット/ピクセルの色 情報を持つ TrueColor 画像が生成されます。透明化塗りつぶし (transparent fill) を使用するときは、このオプション truecolor が必要になります。 以下参照: fillstyle (88.74.4)。背景の透明化は、番号付け画像か TrueColor 画像で 可能です。
butt は線分の描画で、その端の点でのはみだしを起こさない描画メソッド を使うようドライバに指示します。この設定は、線幅が 1 より大きい場合に のみ有効です。この設定は、水平線、垂直線の描画の場合に有用でしょう。 デフォルトは rounded (丸め) です。
フォントの選択の詳細は、やや複雑です。
以下に同じ意味を持つ簡単な例を示します:
set term png font arial 11
set term png font "arial,11"
出力描画サイズ < x,y> はピクセル単位で与えます。デフォルトは 640x480 で す。以下も参照: canvas (8), set size (88.73)。 描画終了後の端の余白は、オプション crop で取り除くことができ、その結 果としてその画像サイズは小さくなります。デフォルトは nocrop です。
set terminal png medium size 640,480 background '#ffffff'
この例は medium サイズの、大きさ変更不能で回転できない組み込みフォント を使用し、透明化されない背景色として白 (16 進数の 24bit RGB) を使用しま す。
set terminal png font arial 14 size 800,600
これは、'arial' というフェース名のスケーラブルフォントを検索し、フォン トサイズを 14pt に設定します。フォントの検索がどのように行われるかにつ いては以下参照: fonts (16)。
set terminal png transparent truecolor enhanced
これは、24 ビット/ピクセルの色情報を使用し、背景を透明化します。そして 表示される文字列の配置制御として enhanced text モードを使用します。
書式:
set term pngcairo
{{no}enhanced} {mono|color}
{{no}transparent} {{no}crop} {background <rgbcolor>
{font <font>} {fontscale <scale>}
{linewidth <lw>} {rounded|butt|square} {dashlength <dl>}
{size <XX>{unit},<YY>{unit}}
この出力形式は、拡張文字列処理モード (enhanced text mode) をサポートし ていて、フォントや書式コマンド (上付、下付など) をラベルや他の文字列に 埋め込むことができます。拡張文字列処理モードの書式は他の gnuplot の出 力形式と共通です。詳細は、以下参照: enhanced (13)。
描画における全ての線の幅は、因子 < lw> で変更できます。
rounded は、線の端や接合部を丸くします。 デフォルトの butt は尖った端と角張った接合部を使用します。
PNG 出力のデフォルトのサイズは、640 x 480 ピクセルです。オプション size は、これをユーザの指定するものへ変更します。デフォルトの X, Y サイズの単位はピクセルですが、他の単位も使用可能です (現在は cm とイン チ)。サイズを cm かインチで与えるとそれは、解像度 72 dpi でのピクセル 数に変換されます。size オプションで指定されたことによる描画の端から 端までの領域は、常にスクリーン座標の 0.0 から 1.0 に対応します。
<
font>
は、"FontFace,FontSize" の書式、つまりフォント名とサイズをカ
ンマで区切った一つの文字列として表記します。FontFace は、'Arial' の
ような通常のフォント名です。フォント名を与えない場合、pngcairo 出力形
式では'Sans' が使用されます。FontSize はポイント単位でのフォントサイ
ズです。指定しない場合は、pngcairo 出力形式では 12 ポイントのサイズが
使用されます。
例 :
set term pngcairo font "Arial,12"
set term pngcairo font "Arial" # フォント名のみ変更
set term pngcairo font ",12" # フォントサイズのみ変更
set term pngcairo font "" # フォント名とサイズをリセット
フォントは、通常のフォント処理機構により取得されます。Windows では、フ ォントはコントロールパネルの "フォント" の項目で構成され見つけられる もので、UNIX では、フォントは "fontconfig" で処理されます。
文字列のレイアウトに使用されるライブラリ Pango は、utf-8 に基づいてい ますので、pngcairo 出力形式では、文字コードを utf-8 に変換する必要があ ります。デフォルトの入力文字コードは、あなたが使用している 'locale' に基づきます。他の文字コードにしたい場合は、あなたがどの文字コードを使 っているのかを確実に gnuplot がわかるようにしてください。詳細について は、以下参照: encoding (88.24)。
pango は、unicode マッピングでないフォントに対しては予期せぬ結果を与え るかもしれません。例えば Symbol フォントに対しては、pngcairo 出力形式 は、文字コードを unicode に変換するために http://www.unicode.org/ で提 供されるマッピングを利用します。なお、"the Symbol font" は、Acrobat Reader と一緒に "SY______.PFB" として配布されている Adobe Symbol フ ォントであると解釈されることに注意してください。この代わりに、 OpenOffice.org と一緒に "opens___.ttf" として配布される OpenSymbol フォントが同じ文字を提供しています。Microsoft も Symbol フォント ("symbol.ttf") を配布していますが、これは異なる文字セットになってい て、いくつかは欠けていますし、いくつかは数式記号に変わってしまっていま す。あなたのデフォルトの設定でなんらかの問題が起きた場合 (例えばデモス クリプト enhancedtext.dem がちゃんと表示されないといった場合) は、 Adobe か OpenOffice の Symbol フォントをインストールして、Microsoft の Symbol フォントを削除しないといけないかもしれません。"windings" のよ うな他の非標準のフォントでも動作することが報告されています。
描画のレンダリングは、今のところ変更できません。出力をより良くするため にこのレンダリングは、アンチエイリアス、オーバーサンプリングの 2 つの 機構を持っています。 アンチエイリアスは、水平や垂直でない線を滑らかに表示します。 オーバーサンプリングは、アンチエイリアスと組でピクセルよりも小さいサイ ズでの精度を提供し、gnuplot が非整数座標の直線を書けるようになります。 これは、対角方向の直線 (例えば 'plot x') が左右に揺れるのを避けます。
書式:
set terminal postscript {default}
set terminal postscript {landscape | portrait | eps}
{enhanced | noenhanced}
{defaultplex | simplex | duplex}
{fontfile [add | delete] "<filename>"
| nofontfiles} {{no}adobeglyphnames}
{level1 | leveldefault | level3}
{color | colour | monochrome}
{background <rgbcolor> | nobackground}
{dashlength | dl <DL>}
{linewidth | lw <LW>}
{rounded | butt}
{clip | noclip}
{palfuncparam <samples>{,<maxdeviation>}}
{size <XX>{unit},<YY>{unit}}
{blacktext | colortext | colourtext}
{{font} "fontname{,fontsize}" {<fontsize>}}
{fontscale <scale>}
"Can't find PostScript prologue file ... "
landscape と portrait は出力が横置か、縦置かを選択します。 eps モードは EPS (Encapsulated PostScript) 出力を生成しますが、これ は通常の PostScript に、それを他の多くのアプリケーションで取り込むこと ができるようにいくつかの行を追加したものです (追加される行は PostScript のコメント行なので、よってそれ自身もちゃんと印刷できます)。EPS 出力を 得るには eps モードを使用し、1 つのファイルには 1 つのグラフのみ、と してください。eps モードではフォントも含めてグラフ全体がデフォルトの 大きさの半分に縮められます。
enhanced は拡張文字列処理モード (上付き文字、下付き文字、および複数 のフォントの利用) の機能を有効にします。詳細は、以下参照: enhanced (13)。 blacktext は、たとえカラーモードでも全ての文字列を黒で書きます。
PostScript の両面印刷命令 (duplex) は、プリンタで 1 枚の紙に両面印刷す ることを可能にします。defaultplex はプリンタのデフォルトの設定を使用 し、simplex は紙の片面のみ印刷、duplex は 両面印刷を行ないます (あ なたのプリンタがそれを行なえないなら無視されます)。
"< fontname> " は有効な PostScript フォントの名前で、< fontsize> は PostScript ポイント単位でのフォントの大きさです。 標準的な postscript フォント以外に、数式を表現するのに便利な obliqueSymbol フォント ("Symbol-Oblique") が定義されています。
default は全てのオプションを以下のデフォルトの値に設定します:landscape, monochrome, dl 1.0, lw 1.0, defaultplex,enhanced, "Helvetica", 14pt。PostScript のグラフのデフォルトの大き さは、10 インチの幅で 7 インチの高さです。 オプション color はカラーを有効にし、monochrome は各要素を黒と白 描画します。さらに、monochrome は灰色の palette も使用しますが、 これは、明示的に colorspec で指定された部品の色を変更しません。
dashlength または dl は点線の線分の長さを < DL> (0 より大きい実数) に設定し、 linewidth または lw は全ての線の幅を < LW> に設定します。
デフォルトでは、生成される PostScript コードは、特にフィルタリングや filledcurves のようなでこぼこな領域のパターン塗りつぶしにおいて、 PostScript Level 2 として紹介されている言語機能を使います。PostScript Level 2 の機能は条件的に保護されていて、PostScript Level 1 のインター プリタがエラーを出さず、むしろメッセージか PostScript Level 1 による 近似であることを表示するようになっています。level1 オプションは、こ れらの機能を近似する PostScript Level1 で代用し、PostScript Level 2 コードを一切使用しません。これは古いプリンタや、Adobe Illustrator の 古いバージョンなどで必要になるかもしれません。このフラグ level1 は 出力された PostScript ファイルのある一行を手で編集することで、後から 強制的に PostScript Level 1 機能を ON/OFF にすることもできます。level 2 のコードが含まれている場合、上の機能は現われないか、このフラグがセ ットされた場合、あるいは PostScript インタプリタプログラムが level 2 以上の PostScript を解釈するとは言わなかった場合に警告文に置き換わります。level3 オプションは、ビットマップ画像の PNG 化の機能を有効に します。それにより出力サイズをかなり削減できます。
rounded は、線の端や接合部を丸くし、デフォルトの butt は尖った端と 角張った接合部を使用します。
clip は、PostScript にすべての出力を BoundingBox (PostScript の外枠) でクリップすることを指示します; デフォルトは noclip です。
palfuncparam は set palette functions から出力の傾きをどのようにコ ード化するかを制御します。解析的な色の成分関数 (set palatte functions で設定される) は、postscript 出力では傾きの線形補完を用いてコード化さ れます: まず色の成分関数が < samples> 個の点で標本化され、そしてそれら の点は、結果として線形補完との偏差が < maxdeviation> 以内に収まるように削除されます。ほとんど全ての有効なパレットで、デフォルトの < samples> =2000 と < maxdeviation> =0.003 の値をそのまま使うのが良いでしょう。
PostScript 出力のデフォルトの大きさは 10 インチ x 7 インチです。EPS 出力のデフォルトの大きさは 5 x 3.5 インチです。オプション size は これらをユーザが指定したものに変更します。デフォルトでは X と Y のサ イズの単位はインチとみなされますが、他の単位 (現在は cm のみ) も使う ことはできます。描画の BoundingBox (PostScript ファイルの外枠) は、 サイズが変更された画像を丁度含むように正しく設定されます。 スクリーン座標は、オプション size で指定された描画枠の全体が 0.0 から 1.0 になります。 注意: これは、以前は、出力形式での設定よりも、コマンド set size で設定した方がいい、と言っていたことの変更を意味します。以前の方法では BoundingBox は変更されずに残ってしまい、スクリーン座標が実際の描画の限界に対応していませんでした。
fontfile や fontfile add で指定されたフォントは、そのフォントのフ ォント定義を直接 postscript Type 1, TrueType フォントから gnuplot の postscript 出力の中にカプセル化します。よって、その埋め込まれたフォン トは見出し、タイトルなどに使うことができます。詳細は、以下参照:postscript fontfile (98.48.2)。fontfile delete によってフォントファイルを埋 め込まれるファイルの一覧から取り除くことができます。 nofontfiles は埋め込みフォントのリストをクリアします。
例:
set terminal postscript default # 以前の postscript
set terminal postscript enhanced # 以前の enhpost
set terminal postscript landscape 22 # 以前の psbig
set terminal postscript eps 14 # 以前の epsf1
set terminal postscript eps 22 # 以前の epsf2
set size 0.7,1.4; set term post portrait color "Times-Roman" 14
set term post "VAGRoundedBT_Regular" 14 fontfile "bvrr8a.pfa"
線の幅と点の大きさは set style line で変更できます。
postscript ドライバは約 70 種類の異なる点種をサポートしていて、これ は plot や set style line の pointtype オプションで選択できます。
gnuplot と Postscript に関する多分有用と思われるファイルが gnuplot の配布物、またはその配布サイトの /docs/psdos サブディレクトリ内にいく つか含まれています。そこには "ps_symbols.gpi" (実行すると postscript ドライバで使える全ての記号を紹介する "ps_symbols.ps" というファイルを生 成する gnuplot のコマンドファイル)、"ps_guide.ps" (拡張された書式に 関する要約と、文字列内で 8 進コードで生成されるもの、symbol フォント等 を含む PostScript ファイル)、"ps_file.doc" (gnuplot で作られる PostScript ファイルの構造の説明を含むテキストファイル)、 "ps_fontfile_doc.tex" (数式フォントの文字の一覧と LaTeX のフォントの埋 め込みに関する短い説明を含む LaTeX ファイル) があります。
PostScript ファイルは編集可能で、一度 gnuplot でそれを作れば、それを 望むように修正することは自由に行なえます。そのためのヒントを得るには、 以下参照: editing postscript (98.48.1) の節。
例えば、PostScript の文 "/Color true def" (set terminal postscript color コマンドに答えてファイルに書き込まれます) を変更して、その描画を白黒の ものにする方法はおわかりでしょう。同様に、線の色、文字の色、線の太さ (weight)、記号のサイズも、本当に簡単に書き換えられるでしょう。タイトル や見出しなどの文字列の誤植や、フォントの変更も編集可能でしょう。任意の ものの配置も変更できますし、もちろん、任意のものを追加したり、削除した りもできますが、それらの修正は PostScript 言語の深い知識が必要でしょう。
gnuplot によって作られる PostScript ファイルの構成に関しては、gnuplot のソース配布物内の docs/ps ディレクトリのテキストファイル "ps_file.doc" に述べられています。
postscript 出力ドライバはいくつかのフォントファイル形式を認識します: ASCII 形式の Type 1 フォント (拡張子 ".pfa")、バイナリ形式の Type 1 フ ォント (拡張子 ".pfb")、TrueType フォント (拡張子 ".ttf")。pfa ファイ ルは直接認識されますが、pfb と ttf ファイルは gnuplot の実行中に並行し て変換され、そのために適切な変換ツール (下記参照) がインストールされて いる必要があります。ファイル名は拡張子も含めて完全な形で指定する必要が あります。各 fontfile オプションはちょうど一つのフォントファイル名に 対応しますので、複数のフォントファイルを埋め込むためにはこのオプション を複数回使って下さい。
フォントファイルは、作業ディレクトリ、そして set fontpath で与えられ るフォントパス一覧の全てのディレクトリが検索されます。さらに、環境変数 GNUPLOT_FONTPATH でフォントパスを設定することもできます。それが設定さ れていない場合はデフォルトの検索リストが使われますが、これはシステムに 依存します。詳細は、以下参照: set fontpath (88.26)。
埋め込まれたフォントファイルを使うには、フォント名 (通常ファイル名と同
じではありません) を指定する必要があります。対話モードで fontfile オ
プションを使ってフォントを埋め込んだ場合、フォント名はスクリーンに表示
されます。例:
Font file 'p052004l.pfb' contains the font 'URWPalladioL-Bold'. Location: /usr/lib/X11/fonts/URW/p052004l.pfb
pfa や pfb フォントでは、フォント名はフォントファイル内に見つけること ができます。フォントファイル中に "/FontName /URWPalladioL-Bold def" の ような行がありますが、この真中の物から / を除いたものがフォント名です。 この例の場合は "URWPalladioL-Bold" となります。 TrueType フォントでは、フォント名はバイナリ形式で保存されているので見 つけるのは容易ではありません。さらに、その名前は多くの場合、Type 1 フ ォント (実行中に TrueType が変換される形式である) ではサポートされてい ない、スペースを含んだ形式になっています。そのため、フォント名はそこか らスペースを取り除いた形に変換されます。gnuplot で使うために生成された フォント名が何であるかを知る最も簡単な方法は、gnuplot を対話モードで起 動して、以下のように入力することです:"set terminal postscript fontfile '< filename.ttf> '".
フォントファイル (ttf, pfb) を pfa 形式に変換するために、フォントファ イルを読んで、そして変換結果を標準出力に吐き出す変換ツールが必要になり ます。その出力を標準出力に書き出すことができない場合、実行中の変換はで きません。
pfb ファイルに対しては、例えば "pfbtops" が使えます。それがシステム にインストールされていれば、実行中の変換はうまく行くはずです。pfb ファ イルのカプセル化をちょっとやってみましょう。もしプログラムの変換時に正 しくツールを呼び出していない場合は、どのようにツールを呼び出したら良い かを環境変数 GNUPLOT_PFBTOPFA に、例えば "pfbtops %s" のように定義し て下さい。%s はフォントファイル名に置き換えられますので、これはその 文字列に必ず必要です。
実行中の変換をしたくなくて、けれども pfa 形式のファイルは必要である場 合、"pfb2pfa" という C で書かれた簡単なツールを使えば良いでしょう。こ れは大抵の C コンパイラでコンパイルでき、たくさんの ftp サーバに置いて あります。例えば
ftp://ftp.dante.de/tex-archive/fonts/utilities/ps2mf/
実際に "pfbtopfa" と "pfb2ps" は同じ作業を行います。"pfbtops" は結果の pfa コードを標準出力に出力しますが、"pfbtopfa" はファイルに出力します。
TrueType フォントは、例えば "ttf2pt1" というツールを使って Type 1 pfa フォーマットに変換できます。これは以下にあります:
http://ttf2pt1.sourceforge.net/
もし gnuplot に組み込まれている変換手順がうまく行かない場合、変換コマ ンドは環境変数 GNUPLOT_TTFTOPFA で変更できます。ttf2pt1 を使う場合は、 それを "ttf2pt1 -a -e -W 0 %s - " のように設定して下さい。ここでも %s はファイル名を意味します。
特殊な用途のために、パイプも使えるようになっています (パイプをサポート している OS 上で)。ファイル名を "< " で始め、その後にプログラム呼び出し を追加します。そのプログラム出力は標準出力への pfa データでなければい けません。結果として pfa ファイルを、例えば以下のようにしてアクセスできることになります: set fontfile "< cat garamond.pfa"。
Type 1 フォントを取り込むことは、例えば LaTeX 文書中に postscript ファ イルを取り込む場合に使えます。pfb 形式の "european computer modern" フ ォント ("computer modern" フォントの一種) が各地の CTAN サーバに置かれ ています。
ftp://ftp.dante.de/tex-archive/fonts/ps-type1/cm-super/
例えば、ファイル "sfrm1000.pfb" は、中太、セリフ付き、立体の 10 ポイン トのフォント (フォント名 "SFRM1000") です。computer modern フォントは 今でも数式を書くのに必要ですが、それは以下にあります:
ftp://ftp.dante.de/tex-archive/fonts/cm/ps-type1/bluesky
これらによって、TeX 用の任意の文字も使えます。しかし、computer modern フォントは少しエンコーディングがおかしくなっています (このため、文字列 には cmr10.pfb の代わりに sfrm1000.pfb を使うべきです)。 TeX フォントの使用法はいくつかのデモの一つで知ることができます。 gnuplot のソース配布物の /docs/psdoc に含まれるファイル "ps_fontfile_doc.tex" に TeX 数学フォントの文字の一覧表が含まれていま す。
フォント "CMEX10" (ファイル "cmex10.pfb") を埋め込むと、gnuplot は 追加フォント "CMEX10-Baseline" も定義します。それは、他の文字にあうよ うに垂直方向にずらされたものです (CMEX10 は、記号の天辺にベースライン があります)。
書式:
set terminal [pslatex | pstex] {default}
set terminal [pslatex | pstex]
{rotate | norotate}
{oldstyle | newstyle}
{auxfile | noauxfile}
{level1 | leveldefault | level3}
{color | colour | monochrome}
{background <rgbcolor> | nobackground}
{dashlength | dl <DL>}
{linewidth | lw <LW>}
{rounded | butt}
{clip | noclip}
{palfuncparam <samples>{,<maxdeviation>}}
{size <XX>{unit},<YY>{unit}}
{<font_size>}
以下のようなエラーメッセージが出た場合:
"Can't find PostScript prologue file ... "
オプション color はカラーを有効にし、monochrome は各要素を黒と白 描画します。さらに、monochrome は灰色の palette も使用しますが、 これは、明示的に colorspec で指定された部品の色を変更しません。
dashlength または dl は点線の線分の長さを < DL> (0 より大きい実数) に設定し、 linewidth または lw は全ての線の幅を < LW> に設定します。
デフォルトでは、生成される PostScript コードは、特にフィルタリングや filledcurves のようなでこぼこな領域のパターン塗りつぶしにおいて、 PostScript Level 2 として紹介されている言語機能を使います。PostScript Level 2 の機能は条件的に保護されていて、PostScript Level 1 のインター プリタがエラーを出さず、むしろメッセージか PostScript Level 1 による 近似であることを表示するようになっています。level1 オプションは、こ れらの機能を近似する PostScript Level1 で代用し、PostScript Level 2 コードを一切使用しません。これは古いプリンタや、Adobe Illustrator の 古いバージョンなどで必要になるかもしれません。このフラグ level1 は 出力された PostScript ファイルのある一行を手で編集することで、後から 強制的に PostScript Level 1 機能を ON/OFF にすることもできます。level 2 のコードが含まれている場合、上の機能は現われないか、このフラグがセ ットされた場合、あるいは PostScript インタプリタプログラムが level 2 以上の PostScript を解釈するとは言わなかった場合に警告文に置き換わります。level3 オプションは、ビットマップ画像の PNG 化の機能を有効に します。それにより出力サイズをかなり削減できます。
rounded は、線の端や接合部を丸くし、デフォルトの butt は尖った端と 角張った接合部を使用します。
clip は、PostScript にすべての出力を BoundingBox (PostScript の外枠) でクリップすることを指示します; デフォルトは noclip です。
palfuncparam は set palette functions から出力の傾きをどのようにコ ード化するかを制御します。解析的な色の成分関数 (set palatte functions で設定される) は、postscript 出力では傾きの線形補完を用いてコード化さ れます: まず色の成分関数が < samples> 個の点で標本化され、そしてそれら の点は、結果として線形補完との偏差が < maxdeviation> 以内に収まるように削除されます。ほとんど全ての有効なパレットで、デフォルトの < samples> =2000 と < maxdeviation> =0.003 の値をそのまま使うのが良いでしょう。
PostScript 出力のデフォルトの大きさは 10 インチ x 7 インチです。EPS 出力のデフォルトの大きさは 5 x 3.5 インチです。オプション size は これらをユーザが指定したものに変更します。デフォルトでは X と Y のサ イズの単位はインチとみなされますが、他の単位 (現在は cm のみ) も使う ことはできます。描画の BoundingBox (PostScript ファイルの外枠) は、 サイズが変更された画像を丁度含むように正しく設定されます。 スクリーン座標は、オプション size で指定された描画枠の全体が 0.0 から 1.0 になります。 注意: これは、以前は、出力形式での設定よりも、コマンド set size で設定した方がいい、と言っていたことの変更を意味します。以前の方法では BoundingBox は変更されずに残ってしまい、スクリーン座標が実際の描画の限界に対応していませんでした。
rotate が指定されると y 軸の見出しが回転されます。 < font_size> は希望するフォントの (ポイント単位での) 大きさです。
auxfile が指定されると、ドライバは PostScript コマンドを、LaTeX ファ イルに直接出力する代わりに、補助ファイルに書き出すようになります。これ は、dvips がそれを扱えないくらい大きいグラフである場合に有用です。補助 PostScript ファイルの名前は、set output コマンドで与えられる TeX フ ァイルの名前から導かれるもので、それはその最後の .tex の部分 (実際の ファイル名の最後の拡張子の部分) を .ps で置き換えたもの、または、TeX ファイルに拡張子がないならば .ps を最後に付け足したものになります。 .ps ファイルは \ special{psfile=...} という命令で .tex ファイルに 取り込まれます。multiplot モード以外では、次の描画を行なう前にその出力ファイルをクローズするのを忘れないでください。
version 4.2 より前の gnuplot は ps(la)tex 出力形式では 5 x 3 インチの 出力でしたが、現在では 5 x 3.5 インチになっています。これは postscript eps 出力形式に合わせた変更です。加えて、文字幅は、以前の epslatex 出力形式はフォントサイズの 50% と見なしましたが、現在は 60% と評価しています。従来の形式に戻すには、オプション oldstyle を指定してください。
pslatex ドライバは文字列の配置の制御に特別な方法を提供します: (a) '{' で始まる文字列は、'}' で閉じる必要がありますが、その文字列全体 が LaTeX によって水平方向にも垂直方向にもセンタリングされます。 (b) '[' で始まる文字列の場合は、位置の指定をする文字列 (t,b,l,r のうち 2 つまで) が続き、次に ']{'、文字列本体、で最後に '}' としますが、この 文字列は LaTeX が LR-box として整形します。 \ rule{}{} を使えばさらに良 い位置合わせが可能でしょう。
ここに記述されていないオプションは Postscript terminal のものと同一で すので、それらが何を行なうのかを知りたければそちらを参照してください。
例:
set term pslatex monochrome rotate # デフォルトに設定
set term pslatex auxfile
set output "foo.tex"; plot ...; set output
set title '\LaTeX\ -- $ \gamma $'
set label '{\LaTeX\ -- $ \gamma $}' at 0,0
set xlabel '[t]{\LaTeX\ -- $ \gamma $}'
set ylabel '[r]{\LaTeX\ -- $ \gamma $\rule{7mm}{0pt}}'
線幅と点の大きさは set style line で変更できます。
PSTricks は anonymous ftp で Princeton.EDU の /pub ディレクトリから取 得できます。このドライバは、PSTricks パッケージの全ての能力を使おうと などとは全く考えてはいません。
書式:
set terminal pstricks {hacktext | nohacktext} {unit | nounit}
最初のオプションは、あまり綺麗ではない方法で数字のより良い出力を生成す るもので、2 つ目のオプションはグラフを伸縮する際には必要です。デフォル トでは hacktext と nounit です。
書式:
set term qt {<n>}
{size <width>,<height>}
{position <x>,<y>}
{title "title"}
{font <font>} {{no}enhanced}
{dashlength <dl>}
{{no}persist} {{no}raise} {{no}ctrl}
{close}
{widget <id>}
複数の描画ウィンドウもサポートしていて、set terminal qt < n> とすれば 番号 n の描画ウィンドウへ出力します。
デフォルトのウィンドウタイトルは、このウィンドウ番号に基づいています。 そのタイトルはキーワード "title" でも指定できます。
描画ウィンドウは、gnuplot の出力形式を別なものに変更した後でも開いた まま残ります。描画ウィンドウは、そのウィンドウが入力フォーカスを持って いる状態で文字 'q' を打つか、ウィンドウマネージャメニューで close を 選択するか、または set term qt < n> close とすることで閉じることができ ます。
描画領域のサイズはピクセル単位で与えます、デフォルトは 640x480 です。 それに加えて、ウィンドウの実際のサイズには、ツールバーやステータスバー 用のスペースも追加されます。 ウィンドウのサイズを変更すると、描画グラフもウィンドウの新しいサイズに ぴったり合うようにすぐに伸縮されます。qt 出力形式はフォント、線幅も含 めて描画全体を伸縮しますが、全体のアスペクト比は一定に保ちます。 その後 replot とタイプするか、ターミナルツールバーの replot アイコ ンをクリックするか、新たに plot コマンドを入力すると、その新しい描画 では完全にそのウィンドウに合わせられますが、フォントサイズや線幅はそれ ぞれのデフォルトにリセットされます。
position オプションは描画ウィンドウの位置を設定するのに使えます。これは コマンド set term 後の最初の描画にのみ適用されます。
現在の描画ウィンドウ (set term qt < n> で選択されたもの) は対話型で、 その挙動は、他の出力形式と共通です。詳細は、以下参照: mouse (88.47)。それには 追加のアイコンもいくつかついていますが、それらはそれ自体が説明的なもの になっているはずです。
この出力形式は、拡張文字列処理モード (enhanced text mode) をサポートし ていて、フォントや書式コマンド (上付、下付など) をラベルや他の文字列に 埋め込むことができます。拡張文字列処理モードの書式は、gnuplot の他の出 力形式と共通です。詳細は、以下参照: enhanced (13)。
<
font>
は "FontFace,FontSize" の形式で、FontFace と FontSize とをコ
ンマで分離して一つの文字列として書きます。FontFace は、'Arial' のよ
うな通常のフォント名です。FontFace を与えない場合は、qt 出力形式は
'Sans' を使用します。FontSize はポイント単位のフォントサイズです。
FontSize を与えない場合は、qt 出力形式は 9 ポイントを使用します。
例 :
set term qt font "Arial,12"
set term qt font "Arial" # フォント名のみ変更
set term qt font ",12" # フォントサイズのみ変更
set term qt font "" # フォント名、、フォントサイズをリセット
dashlength は、点線/破線パターンのユーザ定義にのみ影響を与え、Qt が内部 に持っているパターンには影響を与えません。
Qt のレンダリング速度は、使用するレンダリングモードによって大きく変わり ます。Qt バージョン 4.7 以降では、これは環境変数 QT_GRAPHICSSYSTEM で制御できるようになっています。指定するオプションは、レンダリング速度の遲 い順に、"native", "raster", "opengl" となっています。従来の Qt の 版では、この出力形式ではデフォルトを "raster" にします。
可能な限り最も良い出力を生成するために、このレンダリングはアンチアリア ス、オーバーサンプリング、ヒンチングの 3 つの機構を持っています。 オーバーサンプリングは、アンチエイリアスと組でピクセルよりも小さいサイ ズでの精度を提供し、gnuplot が非整数座標の直線を書けるようになります。 これは、対角方向の直線 (例えば 'plot x') が左右に揺れるのを避けます。 ヒンティングは、オーバーサンプリングによって引き起こされる水平、垂直方 向の線分のぼかしを避けます。この出力形式は、これらの直線を整数座標に揃 え、それにより、1 ピクセル幅の直線は本当に 1 つ (1 つより多くも少なく もない) のピクセルで描画します。
デフォルトでは、描画が行われたときにウィンドウはデスクトップの一番上 (最前面) に表示されます。これは、キーワード "raise" で制御できます。 キーワード "persist" は、すべての描画ウインドウを明示的に閉じない間 は、gnuplot が終了しないようにします。 最後に、デフォルトでは < space> キーは gnuplot コンソールウィンドウを上 に上げ、'q' は描画ウィンドウを閉じます。キーワード "ctrl" は、それら のキー割り当てを、それぞれ < ctrl> +< space> と < ctrl> +'q' に変更します。
プログラムのコンパイル時に選択した場所に、gnuplot の外部ドライバ gnuplot_qt がインストールされますが、環境変数 GNUPLOT_DRIVER_DIR を別 な場所に設定することで置き場所を変更することもできます。
書式:
set terminal regis {4 | 16}
書式:
set terminal svg {size <x>,<y> {|fixed|dynamic}}
{{no}enhanced}
{fname "<font>"} {fsize <fontsize>}
{mouse} {standalone | jsdir <dirname>}
{name <plotname>}
{font "<fontname>{,<fontsize>}"}
{fontfile <filename>}
{rounded|butt|square} {solid|dashed} {linewidth <lw>}
{background <rgb_color>}
ここで < x> と < y> は生成される SVG グラフのサイズですが、dynamic は svg ビューワに描画のリサイズを許し、fixed は絶対サイズを要求します (デフォルト)。
linewidth < w> は図の中で使用される全ての線の幅を因子 < w> だけ増加さ せます。
< font> はデフォルトとして使われるフォント名 (デフォルトでは Arial)、 < fontsize> はポイント単位でのフォントサイズ (デフォルトは 12) です。 svg ビューワソフトは、そのファイルの表示の際には別の代用フォントを使う ことになるでしょう。
svg 出力形式は拡張文字列処理機能 (enhanced) をサポートしています。これ は、フォント指定や他の書式命令をラベルや他の文字列内に埋め込むことを可 能にします。拡張文字列処理モードの書式指定は他の出力形式の場合と同じで す。詳細は、以下参照: enhanced (13)。
オプション mouse は、マウストラッキング機能と、対応する key 上でクリ ックすることでそれぞれのグラフの描画を On/Off にする機能をサポートを追 加することを gnuplot に指示します。デフォルトではローカルディレクトリ、 通常は /usr/local/share/gnuplot/< version> /js 内のあるスクリプトを指すリ ンクを取り込むことで行われますが、オプション jsdir に別のローカルディ レクトリか、通常の URL を指定することでこれは変更できます。SVG 画像を Web ページに入れるのであれば、普通は後者の URL の方を指定します。一方で オプション standalone は、マウス操作プログラムを SVG 文書自体に埋め込 み、外部リソースへのリンクは行いません。
SVG ファイルを何かの外部ファイルと組み合わせて利用したい場合、例えばそ れが PNG 画像を内部に持っていたり、ある Web ページやそれが埋め込んでい る文書の javascriptコードから参照されているような場合、他の SVG グラフ への参照との衝突を避けるために一意的な名前が必要になります。その場合は オプション name を使って固有の名前を確保してください。
SVG では、SVG 文書中にフォントを直接埋め込むこともできますし、好きなフ ォントへのハイパーリンクを与えることもできます。fontfile オプション には、結果として出力される SVG ファイルの < defs> セクションの中にコピ ーされるローカルファイル名を指定します。このファイルは、それ自身がフォ ントを含んでいるか、または期待するフォントを参照するハイパーリンクを生 成するための行を含むもののどちらかです。gnuplot は、環境変数 GNUPLOT_FONTPATH のディレクトリリストから要求されたファイルを探します。 注: TrueType や PostScript フォントではない svg フォントを埋め込む必要 があります。
書式:
set terminal svga {"<fontname>"}
数ある中で、点 (point) は、LaTeX のコマンド " \ Diamond", " \ Box" などを 使って描かれます。これらのコマンドは現在は LaTeX2e のコアには存在せず latexsym パッケージに含まれていますが、このパッケージ基本配布の一部で あり、よって多くの LaTeX のシステムの一部になっています。このパッケー ジを使うことを忘れないでください。
オプションはありません。
tgif ドライバは、フォント指定、フォントサイズ指定、1 ページ内の複数の グラフ描画をサポートしています。軸の比率は変更されません。
書式:
set terminal tgif {portrait | landscape | default} {<[x,y]>}
{monochrome | color}
{{linewidth | lw} <LW>}
{solid | dashed}
{font "<fontname>{,<fontsize>}"}
< [x,y]> にはそのページ内の x 方向、y 方向のグラフの数を指定し、 color はカラー機能を有効にし、linewidth は全ての線幅を < LW> 倍し、 "< fontname> " には有効な PostScript フォント名、< fontsize> はその PostScript フォントの大きさを指定します。defaults は全てのオプション の値をデフォルトの値にセットします。デフォルトは portrait, [1,1], color, linewidth 1.0, dashed, "Helvetica,18" です。
solid オプションは、編集作業中にそうであるように、線がカラーである場 合に普通使われます。ハードコピーは白黒になることが多いので、その場合は dashed を選択すべきでしょう。
多重描画 (multiplot) は 2 種類の方法で実装されています。
その一つは、標準的な gnuplot の多重描画のやり方です:
set terminal tgif
set output "file.obj"
set multiplot
set origin x01,y01
set size xs,ys
plot ...
...
set origin x02,y02
plot ...
unset multiplot
より詳しい情報については、以下参照: set multiplot (88.48)。
もう一つの方法はドライバの [x,y] オプションです。この方法の長所は、原 点 (origin) や大きさ (size) の設定をしなくても全てのグラフが自動的に縮 尺され配置されることです。グラフの比 x/y は、自然な比 3/2 (または set size で設定されたもの) が保持されます。
両方の多重描画の実装が選択された場合、標準的なやり方の方が選択され、警 告のメッセージが表示されます。
単一描画 (または標準的な多重描画) の例:
set terminal tgif # デフォルト
set terminal tgif "Times-Roman,24"
set terminal tgif landscape
set terminal tgif landscape solid
ドライバの持つ多重描画の仕組みを利用する例:
set terminal tgif portrait [2,4] # 縦置、x-方向に 2 つ、y-方向
# に 4 つのグラフ描画
set terminal tgif [1,2] # 縦置、x-方向に 1 つ、y-方向
# に 2 つのグラフ描画
set terminal tgif landscape [3,3] # 横置、両方の方向に 3 つのグ
# ラフ描画
書式:
set terminal tkcanvas {tcl | perl | perltkx | python | ruby | rexx}
{standalone | input}
{interactive}
{rounded | butt}
{nobackground | background <rgb color>}
{{no}rottext}
{size <width>,<height>}
{{no}enhanced}
{externalimages | pixels}
結果を表示するには、以下の Tcl/Tk コマンド列を実行します:
package require Tk
# 以下の 2 行は、外部画像を使用する場合にのみ必要
package require img::png
source resize.tcl
source plot.tcl
canvas .c -width 800 -height 600
pack .c
gnuplot .c
Perl/Tk の場合は、以下のようにします:
use Tk;
my $top = MainWindow->new;
my $c = $top->Canvas(-width => 800, -height => 600)->pack;
my $gnuplot = do "plot.pl";
$gnuplot->($c);
MainLoop;
Perl/Tkx の場合は、以下のようにします:
use Tkx;
my $top = Tkx::widget->new(".");
my $c = $top->new_tk__canvas(-width => 800, -height => 600);
$c->g_pack;
my $gnuplot = do "plot.pl";
$gnuplot->($c);
Tkx::MainLoop();
Python/Tkinter の場合は、以下のようにします:
from tkinter import *
from tkinter import font
root = Tk()
c = Canvas(root, width=800, height=600)
c.pack()
exec(open('plot.py').read())
gnuplot(c)
root.mainloop()
Ruby/Tk の場合は、以下のようにします:
require 'tk'
root = TkRoot.new { title 'Ruby/Tk' }
c = TkCanvas.new(root, 'width'=>800, 'height'=>600) { pack { } }
load('plot.rb')
gnuplot(c)
Tk.mainloop
Rexx/Tk の場合は、以下のようにします:
/**/
call RxFuncAdd 'TkLoadFuncs', 'rexxtk', 'TkLoadFuncs'
call TkLoadFuncs
cv = TkCanvas('.c', '-width', 800, '-height', 600)
call TkPack cv
call 'plot.rex' cv
do forever
cmd = TkWait()
if cmd = 'AWinClose' then leave
interpret 'call' cmd
end
gnuplot が生成するコード (上の例では、"plot.< ext> " として書き出され ているものです) は、以下のような手続き関数を含んでいます:
gnuplot(canvas)
引数として canvas の名前を取ります。 これを呼び出すと、その canvas をクリアし、canvas のサイズを探し、そ の中にグラフを描き、それに合うように伸縮します。
gnuplot_plotarea()
canvas スクリーン座標での描画領域の境界 (xleft, xright, ytop, ybot) を含むリストを返します。 2 次元グラフ描画 (`plot`) に対してのみ動作します。
gnuplot_axisranges()
グラフ座標での 2 つの軸の範囲 (x1min, x1max, y1min, y1max, x2min, x2max, y2min, y2max) を返します。 2 次元グラフ描画 (`plot`) に対してのみ動作します。
オプション standalone を使えば、自己完結した最小スクリプトを生成でき ます。デフォルトは input で、これは取り込まれるべきスクリプトを作りま す (すなわち、load されるか call されるか、または選択した言語用のなんら かの適切な方法で)。
オプション interactive を指定すると、一つの線分上でマウスクリックした
ときにその中点の座標が標準出力に出力されるようになります。
この動作は、user_gnuplot_coordinates という手続き関数を定義することで、
別なものに置き換えることも可能です。その手続き関数には以下の引数が渡されます:
win id x1s y1s x2s y2s x1e y1e x2e y2e x1m y1m x2m y2m,
デフォルトでは、canvas は transparent ですが、オプション background で、明示的に背景色を設定することもできます。
rounded は、線の端や接合部を丸くします。 デフォルトの butt は、尖った端と角張った接合部を使用します。
オプション rottext で、文字列の任意角での回転を有効にできますが、それ には Tcl/Tk 8.6 以降が必要です。デフォルトは norottext です。
オプション size は、目盛りの刻みとフォントサイズを、指定された canvas サイズに対して最適化なものにしようとします。デフォルトでは、出力サイズ は 800 x 600 ピクセルとしています。
enhanced は、拡張文字列処理を選択します (デフォルト) が、これは今のと ころ Tcl でのみ利用可能です。
オプション pixels (デフォルト) は、フェールセーフなピクセル毎の画像処 理ルーチンを選択します。以下参照: image pixels (43.2)。 オプション externalimages は、画像を外部 PNG 画像として保存し、それを あとで tkcanvas コードが読み込んで伸縮します。このオプションは、Tcl で のみ有効で、しかも Tk の画像処理ルーチンが任意の伸縮を提供していないた めに、ある状況では遅くなります。この場合、スクリプトで、提供される rescale.tcl を取り込まなければいけません。
対話型モードは、Python/Tk, Rexx/Tk ではまだ実装されていません。Ryby/Tk の対話型モードは、まだ user_gnuplot_coordinates をサポートしていません。
書式:
set terminal tpic <pointsize> <linewidth> <interval>
pointsize と linewidth は整数でミリインチ単位、interval は実数で 単位はインチです。正でない値を指定するとデフォルトの値が使われます。デ フォルトでは pointsize = 40, linewidth = 6, interval = 0.1 です。
LaTeX に関する全てのドライバは文字列の配置の制御に特別な方法を提供しま す: '{' で始まる文字列は、'}' で閉じる必要がありますが、その文字列全体 が LaTeX によって水平方向にも垂直方向にもセンタリングされます。'[' で 始まる文字列の場合は、位置の指定をする文字列 (t,b,l,r のうち 2 つまで) が続き、次に ']{'、文字列本体、で最後に '}' としますが、この文字列は LaTeX が LR-box として整形します。 \ rule{}{} を使えばさらに良い位置合わ せが可能でしょう。
例:
見出しの位置合わせに関して:
gnuplot のデフォルト (大抵それなりになるが、そうでないこともある):
set title '\LaTeX\ -- $ \gamma $'
set label '{\LaTeX\ -- $ \gamma $}' at 0,0
set xlabel '[t]{\LaTeX\ -- $ \gamma $}'
set ylabel '[r]{\LaTeX\ -- $ \gamma $\rule{7mm}{0pt}}'
書式:
set terminal vgagl \
background [red] [[green] [blue]] \
[uniform | interpolate] \
[mode]
カラーモードは mode オプションで与えることもできます。G1024x768x256 の ような記号的名称や整数で与えることができます。オプション background は [0, 255] の範囲の整数 1 つ、または 3 つの組を取ります。整数 1 つの 場合はそれは背景の灰色の値と見なされ、3 つの組の場合はそれに対応した色 が背景に取られます。 相互に排他的なオプション interpolate と uniform は、三角形の塗りつ ぶしの際に色の補間が行うかどうか (デフォルトでは ON) を制御します。
高解像度モードを得るには、多分 libvga の設定ファイル (通常 /etc/vga/libvga.conf) を修正する必要があるでしょう。VESA fb を使うのは 良い選択ですが、それはカーネルのコンパイルが必要です。
vgagl ドライバは、以下のリストのうちの *有効な* vga モードの最初のものを使用します。
- vgagl の設定時に与えられるモード、例えば `set term vgagl G1024x768x256` は最初に G1024x768x256 モードが有効かどうかチェックします。 - 環境変数 SVGALIB_DEFAULT_MODE - G1024x768x256 - G800x600x256 - G640x480x256 - G320x200x256 - G1280x1024x256 - G1152x864x256 - G1360x768x256 - G1600x1200x256
書式:
set terminal windows {<n>}
{color | monochrome}
{solid | dashed}
{rounded | butt}
{enhanced | noenhanced}
{font <fontspec>}
{linewdith <scale>}
{fontscale <scale>}
{linewdith <scale>}
{background <rgb color>}
{title "Plot Window Title"}
{{size | wsize} <width>,<height>}
{position <x>,<y>}
{close}
複数のウィンドウ描画がサポートされています: set terminal win < n> で 出力が番号 n の描画ウィンドウに送られます。
color, monochrome は、カラー出力か白黒出力かの選択で、 dashed と solid は、点線と実線の選択です。color では solid が デフォルトで、monochrome では dashed がデフォルトです。 rounded は、線の端や接合部を丸くし、デフォルトの butt は尖った端と 角張った接合部を使用します。 enhanced は拡張文字列処理 (enhanced text mode) の機能 (上付、下付文字 やフォントの混在) を有効にします。詳細は以下参照: enhanced text (13)。 < fontspec> は "< fontface> ,< fontsize> " の形式で、"< fontface> " は有 効な Windows のフォント名で、< fontsize> はポイント単位でのフォントの 大きさです。この両要素はいずれも省略可能です。 以前の版の gnuplot では、font キーワードは省略可能で、< fontsize> は引用符なしの数値で与えることができましたが、現在はその形式はサポートしていませんので注意してください。 linewidth と fontscale で線の幅と文字サイズを伸縮できます。 title は、グラフウィンドウのタイトルを変更します。 size はウィンドウの描画領域のピクセル単位での幅と高さを、wsize はウ ィンドウ自身の実際のサイズを、そして position はウィンドウの原点、す なわち左上角のスクリーン上のピクセル単位での位置を定義します。これらの オプションは、ファイル wgnuplot.ini のデフォルトの設定を上書きします。
他のオプションもグラフメニューや初期化ファイル wgnuplot.ini で変更で きます。
Windows 版は、非対話型モードでは通常、コマンドラインから与えたファイル の最後に達すると直ちに終了しますが、コマンドラインの最後に - を指定 した場合は別です。また、このモードではテキストウィンドウは表示せず、グ ラフのみの表示となりますが、オプションとして -persist (x11 版の gnuplot と同じオプション; 従来の Windows のみのオプション /noend や -noend を使うこともできます) を指定すると gnuplot は終了しなくなりま す。この場合他の OS での gnuplot の挙動とは異なり、-persist オプション 後も gnuplot の対話型コマンドラインを受け付けます。
コマンド set term で gnuplot の出力形式を変更した場合、描画ウィンドウ はそのまま残りますが、set term windows close で描画ウィンドウを閉じる ことができます。
gnuplot は、Windows 上での出力の生成のためのいくつかの方法をサポート しています。以下参照: windows printing (98.66.2)。windows 出力形式は、クリップ ボードや EMF ファイルを通して他のプログラムとのデータの交換をサポートし ています。以下参照: graph-menu (98.66.1)。EMF ファイルを生成するには、emf 出 力形式を使うこともできます。
Copy to Clipboard クリップボードにビットマップや EMF 画像をコピー
Save as EMF... 現在のグラフウィンドウを EMF ファイルとして保存
Print... グラフィックウィンドウを Windows プリンタドライバでプリント アウト。プリンタと拡大率の選択が可能ですが、この Print オプションに よる印刷結果は gnuplot の持つプリンタドライバによるもの程良くはあり ません。以下も参照: windows printing (98.66.2)。
Bring to Top チェックを入れるとグラフウィンドウを他の全ての描画ウィン ドウの手前に表示
Color チェックを入れるとカラーの線種が有効、チェック無しでは白黒
Double buffer グラフをスクリーンに写す前にメモリバッファに描画するこ とを有効にします。これは、例えばアニメーション時や 3 次元グラフの回転時 のちらちら (フリッカー) を回避します。以下参照: mouse (88.47), scrolling (88.47.3)。
Oversampling 仮想キャンバスのサイズを倍にします。スクリーンに写す際に は再び半分に縮小されます。これにより、グラフィックはより滑らかになりま すが、しかしメモリや計算時間がより必要です。これは double buffer も必 要です。
Antialiasing 折れ線や線の端の平滑化を選択します。これは描画を遲くする ことに注意してください。
Fast rotation グラフウィンドウをマウスで回転している際にアンチエイリ アスを一時的にオフにします。これは、マウスボタンを離した後に追加の再描 画が行われますが、相当に描画を早くしてくれます。
Background... ウィンドウ背景色の設定
Choose Font... グラフィックウィンドウで使うフォントの選択
Update wgnuplot.ini 現在のウィンドウの位置、ウィンドウの大きさ、テキ ストウィンドウのフォントとそのフォントサイズ、グラフウィンドウのフォン トとそのフォントサイズ、背景色を初期化ファイル wgnuplot.ini に保存
(*) このメニューは、unset mouse によって右マウスボタン押ししか使えな くなるので注意。
1. gnuplot のコマンド set terminal でプリンタを選択し、set output で出力をファイルにリダイレクト
2. gnuplot graph ウィンドウから Print... コマンドを選択。テキス トウィンドウからこれを行なう特別なコマンド screendump もある。
3. set output "PRN" とすると出力は一時ファイルに出力され、gnuplot を終了するかまたは set output コマンドで出力を他のものへ変更すると、 ダイアログ (対話) ボックスが現われ、そこでプリンタポートを選択。そこで OK を選択すると、出力はプリントマネージャでは加工されずにそのまま選択 されたポートでプリントアウトされる。これは偶然 (または故意) に、あるプ リンタ用の出力を、それに対応していないプリンタに送り得ることを意味する。
Copy to Clipboard マークしたテキストをクリップボードにコピー
Paste 打ち込んだのと同じようにクリップボードからテキストをコピー
Choose Font... テキストウィンドウで使うフォントの選択
System Colors 選択するとコントロールパネルで設定したシステムカラーを テキストウィンドウに与える。選択しなければ白背景で文字は黒か青。
Wrap long lines 選択すると現在のウィンドウ幅よりも長い行を折り返す
Update wgnuplot.ini 現在の設定を、ユーザのアプリケーションデータディ レクトリにある初期化ファイル wgnuplot.ini に保存
[Menu] 次の行の名前で新しいメニューを開始 [EndMenu] 現在のメニューを終了 [--] 水平なメニューの仕切りを入れる [|] 垂直なメニューの仕切りを入れる [Button] メニューに押しボタンを入れ、それに次のマクロを割り当てる
マクロは 2 行で書き、最初の行はマクロ名 (メニューの見出し)、2 行目がマ クロ本体です。先頭の空白列は無視されます。マクロコマンドは以下の通り:
[INPUT] [EOS] か {ENTER} までをプロンプトとして出力し文字列を入力
[EOS] 文字列の終り (End Of String)。何も出力しない
[OPEN] 開くファイル名を取得。最初の [EOS] までが対話ウィンドウのタ
イトル、そこから次の [EOS] か {ENTER} までがデフォルトのフ
ァイル名
のタイトル
{ENTER} 復帰 '\r'
{TAB} タブ '\011'
{ESC} エスケープ '\033'
{^A} '\001'
...
{^_} '\031'
マクロは展開後の文字数が最大 256 文字に制限されています。
[WGNUPLOT]
TextOrigin=0 0
TextSize=640 150
TextFont=Terminal,9
TextWrap=1
TextLines=400
SysColors=0
GraphOrigin=0 150
GraphSize=640 330
GraphFont=Arial,10
GraphColor=1
GraphToTop=1
GraphDoublebuffer=1
GraphOversampling=0
GraphAntialiasing=1
GraphFastRotation=1
GraphBackground=255 255 255
以下の設定は wgnuplot のテキストウィンドウのみに適用されます。
TextOrigin と TextSize は、テキストウィンドウの位置とサイズの指定 です。
TextFont は、テキストウィンドウのフォントとサイズの指定です。
TextWrap は、長いテキスト行の折り返しを選択します。
TextLines は、テキストウィンドウの内部バッファに何行 (折り返しなし) 保持するかを指定します。現在は、この値を wgnuplot 内からは変更できませ ん。
以下参照: text-menu (98.66.3)。
GraphFont は、フォント名とポイント単位のフォントサイズの指定です。
以下参照: graph-menu (98.66.1)。
書式:
set term wxt {<n>}
{size <width>,<height>} {position <x>,<y>}
{background <rgb_color>}
{{no}enhanced}
{font <font>} {fontscale <scale>}
{title "title"}
{linewidth <lw>}
{dashlength <dl>}
{{no}persist}
{{no}raise}
{{no}ctrl}
{close}
複数の描画ウィンドウもサポートしていて、set terminal wxt < n> とすれば 番号 n の描画ウィンドウへ出力します。
デフォルトのウィンドウタイトルは、このウィンドウ番号に基づいています。 そのタイトルは "title" キーワードでも指定できます。
描画ウィンドウは、gnuplot の出力形式を別なものに変更しても残ったまま になります。それを閉じるには、そのウィンドウに入力フォーカスがある状態 で 'q' を入力するか、ウィンドウマネージャのメニューで close を選択す るか、set term wxt < n> close としてください。
描画領域のサイズはピクセル単位で与えます。デフォルトは 640x384 です。 それに加えて、ウィンドウの実際のサイズには、ツールバーやステータスバー 用のスペースも追加されます。 ウィンドウのサイズを変更すると、描画グラフもウィンドウの新しいサイズに ぴったり合うようにすぐに伸縮されます。他の対話型出力形式と違い、wxt 出力形式はフォント、線幅も含めて描画全体を伸縮しますが、全体のアスペク ト比は一定に保って、空いたスペースは灰色で塗り潰します。その後 replot とタイプするかターミナルツールバーの replot アイコンをクリックするか 新たに plot コマンドを入力すると、その新しい描画では完全にそのウィン ドウに合わせられますが、フォントサイズや線幅はそれぞれのデフォルトにリ セットされます。
position オプションは描画ウィンドウの位置を設定するのに使えます。これは コマンド set term 後の最初の描画にのみ適用されます。
現在の描画ウィンドウ (set term wxt < n> で選択されたもの) は対話的で その挙動は、他の出力形式と共通です。詳細は、以下参照: mouse (88.47)。それに は追加のアイコンもいくつかついていますが、それらはそれ自体が説明的なも のになっているはずです。
この出力形式は、拡張文字列処理モード (enhanced text mode) をサポートし ていて、フォントや書式コマンド (上付、下付など) をラベルや他の文字列に 埋め込むことができます。拡張文字列処理モードの書式は他の gnuplot の出 力形式と共通です。詳細は、以下参照: enhanced (13)。
<
font>
は "FontFace,FontSize" の形式で、FontFace と FontSize とをコ
ンマで分離して一つの文字列として書きます。FontFace は、'Arial' のよ
うな通常のフォント名です。FontFace を与えない場合は、wxt 出力形式は
'Sans' を使用します。FontSize は、ポイント単位のフォントサイズです。
FontSize を与えない場合は、wxt 出力形式は 10 ポイントを使用します。
例:
set term wxt font "Arial,12"
set term wxt font "Arial" # フォント名のみ変更
set term wxt font ",12" # フォントサイズのみ変更
set term wxt font "" # フォント名、フォントサイズをリセット
フォントは通常のフォントサブシステムから取得します。MS-Windows 上では コントロールパネルの "Fonts" エントリで検索されるので、そこに設定し ます。Unix 上では、フォントは "fontconfig" が処理します。
文字列のレイアウトに使用される pango ライブラリは utf-8 を基本としてい ますので、wxt 出力形式ではエンコーディングを utf-8 にする必要がありま す。デフォルトの入力エンコーディングは、システムの 'locale' によりま す。他のエンコーディングを使用したい場合は、それを gnuplot に知らせる 必要があります。詳細は、以下参照: encoding (88.24)。
pango は、unicode マッピングでないフォントに対しては予期せぬ結果を与え るかもしれません。例えば Symbol フォントに対しては、wxt 出力形式は、文 字コードを unicode に変換するために http://www.unicode.org/ で提供され るマッピングを利用します。pango は、その文字を含むフォントを見つけるた めにあなたの Symbol フォントを検索し、そして DejaVu フォントのように、 幅広く unicode をカバーする他のフォントを探す、といった最善の作業を行 おうとします。なお、"the Symbol font" は、Acrobat Reader と一緒に "SY______.PFB" として配布されている Adobe Symbol フォントであると解 釈されることに注意してください。この代わりに、OpenOffice.org と一緒に "opens___.ttf" として配布される OpenSymbol フォントが同じ文字を提供 しています。Microsoft も Symbol フォント ("symbol.ttf") を配布してい ますが、これは異なる文字セットになっていて、いくつかは欠けていますし、 いくつかは数式記号に変わってしまっています。あなたのデフォルトの設定で なんらかの問題が起きた場合 (例えばデモスクリプト enhancedtext.dem がち ゃんと表示されないといった場合) は、Adobe か OpenOffice の Symbol フォ ントをインストールして、Microsoft の Symbol フォントを削除しないといけ ないかもしれません。 "windings" のような他の非標準のフォントでも動作することが報告されて います。
描画のレンダリングは、ツールバーで対話的に変更できます。可能な限り最も 良い出力を生成するためにこのレンダリングは、アンチエイリアス、オーバー サンプリング、ヒンティングの 3 つの機構を持っています。 アンチエイリアスは、水平や垂直でない線の滑らかな表示を可能にします。 オーバーサンプリングは、アンチエイリアスと組でピクセルよりも小さいサイ ズでの精度を提供し、gnuplot が非整数座標の直線を書けるようになります。 これは、対角方向の直線 (例えば 'plot x') が左右に揺れるのを避けます。 ヒンティングは、オーバーサンプリングによって引き起こされる水平、垂直方 向の線分のぼかしを避けます。この出力形式は、これらの直線を整数座標に揃 え、それにより、1 ピクセル幅の直線は本当に 1 つ (1 つより多くも少なく もない) のピクセルで描画します。
デフォルトでは、描画が行われたときにウィンドウはデスクトップの一番上 (最前面) に表示されます。これは、キーワード "raise" で制御できます。 キーワード "persist" は、すべての描画ウインドウを明示的に閉じない間 は、gnuplot が終了しないようにします。 最後に、デフォルトでは < space> キーは gnuplot コンソールウィンドウを上 に上げ、'q' は描画ウィンドウを閉じます。キーワード "ctrl" は、それら のキー割り当てを、それぞれ < ctrl> +< space> と < ctrl> +'q' に変更します。 これらの 3 つのキーワード (raise, persist, ctrl) は、設定ダイアログ上 のやりとりでも設定し、記憶させることができます。
書式:
set terminal x11 {<n> | window "<string>"}
{title "<string>"}
{{no}enhanced} {font <fontspec>}
{linewidth LW}
{{no}persist} {{no}raise} {{no}ctrlq}
{{no}replotonresize}
{close}
{size XX,YY} {position XX,YY}
set terminal x11 {reset}
複数のグラフ描画ウィンドウをサポートしています。set terminal x11 < n> は番号 n の描画ウィンドウに出力します。n が 0 でなければ、タイトルが明 示的に指定されていなければその番号がウィンドウタイトルとしてつけられ、 アイコンには Gnuplot < n> とラベル付けされます。現在有効なウィンドウ はカーソル記号の変化で区別できます (デフォルトカーソルから十字カーソル へ)。
x11 出力形式は、外部のアプリケーションによって生成されている X のウィ ンドウの X ID (16 進表記) をオプション window の後に文字列として指定 することで、そのウィンドウと接続できます。X は複数のクライアントにイベ ント ButtonPress の選択を認めないため、gnuplot その外部ウィンドウをコン テナとして使用します。この方法により、gnuplot のマウス機能はとりこまれ た描画ウィンドウ内でも作動します。
set term x11 window "220001e"
x11 出力形式は、利用可能なフォントの元で拡張文字列処理モード (以下参照:enhanced (13)) をサポートしています。文字列に埋め込まれ、様々な効果を与え るフォントサイズ命令のために、デフォルトの x11 フォントがスケーラブル フォントである必要があります。よって、以下の最初の例はうまくいくでしょうが、2 番目のものはそうではないでしょう。
set term x11 enhanced font "arial,15"
set title '{/=20 Big} Medium {/=5 Small}'
set term x11 enhanced font "terminal-14"
set title '{/=20 Big} Medium {/=5 Small}'
gnuplot ドライバが別な出力ドライバに変更されても、描画ウィンドウは開 いたままになります。描画ウィンドウは、そのウィンドウにカーソルを置いて 文字 q を押すか、ウィンドウマネージャのメニューの close を選択すれば 閉じることができます。reset を実行すれば全てのウィンドウを一度に閉じ れます。それは実際にウィンドウを管理している子プロセスを終了します (も し -persist が指定されていなければ)。コマンド close は、個々の描画 ウィンドウを番号を指定して閉じるのに使うことができます。しかし、persist のために残っているような描画ウィンドウは close コマンドでは閉じること はできません。番号を省略して close した場合には現在有効な描画ウィンド ウを閉じます。
gnuplot の外にあるドライバ gnuplot_x11 は、プログラムのコンパイル時に 選択されたデフォルトの場所が検索されます。これは環境変数 GNUPLOT_DRIVER_DIR を異なる場所と定義することで変更できます。
描画ウィンドウは -persisit オプションが与えられていなければ、対話の 終了時に自動的に閉じられます。
オプション persist と raise はデフォルトでは設定されていませんが、 それは、デフォルトの値 (persist == no で raise == yes) か、コマンドラ インオプション -persist / -raise の指定か、または X のリソース値が使わ れる、ということを意味します。[no]persist か [no]raise が指定されると それはコマンドラインオプションや X リソースの設定よりも優先されます。 これらのオプションの設定は直ちに効力を持ちますので、既に起動しているド ライバの挙動は変更されます。ウィンドウを前面に出せない場合は、以下参照:raise (82)。
オプション replotonresize (デフォルトで有効) は、描画ウィンドウのリ サイズ時にデータを再描画します。このオプションなしだと、アスペクト比の 変わらない拡大であっても、リサイズ後にウィンドウの一部分にしか描画され ない可能性があります。このオプションを使えば、gnuplot は各リサイズイベ ント毎に完全な再描画を行いますので、枠内をより綺麗に使ってくれます。リ サイズの間の再描画による潜在的な CPU への負荷が心配でない場合、このオ プションは普通は望ましいものです。再描画は、ホットキー 'e' や 'replot' コマンドで手動で実行することも可能です。
オプション title "< title name> " は現在の描画ウィンドウに、または番号 を指定すればその番号の描画ウィンドウに対するウィンドウタイトル名をつけ ます。そのタイトルが表示される場所、または表示されるかどうかは、使って いる X のウィンドウマネージャに依存します。
オプション size は、描画ウィンドウのサイズを設定するのに使用できます。 このオプションは、その後に生成するウィンドウのみに適用されます。
オプション position は、描画ウィンドウの位置を設定するのに使えます。 このオプションは、その後に生成するウィンドウのみに適用されます。
描画サイズとアスペクト比は、gnuplot のウィンドウをリサイズすることで も変更できます。
線の幅と点のサイズは gnuplot の set linestyle で変更可能です。
出力ドライバ x11 に関しては、gnuplot は (起動時に)、コマンドライン、 または設定ファイルから、geometry や font, name などの通常の X Toolkit オプションやリソースの指定を受け付けます。それらのオプションについては X(1) マニュアルページ (やそれと同等のもの) を参照してください。
他にも x11 出力形式用の多くの gnuplot のオプションがあります。これ らは gnuplot を呼ぶときにコマンドラインオプションとして指定するか、 または設定ファイル ".Xdefaults" のリソースとして指定できます。これら は起動時に設定されるので、gnuplot 実行時には変更できません (persist と raise 以外は)。
例:
gnuplot*font: lucidasans-bold-12
`set term x11 font "<fontspec>"`
-*-<font>-<weight>-<s>-*-*-<size>-*-*-*-*-*-<encoding>
<font> はフォントの基本名 (base name) (例: Times, Symbol) <size> はポイントサイズ (指定がなければデフォルトは 12) <s> は <slant>=="italic" なら `i`, <slant>=="oblique" なら `o`, その他は `r` <weight> は明示的に指定されれば `medium` か `bold`、その他は `*` <encoding> は現在の文字集合に基づいて設定 (以下参照: `set encoding`)
gnuplot*encoding: iso8859-15
あなたの gnuplot が configure の -enable-x11-mbfonts オプションをつけ てインストールされたものなら、フォント名の前に "mbfont:" をつけるこ とでマルチバイトフォントを指定することができます。フォント名を複数指定 する個ともできますが、その場合はセミコロンで区切ります。マルチバイトフ ォントのエンコーディングは locale の設定に従いますので、環境変数 LC_CTYPE を適切な値 (例えば ja_JP.eucJP, ko_KR.EUC, zh_CN.EUC など) に に設定する必要があります。
例:
set term x11 font 'mbfont:kana14;k14'
# 'kana14' と 'k14' は日本語の X11 font エイリアス名、';'
# はフォント名の区切りです。
set term x11 font 'mbfont:fixed,16,r,medium'
# <font>,<size>,<slant>,<weight> 形式も使用できます。
set title '(mb strings)' font 'mbfont:*-fixed-medium-r-normal--14-*'
同じ書式は X のリソースでのデフォルトフォントの設定でも有効です。例:
gnuplot*font: \
mbfont:-misc-fixed-medium-r-normal--14-*-*-*-c-*-jisx0208.1983-0
gnuplot が -enable-x11-mbfonts でインストールされた場合、"mbfont:" をつけなくても 2 つの特別な PostScript フォント名 'Ryumin-Light-*', 'GothicBBB-Medium-*' (標準的な日本語 PS フォント) を使うこともできます。
| `-mono` | カラーディスプレイ上で強制的に白黒描画 |
| `-gray` | グレイスケールまたはカラーディスプレイ上でのグレイスケール描画 |
| (デフォルトではグレイスケールディスプレイは白黒描画を受け付ける) | |
| `-clear` | 新しい描画を表示する前に (瞬間的に) 画面を消去 |
| `-tvtwm` | geometry オプションによる位置の指定を、仮想ルートウィンドウ中の |
| 現在の表示部分に対する相対的な位置にする | |
| `-raise` | 各描画後に描画ウィンドウを最前面へ出す |
| `-noraise` | 各描画後に描画ウィンドウを最前面へ出すことはしない |
| `-persist` | gnuplot プログラム終了後も描画ウィンドウを残す |
例:
gnuplot*gray: on
gnuplot*ctrlq: on
gnuplot は描画スタイル points で描画する点のサイズの制御にも、コマンド ラインオプション (-pointsize < v> ) とリソース (gnuplot*pointsize: < v> ) を提供しています。値 v は点のサイズの拡大率として使われる実数値 (0 < v < = 10) で、例えば -pointsize 2 はデフォルトのサイズの 2 倍、 -pointsize 0.5 は普通のサイズの半分の点が使われます。
-ctrlq スィッチは、描画ウィンドウを閉じるホットキーを q から < ctrl> q に変更します。これは、pause mouse keystroke によるキースト ロークの保存機能を使っている場合には、他のアルファベット文字と同様に q を保存できるようになるので有用でしょう。同じ理由で、-ctrlq スィ ッチは < space> ホットキーも < ctrl> < space> に置き換えます。
| gnuplot*background: white | |
| gnuplot*textColor: black | |
| gnuplot*borderColor: black | |
| gnuplot*axisColor: black | |
| gnuplot*line1Color: red | |
| gnuplot*line2Color: green | |
| gnuplot*line3Color: blue | |
| gnuplot*line4Color: magenta | |
| gnuplot*line5Color: cyan | |
| gnuplot*line6Color: sienna | |
| gnuplot*line7Color: orange | |
| gnuplot*line8Color: coral |
これらに関するコマンドラインの書式は、背景 (bacground) に関しては単純で 通常の X11 toolkit オプションの "-bg" に直接対応します。他のものも、 全て一般的なリソースの上書きオプション "-xrm" を使うことで設定できま す。
例:
背景色を変更するには
gnuplot -background coral
線種 1 番目の色を書き換えるには
gnuplot -xrm 'gnuplot*line1Color:blue'
| gnuplot*background: black | |
| gnuplot*textGray: white | |
| gnuplot*borderGray: gray50 | |
| gnuplot*axisGray: gray50 | |
| gnuplot*line1Gray: gray100 | |
| gnuplot*line2Gray: gray60 | |
| gnuplot*line3Gray: gray80 | |
| gnuplot*line4Gray: gray40 | |
| gnuplot*line5Gray: gray90 | |
| gnuplot*line6Gray: gray50 | |
| gnuplot*line7Gray: gray70 | |
| gnuplot*line8Gray: gray30 |
| gnuplot*borderWidth: 1 | |
| gnuplot*axisWidth: 0 | |
| gnuplot*line1Width: 0 | |
| gnuplot*line2Width: 0 | |
| gnuplot*line3Width: 0 | |
| gnuplot*line4Width: 0 | |
| gnuplot*line5Width: 0 | |
| gnuplot*line6Width: 0 | |
| gnuplot*line7Width: 0 | |
| gnuplot*line8Width: 0 |
gnuplot は線描画で使用する点線の形式の設定用に以下のリソースを参照します。0 は実線を意味します。2 桁の 10 進数 jk (j と k は 1 から 9 までの値) は、j 個のピクセルの描画に k 個の空白のピクセルが続く パターンの繰り返しからなる点線を意味します。例えば '16' は 1 個のピク セルの後に 6 つの空白が続くパターンの点線になります。さらに、4 桁の 10 進数でより詳細なピクセルと空白の列のパターンを指定できます。例えば、 '4441' は 4 つのピクセル、4 つの空白、4 つのピクセル、1 つの空白のパタ ーンを意味します。以下のデフォルトのリソース値は、白黒ディスプレイ、あるいはカラーや白黒階調 (grayscale) ディスプレイ上の白黒描画における値 です。 カラーディスプレイでは dashed:off がデフォルトになっています。
| gnuplot*dashed: off | |
| gnuplot*borderDashes: 0 | |
| gnuplot*axisDashes: 16 | |
| gnuplot*line1Dashes: 0 | |
| gnuplot*line2Dashes: 42 | |
| gnuplot*line3Dashes: 13 | |
| gnuplot*line4Dashes: 44 | |
| gnuplot*line5Dashes: 15 | |
| gnuplot*line6Dashes: 4441 | |
| gnuplot*line7Dashes: 42 | |
| gnuplot*line8Dashes: 13 |
デフォルトでは gnuplot はそのスクリーンのデフォルトの visual を使用 します。割り当てることのできる色数は選択された visual クラスによって変 わります。12bit を超える深度を持つ visual クラス上では、gnuplot は最大 色数である 0x200 (=512) 色で起動します。8bit を超える (12bit 以下で) 深度の visual クラスでは最大色数は 0x100 (=256) 色、8bit 以下のディスプレイでは最大色は 240 (16 色は曲線の色用に取られる) になります。
gnuplot は最初に、上に述べたような最大色を割り当てようと起動します。こ れに失敗するとその色数は、gnuplot がその全部を割り付けることができるま で、1/2 ずつ減らされます。maxcolors を繰り返し 2 で割った結果、 mincolors よりも小さい数字になった場合、gnuplot は private カラー マップを使おうとします。この場合、ウィンドウマネージャは、ポインタが X11 ドライバのウィンドウに入るか出るかでカラーマップを退避 (swapping) させる責任を持つことになります。
mincolors のデフォルトの値は maxcolors / (num_colormaps > 1 ? 2 : 8) で、num_colormaps は gnuplot が現在使用しているカラーマップの数で、こ れは、x11 のウィンドウが 1 つだけ開いているような通常の場合は 1 です。
複数の (異なる) visual クラスを、一つのスクリーン上でサポートするよう なシステムもあります。このようなシステムでは、gnuplot に指定した visual クラスを強制的に使わせる必要があります。例えば、デフォルトの visual が 8bit PseudoColor だけれどもスクリーンは 24bit TrueColor を サポートしていてむしろこちらの方を選択すべきであるような場合です。
X サーバの能力に関する情報はプログラム xdpyinfo で取得できます。 visual 名は次のうちの一つが選択できます: StaticGray, GrayScale, StaticColor, PseudoColor, TrueColor, DirectColor。その X サーバが要求 された visual 型の異なる複数の深度をサポートしている場合、gnuplot は 最も大きい (最深の) 深度の visual クラスを選択します。要求された visual クラスがデフォルトの visual とあっていて、その型の複数のクラス がサポートされている場合は、デフォルトの visual が選択されます。
例: 8bit PseudoColor の visual 上では、gnuplot*maxcolors: 240、及び gnuplot*mincolors: 240 と指定することで強制的に private カラーマップ を使うようにできます。
| gnuplot*maxcolors: 整数 | |
| gnuplot*mincolors: 整数 | |
| gnuplot*visual: visual 名 |
デフォルトでは、文字の回転は速くそれを行なう方法が使われますが、背景色 によってはその付近が汚れることがあります。これが起こる場合は、リソース 'gnuplot.fastrotate' を 'off' にしてみてください。
| gnuplot*exportselection: off | |
| gnuplot*fastrotate: on | |
| gnuplot*ctrlq: off |
浮動小数計算例外 (浮動小数値が大きすぎる (または小さすぎる) 場合、0 で 割算した場合など) は、ユーザ定義関数において発生することがあります。特 に、いくつかのデモで、浮動小数の範囲を越える数値を生成することが起こる ようです。システムがそのような例外を無視する (gnuplot はそのような点 を定義できないもの、と見なします) か、または gnuplot の実行を中止す るかは、コンパイル時 (あるいは実行時) の環境によります。
ガンマ関数とベッセル関数は複素数引数をサポートしていません。
"時刻" として指定された座標は 24 時で折り返します。
媒介変数の曲線: nohidden3d は、全体的な設定である set hidden3d を 個々のグラフに対して免除するためのオプションですが、これは媒介変数の曲 線 (parametric) に対しては機能しません。 コマンド plot 内の繰り返し (iteration) は、媒介変数の曲線に対しては 機能しません。
X11 出力形式: UTF-8 フォントの選択が困難です。 すべての x11 描画ウィンドウに対して、一度には 1 つのカラーパレットのみ が有効です。これは、異なるパレットを使用する描画を含んだ multiplot で は x11 上では正しく表示されないことを意味します。
Qt 出力形式: 3 次元での多角形や曲面の回転はかなり遅くなる可能性があり ますが、これは Qt のレンダリングモード (Qt の説明書を参照してください) に強く依存します。
外部ライブラリ PDFlib (PDF ドライバで使用): gnuplot は libpdf のバージョン 4, 5, 6 のいずれかをリンクできます。し かし、これらはバージョンによってパイプされた入出力の処理が違っています ので、パイプを使って PDF を出力する gnuplot スクリプトは、PDFlib のあ るバージョンでだけしかちゃんと動かないかもしれません。
外部ライブラリ svgalib (linux, vgadl ドライバで使用): これは gnuplot が root に setuid (嫌!) されることを要求しますし、ビデ オカードや X11 で使用されるグラフィックドライバに特有の多くのバグがあ ります。
国際化 (ロケールの設定): gnuplot は、入出力の数、時刻、日付文字列のロケールに依存した書式の制御 を、C ランタイムライブラリに含まれる setlocale() を用いて行うので、ロ ケールの有効性や、ロケール機能のサポートのレベル (例えば数字の 3 桁毎 の区切り文字など) などは、あなたのコンピュータが提供する国際化のサポー トの度合いに依存します。
この文書はLaTeX2HTML 翻訳プログラム Version 2008 (1.71)
Copyright © 1993, 1994, 1995, 1996,
Nikos Drakos,
Computer Based Learning Unit, University of Leeds,
Copyright © 1997, 1998, 1999,
Ross Moore,
Mathematics Department, Macquarie University, Sydney.
を日本語化したもの( 2008 (1.71) JA patch-2.1beta1.14 版)
Copyright © 1998, 1999,
Kenshi Muto,
Debian Project.
Copyright © 2001-2011,
Shige TAKENO,
Niigata Inst.Tech.
を用いて生成されました。
コマンド行は以下の通りでした。:
latex2html -image_type gif -split 0 -show_section_numbers -dir gnuplot-ja -html_version 4.0,math -nonavigation gnuplot-ja-ref.tex.
翻訳は 竹野茂治 によって 2016年7月29日 に実行されました。