16 線種、色、スタイル (linetype)

gnuplot の各出力形式は "線種 (linetype)" をある程度用意しています。そ れらは色、太さ、点線/破線のパターン、または色と点線/破線の組合せで違い を表現しています。特定の出力形式のデフォルトの線種は、その出力形式を設 定した (set terminal) 後で test コマンドを発行することで確認できま す。定義されている色、点線/破線のパターンはすべての出力形式で同じもの であるという保証は何もありませんが、線種 -1 は特別に全ての出力形式で、 最も普通の表示色 (通常は黒) の実線を意味しています。デフォルトでは、一 つの描画コマンド内での関数やデータファイルの並びには、順番に線種が割り 当てられます。そのデフォルトは、関数、データファイル、またはその他の描 画要素に個別に線種を指定することで上書きできます。

例:


    plot "foo", "bar"                 # 線種 1, 2 で 2 ファイルを描画
    plot sin(x) linetype 4            # 出力形式に依存する線種色 4
    plot sin(x) lt -1                 # 黒

多くの出力形式で、ユーザ定義色を定義できるようになっています。色の定義 は明示的な rgb (赤、緑、青) を指定するか、色名か、現在の PM3D パレット を参照する色の値のいずれかで行ないます。

例:


    plot sin(x) lt rgb "violet"       # gnuplot の持つ色名の一つ
    plot sin(x) lt rgb "#FF00FF"      # 明示的な 16 進 RGB 3 つ組
    plot sin(x) lt palette cb -45     # 現在のパレットの cbrange の
                                      # -45 に対応する色
    plot sin(x) lt palette frac 0.3   # パレットに対応する小数値

以下参照: show colornames (p. [*]), set palette (p. [*]), cbrange (p. [*])

点線/破線のパターンをサポートする出力形式では、デフォルトの線種は点線/ 破線のパターンと色の両方が定義されています。しかし、デフォルトの色は、 キーワード linecolor (省略形は lc) を使うことで上書きできます。例 えば、postscript 出力形式のデフォルトの線種 3 は青の破線です。以下の描画コマンドは同じ破線パターンで 3 つの描画を行ないますが、一つは青 (デフォルト)、一つは赤 (線種 1 のデフォルト色)、もう一つは金色になります。

例:


    set term postscript dashed color
    plot 'foo' lt 3, 'baz' lt 3 linecolor 1, 'bar' lt 3 lc rgb 'gold'

線は、線幅のような他の属性も持つことができます。点 (point) の記号に対 する同様の属性とともに、これらの属性をコマンド set style line を使っ てユーザ定義 "ラインスタイル (linestyle)" として結びつけることができま す。一度定義された linestyle は、plot コマンド中で、一つまたは多くの描 画要素に対してその表示を制御するのに使うことができます。

例:


    # 新しいラインスタイルを、出力形式に依存しない色 cyan、線幅が 3、
    # 点種 6 (丸の中に点) と定義
    set style line 5 lt rgb "cyan" lw 3 pt 6
    plot sin(x) with linespoints ls 5          # 定義スタイル 5 で

以下参照: linestyle (p. [*]), set style line (p. [*])


Subsections
竹野茂治@新潟工科大学
2010年9月13日