17 線種、色、スタイル (linetypes)

gnuplot の各出力形式は "線種 (linetype)" をある程度用意しています。そ れらは色、太さ、点線/破線のパターン、または色と点線/破線の組合せで違い を表現しています。特定の出力形式のデフォルトの線種は、その出力形式を設 定した (set terminal) 後で test コマンドを発行することで確認できま す。定義されている色、点線/破線のパターンはすべての出力形式で同じもの であるという保証は何もありませんが、線種 -1 は特別に全ての出力形式で、 最も普通の表示色 (通常は黒) の実線を意味しています。また、多くの出力形 式で、背景色での実線を意味する特別な線種 "bgnd" も認識します。

デフォルトの線種 (linetype) の属性は、対話的か初期化ファイルのいずれか によって再定義可能です。これは、すべての gnuplot 描画コマンドで使用さ れる線の色や他の属性をカスタマイズすることを可能にします。以下参照:set linetype (81.32)。

デフォルトでは、一つの描画コマンド内での関数やデータファイルの並びには、 順番に線種が割り当てられます。そのデフォルトの順列は、関数、データファ イル、またはその他の描画要素に個別に線種を指定することで上書きできます。

例:

    plot "foo", "bar"                 # 線種 1, 2 で 2 ファイルを描画
    plot sin(x) linetype 4            # 出力形式に依存する線種色 4
    plot sin(x) lt -1                 # 黒

多くの出力形式で、ユーザ定義色を定義できるようになっています。色の定義 は明示的な rgb (赤、緑、青) を指定するか、色名か、現在の pm3d パレット を参照する色の値のいずれかで行ないます。

例:

    plot sin(x) lt rgb "violet"       # gnuplot の持つ色名の一つ
    plot sin(x) lt rgb "#FF00FF"      # 明示的な 16 進 RGB 3 つ組
    plot sin(x) lt palette cb -45     # 現在のパレットの cbrange の
                                      # -45 に対応する色
    plot sin(x) lt palette frac 0.3   # パレットに対応する小数値

以下参照: show colornames (81.13), set palette (81.54), cbrange (81.126)。

点線/破線のパターンをサポートする出力形式では、デフォルトの線種は点線/ 破線のパターンと色の両方が定義されています。今の所 gnuplot には、点線/ 破線パターンを変更する仕組みがないので、特定の点線パターンと特定の色を 組み合わせたい場合は、先にその点線パターンを持つ線種 (linetype) を選択 し、デフォルトの色をキーワード linecolor (省略形は lc) で上書きす る必要があります。例えば、postscript 出力形式のデフォルトの線種 3 は青 の破線です。以下の描画コマンドは同じ破線パターンで 3 つの描画を行ないますが、一つは青 (デフォルト)、一つは赤 (線種 1 のデフォルト色)、もう 一つは金色になります。

例:

    set term postscript dashed color
    plot 'foo' lt 3, 'baz' lt 3 linecolor 1, 'bar' lt 3 lc rgb 'gold'