05/29 頃に gnuplot-5.2.7 が公開されました。 5.2.7 での新規機能、変更、修正は以下のようです。
- 変更: GPVAL_TERM_HCHAR GPVAL_TERM_VCHAR の可視化 (フォント向けデバック用)
- 変更: ylabel の位置 (5.2.7 以前のものへの譲歩) (Bug #2181)
- 変更: strstrt() を UTF8 用に、 例: strstrt(&quto;αβγ5", "5") は 4 になる
- 修正: "save" からの "set timestamp" が位置揃えを含まない問題 (Bug #2178)
- 修正: 対数軸 z の set cntrparam levels increment <base>, <factor> (Bug #2183)
- 修正: 文字による点種が、通常の点種同様に plot の色付けを継承するように
- 修正: link された y2 軸の自動縮尺の不具合 (Bug #2186)
- 修正: 非データ plot コマンドの非有界な繰り返しの無限ループを避ける
- 修正: "stats matrix every" が報告するサイズ (dimension) の問題 (Bug #2189)
- 修正: boxplot のひげの幅が 1 ポイントミスの可能性 (Bug #2106)
- 修正: 一つの plot コマンドで非有界な繰り返しと関数の混在 (Bug #2201)
- 修正: 組み込み readline での履歴の逆検索 (Bug #2209)
- 修正: qt: ysize の 1 ミスの抑制 (Bug #1759)
- 修正: cairo: ysize の 1 ミスの抑制 (Bug #1759)
- 修正: gd: brushstroke による線に alpha を適用 (Bug #2117)
- 修正: tikz: lua 5.3 と新しい pgf 用への対応
- 修正: wxt: persist モードで ExportToFile ウィジェットを無効に (Bug #2185)
- 修正: qt: キーイベントでの修飾キー (ctrl alt shift) の処理
- 修正: wxt: キーイベントでの修飾キー (ctrl alt shift) の処理
- 修正: fig: 点線種の "solid" が transfig に正しく通らなかった問題
- 修正: gd: 複数行のラベルの不正な行間 (Bug #2215)
修正と変更のみで、大きな仕様変更はありません。 この 5.2.8 が 5.2 系列の最終版で、次はいよいよ 5.4 がでるようですが、 それは来年春位になるようです。
最近、開発版の gnuplot に、set pixmap というものが導入されました。 これは、set object rect と同様に、 PNG/GIF/JPEG の画像を取り込んで、 描画要素の一つとしてグラフに描画するものです。 ドキュメントにも例が書かれていますが、 例えばグラフの背景 (behind) を特定の画像にできます。 背景をグラデーションにしたり、 グラフの特定の場所に画像のロゴを入れたりしたい場合には有用でしょう。
サンプルを一つ紹介します。 犬の写真画像 (jpeg ファイル) を背景 (behind layer) に キャンバス一杯の大きさに貼って、 その上に plot グラフを書きます。
set term pngcairo
set out 'test-pixmap-1.png'
set pixmap 1 'dog.jpg' at screen 0, 0 size screen 1, 1 behind
plot sin(x) w l lw 2
set out
- 上のコマンドによる PNG 画像:
at が画像の左下角の座標の指定、size がサイズ指定です。
ただ、これだとさすがにグラフが見えにくいので、 背景の上 (back) に透明化を使用した薄い白を重ねて書いてみます。
set term pngcairo
set out 'test-pixmap-2.png'
set pixmap 1 'dog.jpg' at screen 0, 0 size screen 1, 1 behind
set object rect from screen 0,0 to screen 1,1 back fc rgb '#60ffffff'
set tics front
plot sin(x) w l lw 2
set out
- 上のコマンドによる PNG 画像:
fillcolor の rgb 指定で 8 桁の 16 進数を指定すると、 最初の 2 桁は alpha 値とみなされるので、 それで透過レベルを調整できます (ffffff は白)。
なお、本来なら set object rect も behind の layer に書いて重ねたいところですが、 それだとどうもうまくいかず、画像の方のみが書かれてしまうようです。 よって set object rect は behind と front の間の back の layer に書いています。
しかしそれだと、back の layer に書かれる軸の刻みやラベルも、 その set object rect に隠されてしまってぼやけてしまいます。 そのため、「set tics front」で tics の layer を front に上げています。
もちろん、いざとなれば multiplot による重ね書き、 という解決法もあります。
set term pngcairo
set out 'test-pixmap-3.png'
set multiplot
set xrange [-10:10]
set yrange [-1:1]
set pixmap 1 'dog.jpg' at screen 0, 0 size screen 1, 1 behind
plot 1/0 # 空書き
set object rect from screen 0,0 to screen 1,1 behind fc rgb '#60ffffff'
plot sin(x) w l lw 2
unset multiplot
set out
- 上のコマンドによる PNG 画像:
結果は前のものとほぼ同じになります。 これなら、xtics の layer を変更する心配はありませんが、 tics がずれないように、空書きの際に range を固定したりするのが 少し面倒かもしれません。 また、上の例がそうなっていますが、 range を指定することで、tics の刻み間隔が、 自動設定の場合とやや変わってしまうこともあります。
gnuplot でヒストグラムのようなグラフを書こうとして、 2 点ほど気がついたことがありますので、ここに書きとめておきます。
- bins と boxwidth
今の gnuplot の
plotコマンドにはbinsというオプションがあり、 それによりデータから自動的に度数分布を作成して グラフにすることができます。例えば、
のようにすれば、 2 列目のデータから階級幅を 10 にした棒グラフが書かれます。 ただし、「plot 'data' using 2 bins binrange [0:100] binwidth=10 with boxesbinrange [0:100] binwidth=10」の場合は 階級値は「0 以上 10 未満」から始まるのではなく 「-5 以上 5 未満」から始まり、 それが x = 0 の場所に箱が書かれます。 最初を「0 以上 10 未満」にするには、 「binrange [5:95] binwidth=10」とすればいいのですが、 その場合その箱は x=5 の場所に書かれます。さて、通常
with boxesの箱のサイズは、 隣合う箱が隣接するサイズになるのですが、 それは「set boxwidth」で幅を狭くすることができます。 しかし、binsを使用した場合、どうもset boxwidthが効かないようで、 それを指定しても幅が変わりません。もしかしたらバグかもしれません。 時間のあるときに調べてみたいと思います。
- smooth frequency と未定義値データ
bins を実現する方法として、demo にもありますが、
smooth frequencyを利用する方法もあります。 例えば、
のような具合です。 こちらではbinwidth = 10
set boxwidth binwidth*0.8
bin(val) = binwidth * floor(val/binwidth)
plot 'data' using (bin($2)) smooth frequency with boxesboxwidthも効きますので、幅を狭くして、 x 座標を少しずらして、cluster 型の histogram 相当のものを書くこともできます。さて、実はこの cluster 型の histogram を、 1 つのデータの 2 列目のデータから作成したのですが、 その際 1 列目の値によって分類して、 複数のデータのように見て作成しました (実は元々の目標はこれ)。 例えば、必要なデータを 1 列目のデータ (整数値) を 3 で割った値で分類して、
のようにやってみたのですが、どうもうまくいきません。 問題は、1/0 で不要なデータを未定義値にしていることにあるようで、 smooth frequency でのデータの累積が、 1/0 の計算が起きたときにクリアされてしまうようです。 よって、1/0 の代わりに明らかにグラフの範囲外であるような大きな値 (例えば 10000) などに変えてやることでとりあえずはうまくいきました。binwidth = 10
set boxwidth binwidth*0.2
bin(val) = binwidth * floor(val/binwidth)
idata(n) = (int($1)%3 == n) ? $1 : 1/0
plot for [j=0:2] 'data' using (bin(idata(j))+3*j) smooth frequency with boxes累積の値がクリアされてしまうのは、仕様かもしれませんし、 もしかしたらバグかもしれません。 時間のあるときに調べてみたいと思います。
最新の開発版 (git) の all.dem の出力を置いておきます。
- all.dem の PDF 出力 (2019-08-05 の GIT 版)
all-current-20190805.pdf (774 ページ、17,916,060 Byte)
06/27 のものよりも 20 ページほど増えていますが、demo として
bins.dem, orbits.dem, spiderplot.dem, bolditalic.dem, unicode.dem, columnhead.dem, clip_radial.dem, linked_autoscale.dem(大半は既に demo/ 内にはあったもの) が all.dem に追加されたためです。
最近の改良・追加には以下のようなものがあります (全部は網羅していません)。
- spiderplot (クモの巣グラフ、レーダーチャート) の描画スタイルが新規導入
- strstr() 等の UTF-8 対応
- columnstacked histogram と spiderplot のタイトルを 1 列目から取るように
- tikz terminal に butt オプションを追加
spiderplot は、いわゆるレーダーチャートを書くための描画モードです。 ここでも過去に何度かレーダーチャートを書くサンプルを紹介しました (例えば 「情報やメモ (06/07 2017)」)。
今回の spiderplot は、 極座標モードでの parallelaxis のような形で実装されたようで、 設定の変更も paxis などで行えます。デモは以下にあります。
- gnuplot 5.3 (開発版) の spiderplot.dem
http://gnuplot.sourceforge.net/demo_5.3/spiderplot.html
まだ若干実行のための書式などが不自然な感じがしますが、 今後徐々に洗練されていくのではないかと思います。
(cf. 「情報やメモ (01/21 2020)」)
以前テレビで、「フラッシュ暗算」なるものが紹介されていました。 モニタ画面にランダムのような数字が何分の 1 秒毎に表示され、 それを暗算で加算する、というものです。 慣れないと、そして暗算能力がないと、2 桁でもだいぶ難しそうでしたが、 その能力のある子供は平気で 3,4 桁の暗算をこなしていました。
乱数を発生させたり、画面表示したり、それを短い時間で切り替えたり、 合計を計算させることなら今の gnuplot にもできそうなので、 簡単なものを作ってみました。もちろん本来のグラフ表示とは全く異なります。 以下がそのスクリプトです。
# keta = 計算される数の最大数 + 1
# num = 計算される数の個数
# flushtime = 各数字のおよその表示時間 (秒)
keta = 1000
keta = 100000
keta = 10000000
num = 10
flushtime = 0.8
flushtime = 0.3
set term wxt size 1000,400
# fname = 表示フォント、size1 = 計算される数字のフォントサイズ、
# size2 = 答のフォントサイズ
fname = "IPAMincho"
size1 = "120"
size2 = "75"
unset tics
unset key
set xrange [0:1]
set yrange [0:1]
#ntos(x) = sprintf("%d", x)
# 上は単に数字を表示、下は 3 桁ずつのカンマ付き数字に変換 (9 桁まで対応)
ntos(x) = (x >= 1000000) ?
sprintf("%d,%03d,%03d", int(x/1000000),
int(x/1000)%1000, x%1000) : \
(x >= 10000) ? sprintf("%d,%03d",
int(x/1000), x%1000) : \
sprintf("%d", x)
# 起動画面の表示
ss = sprintf("To start, please mouse click
((flush,num)=(%.2f,%d))", flushtime, num)
set label 3 ss at 0.1, 0.5 font fname.".20"
left front textcolor black
plot 1/0 # ダミーのプロット
unset label 3
# 全体の背景 (黒)
set object 1 rect from 0,0 to 1,1 back fc black fs solid
pause mouse
# 開始
x = rand(time(0)) # 乱数の種を初期化
total = 0
# 各数字の表示
do for [i=1:num] {
x = int(rand(0)*(keta - 1) + 1)
total = total + x
# 左上に何個目かを表示
set label 1 sprintf("%d", i) at 0.1, 0.9
font fname.",14" right front
textcolor rgb "yellow"
# 計算する数字を表示
set label 2 ntos(x) at 0.9, 0.5
font fname.",".size1 right front
textcolor rgb "white"
plot 1/0
pause flushtime
}
# 一旦数字を全部消す
unset label
plot 1/0
pause 3
# 時間を置いて答を表示
set label 2 "A.".ntos(total) at 0.9, 0.5
font fname.",".size2 right front
textcolor rgb "white"
plot 1/0
pause mouse
- 上の gnuplot スクリプト: flush1.gp (1641 Byte)
背景は set object で、画面の文字や数字の表示は いずれも set label で行っています。 画面表示は plot のタイミングで行われますが、 1/0 のダミーの表示にしています。
数字の桁を決める keta, 数字の個数 num、表示時間 flushtime を変更することで難易度も変わります。 フォント fname や size1, size2、および wxt terminal のサイズも、 keta によって適当に選択してやる必要があります。
乱数 rand() は、(0:1) の実数値を返すので、 それをほぼ keta 倍して整数化しています。 実際には (keta - 1) 倍して + 1 していますが、 これは 0 を排除するためです。 また、rand(time(0)) で一度種を初期化していますが、 そうしないと毎回同じ乱数列になってしまいます。
実は label 2 の数字は、
最初は単に sprint("%d", x)
で表示させていましたが、
そろばんでは通常 3 桁毎に , で区切った整数表示を使います。
sprintf() ではそれは簡単にはできませんので、
それに対応した文字列を作成する ntos(x) を使っていますが、
9 桁を越える場合は修正が必要です (6 桁までなら少し簡単にできます)。
動画は置きませんが、だいたい動作の様子は想像できると思います。 ちなみに flushtime = 0.3, num = 10 だと、 私は 1 桁 (keta = 10) でもまともに暗算できませんでした。
最新の開発版 (git) の all.dem の出力を置いておきます。
- all.dem の PDF 出力 (2019-06-27 の GIT 版)
all-current-20190627.pdf (754 ページ、17,752,109 Byte)
最近の改良・追加には以下のようなものがあります (全部は網羅していません)。
- pm3d 曲面で上下の fillcolor を個別に持てるように
- smooth zsort (3 列目の値で 2 次元の点をソートして上に出せるように)
- set datafile columnheaders で 1 行目を columnheader 専用に (確実に)
- latex, emtex, tpic, eepic terminal がデフォルトで ビルドされないようになり、代わりに pict2e terminal が追加 (LaTeX2e の pict2e パッケージを使用)
- texdraw terminal の現在の gnuplot の機能に合わせた大幅な改良
- 点種として UTF-8 文字を "U+XXXX" のように指定できるように
- stats 変数の STATS_column_header として先頭行の文字列を保持する配列が追加
- stats 変数の接頭辞も columnheader で取れるように
なお、latex, emtex, tpic, eepic を有効化したい場合、
configure オプションなどは今のところ用意されておらず、
src/term.h でそれらの .trm の読み込みが 「#if 0」「#endif」
で囲まれているところの 0 を 1 に変えてやるしかありません。
なんとなくですが、
これらの .trm ドライバを近々完全に捨てるような扱いのように感じます。
最近、今の gnuplot (5.2.7) で各列が [学籍番号]、[テスト 1 回目]、 [テスト 2 回目] のようなデータからグラフを pt variable で描いてみて、 気がついたことがありましたので、少し書いておきます。 その手の例は、 「情報やメモ (05/10 2016)」 でも紹介していますが、 そこでとりあげなかった key の話も含め、以下で紹介します。
まず、最初に書いたグラフは次のようなものです。
データは単に w p で point にした散布図で、 回帰直線は stats を使って回帰直線の係数を取得して書いています:
stats "dataf" using 2:3 nooutput
plot "dataf" using 2:3 w p not,\
STATS_slope*x + STATS_intercept w l lw 2 t "回帰直線"
単純にそれを行うには、awk などで前処理して、データをクラス別に分けて、
stats "dataf" using 2:3 nooutput
plot "dataf-a" using 2:3: w p t "A クラス",\
"dataf-b" using 2:3 w p t "B クラス",\
"dataf-c" using 2:3 w p t "C クラス",\
STATS_slope*x + STATS_intercept w l lw 2 t "回帰直線"
plot "dataf" using 2:3:(column(1)%3+1) w p pt variable
まず、「column(1)%3」がうまくいきませんでした。 「non-integer operand for %」と怒られてしまい、 つまり、column(1) が整数と認識されていないようなのですが、 小数点のない値でも、入力データ列の値はどうやら整数とは見ずに、 すべて実数と認識しているようです。 昔からそうだったかどうかはわかりませんが、これは、int() を使って
plot "dataf" using 2:3:(int(column(1))%3+1) w p pt var
次は記号の色です。 上のままだとクラス毎に記号は変わるのですが、 すべての記号が同じ色で表示されてしまいます (下の図)。
色を変えるためには、色も lc variable で変更し、 その値も追加列として指定する必要があります。 追加列は、マニュアルによれば、pointsize, pointtype, linecolor の順に解釈されることになっていますが、ps var を指定しなければ、 追加列は pointtype と linecolor の順に使用されます:
plot "dataf" using 2:3:(j=int(column(1))%3+1):(j)
w p pt var lc var
次は key です。 pt variable だと、key に異なる点記号の説明を出力できませんが、 それは今の gnuplot なら自前で「keyentry」で作ることができます (gnuplot-5.2.6 以降):
plot "dataf" using 2:3:(j=int(column(1))%3+1):(j)
w p pt var lc var,\
keyentry w p pt 1 lc 1 t "A クラス",\
keyentry w p pt 2 lc 2 t "B クラス",\
keyentry w p pt 3 lc 3 t "C クラス"
ただ、こちらの方がいいか、易しいかというと微妙な気もしますし、 パイプ入力を使えば、事前にファイルを分けなくても、
plot "<awk '$1%3==0' dataf" using 2:3 w p
t "A クラス",\
"<awk '$1%3==1' dataf" using 2:3 w p
t "B クラス",\
"<awk '$1%3==2' dataf" using 2:3 w p
t "C クラス"
05/29 頃に gnuplot-5.2.7 が公開されました。 5.2.7 での新規機能、変更、修正は以下のようです。
- 新規: "set pm3d nolipcb" は cbmin より小さい色の四辺形の描画をスキップ
- 新規: pm 出力形式で utf8, 破線、ボールド、イタリック文字列をサポート
- 新規: 配列値の虚数部分を "using" で 3 列目として使えるように
- 新規: 遅いシステムフォントサーバでの qt 出力形式用に gnuplot --slow
- 変更: splot "with points pt 0" が "with dots" 同様になるように
- 変更: (tikz) gnuplot の矢先スタイルのデフォルトの実装の改良
- 変更: hidden3d で双頭のベクトル (arrowstyle "heads") を処理するできるよう
- 変更: "unset title" や "reset" でタイトル属性をすべてデフォルトに
- 変更: 拡張文字列処理に渡すフォント名を引用符に入れれるように
- 変更: cairo 出力形式で非整数のフォントサイズ指定を可能に
- 変更: "plot with table" が引き続くフィールド分離子を出力しないよう
- 変更: 積み上げ型ヒストグラムの中央揃えの改良
- 変更: 解析の実行前に STATS_* 変数をクリア
- 変更: cairo, libgd, svg 出力形式で LT_NODRAW を何も描かないように処理
- 変更: svg 出力形式のクリック用アイコンを外部参照でなくインラインデータに
- 変更: ylabel 用のスペースの改善と位置揃えを可能に
- 変更: 10^6 ものハイパーテキストラベルを持てるようオーバーヘッドの削減
- 変更: とても多くの fig 出力形式の改善
- 修正: "plot with table" の文字列出力の 60 文字への不必要な制限
- 修正: (windows) gnuplot が隠れていてもグラフウィンドウが見えるように
- 修正: hidden3d モードが arrowstyle backhead を正しく処理していなかった問題
- 修正: using 内での sprintf は数値ロケールを必ず壊さない
- 修正: tikz - 頂点 0 の多角形を要求するとドライバがハングしていた
- 修正: lua/tikz - stdout へのパイプ出力の際に ftruncate しようとしてなかった
- 修正: tkcanvas - stdout へのパイプ出力の際に ftruncate しようとしてなかった
- 修正: "stats FOO matrix" への入力列の NaN 値の処理
- 修正: matrix データを保持するデータブロックの最後に追加入力を通さないよう
- 修正: pm - 箱と多角形の塗り潰し、広い線、拡張文字列処理、画像等の問題
- 修正: 描画ウィンドウを手動で閉じた際にパイプ入力の文字列が落ちる問題
- 修正: 等高線ラベル付きの splot での無関係のドットと内在的な segfault の問題
- 修正: boxplots - 指定した線種で正しく色列が開始するように
- 修正: "gnuplot -c foo.gp baz" で不正な初期化が segfault を引き起こす問題
- 修正: "pm3d depthorder base" で対数軸の z で 3D の箱の処理を可能に
新規機能も少し入りましたが、 だいぶ開発版の 5.3 が持っていて 5.2.X にない機能がたまってきました。 そろそろ次は 5.4 でしょうか。
今さらですが、以下のことに気がつきました。
gnuplot-5.0 より 「set linetype cycle [n]」というものが導入されていて、 これは線種をいくつの番号で折り返すか、ということを指定します。 デフォルトではこれが 8 になっていて、 よって lt として明示的に 8 より大きい値をしても そのままでは効かないようです (例えば post terminal など)。
この 8 での折り返しを解除するには 「unset linetype cycle」か「set linetype cycle 0」とするようですが、 「set colorsequence」を指定する場合はその影響も受けます。 「set colorsequence default」「set colorsequence podo」の場合は、 「set linetype cycle 8」を指定したことになり、 「set colorsequence classic」の場合は 「set linetype cycle 0」を指定したことになるようです。
post terminal のように大きい番号の点種、線種を必要とする場合は 注意が必要です (私もやってしまいました)。
最近の改良・追加には以下のようなものがあります (全部は網羅していません)。
- faq.tex の大幅な改良
- 複素数値配列の using 使用に関する改変
- ylabel に関するスペースの改良
- hypertext に関する改良 (font 等)
- pm, texdraw, fig terminal ドライバの改良
複素数値配列に対しては、その虚数部分は従来は imag(A[1]) のように使用していましたが、 現在は複素数値配列を plot の対象とした場合、 その実数部分を 2 列目、虚数部分を 3 列目として持つような データを指定したことになるようで、 例えば以下の 2 つのコマンドは同等だとマニュアルに書かれています:
plot A using (real(A[$1])) : (imag(A[$1]))
plot A using 2:3
最新の開発版 (git) の all.dem の出力を置いておきます。
- all.dem の PDF 出力 (2019-03-26 の GIT 版)
all-current-20190327.pdf (753 ページ、17,839,889 Byte)
最近の改良・追加には以下のようなものがあります (全部は網羅していません)。
- parallelaxes に関する変更・改良 (上のデモの p655)
- 日時データの表示に timezone 書式 (%z, %Z) の追加 (timedat.dem の最後に画面表示だけ行われている)
- gnuplot のコマンドラインオプション -s の追加 (フォントの初期化をゆっくり待つ)
- pm ドライバの改良 (OS/2 用)
parallelaxis は、軸の数の制限が無くなり、
plot for [col=1:5] $DATA using col with parallelaxes
at で明示的に指定することもできるようになり、
「set style parallelaxes」コマンドも追加されました。
これまで何度か、all.dem を画像化したものを置いていました (例えば 「情報やメモ (11/02 2018)」 )。 以前は GIF アニメーションと PDF ファイルを置いていましたが、 PDF のビューワでも大抵連続して流し表示のようなことができるようなので、 GIF アニメーションはやめて PDF ファイル (pdfcairo terminal 出力) のみを置いておきます。
- all.dem の PDF 出力 (2019-02-26 の GIT 版)
all-current-20190226.pdf (753 ページ、17,976,786 Byte)
特に最後の方に色々新しいデモが追加されています。 p636 にはグラフ上にタイトルをつけるデモ、 p637, 638 はグラフにないキーを自由につけるデモ、 p674 以降は voxel データに関するデモ等です。
なお、うちの Unix 上の xpdf (PDF ビューワ) では、 413 ページあたりから始まる pm3d 画像の 2 次元射影グラフなどに 横線や縦線が表示されたりしているのですが、 MS-Windows 上の Acrobat reader で見たら問題なかったので、 単に xpdf のレンダリング機能の低さの問題のようです。
01/02 頃に gnuplot-5.2.6 が公開されました。 5.2.6 での新規機能、変更、修正は以下のようです。
- 新規: 実際のグラフ無しに key に項目を置くキーワード "keyentry"
- 新規: "set style boxplot medianlinewidth <lw>"
- 変更: 動作しない CIE/XYZ 色空間のサポートを削除
- 変更: strptime が書式 a/A/w/W で読みこんだ内容を無視するように
- 修正: ファズテストで見つけたさまざまなバグやオーバーランの修正
- 修正: x11 出力形式での waitforinput の改良
- 修正: qt 出力形式での waitforinput とドライバを閉じるイベントの改良
- 修正: wxt 出力形式での waitforinput と 単一スレッド新規ウィンドウイベントの改良
- 修正: lua.trm を lua のバージョン 5.3 対応に
- 修正: if/else カッコ内のエラー行の出力に関する修正
- 修正: 年境界のナノ秒単位での時間/日付変換に関するエラー
新規機能はほとんど入っておらず、修正、変更が主ですが、 それもかなり少ないように思います。 5.4 の公開も近そうな気がしますね。