7 全ソースファイル

ここまでの改良も含めた、全ソースファイルを最後に紹介しておきます。

#! /bin/csh -f
# wwwcheck1.csh
# shige 01/16 2008
#
#### 初期設定 ####
set urllistf = ~/wwwcheck/urllist # URL リストファイル
set datad = ~/wwwcheck/data # 取得したファイルの置き場所
set wget = "wget -q -O -"     # wget のコマンドライン
set browser = "w3m -N"     # 最後に立ち上げるブラウザ
#set browser = "firefox"
set browserOn = 0     # ブラウザを立ち上げるかどうか
set myverbose = 0     # 冗長出力をするかどうか

##### コマンドライン解析 ####
foreach option ( $argv )
    switch ( $option )
    case -v:
        set myverbose = 1
        breaksw
    case -q:
        set myverbose = 0
        breaksw
    case -b:
        set browserOn = 1
        breaksw
    case -nb:
        set browserOn = 0
        breaksw
    case -h:
    default:
        echo "csh -f $0 ([option])"
        echo " [option]:"
        echo "     -b : ブラウザを立ち上げる"
        echo "     -nb: ブラウザを立ち上げない (default)"
        echo "     -v : 冗長出力"
        echo "     -q : 画面出力を抑制 (default)"
        echo "     -h : このメッセージ"
        exit
    endsw
end

##### 実行部分 ####
if ( $myverbose ) then
    echo "(browserOn,myverbose) = ($browserOn,$myverbose)"
endif

set j=1
foreach url ( `grep "^#" $urllistf` )
    if ( $myverbose ) then
        echo "[$j] $url ==> $j.html"
    endif
    $wget "$url" > $datad/$j.html
    @ j ++
end

if( $browserOn ) then
    $browser $datad/*.html
endif