Gnuplot: An Interactive Plotting Program

Master Menu

                       GNUPLOT

            An Interactive Plotting Program
             Thomas Williams & Colin Kelley
                Version 5.0 organized by
       Ethan A Merritt with help from many others

   Copyright (C) 1986 - 1993, 1998, 2004   Thomas Williams, Colin Kelley
           Copyright (C) 2004 - 2012  various authors

       Mailing list for comments: gnuplot-info@lists.sourceforge.net
     Mailing list for bug reports: gnuplot-bugs@lists.sourceforge.net

         This manual was originally prepared by Dick Crawford
                   Version 5.0 - March 2014


Major contributors (alphabetic order):

1 gnuplot

1.1 著作権 (Copyright)

    Copyright (C) 1986 - 1993, 1998, 2004, 2007  Thomas Williams, Colin Kelley

Permission to use, copy, and distribute this software and its documentation for any purpose with or without fee is hereby granted, provided that the above copyright notice appear in all copies and that both that copyright notice and this permission notice appear in supporting documentation.

Permission to modify the software is granted, but not the right to distribute the complete modified source code. Modifications are to be distributed as patches to the released version. Permission to distribute binaries produced by compiling modified sources is granted, provided you

  1. distribute the corresponding source modifications from the
   released version in the form of a patch file along with the binaries,
  2. add special version identification to distinguish your version
   in addition to the base release version number,
  3. provide your name and address as the primary contact for the
   support of your modified version, and
  4. retain our contact information in regard to use of the base software.

Permission to distribute the released version of the source code along with corresponding source modifications in the form of a patch file is granted with same provisions 2 through 4 for binary distributions.

This software is provided "as is" without express or implied warranty to the extent permitted by applicable law.

      AUTHORS
              Original Software:
                 Thomas Williams,  Colin Kelley.
              Gnuplot 2.0 additions:
                 Russell Lang, Dave Kotz, John Campbell.
              Gnuplot 3.0 additions:
                 Gershon Elber and many others.
              Gnuplot 4.0 and 5.0 additions:
                 See list of contributors at head of this document.

(以下おおまかな訳; 訳は正しくないかも知れませんので詳しくは上記の原文 を当たってください。訳者は責任を持ちません。)

    Copyright (C) 1986 - 1993, 1998, 2004, 2007  Thomas Williams, Colin Kelley

このソフトウェアとその付属文書の使用、複製、配布の許可は、上記の著作権 (copyright) 表示が、全ての複製物に書かれていること、および著作権表示と この許諾文の両方がその支援文書に書かれていることを条件とした上で、この 文書により保証されます。

このソフトウェアの修正も認められています。しかし、修正を含む全ソースコ ードの配布の権利は認められません。修正はリリース版に対するパッチの形で 配布しなければなりません。修正されたソースをコンパイルして作られたバイ ナリの配布は、以下の条件の元で認められます:

  1. リリース版からのソースの修正部分を、パッチの形でバイナリと共に配
     布すること
  2. ベースとなるリリース版と区別するために、そのバージョン番号に特別
     なバージョン指定子を付加すること
  3. その修正版のサポート用に、あなたの名前とアクセス可能なアドレスと
     を提供すること
  4. ベースとなるソフトウェアの使用に関しては、我々の連絡情報を保持し
     続けること

リリース版のソースコードを、パッチの形でのソースの修正と一緒に配布する ことは、バイナリ配布に関する条項 2 から 4 までの条件の元で許されます。

このソフトウェアは "あるがまま" 提供され、適用可能な法律で許められる範 囲の保証を表明あるいは暗示していはいません。

      著者
              オリジナルソフトウェア:
                 Thomas Williams,  Colin Kelley.
              Gnuplot 2.0 追加:
                 Russell Lang, Dave Kotz, John Campbell.
              Gnuplot 3.0 追加:
                 Gershon Elber とその他の人々。
              Gnuplot 4.0, 5.0 追加:
                 この文書の先頭の寄与者 (contributors) の一覧参照。

1.2 はじめに (Introduction)

‘gnuplot‘ は、ポータブルなコマンド入力方式のグラフユーティリティで、 Linux, OS/2, MS Windows, OSX, VMS, その他多くのプラットホーム上で動作 します。ソースコードには著作権がありますが、無料で配布されています (す なわち、それに対価を支払う必要はありません)。元は、科学者や学生が数学 関数やデータなどを対話的に表示できるよう作られたのですが、現在までに、 例えば Web スクリプトなど、多くの非対話型の利用もサポートするように成 長しています。これは、例えば Octave のようにサードパーティのアプリケー ションの描画エンジンとしても使われています。gnuplot は、1986 よりサポ ートと活発な開発が行われています。

gnuplot は、2 次元、または 3 次元の、多くの種類のグラフをサポートして います: 折線グラフ、点グラフ、棒グラフ、等高線、ベクトル場描画、曲面、 そしてそれらに関連するさまざまな文字列等。そしてさらにいくつかの特別な 描画型もサポートしています。

gnuplot は多くの異なる出力をサポートしています: 対話型スクリーン出力形 式 (マウスやホットキー入力も可能)、ペンプロッタや現在のプリンタへの直 接出力、または多くのファイル形式への出力 (eps, emf, fig, jpeg, LaTeX, pdf, png, postscript, ...)。gnuplot は、容易に新しい出力形式を追加する よう拡張することができます。最近追加された対話型出力形式には、 wxWidgets (複数のプラットホームで利用可能), Qt を元にしたものがありま す。svg や HTML5 canvas 出力形式を利用すれば、グラフを Web ページ内に マウス利用可能な形で埋め込んだ出力を生成することもできます。

‘gnuplot‘ のコマンド言語は大文字小文字を区別します。すなわち、小文字で 書かれたコマンドや関数名は、それらを大文字で書いたものとは同じではあり ません。いずれのコマンドも、あいまいさの無い限りにおいて省略することが できます。1 行中にはセミコロン (;) で区切って複数のコマンドを書くこと ができます。文字列は単一引用符、あるいは二重引用符のどちらかで書き始め ますが、両者には微妙な違いがあります (詳細は、以下参照: ‘syntax‘)。例:

      set title "My First Plot";  plot 'data';  print "all done!"

コマンドは、複数行にまたがることができます。その場合は、最終行以外の 全ての行の行末にバックスラッシュ (\) を書く必要があります。バックスラ ッシュは必ず各行 *最後* の文字でなくてはなりません。その結果としてバッ クスラッシュと、それに続く改行文字が存在しなかったかのように扱われます。 つまり、改行文字がスペースの役をすることもありませんし、改行によってコ メントが終了することもありません。ですから複数行にまたがる行の先頭をコ メントアウトすると、そのコマンド全体がコメントアウトされることになりま す (以下参照: ‘comments‘)。なお注意しますが、もし、複数行のコマンドの どこかでエラーが起きたとき、パーサはその場所を正確には指示することがで きませんし、また、正しい行に指示する必要もないでしょう。

このドキュメントにおいて、中括弧 ({}) は省略可能な引数を表すものとし、 縦棒 (|) は、互いに排他的な引数を区切るものとします。‘gnuplot‘ のキー ワードや help における項目名は、逆引用符 (｀)、または可能な場合には ‘boldface‘ (太字) で表します。角括弧 (<>) は、それに対応するものに置き 換えられるべきものを表します。多くの場合、オプションの引数には、それが 省略されるとデフォルトの値が使用されます。しかし、これらの場合、必ずし も角括弧が中括弧で囲まれて書かれているわけではありません。

ある項目についてのヘルプが必要なときには、help に続けてその項目名を 入力して下さい。または単に ‘help ?‘ でもヘルプの項目のメニューが現われ ます。

大量のグラフサンプルが、以下の Web ページにあります。 http://www.gnuplot.info/demo/ コマンドラインから起動するときは、以下の書式が使えます。

      gnuplot {OPTIONS} file1 file2 ...

ここで file1, file2 等は、‘local‘ コマンドで取り込むのと同等の入力ファ イル (スクリプトファイル) です。 X11 ベースのシステムでは、以下の書式が使えます。

      gnuplot {X11OPTIONS} {OPTIONS} file1 file2 ...

詳細は、X11 のドキュメント、および以下参照: ‘x11‘。

gnuplot に与えるオプションは、コマンド行のどこに置いても構いません。フ ァイルは指定した順に実行され、同様に -e オプションで任意のコマンドを与 えることもできます。例:

      gnuplot   file1.in   -e "reset"   file2.in

特別なファイル名 "-" は、標準入力から読ませるのに使います。‘gnuplot‘ は最後のファイルを処理し終わると終了します。読み込ませるファイルを一つ も指定しない場合は、‘gnuplot‘ は標準入力からの対話入力を取ります。詳細 は、以下参照: ‘batch/interactive‘。gnuplot 用のオプションについては、 以下のようにして一覧を見ることができます:

      gnuplot --help

詳細は以下参照: ‘command line options‘。

対話型描画ウィンドウでの作業中は、’h’ を打つとホットキー (‘hotkeys‘) とマウス機能 (‘mousing‘) に関するヘルプを見ることができます。 ‘seeking-assistance‘ のセクションは、さらなる情報やヘルプ、FAQ を探す 手掛りを与えてくれるでしょう。

1.3 探し出す手助け (Seeking-assistance)

公式の gnuplot Web ページは以下にあります。 http://www.gnuplot.info

助けを求める前に、ファイル FAQ.pdf か、または上の Web サイトの FAQ (度々聞かれる質問; Frequently Asked Questions) の一覧 をチェックしてください。

gnuplot ユーザとしての手助けが必要なら、以下のニュースグループを利用し てください。

          comp.graphics.apps.gnuplot

gnuplot メーリングリストへの投稿の方法に関しては、SouceForge にある gnuplot の開発 Web サイト http://sourceforge.net/projects/gnuplot を参照してください。

gnuplot メーリングリストにメールを書く前に、最初にそのメーリングリスト に参加する必要があることに注意してください。これは、スパムの量を減らす ことを維持するために必要です。

メーリングリストメンバーへのメールアドレス:

          gnuplot-info@lists.sourceforge.net

バグリポート、ソースの改良等は以下の trackers に upload してください:

          http://sourceforge.net/projects/gnuplot/support

ただし、リポートを送る前に、あなたがリポートしようとしているバグが、よ り新しい版で既に修正されていないかチェックしてください。

開発版に関するメーリングリスト:

          gnuplot-beta@lists.sourceforge.net

何か質問を投稿するときは、あなたが使用している gnuplot のバージョン、 出力形式、オペレーティングシステム、といった全ての情報を含むようにして ください。それだけで閉じていて、その問題を再現する短いスクリプトを提示 するとなお良いでしょう。

1.4 新しい機能 (New features)

1.4.1 バージョン 5.2 で導入された機能 (Features introduced in version 5.2)

バージョン 5.2 は gnuplot の現在の安定版系列です。 以下の新機能の一覧は、2017 5 月時点で最新のものです。

1.4.1.1 新しい描画スタイルとオプション (New plot styles and style options)

• 3 次元描画スタイル zerrorfill。以下参照: zerrorfill, ‘fenceplots‘, zerror デモ。
• ビースウォームグラフ。以下参照: jitter, ‘beeswarm‘, ビースウォームグラフデモ。
• グラフの点 (points) で使われる個々の記号は、データ値で制御できます。 (以下参照: ‘pointtype variable‘)

1.4.1.2 データ用の新しい前処理フィルタ (New data pre-processing filters)

• データ集合内での出現回数の正規化 (以下参照: ‘smooth fnormal‘)
• データの階級幅割り当ての自動化 (以下参照: bins)

1.4.1.3 極座標モードの改良と拡張 (Polar mode improvements and extensions)

• ラベル、矢 (arrow)、オブジェクトの定義に極座標が使えます。
• ‘set [m]ttics‘ は極座標モードでの外周方位軸のラベルと刻みを配置しま す。以下参照: 極座標軸と刻みラベルデモ
• rlabel は動径軸 (r 軸) の上にラベルを配置します。
• 逆向きの rrange (例: set rrange [90:0]) で天球地平座標 (celestial horizontal coordinates) が使えるようになります。以下参照: 天体軌道デモ
• ‘set border polar‘ は極座標の外周の回りに実線を描きます。
• ‘set theta‘ は極座標グラフの外周方位軸での theta = 0 の位置と、角の 増加方向 (時計回りか反時計回りか) を制御します。

1.4.1.4 非線形座標系 (Nonlinear coordinates systems)

• グラフの任意の軸に、線形の範囲への写像とその逆写像を意味する関数の組 を割り当てることができ、それを非線形にすることも可能です (以下参照: nonlinear)。 y 軸デモ
• なじみ深いコマンド ‘set logscale‘ は、現在は関数の組 log(x), exp(x) による非線形軸の例の一つとして再実装されました。

1.4.1.5 新しいコマンドやオプション (New commands and command options)

• 繰り返し実行部分の中カッコ内では、‘continue‘ は次の繰り返しにすぐに 移動し、‘break‘ は繰り返しを中断します。
• ‘toggle {<plotno> | "plottitle" | all}"‘ は、対話的に現在のグラフの 構成要素を表示させるか消すかを選択できます。
• ‘save fit‘ は非推奨のコマンド update を置き換え
• ‘set table "outfile.name" append‘ で、その後の table 出力を、既に存 在するテキストファイルを上書きせず、追加出力にします。
• ‘set pm3d lighting‘ で、反射光ハイライトによる点光源モデルを使用しま す (以下参照: ‘lighting‘)。
• minussign は、負の数でのアスキー文字 ’-’ を、現在のエンコード での特殊文字に置き換えるよう gnuplot に指示します。
• micro は、科学用接頭辞の「マイクロ」用のアスキー文字 ’u’ を、 現在のエンコードでの特殊文字に置き換えるよう gnuplot に指示します。 micro, minussign の特殊印刷記号は、軸刻みラベルと、明示的に gprintf() で生成した文字列にのみ使用します。それらの文字表現のバイト列は、現在 のエンコード設定に依存します。

1.4.1.6 新しい配列データ型 "array" (New data type "array")

• このバージョンの gnuplot には、新しい配列データ型 ‘array name[size]‘ が導入されています。配列は、使用する前に宣言しなければいけません。各 配列要素 A[i] は、文字列、整数、実数、複素数のいずれでも構いません。 一つの配列が異なる型の要素を持つことも可能です。基数演算子 |A| は配 列のサイズを返します。以下参照: ‘arrays‘。

1.4.1.7 新しい出力形式とそのオプション (New terminals and terminal options)

• 新しい ‘sixelgd‘ 出力形式は、vt340 と互換の端末エミュレータ上で gnuplot を実行した場合に、グラフを出力する命令のコマンドラインの合間 にグラフを挟むような出力をサポートします。以下参照: ‘sixelgd‘。
• ‘domterm‘ 出力形式は、svg を解釈する端末エミュレータ上で gnuplot を 実行した場合に、グラフを出力する命令のコマンドラインの合間にグラフを 挟むような出力をサポートします。
• ‘windows‘ 出力形式は、現在のグラフのビットマップファイルへの保存をサ ポートします。
• ‘windows‘ 出力形式は、グラフウィンドウと wgnuplot テキストウィウンド ウをドッキングできます。
• ‘windows‘ 出力形式用 (試験的) Direct2D/DirectWrite 新バックエンド。
• ‘wxt‘ 出力形式は、Windows 上では EMF ファイルへの出力とプリンタ出力 をサポート。
• ‘dumb‘ 出力形式は、線と領域の塗り潰しで ANSI カラーをサポート。
• ‘tkcanvas‘ 出力形式は、新しい言語と、最近の gnuplot の多くの機能をサ ポートするように書き直されています (5.0.3 より)。

1.4.1.8 その他の新しい機能 (Other new features)

• 3 次元グラフの向きに影響する追加回転角 azimuth。これは、コマンドラ インから (以下参照: azimuth)、または右マウスボタンのドラ ッグで設定できます。
• Windows 上の gnuplot では、Unicode (BMP) スクリプトの入力を、 ‘set encoding‘ による現在のエンコード (UTF-8 を含む) に変換して解釈 します。
• 文字枠に境界色と背景色を指定できます (以下参照: ‘set style textbox‘)
• グラフの表題のカスタマイズ (以下参照: title, ‘set key‘, ‘multiple keys‘)
• 疑似ファイル ’+’ でのグラフのサンプリング範囲指定にサンプリング区間 を指定できます。例: plot sample [t=0:100:10] ’+’ using (t):(1):(label[t]) with labels
• 疑似ファイル ’++’ は、x, y 軸でなく u, v 軸に沿ったサンプリングを行 います。これは、3 次元グラフ中に、別々のデカルト座標領域を占めるよう な複数の媒介変数曲面を置くのに便利でしょう。
• ^R で、組み込み readline (Windows でも使われている) の履歴の逆向き検 索を開始します。以下参照: ‘command-line-editing‘。
• Windows での ‘set output "PRN"‘ による印刷の改良。以下参照: ‘windows printing‘。

1.4.2 バージョン 5.0 で導入された機能 (Features introduced in version 5.0)

• 線の点線/破線パターンは、現在は線の他の属性と独立に指定できます。以 下参照: ‘dashtype‘, ‘set dashtype‘, linetype。
• 一つの plot での連続した要素に使用されるデフォルトの色の巡回列は、色 弱者により容易に区別できるものになりました。その色の巡回列は、ユーザ が制御できます (以下参照: ‘set colorsequence‘)。この仕組みは、白黒の グラフを生成することでも行えます (以下参照: monochrome)。なお、 従来の gnuplot のバージョンでは monochrome は、現在の出力形式を ‘set temrinal‘ で変更するときにのみにしか選択できませんでした。
• 新しい描画スタイル parallelaxes、‘with table‘、および等高線の ラベル付け。
• 単調 3 次スプラインによるデータの新しい前処理フィルタ (以下参照: ‘smooth mcsplines‘)
• 文字の書式制御は、下付き、上付き、フォントサイズ、その他以前有効だっ たものに加え、今は太字体 (bold) と斜体 (italic) フォント設定もサポー トしています。このモード (拡張文字処理) は、現在はデフォルトで有効と なっています。以下参照: ‘enhanced text‘。文字列要素は枠で囲むことも できます (以下参照: ‘set style textbox‘)。
• 対話型出力形式は、ハイパーテキストラベルをサポートしていますが、これ はマウスがそのラベルのリンク点上にあるときにのみ現れるものです。
• 新しい座標系 (度、分、秒)。以下参照: geographic。
• 軸の見出しのデフォルト書式用の "% h" (LaTeX 系出力形式では "$%h$")。 この書式は C の標準書式の %g に似ていますが、指数部分がある場合は、 それが上付き文字として書かれることが違います。例えば、1.2E05 でなく 1.2 x 10^5 となります。
• スクリプト内で、インラインデータを名前付きのデータブロックとして保存 し繰り返し描画できるように。以下参照: ‘inline data‘。
• 32-bit のアルファ値 + RGB 色表記 (#AARRGGBB) をサポート。以下参照: ‘colorspec‘。
• hsv2rgb(H,S,V) という変換関数による HSV 色空間のサポート。
• 第 2 軸 (x2, y2) は、対応関数により、第 1 軸に固定できます。最も単純 なのは、これにより第 1 軸と 2 軸の軸の範囲を一致させることです。より 一般に、これにより非線形な軸を定義できるようになりますが、これまでは そのようなことは対数軸しかできませんでした。以下参照: ‘set link‘。
• plot コマンドの各関数にオプションとして描画範囲を前置指定できます。 これは、plot 全体の範囲には影響せず、その関数のデータをサンプリング する範囲でしかありません。以下参照: ‘plot‘, ‘piecewise.dem‘。
• 外部ライブラリ libcerf が利用可能であれば、それは複素数学関数 cerf, cdawson, erfi, faddeeva, および Voigt プロファイル VP(x,sigma,gamma) を提供するのに使われます。
• コマンド import は、外部共有オブジェクト (サポートはオペレーティン グシステム依存) が提供する関数にユーザ定義関数名を割り当てます。適当 な外部共有オブジェクトを作るためのテンプレートヘッダファイル、サンプ ルソース、makefile などが demo の中にあります。
• 対話作業の履歴一覧内の直前のコマンドは、番号で再実行できます。例えば ‘history !5‘ は、‘history‘ の一覧内の 5 番のコマンドを再実行します。
• ビットシフト演算子 >> と <<。
• gnuplot のシェル呼び出しで gnuplot スクリプトにパラメータを渡せます。 gnuplot -c scriptfile.gp ARG1 ARG2 ARG3 ...

1.5 バージョン 4 との違い (Differences from version 4)

バージョン 5 で導入されたいくつかの変更は、前の版の gnuplot 用のスクリ プトの挙動を変える可能性があります。

* NaN や、正しくないデータ列数、または他の予期しないものを含む入力デー タの処理の改良。例 (や図) については、以下参照: ‘missing‘。

* 時間座標は、標準的な Unix エポック (1970 年 1 月 1 日) からの秒数と して内部で保存します。以前の版の gnuplot では、別のエポック (2000 年 1 月 1 日) を内部で使用していました。この変更は、gnuplot の外で作られ た秒単位のデータによって矛盾がもたらされる問題を解決します。インストー ルされている個々の gnuplot がどちらのエポックを使用しているかについて は、コマンド ‘print strftime("%F",0)‘ で知ることができます。現在は、時 間は少なくともミリ秒の精度で保存されます。

* 関数 ‘timecolumn(N,"timeformat")‘ は、現在は 2 つの引数を持ちます。 新しい 2 つ目の引数はどのデータ軸とも関連しておらず、よってこれにより 関数 timecolumn を、x や y 軸に指定するのとは違う形式の日時データの 読み込みに使えるようになります。この機能は、次のコマンド列に取って変わ ります: ‘set xdata time; set timefmt "timeformat"‘。これは、複数のファ イルから異なる書式の日時データを読んで、それらを組み合わせて 1 つのグ ラフにすることを可能にします。

* コマンド ‘set [axis]range‘ のキーワード ‘reverse‘ は、自動縮尺 (autoscaling) にのみ影響し、‘set xrange [0:1]‘ のようなコマンドの意味 を逆にしたり他の変更を行ったりはしません。このような場合に x 軸の方向 を逆向きにしたければ、代わりに ‘set xrange [1:0]‘ としてください。

* コマンド call は、変数群 ARGC, ARG0, ..., ARG9 を提供します。ARG0 は、実行するスクリプト名を指します。ARG1 から ARG9 は文字列変数になる ので、直接参照するか、または例えば @ARG1 のようにマクロ展開させたもの を参照することができます。ARG0 ... ARG9 の内容は、他にも配列変数 ARGV の要素 ARGV[0] ... ARGV[ARGC] としても取得できます。古い gnuplot での call のパラメータ参照形式 $0 ... $9 は現在は非推奨です。

* オプション smooth の kdensity の、bandwidth の追加指定では、データ列 からでなく 1 つのキーワードとして値を取ります。以下参照: ‘smooth kdensity‘。

1.6 非推奨な書式 (Deprecated syntax)

以前の版で使われていたいくつかの書式は gnuplot 4 で非推奨となりました が、後方互換性を持たせるためのコンパイル時のオプションが用意されていま す。古い書式のサポートは現在は削除されています。

gnuplot 4 では非推奨で、バージョン 5 では削除:

      set title "Old" 0,-1
      set data linespoints
      plot 1 2 4               # y=1 での水平線

現在の同等の機能:

      TITLE = "New"
      set title TITLE offset char 0, char -1
      set style data linespoints
      plot 1 linetype 2 pointtype 4

バージョン 5.0 では –enable-backwards-compatibility で構築された場合 は使えるが非推奨:

      if (defined(VARNAME)) ...
      set style increment user
      plot 'file' thru f(x)
      call 'script' 1.23 ABC
         (in script:  print $0, "$1", "number of args = $#")

現在の同等の機能:

      if (exists("VARNAME")) ...
      set linetype
      plot 'file' using 1:(f(column(2)))
      call 'script' 1.23 "ABC"
         (in script:  print ARG1, ARG2, "number of args = ", ARGC

1.7 デモ、ネット上のサンプル (Demos and Online Examples)

‘gnuplot‘ の配布物の ‘demo‘ ディレクトリ内には、多くのサンプルが収めら れています。これらのサンプルの png, svg, canvas 出力形式による出力を、 以下のネット上で見ることもできます: http://gnuplot.info/demos そこでは、各デモを作成するコマンドがグラフの隣りに表示されますし、その gnuplot スクリプトをダウンロードすることもできますので、それを保存し同 様のグラフを作成することができます。

1.8 バッチ/対話型操作 (Batch/Interactive)

‘gnuplot‘ は多くのシステム上で、バッチ処理形式、あるいは対話型のどちら の形式でも実行でき、それらを組み合わせることも可能です。

コマンドライン引数は、プログラムへのオプション (文字 - で始まる) か、 ‘gnuplot‘ コマンドを含むファイルの名前であると解釈されます。 -e "command" の形式のオプションは、gnuplot コマンドを強制的に実行させ、 各ファイルとこのコマンド文字列は、指定された順に実行されます。特別なフ ァイル名 "-" は、コマンドを標準入力から読み込むことを意味します。最後 のファイルを実行した後に ‘gnuplot‘ は終了します。読み込ませるファイル、 およびコマンド文字列を指定しなかった場合は、‘gnuplot‘ は標準入力からの 対話型の入力を受け付けます。

exit と quit はどちらも現在のコマンドファイルを終了し、まだ全ての ファイルが終っていなければ、次のファイルを load するのに使われます。

例:

対話を開始する:

      gnuplot

2 つのコマンドファイル "input1", "input2" を使ってバッチ処理を行なう:

      gnuplot input1 input2

初期化ファイル "header" の後、対話型モードを起動し、その後別のコマンド ファイル "tailer" を実行する:

      gnuplot header - trailer

コマンドラインから ‘gnuplot‘ コマンドを直接与え、終了後にスクリーン上 にグラフが残るようにオプション "-persist" を使う:

       gnuplot -persist -e "set title 'Sine curve'; plot sin(x)"

ファイルのコマンドを実行する前に、ユーザ定義変数 a と s をセットする:

      gnuplot -e "a=2; s='file.png'" input.gpl

1.9 キャンバスサイズ (Canvas size)

gnuplot の以前の版では、‘set size‘ の値を、出力する描画領域 (キャンバ ス) のサイズを制御するのにも使っていた出力形式もありましたが、すべての 出力形式がそうだったわけではありませんでした。この目的のために ‘set size‘ を使用することはバージョン 4.2 で非推奨となり、現在はほとん どの出力形式が以下のルールに従います:

‘set term <terminal_type> size <XX>, <YY>‘ は、出力ファイルのサイズ、 または "キャンバス" のサイズを制御します。デフォルトでは、グラフはその キャンバス全体に描画されます。

‘set size <XX>, <YY>‘ は、描画自体をキャンバスのサイズに対して相対的に 伸縮させます。1 より小さい伸縮値を指定すると、グラフはキャンバス全体を 埋めず、1 より大きい伸縮値を指定すると、グラフの一部分のみがキャンバス 全体に合うように描画されます。1 より大きい伸縮値を指定すると、問題が起 こるかもしれないことに注意してください。

このルールに沿わない主な例外は PostScript ドライバで、デフォルトでは以 前の版と同じ振舞いをしますが、将来は PostScript ドライバも同様にデフォ ルトの振舞いを変更することになるでしょう。

例:

      set size 0.5, 0.5
      set term png size 600, 400
      set output "figure.png"
      plot "data" with lines

このコマンドは、幅 600 ピクセル、高さ 400 ピクセルの出力ファイル "figure.png" を生成します。グラフはキャンバスの中の左下に置かれます。 これは、multiplot モードが常に行ってきた方法と矛盾しません。

1.10 コマンドライン編集 (Command-line-editing)

コマンドラインでの編集機能とコマンドヒストリの機能は、外部の GNU readline ライブラリか外部の BSD libedit ライブラリ、または組み込まれて いる同等のもののいずれかを使ってサポートしています。この選択は、 gnuplot のコンパイル時の configure のオプションで行います。

組み込みの readline 版の場合の編集コマンドは以下の通りですが、DEL キー に関する動作はシステムに依存することに注意してください。GNU readline ライブラリと BSD libedit ライブラリに関しては、それ自身のドキュメント を参照してください。

      `行編集`:

      ^B    1 文字前へ戻す
      ^F    1 文字先へ進める
      ^A    行の先頭に移動
      ^E    行の最後に移動
      ^H    直前の文字を削除
      DEL   現在の文字を削除
      ^D    現在位置の文字を削除、空行なら EOF を送信
      ^K    現在位置から行末まで削除
      ^L    壊れた表示の行を再表示
      ^U    行全体の削除
      ^W    直前の単語を削除
      ^V    この次のキーを編集コマンドと見なさない
      TAB   ファイル名補完動作

      `履歴`:

      ^P    前の履歴へ移動
      ^N    次の履歴へ移動
      ^R    後方検索を開始

1.11 コメント (Comments)

コメント記号 ‘#‘ は、コマンド行中のほとんどどこにでも書くことができま す。このとき ‘gnuplot‘ は、その行の残りの部分を無視します。ただし、記 号 ‘#‘ は引用符内ではこの効果がありません。コメント行が ’\’ で終わって いる場合、次の行もコメントの一部として扱われることに注意してください。

データファイルに対するコメント文字の指定については、以下参照: ‘set datafile commentschars‘。

1.12 座標系 (Coordinates)

コマンド ‘set arrow‘, ‘set key‘, ‘set label‘, ‘set object‘ はグラフ上 の任意の位置が指定できます。その位置は以下の書式で指定します:

      {<system>} <x>, {<system>} <y> {,{<system>} <z>}

各座標系指定 <system> には、‘first‘, ‘second‘, ‘polar‘, ‘graph‘, ‘screen‘, ‘character‘ のいずれかが入ります。

‘first‘ は左と下の軸で定義される x,y (3D の場合は z も) の座標系を使用 します。‘second‘ は x2, y2 軸 (上と右の軸) を使用します。‘graph‘ はグ ラフ描画領域内の相対的位置を指定し、左下が 0,0 で 右上が 1,1 (splot の 場合はグラフ描画領域内の左下が 0,0,0 で、土台の位置は負の z の値を使用 します。以下参照: ‘set xyplane‘) となります。‘screen‘ は表示範囲内 (範 囲全体であり、‘set size‘ で選択される一部分ではありません) を指定し、 左下が 0,0 で 右上が 1,1 となります。‘character‘ 座標は主にずれを指定 するのに使用し、絶対的な位置を示すものではありません。‘character‘ の水 平、垂直サイズは、現在使用しているフォントに依存します。

‘polar‘ は、最初の 2 つの値を、x, y ではなく、角 theta と半径 r である と解釈します。これは、例えば 2 次元の極座標、あるいは 3 次元円柱座標で のグラフにラベルを配置するのに役に立つでしょう。

x の座標系が指定されていない場合は ‘first‘ が使われます。y の座標系が 指定されていない場合は x に対する座標系が使用されます。

与える座標が絶対的な位置ではなくて相対的な値である場合もあります (例え ば ‘set arrow‘ ... ‘rto‘ の 2 番目の数値)。そのほとんどが、与えられた 数値を最初の位置に対する差として使います。与えられた座標が対数軸内にあ る場合は、その相対的な値は倍率として解釈されます。例えば

      set logscale x
      set arrow 100,5 rto 10,2

は、x 軸が対数軸で y 軸が線形の軸なので、100,5 の位置から 1000,7 の位 置への矢印を書くことになります。

一つ (あるいはそれ以上) の軸が時間軸である場合、‘timefmt‘ の書式文字列 に従って、引用符で囲まれた時間文字列で適切な座標を指定する必要がありま す。以下参照: ‘set xdata‘, ‘set timefmt‘。また、‘gnuplot‘ は整数表記も 認めていて、その場合その整数は 1970 年 1 月 1 日からの秒数と解釈されま す。

1.13 文字列データ (Datastrings)

データファイルには、ホワイトスペース (空白やタブ) を含まない任意の印字 可能な文字列、あるいは 2 重引用符で囲まれた任意の文字列 (ホワイトスペ ースが含まれても良い)、のいずれかの形からなる文字列データを持たせるこ とも可能です。データファイルに次のような行が含まれている場合、それは 4 つの列を含み、3 列目がテキスト部分であると見なされます:

  1.000 2.000 "Third column is all of this text" 4.00

テキスト部分は 2 次元や 3 次元描画内で例えば以下のように使用されます:

  plot 'datafile' using 1:2:4 with labels
  splot 'datafile' using 1:2:3:4 with labels

テキスト部分の列データは 1 つ、または複数の描画軸の目盛りのラベルとし て使用できます。次の例は、入力データの 3 列目と 4 列目を (X,Y) 座標と して取り出し、それらの点の列を結ぶ線分を描画します。しかしこの場合 gnuplot は、x 軸に沿って標準的に間の空いた数字ラベルのついた目盛り刻み をつけるのではなく、入力データファイルの 1 行目の X 座標の位置に、目盛 り刻みと文字列を x 軸に沿ってつけて行きます。

  set xtics
  plot 'datafile' using 3:4:xticlabels(1) with linespoints

入力データの列の最初のエントリ (すなわち列の見出し) をテキスト部分と解 釈するもう一つのオプションがあり、それはテキスト部分を、その描画した列 のデータの凡例 (key) のタイトル部分として使用します。次の例は、先頭の 行の 2 列目の部分を凡例ボックス内のタイトルを生成するのに使用し、その 後の列の 2,4 列目は要求された曲線を描画するのに処理されます:

  plot 'datafile' using 1:(f($2)/$4) with lines title columnhead(2)

別の例:

  plot for [i=2:6] 'datafile' using i title "Results for ".columnhead(i)

この列の先頭を使用する方法は、columnhead で自動化 できます。 以下参照: labels, ‘using xticlabels‘, title, using, ‘key autotitle‘。

1.14 拡張文字列処理モード (Enhanced text mode)

多くの出力形式が、拡張文字列処理モード (enhanced text mode) をサポート しています。これは、文字列に追加の書式情報を埋めこみます。例えば "x^2" は x の自乗を、通常我々が見る上付きの 2 がついた形で書き出します。この モードは、出力形式の設定時にデフォルトとして選択されますが、その後で "set termoption [no]enhanced" を使ってその機能を有効/無効にもできます し、"set label ’x_2’ noenhanced" のように個々の文字列に適用することも できます。

 制御記号     例              説明
  ^           a^x             上付き文字
  _           a_x             下付き文字
  @           @x, a@^b_{cd}   空ボックス (幅がない)
  &           &{space}        指定した長さのスペースを挿入
  ~           ~a{.8-}         'a' の上に '-' を、現在のフォントサ
                              イズの .8 倍持ち上げた位置に重ね書き
  {/Times abc}                Times フォント、今のサイズで abc を出力
  {/Times*2 abc}              Times フォント、今の倍のサイズで abc
  {/Times:Italic abc}         TImes フォント、イタリック体で abc
  {/Arial:Bold=20 abc}        Arial フォント、太字、サイズ 20 で abc

書式制御文字は、それに続く 1 文字、または中カッコで囲まれたものに適用 されます。中カッコ内には、例えば 2^{10} のような追加の書式文字列のない 文字列か、またはフォントの属性を変更する追加制御文字列を入れることがで きます。以下の例はその中カッコの入れ子を示していて、ボールド体の A に イタリック体の下付きの添字 i がついたものが、いずれも現在のフォントで 描かれます。この例の :Normal を取ると、下付きの添字はボールド体でかつ イタリック体になります。

     {/:Bold A_{/:Normal{/:Italic i}}}

フォント指定は、開き中カッコ ’{’ の直後に続く ’/’ のすぐ次に書かなけれ ば「いけません」。

空ボックス (phantom box) は a@^b_c の上付き文字と下付き文字を揃えると きに有用ですが、文字にアクセント記号を重ねる場合にはうまく働きません。 後者の目的のためには、色々なアクセントやその他のダイアクリティカルマ ークのある多くの文字を持つエンコード (例えば iso_8859_1 や utf8) を使 用する方がいいでしょう。以下参照: ‘set encoding‘。そのボックスはスペー シングが行なわれないので、ボックス内 (つまり @ の後ろ) の上付き文字や 下付き文字を短く出力するのに適しています。

ある文字列と同じ長さのスペースを文字 ’&’ を使うことで入れることができ ます。すなわち、

        'abc&{def}ghi'

は以下を生成します (abc と ghi の間は 3 文字分の空白):

        'abc   ghi'

文字 ’~’ は、次の文字、またはカッコで囲まれた文字列に、それに続く文字 またはカッコで囲まれた文字列を重ね書きします。2 番目の文字は最初の文字 にあわせて水平方向にセンタリングされます。よって ’~a/’ は ’a’ を貫くよ うなスラッシュが得られます。2 番目の文字は、その前に数字を置くことで垂 直方向に移動させることができます。その数字は現在のフォントサイズに対す る割合を意味し、それに従って文字が上がったり下がったりします。この場合 数字と文字列は 1 文字より長くなるのでカッコで囲む必要があります。重ね 書きされる文字列が数字から始まっている場合は、垂直にずらす値と文字列と の間にスペースを入れてください (’~{abc}{.5 000}’)。それ以外はスペース は不要です (’~{abc}{.5—}’)。一方、あるいは両方のフォントを変更するこ ともできます (’~a{.5 /*.2 o}’; ’a’ その 1/5 の大きさの ’o’、この場合数 字とスラッシュの間のスペースは必要です) が、その文字列が始まった後で変 更することはできません。それぞれの文字列内で、他の特殊な書式を使うこと もできません。もちろん、’~a{\^}’ のように特殊な文字をエスケープするこ と (下記参照) は可能です。

特殊記号は、8 進文字コードを与えることで数字で指定できます。例えば、 {/Symbol \245} は、Adobe Symbol フォントの無限大の記号です。しかし、こ れは、 UTF-8 のようなマルチバイトエンコーディングではうまくいきません。 UTF-8 環境では、タイプ打ち、そうでなければあなたが望む文字を選ぶような 方法で、マルチバイト列を間接的に入力できるようにすべきです。

制御文字は、 \\ や \{ などのように \ を使ってエスケープできます。

二重引用符内の文字列は単一引用符内の文字列とは異なって解釈されることに 注意してください。主な違いは、二重引用符内の文字列ではバックスラッシュ は 2 つ重ねる必要があることです。

gnuplot ソース配布物内の /docs/psdoc サブディレクトリにあるファイル "ps_guide.ps" に、拡張された書式に関する例が載っています。同様のものが デモ ‘enhanced_utf8.dem‘ にもあります。

1.15 環境変数 (Environment)

‘gnuplot‘ は多くのシェル環境変数を認識します。必須のものはありませんが、 使えば便利になるかも知れません。

GNUTERM は、それが定義されていれば、起動時の出力形式を設定するのに使わ れます。バージョン 5.2 からは、GNUTERM の文字列全部が "set term" に渡 されるので、そこに terminal オプションを入れることもできます。例:

     GNUTERM="postscript eps color size 5in, 3in"

これは、~/.gnuplot (またはそれに相当する) 初期化ファイル (以下参照: ‘startup‘) による指定や、もちろんその後の明示的な ‘set term‘ コマンド による指定で変更できます。

GNUHELP にヘルプファイル (gnuplot.gih) のパス名を定義しておくことがで きます。

VMS では、論理名 GNUPLOT$HELP を ‘gnuplot‘ のヘルプライブラリの名前と して定義します。‘gnuplot‘ のヘルプは任意の VMS システムのヘルプライブ ラリに入れることができます。

Unix においては、カレントディレクトリに .gnuplot というファイルがない 場合には、HOME に定義されたディレクトリを探します。MS-DOS, Windows, OS/2 では GNUPLOT がその役割に使われます。Windows では、NT 専用の変数 USERPROFILE も参照されます。VMS では SYS$LOGIN です。‘help startup‘ と打ってみてください。

Unix においては、PAGER がヘルプメッセージの出力用のフィルタとして使わ れます。

Unix では、SHELL が ‘shell‘ コマンドの際に使われます。MS-DOS, OS/2 で は COMSPEC が ‘shell‘ コマンドの際に使われます。

‘FIT_SCRIPT‘ は、当てはめ (fit) が中断されたときに実行する ‘gnuplot‘ コマンドの指定に使われます。以下参照: ‘fit‘。‘FIT_LOG‘ は当てはめによ るログファイルのデフォルトのファイル名の指定に使われます。

GNUPLOT_LIB は、データやコマンドファイルの検索ディレクトリを追加定義す るのに使われます。その変数は、一つのディレクトリ名かまたは複数のディレ クトリ名を書くことができますが、ディレクトリの区切りはプラットホーム毎 に違います。例えば Unix では ’:’ で、MS-DOS, Windows, OS/2 では ’;’ で す。GNUPLOT_LIB の値は変数 ‘loadpath‘ に追加されますが、それは save や ‘save set‘ コマンドでは保存されません。

出力ドライバの中には gd ライブラリ経由で TrueType フォントを扱えるもの もいくつかあります。これらのドライバのフォント検索パスは、環境変数 GDFONTPATH で制御できます。さらに、それらのドライバでのデフォルトのフ ォントは環境変数 GNUPLOT_DEFAULT_GDFONT で制御できます。

postscript 出力ドライバは自分で持っているフォント検索パスを使いますが、 それは環境変数 GNUPLOT_FONTPATH で制御できます。書式は GNUPLOT_LIB と 同じです。GNUPLOT_FONTPATH の値は変数 ‘fontpath‘ に追加されますが、そ れは save や ‘save set‘ コマンドでは保存されません。

PostScript ドライバは、外部 (組み込まれていない) 定義ファイルを探すた めに環境変数 GNUPLOT_PS_DIR を利用します。インストール時の作業により、 gnuplot にはそれらのファイルのコピーが組み込まれているか、またはデフォ ルトのパスが埋め込まれています。この変数は、postscript 出力形式でデフ ォルトのファイルの代わりにカスタマイズした prologue ファイルを使用する のに利用できます。以下参照: ‘postscript prologue‘。

1.16 式 (Expressions)

基本的には C, FORTRAN, Pascal, BASIC において利用可能な数学表現を使用 できます。 演算子の優先順位は C 言語の仕様に従います。数式中の空白文字 とタブ文字は無視されます。

gnuplot は "実数" と "整数" 演算を FORTRAN や C のように扱うということ に注意してください。"1", "-10" などは整数と見なされ、"1.0", "-10.0", "1e1", 3.5e-1 などは実数と見なされます。 これら 2 つのもっとも重要な違 いは割算です。整数の割算は切り捨てられます: 5/2 = 2。実数はそうではあ りません: 5.0/2.0 = 2.5。それらが混在した式の場合、計算の前に整数は実 数に "拡張" されます: 5/2e0 = 2.5。負の整数を正の整数で割る場合、その 値はコンパイラによって変わります。"print -5/2" として、あなたのシステ ムが常に切り捨てる (-5/2 で -3 になる) のか、または 0 の近くに丸める (-5/2 で -2 になる) のかを確認してください。

数式 "1/0" は "未定義値 (undefined)" フラグを生成し、それによりその点 を無視します。あるいは、あらかじめ定義されている値 NaN を使っても同じ ことになります。例については、以下参照: using。

gnuplot は文字列に対する単純な演算、および文字列変数も利用できます。例 えば式 ("A" . "B" eq "AB") は真と評価されますが、これは文字列の結合演 算子と文字列の等号演算子を意味しています。

数としての値を含む文字列は、それが数式で利用された場合は、対応する整数 や実数に変換されます。よって、("3" + "4" == 7) や (6.78 == "6.78") は どちらも真になります。整数は、それが文字列結合演算子で使われた場合は文 字列に変換されますが、実数や複素数はダメです。典型的な例は、ファイル名 や他の文字列内に整数を使う場合でしょう: 例えば ("file" . 4 eq "file4") は真です。

後置指定する範囲記述子 [beg:end] によって、部分文字列を指定することが できます。例えば、"ABCDEF"[3:4] == "CD" で、"ABCDEF"[4:*] == "DEF" で す。書式 "string"[beg:end] は、文字列値の組み込み関数 substr("strings",beg,end) を呼ぶこととほぼ同じですが、関数呼び出しでは beg, end は省略することはできません。

1.16.1 定数 (Constants)

整数定数は、C の strtoll() ライブラリルーチンを使って解釈しますが、こ れは、"0" で始まる定数は 8 進数と、また "0x" か "0X" で始まる定数は 16 進数とみなすことを意味します。

実数 (浮動小数) 定数は、C の atof() ライブラリルーチンを使って解釈しま す。

複素数の定数は {<real>,<imag>} と表現します。ここで <real> と <imag> (実部、虚部) は数値定数である必要があります。例えば {3,2} は 3 + 2i を あらわし、{0,1} は ’i’ 自身を表します。これらには明示的に中カッコを使 う必要があります。

文字列定数は単一引用符か二重引用符のいずれかで囲まれた任意の文字の並び からなるものです。単一引用符と二重引用符の違いは重要です。以下参照: ‘quotes‘。

例:

     1 -10 0xffaabb        # 整数定数
     1.0 -10. 1e1 3.5e-1   # 実数定数
     {1.2, -3.4}           # 複素数定数
     "Line 1\nLine 2"      # 文字列定数 (\n は改行に展開される)
     '123\n456'            # 文字列定数 (\ と n はそのままの文字)

1.16.2 関数 (Functions)

特に注意がなければ、‘gnuplot‘ の数学関数の引数は整数、実数、複素数の値 を取ることができます。角を引数や戻り値とする関数 (例えば sin(x)) は、 その値をラジアンとして扱いますが、これはコマンド ‘set angles‘ によって 度に変更できます。

1.16.2.1 abs

関数 ‘abs(x)‘ 引数の絶対値を返します。返り値の型は引数と同じです。

複素数の引数に対しては, abs(x) は複素平面における x の長さと定義されて います [すなわち sqrt(real(x)**2 + imag(x)**2) ]。これは x のノルム (norm)、または x の複素絶対値 (modulus) とも呼ばれます。

1.16.2.2 acos

関数 ‘acos(x)‘ は引数のアークコサイン (逆余弦) を返します。‘acos‘ の返 す値がラジアン単位かまたは度であるかは ‘set angles‘ で選択されます。

1.16.2.3 acosh

関数 ‘acosh(x)‘ は逆ハイパボリックコサイン (逆双曲余弦) の値をラジアン で返します。

1.16.2.4 airy

関数 ‘airy(x)‘ は、エアリー (Airy) 関数 Ai(x) の値を返します。関数 Ai(x) は、微分方程式 y” - x y = 0 の、実数全体で有界な解です。引数が 複素数の場合、その虚数部分は無視されます。

1.16.2.5 arg

関数 ‘arg(x)‘ は複素数の偏角を、‘set angles‘ の設定にしたがってラジア ン、または度で返します。

1.16.2.6 asin

関数 ‘asin(x)‘ は引数のアークサイン (逆正弦) を返します。‘asin‘ の返す 値は ‘set angles‘ の設定によってラジアン単位かまたは度になります。

1.16.2.7 asinh

関数 ‘asinh(x)‘ は逆ハイパボリックサイン (逆双曲正弦) の値をラジアンで 返します。

1.16.2.8 atan

関数 ‘atan(x)‘ は引数のアークタンジェント (逆正接) の値を返します。 ‘atan‘ の返す値は ‘set angles‘ の設定によってラジアン単位かまたは度に なります。

1.16.2.9 atan2

関数 ‘atan2(y,x)‘ は引数の実数部分の比のアークタンジェント (逆正接) の 値を返します。atan2 は ‘set angles‘ の設定によってラジアン単位か度に なる、適切な四分円における値を返します。

1.16.2.10 atanh

関数 ‘atanh(x)‘ は逆ハイパボリックタンジェント (逆双曲正接) の値をラジ アンで返します。

1.16.2.11 EllipticK

関数 ‘EllipticK(k)‘ は、第 1 種完全楕円積分の値を返します。詳細は、以 下参照: ‘elliptic integrals‘。

1.16.2.12 EllipticE

関数 ‘EllipticE(k)‘ は、第 2 種完全楕円積分の値を返します。詳細は、以 下参照: ‘elliptic integrals‘。

1.16.2.13 EllipticPi

関数 ‘EllipticPi(n,k)‘ は、第 3 種完全楕円積分の値を返します。詳細は、 以下参照: ‘elliptic integrals‘。

1.16.2.14 besj0

esj0(x) & 整数または実数 & $J_{0}$ ベッセル関数 (0 次ベッセル関数)\\ 関数 ‘besj0(x)‘ は引数の J0 ベッセル関数 (0 次の第 1 種円柱関数 J0、0 次ベッセル関数) の値を返します。besj0 には引数はラジアンで与えます。

1.16.2.15 besj1

esj1(x) & 整数または実数 & $J_{1}$ ベッセル関数 (1 次ベッセル関数)\\ 関数 ‘besj1(x)‘ は引数の J1 ベッセル関数 (1 次の第 1 種円柱関数 J1、1 次ベッセル関数) の値を返します。besj1 には引数はラジアンで与えます。

1.16.2.16 besy0

esy0(x) & 整数または実数 & $Y_{0}$ ベッセル関数 (0 次ノイマン関数)\\ 関数 ‘besy0(x)‘ は引数の Y0 ベッセル関数 (0 次の第 2 種円柱関数 Y0、0 次ノイマン関数) の値を返します。besy0 には引数はラジアンで与えます。

1.16.2.17 besy1

esy1(x) & 整数または実数 & $Y_{1}$ ベッセル関数 (1 次ノイマン関数)\\ 関数 ‘besy1(x)‘ は引数の Y1 ベッセル関数 (1 次の第 2 種円柱関数 Y1、1 次ノイマン関数) の値を返します。besy1 には引数はラジアンで与えます。

1.16.2.18 ceil

関数 ‘ceil(x)‘ は引数以上の最小の整数を返します。複素数引数に対しては ceil はその引数の実部以上の最小の整数を返します。

1.16.2.19 cos

関数 ‘cos(x)‘ は引数のコサイン (余弦) の値を返します。‘cos‘ は ‘set angles‘ の選択にしたがって、ラジアンまたは度の引数を受け付けます。

1.16.2.20 cosh

関数 ‘cosh(x)‘ は引数のハイパボリックコサインの値を返します。cosh の 引数はラジアンで与えます。

1.16.2.21 erf

関数 ‘erf(x)‘ は引数の実部の誤差関数の値を返します。引数が複素数の場合 は虚部は無視されます。以下参照: erfc, inverf, norm。

1.16.2.22 erfc

関数 ‘erfc(x)‘ は 1.0 から、引数の実部の誤差関数の値を引いたものを返し ます。引数が複素数の場合は虚部は無視されます。以下参照: ‘erf‘, inverf, norm。

1.16.2.23 exp

関数 ‘exp(x)‘ 引数の指数関数の値 (‘e‘ の引数乗) を返します。環境によっ ては (特に sun) 大きい x の値に対する exp(-x) は未定義値を返す場合があ ります。このような場合、safe(x) = x<-100 ? 0 : exp(x) のようなユーザ定 義関数が役に立つでしょう。

1.16.2.24 expint

関数 ‘expint(n,x)‘ は、その引数の実数部分の指数積分、すなわち t の関数 t^(-n) e^(-tx) の 1 から∞までの積分値を返します。n は 0 以上の整数、 x は 0 以上の実数で、x>0 か n>1 のいずれかでなければなりません。

1.16.2.25 floor

関数 ‘floor(x)‘ はその引数以下の最大の整数を返します。複素数引数に対し ては floor はその引数の実部以下の最大の整数を返します。

1.16.2.26 gamma

関数 ‘gamma(x)‘ は引数の実部のガンマ関数の値を返します。整数 n に対し ては gamma(n+1) = n! です。引数が複素数の場合、虚数部分は無視されます。

1.16.2.27 ibeta

関数 ‘ibeta(p,q,x)‘ は引数の実部の不完全ベータ関数の値を返します。p, q は正で x は [0:1] 内の値です。引数が複素数の場合は虚部は無視されます。 この関数は連分数法 (Abramowitz and Stegun, 1964) で近似していて、この 近似は x < (p-1)/(p+q-2) の範囲でしか正確ではありません。

1.16.2.28 inverf

関数 ‘inverf(x)‘ は引数の実部の逆誤差関数の値を返します。以下参照: ‘erf‘, invnorm。

1.16.2.29 igamma

関数 ‘igamma(a,x)‘ は引数の実部の、正規化された不完全ガンマ関数の値を 返します。ここで、a > 0, x >= 0 です。標準的な記法では P(a,x) (例えば Abramowitz and Stegun (6.5.1)) で、x が無限大に発散する場合の極限値は 1 です。引数が複素数の場合は虚部は無視されます。

1.16.2.30 imag

関数 ‘imag(x)‘ は引数の虚数部分を実数として返します。

1.16.2.31 invnorm

関数 ‘invnorm(x)‘ は引数の実部に対する、正規分布 (ガウス分布) の累積分 布関数の逆関数の値を返します。以下参照: norm。

1.16.2.32 int

関数 ‘int(x)‘ は、引数の整数部分 (0 に向かって丸めた) を返します。

1.16.2.33 lambertw

関数 ‘lambertw(x)‘ は Lambert の W 関数の主値を返します。W 関数は、方 程式 (W(x)*exp(W(x))=x によって定義されます。x は x >= -exp(-1) を満た す実数でなければいけません。

1.16.2.34 lgamma

関数 ‘lgamma(x)‘ は引数の実部のガンマ関数値の自然対数の値を返します。 引数が複素数の場合、虚部は無視されます。

1.16.2.35 log

関数 ‘log(x)‘ は引数の自然対数 (底 ‘e‘) の値を返します。以下参照: log10。

1.16.2.36 log10

関数 ‘log10(x)‘ は引数の対数 (底 10) を返します。

1.16.2.37 norm

関数 ‘norm(x)‘ は、引数の実部に対する、正規分布 (ガウス分布) の累積分 布関数の値を返します。以下参照: invnorm, ‘erf‘, erfc。

1.16.2.38 rand

関数 ‘rand(x)‘ は、区間 [0:1] 内の疑似乱数を返します。詳しくは以下参 照: ‘random‘。

1.16.2.39 real

関数 ‘real(x)‘ は引数の実部を返します。

1.16.2.40 sgn

関数 ‘sgn(x)‘ は引数が正なら 1 を、負なら -1 を、0 ならば 0 を返します。 引数が複素数の場合虚部は無視されます。

1.16.2.41 sin

関数 ‘sin(x)‘ は引数のサイン (正弦) の値を返します。‘sin‘ は ‘set angles‘ の選択にしたがって、ラジアンまたは度の引数を受け付けます。

1.16.2.42 sinh

関数 ‘sinh(x)‘ は引数のハイパボリックサインの値を返します。sinh の 引数はラジアンで与えます。

1.16.2.43 sqrt

関数 ‘sqrt(x)‘ は引数の平方根の値を返します。x が複素数の場合、これは 常に正の実部を持つ根を返します。

1.16.2.44 tan

関数 ‘tan(x)‘ は引数のタンジェント (正接) の値を返します。‘tan‘ は ‘set angles‘ の選択にしたがって、ラジアンまたは度の引数を受け付けます。

1.16.2.45 tanh

関数 ‘tanh(x)‘ は引数のハイパボリックタンジェントの値を返します。 tanh の引数はラジアンで与えます。

1.16.2.46 voigt

関数 ‘voigt(x,y)‘ は、スペクトル解析で使用される Voigt/Faddeeva 関数の 近似を返します。その誤差は 1/10^4 以内です。libcerf ルーチンが利用可能 ならば、より正確な値を求めるために re_w_of_z() ルーチンが使われます。 voigt(x,y) = real(faddeeva( x + y*{0,1} )) に注意してください。

1.16.2.47 cerf

‘cerf(z)‘ は誤差関数 erf(x) の複素バージョンです。

1.16.2.48 cdawson

‘cdawson(z)‘ は複素引数に対する Dawson 積分の値を返します。 cdawson(z) = sqrt(pi)/2 * exp(-z^2) * erfi(z)

1.16.2.49 faddeeva

関数 ‘faddeeva(z)‘ は再スケール化複素誤差関数です。 faddeeva(z) = exp(-z^2) * erfc(-i*z) これは、Abramowitz-Stegun の式 7.1.3, 7.1.4 に対応します。

1.16.2.50 erfi

虚誤差関数 erfi(x) = -i * erf(ix)

1.16.2.51 Voigt Profile

‘VP(x,sigma,gamma)‘ はガウス密度関数 G(x;sigma) とローレンツ密度関数 L(x;gamma) の畳み込みで定義される Voigt プロファイル (密度関数) に対 応します。

1.16.2.52 gprintf

‘gprintf("format",x)‘ は、gnuplot 独自の書式指定子に一つの変数 x を適 用し、その結果の文字列を返します。標準的な C 言語書式指定子を使いたい 場合は、代わりに ‘sprintf("format",x)‘ を使う必要があります。 以下参照: ‘format specifiers‘。

1.16.2.53 sprintf

‘sprintf("format",var1,var2,...)‘ は標準的な C 言語の書式指定子を複数 個の引数に適用し、その結果の文字列を返します。gnuplot 独自の書式指定子 を使いたい場合は、代わりに ‘gprintf()‘ を使用する必要があります。 sprintf の書式指定子に関するより詳しい情報については、標準的な C 言語 の本か、unix の sprintf の man ページを参照してください。

1.16.2.54 strlen

‘strlen("string")‘ は、現在のエンコーディングを考慮した、文字列中の文 字数を返します。現在のエンコーディングが多バイト文字 (SJIS UTF8) をサ ポートしていれば、この値は、文字列のバイト数よりも小さくなるでしょう。 文字列に多バイト UTF8 文字が含まれていて、しかし現在のエンコーディング が UTF8 以外の別のものに設定されていると、strlen("utf8文字列") は、 実際の文字数よりも大きな値を返すでしょう。

1.16.2.55 strstrt

‘strstrt("string","key")‘ は、文字列 "key" を "string" の中で探し、そ れが現れる先頭位置を返します。"key" が見つからなかった場合は 0 を返し ます。C ライブラリの strstr 関数に似ていますが、文字列へのポインタを返 す strstr とは違い、これは整数での位置を返します。例えば、 strstrt("hayneedlestack","needle") = 4 となります。

1.16.2.56 substr

‘substr("string",beg,end)‘ は、元の文字列の beg から end 番目までの文 字からなる文字列を返します。これは、"string"[beg:end] という式とほぼ同 じですが、こちらはオプション beg, end を省略できません。

1.16.2.57 strftime

‘strftime("timeformat",t)‘ は、1970 年からの秒数による時刻 t に、時刻 書式指定 timeformat を適用します。 以下参照: ‘time_specifiers‘, strptime。

1.16.2.58 strptime

‘strptime("timeformat",s)‘ 書式指定 timeformat を使って文字列 s から時 刻を読み込んで、それを 1970 年からの秒数に変換します。 以下参照: ‘time_specifiers‘, strftime。

1.16.2.59 system

‘system("command")‘ は、標準的なシェルを用いて "command" を実行し、そ の標準出力への文字列を文字列変数として返します。一番最後の改行一つは無 視されます。

これは、’f(x) = real(system(sprintf("somecommand %f", x)))’ のようにし て、外部関数の出力を gnuplot スクリプト内に取り込むのに利用できます。

1.16.2.60 word

‘word("string",n)‘ は文字列 string の n 番目の単語文字列を返します。例 えば ‘word("one two three",2)‘ は文字列 "two" を返します。

1.16.2.61 words

‘words("string")‘ は文字列 string 中の単語数を返します。例えば ‘words(" a b c d")‘ は 4 を返します。

1.16.2.62 column

‘column(x)‘ は、plot, splot, stats コマンドの一部としてのみ使います。 これは、$x$ 列目の内容を数値として評価します。以下参照: using。

1.16.2.63 columnhead

‘columnhead(x)‘ は、plot, splot, stats コマンドの一部としてのみ使いま す。これは、データファイルの最初の行の $x$ 列目の内容を文字列として評 価します。以下参照: using。

1.16.2.64 exists

‘exists()‘ の引数は文字列定数、または文字列変数です。その文字列が、定 義されている変数名を持っていれば 1 を、そうでなければ 0 を返します。

1.16.2.65 hsv2rgb

関数 ‘hsv2rgb(h,s,v)‘ は、HSV (色相(Hue)/彩度(Saturation)/明度(Value)) の 3 つ組をそれと同等な RGB 値に変換します。

1.16.2.66 stringcolumn

‘stringcolumn(x)‘ は fit あるいはデータファイルプロットでの using の 操作の数式の一部としてのみ使われます。これは $x$ 列目の内容を文字列変 数として返します。‘strcol(x)‘ は、‘stringcolumn(x)‘ の省略形です。 以下も参照: using。

1.16.2.67 timecolumn

‘timecolumn(N,"timeformat")‘ は fit、あるいはデータファイル描画での using 処理の数式の一部としてのみ使います。以下参照: using。

これは、N 列目から始まる文字列データを日時データ値として読み、これをミ リ秒精度の "Unix エポック (1970 年 1 月 1 日) からの秒数" として解釈す るために "timeformat" を使用します。 注意: バージョン 5 より前は、この関数は一つの引数しか取らず、また純粋 に軸の座標を含んでいる列にしか機能していませんでした。

1.16.2.68 tm_hour

関数 ‘tm_hour(x)‘ は引数を 1970 年 1 月 1 日からの秒数と解釈し、それが 時刻の何時 (0–23 の範囲の整数) であるかを、実数として返します。

1.16.2.69 tm_mday

関数 ‘tm_mday(x)‘ は引数を 1970 年 1 月 1 日からの秒数と解釈し、それが その月の何日 (1–31 の範囲の整数) であるかを、実数として返します。

1.16.2.70 tm_min

関数 ‘tm_min(x)‘ は引数を 1970 年 1 月 1 日からの秒数と解釈し、それが 時刻の何分 (0–59 の範囲の整数) であるかを、実数として返します。

1.16.2.71 tm_mon

関数 ‘tm_mon(x)‘ は引数を 1970 年 1 月 1 日からの秒数と解釈し、それが 何月 (0–11 の範囲の整数) であるかを、実数として返します。

1.16.2.72 tm_sec

関数 ‘tm_sec(x)‘ は引数を 1970 年 1 月 1 日からの秒数と解釈し、それが 時刻の何秒 (0–59 の範囲の整数) であるかを、実数として返します。

1.16.2.73 tm_wday

関数 ‘tm_wday(x)‘ は引数を 1970 年 1 月 1 日からの秒数と解釈し、それが その週の何日目 (0–6 の範囲の整数) であるかを、実数として返します。

1.16.2.74 tm_yday

関数 ‘tm_yday(x)‘ は引数を 1970 年 1 月 1 日からの秒数と解釈し、それが その年の何日目 (1–366 の範囲の整数) であるかを、実数として返します。

1.16.2.75 tm_year

関数 ‘tm_year(x)‘ は引数を 1970 年 1 月 1 日からの秒数と解釈し、それが 西暦何年 (整数) であるかを、実数として返します。

1.16.2.76 time

関数 ‘time(x)‘ は現在のシステム時刻を返します。この値は strftime 関 数で日時文字列に変換できますし、timecolumn と組み合わせて相対的な日 時グラフを作成するのにも使えます。引数の型はそれが返すものを決定します。 引数が整数の場合は time() は現在の時刻を 1970 年 1 月 1 日からの整数と して返し、引数が実数 (または複素数) ならば同様の値を実数として返します。 引数が文字列ならば、それを書式文字列であるとみなし、書式化された日時文 字列を提供するようそれを strftime に渡します。

1.16.2.77 valid

‘valid(x)‘ は、データ描画か fit における using の式の中でしか使われ ません。以下参照: using。

1.16.2.78 種々の楕円積分 (elliptic integrals)

関数 ‘EllipticK(k)‘ は、第 1 種完全楕円積分、すなわち、関数 ‘(1-(k*sin(p))**2)**(-0.5)‘ の 0 からπ/2 までの範囲の広義積分の値を返 します。‘k‘ の定義域は -1 から 1 です (両端は含まない)。

関数 ‘EllipticE(k)‘ は、第 2 種完全楕円積分、すなわち、関数 ‘(1-(k*sin(p))**2)**0.5‘ の 0 からπ/2 までの範囲の広義積分の値を返し ます。‘k‘ の定義域は -1 から 1 です (両端も含む)。

関数 ‘EllipticPi(n,k)‘ は、第 3 種完全楕円積分、すなわち関数 ‘(1-(k*sin(p))**2)**(-0.5)/(1-n*sin(p)**2)‘ の 0 からπ/2 までの範囲の 広義積分の値を返します。パラメータ ‘n‘ は 1 より小さく、‘k‘ は -1 と 1 の間 (両端は含まない) でなければいけません。定義より、すべての正の ‘k‘ に対し EllipticPi(0,k) == EllipticK(k) であることに注意してください。

1.16.2.79 乱数の生成 (random)

関数 ‘rand()‘ は 0 と 1 の間の疑似乱数列を生成します。これは以下からの アルゴリズムを使用しています: P. L’Ecuyer and S. Cote, "Implementing a random number package with splitting facilities", ACM Transactions on Mathematical Software, 17:98-111 (1991).

      rand(0)     内部に持つ 2 つの 32bit の種 (seed) の現在の値から生
                  成される [0:1] 区間内の疑似乱数値を返す
      rand(-1)    2 つの種の値を標準値に戻す
      rand(x)     0 < x < 2^31-1 の整数なら種の両方を x に設定する
      rand({x,y}) 0 < x,y < 2^31-1 の整数なら seed1 を x に seed2 を y
                  に設定する

1.16.2.80 value

A がユーザー定義変数の名前であれば、B = value("A") は事実上 B = A と全 く同じです。これは、変数の名前自身が文字列変数に収められている場合に有 用です。以下参照: variables。これは、変数名をデータファ イルから読み取ることも可能にします。引数が数式である場合、value() はそ の数式の値を返します。引数が文字列で、定義されている変数に対応するもの がない場合、value() は NaN を返します。

1.16.2.81 単語の取り出しと単語数 (word, words)

‘word("string",n)‘ は、文字列 (string) の n 番目の単語を返します。例え ば ‘word("one two three",2)‘ は文字列 "two" を返します。

‘words("string")‘ は、文字列 (string) の単語数を返します。例えば、 ‘words(" a b c d")‘ は 4 を返します。

関数 ‘word‘ と words は、単一引用符、二重引用符で囲まれた文字列も、 限定的ですがサポートしています:

      print words("\"double quotes\" or 'single quotes'")   # 3

開始引用符の前は、スペースか、または文字列の先頭でなければいけません。 これは、単語内、あるいは単語終わりにつくアポストロフィー (’) は、それ ぞれの単語の要素であると見なされることを意味します:

      print words("Alexis' phone doesn't work") # 4

引用符文字のエスケープはサポートしていませんので、ある引用符を維持した い場合は、それぞれを別の種類の引用符で囲まなければいけません:

      s = "Keep \"'single quotes'\" or '\"double quotes\"'"
      print word(s, 2) # 'single quotes'
      print word(s, 4) # "double quotes"

最後の例では、引用符のエスケープが文字列の定義時のみに必要であることに 注意してください。

1.16.3 演算子 (Operators)

‘gnuplot‘ の演算子は、C 言語の演算子とほぼ同じですが、特に注意がなけれ ば全ての演算子が整数、実数、複素数の引数を取ることができます。また、 FORTRAN で使える ** (累乗) 演算子もサポートされています。

演算の評価の順序を変更するにはかっこを使います。

1.16.3.1 単項演算子 (Unary)

以下は、単項演算子とその使用法の一覧です:

    記号          例        説明
      -           -a          マイナス符号
      +           +a          プラス符号 (何もしない)
      ~           ~a        * 1 の補数 (ビット反転)
      !           !a        * 論理的否定
      !           a!        * 階乗
      $           $3        * using 内での引数/列指定
      ||          |A|         配列 A の要素数

説明に星印 (*) のついた演算子の引数は整数でなければなりません。

演算子の優先順位は Fortran や C と同じです。それらの言語同様、演算の評 価される順序を変えるためにかっこが使われます。よって -2**2 = -4 で、 (-2)**2 = 4 です。

階乗演算子は、大きな値を返せるように実数を返します。

1.16.3.2 二項演算子 (Binary)

以下は、二項演算子とその使用法の一覧です:

    記号          例          説明
      **          a**b          累乗
      *           a*b           積
      /           a/b           商
      %           a%b         * 余り
      +           a+b           和
      -           a-b           差
      ==          a==b          等しい
      !=          a!=b          等しくない
      <           a<b           より小さい
      <=          a<=b          以下
      >           a>b           より大きい
      >=          a>=b          以上
      <<          0xff<<1       符号なし左シフト
      >>          0xff>>2       符号なし右シフト
      &           a&b         * ビット積 (AND)
      ^           a^b         * ビット排他論理和 (XOR)
      |           a|b         * ビット和 (OR)
      &&          a&&b        * 論理的 AND
      ||          a||b        * 論理的 OR
      =           a = b         代入
      ,           (a,b)         累次評価
      .           A.B           文字列の連結
      eq          A eq B        文字列が等しい
      ne          A ne B        文字列が等しくない

説明に星印 (*) のついた演算子の引数は整数でなければなりません。 大文字の A,B は演算子が文字列引数を要求することを意味します。

論理演算子の AND (&&) と OR (||) は C 言語同様に必要最小限の評価しかし ません。すなわち、‘&&‘ の第 2 引数は、第 1 引数が偽ならば評価されませ んし、‘||‘ の第 2 引数は、第 1 引数が真ならば評価されません。

累次評価 (,) は、カッコの中でのみ評価され、左から右へ順に実行すること が保証され、最も右の式の値が返されます。

1.16.3.3 三項演算子 (Ternary)

一つだけ三項演算子があります:

     記号          例       説明
      ?:          a?b:c     三項演算子

三項演算子は C のものと同じ働きをします。最初の引数 (a) は整数でなけれ ばいけません。この値が評価され、それが真 (ゼロでない) ならば 2 番目の 引数 (b) が評価されその値が返され、そうでなければ 3 番目の引数 (c) が 評価され、その値が返されます。

三項演算子は、区分的に定義された関数や、ある条件が満たされた場合にのみ 点を描画する、といったことを行なう場合に有用です。

例:

0 <= x < 1 では sin(x) に、1 <= x < 2 では 1/x に等しくて、それ以外の x では定義されない関数を描画:

      f(x) = 0<=x && x<1 ? sin(x) : 1<=x && x<2 ? 1/x : 1/0
      plot f(x)

‘gnuplot‘ は未定義値に対しては何も表示せずにただ無視するので、最後の場 合の関数 (1/0) は点を何も出力しないことに注意してください。また、この 関数描画の描画スタイルが lines (線描画) の場合、不連続点 (x=1) の所も 連続関数として線が結ばれてしまうことにも注意してください。その点を不連 続になるようにするには、関数を 2 つの部分それぞれに分けてください (こ のような場合、媒介変数関数を使うのが便利です)。

ファイル ’file’ のデータで、4 列目のデータが負でないときだけ、1 列目の データに関する 2 列目と 3 列目のデータの平均値を描画:

      plot 'file' using 1:( $4<0 ? 1/0 : ($2+$3)/2 )

using の書式の説明に関しては、以下参照: using。

1.16.4 和 (Summation)

和の式は、以下の形式で表します:

      sum [<var> = <start> : <end>] <expression>

ここで <var> は、<start> から <end> までの整数値を順に取る整数変数とし て扱われます。その各値に対して、式 <expression> の値が合計値に追加され、 最終的な合計値がこの和の式の値となります。 例:

      print sum [i=1:10] i
          55.
      # 以下は plot 'data' using 1:($2+$3+$4+$5+$6+...) と同等
      plot 'data' using 1 : (sum [col=2:MAXCOL] column(col))

<expression> は、必ずしも変数 <var> を含む必要はありません。<start> と <end> は変数値や数式で指定もできますが、それらの値は動的に変更すること はできません。そうでないと副作用が起こり得ます。<end> が <start> より 小さい場合は、和の値は 0 となります。

1.16.5 定義済み変数 (Gnuplot-defined variables)

gnuplot は、プログラムの現在の内部状態と直前の描画を反映するような読み 出し専用の変数をいくつか持っています。これらの変数の名前は、例えば GPVAL_TERM, GPVAL_X_MIN, GPVAL_X_MAX, GPVAL_Y_MIN のように "GPVAL_" で 始まります。これらすべての一覧とその値を見るには、‘show variables all‘ と入力してください。ただし、軸のパラメータに関連する値 (範囲、対数軸で あるか等) は、現在 ‘set‘ したものではなく、最後に描画されたものが使用 されます。

例: 点 [X,Y] のスクリーン比での座標を計算する方法

     GRAPH_X = (X - GPVAL_X_MIN) / (GPVAL_X_MAX - GPVAL_X_MIN)
     GRAPH_Y = (Y - GPVAL_Y_MIN) / (GPVAL_Y_MAX - GPVAL_Y_MIN)
     SCREEN_X = GPVAL_TERM_XMIN + GRAPH_X * (GPVAL_TERM_XMAX - GPVAL_TERM_XMIN)
     SCREEN_Y = GPVAL_TERM_YMIN + GRAPH_Y * (GPVAL_TERM_YMAX - GPVAL_TERM_YMIN)
     FRAC_X = SCREEN_X * GPVAL_TERM_SCALE / GPVAL_TERM_XSIZE
     FRAC_Y = SCREEN_Y * GPVAL_TERM_SCALE / GPVAL_TERM_YSIZE

読み出し専用変数 GPVAL_ERRNO は、任意の gnuplot コマンドがあるエラーの ために早く終わってしまった場合に 0 でない値にセットされ、直前のエラー メッセージは文字列変数 GPVAL_ERRMSG に保存されます。GPVAL_ERRNO と GPVAL_ERRMSG は、コマンド ‘reset errors‘ を使ってクリアできます。

‘mouse‘ 機能が使える対話型入出力形式は、"MOUSE_" で始まる読み出し専用 変数をいくつか持っています。詳細は、以下参照: variables。

‘fit‘ 機能は、"FIT_" で始まるいくつかの変数を使用しますので、そのよう な名前を使うのは避けるべきでしょう。‘set fit errorvariables‘ を使用す ると、各当てはめ変数のエラーは、そのパラメータ名に "_err" を追加した変 数に保存されます。詳細は、以下参照: ‘fit‘。

以下も参照: variables, ‘reset errors‘, variables, ‘fit‘。

1.16.6 ユーザ定義の変数と関数 (User-defined)

新たなユーザ定義変数と 1 個から 12 個までの引数を持つユーザ定義関数を、 任意の場所で定義したり使ったりすることができます。それは ‘plot‘ コマン ド上でも可能です。

ユーザ定義関数書式:

      <func-name>( <dummy1> {,<dummy2>} ... {,<dummy12>} ) = <expression>

ここで <expression> は仮変数 <dummy1> から <dummy12> で表される数式です。

ユーザ定義変数書式:

      <variable-name> = <constant-expression>

例:

      w = 2
      q = floor(tan(pi/2 - 0.1))
      f(x) = sin(w*x)
      sinc(x) = sin(pi*x)/(pi*x)
      delta(t) = (t == 0)
      ramp(t) = (t > 0) ? t : 0
      min(a,b) = (a < b) ? a : b
      comb(n,k) = n!/(k!*(n-k)!)
      len3d(x,y,z) = sqrt(x*x+y*y+z*z)
      plot f(x) = sin(x*a), a = 0.2, f(x), a = 0.4, f(x)

      file = "mydata.inp"
      file(n) = sprintf("run_%d.dat",n)

最後の 2 行の例は、ユーザ定義文字列変数と、ユーザ定義文字列関数を意味 しています。

変数 ‘pi‘ (3.14159...) と ‘NaN‘ (IEEE 非数 ("Not a Number")) はあらか じめ定義されています。これらが必要なければ、他のものに再定義することも 可能ですし、以下のようにして元の値に復帰することもできます:

      NaN = GPVAL_NaN
      pi  = GPVAL_pi

他にもいくつかの変数が、例えば対話型入出力形式でのマウス操作や当てはめ (fit) などの gnuplot の動作状態に応じて定義されます。詳細は 以下参照: variables。

ある変数 V が既に定義されているかどうかは、式 exists("V") でチェックで きます。例:

      a = 10
      if (exists("a")) print "a is defined"
      if (!exists("b")) print "b is not defined"

変数名や関数名の命名規則は、大抵のプログラミング言語と同じで、先頭はア ルファベットで、その後の文字はアルファベット、数字、"_" が使えます。

各関数の定義式は、’GPFUN_’ という接頭辞を持つ特別な文字列値変数として 利用できます。

例:

      set label GPFUN_sinc at graph .05,.95

以下参照: functions, functions, variables, ‘macros‘, value。

1.16.7 配列 (Arrays)

配列は、ユーザ変数の添字付きリストとして実装されています。一つの配列の 要素は、一つの変数型には限定されていません。配列は、参照する前に明示的 に作られていなければいけません。配列を作成した後で、そのサイズを変更す ることはできません。すべての要素は、最初は未定義 (undefined) です。ほ とんどの場面で、名前付きユーザ変数の代わりに配列要素を利用できます。 配列 A の要素数は、数式 |A| で取得できます。

例:

     array A[6]
     A[1] = 1
     A[2] = 2.0
     A[3] = {3.0, 3.0}
     A[4] = "four"
     A[6] = A[2]**3
     array B[6] = [ 1, 2.0, A[3], "four", , B[2]**3 ]

     do for [i=1:6] { print A[i], B[i] }
         1 1
         2.0 2.0
         {3.0, 3.0} {3.0, 3.0}
         four four
         <undefined> <undefined>
         8.0 8.0

注意: 配列と変数は、同じ名前空間を共有します。例えば、あらかじめ FOO という名前の配列がある場合、FOO という名前の文字列変数を使うと、配列 を破壊します。

配列の名前を ‘plot‘, ‘splot‘, ‘fit‘, ‘stats‘ コマンドに与えることもで きます。その場合、配列の添字がファイルの 1 列目の値で (1 から size ま で)、その値 A[i] がファイルの 2 列目であるようなデータファイルを与えた ことと同等になります。

例:

     array A[200]
     do for [i=1:200] { A[i] = sin(i * pi/100.) }
     plot A title "sin(x) in centiradians"

ただし、plot 時に複素数値配列の虚数部分を使用する場合は、その値は $2 ではなく、A[$1] として参照する必要があります。例:

     plot A using (F1(real(A[$1])) : (F2(imag(A[$1]))

1.17 フォント

gnuplot それ自身にはどんなフォントも含まれてはおらず、外部フォント処理 に頼っているだけで、その細部は悲しいことに出力形式毎に異なります。ここ では、複数の出力形式に適用されるフォント機構について説明します。ここに 上げたもの以外の出力形式でのフォントの使用に関しては、その出力形式のド キュメントを参照してください。

一時的に、例えば Adobe Symbol フォントのような特別なフォントに切り替え ることでアルファベットではない記号を入れることも可能ですが、現在は、 UTF-8 エンコーディングを使用して、必要な記号を指す Unicode エントリを 指定するという方法があります。以下参照: ‘encoding‘, ‘locale‘。

1.17.1 cairo (pdfcairo, pngcairo, epscairo, wxt 出力形式)

これらの出力形式は、フォントの検索とアクセスに外部の fontconfig ツール 群を使用します。 fontconfig ユーザマニュアル を参照してください。これは、gnuplot で一般的な名前やサイズでフォントを 要求することを可能にし、必要ならば fontconfig に同等のフォントを代用さ せることもできるので、通常はこれで十分でしょう。以下は、多分いずれも機 能します:

     set term pdfcairo font "sans,12"
     set term pdfcairo font "Times,12"
     set term pdfcairo font "Times-New-Roman,12"

1.17.2 gd (png, gif, jpeg, sixel terminals)

png, gif, jpeg, sixelgd 出力形式のフォント処理は、外部ライブラリ libgd によって行われます。libgd は、次の 5 種類の基本フォントを直接提供して います: ‘tiny‘ (5x8 ピクセル), ‘small‘ (6x12 ピクセル), ‘medium‘, (7x13 Bold), ‘large‘ (8x16), ‘giant‘ (9x15 ピクセル)。これらのフォント は大きさを変更したり回転したりすることはできません。使用する際は、 ‘font‘ キーワードの代わりに上のキーワードを指定します。例:

     set term png tiny

多くのシステムで、libgd は Adobe Type 1 フォント (*.pfa) と TrueType フォントへのアクセスも提供します。その場合フォント自身の名前ではなく、 フォントファイルの名前を、"<face> {,<pointsize>}" の形式で与えます。 ここで、<face> はフォントファイルのフルパス名か、または環境変数 GDFONTPATH で指示されるディレクトリの一つの中のファイル名の先頭部分、 のいずれかです。よって、’set term png font "Face"’ は、 <あるディレクトリ>/Face.ttf か <あるディレクトリ>/Face.pfa というファ イル名のフォントを探そうとします。例えば、GDFONTPATH に ‘/usr/local/fonts/ttf:/usr/local/fonts/pfa‘ が含まれている場合は、以下 のコマンドの 2 つずつはいずれも同じことになります:

     set term png font "arial"
     set term png font "/usr/local/fonts/ttf/arial.ttf"
     set term png font "Helvetica"
     set term png font "/usr/local/fonts/pfa/Helvetica.pfa"

デフォルトのフォントサイズも同時に指定するには:

     set term png font "arial,11"

TrueType と Adobe Type 1 フォントは、完全に大きさの変更や回転が可能で す。"set term" コマンドでフォントを指定しなかった場合、gnuplot は別の デフォルトフォントの設定があるかどうかを調べるために環境変数 GNUPLOT_DEFAULT_GDFONT を参照します。

1.17.3 postscript (カプセル化 postscript *.eps も)

PostScript フォント処理は、プリンタか表示ソフトが行います。もし、あな たのコンピュータにフォントが一切なくても、gnuplot は正しい PostScript ファイル、またはカプセル化 PostScript (*.eps) ファイルを生成できます。 gnuplot は単に出力ファイル中にフォントを名前として入れるだけで、プリン タや表示ソフトがその名前からフォントを見つけるか近似することを仮定して います。

PostScript プリンタや表示ソフトはすべて、標準的な Adobe フォントセット ‘Times-Roman‘, ‘Helvetica‘, ‘Courier‘, ‘Symbol‘ は知っているはずです。 多分その他にも多くのフォントが使えるようになっていると思いますが、それ ら特定のフォントセットはあなたのシステムやプリンタの設定に依存します。 gnuplot は、それは知りませんし気にもしません。gnuplot が作成した *.ps や *.eps 出力は、あなたの要求したフォント名を単に持っているだけです。

よって、

     set term postscript eps font "Times-Roman,12"

は、すべてのプリンタや表示ソフトに適切な出力を作成します。

一方、

     set term postscript eps font "Garamond-Premier-Pro-Italic"

は、正しい PostScript を含む出力ファイルを作成しますが、それは特殊なフ ォントを参照しますので、一部のプリンタや表示ソフトしか、要求したその特 定のフォントは表示できないでしょう。大抵の場合は別なフォントで代用され ます。

しかし、指定したフォントを出力ファイル中に埋め込んで、どんなプリンタで もそれを使うようにすることも可能です。これには、あなたのシステムに適切 なフォント記述ファイルがあることが必要となります。この方法でフォントを 埋め込む場合、特定のライセンスが必要となるフォントファイルもあることに 注意してください。より詳細な説明や例については、以下参照: ‘postscript fontfile‘。

1.18 ヘルプの用語解説 (Glossary)

このドキュメント全体に渡って、用語に関する一貫性の維持が考えられていま す。しかしこの試みは完全には成功していません。それは ‘gnuplot‘ が時間 をかけて進化してきたように、コマンドやキーワードの名前もそのような完全 性を排除するかのように採用されて来ているからです。このセクションでは、 これらのキーワードのいくつかがどのように使われているかを説明します。

"ページ (page)"、"表示画面 (screen)"、"キャンバス (canvas)" は、 ‘gnuplot‘ がアクセス可能な領域全体を指します。デスクトップではそれはウ ィンドウ全体を指し、プロッタでは、一枚の紙全体、svga モードでは、モニ タスクリーン全体を指します。

表示画面は、一つ、またはそれ以上の "グラフ描画 (plot)" を含みます。グ ラフ描画は一つの横座標と一つの縦座標で定義されますが、余白 (margin) や その中に書かれる文字列 (text) 同様、それらは実際にその上に表示されてい る必要はありません。

グラフ描画は一つの "グラフ" を含みます。グラフは一つの横座標と一つの縦 座標で定義されますが、これらは実際にその上に表示されている必要はありま せん。

グラフは一つまたはそれ以上の "曲線 (line)" を含みます。曲線は一つの関 数、またはデータ集合です。用語 "line" は描画スタイルとしても使われます。 さらにこの用語は "文字列の一行 (a line of text)" のように使われること もあります。多分文脈からそれらは区別できるでしょう。

一つのグラフ上の複数の曲線はそれぞれ名前を持ちます。その名前は、その曲 線の表現に使われる描画スタイルのサンプルとともに "凡例 (key)" 内に一覧 表示されます。凡例は、時には "表題 (legend)" とも呼ばれます。

用語 "タイトル (title)" は ‘gnuplot‘ では複数の意味で使われます。この ドキュメントではそれらを区別するために、形容詞として "描画の (plot)"、 "曲線の (line)"、"凡例の (key)" を頭につけたりもします。 2 次元のグラフは 4 つまでの見出し付けされる軸を持つことができます。こ れら 4 つの軸の名前はそれぞれ、グラフ描画の下の境界に沿う軸である "x"、 左の境界に沿う軸 "y"、上の境界に沿う軸 "x2"、右の境界に沿う軸 "y2" と なっています。以下参照: ‘axes‘。

3 次元のグラフは 3 つまでの見出し付けされる軸 (‘axes‘) "x","y","z" を 持つことができます。どの特定の軸に関してもそれがグラフ上でどこに書かれ るかを述べることはできません。それは、‘set view‘ でグラフを見る方向を 変更できるからです。

データファイルに関する議論では、用語 "行 (record)" を復活し、ファイル の一行の文字列、すなわち、改行文字や行末文字同士の間の文字列、を指し示 すのに使います。"点 (point)" は行から取り出した一つのデータです。デー タの "ブロック (block)" は、空行で区切られた連続した複数の行からなる集 合です。データファイルの議論の中で "line" が参照される場合は、これはブ ロックの部分集合を指します。"データのブロック (data block)" という言葉 は、インラインデータの名前付きブロックを指すのにも使われています。以下 参照: ‘datablocks‘。

(訳注: この日本語訳の中ではここに書かれているような用語の統一は考慮さ れてはおらず、よって混乱を引き起こす可能性があります。厳密には原文を参 照すべきでしょう。)

1.19 インラインデータとデータブロック (inline data and datablocks)

gnuplot のコマンド入力の中にデータを埋め込む仕組みは 2 種類用意されて います。まず、特殊ファイル名 ’-’ が plot コマンド中に与えると、その plot コマンド以下に続く行がインラインデータと解釈されます。以下参照: ‘special-filenames‘。この方法で提供されるデータは、その plot コマンド で一度しか使用できません。

もう一つは、ヒアドキュメントとして名前付きのデータブロックを定義する方 法です。その名前付きのデータは残るので、複数の plot コマンドで参照でき ます。例:

     $Mydata << EOD
     11 22 33 first line of data
     44 55 66 second line of data
     # データファイル同様コメントも機能する
     77 88 99
     EOD
     stats $Mydata using 1:3
     plot $Mydata using 1:3 with points, $Mydata using 1:2 with impulses

データブロック名は、他の変数と区別するために、最初の文字を $ にする必 要があります。データの終わりの区切り (上の例では EOD) は、任意のアルフ ァベット、数字からなる文字列で構いません。

コマンド undefine を使えば、保存した名前付きデータブロックを削除でき ます。‘undefine $*‘ は、すべての名前付きデータブロックを一度に削除しま す。

1.20 繰り返し (iteration)

gnuplot バージョン 4.6 には、繰り返し (iteration) コマンドやブロック構 造を扱える if/else/while/do が導入されています。以下参照: ‘if‘, ‘while‘, ‘do‘。単純な繰り返しは、コマンド ‘plot‘, ‘set‘ で利用できま す。以下参照: ‘plot for‘。複数のコマンドを包含する一般的な繰り返しは、 下で紹介するブロック構造を利用することで行えます。関連する新しい機能で ある数式型の以下も参照: ‘summation‘。以下は、これらの新しい構文機能を いくつか利用した例です:

      set multiplot layout 2,2
      fourier(k, x) = sin(3./2*k)/k * 2./3*cos(k*x)
      do for [power = 0:3] {
          TERMS = 10**power
          set title sprintf("%g term Fourier series",TERMS)
          plot 0.5 + sum [k=1:TERMS] fourier(k,x) notitle
      }
      unset multiplot

繰り返しは、以下のような書式による繰り返し指定で制御します。

     for [<var> in "string of N elements"]

または

     for [<var> = <start> : <end> { : <increment> }]

最初の書式では <var> は文字列変数で、その後ろに指定した文字列に含まれ る 1 番目から N 番目までの単語文字列を順に値として取ります。 2 番目の書式では、<start>, <end>, <increment> は整数、または整数値を取 る数式です。

一つの例外を除いて、gnuplot の変数は大域的です。 名前で添字づけされた、永続的で有効な変数のリストが一つだけあり、変数の 割り当ては、そのリストに項を生成するか、または項の置き換えにより行われ ます。変数をそのリストから削除するただ一つの方法は、undefine コマン ドを使うことです。

これのただ一つの例外は、繰り返し指定で用いられる変数です。繰り返し変数 の有効範囲 (scope) は、その繰り返しの中だけですから、その値を、繰り返 しの実行ブロック内から永続的に変更することはできません。繰り返し変数が 繰り返しの前に値を持っていたとしたら、その値は繰り返しの終了時に保持、 または復帰されます。 例えば、以下のコマンドは、1 2 3 4 5 6 7 8 9 10 A を出力します。

     i = "A"
     do for [i=1:10] { print i; i=10; }
     print i

1.21 線種、色、スタイル (linetypes)

古い版の gnuplot では、各出力形式は "線種 (linetype)" をある程度用意し ていて、それらは色、太さ、点線/破線のパターン、または色と点線/破線の組 合せで違いを表現していました。それらの色、点線/破線のパターンは、出力 形式を越えて同じものになるという保証は何もありませんでしたが、多くは同 じ色の列、赤/緑/青/紫/水色/黄色を使用していました。この古い挙動は、今 は ‘set colorsequence classic‘ で選択できますが、gnuplot バージョン 5 のデフォルトは、出力形式に無関係に共通の 8 色列を使用します。

線種 (linetype) の属性の並びは、対話的か初期化ファイルのいずれかによっ てさらにカスタマイズ可能です。以下参照: linetype。配布パッケージ に初期化ファイルのサンプルがいくつか用意されています。

特定の出力形式に対する線種の属性の現在の状態は、その出力形式を設定した あとで test コマンドを実行することで確認できます。

一つの描画コマンド内での関数やデータファイルの連続する並びには、現在の デフォルトの線種列から線種が順番に割り当てられます。個々の関数、データ ファイル、またはその他の描画要素に対する線種は、その描画コマンド上で明 示的に線の属性を指定することで上書きできます。

例:

     plot "foo", "bar"                 # 線種 1, 2 で 2 ファイルを描画
     plot sin(x) linetype 4            # 線種色 4 を使用

一般に、色の指定は、色の名前か、RGB (赤、緑、青) 成分か、HSV (色相、彩 度、明度) 成分か、現在の pm3d パレットに沿った座標で行います。

例:

     plot sin(x) lt rgb "violet"       # gnuplot の持つ色名の一つ
     plot sin(x) lt rgb "#FF00FF"      # 明示的な 16 進 RGB 3 つ組
     plot sin(x) lt palette cb -45     # 現在のパレットの cbrange の
                                       # -45 に対応する色
     plot sin(x) lt palette frac 0.3   # パレットに対応する小数値

以下参照: ‘colorspec‘, ‘show colornames‘, ‘hsv‘, ‘set palette‘, cbrange。以下も参照: monochrome。

線種 (linetype) には、点線/破線のパターンも結びつけられていますが、す べての出力形式でそれが使えるわけではありません。gnuplot バージョン 5 では、線色とは独立に点線/破線パターンを指定できます。以下参照: ‘dashtype‘。

1.21.1 色指定 (colorspec)

多くのコマンドで、明示的な色の指定をともなった線種を指定することができ ます。

書式:

      ... {linecolor | lc} {"colorname" | <colorspec> | <n>}
      ... {textcolor | tc} {<colorspec> | {linetype | lt} <n>}

<colorspec> は以下の形式のいずれかです:

      rgbcolor "colorname"    # 例: "blue"
      rgbcolor "0xRRGGBB"     # 16 進数値の定数文字列
      rgbcolor "0xAARRGGBB"   # 16 進数値の定数文字列
      rgbcolor "#RRGGBB"      # x11 形式の 16 進数文字列
      rgbcolor "#AARRGGBB"    # x11 形式の 16 進数文字列
      rgbcolor <integer val>  # AARRGGBB を表す整数値
      rgbcolor variable       # 入力ファイルから整数値を読み込む
      palette frac <val>      # <val> は 0 から 1 の値
      palette cb <value>      # <val> は cbrange の範囲の値
      palette z
      variable                # 入力ファイルから色番号を読み込む
      bgnd                    # 背景色
      black

<n> は、その線種 (linetype) 番号が使う色を意味します。以下参照: test。

"colorname" は gnuplot が内部に持っている色の名前のうちの一つを指定し ます。有効な名前の一覧に関しては、以下参照: ‘show colornames‘。

16 進定数は、引用符付きで "#RRGGBB" や "0xRRGGBB" の形で与えることがで きます。RRGGBB は、色の赤、緑、青の成分を意味し、それぞれ 00 から FF までの範囲内でなければいけません。例えば、マゼンタ (紫) は、最も明るい 赤 + 最も明るい青、なので "0xFF00FF" と表され、これは 16 進数で (255 << 16) + (0 << 8) + (255) を意味しています。

"#AARRGGBB" は、RGB 色の上位ビットにアルファ値 (透過性) がついているこ とを意味します。アルファ値 0 は完全に不透明色であることを意味し、よっ て "#00RRGGBB" は "#RRGGBB" と同じになります。アルファ値の 255 (FF) は 完全に透明であることを意味します。‘注意‘: この指定法のアルファ値の位置 は、以前の版の gnuplot の画像描画モード "with rgbalpha" による指定の場 合の反対になっています。

カラーパレットとは、色の線型な勾配で、単一の数値を特定の色に滑らかに対 応づけます。常にそのような 2 つの対応付けが効力を持ちます。 ‘palette frac‘ は 0 から 1 までの小数値を、カラーパレットの全範囲に対 応付けるもので、‘palette cb‘ は、色軸の範囲を同じカラーパレットへ割り 当てるものです。以下参照: cbrange, ‘set colorbox‘。これらの対応 付けのどちらかを使って、現在のパレットから定数色を選び出すことができま す。

"palette z" は、各描画線分や描画要素の z の値を、パレットへ対応づけら れている cbrange の範囲に対応づけます。これにより、3 次元の曲線や曲面 に沿って色を滑らかに変化させることができます。これは、2 次元描画で、パ レット値を追加の列データから読み込ませて色付けするのにも使えます (すべ ての 2 次元描画スタイルがこの追加列を認識するわけではありません)。

特殊な色指定が 2 つあります。背景色の ‘bgnd‘ と、‘black‘ です。

1.21.1.1 background color

多くの出力形式でグラフの背景色を明示的に設定できます。特別な線種 (linetype) ‘bgnd‘ はその色で描画しますが、その ‘bgnd‘ は色としても認識 されます。 例:

     # 以下はキャンバスの一部分を背景色で上書きすることで消去します。
     set term wxt background rgb "gray75"
     set object 1 rectangle from x0,y0 to x1,y1 fillstyle solid fillcolor bgnd
     # 以下は x 軸に沿った「見えない」線を描きます。
     plot 0 lt bgnd

1.21.1.2 linecolor variable

‘lc variable‘ は、入力データの一つの列から読んだ値を線種 (linetype) の 番号として使い、その線種に属する色を使うようプログラムに指示します。よ ってこれは、using 指定子へ対応する列の指定の追加を必要とします。文字 の色も同様に、‘tc variable‘ で指定できます。

例:

      # データの 3 列目を、個々の点に色を割り当てるのに使用
      plot 'data' using 1:2:3 with points lc variable

      # 一つのデータファイルには複数のデータ集合を入れることが可能で、
      # それらは 2 行の空行で分離されています。個々のデータ集合には
      # index 値が割り当てられていて (以下参照: index)、using 指定の
      # column(-2) で取得できます。以下参照: `pseudocolumns`。以下の例
      # は -2 の column 値を使って、個々のデータ集合を異なる線色で描画
      # します。
      plot 'data' using 1:2:(column(-2)) with lines lc variable

1.21.1.3 rgbcolor variable

グラフの各データ点、各線分、または各ラベルにそれぞれ異なる色を割り当て ることができます。‘lc rgbcolor variable‘ は、データファイルの各行から RGB 色の情報を読み込むようプログラムに指示します。よってこれは、 using 指定子による対応する列の指定の追加を必要とし、その列は 24-bit 形式の RGB の 3 つ組であるとみなされます。その値をデータファイルから直 接与える場合は、これは最も簡単な形式の 16 進値で与えます (以下参照: ‘rgbcolor‘)。一方で、以下の例のように 24-bit RGB 色として評価されるよ うな数式を using 指定子に入れることもできます。文字の色も同様に、 ‘tc rgbcolor variable‘ で指定できます。

例:

      # 3 次元描画で、各 x,y,z 座標に対応した赤、緑、青の成分を持つ色
      # のついた点を配置
      rgb(r,g,b) = 65536 * int(r) + 256 * int(g) + int(b)
      splot "data" using 1:2:3:(rgb($1,$2,$3)) with points lc rgb variable

1.21.2 点線/破線種 (dashtype)

gnuplot バージョン 5 で、‘linecolor‘ や ‘linewidth‘ と同様に、点線/破 線パターン (‘dashtype‘) が各曲線毎の属性として独立しました。従来のよう な、使用中の出力形式の点線を書くための特別なモードとして指定する必要は ありません。すなわち、‘set term <termname> {solid|dashed}‘ のようなコ マンドは現在は無視されます。バージョン 4 用に書いた古いスクリプトへの 後方互換性が必要な場合は、以下のような書き方で代用できます:

     if (GPVAL_VERSION >= 5.0) set for [i=1:9] linetype i dashtype i
     if (GPVAL_VERSION < 5.0) set termoption dashed

すべての線は、ほかに指定しなければ、‘dashtype solid‘ という属性を持ち ますが、このデフォルト値をコマンド linetype で特定の線種に変更し その後のコマンドで使えるようにできます。または、‘plot‘ や他のコマンド の一部分として使用したい点線/破線の型を指定できます。

書式:

      dashtype N          # 定義済み点線/破線型を番号で呼び出し
      dashtype "pattern"  # 点 (.) 横線 (-) 下線 (_) と空白の組み合わ
                          # せ文字列による指定
      dashtype (s1,e1,s2,e2,s3,e3,s4,e4)  # 1~4 個の <実線長>,<空白長>
                          # の組による点線/破線パターン指定

例:

      # 2 つの関数が線種 1 を使うが dashtype で区別
      plot f1(x) with lines lt 1 dt solid, f2(x) with lines lt 1 dt 3

いくつかの出力形式は、それが提供する定義済み点線/破線パターンに、ユー ザ定義パターンを追加することをサポートしています。

例:

     plot f(x) dt 3            # 出力形式の持つパターン 3 を使用
     plot f(x) dt ".. "        # 一時的なパターンを作成
     plot f(x) dt (2,5,2,15)   # 同じパターンを数値で表現
     set dashtype 11 (2,4,4,7) # 新パターンを番号で呼び出せるよう定義
     plot f(x) dt 11           # 新パターンを使って描画

点線/破線パターンを文字列で指定した場合、gnuplot はそれを <実線長>, <空白長> の組の列に変換します。ドット "." は (2,5) に、ダッシュ "-" は (10,10) に、下線 "_" は (20,10) に、また空白 " " は直前の <空白長> の 値に 10 を追加します。その場合、コマンド ‘show dashtype‘ は、元の文字 列と変換後の数値の列の両方を表示します。

1.21.3 linestyles と linetypes

‘linestyle‘ は、属性 linecolor, linewidth, dashtype, pointtype の一時 的な組み合わせで、これはコマンド ‘set style line‘ で定義します。一度 linestyle を定義すると、1 回の plot コマンド上でそれを使って、1 つ、ま たはより多くの描画要素の見た目を制御できます。言い換えれば、これは丁度 linetype から永続性を取り除いたもの、と言うことができるでしょう。 ‘linetypes‘ は永続的 (明示的にそれらを再定義するまでは保持される) です が、‘linestyles‘ は、次のグラフィックの状態がリセットされるまでの間し か保持されません。

例:

     # 新しいラインスタイルを、出力形式に依存しない色 cyan、線幅が 3、
     # 点種 6 (丸の中に点) と定義
     set style line 5 lt rgb "cyan" lw 3 pt 6
     plot sin(x) with linespoints ls 5          # 定義スタイル 5 で

1.22 レイヤー (layers)

gnuplot のグラフは、色々な要素を固定された順番で描き上げていくことで構 成されています。この順番は、キーワード ‘behind‘, ‘back‘, ‘front‘ を使 って要素に特定の階層を割り当てることで変更できます。例えば、グラフ領域 の背景色を変更するには、色のついた長方形を属性 ‘behind‘ で定義すればい いわけです。

     set object 1 rectangle from graph 0,0 to graph 1,1 fc rgb "gray" behind

描画の順番は以下の通りです:

     behind
     back
     グラフ自体
     グラフの表題 (`key`)
     front

各階層内では、要素の描画は以下の順番です:

     番号順のオブジェクト (rectangle, circle, ellipse, polygon)
     番号順のラベル (label)
     番号順の矢印 (arrow)

1 ページに複数のグラフがある場合 (multiplot モード)、この順序は、複数 グラフを全体として適用するのではなく、各描画要素に別々に適用します。

1.23 マウス入力 (mouse input)

多くの出力形式で、現在の描画にマウスを使って作用をすることが可能になっ ています。そのうちいくつかはホットキーの定義もサポートしていて、マウス カーソルが有効な描画ウィンドウにあるときに、あるキーを押すことであらか じめ定義した関数を実行させることができます。マウス入力を ‘batch‘ コマ ンドスクリプトと組み合わせることも可能で、例えば ‘pause mouse‘ として、 その後にマウスクリックによってパラメータとして返って来るマウス変数をそ の後のスクリプト動作に反映させることができます。以下参照: ‘bind‘, variables。また以下も参照: ‘set mouse‘。

1.23.1 bind

書式:

      bind {allwindows} [<key-sequence>] ["<gnuplot commands>"]
      bind <key-sequence> ""
      reset bind

‘bind‘ は、ホットキーの定義、再定義に使用します。ホットキーとは、入力 カーソルがドライバのウィンドウ内にあるときに、あるキー、または複数のキ ーを押すことで、gnuplot のコマンド列を実行させる機能のことを言います。 ‘bind‘ は、gnuplot が ‘mouse‘ をサポートするようにコンパイルされていて かつマウスが有効な出力形式上で使われてる場合にのみ有効であることに注意 してください。ユーザ指定のキー割当 (binding) は、組み込み (builtin) キ ー割当を置き換えますが、<space> と ’q’ は通常は再定義はできません。そ の唯一の例外については、以下参照: ‘bind space‘。

マウスボタンは、ボタン 1 のみ、2 次元描画用にのみ定義可能です。

ホットキーの一覧を得るには ‘show bind‘, または ‘bind‘ とタイプするか、 グラフウィンドウ上でホットキー ’h’ を入力してください。

キー定義は、‘reset bind‘ でデフォルトの状態に復帰できます。

修飾キーを含む複数のキーの定義は引用符で囲む必要があることに注意してく ださい。

標準ではホットキーは現在の描画ウィンドウ上に入力カーソルがある場合のみ 認識されます。‘bind allwindows <key> ...‘ (‘bind all <key> ...‘ と省略 可) は、<key> の割当を、それが現在の有効なものか否かに関わらず、すべて の gnuplot の描画ウィンドウ上で可能にします。この場合、gnuplot 変数 MOUSE_KEY_WINDOW にそれが行なわれたウィンドウの ID が保存されるのでそ れをキーに割り当てたコマンドで使用することができます。

例:

- キー割当の設定:

    bind a "replot"
    bind "ctrl-a" "plot x*x"
    bind "ctrl-alt-a" 'print "great"'
    bind Home "set view 60,30; replot"
    bind all Home 'print "This is window ",MOUSE_KEY_WINDOW'

- キー割当を表示:

    bind "ctrl-a"          # ctrl-a に対するキー割当を表示
    bind                   # 全てのキー定義を表示
    show bind              # 全てのキー定義を表示

- キー割当を削除:

    bind "ctrl-alt-a" ""   # ctrl-alt-a のキー割当を削除
                             (組み込みキー定義は削除されません)
    reset bind             # デフォルト (組み込み) のキー定義を導入

- トグルスイッチ形式にキー割当:

  v=0
  bind "ctrl-r" "v=v+1;if(v%2)set term x11 noraise; else set term x11 raise"

修飾キー (ctrl / alt) は大文字小文字の区別はありませんが、キーはそうで はありません:

    ctrl-alt-a == CtRl-alT-a
    ctrl-alt-a != ctrl-alt-A

修飾キー (alt == meta) の一覧:

    ctrl, alt, shift (ボタン 1 でのみ有効)

サポートされている特殊キーの一覧:

   "BackSpace", "Tab", "Linefeed", "Clear", "Return", "Pause", "Scroll_Lock",
   "Sys_Req", "Escape", "Delete", "Home", "Left", "Up", "Right", "Down",
   "PageUp", "PageDown", "End", "Begin",

   "KP_Space", "KP_Tab", "KP_Enter", "KP_F1", "KP_F2", "KP_F3", "KP_F4",
   "KP_Home", "KP_Left", "KP_Up", "KP_Right", "KP_Down", "KP_PageUp",
   "KP_PageDown", "KP_End", "KP_Begin", "KP_Insert", "KP_Delete", "KP_Equal",
   "KP_Multiply", "KP_Add", "KP_Separator", "KP_Subtract", "KP_Decimal",
   "KP_Divide",

   "KP_1" - "KP_9", "F1" - "F12"

以下は、実際のキーではなく、ウィンドウに関するイベントです:

   "Button1" "Close"

以下も参照: ‘mouse‘。

1.23.1.1 bind space

gnuplot が、configure 時にオプション –enable-rase-console をつけてイ ンストールされた場合は、描画ウィンドウ内で <space> をタイプすると gnuplot のコマンドウィンドウが前面に出ます。このホットキーは、 ’gnuplot -ctrlq’ のようにして gnuplot を起動するか、または X リソース の ’gnuplot*ctrlq’ を設定することで ctrl-space に変更できます。 以下参照: ‘x11 command-line-options‘。

1.23.2 マウス用の変数 (Mouse variables)

‘mousing‘ (マウス機能) が有効な場合、現在のウィンドウ上でのマウスクリ ックによって gnuplot のコマンドライン上で使うことができる色々なユーザ 変数が設定されます。クリック時のマウスの座標は変数 MOUSE_X, MOUSE_Y, MOUSE_X2, MOUSE_Y2 に代入されます。クリックされたボタンや、そのときの メタキーの状態は MOUSE_BUTTON, MOUSE_SHIFT, MOUSE_ALT, MOUSE_CTRL に代 入されます。これらの変数は任意の描画の開始時には未定義で、有効な描画ウ ィンドウ中でのマウスクリックイベントによって初めて定義されます。有効な 描画ウィンドウ中でマウスが既にクリックされたかどうかをスクリプトから調 べるには、これらの変数のうちのどれか一つが定義されているかどうかをチェ ックすれば十分です。

      plot 'something'
      pause mouse
      if (exists("MOUSE_BUTTON")) call 'something_else'; \
      else print "No mouse click."

描画ウィンドウ上での一連のキー入力を追跡することも、マウスコードを使う ことで可能となります。

      plot 'something'
      pause mouse keypress
      print "Keystroke ", MOUSE_KEY, " at ", MOUSE_X, " ", MOUSE_Y

‘pause mouse keypress‘ が、キー入力で終了した場合は MOUSE_KEY には押さ れたキーの ASCII コードが保存されます。MOUSE_CHAR にはその文字自身が文 字列値として保存されます。pause コマンドが (例えば ctrl-C や描画ウィン ドウが外部から閉じられるなどして) 異常終了した場合は MOUSE_KEY は -1 になります。

マウスによる拡大の後の新しい描画範囲は、GPVAL_X_MIN, GPVAL_X_MAX, GPVAL_Y_MIN, GPVAL_Y_MAX で参照できることに注意してください。 以下参照: variables。

1.24 残留 (Persist)

gnuplot の多くの出力形式 (aqua, pm, qt, x11, windows, wxt, ...) が、ス クリーン上にグラフをその中に描いた表示用のウィンドウを別に開きます。オ プション ‘persist‘ は、主たるプログラムが終了したときにも、それらのウ ィンドウを残すよう gnuplot に指示します。 これは、非対話型出力形式出力では何もしません。 例えば、以下のコマンドを実行すると

     gnuplot -persist -e 'plot [-5:5] sinh(x)'

gnuplot は、表示ウィンドウを開き、その中にグラフを描き、そして終了し、 表示ウィンドウはグラフをその中に持ったままスクリーンに残ります。出力形 式によっては、その残ったウィンドウ上でも多少のマウス操作が可能な場合も あります。しかし、グラフの再描画を要求するズーム (とその逆) のような操 作は、既にプログラムが終了しているので一般的には無理です。

新しい出力形式を設定するときにも ‘persist‘ や ‘nopersist‘ を指定できま す。例:

     set term qt persist size 700,500

1.25 描画 (Plotting)

‘gnuplot‘ にはグラフを描画する 4 つのコマンド ‘plot‘, ‘splot‘, replot, refresh があります。他のコマンドは、最終的にグラフ上に生成される描画 要素や、レイアウト、スタイルの制御を行います。 ‘plot‘ は 2 次元グラフを生成します。‘splot‘ は 3 次元グラフ (もちろん 実際にはその 2 次元面への射影) を生成します。replot は、直前の ‘plot‘ や ‘splot‘ コマンドを再実行します。refresh は、replot と似ています が、入力データをファイルや入力ストリームから再読み込みする代わりに、前 に保存したデータを再使用します。

これら 4 つのコマンドのうちの一つを実行した場合は、現在定義されている 軸、ラベル、タイトル、および元の plot コマンドで指定されたさまざまな関 数やデータのすべてを含む出力のスクリーンを再描画するか、新しい出力ペー ジを生成します。もし、一つのページに複数のグラフを隣り合うように並べて 出力したい場合、例えば複数の図のパネルを作成したり、大きなグラフの中に 小さなグラフを挿入したりしたい場合は、コマンド ‘set multiplot‘ を使用 し、各描画コマンドで新しいページが作られるのを抑制してください。

描画に関する一般的な情報の大半は、‘plot‘ に関する項で見つかります。3 次元描画に固有の情報は ‘splot‘ の項にあります。

‘plot‘ は xy 直交座標系と極座標系が使えます。以下参照: ‘set polar‘。 ‘splot‘ は xyz 直交座標が使えますが、3 次元極座標、円柱座標データも入 力できます。以下参照: ‘set mapping‘。

‘plot‘ では、4 つの境界 x (下), x2 (上), y (左), y2 (右) をそれぞれ独 立な軸として扱うこともできます。オプション ‘axes‘ で、与えられた関数や データ集合をどの軸のペアで表示させるかを選べます。また、各軸の縮尺や見 出しづけを完全に制御するために十分な補佐となる ‘set‘ コマンド群が存在 します。いくつかのコマンドは、‘set xlabel‘ のように軸の名前をその中に 持っていますし、それ以外のものは ‘set logscale xy‘ のように、1 つ、ま たは複数の軸の名前をオプションとしてとります。z 軸を制御するオプション やコマンドは 2 次元グラフには効力を持ちません。

‘splot‘ は、点や線に加えて曲面や等高線を書くことができます。3 次元の関 数の格子定義に関する情報については、以下参照: ‘set isosamples‘。3 次元 データのファイルに必要な形態については、以下参照: datafile。等 高線に関する情報については、以下参照: ‘set contour‘, ‘set cntrlabel‘, ‘set cntrparam‘。

‘splot‘ での縮尺や見出し付けの制御は、z 軸にも有効であること、および x2 軸、y2 軸のラベル付けが ‘set view map‘ を使って作られる疑似的な 2 次元描画にのみ可能であることを除けば ‘plot‘ と全く同じです。

1.26 初期化 (Startup (initialization))

起動時に、gnuplot はまずシステム用の初期設定ファイル ‘gnuplotrc‘ を探 します。そのファイルの置き場所は gnuplot のインストール時に決定され、 ‘show loadpath‘ で知ることができます。次にユーザのホームディレクトリ内 に個人用の設定ファイルを探します。そのファイルは Unix 系のシステムでは ‘.gnuplot‘ であり、その他の処理系では ‘GNUPLOT.INI‘ となっています。 (OS/2 では、環境変数 ‘GNUPLOT‘ に設定されている名前のディレクトリ内に それを探します; Windows では、‘APPDATA‘ を使用します)。注意: インスト ール時に ‘gnuplot‘ が最初にカレントディレクトリを探すように設定できま すが、セキュリティ上危険なのでそれは推奨しません。

1.27 文字列定数と文字列変数 (Strings)

文字列定数に加えて、ほとんどの gnuplot コマンドは文字列変数、文字列式 または文字列を返す関数も受け付けます。例えば、以下の 4 つの plot のや り方は結果として全て同じ描画タイトルを生成します:

      four = "4"
      graph4 = "Title for plot #4"
      graph(n) = sprintf("Title for plot #%d",n)

      plot 'data.4' title "Title for plot #4"
      plot 'data.4' title graph4
      plot 'data.4' title "Title for plot #".four
      plot 'data.4' title graph(4)

整数は、それが文字列結合演算子 (文字 ’.’) によって作用された場合は、文 字列に変換されますので、以下の例も上と同様に動作します:

      N = 4
      plot 'data.'.N title "Title for plot #".N

一般に、コマンドラインの各要素は、それらが標準的な gnuplot への命令文 法の一部分と認識されるもの以外は、有効な文字列変数としての評価のみが行 なわれます。よって、以下のコマンド列は、恐らくは混乱を引き起こさないよ うに避けられるべきですが、文法的には間違ってはいません:

      plot = "my_datafile.dat"
      title = "My Title"
      plot plot title title

次の 3 つの二項演算子は文字列に作用します: 文字列の結合演算子 ".", 文 字列の等号演算子 "eq", および文字列の不等号演算子 "ne" です。以下の例 では TRUE が表示されます。

     if ("A"."B" eq "AB") print "TRUE"

以下も参照: 2 つの文字列書式関数 gprintf, sprintf。

任意の文字列、文字列変数、文字列値関数に、範囲指定子をつけることにより 部分文字列を指定できます。範囲指定子は [begin:end] の形で、begin は部 分文字列の先頭位置、end は最後の位置です。位置指定は、最初の文字を 1 番目と見ます。先頭の位置、最後の位置は空、あるいは ’*’ でも構いません。 その場合、それは元の文字列自体の先頭、あるいは最後を意味します。例えば、 str[:] や str[*:*] はどちらも str の文字列全体を意味します。

1.28 置換とコマンドラインマクロ (Substitution)

gnuplot への命令文字列が最初に読み込まれた時点、すなわちまだそれが解釈 され、もしくは実行される前の段階で、2 つの形式の単語の置換が実行されま す。それらは逆引用符 (｀) (ASCII 番号 96) で囲まれているか、または @ (ASCII 番号 64) が頭についた文字列に対して行なわれます。

1.28.1 逆引用符によるシステムコマンドの置換 (Substitution backquotes)

シェルコマンドを逆引用符 (｀) で囲むことによってコマンド置換を行うこと ができます。このコマンドは子プロセスで実行され、その出力結果でコマンド ラインの逆引用符で囲まれた部分を置き換えます。システムコマンドの終了ス テータスは、変数 GPVAL_SYSTEM_ERRNO と GPVAL_SYSTEM_ERRMSG に返されま す。以下参照: system。

コマンド置換は、単一引用符内の文字列以外は、‘gnuplot‘ のコマンドライ ン中、どこででも使用可能です。

例:

以下の例は、‘leastsq‘ というプログラムを実行し、その出力結果で、 ‘leastsq‘ を (まわりの引用符こみで) 置き換えます:

      f(x) = `leastsq`

ただし VMS では、

      f(x) = `run leastsq`

以下は現在の日付とユーザー名のラベルを生成します:

      set label "generated on `date +%Y-%m-%d` by `whoami`" at 1,1
      set timestamp "generated on %Y-%m-%d by `whoami`"

1.28.2 文字列変数のマクロ置換 (Substitution macros)

文字 @ は、コマンドライン上でその文字列変数の値への置換を行なうのに使 われます。文字列変数の値としての文は、複数の単語からなることも可能です。 これにより文字列変数をコマンドラインマクロとして使うことが可能になりま す。この機能により展開できるのは文字列定数のみで、文字列を値に取る数式 を使うことはできません。 例:

      style1 = "lines lt 4 lw 2"
      style2 = "points lt 3 pt 5 ps 2"
      range1 = "using 1:3"
      range2 = "using 1:5"
      plot "foo" @range1 with @style1, "bar" @range2 with @style2

この @ 記号を含む行は、その入力時に展開され、それが実際に実行されると きには次のように全部打ち込んだ場合と同じことになります。

      plot "foo" using 1:3 with lines lt 4 lw 2, \
           "bar" using 1:5 with points lt 3 pt 5 ps 2

関数 exists() はマクロの評価に関して有用でしょう。以下の例は、C が安全 にユーザ定義変数の名前に展開できるかどうかをチェックします。

      C = "pi"
      if (exists(C)) print C," = ", @C

マクロの展開は、単一引用符内、または二重引用符内では行なわれませんが、 逆引用符 (｀) 内ではマクロ展開されます。

マクロの展開は、gnuplot が新しいコマンド行を見たときに非常に早い段階で gnuplot が処理し、そしてただ一度だけそれを行います。よって、

     A = "c=1"
     @A

のようなコードは正しく実行しますが、以下のような行はだめです。それは、 マクロの定義が同じ行にあるため展開に間に合わないからです。

     A = "c=1"; @A   # will not expand to c=1

コマンドを完成させて実行するには、コマンド evaluate も有用でしょう。

1.28.3 文字列変数、マクロ、コマンドライン置換 (mixing_macros_backquotes)

文字列変数や逆引用符 (｀) による置換、マクロによる置換の相互関係は少し ややこしいです。逆引用符はマクロ置換を妨げないので、

      filename = "mydata.inp"
      lines = ` wc --lines @filename | sed "s/ .*//" `

は、mydata.ipn の行数を整数変数 lines に保存することになります。また、 二重引用符は逆引用符の置換を妨げないので、

      mycomputer = "`uname -n`"

は、システムコマンド ‘uname -n‘ の返す文字列を文字列変数 mycomputer に 保存することになります。

しかし、マクロ置換は二重引用符内では機能しないので、システムコマンドを マクロとして定義してそれをマクロとして利用しかつ逆引用符置換を行なうこ とはでできません。

       machine_id = "uname -n"
       mycomputer = "`@machine_id`"  # うまくいかない !

この失敗は、二重引用符が @machine_id をマクロとして解釈することを妨げ ているからです。システムコマンドをマクロとして保存し、その後それを実行 するには、逆引用符自体もマクロ内に含める必要があります。これは以下のよ うにマクロを定義することで実現できます。sprintf の書式には 3 種類の引 用符全てが入れ子になっていることに注意してください。

      machine_id = sprintf('"`uname -n`"')
      mycomputer = @machine_id

1.29 区切りやカッコの使い方 (Syntax)

リストや座標がコンマ (,) 区切りであるのに対し、オプションやそれに伴う パラメータはスペース ( ) 区切りです。範囲はコロン (:) で区切ってかぎか っこ ([]) でくくりますし、文字列やファイル名は引用符でくくり、他にいく つかカッコ (()) でくくるものがあります。

コンマは以下の区切りで使用されます。‘set‘ コマンドの ‘arrow‘, ‘key‘, ‘label‘ の座標; 当てはめ (fit) られる変数のリスト (コマンド ‘fit‘ のキ ーワード ‘via‘ に続くリスト); コマンド ‘set cntrparam‘ で指定されると びとびの等高線の値やそのループパラメータのリスト; ‘set‘ コマンドの ‘dgrid3d‘ ‘dummy‘, ‘isosamples‘, ‘offsets‘, ‘origin‘, ‘samples‘, ‘size‘, ‘time‘, ‘view‘ の引数; 目盛りの位置やそのループパラメータのリ スト; タイトルや軸の見出しの位置; ‘plot‘, replot, ‘splot‘ コマンドの x,y,z 座標の計算に使われる媒介変数関数のリスト; ‘plot‘, replot, ‘splot‘ コマンドの複数の描画 (データ、または関数) のそれぞれの一連のキ ーワードのリスト。

(丸) カッコは、目盛りの見出しを (ループパラメータではなく) 明示的に集 合与える場合の区切りとして、または ‘fit‘, ‘plot‘, replot, ‘splot‘ コ マンドの using フィルタでの計算を指示するために使われます。

(カッコやコンマは通常の関数の表記でも使われます。)

かぎかっこは、‘set‘, ‘plot‘, ‘splot‘ コマンドでは範囲を区切るのに使わ れます。

コロンは ‘range‘ (範囲) 指定 (‘set‘, ‘plot‘, ‘splot‘ コマンドで使われ る) の両端の値を区切るのに、または ‘plot‘, replot, ‘splot‘, ‘fit‘ コ マンドの using フィルタの各エントリを区切るのに使われます。

セミコロン (;) は、一行のコマンド行内で与えられる複数のコマンドを区切 るのに使われます。

中カッコ ({}) は、拡張文字列処理モード (enhanced text mode) の記述や、 if/then/else 文のブロックの区切りとして使われますし、または複素数を記 述するのにも使われます: {3,2} = 3 + 2i となります。

EEPIC, Imagen, Uniplex, LaTeX, TPIC の各出力形式では、単一引用符内の \\ または二重引用符内の \\\\ で改行を示すことが可能です。

1.29.1 引用符 (Quotes)

gnuplot は、文字列を区切るのに、二重引用符 (ASCII コード 34 番)、単一 引用符 (ASCII コード 39 番)、および逆引用符 (｀) (ASCII コード 96 番) の 3 種類の引用符を使います。

ファイル名は単一引用符、あるいは二重引用符内で囲みます。このマニュアル では一般にコマンドの例示では、わかりやすくするためにファイル名は単一引 用符でくくり、他の文字列は二重引用符でくくります。

見出し (label)、タイトル (title)、またはその他の描画要素で使用される文 字列定数や複数行文字列は単一引用符、あるいは二重引用符内で囲みます。引 用符で囲まれた文字列のさらなる処理の結果は、どの引用符記号を選ぶかによ って変わります。

\n (改行) や \345 (8 進表記の文字コード) のようなバックスラッシュ (\) による特殊文字表現は、2 重引用符内の文字列でのみ効力を持ちます。単一引 用符内では、バックスラッシュ自体が通常の文字と見なされます。単一引用符 内の文字列で単一引用符自体 (ASCII コード 39 番) を使うには、それを重ね て書く必要があります。つまり、文字列 "d\" s’ b\\" と、’d" s” b\’ は完 全に同じものとなります。

1 つの複数行文字列に関する行揃えは各行に同等に働きます。よって、中央に 行揃えされた文字列

      "This is the first line of text.\nThis is the second line."

は次のように表示されます:

                       This is the first line of text.
                          This is the second line.

しかし

      'This is the first line of text.\nThis is the second line.'

だと次のようになります。

          This is the first line of text.\nThis is the second line.

拡張文字列処理 (enhanced text processing) は二重引用符に対しても単一引 用符に対しても機能します。しかし、そのモードをサポートしている出力形式 でのみ働きます。以下参照: ‘enhanced text‘。

逆引用符は,コマンドライン中の置換のためにシステムコマンドを囲むのに使 います。以下参照: ‘substitution‘。

1.30 時間/日付データ (Time/Date)

‘gnuplot‘ は入力データとして時間/日付情報の使用をサポートしています。 この機能は ‘set xdata time‘, ‘set ydata time‘ などのコマンドによって有 効になります。

内部では全ての時間/日付は 1970 年からの秒数に変換されます。コマンド ‘set timefmt‘ は全ての入力に対するデフォルトの書式を定義します。データ ファイル、範囲、軸の目盛りの見出し、ラベルの位置と、日時データ値を受け 入れるすべてのものへの入力の書式が、デフォルトでこれになります。一時に は一つのデフォルト入力書式のみが有効です。よって、ファイル内の x と y の両方が時間/日付データである場合は、デフォルトではそれは同じ書式と解 釈されます。しかし、このデフォルトは、using 指定で関数 timecolumn を用いて、それに対応する特定のファイルや列からデータを読みこむことによ り、変えることが可能です。

秒数へ (秒数から) の変換は国際標準時 (UT; グリニッジ標準時 (GMT) と同 じ) が使われます。各国標準時や夏時間への変換の機能は何も持ち合わせてい ません。もしデータがすべて同じ標準時間帯に従っているなら (そして全てが 夏時間か、そうでないかのどちらか一方にのみ従うなら) これに関して何も心 配することはありません。しかし、あなたが使用するアプリケーションで絶対 的な時刻を厳密に考察しなければいけない場合は、あなた自身が UT に変換す べきでしょう。

‘show xrange‘ のようなコマンドは、その整数値を ‘timefmt‘ に従って解釈 し直します。‘timefmt‘ を変更してもう一度 ‘show‘ でその値を表示させると、 それは新しい ‘timefmt‘ に従って表示されます。このため、(‘set xdata‘ な どにより) その軸に対するデータ型をリセットすると、その値は整数値として 表示されることになります。

コマンド format または format は、指定された軸に対す る入力が時間/日付であるなしに関わらず目盛りの見出しに使われる書式を定 義します。

時間/日付情報がファイルから描画される場合、‘plot‘, ‘splot‘ コマンドで は using オプションを「必ず」使う必要があります。‘plot‘, ‘splot‘ で は各行のデータ列の分離にスペースを使いますが、時間/日付データはその中 にスペースを含み得るからです。もしタブ区切りを使用しているのなら、あな たのシステムがそれをどう扱うか確かめるために何度もテストする必要がある でしょう。

関数 ‘time‘ は、現在のシステム時刻を得るのに使えます。この値は、 strftime 関数で日時文字列に変換できますし、timecolumn と組み合わせ て相対的な日時グラフを作成するのにも使えます。引数の型はそれが返すもの を決定します。引数が整数の場合は time() は現在の時刻を 1970 年 1 月 1 日からの整数として返し、引数が実数 (または複素数) ならば同様の値を実数 として返しますが、小数 (秒以下) 部分の精度は、オペレーティングシステム に依存します。引数が文字列ならば、それを書式文字列であるとみなし、書式 化された日時文字列を提供するようそれを strftime に渡します。

次の例は時間/日付データの描画の例です。

ファイル "data" は以下のような行からなるとします:

      03/21/95 10:00  6.02e23

このファイルは以下のようにして表示されます:

      set xdata time
      set timefmt "%m/%d/%y"
      set xrange ["03/21/95":"03/22/95"]
      set format x "%m/%d"
      set timefmt "%m/%d/%y %H:%M"
      plot "data" using 1:3

ここで、x 軸の目盛りの見出しは "03/21" のように表示されます。

現在の gnuplot は、時刻をミリ秒精度で追跡し、時刻のフォーマットもそれ に伴って変更されています。 例: 現在の時刻をミリ秒精度で表示

     print strftime("%H:%M:%.3S %d-%b-%Y",time(0.0))
     18:15:04.253 16-Apr-2011

以下参照: ‘time_specifiers‘。

2 描画スタイル (plotting styles)

gnuplot では、たくさんの描画スタイルが利用できます。 それらは、アルファベット順に以下に紹介されています。 コマンド ‘set style data‘ と ‘set style function‘ は、それ以降の ‘plot‘ や ‘splot‘ コマンドに対してデフォルトの描画スタイルを変更 します。

描画スタイルは、コマンド ‘plot‘ や ‘splot‘ の一部分として、明示的にオ プション指定することもできます。一つの描画の中で、複数の描画スタイルを 組み合わせたい場合は、各要素に対して描画スタイルを指定する必要がありま す。

例:

     plot 'data' with boxes, sin(x) with lines

各描画スタイルは、それ自体がデータファイルからのいくつかのデータの組 を期待します。例えば、デフォルトでは ‘lines‘ スタイルは、y の値だけの 1 列のデータ (x の値は暗黙に順番に取られる)、または最初が x, 次が y の 2 つの列を期待しています。ファイルの何列のデータを描画データと解釈させ るうまい方法に関する情報については、以下参照: using。

2.1 boxerrorbars

描画スタイル boxerrorbars は 2 次元のデータ描画でのみ利用可能です。 これは、3 列、または 4 列、または 5 列のデータが必要です。入力列を追加 (4,5,6 列目) すると、それらは各データ点毎の variable color 情報 (以下 参照: ‘linecolor‘, ‘rgbcolor variable‘) として使われます。誤差線は、箱 の境界と同じ色で描画されます。

     3 列:  x  y  ydelta
     4 列:  x  y  ydelta xdelta        # 箱の幅 != -2
     4 列:  x  y  ylow  yhigh          # 箱の幅 == -2
     5 列:  x  y  ylow  yhigh  xdelta

y の誤差が "ydelta" の形式で与えられて、箱の横幅があらかじめ -2.0 に設 定されて (‘set boxwidth -2.0‘) いなければ、箱の横幅は 4 列目の値で与え られます。y の誤差が "ylow yhigh" の形式で与えられる場合は箱の横幅は 5 列目の値で与えられます。特別な場合として、"ylow yhigh" の誤差形式の 4 列のデータに対する ‘boxwidth = -2.0‘ という設定があります。この場合箱 の横幅は、隣接する箱にくっつくように自動的に計算されます。3 列のデータ の場合も、横幅は自動的に計算されます。

箱の高さは、yerrorbars スタイル同様に y の誤差の値から決定されます。 y-ydelta から y+ydelta まで、あるいは ylow から yhigh まで、これらは何 列のデータが与えられているかによって決まります。

2.2 boxes

boxes スタイルは 2 次元描画でのみ利用可能です。これは与えられた x 座 標を中心とし、x 軸から (グラフの境界から、ではありません) 与えられた y 座標までの箱を書きます。これは基本的に、2 列、または 3 列のデータを使 用します。余分な入力列は、variable 行や塗り潰し色の情報が提供されたも のとして使用されます (以下参照: ‘rgbcolor variable‘)。

     2 列:  x  y
     3 列:  x  y  x_width

箱の幅は 3 つのうち一つの方法で決定されます。入力データが 3 列目のデー タを持っている場合は、それが箱の幅にセットされます。そうでなくて ‘set boxwidth‘ コマンドで箱の幅がセットされていた場合は、それが使われ ます。そのどちらでもない場合、箱の幅は、隣接する箱がくっつくように自動 的に計算されます。

箱の中身は現在の塗りつぶしスタイル (fillstyle) に従って塗りつぶされま す。詳細は、以下参照: ‘set style fill‘。新しい塗りつぶしスタイルを plot コマンド上で指定することもできます。 塗りつぶしスタイルが ‘empty‘ の場合は、箱は塗りつぶされません。 塗りつぶしスタイルが ‘solid‘ の場合は、箱は現在の描画色でベタ塗りされ ますが、fillstyle パラメータを追加することで塗りつぶし密度を制御できま す。0 は背景色、1 は描画色そのものになります。 塗りつぶしスタイルが ‘pattern‘ の場合は、箱は現在の描画色で、あるパタ ーンで塗りつぶします。

例:

データファイルを塗りつぶした箱で描画し、箱同士を少し垂直方向にスペース を空ける (棒グラフ):

      set boxwidth 0.9 relative
      set style fill solid 1.0
      plot 'file.dat' with boxes

パターンでの塗りつぶしスタイルの箱で sin と cos のグラフを描画:

      set style fill pattern
      plot sin(x) with boxes, cos(x) with boxes

sin はパターン 0 で、cos はパターン 1 で描画されます。追加される描画は 出力ドライバがサポートするパターンを循環的に使用します。

それぞれのデータ集合で明示的に塗りつぶしスタイルを指定:

     plot 'file1' with boxes fs solid 0.25, \
          'file2' with boxes fs solid 0.50, \
          'file3' with boxes fs solid 0.75, \
          'file4' with boxes fill pattern 1, \
          'file5' with boxes fill empty

2.3 boxplot

boxplot は、値の統計的な分布を表現する一般的な方法です。四分位境界は、 1/4 の点が第一四分位境界以下の値を持つように、1/2 の点が第二四分位境界 (メジアン) 以下の値を持つように、等と決定されます。第一四分位と第三四 分位の間の領域を囲むように箱を描画し、メジアン値のところには水平線を描 きます。箱ひげは、箱からユーザ指定限界まで延長されます。それらの限界の 外にある点は、ひとつひとつ描画されます。

例:

    # x 座標は 1.0、y は 5 列目の値のところに boxplot を配置
    plot 'data' using (1.0):5

    # 上と同じだが、範囲外の点は隠し、boxplot の幅を 0.3 にする
    set style boxplot nooutliers
    plot 'data' using (1.0):5:(0.3)

デフォルトでは、using 指定による 2 列目の y のすべての値に対する boxplot を 1 つだけ生成します。しかし、追加の (4 つ目の) 列を指定する と、その列の値をある因子変数の離散的なレベル値であると見なし、その離散 値のレベルの値の数だけの boxplot を描画します。それらの boxplot の間隔 はデフォルトでは 1.0 ですが、これは ‘set style boxplot separation‘ で 変更できます。デフォルトでは、因子変数の値は、各 boxplot の下 (または 上) の目盛りのラベルに表示します。

例

    # 'data' の 2 列目は "control" か "treatment" のいずれかの文字列で
    # 以下の例は、その因子毎の 2 つの boxplot を生成する
    plot 'data' using (1.0):5:(0):2

その箱のデフォルトの幅は ‘set boxwidth <width>‘ で設定できますが、plot コマンドの using による 3 番目のオプション列でも指定できます。1 番目 と 3 番目の列 (x 座標と幅) は通常データ列ではなく定数として与えます。

デフォルトでは、箱ひげは箱の端から、y の値が四分位範囲の 1.5 倍の中に 収まっていて最も離れているような点まで延長されます。デフォルトでは、範 囲外の点 (outlier) は円 (pointtype 7) で描かれます。箱ひげの端の棒の幅 は ‘set bars‘ または errorbars を使って制御できます。

これらのデフォルトの性質は ‘set style boxplot‘ コマンドで変更できます。 以下参照: ‘set style boxplot‘, ‘bars‘, ‘boxwidth‘, ‘fillstyle‘, candlesticks。

2.4 boxxyerror

boxxyerror 描画スタイルは 2 次元のデータ描画でのみ利用可能です。これ は、xyerrorbars スタイルが線分の交差で表現するところを長方形で表現す ることを除けば、ほぼ同じです。これは、入力データの 4 列、または 6 列を 使用します。余分な入力列は、variable 行や塗り潰し色の情報が提供された ものとして使用されます (以下参照: ‘rgbcolor variable‘)。

     4 列:  x  y  xdelta  ydelta
     6 列:  x  y  xlow  xhigh  ylow  yhigh

箱の幅と高さは xyerrorbars スタイル同様 x, y の誤差から決定されます つまり、xlow から xhigh までと ylow から yhigh まで、または x-xdelta から x+xdelta までと y-ydelta から y+ydelta まで。これらは何列のデータ が与えられているかによって決まります。

6 列の形式のコマンドは、任意の x, y の幅の長方形を書く簡単な方法を提供 します。

入力列を追加 (5,7 列目) すると、それらは各データ点毎の variable color 情報 (以下参照: ‘linecolor‘, ‘rgbcolor variable‘) であるとして使われま す。

箱の内部は現在の塗りつぶしスタイル (fillstyle) に従って塗られます。詳 細は、以下参照: ‘set style fill‘, boxes。plot コマンド上で新しい塗り つぶしスタイルを指定することもできます。

2.5 candlesticks

candlesticks スタイルは、金融データの 2 次元のデータ描画、および統計 データのひげ付きの棒グラフを生成するのに使えます。 記号は、水平方向には x を中心とし、垂直方向には開始値 (open) と終値 (close) を境界とする長方形が使われます。そして、その x 座標のところに 長方形のてっぺんから最高値 (high) までと、長方形の底から最安値 (low) までの垂直線が引かれますが、この垂直線は最高値と最安値が入れ替わっても 変更されません。

基本的に 5 列のデータが必要です:

      金融データ:   date  open  low  high  close
      箱ひげ描画:   x  box_min  whisker_min  whisker_high  box_high

長方形の幅はコマンド ‘set boxwidth‘ で制御できますが、以前の gnuplot への後方互換性として、boxwidth パラメータが設定されていない場合は ‘set errorbars <width>‘ で制御されるようになっています。

これの代わりに、箱ひげ (box-and-whisker) のグループ化に関する明示的な 幅の指定を、追加の 6 番目のデータで指定できます。その幅は、x 座標と同 じ単位で与えなければいけません。

入力列を追加 (6 列目、または 6 列目がデータの幅として使れる場合は 7 列 目) すると、それらは各データ点毎の variable color 情報 (以下参照: ‘linecolor‘, ‘rgbcolor variable‘) として使われます。

デフォルトでは、鉛直線分のてっぺんと底には垂直に交わる水平線は引かれま せん。それを引きたい場合、例えば典型的な例は箱ひげ図 (box-and-whisker plot) での使用ですが、描画コマンドにキーワード ‘whiskerbars‘ を追加し てください。デフォルトでは、水平線は箱 (candlestick) の水平幅一杯に引 かれますが、それは全体の幅に対する割合を指定することで変更できます。

金融データの通常の慣習では、(開始値) < (終値) の場合は長方形は空で、 (終値) < (開始値) の場合は塗り潰されます。現在の fillstyle に "empty" をセットしている場合は、実際にこうなります。以下参照: ‘fillstyle‘。 fillstyle に塗り潰し、またはパターンをセットしている場合は、開始値、終 値に関係なく、すべての箱にそれが使われます。以下参照: errorbars, financebars。また、以下も参照してください。 candlestick と finance のデモ。

注意: 中央値を表すための記号などを追加したい場合、以下の例のように、ひ げ付きの棒グラフに他の描画コマンドを追加する必要があります:

  # データ列:  X '最小値' '1/4 位の値' '中央値' '3/4 位の値' '最大値'
  set errorbars 4.0
  set style fill empty
  plot 'stat.dat' using 1:3:2:6:5 with candlesticks title 'Quartiles', \
       ''         using 1:4:4:4:4 with candlesticks lt -1 notitle

  # ひげの上に水平線を伴う描画で、水平線の幅を全体幅の 50% にする
  plot 'stat.dat' using 1:3:2:6:5 with candlesticks whiskerbars 0.5

以下参照: ‘set boxwidth‘, errorbars, ‘set style fill‘, ‘boxplot‘。

2.6 circles

スタイル circles は、各データ点に明示された半径の円を描画します。3 列のデータを与えた場合は、それを x, y, 半径と解釈します。半径は、常に 描画の水平軸 (x または x2) の単位で解釈されます。y 方向の縮尺と描画の アスペクト比は、いずれも無視されます。2 列のデータしか与えないと、半径 は ‘set style circle‘ から取ります。この場合、半径は graph か screen の座標系で与えることができます。

デフォルトでは完全な円を描画しますが、4 列目、5 列目に開始角、終了角を 指定することで扇形を描画することもできます。4 列目、あるいは 6 列目の データを追加して部分円の色を指定することもできます。扇形の開始角、終了 角の単位は度で指定する必要があります。以下参照: ‘set style circle‘, ‘set style fill‘。

例:

    # 面積が 3 列目の値に比例するような円を描画
    set style fill transparent solid 0.2 noborder
    plot 'data' using 1:2:(sqrt($3)) with circles, \
         'data' using 1:2 with linespoints

    # 円の代わりにパックマンを描画
    plot 'data' using 1:2:(10):(40):(320) with circles

    # インランデータで円グラフを描画
    set xrange [-15:15]
    set style fill transparent solid 0.9 noborder
    plot '-' using 1:2:3:4:5:6 with circles lc var
    0    0    5    0    30    1
    0    0    5   30    70    2
    0    0    5   70   120    3
    0    0    5  120   230    4
    0    0    5  230   360    5
    e

これは、pointstyle 7 で点のサイズを variable とした points による描 画と似ていますが、circles は x 軸の範囲で伸縮される点が異なります。以 下も参照: ‘set object circle‘, ‘fillstyle‘。

2.7 ellipses

スタイル ellipses は、各データ点に楕円 (ellipse) を描画します。この スタイルは、2 次元描画にのみ適用されます。各楕円は、中心、主軸直径、副 軸直径、x 軸と主軸のなす角、で表現されます。

     2 列: x y
     3 列: x y major_diam
     4 列: x y major_diam minor_diam
     5 列: x y major_diam minor_diam angle

2 列のデータのみが与えられた場合は、それらは中心の座標とみなされ、楕円 はデフォルトの大きさで描画されます (以下参照: ‘set style ellipse‘)。楕 円の向きは、主軸と x 軸のなす角で定義されますが、それもデフォルトの ellipse のスタイルから取られます (以下参照: ‘set style ellipse‘)。 3 列のデータが与えられた場合は、3 列目は主、副両軸の直径 (幅) として使 われます。向きはデフォルトで 0 になります。 4 列のデータが与えられた場合は、それらは中心の座標、主軸直径 (幅)、副 軸直径として使わわれます。これらは直径であり、半径でないことに注意して ください。 5 列のデータが与えられた場合は、5 列目の値は度単位の向きの角度の指定と して使われます。 楕円は、3,4,5 列の値は負の値として指定することで、それらのデフォルトの 値を利用して楕円を書かせることもできます。

上のすべての場合で、variable color データを最後の列 (3,4,5,6 列目) と して追加できます。詳細は以下参照: ‘colorspec‘。

デフォルトでは、主軸直径は水平軸 (x または x2) の単位、副軸直径は垂直 軸 (y または y2) の単位であるとみなされます。これは、x 軸と y 軸の縮尺 が異なる場合、主軸と副軸の比は回転後には正しくはならない、ということを 意味しています。しかしこの挙動は、キーワード ‘units‘ で変更できます。

これに関しては、3 種類の代用品があります: ‘units xy‘ が描画指定に含まれている場合、その軸は上に述べたように縮尺 されます。‘units xx‘ とすると、直径は両軸とも x 軸の単位で計算され、 ‘units yy‘ は両軸とも y 軸の単位で計算されます。後の 2 つは、描画のサ イズを変更しても、楕円は正しいアスペクト比を持ちます。

‘units‘ を省略した場合は、デフォルトの設定が使用され、‘units xy‘ とな りますが、これは、‘set style ellipse‘ で再定義可能です。

例 (楕円を有効な線種を周期的に使用して描画):

    plot 'data' using 1:2:3:4:(0):0 with ellipses

以下も参照: ‘set object ellipse‘, ‘set style ellipse‘, ‘fillstyle‘。

2.8 dots

dots スタイルは各点に小さなドットを描画します。これはたくさんの点か らなる散布図の描画に便利でしょう。2 次元描画では 1 列、または 2 列の入 力データが、3 次元描画では 3 列のデータが必要です。

出力形式によっては (post, pdf など)、ドットの大きさは linewidth を変更 することで制御できることもあります。

     1 列:  y         # x は行番号
     2 列:  x  y
     3 列:  x  y  z   # 3D のみ (splot)

2.9 filledcurves

スタイル filledcurves は 2 次元描画でのみ利用します。これは 3 種類の 異なる指定が可能です。最初の 2 種類は 1 つの関数描画、あるいは (x,y) 2 列の入力データ用のもので、後で紹介するようにオプションで更なる指定がで きます。

書式:

    plot ... with filledcurves [option]

ここで、オプションは以下のうちのいずれかです:

    [closed | {above | below}
    {x1 | x2 | y | r}[=<a>] | xy=<x>,<y>]

最初のものは ‘closed‘ で、これは曲線それ自身を閉多角形と見なします。入 力データが 2 列の場合にはこれがデフォルトです。

2 種類目は指定された軸、あるいは水平線、垂直線、与えられた点などと、曲 線との間に作られる領域を塗りつぶします。

    filledcurves closed   ... 丁度閉曲線で囲まれる領域
    filledcurves x1       ... x1 軸
    filledcurves x2       ... x2 軸 (y1, y2 軸も同様)
    filledcurves y=42     ... 直線 y=42, すなわち x 軸と平行
    filledcurves xy=10,20 ... x1,y1 軸での点 10,20 (扇型のような形状)
    filledcurves above r=1.5  極座標での動径軸の 1.5 の外側の領域

3 種類目は、x 座標の集合が同じである 2 つの曲線の間の領域を塗り潰しま す。これは、(x, y1, y2) の 3 列の入力データが必要です。入力データが 3 列以上の場合にはこれがデフォルトです。2 列目が y の値で、3 列目がその 誤差データである場合は、不確定領域を陰影で表現することができます。 これに似た 3 次元描画スタイル zerrorfill も参照してください。

     3 列:  x  y  yerror

    plot $DAT using 1:($2-$3):($2+$3) with filledcurves, \
         $DAT using 1:2 smooth mcs with lines

‘above‘ と ‘below‘ オプションは

    ... filledcurves above {x1|x2|y|r}=<val>

および

    ... using 1:2:3 with filledcurves below

の形のコマンドに適用可能です。どちらの場合でも、これらのオプションは 塗りつぶし領域を、境界線、または境界曲線の片側に制限します。

注意: この描画モードは全ての出力形式でサポートされるとは限りません。

      3 列のデータ描画では、x= と y= のキーワードは無視します。

データファイルから描かれた曲線の塗りつぶしを拡大すると、何もなくなった り正しくない領域になることがありますが、それは gnuplot が、領域ではな く点や線をクリッピングしているからです。

<x>, <y>, <a> が描画領域の外にある場合、それらはグラフの境界へ移動され ます。よって、オプション xy=<x>,<y> を指定した場合の実際の塗りつぶし領 域は、xrange や yrange に依存します。

2.9.1 塗り潰しの属性 (fill properties)

filledcurves での描画は、fillstyle (solid/transparent/pattern) や fillcolor を指定することでさらにカスタマイズできます。plot コマンド で fillstyle (‘fs‘) を指定しなければ、現在のデフォルトの fill スタイル を使用します。以下参照: ‘set style fill‘。plot コマンドで fillcolor (‘fc‘) を指定しなければ、通常の線種 (linetype) の色列に従います。

fillstyle の属性の {{no}border} は、filledcurves のモードがデフォルト の ‘closed‘ である場合に受け付けます。 例:

     plot 'data' with filledcurves fc "cyan" fs solid 0.5 border lc "blue"

2.10 financebars

financebars スタイルは金融データの 2 次元のデータ描画でのみ利用可能 です。これは、x 座標 1 つ (通常日付) と、4 つの y 座標 (金額) を必要と します。

     5 列:   date  open  low  high  close

入力列を追加 (6 列目) すると、それらは各行毎の variable color 情報 (以 下参照: ‘linecolor‘, ‘rgbcolor variable‘) として使われます。

記号は、水平方向にはその x 座標に置かれ、垂直方向には最高値 (high) と 最安値 (low) を端とする線分が使われます。そして、その線分に水平左側の 刻みが開始値 (open) の所に、水平右側の刻みが終り値 (close) の所につき ます。その刻みの長さは errorbars で変更できます。記号は最高値と 最安値が入れ替わっても変わりません。以下参照: errorbars, candlesticks。以下も参照してください。 金融データデモ。

2.11 fsteps

fsteps スタイルは 2 次元描画でのみ利用可能です。これは 2 本の線分で 隣り合う点をつなぎます: 1 本目は (x1,y1) から (x1,y2) まで、2 本目は (x1,y2) から (x2,y2) まで。入力列の条件は、‘lines‘ や points に対す るものと同じです。fsteps と steps の違いは、fsteps は、折れ線を 先に y 方向に書いてから次に x 方向に書くのに対し、steps は先に x 方 向に書いてから次に y 方向に書きます。

以下も参照 steps デモ。

2.12 fillsteps

fillsteps スタイルは、steps とほぼ同じですが、曲線と y=0 との間の 領域を現在の fillstyle で塗り潰します。以下参照: steps。

2.13 histeps

histeps スタイルは 2 次元描画でのみ利用可能です。これはヒストグラム の描画での利用を意図しています。y の値は、x の値を中心に置くと考え、 x1 での点は ((x0+x1)/2,y1) から ((x1+x2)/2,y1) までの水平線として表現 されます。端の点では、その線はその x 座標が中心になるように延長されま す。隣り合う点同士の水平線の端は、その両者の平均値のところでの鉛直線、 すなわち ((x1+x2)/2,y1) から ((x1+x2)/2,y2) の線分で結ばれます。 入力列の条件は、‘lines‘ や points に対するものと同じです。

‘autoscale‘ が有効である場合、x の範囲は、その延長された水平線の範囲で はなく、データ点の範囲が選択されます。よって、端の点に関してはその水平 線は半分しか描かれないことになります。 以下も参照 steps デモ。

2.14 histograms

スタイル histograms は 2 次元描画でのみ有効です。これは、データの各 列の並びから平行な棒グラフを作ります。‘plot‘ コマンドの各要素は、それ に関する目盛りの値や凡例 (key) のタイトルが付属するかも知れませんが、 単一の入力データを指定する必要があります (例えば入力ファイルの 1 つの 列)。現在は、4 種類のヒストグラム形式のスタイルをサポートしています。

      set style histogram clustered {gap <gapsize>}
      set style histogram errorbars {gap <gapsize>} {<linewidth>}
      set style histogram rowstacked
      set style histogram columnstacked
      set style histogram {title font "name,size" tc <colorspec>}

デフォルトのスタイルは ‘set style histogram clustered gap 2‘ に対応し ています。このスタイルでは、並列に指定されたデータの値の集合は、選択さ れたデータ列のそのそれぞれの序列 (行番号) に対応する x 座標の場所に、 各々箱のグループとして固められて置かれます。よって、<n> 個のデータ列を 並列に指定した場合、最初の固まりは x=1 を中心とする <n> 個の箱の固まり からなり、その各々の高さは、その <n> データ列各々の最初 (1 行目) の値 が取られます。その後に少し空白 (gap) が空けられ、次に各データ列の次 (2 行目) の値に対応する箱の固まりが x=2 を中心として置かれます。以下同様 です。デフォルトの空白 (gap) 幅の 2 は、箱の固まり同士の間の空白が、箱 2 つの幅に等しいことを意味します。同じ列に対する箱は全て同じ色または同 じパターンで与えられます (以下参照: ‘set style fill‘)。

箱の固まりそれぞれは、データファイルの 1 つの行から得られます。そのよ うな入力ファイルの各行の最初の項目が見出し (ラベル) でることは良くある ことです。その列にある見出し (ラベル) は、using に ‘xticlabels‘ オプ ションをつけることで、それに対応する箱の固まりの真下の x 軸に沿ったと ころに置くことができます。

errorbars スタイル は、各エントリに対して追加の入力列を必要とする以 外は ‘clustered‘ スタイルにとても良く似ています。最初の列は、 ‘clustered‘ スタイルの場合と全く同様に箱の高さ (y の値) として保持され ます。

     2 列:       y yerr          # 線は y-yerr から y+err へ伸びる
     3 列:       y ymin ymax     # 線は ymin から ymax へ伸びる

誤差線の見た目は、現在の errorbars の値と <linewidth> オプション 指定で制御できます。

積み上げ型のヒストグラムも 2 つの形式がサポートされています。それらは コマンド ‘set style histogram {rowstacked|columnstacked}‘ で選択できま す。これらのスタイルにおいて、選択された列のデータの値は積み上げられた 箱として集められます。正の値は、y=0 から上の方へ積み上げられ、負の値は 下へ向かって積み上げられます。正の値と負の値が混じってい場合は、上向き と下向きの両方の積み上げが生成されます。デフォルトの積み上げモードは ‘rowstacked‘ です。

スタイル ‘rowstacked‘ は、まず最初に選択された列の各行の値を x 軸のそ れぞれの位置に配置します: 1 行目の値は x=1 の箱、2 行目のは x=2、以下 同様となります。2 番目以降に選択された列に対応する箱は、それらの上に積 み重ねられて行きます。そして結果として、x=1 にできる箱の積み重ねは、各 列の最初の値 (1 行目の値) からなり、x=2 の箱の積み重ねは各列の 2 行目 の値、などのようになります。同じ列に対する箱は全て同じ色または同じパタ ーンで与えられます (以下参照: ‘set style fill‘)。

スタイル ‘columnstacked‘ も同様ですが、こちらは各箱の積み上げは (各行 のデータからではなく) 各列のデータからなります。最初に指定された列の各 行のデータが x=1 の箱の積み上げを生成し、2 番目に指定した列の各行のデ ータが x=2 の箱の積み上げ、などのようになります。このスタイルでは、各 箱の色は、各データ項目の (列番号ではなく) 行番号から決定されます。

箱の幅はコマンド ‘set boxwidth‘ で変更できます。 箱の塗りつぶしスタイルはコマンド ‘set style fill‘ で設定できます。

histograms は x 軸は常に x1 軸を使いますが、y 軸に関しては y1 軸か y2 軸かを選択できます。plot 命令が、histograms と他のスタイルの描画の両方 を含む場合、histogram でない方は、x1 軸を使うか x2 軸を使うかを選択で きます。

例: 入力ファイルは、2, 4, 6, ... の列にデータ値を持ち、3, 5, 7, ... の列 に誤差評価を持つとします。以下の例は、2 列目、4 列目の値を箱の固まり型 (clustered; デフォルトスタイル) のヒストグラムとして描画します。ここで は、plot コマンドで繰り返し (iteration) を使用していますので、任意の個 数のデータ列を一つのコマンドで処理できます。以下参照: ‘plot for‘。

      set boxwidth 0.9 relative
      set style data histograms
      set style histogram cluster
      set style fill solid 1.0 border lt -1
      plot for [COL=2:4:2] 'file.dat' using COL

これは、x 軸上の各整数値を中心とするそれぞれ 2 つの箱 (鉛直な棒) 毎の 固まりによる描画を生成します。入力ファイルの最初の列にラベルが含まれて いるならそれを、以下の少し変更したコマンドで x 軸に沿って配置できます。

      plot for [COL=2:4:2] 'file.dat' using COL:xticlabels(1)

ファイルが、各データの測定値と範囲の情報の両方を含んでいる場合、描画に 誤差線を追加することができます。以下のコマンドは誤差線を (y-<error>) から (y+<error>) に引き、その頭に箱と同じ幅の水平線をつけます。誤差線 と誤差線の端の線は、黒で線幅 2 で描画されます。

      set errorbars fullwidth
      set style fill solid 1 border lt -1
      set style histogram errorbars gap 2 lw 2
      plot for [COL=2:4:2] 'file.dat' using COL:COL+1

以下は、同じデータを行毎の積み上げ型 (rowstacked) のヒストグラムで描画 する方法を示しています。これまでとは違い、以下の例では繰り返しを使うの でなく、明示的に別々の列を指定します。

      set style histogram rowstacked
      plot 'file.dat' using 2, '' using 4:xtic(1)

これは、一つ一つの鉛直な棒が、データの一つの列に対応する描画を生成しま す。各棒は、2 つの部分の積み上げの形であり、それぞれの部分の高さが、デ ータファイルの 2 列目と 4 列目の値に対応します。 最後に以下のコマンド

      set style histogram columnstacked
      plot 'file.dat' using 2, '' using 4

は、一つ一つがそれぞれデータ列に対応する、2 つの鉛直な積み重ねの棒を生 成します。x=1 にある棒は、データファイルの 2 列目の各行の値に対応する 箱からなります。x=2 にある棒は、データファイルの 4 列目の各行の値に対 応する箱からなります。

これは、gnuplot の通常の入力の縦、横の解釈を入れ換えることになりますの で、凡例のタイトルや x 軸の目盛りの見出しの指定も変更する必要がありま す。以下のコメント部分を参照してください。

      set style histogram columnstacked
      plot '' u 5:key(1)            # 1 列目を凡例タイトルに使用
      plot '' u 5 title columnhead  #

この 2 つの例は、全く同じデータ値を与えているのですが、異なる書式であ ることに注意してください。

2.14.1 newhistogram

書式:

     newhistogram {"<title>" {font "name,size"} {tc <colorspec>}}
                  {lt <linetype>} {fs <fillstyle>} {at <x-coord>}

一回の描画に 2 つ以上のヒストグラムの組を作ることもできます。この場合 コマンド newhistogram を使うことで、それらを強制的に分離し、またそれ ぞれのラベルを分離することができます。 例:

      set style histogram  cluster
      plot newhistogram "Set A", 'a' using 1, '' using 2, '' using 3, \
           newhistogram "Set B", 'b' using 1, '' using 2, '' using 3

ラベル "Set A" と "Set B" は、それぞれのヒストグラムの組の下、x 軸の全 てのラベルの下の位置に現われます。

コマンド newhistogram は、ヒストグラムの色付けを強制的に指定した色 (linetype) で始めるのにも使えます。デフォルトでは、色の番号はヒストグ ラムの境界をまたいでさえも連続的に増加し続けます。次の例は、複数のヒス トグラムに同じ色付けを施します。

      plot newhistogram "Set A" lt 4, 'a' using 1, '' using 2, '' using 3, \
           newhistogram "Set B" lt 4, 'b' using 1, '' using 2, '' using 3

同様に、次のヒストグラムを指定した fillstyle で始めさせることが可能で す。その fillstyle を ‘pattern‘ にセットした場合、塗り潰しに使用される パターン番号は自動的に増加されていきます。

オプション ‘at <x-coord>‘ は、その後のヒストグラムの x 座標の位置を <x-coord> に設定します。例:

       set style histogram cluster
       set style data histogram
       set style fill solid 1.0 border -1
       set xtic 1 offset character 0,0.3
       plot newhistogram "Set A", \
            'file.dat' u 1 t 1, '' u 2 t 2, \
            newhistogram "Set B" at 8, \
            'file.dat' u 2 t 2, '' u 2 t 2

この場合、2 つ目のヒストグラムの位置は x=8 から始まります。

2.14.2 複数の列に渡る自動的な繰り返し (automated)

一つのデータファイルのたくさんの列から、一つのヒストグラムを生成したい 場合、plot の繰り返し (iteration) 機能を使うと便利でしょう。以下参照: ‘plot for‘。例えば、3 列目から 8 列目までのデータを積み上げた形のヒス トグラムを生成する例:

      set style histogram columnstacked
      plot for [i=3:8] "datafile" using i title columnhead

2.15 image

描画スタイル ‘image‘, rgbimage, rgbalpha は、いずれも一様に標本点 を取った格子状データ値を、2 次元、または 3 次元中のある平面上に射影し ます。入力データは、既にあるビッマップ画像ファイル (PNG のような標準的 なフォーマットから変換したものでよい) か、単純な数値配列です。

この図は、スカラー値の配列から温度分布を生成した例です (訳注: 図が表示 されている場合)。現在のパレットを、各スカラー値から対応するピクセルの 色への割り当てに使用します。

      plot '-' matrix with image
      5 4 3 1 0
      2 2 0 0 1
      0 0 0 1 0
      0 1 2 4 3
      e
      e

入力 2 次元画像の各ピクセル (データ点) は、描画グラフ中では長方形、ま たは平行六面体となります。画像の各データ点の座標は、平行六面体の中心を 決定します。すなわち、M x N 個のデータ集合は M x N ピクセルの画像を生 成します。これは、M x N 個のデータ集合が (M-1) x (N-1) 要素を作成する pm3d の構造とは異なります。バイナリ画像データの格子の走査方向は、追加 キーワードでさらに制御可能です。以下参照: ‘binary keywords flipx‘, ‘keywords center‘, ‘keywords rotate‘。

各ピクセルの x と y の大きさを示すことで、画像データを 2 次元描画座標 系内の特定の長方形に収まるように伸縮することができます。以下参照: ‘binary keywords dx‘, ‘dy‘。右の画像を生成するのには、同じ入力画像を、 それぞれ dx, dy, origin を指定して複数回配置しました。入力 PNG 画像で あるビルの絵は 50x128 ピクセルです。高いビルは、‘dx=0.5 dy=1.5‘ で割り 当てて描画し、低いビルは、‘dx=0.5 dy=0.35‘ としています (訳注: 図が表 示されている場合)。

スタイル ‘image‘ は、グレイスケール (灰色階調)、またはカラーパレット値 を含んでいるピクセルの入力を処理します。よって 2 次元描画 (‘plot‘ コマ ンド) では 3 列のデータ (x,y,value) を、3 次元描画 (‘splot‘ コマンド) では 4 列のデータ (x,y,z,value) が必要になります。

スタイル rgbimage は、赤、緑、青の 3 つの色成分 (RGB) で記述されたピ クセルの入力を処理します。よって ‘plot‘ では 5 次元データ (x,y,r,g,b) が、‘splot‘ では 6 次元データ (x,y,z,r,g,b) が必要になります。赤、緑、 青の各成分は [0:255] の範囲内にあると仮定されます。 これは、PNG や JPEG ファイルで使用されている仕組みに合っています (以下 参照: filetype)。しかし、RGB 成分として [0:1] の範囲の実数値 を取る仕組みを使用するようなデータファイルも中にはあります。そのような データで rgbimage スタイルを使用するには、色成分を [0:255] の範囲に スケール変換しなければいけません。

スタイル rgbalpha は、赤、緑、青の RGB 成分に加えて、アルファ値 (透 過パラメータ) の情報も含んだピクセルの入力を処理します。よって、‘plot‘ では 6 次元データ (x,y,r,g,b,a) が、‘splot‘ では 7 次元データ (x,y,z,r,g,b,a) が必要になります。赤、緑、青、およびアルファの各成分は [0:255] の範囲内にあると仮定されます。RGBA 成分が [0:1] の範囲の実数値 であるデータを描画するには、色成分を [0:255] の範囲内にスケール変換し なければいけません。

2.15.1 透明化 (transparency)

描画スタイル rgbalpha は、入力データの各ピクセルが [0:255] の範囲内 のアルファ値を持っている必要があります。alpha = 0 のピクセルは完全な透 明で、その下 (奥) の描画要素を全く変えません。alpha = 255 のピクセルは 完全な不透明です。すべての出力形式は、これら 2 つの両極端な値をサポー トします。0 < alpha < 255 のピクセルは半透明で、半透明をサポートしてい ない出力形式では、その値を 0 か 255 のいずれかに丸めます。

2.15.2 image pixels

出力形式によっては、2 次元の長方形領域内での画像データ描画の、デバイス やライブラリに依存した最適化ルーチンを使用しています。これは、例えばク リッピングや伸縮がうまくなかったり、縁が欠けるなど、望ましくない出力を 生成することがあります。キーワード ‘pixels‘ は、そのようなルーチンの代 わりに、画像を 1 ピクセルずつ描画するような一般的なコードを使用するよ う gnuplot に指示します。この描画モードでは、描画は遅く、とても大きな 出力ファイルを生成しますが、どの出力形式でも共通的な見た目を作成してく れるでしょう (オプション ‘pixels‘ は、以前の gnuplot では ‘failsafe‘ と呼ばれていました)。 例:

      plot 'data' with image pixels

2.16 impulses

impulses スタイルは、2 次元描画では y=0 から各点の y の値への、3 次 元描画では z=0 から各点の z の値への、垂直な線分を表示します。y や z の値は負の値でもよいことに注意してください。データの追加列を各垂直線分 の色の制御に利用できます。このスタイルを 3 次元描画で使用する場合、太 い線 (linewidth > 1) を利用するとより効果的でしょう。それは 3 次元の棒 グラフに似たものになります。

     1 列:  y
     2 列:  x  y     # [x,0] から [x,y] への線 (2D)
     3 列:  x  y  z  # [x,y,0] から [x,y,z] への線 (3D)

2.17 labels

スタイル labels は、データファイルから座標と文字列を読み込み、その文 字列をその 2 次元、または 3 次元座標に置きます。これは基本的に 3 列、 または 4 列の入力を必要とします。さらに余分な入力列は、文字列の回転角 (キーワード ‘rotate variable‘) や文字色 (以下参照: ‘textcolor variable‘) のような、点毎に変動する属性値が指定されたとみなされます。

     3 列:  x  y  string    # 2 次元版
     4 列:  x  y  z  string # 3 次元版

フォント、色、回転角やその他の描画テキストの属性は追加オプションとして 指定可能です (以下参照: ‘set label‘)。次の例は、入力ファイルの 1 列目 から取った市の名前から作られる文字列を、4, 5 列目から取った地図座標に 描画します。フォントサイズは、3 列目の値から計算していて、この場合はそ れは人口を意味しています。

  CityName(String,Size) = sprintf("{/=%d %s}", Scale(Size), String)
  plot 'cities.dat' using 5:4:(CityName(stringcolumn(1),$3)) with labels

フォントサイズを、個々の市の名前に対して異なるサイズに合わせなくていい ならば、コマンドはもっと簡単です:

  plot 'cities.dat' using 5:4:1 with labels font "Times,8"

labels に ‘hypertext‘ がついている場合、その文字列はマウスがそれに対応 する点の上に来たときにだけ現われます。以下参照: ‘hypertext‘。この場合 ハイパーテキストの置き場所として機能する点を作るためにそのラベルの ‘point‘ 属性を有効にする必要があります:

  plot 'cities.dat' using 5:4:1 with labels hypertext point pt 7

スタイル points であらかじめ定義されている点の記号が適切でない、ある いは十分でない場合、その代わりとしてスタイル labels を使うこともでき ます。例えば、以下は単一文字として選択される組を定義し、3 列目のデータ 値に対応するその一つをグラフの各点に割り当てる例です (訳注: 以下のサン プルの <UTF-8 文字列> の部分には、元々、丸に中点記号や□、＋、トランプ 記号などの UTF-8 文字列が並んでいますが、この日本語訳とは両立しないた め取り除いています):

  set encoding utf8
  symbol(z) = "<UTF-8 文字列>"[int(z):int(z)]
  splot 'file' using 1:2:(symbol($3)) with labels

以下は、4 列目の値を可変値の回転角とし、5 列目の値を文字色 ("tc") とす るラベルの使用例です。可変値の色指定は、常に using 指定の最後の列か ら取ることに注意してください。

  plot $Data using 1:2:3:4:5 with labels tc variable rotate variable

2.18 lines

‘lines‘ スタイルは隣接する点を真直な線分で結びます。 これは、2 次元描画でも、3 次元描画でも使用でき、基本的には、1 列か 2 列か 3 列かの入力データを必要とします。 余分な入力列は、線の色の変更などの情報が提供されたものとして使用されま す (以下参照: ‘rgbcolor variable‘)。

2 次元 ("using" 指定なし) の場合

     1 列:  y       # 行番号による暗黙の x
     2 列:  x  y

3 次元 ("using" 指定なし) の場合

     1 列:  z       # x は暗黙の行番号、y は index から
     3 列:  x  y  z

以下も参照: linetype, ‘linewidth‘, ‘linestyle‘。

2.19 linespoints

linespoints スタイル (省略形 ‘lp‘) は、隣接する点を真っ直ぐな線分で 結び、その後で最初に戻って各点に小さな記号を描きます。点記号は、 ‘set pointsize‘ で決まるデフォルトの大きさで描きますが、plot コマンド 上で点のサイズを指定したり、あるいは入力データの追加列で個別の点サイズ を指定することもできます。追加の入力列は、個別の線の色などの情報を提供 するのにも使われます。以下参照: ‘lines‘, points。

グラフのすべての点に記号の印をつけるか否かを制御する 2 つのキーワード ‘pointinterval‘ (省略形 ‘pi‘), ‘pointnumber‘ (省略形 ‘pn‘) があります。

‘pi N‘ あるいは ‘pi -N‘ は、N 個毎に 1 つだけ記号を置くよう gnuplot に 指示します。負の値を指定すると、記号の下の線分の部分を消します。その消 す部分のサイズは ‘set pointintervalbox‘ で制御できます。

‘pn N‘ あるいは ‘pn -N‘ は、データ点のうち N 個だけラベル付けするよう gnuplot に指示します。点はそのデータ全体に渡って均等な間隔に取ります。 ‘pi‘ 同様、負の値を指定すると、記号の下の線分の部分を消します。

2.20 parallelaxes

平行座標描画 (parallel axis plot, parallel coordinates plot とも呼ばれ る) は、多次元データの相関を視覚化します。各入力列は、別々のスケールの 縦軸に割り当てられます。入力 1 行から読み込んだそれぞれの列の値は、1 つ目の軸から 2 つ目の軸へ、2 つ目の軸から 3 つ目の軸へと線分で結ばれま す。すなわち平行座標描画中では、入力の各行がそれぞれ独立した折れ線にな ります。それらを数種類に分類して色を割り当てることはよく行われますが、 それは、その分類と軸との間の関係を視覚的に調査することを可能にします。 デフォルトでは、gnuplot は自動的に個々の軸の範囲、スケールを入力データ から決定しますが、通常の ‘set axis range‘ コマンドによってそれをカスタ マイズすることも可能です。以下参照: ‘set paxis‘。

平行軸の最大個数は、gnuplot のコンパイル時に固定され、その最大値は、 ‘show version long‘ で表示されます。

2.21 points

points スタイルは各点に小さな記号を表示します。その記号のデフォルト の大きさを変更するにはコマンド ‘set pointsize‘ が使えます。デフォルト の点種は、線種と同じものになります。以下参照: linetype。plot コマン ドに using 指定がない場合は、入力データ列は仮定された方法で解釈され ます。以下参照: ‘style lines‘。

最初の 8 つの点種は、すべての出力形式で共通ですが、より多くの点種を個 別にサポートする出力形式もあります。現在の出力形式の設定でどのような点 種が用意されているかを見るには、コマンド test を使用してください。ま た、下の例のようにして、任意の印字可能文字を点種番号の代わりに使用する こともできます。より長い文字列は、描画スタイル points ではなく labels を使えば出力できます。

     plot sin(x) with points pt "#"

点種として、任意の UTF-8 文字を使用できます。以下参照: ‘utf8‘。

plot コマンド上でキーワード ‘pointtype‘, ‘pointsize‘, ‘linecolor‘ を使 う際、番号の代わりにキーワード ‘variable‘ を追加することができます。こ の場合、各点の対応する属性値を入力データの追加列から取得します。可変 (variable) pointsize 値は、常に using 指定で与えられる最初の追加列か ら取り、可変 color 値は、常に最後の追加列から取ります。今のところは、 スタイル linespoints の描画で線と点の色を別々に指定することはできま せん。各点に対して 3 つの属性をすべて指定する場合は、入力データ列指定 の順番は以下のようになります。

     plot DATA using x:y:pointsize:pointtype:color \
          with points lc variable pt variable ps variable

注意: 「ユーザ定義変数」の方の variable に関する情報については、以下参 照: variables。

2.22 steps

steps スタイルは 2 次元描画でのみ利用可能です。これは 2 本の線分で隣 り合う点をつなぎます: 1 本目は (x1,y1) から (x2,y1) まで、2 本目は (x2,y1) から (x2,y2) まで。入力列の条件は、‘lines‘ や points に対す るものと同じです。fsteps と steps の違いは、fsteps は、折れ線を 先に y 方向に書いてから次に x 方向に書くのに対し、steps は先に x 方 向に書いてから次に y 方向に書きます。曲線とベースラインである y=0 との 間の領域を塗り潰すには、fillsteps を使用してください。 以下も参照 steps デモ。

2.23 rgbalpha

以下参照: ‘image‘。

2.24 rgbimage

以下参照: ‘image‘。

2.25 vectors

2 次元の vectors スタイルは (x,y) から (x+xdelta,y+ydelta) までのベ クトルを書きます。3 次元の vectors スタイルも同様ですが、データは基 本的に 6 列必要です。いずれの場合も、入力列を追加 (2D では 5 列目、3D では 7 列目) すると、それらは各データ点毎の variable color 情報 (以下 参照: ‘linecolor‘, ‘rgbcolor variable‘) として使われます。 各ベクトルの先端には小さな矢先も書かれます。

     4 列:  x  y  xdelta  ydelta
     6 列:  x  y  z  xdelta  ydelta  zdelta

キーワード "with vectors" は、その後ろに、インラインの arrow スタイル 指定や、あらかじめ定義されている arrow スタイルの参照、あるいは列から 各ベクトルに対する必要な arrow スタイルのインデックスを読むような指定 を伴うことができます。注意: "arrowstyle variable" を使用する場合、対応 するベクトルが描画される際にはそれが arrow の属性値すべてを埋めるので その plot コマンド内に他の線属性や arrow スタイル指定をこのキーワード と混在させることはできません。

     plot ... with vectors filled heads
     plot ... with vectors arrowstyle 3
     plot ... using 1:2:3:4:5 with vectors arrowstyle variable

例:

      plot 'file.dat' using 1:2:3:4 with vectors head filled lt 2
      splot 'file.dat' using 1:2:3:(1):(1):(1) with vectors filled head lw 2

vectors スタイルを使っての splot は ‘set mapping cartesian‘ のみでサポ ートされています。 ‘set clip one‘ と ‘set clip two‘ は 2 次元のベクトルの描画に影響を与え ます。以下参照: ‘set clip‘, ‘arrowstyle‘。

2.26 xerrorbars

xerrorbars スタイルは 2 次元のデータ描画のみで利用可能です。 xerrorbars は、水平の誤差指示線 (error bar) が表示される以外は points と同じです。各点 (x,y) において (xlow,y) から (xhigh,y) まで、 または (x-xdelta,y) から (x+xdelta,y) までの線分が引かれますが、これら はいくつのデータ列が与えられるかによって変わります。誤差指示線の端の刻 みの印の見た目は、errorbars で制御できます。このスタイルは基本的 に、3 列か 4 列のデータが必要です:

     3 列:  x  y  xdelta
     4 列:  x  y  xlow  xhigh

入力列を追加 (4,5 列目) すると、それらは点の variable color 情報として 使われます。

2.27 xyerrorbars

xyerrorbars スタイルは 2 次元のデータ描画のみで利用可能です。 xyerrorbars は、水平、垂直の誤差指示線 (error bar) も表示される以外 は points と同じです。各点 (x,y) において (x,y-ydelta) から (x,y+ydelta) までと (x-xdelta,y) から (x+xdelta,y) まで、または (x,ylow) から (x,yhigh) までと (xlow,y) から (xhigh,y) までの線分が引 かれますが、これらはいくつのデータ列が与えられるかによって変わります。 誤差指示線の端の刻みの印の見た目は、errorbars で制御できます。こ れは 4 列か、6 列のデータが必要です。

     4 列:  x  y  xdelta  ydelta
     6 列:  x  y  xlow  xhigh  ylow  yhigh

データが、サポートされていない混合型の形式で与えられた場合、‘plot‘ コ マンドの using フィルタを使って適切な形に直さないといけません。例え ばデータが (x,y,xdelta,ylow,yhigh) という形式である場合、以下のように します:

      plot 'data' using 1:2:($1-$3):($1+$3):4:5 with xyerrorbars

入力列を追加 (5,7 列目) すると、それらは各データ点毎の variable color 情報として使われます。

2.28 yerrorbars

yerrorbars (または errorbars) スタイルは 2 次元のデータ描画のみで 利用可能です。yerrorbars は、垂直の誤差指示線 (error bar) が表示され る以外は points に似ています。各点 (x,y) において (x,y-ydelta) から (x,y+ydelta) まで、または (x,ylow) から (x,yhigh) までの線分が引かれま すが、これらはいくつのデータ列が与えられるかによって変わります。誤差指 示線の端の刻みの印の見た目は、errorbars で制御できます。

     2 列:  [暗黙の x]  y  ydelta
     3 列:  x  y  ydelta
     4 列:  x  y  ylow  yhigh

入力列を追加 (4,5 列目) すると、それらは点の variable color 情報として 使われます。

以下も参照 errorbar デモ。

2.29 xerrorlines

xerrorlines スタイルは 2 次元のデータ描画のみで利用可能です。 xerrorlines は linespoints に似ていますが、水平の誤差線が描かれる ことが違います。各点 (x,y) で、データ列の個数に応じて (xlow,y) から (xhigh,y) まで、または (x-xdelta,y) から (x+xdelta,y) までの線分が描か れます。誤差線の端の刻みの印の見た目は、errorbars で制御できます。 基本的には、3 列か 4 列のデータが必要です:

     3 列:  x  y  xdelta
     4 列:  x  y  xlow  xhigh

入力列を追加 (4,5 列目) すると、それらは点の variable color 情報として 使われます。

2.30 xyerrorlines

xyerrorlines スタイルは 2 次元のデータ描画のみで利用可能です。 xyerrorlines は linespoints に似ていますが、水平と垂直の誤差線も描 かれることが違います。各点 (x,y) で、データ列の個数に応じて、 (x,y-ydelta) から (x,y+ydelta) までと (x-xdelta,y) から (x+xdelta,y) まで、あるいは (x,ylow) から (x,yhigh) までと (xlow,y) から (xhigh,y) までの線分が描かれます。誤差線の端の刻みの印の見た目は、errorbars で制御できます。これは、4 列か 6 列の入力データが必要です。

     4 列:  x  y  xdelta  ydelta
     6 列:  x  y  xlow  xhigh  ylow  yhigh

データが、サポートされていない混合型の形式で与えられた場合、‘plot‘ コ マンドの using フィルタを使って適切な形に直さないといけません。例え ばデータが (x,y,xdelta,ylow,yhigh) という形式である場合、以下のように します:

      plot 'data' using 1:2:($1-$3):($1+$3):4:5 with xyerrorlines

入力列を追加 (5,7 列目) すると、それらは各データ点毎の variable color 情報として使われます。

2.31 yerrorlines

yerrorlines (または errorlines) スタイルは 2 次元のデータ描画のみ で利用可能です。yerrorlines は linespoints に似ていますが、垂直の 誤差線が描かれることが違います。各点 (x,y) で、データ列の個数に応じて (x,y-ydelta) から (x,y+ydelta) まで、または (x,ylow) から (x,yhigh) までの線分が描かれます。誤差線の端の刻みの印の見た目は、 errorbars で制御できます。これは、3 列か 4 列の入力が必要です。

     3 列:  x  y  ydelta
     4 列:  x  y  ylow  yhigh

入力列を追加 (4,5 列目) すると、それらは点の variable color 情報として 使われます。

以下も参照。 エラーバーのデモ

2.32 zerrorfill

書式:

     splot DATA using 1:2:3:4[:5] with zerrorfill {fc|fillcolor <colorspec>}
                {lt|linetype <n>} {<line properties>}

描画スタイル zerrorfill は、2 次元の描画スタイルの一つの変種のような ものです。これは、2 つの関数の間、または同じ x に対して 2 つの y 座標 の点を与えて得られるデータの折れ線の間の領域を塗り潰します。これは、4 列か 5 列の入力が必要です。

     4 列:  x  y  z  zdelta
     5 列:  x  y  z  zlow  zhigh

zlow と zhigh の間の領域を塗り潰し、その後 z の値のところに線を描きま す。デフォルトでは、その線と塗り潰しには同じ色を使いますが、その色は splot コマンド上で変更できます。塗り潰しの設定は、大域的な fill style の影響も受けます。以下参照 ‘set style fill‘。

splot コマンドに複数の曲線を指定した場合は、後に描いた曲線が、前のすべ ての曲線を隠してしまう可能性があります。見る人側の手前の曲線のみが隠す ように適切な深さ順の並べかえを行うには、コマンド ‘set pm3d depthorder‘ を使用してください。残念ながら、これは z の値に対応するすべての折れ線 を描いた後に、すべての領域の塗り潰しを行います。よって、折れ線を見える ようにして、かつ領域の塗り潰しの深さ順の並べかえを行うには、領域の塗り 潰しは部分的に透過 (transparent) させるか、ベタ塗り (solid fill) の代 わりにパターン塗り (pattern fill) を使用するといいかもしれません。

以下の最初の 2 つの例の塗り潰し領域は、同じものになります。

     splot 'data' using 1:2:3:4 with zerrorfill fillcolor "grey" lt black
     splot 'data' using 1:2:3:($3-$4):($3+$4) with zerrorfill
     splot '+' using 1:(const):(func1($1)):(func2($1)) with zerrorfill
     splot for [k=1:5] datafile[k] with zerrorfill lt black fc lt (k+1)

この描画スタイルは、柵グラフ (fence plot) を作成するのに使うこともでき ます。以下参照: ‘fenceplots‘。

2.33 3 次元描画 (3D plots)

3 次元グラフは、コマンド ‘plot‘ ではなくコマンド ‘splot‘ を使って生成 します。多くの 2 次元描画スタイル (points, images, impulse, labels, vectors) は、z 座標データ列を追加指定すれば 3 次元でも使えます。2 次元 射影グラフのみが欲しい場合でも、‘splot‘ コマンドを使って生成しなければ いけない描画型 (pm3d coloring, surfaces, contours) も中にはあります。

2.33.1 曲面描画 (Surface plots)

描画スタイル ‘splot with lines‘ や ‘splot with surface‘ はいずれも曲面 を格子線で生成します。曲面の塗り潰しは、スタイル ‘splot with pm3d‘ で 行うことができます。曲面は通常、それが 3 次元の曲面であるとはっきりわ かるような適切な視方向から表示されます。以下参照: ‘set view‘。 その場合、X, Y, Z 軸はすべて描画内に表示されます。3 次元的な錯覚は、隠 線処理や、曲面要素の深さ整列により、より増幅されます。以下参照: ‘hidden3d‘, および ‘set pm3d‘ のオプションである ‘depthorder‘。 コマンド ‘splot‘ は、定数の Z 値に対する等高線を計算し描画することもで きます。これらの等高線は、曲面それ自体の上に書くこともできますし、XY 平面へ射影することもできます。以下参照: ‘set contour‘。

2.33.2 2 次元射影 (set view map)

コマンド ‘splot‘ の特別な場合として、描画の Z 方向の射影による、Z 座標 の 2 次元曲面への地図作成 (map) があります。以下参照: ‘set view map‘。 この描画モードは、等高線の描画や温度分布を生成するのに利用できます。こ の図は描画スタイル ‘lines‘ を一度、labels を一度描画した等高線を示し ています (訳注: 図が表示されている場合)。

2.34 極座標描画 (Polar plots)

極座標描画 (polar) は、plot コマンドを入力する前に現在の座標系を極座標 に変更することによって生成します。オプション ‘set polar‘ は、入力する 2 次元座標を <x>,<y> の代わりに <角>,<半径> と解釈することを gnuplot に指示します。すべてではないですが、多くの 2 次元描画スタイルが極座標 モードでも機能します。図は、描画スタイル ‘lines‘ と filledcurves の 組み合わせを示しています。(訳注: 図が表示されている場合) 以下参照: ‘set polar‘, rrange, ‘set size square‘, ‘set theta‘, ttics。

2.35 ビースウォーム描画 (Bee swarm plots)

ビースウォーム (bee swarm) グラフは、揺らぎ (jitter) を適用して重複点 を分離することにより得られる結果です。その典型的な例は、各点に x 座標 を決定する 2 つ以上のカテゴリによって表わされる y の値の分布の比較です。 重なりの判定基準や、jitter で使用する移動パターンを制御する方法に関し ては、以下参照: jitter。この図のグラフは、異なる jitter の設定に 対する同じ plot コマンドによって作られたものです。

     `plot $data using 1:2:1 lc variable`

2.36 柵グラフ (Fence plots)

柵グラフ (fence plot) は、複数の 2 次元グラフを、その Y 座標は揃え、そ れぞれを区別するために X に沿ってはずらした形で結合したものです。土台 の値から個々のグラフの Z 座標までの間の領域を塗り潰すことで、Y 方向の 整列と Z 座標の高さの違いの見た目を強調します。gnuplot でこの形式のグ ラフを書くにはいくつかの方法があります。最も単純なのは、5 列の形式の zerrorfill スタイルを利用する方法です。i で添字化された複数の曲線 z

 = Fi(y) があるとき、zerrorfill で以下のような入力列を使

えば柵グラフを書くことができます:

     i y z_base z_base Fi(y)

3 コマンド (Commands)

このセクションでは ‘gnuplot‘ が受け付けるコマンドをアルファベット順に 並べています。このドキュメントを紙に印刷したものは全てのコマンドを含ん でいますが、対話型で参照できるドキュメントの方は完全ではない可能性があ ります。実際、この見出しの下に何のコマンドも表示されないシステムがあり ます。

ほとんどの場合、コマンド名とそのオプションは、紛らわしくない範囲で省略 することが可能です。すなわち、"‘plot f(x) with lines‘" の代わりに "‘p f(x) w li‘" とすることができます。

書式の記述において、中カッコ ({}) は追加指定できる引数を意味し、 縦棒 (|) は互いに排他的な引数を区切るものとします。

3.1 Break

コマンド ‘break‘ は、‘do‘, ‘while‘ 文の繰り返し実行部分のカッコ内での み意味を持ちます。このコマンドは、その中カッコ内の残りの命令をスキップ し、繰り返しを中断し、その閉じカッコの次の文から実行を再開します。以下 も参照: ‘continue‘。

3.2 cd

‘cd‘ コマンドはカレントディレクトリを変更します。

書式:

        cd '<ディレクトリ名>'

ディレクトリ名は引用符に囲まれていなければなりません。

例:

        cd 'subdir'
        cd '..'

バックスラッシュ (\) は二重引用符内 (") では特別な意味を持ってしまうた めにエスケープする必要がありますので、Windows ユーザには単一引用符を使 うことを勧めます。例えば、

        cd "c:\newdata"

では失敗しますが、

        cd 'c:\newdata'
        cd "c:\\newdata"

なら期待通りに動くでしょう。

3.3 call

call コマンドは、読み込むファイル名の後ろに、9 つまでのパラメータを 与えることができることを除けば load コマンドと等価です。

     call "inputfile" <param-1> <param-2> <param-3> ... <param-9>

gnuplot の以前のバージョンでは、そのパラメータ文字列の内容を、特別な記 号 $0, $1, ..., $9 をマクロのように置換することで表現していました。こ の仕組みは、現在は非推奨です (以下参照: old-style)。

現在の gnuplot は、文字列変数 ARG0, ARG1, ..., ARG9 と、整数変数 ARGC を提供します。call コマンドを実行すると、ARG0 には入力ファイル名が、 ARGC にはパラメータ数が設定され、ARG1 から ARG9 にはコマンドラインに並 べられたパラメータの値が読み込まれます。

通常パラメータは文字列値として保存されるので、それをマクロ展開して参照 することもできます (古い形式の書式の類似)。しかし、多くの場合、それらは 他の変数と同様に利用する方がより自然でしょう。

3.3.1 例 (Example)

     以下を call すると:
         MYFILE = "script1.gp"
         FUNC = "sin(x)"
         call MYFILE FUNC 1.23 "This is a plot title"
     呼び出されたスクリプト内では以下のようになり:
         ARG0 は "script1.gp"
         ARG1 は文字列値 "sin(x)"
         ARG2 は文字列値 "1.23"
         ARG3 は文字列値 "This is a plot title"
         ARGC は 3
     そのスクリプト内では以下のようなものを実行できる:
         plot @ARG1 with lines title ARG3
         print ARG2 * 4.56, @ARG2 * 4.56
         print "This plot produced by script ", ARG0

この例の ARG1 はマクロとして参照しなければいけませんが、ARG2 はマクロ 参照でも (数値定数になる)、変数のままでも (文字列 "1.23" が実数値に自 動的に変換された後の同じ数値になる) 構わないことに注意してください。

シェルスクリプトで gnuplot をコマンドラインオプション ‘-c‘ つきで実行 することで、これと同じことを直接行うこともできます:

     gnuplot -persist -c "script1.gp" "sin(x)" 1.23 "This is a plot title"

3.3.2 old-style

以下は、古いバージョンの gnuplot で使われていた call の仕組みの記述で すが、現在は非推奨です。

      call "<input-file>" <param-0> <param-1> ... <param-9>

入力ファイル名は引用符で囲まなければなりません。入力ファイルの各行を読 み込む際に、以下の特別な文字列を走査します: $0 $1 $2 $3 $4 $5 $6 $7 $8 $9 $#。それが見つかったら、「‘$‘+数字」の列は call コマンドラインの 対応するパラメータに置き換えます。引用符はコピーせず、文字列変数置換は 行いません。文字列 ‘$#‘ はパラメータ数に置き換えます。その他の文字が後 ろについている ‘$‘ は、エスケープシーケンスとして処理します。例えば 1 個 の ‘$‘ を使うには ‘$$‘ とします。

例:

ファイル ’calltest.gp’ は以下の行を含んでいるとすると:

    print "argc=$# p0=$0 p1=$1 p2=$2 p3=$3 p4=$4 p5=$5 p6=$6 p7=x$7x"

次の行を入力すると:

    call 'calltest.gp' "abcd" 1.2 + "'quoted'" -- "$2"

以下のように表示されるでしょう:

    argc=7 p0=abcd p1=1.2 p2=+ p3='quoted' p4=- p5=- p6=$2 p7=xx

注意: 文字 ‘$‘ は、gnuplot 自身のデータ列用の書式とぶつかりますし、 Unix 系のシェルの環境変数を参照する ‘$‘ ともぶつかります。特別な文字列 ‘$#‘ は、gnuplot のバージョン 4.5 から 4.6.3 までは、間違えてコメント 文字列の区切り文字として解釈されていました。文字列置換では引用符は無視 されるので、文字列定数は簡単に壊れてしまいます。

3.4 clear

clear コマンドは、terminal や output で選択した画面、出 力装置をクリアします。ハードコピー装置に対しては通常改ページを行います。

いくつかの出力装置は clear コマンドでは ‘set size‘ で定義された描画 領域のみを消去します。そのため、‘set multiplot‘ とともに使用することで 挿入図を一つ作ることができます。

例:

      set multiplot
      plot sin(x)
      set origin 0.5,0.5
      set size 0.4,0.4
      clear
      plot cos(x)
      unset multiplot

詳細については、以下参照: ‘set multiplot‘, ‘set size‘, ‘set origin‘。

3.5 Continue

コマンド ‘continue‘ は、‘do‘, ‘while‘ 文の繰り返し実行部分のカッコ内で のみ意味を持ちます。このコマンドは、その中カッコ内の残りの命令をスキッ プし、次の繰り返しに進みます (もしループの残りがあれば)。以下も参照: ‘break‘。

3.6 Do

書式:

      do for <iteration-spec> {
           <commands>
           <commands>
      }

これは、コマンド列を複数回実行します。コマンドは中カッコ {} で囲み、か つ開始カッコ "{" は、キーワード ‘do‘ と同じ行に置く必要があります。こ のコマンドは、古い形式 (かっこなし) の if/else 構文と一緒に使うことは できません。繰り返し指定 <iteration-spec> の例については、以下参照: ‘iteration‘。例:

      set multiplot layout 2,2
      do for [name in "A B C D"] {
          filename = name . ".dat"
          set title sprintf("Condition %s",name)
          plot filename title name
      }
      unset multiplot

以下も参照: ‘while‘, ‘continue‘, ‘break‘。

3.7 evaluate

コマンド evaluate は、引数文字列として与えられたコマンドを実行します。 その文字列中に改行文字を入れてはいけません。

書式:

      eval <string expression>

これは、特に同様のコマンドの繰り返しに有用です。

例:

      set_label(x, y, text) \
        = sprintf("set label '%s' at %f, %f point pt 5", text, x, y)
      eval set_label(1., 1., 'one/one')
      eval set_label(2., 1., 'two/one')
      eval set_label(1., 2., 'one/two')

文字列からコマンドを実行する別の方法に関しては、以下参照: ‘substitution macros‘。

3.8 exit

     exit
     exit message "エラーメッセージ文字列"
     exit status <整数のエラーコード>

exit と quit の両コマンドは END-OF-FILE 文字 (通常 Ctrl-D) 同様、 現在の入力ストリーム、すなわち端末の対話やパイプ入力、ファイル入力 (パ イプ) からの入力を終了させます。入力ストリームが入れ子 (階層的な load のスクリプトで) になっている場合、読み込みは親のストリームで継 続されます。トップレベルのストリームが閉じられると、プログラムはそれ自 身終了します。

コマンド ‘exit gnuplot‘ は、直ちに、無条件に、そして例え入力ストリーム が多段階にネストされていても、gnuplot を終了させます。その場合、開かれ ていた全ての出力ファイルはきれいに完全な形では閉じられない可能性があり ます。使用例:

      bind "ctrl-x" "unset output; exit gnuplot"

コマンド ‘exit error "error message"‘ は、疑似プログラムエラーを行いま す。対話型モードでは、そのエラーメッセージを表示し、すべのネストされた ループや call を中断してコマンドラインに帰ります。非対話型モードでは、 プログラムを終了します。

gnuplot が終了しシェルの制御に戻る場合、その返り値は意味のないものにな ることがありますが、このコマンドを以下のように実行すれば、シェルに特定 の値を返すことが可能です。

     exit status <value>

詳細は、以下参照: ‘batch/interactive‘。

3.9 fit

コマンド ‘fit‘ は、Marquardt-Levenberg 法による非線形最小自乗法 (NLLS) を用いて、データ点の集合にユーザが与える式を当てはめます。独立変数は 12 まで許されていて、従属変数は常に 1 つで、任意個数のパラメータを当て はめることができます。さらに追加で、データ点の重み付け用に誤差評価を入 力することも可能です。

‘fit‘ の最も基本的な使用法は、以下の単純な例が示しています:

      f(x) = a + b*x + c*x**2
      fit f(x) 'measured.dat' using 1:2 via a,b,c
      plot 'measured.dat' u 1:2, f(x)

書式:

      fit {<ranges>} <expression>
          '<datafile>' {datafile-modifiers}
          {{unitweights} | {y|xy|z}error | errors <var1>{,<var2>,...}}
          via '<parameter file>' | <var1>{,<var2>,...}

範囲 (xrange, yrange 等) は、当てはめに使用するデータを制限する目的で 使うことができ、その範囲を超えたデータは無視します。その書式は ‘plot‘ コマンド同様

      [{dummy_variable=}{<min>}{:<max>}],

です。以下参照: ‘plot ranges‘。

<expression> は、通常はあらかじめユーザ定義された f(x) または f(x,y) の形の関数ですが、‘gnuplot‘ で有効などんな数式でも指定できます。ただし 実数値関数でなければいけません。 独立変数の名前は、コマンド ‘set dummy‘ で設定するか、fit の範囲指定部 分 (<rangse>) で設定します (以下を参照)。デフォルトでは、最初の 2 つは x, y となります。 さらに、その数式は、当てはめの作業により決定する値を持つ 1 つ以上の変 数 (パラメータ) に依存すべきです。

<datafile> は ‘plot‘ コマンドと同様に扱われます。datafile の修 飾子 (using, every,...) は、smooth を除いて、全て ‘fit‘ に使うこ とができます。以下参照:datafile。

データファイルの内容は、plot コマンドに使用するのと同じ using 指定を 使うことで柔軟に解釈させることができます。例えば、独立変数 x を2 列目 と 3 列目の和として生成し、z の値を 6 列目から取り、重みを 1 としたい 場合は以下のようにします:

      fit ... using ($2+$3):6

using 指定がない場合、fit は暗黙に独立変数は 1 つだけと仮定します。 ファイル自身、または using 指定が 1 列だけのデータを持つ場合、その行番 号を独立変数値として使用します。 using 指定を与えた場合、最大 12 個 (指定してコンパイルしていればさら にそれ以上) の独立変数を利用できます。

オプション ‘unitweights‘ (これがデフォルト) は、すべてのデータ点が等し い重みを持つとみなします。これは、キーワード ‘error‘ を使用することで 変更でき、これはデータファイルから 1 つ以上の変数の誤差評価を読み込み、 その誤差評価を対応する変数値の標準偏差 s とみなし、各データに 1/s**2 の重みを計算するのに使用します。

独立変数の誤差評価において、その重みには、"有効分散法" (effective variance method; Jay Orear, Am. J. Phys., Vol. 50, 1982) に従って、さ らに当てはめ関数の微分係数をかけます。

キーワード ‘errors‘ には、その後ろに、入力がどの変数の誤差であるのかを 示すコンマ区切りの 1 つ以上の変数名のリストが付きます。従属変数 z は常 にその中になければいけませんが、独立変数は必須ではありません。 そのリストの各変数に対し、ファイルからその分の、各変数の誤差評価を持つ 追加の列を読み込みます。繰り返しになりますが、using 指定により柔軟な 解釈が可能になります。 よって、独立変数の数は暗黙に、using 指定内の列の数から 1 を引いて (従属変数分)、さらに ‘errors‘ 指定内の変数の個数を引いた数になることに 注意してください。

例として、2 つの独立変数があり、そして 1 つ目の独立変数と従属変数の誤 差データがある場合は、‘errors x,z‘ 指定と 5 列の using 指定を使うこ とになりますが、それは x:y:z:sx:sz のように解釈されます (x, y は独立変 数、z が従属変数、sx, sz は x, z の標準偏差)。

‘errors‘ 指定のちょっとした略記法も 2,3 用意されています: ‘yerrors‘ (独立変数が 1 列ある当てはめ用)、 ‘zerrors‘ (より一般の場合) は、いずれも ‘errors z‘ と同値で、1 列だけ 追加の従属変数用の誤差列があることを意味しています。

‘xyerrors‘ は、独立変数は 1 列で、その独立変数と従属変数の両方の 2 列 の誤差列が追加されることを意味します。この場合、x と y の誤差は Orear の有効分散法 (effective variance method) で処理されます。

‘yerror‘ と ‘xyerror‘ の形式および解釈は、それぞれ 2 次元描画スタイル の yerrorlines と xyerrorlines に同等であることに注意してください。

コマンド ‘set fit v4‘ を使用すると、fit のコマンド書式は ‘gnuplot‘ バ ージョン 4 以前と互換の書式になります。その場合、using には、独立変 数が 2 つ以上ならば、独立変数の数より 2 つ (z と s) 多い指定が必要で、 ‘gnuplot‘ は、using 指定で与えられた列の数に応じて、以下の書式に従い ます:

      z                           # 独立変数は 1 つ (行番号)
      x:z                         # 独立変数は 1 つ (第 1 列)
      x:z:s                       # 独立変数は 1 つ (全部で 3 列)
      x:y:z:s                     # 独立変数は 2 つ (全部で 4 列)
      x1:x2:x3:z:s                # 独立変数は 3 つ (全部で 5 列)
      x1:x2:x3:...:xN:z:s         # 独立変数は N 個 (全部で N+2 列)

これは、2 つ以上の独立変数で fit をする場合、z-誤差 s を与える必要があ ることを意味することに注意してください。重みを 1 にしたい場合は、それ を、例えば x:y:z:(1) のような書式を using に指定することで明示的に与え る必要があります。

仮変数名は、下で紹介するように範囲指定で指定することで変更できます。最 初の範囲は using 指定の最初のものに対応し、以下同様です。従属変数で ある z の範囲指定もできますが、それは、f(x,...) の値をその範囲外にして しまうようなデータ点が、残差を最小化することには寄与しない場合に有効で す。

複数のデータ集合も複数の 1 変数関数に同時に当てはめることも、y を ’仮 変数’ とすれば可能です。例えばデータ行番号を使い、2 変数関数への当ては め、とすればいいでしょう。以下参照: ‘fit multi-branch‘。

‘via‘ 指定子は、パラメータの最適化を、直接行うか、またはパラメータファ イルを参照することによって行うかを指定します。

例:

      f(x) = a*x**2 + b*x + c
      g(x,y) = a*x**2 + b*y**2 + c*x*y
      set fit limit 1e-6
      fit f(x) 'measured.dat' via 'start.par'
      fit f(x) 'measured.dat' using 3:($7-5) via 'start.par'
      fit f(x) './data/trash.dat' using 1:2:3 yerror via a, b, c
      fit g(x,y) 'surface.dat' using 1:2:3 via a, b, c
      fit a0 + a1*x/(1 + a2*x/(1 + a3*x)) 'measured.dat' via a0,a1,a2,a3
      fit a*x + b*y 'surface.dat' using 1:2:3 via a,b
      fit [*:*][yaks=*:*] a*x+b*yaks 'surface.dat' u 1:2:3 via a,b

      fit [][][t=*:*] a*x + b*y + c*t 'foo.dat' using 1:2:3:4 via a,b,c

      set dummy x1, x2, x3, x4, x5
      h(x1,x2,x3,x4,s5) = a*x1 + b*x2 + c*x3 + d*x4 + e*x5
      fit h(x1,x2,x3,x4,x5) 'foo.dat' using 1:2:3:4:5:6 via a,b,c,d,e

反復の個々のステップの後で、当てはめの現在の状態についての詳細な情報が 画面に表示されます。そし最初と最後の状態に関する同じ情報が "fit.log" というログファイルにも書き出されます。このファイルは前の当てはめの履歴 を消さないように常に追加されていきます。これは望むなら削除、あるいは別 な名前にできます。コマンド ‘set fit logfile‘ を使ってログファイルの名 前を変更することもできます。

‘set fit errorvariables‘ を使用した場合、各当てはめパラメータの誤差は そのパラメータと似た名前 ("_err" が追加された名前) の変数に保存されま すので、その誤差をその後の計算の入力として使用することができます。

‘set fit prescale‘ とした場合、当てはめパラメータを、それらの初期値か らスケール変換します。これにより、個々のパラメータの大きさにかなり違い があるような場合でも、Marquardt-Levenberg ルーチンがより早く、より信頼 性のある値に収束させられるようになります。

当てはめの反復は Ctrl-C (wgnuplot では Ctrl-Break) を押すことで中断で きます。現在の反復が正常に終了した後、以下のいずれかを選ぶことができま す: (1) 当てはめを止めて現在のパラメータの値を採用する (2) 当てはめを続行する (3) ‘set fit script‘ か、環境変数 ‘FIT_SCRIPT‘ で指定した ‘gnuplot‘ コ マンドを実行する。そのデフォルトは replot で、もしデータと当てはめ関 数を一つのグラフにあらかじめ描画してあれば、現在の当てはめの状態を表示 することができます。

‘fit‘ が終了した後は、最後のパラメータの値を保存するのに ‘save fit‘ コ マンドを使います。その値は再びパラメータの値として使うことができます。 詳細は、以下参照: ‘save fit‘。

3.9.1 パラメータの調整 (adjustable parameters)

‘via‘ はパラメータを調節するための 2 つの方法を指定できます。一つは コマンドラインから直接指示するもので、もう一つはパラメータファイルを 参照して間接的に行うものです。この 2 つは初期値の設定で違った方法を取 ります。

調整するパラメータは、‘via‘ キーワードの後ろにコンマで区切られた変数名 のリストを書くことで指定できます。定義されていない変数は初期値 1.0 と して作られます。しかし当てはめは、変数の初期値があらかじめ適切な値に設 定されている方が多分速く収束するでしょう。

パラメータファイルは個々のパラメータを、個別に 1 行に一つずつ、初期値を 次のような形で指定して書きます。

      変数名 = 初期値

’#’ で始まるコメント行や空行も許されます。特別な形式として

      変数名 = 初期値       # FIXED

は、この変数が固定されたパラメータであることを意味し、それはこのファイ ルで初期化されますが、調節はされません。これは、‘fit‘ でレポートされる 変数の中で、どれが固定された変数であるかを明示するのに有用でしょう。な お、‘# FIXED‘ と言うキーワードは厳密にこの形でなくてはなりません。

3.9.2 fit の概略 (fit beginners_guide)

‘fit‘ は、与えられたデータ点を与えられたユーザ定義関数にもっとも良く 当てはめるようなパラメータを見つけるのに使われます。その当てはめは、 同じ場所での入力データ点と関数値との自乗誤差、あるいは残差 (SSR:Sum of the Squared Residuals) の和を基に判定されます。この量は通常χ(カイ) 自乗と呼ばれます。このアルゴリズムは SSR を 最小化することをしようと します。もう少し詳しく言うと、データ誤差 (または 1.0) の重みつき残差の 自乗和 (WSSR) の最小化を行っています。詳細は、以下参照: ‘fit error_estimates‘。

これが、(非線形) 最小自乗当てはめ法と呼ばれるゆえんです。‘非線形‘ が 何を意味しているのかを見るための例を紹介しますが、その前にいくつかの 仮定について述べておきます。ここでは簡単のため、1 変数のユーザー定義 関数は z=f(x), 2 変数の関数は z=f(x,y) のようにし、いずれも従属変数と して z を用いることにします。パラメータとは ‘fit‘ が調整して適切な値を 決定するユーザ定義変数で、関数の定義式中の未知数です。ここで言う、線形 性/非線形性とは、従属変数 z と ‘fit‘ が調整するパラメータとの関係に対 するものであり、z と独立変数 x (または x と y) との関係のことではあり ません (数学的に述べると、線形最小自乗問題では、当てはめ関数のパラメー タによる 2 階 (そして更に高階の) 導関数は 0、ということになります)。

線形最小自乗法 (LLS) では、ユーザ定義関数は単純な関数の和であり、それ ぞれは一つのパラメータの定数倍で他のパラメータを含まない項になります。 非線形最小自乗法 (NLLS) ではより複雑な関数を扱い、パラメータは色んな 使われ方をされます。フーリエ級数は線形と非線形の最小自乗法の違いを表す 一つの例です。フーリエ級数では一つの項は

     z=a*sin(c*x) + b*cos(c*x).

のように表されます。もし、a と b が未知なパラメータで c は定数だとすれば パラメータの評価は線形最小自乗問題になります。しかし、c が未知なパラメー タならばそれは非線形問題になります。

線形の場合、パラメータの値は比較的簡単な線形代数の直接法によって決定で きます。しかしそのような LLS は特殊な場合であり、’gnuplot’ が使用する 反復法は、もちろんそれも含めて、より一般的な NLLS 問題を解くことができ ます。‘fit‘ は検索を行うことで最小値を探そうとします。反復の各ステップ は、パラメータの新しい値の組に対して WSSR を計算します。Marquardt- Levenberg のアルゴリズムは次のステップのパラメータの値を選択します。そ してそれはあらかじめ与えた基準、すなわち、(1) 当てはめが "収束した" (WSSR の相対誤差がある限界値より小さくなった場合。以下参照: ‘set fit limit‘)、または (2) あらかじめ設定された反復数の限界に達した 場合 (以下参照: ‘set fit maxiter‘)、のいずれかを満たすまで続けられます。 キーボードからその当てはめの反復は中断できますし、それに続いて中止する こともできます (以下参照: ‘fit‘)。ユーザ変数 FIT_CONVERGED は、 直前の fit コマンドが収束により終了した場合は 1 を持ち、それ以外の理由で中断 した場合は 0 を持ちます。FIT_NITER は、直前の当てはめで行われた繰り返 しの回数を持ちます。

当てはめに使われる関数はしばしばあるモデル (またはある理論) を元にして いて、それはデータの振舞を記述したり、あるいは予測しようとします。よっ て ‘fit‘ は、データがそのモデルにどれくらいうまく当てはまっているのかを 決定するため、そして個々のパラメータの誤差の範囲を評価するために、モデ ルの自由なパラメータの値を求めるのに使われます。以下参照: ‘fit error_estimates‘。

そうでなければ、曲線による当てはめにおける関数は、モデルとは無関係に選 ばれています (それは十分な表現力と最も少ない数のパラメータを持ち、デー タの傾向を記述しそうな関数として経験に基づいて選ばれるでしょう)。

しかし、もしあなたが全てのデータ点を通るような滑らかな曲線を欲しいなら ‘fit‘ ではなく、むしろ ‘plot‘ の smooth オプションでそれを行うべきで しょう。

3.9.3 誤差評価 (error estimates)

‘fit‘ において "誤差" という用語は 2 つの異なった文脈で用いられます。 一つはデータ誤差、もう一つはパラメータ誤差です。

データ誤差は、平方残差の重み付きの和 WSSR、すなわちχ自乗を決定する際 個々のデータ点の相対的な重みを計算するのに用いられます。それらはパラメ ータの評価に影響を与えます。それは、それらが、当てはめられた関数からの 個々のデータ点の偏差が最終的な値に与える影響の大きさを決定することによ ります。正確なデータ誤差評価が与えられている場合には、パラメータの誤差 評価等の ‘fit‘ が出力する情報はより役に立つでしょう。

‘statistical overview‘ では ‘fit‘ の出力のいくつかを説明し、 ’practical guidelines’ に対する背景を述べています。

3.9.3.1 統計的な概要 (statistical overview)

非線形最小自乗法 (Non-Linear Least-Squares; NLLS) の理論は、誤差の正規 分布の点から一般的に記述されています。すなわち、入力データは与えられた 平均とその平均に対する与えられた標準偏差を持つガウス (正規) 分布に従う 母集団からの標本と仮定されます。十分大きい標本、そして母集団の標準偏差 を知ることに対しては、χ自乗分布統計を用いて、通常「χ自乗」と呼ばれる 値を調べることにより「当てはめの良さ」を述べることができます。減らされ た自由度のχ自乗 (χ自乗の自由度は、データ点の数から当てはめられるパラ メータの個数だけ引いた数) が 1.0 である場合は、データ点と当てはめられた 関数との偏差の重みつき自乗和が、現在のパラメータ値に対する関数と与えら れた標準偏差によって特徴付けられた母集団の、ランダムなサンプルに対する 自乗和とが全く同じであることを意味します。

分散 = 総計である数え上げ統計学同様、母集団の標準偏差が定数でない場合、 各点は観測される偏差の和と期待される偏差の和を比較するときに個別に重み づけされるべきです。

最終段階で ‘fit‘ は ’stdfit’、すなわち残差の RMS (自乗平均平方根) で求 められる当てはめの標準偏差と、データ点が重みづけられている場合に ’減ら されたχ自乗’ とも呼ばれる残差の分散をレポートします。自由度 (データ点 の数から当てはめパラメータの数を引いたもの) はこれらの評価で使用されま す。なぜなら、データ点の残差の計算で使われるパラメータは同じデータから 得られるものだからです。データ点が重みを持つ場合、‘gnuplot‘ はいわゆる p-値を計算します。それはその自由度と結果のχ自乗値に対するχ自乗分布の 累積分布関数値を 1 から引いた値です。以下参照: ‘practical_guidelines‘。 これらの値は以下の変数に代入されます:

      FIT_NDF = 自由度の数
      FIT_WSSR = 重みつき残差の自乗和
      FIT_STDFIT = sqrt(WSSR/NDF)
      FIT_P = p-値

パラメータに関する信頼レベルを評価することで、当てはめから得られる最小 のχ自乗と、要求する信頼レベルのχ自乗の値を決定するためのχ自乗の統計 を用いることが出来ます。しかし、そのような値を生成するパラメータの組を 決定するには、相当のさらなる計算が必要となるでしょう。

‘fit‘ は信頼区間の決定よりむしろ、最後の反復後の分散-共分散行列から直 ちに得られるパラメータの誤差評価を報告します。これらの評価は、標準偏差 として計算される量の指定に関する統計上の条件が、一般には非線形最小自乗 問題では保証されないのですが、線形最小自乗問題での標準誤差 (各パラメー タの標準偏差) と同じ方法で計算されます。そしてそのため慣例により、これ らは "標準誤差" とか "漸近標準誤差" と呼ばれています。漸近標準誤差は一 般に楽観過ぎ、信頼レベルの決定には使うべきではありませんが、定性的な指 標としては役に立つでしょう。

最終的な解は、解の範囲におけるパラメータの相関を示す相関行列も生成しま す: その主対角要素、すなわち自己相関は常に 1 で、全てのパラメータが独 立ならば非対角要素はすべて 0 に近い値になります。完全に他を補いあう 2 つの変数は、大きさが 1 で、関係が正の相関か負の相関かによって正か負に なる符号を持つ非対角要素を持ちます。非対角要素の大きさが小さいほど、各 パラメータの標準偏差の評価は、漸近標準誤差に近くなります。

3.9.3.2 実用的なガイドライン (practical guidelines)

個々のデータ点への重みづけの割り当ての基礎を知っているなら、それが測定 結果に対するより詳しい情報を使用させようとするでしょう。例えば、幾つか の点は他の点より当てになるということを考慮に入れることが可能です。そし て、それらは最終的なパラメータの値に影響します。

データの重み付けは、最後の反復後の ‘fit‘ の追加出力に対する解釈の基礎 を与えます。各点に同等に重み付けを行なうにしても、重み 1 を使うことよ りもむしろ平均標準偏差を評価することが、χ自乗が定義によりそうであるよ うに、WSSR を 無次元変数とすることになります。

当てはめ反復の各段階で、当てはめの進行の評価に使うことが出来る情報が表 示されます (’*’ はより小さい WSSR を見つけられなかったこと、そして再試 行していることを意味します)。’sum of squares of residuals’ (残差の自乗 和) は、’chisquare’ (χ自乗) とも呼ばれますが、これはデータと当てはめ 関数との間の WSSR を意味していて、‘fit‘ はこれを最小化しようとします。 この段階で、重み付けされたデータによって、χ自乗の値は自由度 (= データ 点の数 - パラメータの数) に近付くことが期待されます。WSSR は補正された χ自乗値 (WSSR/ndf; ndf = 自由度)、または当てはめ標準偏差 (stdfit = sqrt(WSSR/ndf)) を計算するのに使われます。それらは最終的な WSSR に対し てレポートされます。

データが重み付けされていなければ、stdfit は、ユーザの単位での、データ と当てはめ関数の偏差の RMS (自乗平均平方根) になります。

もし妥当なデータ誤差を与え、データ点が十分多く、モデルが正しければ、 補正χ自乗値はほぼ 1 になります (詳細は、適当な統計学の本の ’χ自乗分 布’ の項を参照してください)。この場合、この概要に書かれていること以外 に、モデルがデータにどれくらい良く当てまっているかを決定するための追加 の試験方法がいくつかあります。

補正χ自乗が 1 よりはるかに大きくなったら、それは不正なデータ誤差評価、 正規分布しないデータ誤差、システム上の測定誤差、孤立した標本値 (outliers)、または良くないモデル関数などのためでしょう。例えば ‘plot ’datafile’ using 1:($2-f($1))‘ などとして残差を描画することは、 それらのシステム的な傾向を知るための手がかりとなります。データ点と関数 の両者を描画することは、他のモデルを考えための手がかりとなるでしょう。

同様に、1.0 より小さい補正χ自乗は、WSSR が、正規分布する誤差を持つラ ンダムなサンプルと関数に対して期待されるものよりも小さいことを意味しま す。データ誤差評価が大きすぎるのか、統計的な仮定が正しくないのか、また はモデル関数が一般的すぎて、内在的傾向に加えて特殊なサンプルによる変動 の当てはめになっているのでしょう。最後の場合は、よりシンプルな関数にす ればうまく行くでしょう。

当てはめの p-値は、自由度と結果のχ自乗値に対するχ自乗分布の累積分布 関数値を 1 から引いた値です。これは、当てはめの良さのものさしを提供し ます。p-値の範囲は 0 から 1 までで、p-値がとても小さい、あるいはとても 大きい場合は、モデルがデータとその誤差をちゃんと記述していないことを意 味します。上で述べたように、これはデータに問題があるか、誤差かモデルに 問題がある、またはそれらの組み合わせなのだろうと思います。p-値が小さい ことは、誤差が過小評価されているので、よって最終的なパラメータ誤差をス ケール変換すべきだろうということを意味するでしょう。以下も参照: ‘set fit errorscaling‘。

標準的なエラーを、パラメータの不確定性に関する、あるより現実的な評価に 関係付けること、および相関行列の重要性を評価することができるようになる 前に、あなたは ‘fit‘ と、それを適用しようとするある種の問題に慣れてお く必要があるでしょう。

‘fit‘ は、大抵の非線形最小自乗法の実装では共通して、距離の自乗 (y-f(x))**2 の重み付きの和を最小化しようとすることに注意してください。 それは、x の値の "誤差" を計算に関してはどんな方法も与えてはおらず、単 に y に関する評価のみです。また、"孤立点" (正規分布のモデルのから外れ ているデータ点) は常に解を悪化させる可能性があります。

3.9.4 制御 (control)

コマンド ‘fit‘ の設定は、‘set fit‘ で制御します。以前の ‘gnuplot‘ のユ ーザ変数は、バージョン 5 で非推奨となっています。以下参照: variables。

‘gnuplot‘ の起動前に ‘fit‘ に影響を与えるように定義できる多くの環境変 数があります。以下参照: ‘fit control environment‘。

3.9.4.1 制御変数 (control variables)

ここで説明するユーザ定義変数は、非推奨です。以下参照: ‘set fit‘。

デフォルトのもっとも小さい数字の限界 (1e-5) は、変数

      FIT_LIMIT

で変更できます。残差の平方自乗和が 2 つの反復ステップ間で、この数値よ り小さい数しか変化しなかった場合、当てはめルーチンは、これを ’収束した’ と見なします。

反復数の最大値は変数

      FIT_MAXITER

で制限されます。0 (または定義しない場合) は制限無しを意味します。

更にそのアルゴリズムを制御したい場合で、かつ Marquardt-Levenberg アル ゴリズムを良く知っている場合は、さらにそれに影響を与える変数があります。 ‘lambda‘ (λ) の最初の値は、通常 ML 行列から自動的に計算されますが、も しそれをあらかじめ用意した値にセットしたければ

      FIT_START_LAMBDA

にセットしてください。FIT_START_LAMBDA を 0 以下にセットすると、自動的 に計算されるようになります。変数

      FIT_LAMBDA_FACTOR

は、χ自乗化された関数が増加、あるいは減少するにつれて ‘lambda‘ が増加 あるいは減少する因数を与えます。FIT_LAMBDA_FACTOR を 0 とすると、それは デフォルトの因数 10.0 が使用されます。

‘fit‘ には FIT_ から始まる変数が他にもありますから、ユーザ定義変数とし てはそのような名前で始まる変数は使わないようにするのが安全でしょう。

変数 FIT_SKIP と FIT_INDEX は、以前の版の ‘gnuplot‘ の、‘gnufit‘ と呼 ばれていた ‘fit‘ パッチで使われていたもので、現在は使用されていません。 FIT_SKIP の機能はデータファイルに対する every 指定子で用意されていま す。FIT_INDEX は複数当てはめ法 (multi-branch fitting) で使われていたも のですが、1 変数の複数当てはめ法は、今では 疑似 3 次元当てはめとして行 なわれていて、そこでは枝の指定には 2 変数と using が使われています。 以下参照: ‘fit multi-branch‘。

3.9.4.2 環境変数 (control environment)

環境変数は ‘gnuplot‘ が立ち上がる前に定義しなければなりません。その設 定方法はオペレーティングシステムに依存します。

      FIT_LOG

は、当てはめのログが書かれるファイル名 (およびパス) を変更します。デフ ォルトでは、作業ディレクトリ上の "fit.log" となっています。そのデフォ ルトの値はコマンド ‘set fit logfile‘ を使って上書きできます。

      FIT_SCRIPT

は、ユーザが中断した後に実行するコマンドを指定します。デフォルトでは replot ですが、‘plot‘ や load コマンドとすれば、当てはめの進行状 況の表示をカスタマイズするのに便利でしょう。その設定は、 ‘set fit script‘ を使って変更できます。

3.9.5 複数の当てはめ (multi-branch)

複数当てはめ法 (multi-branch fitting) では、複数のデータ集合を、共通の パラメータを持つ複数の 1 変数の関数に、WSSR の総和を最小化することによ って同時に当てはめることが出来ます。各データ集合に対する関数とパラメー タ (枝) は ’疑似変数’ を使うことで選択できます。例えば、データ行番号 (-1; ’データ列’ の番号) またはデータファイル番号 (-2) を 2 つ目の独立 変数とします。

例: 2 つの指数減衰形 z=f(x) が与えられていて、それぞれ異なるデータ集合 を記述しているが、共通した減衰時間を持ち、そのパラメータの値を評価する。 データファイルが x:z:s の形式であったとすると、この場合以下のようにす ればよい。

     f(x,y) = (y==0) ? a*exp(-x/tau) : b*exp(-x/tau)
     fit f(x,y) 'datafile' using  1:-2:2:3  via a, b, tau

より複雑な例については、デモファイル "fit.dem" で使われる "hexa.fnc" を参照してください。

もし従属変数のスケールに差がある場合、単位の重み付けでは 1 つの枝が支 配してしまう可能性があるので、適当な重み付けが必要になります。各枝をバ ラバラに当てはめるのに複数当てはめ法の解を初期値として用いるのは、全体 を合わせた解の各枝に対する相対的な影響に関する表示を与えることになるで しょう。

3.9.6 初期値 (starting values)

非線形当てはめは、大域的な最適値 (残差の自乗和 (SSR) の最小値を持つ解) への収束は保証はしませんが、局所的な極小値を与えることはできます。その サブルーチンはそれを決定する方法を何も持ち合わせていないので、これが起 こったかどうかを判断するのはあなたの責任となります。

‘fit‘ は、解から遠くから始めると失敗するかも知れませんし、しばしばそれ は起こり得ます。遠くというのは、SSR が大きく、パラメータの変化に対して その変化が小さい、あるいは数値的に不安定な領域 (例えば数値が大きすぎて 浮動小数の桁あふれを起こす) に到達してしまって、その結果 "未定義値 (undefined value)" のメッセージか ‘gnuplot‘ の停止を引き起こしてしまう ような場合を意味します。

大域的な最適値を見つける可能性を改善するには、最初の値をその解に少なく ともほぼ近くに取るべきでしょう。例えば、もし可能ならば一桁分の大きさの 範囲内で。最初の値が解に近いほど不正な解で終了してしまう可能性は低くな ります。最初の値を見つける一つの方法は、データと当てはめ関数を同じグラ フの上に描画して適当な近さに達するまで、パラメータの値を変更して replot することを繰り返すことです。その描画は、不正な極小値を見つけ たことで当てはめが終了したかどうかをチェックするのにも有用です。

もちろん、見た目が良い当てはめが見つかっても、それは "それよりよい" 当 てはめ (ある改良された当てはめの良さの基準によって特徴付けられた統計学 的な意味で、あるいはそのモデルのより適切な解である、という物理的な意味 で) が存在しないことの証明にはなりません。問題によっては、各パラメータ の意味のある範囲をカバーするような様々な初期値の集合に対して ‘fit‘ す ることが望ましいかも知れません。

3.9.7 ヒント (tips)

ここでは、‘fit‘ を最大限に利用するためにいくつか覚えておくべきヒントを 紹介します。それらは組織的ではないので、その本質がしみ込むまで何回もよ く読んでください。

‘fit‘ の引数の ‘via‘ には、2 つの大きく異なる目的のための 2 つの形式が あります。‘via "file"‘ の形式は、バッチ処理 (非対話型での実行が可能) で最も良く使われ、そのファイルの中で初期値を与えることができます。

‘via var1, var2, ...‘ の形式は対話型の実行で良く使われ、コマンドヒスト リの機構が使ってパラメータリストの編集を行い、当てはめを実行したり、あ るいは新しい初期値を与えて次の実行を行なったりします。これは難しい問題 に対しては特に有用で、全てのパラメータに対して 1 度だけ当てはめを直接 実行しても、良い初期値でなければうまくいかないことが起こり得るからです。 それを見つけるには、いくつかのパラメータのみに対して何回か反復を行ない、 最終的には全てのパラメータに対する 1 度の当てはめがうまくいくところに 十分近くなるまでそれを繰り返すことです。

当てはめを行なう関数のパラメータ間に共通の依存関係がないことは確認して おいてください。例えば、a*exp(x+b) を当てはめに使ってはいけません。そ れは a*exp(x+b)=a*exp(b)*exp(x) だからです。よってこの場合は a*exp(x) または exp(x+b) を使ってください。

技術的なお話: 絶対値が最も大きいパラメータと最も小さいパラメータの比が 大きい程当てはめの収束は遅くなります。その比が、マシンの浮動小数の精度 の逆数に近いか、またはそれ以上ならば、ほぼずっと収束しないか収束する前 に実行が中断するでしょう。よってそのような場合は、その関数の定義で例え ば ’parameter’ を ’1e9*parameter’ にするとか、最初の値を 1e9 で割ると かしてこれを避けるように改良するか、または ‘set fit prescale‘ でパラメ ータの初期値に従ってそのスケール変換を内部でやらせる機能を用いるか、の いずれかが必要でしょう。

もし、関数を、当てはめるパラメータを係数とする、単純な関数の線形結合で 書けるなら、それはとてもいいので是非そうしてください。何故なら、問題が もはや非線形ではないので、反復は少ない回数で収束するでしょう。もしかし たらたった一回ですむかもしれません。

実際の実験の講義ではデータ解析に対するいくつかの指示が与えられ、それで データへの最初の関数の当てはめが行なわれます。もしかすると、基礎理論の 複数の側面にひとつずつ対応する複数回のプロセスが必要かも知れませんが、 そしてそれらの関数の当てはめのパラメータから本当に欲しかった情報を取り 出すでしょう。しかし、‘fit‘ を使えば、求めるパラメータの視点から直接モ デル関数を書くことにより、それはしばしば 1 回で済むのです。時々はより 難しい当てはめ問題の計算コストがかかりますが、データ変換もかなりの割合 で避けることが出来ます。もしこれが、当てはめ関数の単純化に関して、前の 段落と矛盾してると思うなら、それは正解です。

"singular matrix" のメッセージは、この Marquardt-Levenberg アルゴリズ ムのルーチンが、次の反復に対するパラメータの値の計算が出来ないことを意 味します。この場合、別な初期値から始めるか、関数を別な形で書き直すか、 より簡単な関数にしてみてください。

最後に、他の当てはめパッケージ (fudgit) のマニュアルから、これらの文書 を要約するようないい引用を上げます: "Nonlinear fitting is an art! (非 線形当てはめ法は芸術だ !)"

3.10 help

helpコマンドは、組み込みヘルプを表示します。ある項についての説明を指 定したいときには、次の書式を使って下さい:

        help {<項目名>}

もし <項目名> が指定されなかった場合は、‘gnuplot‘ についての簡単な説明 が表示されます。指定した項目についての説明が表示された後、それに対する 細目のメニューが表示され、その細目名を入力することで細目に対するヘルプ を続けることができます。そして、その細目の説明が表示された後に、さらな る細目名の入力を要求されるか、または 1 つ前の項目のレベルへ戻ります。 これを繰り返すとやがて、‘gnuplot‘ のコマンドラインへと戻ります。

また、疑問符 (?) を項目として指定すると、現在のレベルの項目のリストが 表示されます。

3.11 history

コマンド ‘history‘ は、コマンド履歴の一覧を表示したり、保存したり、一 覧の中のコマンドを再実行したりします。このコマンドの挙動を変えるには、 以下参照: ‘set history‘。

‘history‘ コマンドで始まる入力行は、コマンド履歴には保存しません。

例:

      history               # 履歴全体を表示
      history 5             # 履歴内の直前の 5 つを表示
      history quiet 5       # エントリ番号なしで直前の 5 つを表示
      history "hist.gp"     # 履歴全体をファイル hist.gp に書き出す
      history "hist.gp" append # 履歴全体をファイル hist.gp に追加する
      history 10 "hist.gp"  # 直前の 10 個をファイル hist.gp に出力
      history 10 "|head -5 >>diary.gp" # パイプで履歴を 5 つ書き出す
      history ?load         # 履歴内の "load" で始まるものすべてを表示
      history ?"set c"      # 上と同様 (複数の語は引用符で囲む)
      hi !reread            # "reread" で始まる最も新しい行を実行
      hist !"set xr"        # 上と同様 (複数の語は引用符で囲む)
      hist !55              # 55 番目の履歴項目のコマンドを再実行

3.12 if

新しい書式:

      if (<condition>) { <commands>;
             <commands>
             <commands>
      } else {
             <commands>
      }

以前の書式:

      if (<条件>) <コマンド行> [; else if (<条件>) ...; else ...]

このバージョンの gnuplot は、if/else のブロック形式をサポートしていま す。キーワード ‘if‘, ‘else‘ の後ろに開始カッコ "{" が続く場合、"}" で 終了するブロックまでのすべての文 (複数の入力行も可) に条件的な実行が適 用されます。if コマンドは入れ子にすることもできます。

古い形式の 1 行の if/else 文もまだサポートされていますが、新しいブロッ ク形式の書式とは混ぜてはいけません。以下参照: if-old。

3.12.1 if-old

gnuplot バージョン 4.4 までは、if/else コマンドの通用範囲は 1 行内に留 まっていましたが、現在は複数行を中カッコ { } で囲んで書くことができま す。古い形式も一応残されていますが、それは中カッコのブロック内で使うこ とはできません。

キーワード ‘if‘ が "{" をともなわない場合は、<条件> が真 (ゼロでない) ならば <コマンド行> のコマンド (複数も可) が実行され、偽 (ゼロ) ならば スキップされます。いずれの場合も入力行の最後になるか、‘else‘ が現れる ところまでそれが行われます。‘;‘ を使うと同じ行に複数のコマンド置くこと が可能ですが、条件付きのコマンド (‘if‘ の構文自体) はそこでは終らない ことに注意してください。

例:

      pi=3
      if (pi!=acos(-1)) print "?Fixing pi!"; pi=acos(-1); print pi

を実行すると、

      ?Fixing pi!
      3.14159265358979

と表示されますが、

      if (1==2) print "Never see this"; print "Or this either"

とすると、何も表示されません。

その他:

      v=0
      v=v+1; if (v%2) print "2" ; else if (v%3) print "3" ; else print "fred"

(何度も最後の行を繰り返してみてください !)

3.13 for

‘plot‘, ‘splot‘, ‘set‘, unset コマンドでは、繰り返しの for 節を使う こともできます。これは、基本的なコマンドを複数回実行する効果を持ち、そ のおのおのの実行では繰り返し制御変数によって数式は再評価されます。‘do‘ コマンドでは、どんなコマンド列でも繰り返し実行させることができます。繰 り返し節は現在は以下の 2 つの形式をサポートしています:

      for [intvar = start:end{:increment}]
      for [stringvar in "A B C D"]

例:

      plot for [filename in "A.dat B.dat C.dat"] filename using 1:2 with lines
      plot for [basename in "A B C"] basename.".dat" using 1:2 with lines
      set for [i = 1:10] style line i lc rgb "blue"
      unset for [tag = 100:200] label tag

繰り返しの入れ子もサポートしています:

      set for [i=1:9] for [j=1:9] label i*10+j sprintf("%d",i*10+j) at i,j

さらなる説明については、以下参照: ‘iteration‘, ‘do‘。

3.14 import

コマンド import は、ユーザ定期関数名を外部共有オブジェクトから取り込 まれる関数に結びつけます。これは、gnuplot で利用可能な関数の設定を拡張 するプラグイン機構を構成します。

書式:

      import func(x[,y,z,...]) from "sharedobj[:symbol]"

例:

      # 関数 myfun を "mylib.so" か "mylib.dll" から取り込んで作成する
      # gnuplot では描画、または数値計算で利用可能
      import myfun(x) from "mylib"
      import myfun(x) from "mylib:myfun"    # 上と同様

      # "theirlib.so" か "theirlib.dll" で定義済の関数 theirfun を作成
      # 異なる名前で利用可能
      import myfun(x,y,z) from "theirlib:theirfun"

プログラムは共有オブジェクトとして与えられた名前に、オペレーティングシ ステムに従って ".so" か ".dll" を追加し、まずそれをフルパス名として検 索し、次にカレントディレクトリからの相対パス名として検索します。オペレ ーティングシステム自体も LD_LIBRARY_PATH か DYLD_LIBRARY_PATH の任意の ディレクトリを検索します。

3.15 load

load コマンドは、指定された入力ファイルの各行を、それが対話的に入力 されたかのように実行します。save コマンドでつくられたファイルは、 load することができます。有効なコマンドの書かれたテキストファイルを つくれば、それは、loadコマンドによって、実行することができます。 load 中のファイルの中にさらに load または call コマンドがあって も構いません。コマンド中のコメントについては、以下参照: ‘comments‘。 load するときに引数を与える方法については、以下参照: call。

書式:

        load "<入力ファイル名>"

入力ファイル名は引用符で囲まなければなりません。

load コマンドは、標準入力からのコマンドの入力のために、特別なファイ ル名 "-" を用意しています。これは、‘gnuplot‘ のコマンドファイルが、い くつかのコマンドを標準入力から受け付けることを意味します。詳細について は、以下参照: ‘batch/interactive‘。

Unix のように popen 関数をサポートするようなシステムでは、’<’ で始まる ファイル名にすることで、入力ファイルをパイプから読み込むことができます。

例:

        load 'work.gnu'
        load "func.dat"
        load "< loadfile_generator.sh"

‘gnuplot‘ への引数として与えられたファイル名は、暗黙のうちに load コ マンドによって実行されます。これらは、指定された順にロードされ、その後 ‘gnuplot‘ は終了します。

3.16 lower

以下参照: raise。

3.17 pause

pause コマンドは、コマンドに続く任意の文字列を表示した後、指定され た時間または、改行キーが押されるまで待ちます。pause コマンドは、 load 用のファイルと共に使用すると、便利になるでしょう。

書式:

      pause <time> {"<string>"}
      pause mouse {<endcondition>}{, <endcondition>} {"<string>"}

<time> は、任意の定数または実数値の式です。‘pause -1‘ は改行キーが押さ されるまで待ち、0 を指定すると一切待たず、正の数を指定するとその秒数だ け待ちます。‘pause 0‘ は ‘print‘ と同じです。

使用している出力形式が ‘mousing‘ (マウス機能) をサポートしている場合、 ‘pause mouse‘ は、マウスクリックがあるか ctrl-C が押されるまで待つよう になります。そうでない出力形式、またはマウス機能が有効になってない場合 ‘pause mouse‘ は ‘pause -1‘ と同じです。

一つ、あるいは複数の終了条件 (endcondition) が ‘pause mouse‘ の後に与 えられた場合、そのうちのどの一つでも pause は終了します。指定できる終 了条件は、‘keypress‘, ‘button1‘, ‘button2‘, ‘button3‘, ‘close‘, ‘any‘ のいずれかです。pause がキー入力によって終了した場合、押されたキーの ASCII コードは MOUSE_KEY に保存され、文字それ自身は、1 文字の文字列値 として MOUSE_CHAR に返されます。‘keypress‘ が終了条件の一つであれば、 ホットキー (キー割り当てコマンド) は無効になります。‘buttons3‘ が終了 条件の一つであれば、拡大機能は無効になります。

どの場合でもマウスの座標は変数 MOUSE_X, MOUSE_Y, MOUSE_X2, MOUSE_Y2 に 保存されます。以下参照: variables。

注意: pause コマンドは OS へのコマンドであり描画の一部ではないので、 異なる出力装置では異なる動作をする可能性があります。(これは、テキスト とグラフィックスが、どのように混在するかによります。)

例:

      pause -1    # 改行キーが押されるまで待つ
      pause 3     # 3 秒待つ
      pause -1  "続けるには return を打ってください"
      pause 10  "これは美しくないですか ? 3 次の spline です"
      pause mouse "選択したデータ点上で任意のボタンをクリックしてください"
      pause mouse keypress "有効なウィンドウ内で A-F の文字を入力してください"
      pause mouse button1,keypress
      pause mouse any "任意のキー、ボタンで終了します"

亜種である "pause mouse key" は、有効な描画ウィンドウ内での任意のキー 入力によって再開されます。特別なキー入力まで待つようにしたい場合は、以 下のような reread によるループを使うことができます:

      print "描画ウィンドウ内で Tab キーを打つと復帰します。"
      load "wait_for_tab"

ファイル "wait_for_tab" は以下のようなものです:

      pause mouse key
      if (MOUSE_KEY != 9) reread

3.18 plot

‘plot‘ は ‘gnuplot‘ で図を描くための基本的なコマンドです。 それは関数 やデータの、多くの種類のグラフ表現を提供します。‘plot‘ は 2 次元の関数 やデータを描くのに使われ、‘splot‘ は 3 次元の曲面やデータの 2 次元投影 を描きます。

書式:

      plot {<ranges>} <plot-element> {, <plot-element>, <plot-element>}

各描画要素 (plot-element) は、定義 (definition) か関数 (function) かデ ータ (data source) のいずれか 1 つに、オプションの属性、修正子などがつ いたものです:

      描画要素 (plot-element):
           {<iteration>}
           <definition> | {sampling-range} <function> | <data source>
           {axes <axes>} {<title-spec>}
           {with <style>}

各描画要素のグラフ表現形式は、例えば ‘with lines‘ や ‘with boxplot‘ な どのようにキーワード with で決定します。以下参照: ‘plotting styles‘。

描画するデータは、1 つの関数から生成されるもの (媒介変数モード (parametric) では 2 つの関数から)、または一つのデータファイルから読み 込まれるもの、または事前に定義された名前付きデータブロックから読み込ま れるもの、のいずれかです。コンマで区切ることで、複数のデータファイル、 データブロック、関数などを 1 つの plot コマンドで描画できます。以下参 照: ‘data‘, ‘inline data‘, functions。

関数、変数の定義の描画要素は、画像出力を生成しません。下の 3 つ目の例 を参照してください。

例:

      plot sin(x)
      plot sin(x), cos(x)
      plot f(x) = sin(x*a), a = .2, f(x), a = .4, f(x)
      plot "datafile.1" with lines, "datafile.2" with points
      plot [t=1:10] [-pi:pi*2] tan(t), \
           "data.1" using (tan($2)):($3/$4) smooth csplines \
                    axes x1y2 notitle with lines 5
      plot for [datafile in "spinach.dat broccoli.dat"] datafile

以下参照: ‘show plot‘。

3.18.1 軸 (axes)

軸 (axes) は、4 種類の組が利用できます; キーワード <axes> は、特定の直 線をどの軸に尺度を合わせるか、ということを選択するのに使われます。 ‘x1y1‘ は下の軸と左の軸を指定; ‘x2y2‘ は上と右の軸の指定; ‘x1y2‘ は下 と右の軸の指定; ‘x2y1‘ は上と左の軸の指定です。‘plot‘ コマンドで指定さ れた範囲は、この最初の軸の組 (下と左) にのみ適用されます。

3.18.2 binary

バイナリデータファイル:

ファイル名の後ろに binary のキーワードを与えなければいけません。ファ イル形式に関する十分詳細な情報は、ユーザがコマンドラインから与えるか、 またはサポートしている filetype のバイナリ形式のファイルそれ自身から 抜き出されるかする必要があります。バイナリファイルには、大きく 2 つの 形式、binary matrix 形式と binary general 形式があります。

matrix 形式は、32 ビット IEEE 規格の浮動小数値 (float) が 2 次元配列の形で並び、それらの座標値を表す行と列が追加されています。plot コマンドの using 指定において、1 番目 (column(1)) は行列の行の座標を 参照し、2 番目 (column(2)) は列の座標を参照し、3 番目 (column(3)) は、 配列のそれらの座標の場所に保存されている値を参照します。

general 形式は、任意個の列のデータを含み、それらの情報はコマ ンドラインで指定する必要があります。例えば array, record, format, using などでサイズや形式、データの次元を指定できます。他にも、ファイ ルヘッダ読み飛ばしたり、エンディアン (endian) を変更するための有用なコ マンドがありますし、配置、データの変換を行なうコマンドの組があります。 それは、一様に標本化されたデータの場合、その座標がファイルには含まれな いことが良くあるからです。matrix バイナリファイルやテキストデータから の入力と違うところですが、general バイナリは 1,2,3 といった using リ ストで生成される列番号を使わず、代わりに 1 列目はファイルの 1 列目、あ るいは format リストで指定されたもの、になります。

さまざまな binary オプションに対する大域的なデフォルトの設定も可能で、 それは ‘(s)plot <filename> binary ...‘ コマンドに与えるオプションと全 く同じ書式で指定できます。その書式は ‘set datafile binary ...‘ です。 一般的な規則として、デフォルトのパラメータはファイルから抜き出されたパ ラメータで上書きされ、それはコマンドラインで指定された共通なパラメータ で上書きされます。

例えば array, record, format, filetype の general 形 式を特定するようなキーワードが何もついていなければ、デフォルトのバイナ リ形式は matrix です。

general バイナリデータは、特別なファイル名 ’-’ を使ってコマンドライン から入力することもできます。しかし、これはキーボードからの入力を意図し たものではなく、パイプを使ってプログラムにバイナリ形式を変換させるため のものです。バイナリデータには最後を表す記号がありませんので、gnuplot はパイプからデータを読み込む場合、array 指定子で指定した数の点数にな るまでデータを読み込み続けます。詳細に関しては、以下参照: matrix, general。

index キーワードは、ファイルフォーマットが 1 つのファイルにつき 1 つ の曲面しか許さないため、サポートされません。every や using フィルタ はサポートされます。using は、データがあたかも上の 3 つ組の形で読まれ たかのように働きます。 バイナリファイルの splot のデモ。

3.18.2.1 general

キーワード binary を単独で指定した場合は、非一様な格子を形成する座標 情報と、各格子点での値の両方を持つバイナリデータであることを意味し (以 下参照: matrix)、他の形式のバイナリデータの場合は、そのデータ の形式を意味する追加キーワードを指定する必要があります。残念ながら、こ れらの追加キーワードの書式は単純ではありませんが、それでも general バ イナリモードは、特に多量のデータを gnuplot に送るようなアプリケーショ ンに取っては有用です。

書式:

      plot '<file_name>' {binary <binary list>} ...
      splot '<file_name>' {binary <binary list>} ...

general バイナリ形式は、ファイル構造に関する情報に関連するキーワード、 すなわち array, record, format, filetype などを <binary list> 内に与えることで有効になります。それ以外の場合は、非一様な matrix バイ ナリ形式と見なします。(詳細に関しては、以下参照: matrix。)

注意: 以前の版の gnuplot では、バイナリデータ用のキーワードの解釈に、 ‘plot‘ と ‘splot‘ では少し違いがありました。その意味の違う箇所は、今後 の版の gnuplot では、その一方あるいは両方が変更される可能性があります。

gnuplot は、例えば PNG 画像のように完全に自己記述される標準的なバイナ リファイル形式の読み込み方法をいくつか知っています。その一覧は、対話画 面で binary と入力することで参照できます。それら以外の ものについては、概念上はバイナリデータはテキストデータと同様に考えるこ とができます。各点には、using 指定で選択される情報の列があります。 format 文字列を指定しなかった場合、gnuplot はバイナリ数値の数を ‘<using list>‘ で与えられる最大の列番号に等しく取ります。例えば、 ‘using 1:3‘ とすると 3 列ずつデータが読み取られ、2 番目のものは無視し ます。各描画スタイルにはデフォルトの using 指定があります。例えば ‘with image‘ はデフォルトで ‘using 1‘ を、rgbimage はデフォルト で ‘using 1:2:3‘ を使います。

3.18.2.2 array

バイナリファイルの標本の配列の大きさを設定します。座標は gnuplot が生 成してくれます。各方向の次元を表す数を指定しなければいけません。例えば ‘array=(10,20)‘ は、2 次元で最初の次元方向 (x) には 10 点、2 番目の次 元方向 (y) には 20 点の標本化データがあることを意味します。ファイルの 終了までデータが続くことを示すのに負の値を使えます。データ次元が 1 の 場合は、カッコは省略できます。複数のデータのサイズ指定を分離するのに、 コロンを使うことができます。例えば ‘array=25:35‘ は 2 つの 1 次元デー タがファイルの中にあることを意味します。

      注意:  gnuplot バージョン 4.2 では array=(128,128) という書式で
             はなく、array=128x128 という書式を使用していました。古い
             書式は推奨されていません。

3.18.2.3 record

このキーワードは array と同じ書式で、同じ機能を提供します。しかし record は gnuplot に座標情報を自動生成させません。これは、そのような 座標情報が、バイナリデータファイルのある列に含まれている場合のためのも のです。

3.18.2.4 skip

このキーワードは、バイナリファイルのある区画のスキップを可能にします。 例えば、そのファイルがデータ領域の開始位置の前に 1024 バイトのヘッダを 持つような場合には、以下のようにしたいと思うでしょう:

      plot '<file_name>' binary skip=1024 ...

ファイルに複数のレコードがある場合、そのそれぞれに対する先頭のずらし位 置を指定することができます。例えば、最初のレコードの前の 512 バイトを スキップし、2 番目、3 番目のレコードの前の 256 バイトをスキップするに は以下のようにします:

      plot '<file_name> binary record=356:356:356 skip=512:256:256 ...

3.18.2.5 format

デフォルトのバイナリ形式は、単精度浮動小数 (float) が一つ、です。それ をより柔軟に設定するために、この format で変数のサイズに関する詳細な情 報を指定できます。例えば ‘format="%uchar%int%float"‘ は、最初の using 列として符号なし文字型変数 (unsigned char) を、2 番目の列は符号つき整 数 (int) を、3 番目の列は単精度浮動小数 (float) を指定しています。もし サイズ指定子の数が最大列数より小さい場合は、残りの列の変数サイズは暗黙 のうちに最後に与えた変数サイズに等しく取られます。

さらに using 指定同様、‘*‘ 文字がついた読み捨てる列を書式に指定する こともできますし、繰り返しフィールドへの回数指定によって暗黙の繰り返し を指定することもできます。例えば、‘format="%*2int%3float"‘ は、3 つの 実数データを読む前に、2 つの整数データを読み捨てます。使用できる変数サ イズの一覧は、‘show datafile binary datasizes‘ で見ることができます。 それらは、それぞれのコンパイルによってそのバイトサイズとともにマシンに 依存する変数名のグループと、マシンに依存しない変数名のグループに分かれ ています。

3.18.2.6 endian

ファイルのバイナリデータのエンディアンは、gnuplot が動作するプラットホ ームのエンディアンとは異なる場合も良くあります。いくつかの指定で gnuplot がバイトをどのように扱うかを制御できます。例えば ‘endian=little‘ は、バイナリファイルを、そのバイトの並びが小さい桁から 大きい桁へ並んでいると見なされます。オプションは以下のものが使えます。

              little:  小さい桁から大きな桁へ並ぶ
                 big:  大きな桁から小さな桁へ並ぶ
             default:  compiler と同じエンディアンと見なす
         swap (swab):  エンディアンを変更する (おかしいようならこれを
                       使ってみてください)

gnuplot は、コンパイル時にオプションが指定されていれば、"middle" (や "pdp") エンディアンもサポートできます。

3.18.2.7 filetype

gnuplot は、いくつか標準的なバイナリファイル形式については必要な情報を そのファイルから抜き出すことができます。例えば "format=edf" は ESRF ヘ ッダーファイル形式のファイルとして読み込みます。現在サポートしているフ ァイル形式については、‘show datafile binary filetypes‘ で見てください。

特別なファイル形式として ‘auto‘ があり、この場合 gnuplot はバイナリフ ァイルの拡張子が、サポートされている形式の標準的な拡張子であるかをチェ ックします。

コマンドラインキーワードはファイルから読み取る設定を上書きするのに使わ れ、ファイルから読み取る設定はデフォルトの設定を上書きします。以下参照: binary。

— AVS —

‘avs‘ は、自動的に認識される画像イメージに対するバイナリファイルの型の 一つです。AVS は非常単純なフォーマットで、アプリケーション間でやりとり するのに最も適しています。これは、2 つの long (xwidth と ywidth) と、 その後続くピクセルの列から成り、その各ピクセルは alpha/red/green/blue の 4 バイトから成ります。

— EDF —

‘edf‘ は、自動的に認識される画像イメージに対するバイナリファイルの型の 一つです。EDF は ESRF データフォーマット (ESRF Data Format) を意味して いて、それは edf と ehf の両方の形式をサポートしています (後者は ESRF Header Format)。画像の使用に関する詳しい情報は以下で見つかるでしょう:

  http://www.edfplus.info/specs

— PNG —

gnuplot が png/gif/jpeg 出力用に libgd ライブラリを使うようにインスト ールされている場合、それらの画像形式をバイナリファイルとして読み込むこ ともできます。以下のような明示的なコマンド

      plot 'file.png' binary filetype=png

を使うこともできますし、あらかじめ以下のように設定して、拡張子から自動 的に画像形式を自動的に認識させることもできます。

      set datafile binary filetype=auto

3.18.2.8 keywords

以下のキーワード (keyword) は、バイナリファイルから座標を生成するとき にのみ適用されます。つまり、binary array, matrix, image の個々の要素を 特定の x,y,z の位置への配置の制御のためのものです。

— SCAN —

gnuplot がバイナリファイルをどのように走査するか、ということと実際の描 画で見られる軸の方向との間の関係については多くの混乱が起こり得ます。そ の混乱を減らすには、gnuplot はバイナリファイルを "常に" 点/線/面、また は速い/普通/遅い、と走査すると考えるといいでしょう。このキーワードは gnuplot に、その走査の方向を描画内のどの座標方向 (x/y/z) に割り当てる かを指定します。指定は 2 つ、または 3 つの文字の並びで表現し、最初の文 字が点に、次の文字が線に、3 つ目の文字が面に対応します。例えば、 ‘scan=yx‘ は、最も速い走査 (点の選択) は y 方向に対応し、普通の速さの 走査 (線の選択) が x 方向に対応することを意味します。

描画モードが ‘plot‘ の場合、指定には x と y の 2 つの文字を使うことが でき、‘splot‘ に対しては x, y, z の 3 つの文字を使うことができます。

割り当てに関しては、点/線/面から直交座標方向へのみに制限する内部事情は 別にありません。この理由で、円柱座標への割り当てのための指定子も用意さ れていて、それらは直交座標の x, y, z に類似した形で t (角度), r, z と なっています。

— TRANSPOSE —

‘scan=yx‘、または ‘scan=yxz‘ と同じです。すなわち、これは入力時の走査 行のピクセルへの割り当てに影響を与えます。表示する際に画像を転置するに は、以下のようにしてみてください:

     plot 'imagefile' binary filetype=auto flipx rotate=90deg with rgbimage

— DX, DY, DZ —

gnuplot が座標を生成する場合、その間隔はこれらのキーワードで指定された ものが使用されます。例えば ‘dx=10 dy=20‘ は x 方向に 10、y 方向に 20 の間隔で標本化されたことを意味します。‘dy‘ は ‘dx‘ がなければ使えませ ん。同様に ‘dz‘ は ‘dy‘ がなければ使えません。もしデータの次元が指定し たキーワードの次元よりも大きい場合、残りの次元方向の間隔は、指定された 最も高い次元のものと同じ値が使用されます。例えば画像がファイルから読み 込まれ、‘dx=3.5‘ のみ指定された場合、gnuplot は x 方向の間隔も y 方向 の間隔も 3.5 を使用します。

以下のキーワードも座標の生成時にのみ適用されます。しかし、以下のものは matrix バイナリファイルにも使われます。

— FLIPX, FLIPY, FLIPZ —

バイナリデータファイルの走査方向が gnuplot の走査方向と一致しないこと がたまにあります。これらのキーワードは、それぞれ x, y, z 方向のデータ の走査方向を逆向きにします。

— ORIGIN —

gnuplot は転置 (transpose) や反転 (flip) において座標を生成する場合、 常に配列の左下の点が原点になるようにします。すなわち、データが、転置や 反転の行なわれた後の直交座標系の第 1 象限に来るようにします。

配列をグラフのその他の場所に配置したい場合、‘origin‘ キーワードで指定 した場所に gnuplot は配列の左下の点を合わせます。その指定は、‘plot‘ で は 2 つの座標の組、‘splot‘ では 3 つの座標の組を指定してください。例え ば ‘origin=(100,100):(100,200)‘ は、一つのファイルに含まれる 2 つのデ ータに対する指定で、2 次元の描画に対する指定です。2 つ目の例として ‘origin=(0,0,3.5)‘ をあげると、これは 3 次元描画用の指定です。

— CENTER —

‘origin‘ と似ていますが、このキーワードは、配列の中心がこのキーワード で指定した点になるように配置します。例えば ‘center=(0,0)‘ のようにしま す。配列のサイズが ‘Inf‘ のときは center は適用されません。

— ROTATE —

転置 (transpose) と反転 (flip) コマンドは座標の生成と座標軸の方向にあ る種の柔軟性を与えてくれます。しかし、角度に関する完全な制御は、2 次元 の回転角を記述した回転角ベクトルを与えることにより行なうことが可能にな ります。

キーワード ‘rotate‘ は, ‘plot‘, ‘splot‘ の両方で、2 次元面に対して適用 されます。回転は座標平面の正の角度に関して行なわれます。

角度は、ラジアン単位ですが、pi や degrees の倍数としてのラジアンでも表 現できます。例えば、‘rotate=1.5708‘, ‘rotate=0.5pi‘, ‘rotate=90deg‘ は すべて同じ意味です。

‘origin‘ が指定された場合、回転は平行移動の前に左下の点を中心にして行 なわれます。それ以外では回転は配列の中心 (‘center‘) に関して行なわれま す。

— PERPENDICULAR —

‘splot‘ に関して回転ベクトルの設定が、ベクトルを表現する 3 つの数字の 組を指定することで実装されていて、このベクトルは 2 次元の xy 平面に対 して向き付けられた法線ベクトル (perpendicular) を表しています。もちろ んそのデフォルトは (0,0,1) です。rotate と perpendicular の両方を指定 することにより、3 次元空間内で無数の方向へデータを向き付けられることに なります。

まず最初に 2 次元の回転が行なわれ、その次に 3 次元の回転が行なわれます。 つまり、R’ をある角による 2 x 2 の回転行列とし、P を (0,0,1) を (xp,yp,zp) へ子午線方向に回転させる 3 x 3 の行列とし、R’ を左上の部分 行列として持ち 3,3 成分が 1 でその他の成分が 0 であるような行列 (つま り z 軸周りの回転行列) とすれば、この変換を表す行列による関係式は v’ = P R v となります。ここで、v はデータファイルから読み込まれた 3 x 1 の位置ベクトルです。ファイルのデータが 3 次元的なものでない場合 は、論理的なルールが適用されて 3 次元空間内のデータと見なされます (例 えば、通常は z 座標は 0 とされ、xy 平面内の 2 次元データと見なされます)。

3.18.3 データ (data)

ファイルに納められた離散的なデータは、‘plot‘ コマンドライン上で、その データファイル名 (<datafile>) を単一引用符または二重引用符で囲んで指定 することによって表示できます。

書式:

      plot '<file_name>' {binary <binary list>}
                         {{nonuniform} matrix}
                         {index <index list> | index "<name>"}
                         {every <every list>}
                         {skip <number-of-lines>}
                         {using <using list>}
                         {smooth <option>}
                         {bins <options>}
                         {volatile} {noautoscale}

修正子の binary, index, every, skip, using, bins, smooth は、それぞれに分けて説明します。簡単に言うと、binary はデータ列をバ イナリファイルから取得できるようにし、index はマルチデータ集合ファイ ルからどのデータ集合を表示するのかを選び、every が、一つのデータ集合 からどの点を表示するのかを選び、using は一行からどの列を解釈するのか を決定し、そして smooth が、単純な補間と近似を行います。bins は個 々の入力点を x に沿う等幅の区間に仕分け、各区間に一つだけの累積値を描 画します。

‘splot‘ もよく似た書式を使いますが、smooth オプションはサポートして いません。

キーワード ‘noautoscale‘ は、自動的に軸の範囲が決定される機能が有効で ある場合に、この描画を構成するデータ点については、それを無視させる (自 動縮尺機能の計算対象から外す) ようにします。

テキストデータファイル:

データファイルは、一行につき少なくとも一つのデータ点を含む必要がありま す (using は一行から一つのデータポイントを選ぶことができます)。‘#‘ (VMS では ‘!‘) で始まる行は、コメントとして扱われ、無視されます。各デ ータ点は、(x,y) の組を表します。エラーバー、または折れ線表示付エラーバ ーの ‘plot‘ では (以下参照: errorbars, errorlines)、各データ点は、 (x,y,ydelta), (x,y,ylow,yhigh), (x,y,xdelta), (x,y,xlow,xhigh), (x,y,xlow,xhigh,ylow,yhigh) のいずれかを意味します。

どんな場合でも、書式の指定子が using オプションによって与えられてい なければ、データファイルの各行の数字は、ホワイトスペース (一つまたは複 数の空白かタブ) によって区切られている必要があります。このホワイトスペ ースは、各行を列の項目に区切ります。ただし、二重引用符で囲まれたホワイ トスペースは列の勘定では無視され、よって次のようなデータ行は 3 列、と 見なされます:

      1.0 "second column" 3.0

データは、指数部に e, E の文字をつけた指数表記で書かれていても構いませ ん。コマンド ‘set datafile fortran‘ が有効な場合は、fortran の指数指定 子 d, D, q, Q も使えます。

必要であるのはただ一つの列 (y の値) のみです。もし x の値が省略された ら、‘gnuplot‘ はそれを 0 で始まる整数値として用意します。

データファイルにおいて、ブランク行 (空白と改行、復帰以外に文字を含まな い行) は重要です。

1 行のブランク行は、‘plot‘ に不連続を指示します; ブランク行によって区 切られた点は線で結ばれることはありません (line style で書かれている場 合には)。

2 行のブランク行は、別々のデータ集合間の区切りを示します。以下参照: index。

もし autoscale の状態であれば (以下参照: ‘set autoscale‘)、軸は全ての データポイントを含むように自動的に引き伸ばされて、目盛りが書かれる状態 ならば全ての目盛りがマークされます。これは、2 つの結果を引き起こします: i) ‘splot‘ では、曲面の角は底面の角に一致していないことがあります。こ の場合、縦の線は書かれることはありません。ii) 2 種類の軸での、同じ x の範囲のデータの表示の際、もし x2 の軸に対する目盛りが書かれていない場 合は、x 座標があっていないことがあります。これは x 軸 (x1) は全ての目 盛りにまで自動的に引き延ばされるのに対し、x2 軸はそうではないからです。 次の例でその問題を見ることができます:

      reset; plot '-', '-' axes x2y1
      1 1
      19 19
      e
      1 1
      19 19
      e

これを避けるには、‘set autoscale‘ コマンドの ‘fixmin‘/‘fixmax‘ オプシ ョンを使うことができます。これは、次の目盛りの刻みに合うように軸の範囲 を自動的に拡張する機能を無効にします。

ラベルの座標と文字列もデータファイルから読み込むことができます (以下参 照: labels)。

3.18.3.1 bins

試験段階の機能 (仕様の細かい部分は、今後の版で変更する可能性あり)。 書式:

     plot 'DATA' using <XCOL> {:<YCOL>} bins{=<NBINS>}
          {binrange [<LOW>:<HIGH>]} {binwidth=<width>}

‘plot‘ コマンドに対するオプション bins は、最初に元のデータを、x 軸 上で等しい幅を持ついくつかの箱 (ビン) に割り当て、そして箱毎に一つの値 のみを描画します。箱の数のデフォルト値は、‘set samples‘ で決定しますが これは plot コマンドでビンの数を明示的に指定することで変更できます。

binrange を指定しないと、範囲は ’DATA’ 内の値の両端を取ります。

箱の幅は、指定した範囲と箱の数から自動的に計算し、各点を 0 から NBINS-1 までの箱に割り当てます:

     BINWIDTH = (HIGH - LOW) / (NBINS-1)
     xmin = LOW - BINWIDTH/2
     xmax = HIGH + BINWIDTH/2
     first bin holds points with (xmin <= x < xmin + BINWIDTH)
     最初の箱は (xmin <= x < xmin + BINWIDTH) の範囲の点を保持
     最後の箱は (xmax-BINWIDTH <= x < xman) の範囲の点を保持
     各点は i = floor(NBINS * (x-xmin)/(xmax-xmin)) 番の箱に割り当て

それとは別に、固定幅の箱を指定することも可能です。その場合、箱の数 (nbins) は、点の範囲全体にわたる最小の箱の数となります。

箱の出力は、その中点で描画、または表にされます。例えば gnuplot が上の ように箱の幅を計算する場合、最初の箱の x 座標の出力は x=LOW であり、 x=xmin ではありません。

using 命令で一つの列のみを指定した場合、各データ点は、その x 座標値に 対する箱の合計値に 1 だけ寄与します。2 列目を指定すると、その箱の合計 値には 2 列目の値が追加されます。よって、以下の 2 つの plot コマンドは 同じになります:

     plot 'DATA" using N bins=20
     set samples 20
     plot 'DATA' using (column(N)):(1)

関連する描画スタイルに関しては、以下参照: ‘smooth frequency‘, ‘smooth kdensity‘。

3.18.3.2 every

キーワード every は、描画するデータをデータ集合から周期的にサンプリ ングすることを可能にします。

ここでは 「ポイント」はファイル中の 1 つの行によって定義されるデータと し、データの「ブロック」は、前後のブロックと空行で区切られる連続した行 の集合を意味することとします。

書式:

         plot 'file' every {<ポイント増分>}
                           {:{<ブロック増分>}
                             {:{<開始ポイント>}
                               {:{<開始ブロック>}
                                 {:{<終了ポイント>}
                                   {:<終了ブロック>}}}}}

描画するデータポイントは、<開始ポイント> から <終了ポイント> まで <ポ イント増分> の増加で選び、ブロックは <開始ブロック> から <終了ブロック> まで <ブロック増分> の増加で選びます。

各ブロックの最初のデータは、ファイル中の最初のブロックと同じように、 「0 番」と数えます。

プロットできない情報を含む行もカウントすることに注意して下さい。

いくつかの数字は省略できます; 増分のデフォルトは 1 、開始の値は最初の ポイントか最初のブロック、そして終了の値は最後のポイントか最後のブロッ クに設定します。every のオプションが ’:’ で終わるのは許されていませ ん。every を指定しなければ、全ての行の全てのポイントをプロットします。

例:

       every :::3::3   # 4 番目のブロックだけ選びます (0 番が最初)
       every :::::9    # 最初の 10 ブロックを選びます
       every 2:2       # 1 つおきのブロックで 1 つおきのポイントを選び
                       # ます
       every ::5::15   # それぞれのブロックでポイント 5 から 15 までを
                       # 選びます

参照: 単純な plot デモ (simple.dem) , 非媒介変数モードでの splot デモ , 媒介変数モードでの splot デモ 。

3.18.3.3 データファイルの例 (example)

次の例は、ファイル "population.dat" 中のデータと理論曲線を図にするもの です。

      pop(x) = 103*exp((1965-x)/10)
      set xrange [1960:1990]
      plot 'population.dat', pop(x)

ファイル "population.dat" は次のようなファイルです。

      # Gnu population in Antarctica since 1965
         1965   103
         1970   55
         1975   34
         1980   24
         1985   10

binary の例:

      # 2 つの float の値を選択し (2 つ目の値は無意味)、一方を読み捨て、
      # 一つおきの float 値を無限に長く続く 1 次元データとして使用
      plot '<file_name>' binary format="%float%*float" using 1:2 with lines

      # データファイルから座標を生成するのに必要な情報をすべてそのヘッ
      # ダに含んでいる EDF ファイルの場合
      plot '<file_name>' binary filetype=edf with image
      plot '<file_name>.edf' binary filetype=auto with image

      # 3 つの符号なし文字型整数値 (unsigned char) を生の RGB 画像の色
      # 成分として選択し、y 方向は反転させ画像の方向を座標平面上で変更
      # する (左上が原点になるように)。ピクセルの間隔も指定し、ファイ
      # ルには 2 つの画像が含まれていて、そのうち一つは origin で平行
      # 移動する。
      plot '<file_name>' binary array=(512,1024):(1024,512) format='%uchar' \
           dx=2:1 dy=1:2 origin=(0,0):(1024,1024) flipy u 1:2:3 w rgbimage

      # 4 つの別のデータからなり、座標情報もデータファイルに含まれてい
      # る。ファイルは gnuplot が実行されているシステムとは異なるエン
      # ディアンで生成されている。
      splot '<file_name>' binary record=30:30:29:26 endian=swap u 1:2:3

      # 同じ入力ファイルで、今回は 1 番目と 3 番目のレコードをスキップ
      splot '<file_name>' binary record=30:26 skip=360:348 endian=swap u 1:2:3

以下参照: matrix。

3.18.3.4 index

キーワード index は、描画用に複数のデータ集合を持つファイルから、特 定のデータ集合を選択することを可能にします。

書式:

      plot 'file' index { <m>{:<n>{:<p>}} | "<name>" }

データ集合は 2 行の空白で分離されています。‘index <m>‘ は <m> 番目の集 合だけを選択します; ‘index <m>:<n>‘ は <m> から <n> までのデータ集合の 選択; ‘index <m>:<n>:<p>‘ は、<m>, <m>+<p>, <m>+2<p>, など、<p> おきの 集合を選択し、集合 <n> で終了します。C 言語の添字 (index) の付け方に従 い、index 0 はそのファイルの最初のデータ集合を意味します。大きすぎる index の指定にはエラーメッセージが返されます。<p> を指定し、<n> を空欄 にした場合、<p> 毎のデータをファイルの最後まで読み込みます。index を 指定しない場合は、ファイルのデータ全体を単一のデータ集合として描画しま す。

例:

      plot 'file' index 4:5

ファイルの各点に対して、それが含まれるデータ集合の index 値は、疑似列 ‘column(-2)‘ で利用できます。これは、以下に見るように、そのファイル内 の個々のデータ集合を区別する別の方法を提供します。これは、描画用に 1 つのデータ集合の選択しかしない場合は index コマンドよりも不恰好です が、個々のデータ集合に異なる属性を割り当てたい場合にはとても便利です。 以下参照: ‘pseudocolumns‘, ‘lc variable‘。

例:

      plot 'file' using 1:(column(-2)==4 ? $2 : NaN)        # とても不恰好
      plot 'file' using 1:2:(column(-2)) linecolor variable # とても便利 !

‘index ’<name>’‘ は、データ集合を名前 ’<name>’ で選択します。名前はコ メント行に書いてデータ集合に割り当てます。コメント文字とそれに続く空白 をそのコメント行から取り除いて、その結果が <name> から始まっていれば、 それに続くデータ集合に <name> という名前がつけられて、それを指定できま す。

例:

      plot 'file' index 'Population'

<name> で始まるすべてのコメントがそれに続くデータ集合の名前になること に注意してください。問題を避けるために、例えば ’== Popolation ==’ や ’[Population]’ などの命名法を選択すると便利でしょう。

index を使った splot のデモ</p>

3.18.3.5 skip

キーワード skip は、プログラムにテキストデータファイル (バイナリデー タは不可) の先頭の数行をスキップさせます。スキップする行は、every キ ーワード処理での行数にはカウントしません。‘every ::N‘ はそのファイル内 のデータのすべてのブロックの先頭をスキップしますが、‘skip N‘ はそのフ ァイルの先頭部分の行のみをスキップすることに注意してください。バイナリ データファイルに適用される同様のオプションについては、以下参照: skip。

3.18.3.6 smooth

‘gnuplot‘ は、データの補間と近似を行う汎用的なルーチンをいくつか持っ ています。これ smooth オプションの中にグループ化されています。より 洗練されたデータ処理をしたければ、外部においてデータの前処理をするか、 または適切なモデルで fit を使うのがいいでしょう。

書式:

      smooth {unique | frequency | fnormal | cumulative | cnormal | bins
                     | kdensity {bandwidth}
                     | csplines | acsplines | mcsplines | bezier | sbezier
                     | unwrap}

‘unique‘, ‘frequency‘, ‘fnormal‘, ‘cumulatie‘, ‘cnormal‘ は、x 座標に 関してデータをソートし、そしてその x の値に対する分布のある種の様子を 描画します。

spline 系、Bezeir 系のオプションは、データの端と端を結ぶ連続曲線の係数 を決定します。この曲線は関数グラフと同じ方法、すなわちその値を x 座標 に沿う同じ幅の区間ごとに選び (以下参照: ‘set samples‘)、それらの点を 線分でつなぐことで描画します。データ集合が空行や未定義値で切られてい る場合、切られていないそれぞれの部分を別々の連続曲線としてつなぎます。 これらの別々につないだ部分同士は、曲線として切れたり、不連続になった りするかもしれません。

‘unwrap‘ は、データがπより大きなジャンプをしないように、2πの整数倍を 加える操作をします。

もし ‘autoscale‘ の状態であれば、軸の範囲は元のデータからではなく、そ こから作られる最終的な曲線に対して計算されます。

もし ‘autoscale‘ の状態でなく、かつスプライン曲線を生成する場合、その スプライン曲線の標本化は、入力データを含むような x の範囲と、 ‘set xrange‘ で定義される固定した横座標の範囲の共通部分の上で行なわれ ます。

要求する平滑化オプションを適用するにはデータの点数が少なすぎる場合は、 エラーメッセージが表示されます。

smooth オプションは、関数の描画のときには無視されます。

— ACSPLINES —

‘acsplines‘ オプションは「自然な滑らかなスプライン」でデータを近似しま す。データが x に関して単調にされた後 (以下参照: ‘smooth unique‘)、1 つの曲線が、いくつかの 3 次多項式の一部分により区分的に構成されます。 それらの 3 次式の係数は、個々のデータ点に合うように求められますが、 using 指定によって 3 列目の値が与えられた場合は、その値で個々の点に重 みをつけます。デフォルトは、以下と同じです:

      plot 'data-file' using 1:2:(1.0) smooth acsplines

性質上、重みの絶対的な大きさは、曲線を構成するのに使われる区分の数を決 定します。もし重みが大きければ、個々のデータの影響は大きくなり、そして その曲線は、隣り合う点同志を自然 3 次スプラインでつないで得られるもの に近づきます。もし重みが小さければ、その曲線はより少ない区分で構成され、 それによってより平滑的になります。その最も極端な場合はただ 1 つの区分 からなる場合であり、それは全てのデータに重みの付き線形最小 2 乗近似に よって作られます。誤差の立場から言えば、平滑さの重みは、その曲線に対す る「平滑化因子」によって分割された各点への、統計的な重みと見ることがで きます。それにより、そのファイル中の (標準的な) 誤差は平滑さの重みとし て使うことができます。

例:

      sw(x,S)=1/(x*x*S)
      plot 'data_file' using 1:2:(sw($3,100)) smooth acsplines

— BEZIER —

‘bezier‘ オプションは、n 次 (データ点の個数) のベジェ曲線でデータを近 似します。この曲線は両端の点をつなぎます。

— BINS —

bins は bins と同じです。以下参照: bins。 関連する描画スタイルに関しては、以下参照: ‘smooth frequency‘, ‘smooth kdensity‘。

— CSPLINES —

‘csplines‘ オプションはデータを単調に揃えた後で (以下参照: ‘smooth unique‘) 自然 3 次スプライン曲線で引き続く点をつなぎます。

— MCSPLINES —

‘mcsplines‘ オプションは、平滑化された関数が元の点の単調性と凸性を保存 するような 3 次スプライン曲線で引き続く点をつなぎます。これは、外れ値 の影響を低減します。 FN Fritsch & RE Carlson (1980) "Monotone Piecewise Cubic Interpolation", SIAM Journal on Numerical Analysis 17: 238-246.

— SBEZIER —

‘sbezier‘ オプションは、最初にデータを単調に揃え (以下参照: ‘unique‘) そして ‘bezier‘ アルゴリズムを適用します。

— UNIQUE —

‘unique‘ オプションは、データを x 方向に単調にします。同じ x を持つデ ータ点は y の値を平均して一つの点で置き換えます。そしてその結果として 得られる点を線分で結びます。

— UNWRAP —

‘unwrap‘ オプションは、2 つの続く点がπを越える違いが出ないようにデー タを修正します: y の値がその範囲を越えるような点に対しては、前の点との 差がπの範囲に収まるように 2πの整数倍を加えます。この操作は、巻き戻し を持つ系の値を時間的に連続にさせるのに有用です。

— FREQUENCY —

オプション ‘frequency‘ は、データを x に関して単調にします。x 座標が同 じ点は、それらの y の値の合計を y の値として持つ一つの点に置き換えます。 多くの値のデータのヒストグラムを一定の階級幅 (bin) で描くには、それら の y の値を 1.0 にして、それでその和が同じ階級幅内の点の個数を表すよう にします。これは、データ 1 列だけを指定した場合は、暗黙のうちに行なわ れます。 例:

     binwidth = <適当な値>  # x の値の各階級幅
     bin(val) = binwidth * floor(val/binwidth)
     plot "datafile" using (bin(column(1))):(1.0) smooth frequency
     plot "datafile" using (bin(column(1))) smooth frequency  # 同上

以下も参照。 smooth.dem

— FNORMAL —

オプション ‘fnormal‘ は、オプション ‘frequency‘ と同様の動作をしますが、 正規化したヒストグラムを生成します。すなわち、データを x に関して単調 にして、y の値はそのすべての和が 1 になるように正規化します。x 座標が 同じ点は、それらの y の値の合計を y の値として持つ一つの点に置き換えま す。多くの値のデータのヒストグラムを一定の階級幅 (bin) で描くには、そ れらの y の値を 1.0 にして、それでその和が同じ階級幅内の点の個数を表す ようにします。これは、データ 1 列だけを指定した場合は、暗黙のうちに行 なわれます。以下も参照。 smooth.dem

— CUMULATIVE —

オプション ‘cumulative‘ は、データを x に関して単調にします。x 座標が 同じ点は、それ以下の x の値を持つすべての点 (すなわち現在のデータ点の 左側の点) に対する y の値の累積的な合計を y の値として持つ一つの点に置 き換えられます。これは、データから累積分布関数を得るのに利用できます。 以下も参照。 smooth.dem

— CNORMAL —

オプション ‘cnormal‘ は、x に関して単調で、y の値は [0:1] に正規化され たデータを生成します。同じ x の値を持つ点が複数ある場合は、それより小 さい x の値を持つすべてのデータ点 (すなわち現在のデータ点よりも左にあ る点) の累積和を、すべての y の値の和で割った値を y の値として持つよう な一点のデータに置き変えられます。これは、データから正規化された累積分 布関数を得るのに使えます (特に標本点数の異なるデータ集合を比較するのに 有用です)。 以下も参照。 smooth.dem

— KDENSITY —

オプション ‘kdensity‘ は、ガウス核を用いた、ランダム選択点の核密度評価 (それは滑らかなヒストグラムになります) を描画する方法の一つです。ガウ ス核が第 1 列の各点の位置に置かれ、これらのガウス核すべての和が関数と して描画されます。2 列目の値は、ガウス核の重みとして使用されます。正規 化されたヒストグラムを得るには、これを 1/(点の個数) とすべきです。デフ ォルトでは、gnuplot は正規分布のデータに対して最適となるようなバンド幅 を計算し使用します。

     default_bandwidth = sigma * (4/3N) ** (0.2)

これは通常はとても保守的で、すなわち幅広いバンド幅です。バンド幅は、明 示的に指定することもできます。

     plot $DATA smooth kdensity bandwidth <value> with boxes

前の描画で使用されたバンド幅は、変数 GPVAL_KDENSITY_BANDWIDTH に保存さ れます。

3.18.3.7 特別なファイル名 (special-filenames)

特別な意味を持つファイル名として、次のものがあります: ”, ’-’, ’+’, ’++’

空のファイル名 ” は、同じ plot コマンド上で、直前の入力ファイルを再び 使用することを gnuplot に指示します。よって、同じ入力ファイルの 2 つの データ列を描画するには以下のようにします:

      plot 'filename' using 1:2, '' using 1:3

この filename は、この後の plot コマンドでも ” で再利用できますが、 その場合に save すると、コメントとしてその名前を記録するのみです。

’+’ と ’++’ という特別なファイル名は、using 指定の全体と描画スタイル にインライン関数を使えるようにするための仕組みです。通常、関数描画はサ ンプル点毎に単一の y (または z) の値しか持てません。しかし疑似ファイル ’+’ はそれがあたかも実際の入力ファイルであるように、using 指定による 1 列目の値を標本点として扱い、さらに追加の列の値を指定することも可能で す。標本点は、デフォルトでは ‘set xrange‘ で設定した範囲全体に渡り、 ‘set samples‘ で制御する標本化に従って取られます。

      plot '+' using ($1):(sin($1)):(sin($1)**2) with filledcurves

’+’ の直前に、独立な標本範囲を指定することもできます。通常の関数描画の と同様、独立変数に名前を割り当てることもできます。plot の最初の要素に 与える場合、標本範囲にはそれを明示するキーワード ‘sample‘ を前置する必 要があります (以下も参照: ‘plot sampling‘)。

      plot sample [beta=0:2*pi] '+' using (sin(beta)):(cos(beta)) with lines

さらに、‘+‘ の範囲指定には、標本増分を与えることもできます。

      plot $MYDATA, [t=-3:25:1] '+' using (t):(f(t))

疑似ファイル ’++’ は、u 方向は ‘set samples‘ で制御される点の数、v 方 向は ‘set isosamples‘ で制御される点の数の、標準的な [u,v] 座標の格子 を生成する 2 列のデータを返します。よって、’++’ の描画の前に、urange と vrange を設定する必要がありますが、x と y の範囲は自動的に設定され るか、または明示的に urange, vrange とは違う値に設定できます。’++’ の サンプリングでの u, v の使用は、version 5.0 からの変更です。 例:

      splot '++' using 1:2:(sin($1)*sin($2)) with pm3d
      plot '++' using 1:2:(sin($1)*sin($2)) with image

‘’-’‘ という特別なファイル名は、データがインラインであることを指示し ます。すなわち、データをコマンドの後に続けて指定します。このときはデ ータのみがコマンドに続き得ます。よって、‘plot‘ コマンドに対するフィル ター、タイトル、ラインスタイルといったオプションは、‘plot‘ のコマンド ラインの方に書かないといけません。これは、unix シェルスクリプトにおけ る << (ヒアドキュメント)、あるいは VMS DCL における $DECK と同様です。 そのデータは、それらがファイルから読み込まれたかのように、1 行につき 1 つずつのデータ点が入力されます。そしてデータの終りは、1 列目の始めに 文字 "e" を置くことで指示します。

‘’-’‘ は、データとコマンドを一緒に持つことが有用である場合のためにあり ます。例えば、別々のアプリケーションから ‘gnuplot‘ にその両方がパイプ 入力される場合です。例えば、デモファイルの中にはこの機能を使うものがあ るでしょう。index や every のような ‘plot‘ のオプションが与えられ ていると、それらは使われることのないデータの入力を要求してきます。ごく 単純な場合を除くすべての場合で、‘’-’‘ からデータを読み込むよりも、最初 にデータブロックを定義してそれを読み込む方が多分簡単です。以下参照: ‘datablocks‘。

もし、replot コマンドで ‘’-’‘ を使うなら、あなたは 1 度以上データを 入力する必要があるでしょう。以下参照: replot, refresh。繰り返しま すが、データブロックを使う方がいいです。

空のファイル名 (”) は、直前のファイル名が再び使われることを指示しま す。これは、

      plot 'ある/とても/長い/ファイル名' using 1:2, '' using 1:3, '' using 1:4

のようなときに便利です。(もし同じ plot コマンド上で、‘’-’‘ と ‘”‘ の 両方を使用すると、上の例にあるように、インラインデータの 2 つの集合を 与える必要があります。)

3.18.3.8 パイプによる入力データ (piped-data)

popen 関数を持っているシステム上では、データファイルは、’<’ で始まるフ ァイル名によって、シェルコマンドからパイプ入力することができます。例え ば

      pop(x) = 103*exp(-x/10)
      plot "< awk '{print $1-1965, $2}' population.dat", pop(x)

は、最初の人口の例と同じ情報を描画します。ただし、x 座標は 1965 年か らの経過年を表すようになります。この例を実行するときは、上のデータフ ァイルのコメント行をすべて削除しなければなりませんが、または上のコマ ンドの最初の部分を次のように変えることもできます (コンマに続く部分):

      plot "< awk '$0 !~ /^#/ {print $1-1965, $2}' population.dat"

このアプローチは最も柔軟性がありますが、using キーワードを用いた単純 なフィルタリングで行うことも可能です。

fdopen() 関数を持つシステムでは、データを、ファイルかパイプに結びつけ られた任意のファイルデスクリプタから読み込むことができます。‘n‘ 番のフ ァイルデスクリプタから読み込むには、‘’<&n’‘ としてください。これにより、 1 回の POSIX shell からの呼び出しの中で、複数のデータファイルからのパ イプ入力が容易に行えるようになります:

      $ gnuplot -p -e "plot '<&3', '<&4'" 3<data-3 4<data-4
      $ ./gnuplot 5< <(myprogram -with -options)
      gnuplot> plot '<&5'

3.18.3.9 thru

キーワード thru は非推奨です。

古い書式:

      plot 'file' thru f(x)

現在の書式:

      plot 'file' using 1:(f($2))

3.18.3.10 using

最もよく使われるデータファイルの修飾子は using で、これは入力ファイ ルのどの行を描画するのかを指示します。

書式:

      plot 'file' using <entry> {:<entry> {:<entry> ...}} {'format'}

format を指定すると、それを C ライブラリ関数 ’scanf’ に適用してデータ ファイルの各行を読みます。そうでなければ、各行はホワイトスペース (スペ ースやタブ) で区切られたデータの列 (フィールド) からなるとみなしますが 以下も参照: ‘datafile separator‘。

各 <entry> は、入力ファイルの一つのフィールドを選択するための単なる列 の番号か、一つのデータ集合の最初の行の列のラベルに一致する文字列、カッ コで囲まれた数式、xticlabels(2) のようにカッコで囲まない特別な関数、の いずれかです。

そのエントリがカッコで囲まれた数式の場合、N 列目の値を指定するのに関数 column(N) を使用できます。つまり、column(1) は読み込まれた最初の項目を 参照し、column(2) は次の項目、といった具合です。column(1), column(2), ... の略記として、特別な記号 $1, $2, ... を使用できます。関数 ‘valid(N)‘ で、N 番目の列が有効な数字であるかどうかテストできます。

入力ファイルの最初の行の各列に、データの値ではなくラベルを持っている場 合、このラベルを入力列の特定や plot タイトルに使用できます。関数 column() は、列番号以外にラベルで入力列を選択できます。例えば、データ ファイルが以下のような場合:

      Height    Weight    Age
      val1      val1      val1
      ...       ...       ...

以下の plot コマンドは同じ意味になります:

      plot 'datafile' using 3:1, '' using 3:2
      plot 'datafile' using (column("Age")):(column(1)), \
                   '' using (column("Age")):(column(2))
      plot 'datafile' using "Age":"Height", '' using "Age":"Weight"

指定文字列が完全に一致する必要がありますし、大文字小文字も区別します。 列のラベルを plot タイトルに使うには、columnhead としてください。

入力データファイルの 1...N という実際の列に加えて、gnuplot は管理情報 を持ついくつかの "疑似列" を提供します。例えば、$0 または column(0) は、 データ集合内のそのデータ行の行番号を返します。以下参照: ‘pseudocolumns‘。

<entry> に何も書かなければ、そのエントリのリストの順にデフォルトの値が 使われます。例えば ‘using ::4‘ は、‘using 1:2:4‘ と解釈されます。

using にただ一つのエントリを指定した場合は、その <entry> は y の値と して使われ、データ点の番号 (疑似列 $0) が x として使われます。例えば "‘plot ’file’ using 1‘" は "‘plot ’file’ using 0:1‘" と同じ意味です。 using に 2 つのエントリを与えた場合、それらは x, y として使われます。 さらにエントリを追加して、入力からのデータを利用するような描画スタイル の詳細については、以下参照: ‘set style‘, ‘fit‘。

’scanf’ 関数では色々なデータ形式の数値入力が使えますが、‘gnuplot‘ は全 ての入力データを倍精度浮動小数とみなしますから、‘gnuplot‘ では ‘%lf‘ が本質的に唯一の数値入力指定、ということになります。 書式文字列には、少なくとも一つ、そして 7 つ以下の、そのような入力指定子 を入れる必要があります。 ’scanf’ は数と数の間にホワイトスペース、すなわち空白、タブ ("\t")、改行 ("\n")、または改ページ ("\f") があると期待します。それ以外の入力は明示 的にスキップされるべきです。

"\t", "\n", "\f" を使うときは単一引用符よりむしろ二重引用符を使うべき であることに注意してください。

— USING の例 (USING_EXAMPLES) —

次の例は、1 番目のデータに対する 2 番目と 3 番目の和の値を plot します。 書式文字列は、各列データがスペース区切りでなく、コンマ区切りであること を指示していますが、同じことが ‘set datafile separator comma‘ を指定す ることでも可能です。

      plot 'file' using 1:($2+$3) '%lf,%lf,%lf'

次の例は、より複雑な書式指定でデータをファイル "MyData" から読み込み ます。

      plot 'MyData' using "%*lf%lf%*20[^\n]%lf"

この書式指定の意味は以下の通りです:

      %*lf        数値を無視
      %lf         倍精度浮動小数を読み込む (デフォルトでは x の値)
      %*20[^\n]   20 個の改行以外の文字を無視
      %lf         倍精度浮動小数を読み込む (デフォルトでは y の値)

3 項演算子 ‘?:‘ を使ってデータをフィルタする一つの芸当を紹介します。

      plot 'file' using 1:($3>10 ? $2 : 1/0)

これは、1 列目のデータに対して、3 列目のデータが 10 以上であるような 2 列目のデータを plot します。‘1/0‘ は未定義値であり、‘gnuplot‘ は未定 義の点を無視するので、よって適切でない点は隠されることになります。 または、あらかじめ定義されている値 NaN を使っても同じことになります。

カッコで始まっていない限りは定数式を列番号として使うことができます。 例えば ‘using 0+(複雑な式)‘ の様なことができます。そして、その数式は、 カッコでスタートしていなければ数式の値が一度評価され、カッコでスタート していれば個々のデータ点を読み込むためにその値が一度評価される、という 点が重要です。

時系列フォーマットデータを使っている場合、その時間のデータは複数の列に 渡らせることができます。その場合、他のデータの開始位置を計算するとき、 時間のデータに空白が含まれていることに注意してください。例えば、データ 行の最初の要素がスペースが埋め込まれた時間データであるならば、y の値は 3 列目の値として指定されるべきです。

(a) ‘plot ’file’‘ と、(b) ‘plot ’file’ using 1:2‘、そして (c) ‘plot ’file’ using ($1):($2)‘ には微妙な違いがあることに注意してく ださい。細かい挙動は、バージョン 5 で変更されています。以下参照: ‘missing‘。

最初に単に

      plot 'file' using 1:2

と指定することで、大抵の場合どんなにゴミのデータを含む行を持つファイル をも plot することが可能になります。しかし、どうしてもデータファイルに 文字列を残しておきたいならば、そのテキスト行の第一列にコメント文字 (#) を置く方がより安全でしょう。

— 疑似列 (PSEUDOCOLUMNS) —

plot 文の using 項目内の式では、入力ファイルに含まれる実際のデータ値 に加えて管理情報も参照でき、これらは "疑似列" (pseudocolumns) に含まれ ています。

      column(0)   データ集合内での各点の順番。順番は 0 から始まり、2
                  行のブランク行でリセットされます。略記 $0 も使用可。
      column(-1)  この番号は 0 から始まり、1 行のブランク行でリセット
                  されます。これは、行列、または格子状データ内のデータ
                  行に対応します。
      column(-2)  複数のデータ集合を持つファイル内の、現在のデータ集合
                  の index 番号。以下参照: index。

— XTICLABELS —

軸の刻みの見出し (ticlabel) は文字列関数によって作ることもでき、それは 通常は引数としてデータ列から取得します。最も単純な形式は、データ列自身 の文字列としての利用で、xticlabels(N) は xticlabels(stringcolumn(N)) の省略形として使えます。以下の例は 3 列目の要素を x 軸の刻みの見出しと して使用します。

      plot 'datafile' using <xcol>:<ycol>:xticlabels(3) with <plotstyle>

軸の目盛りの見出しは、任意の描画軸 x,x2,y,y2,z 用に生成できます。 ‘ticlabels(<labelcol>)‘ 指定は、using 指定の中で、そのデータの座標指 定が全て済んだ後に行う必要があります。有効な X,Y[,Z] 座標の組を持つ各 データ点に対して、xticlabels() に与える文字列値は、それに対応する点の x 座標と同じ場所の x 軸の見出しのリストに追加されます。‘xticlabels()‘ は ‘xtic()‘ と省略することもでき、他の軸に関しても同様です。

例:

      splot "data" using 2:4:6:xtic(1):ytic(3):ztic(6)

この例では、x 軸、y 軸の見出しは x,y 座標値とは別の列から取り出されま すが、z 軸の見出しは、対応する点の z 座標値から生成されます。

例:

      plot "data" using 1:2:xtic( $3 > 10. ? "A" : "B" )

この例は、x 軸の見出しの生成に文字列値関数を使用したもので、データファ イルの各点の x 軸の刻みの見出しは、3 列目の値によって "A" か "B" かの いずれかとなります。

— X2TICLABELS —

以下参照: ‘plot using xticlabels‘。

— YTICLABELS —

以下参照: ‘plot using xticlabels‘。

— Y2TICLABELS —

以下参照: ‘plot using xticlabels‘。

— ZTICLABELS —

以下参照: ‘plot using xticlabels‘。

3.18.3.11 volatile

plot コマンドのキーワード volatile は、入力ストリームかファイルから 以前に読み込んだデータが、再読み込み時には有効ではないことを意味します。 これは、replot コマンドの代わりに、可能な限り refresh コマンド を使うよう gnuplot に指示します。以下参照: refresh。

3.18.4 errorbars

エラーバーは、1 から 4 個の追加されたデータを読む (またはエントリを using で追加選択する) ことにより、2 次元データの描画において実現され ています。これら追加される値は、それぞれのエラーバースタイルで異なった 形で使われます。

デフォルトでは、‘gnuplot‘ はデータファイルの各行に以下のような 3 つ、 4 つ、あるいは 6 つの列があることを期待しています:

      (x, y, ydelta),
      (x, y, ylow, yhigh),
      (x, y, xdelta),
      (x, y, xlow, xhigh),
      (x, y, xdelta, ydelta),
      (x, y, xlow, xhigh, ylow, yhigh)

x 座標は必ず指定しなければいけません。各数値を書く順序も上で挙げた通りで なくてはなりません。ただ、using 修飾子を使えばその順序を操作できますし、 欠けている列の値も補うことは可能ですが。例えば、

      plot 'file' with errorbars
      plot 'file' using 1:2:(sqrt($1)) with xerrorbars
      plot 'file' using 1:2:($1-$3):($1+$3):4:5 with xyerrorbars

最後の例は、相対的な x の誤差と絶対的な y の誤差、という、サポートされて いない組のファイルに対するものです。using エントリが相対的な x の誤差 から絶対的な x の最小値と最大値を生成しています。

y のエラーバーは、(x, ylow) から (x, yhigh) への鉛直な線として描かれます。 ylow と yhigh の代わりに ydelta が指定されたときは、ylow = y - ydelta, yhigh = y + ydelta となります。ある行にデータが 2 つしかなければ、ylow と yhight はともに y となります。x エラーバーは同様に計算された水平線です。 データの各点を結ぶ折れ線を引きたい場合は、with errorbars と with lines を 指定して、同じデータファイルを 2 回 ‘plot‘ して下さい (ただし、キーの中に 2 つのエントリを作らないように、その一方には ‘notitle‘ オプションを使う ことを忘れないで下さい)。他の選択肢として、errorlines コマンドもあります (以下参照: errorlines)。

エラーバーの端の刻みの印の見た目は、errorbars で制御できます。

自動範囲指定が有効であれば、その描画範囲はエラーバーも含むように調整 されます。

以下も参照 エラーバーのデモ

更なる情報に関しては、以下参照: using, with, ‘set style‘。

3.18.5 errorlines

誤差線 (errorbar) を伴う線描画は、2 次元データファイルの描画でサポート されていて、それは 1 個から 4 個の追加の (または using で指定する) 列データを与えることで行なわれます。これらの追加される値は、様々な errorline スタイルのそれぞれで異なった形で使われます。

デフォルトの状態では、‘gnuplot‘ は、データファイルの各行に 3 個、4 個、 6 個のいずれかの個数のデータがあることを期待し、それぞれ以下のいずれか に対応します。

      (x, y, ydelta),
      (x, y, ylow, yhigh),
      (x, y, xdelta),
      (x, y, xlow, xhigh),
      (x, y, xdelta, ydelta),
      (x, y, xlow, xhigh, ylow, yhigh)

x 座標は指定する必要がありますし、データの順番も上の形式である必要があ りますが、using 修飾子でその順番を操作したり、欠けている列に対する値 を与えたりすることができます。例えば

      plot 'file' with errorlines
      plot 'file' using 1:2:(sqrt($1)) with xerrorlines
      plot 'file' using 1:2:($1-$3):($1+$3):4:5 with xyerrorlines

最後の例は、相対的な x の誤差と絶対的な y の誤差、というサポートされて いない組合せのデータのファイルに対するもので、using で相対的な誤差か ら絶対的な x の最小値と最大値を生成しています。

y 誤差線は (x, ylow) から (x, yhigh) へ描画される縦線です。ylow, yhigh 代わりに ydelta が指定された場合は、ylow = y - ydelta, yhigh = y + ydelta と扱われます。ある行に 2 つのデータしかない場合、yhigh, ylow は両方と も y になります。x 誤差線は同様の方法で計算される水平線です。

エラーバーの端の刻みの印の見た目は、errorbars で制御できます。

自動縮尺 (autoscaling) が ON の場合、描画範囲は誤差線が入るように調整 されます。

更なる情報については、以下参照: using, with, ‘set style‘。

3.18.6 関数描画 (functions)

コマンド ‘plot‘, ‘splot‘ では、ファイルから読み込んだデータの描画だけ でなく、組み込み関数やユーザ定義関数を描画することもできます。関数の値 は、独立な軸の通常の範囲に渡ってデータサンプルを取ることで評価します。 以下参照: ‘set samples‘, ‘set isosamples‘。

例:

      approx(ang) = ang - ang**3 / (3*2)
      plot sin(x) title "sin(x)", approx(x) title "approximation"

関数のデフォルトの描画スタイルを設定する方法については、以下参照: ‘set style function‘。組み込み関数の情報については、以下参照: functions。自前で関数を定義する方法については、以下参照: ‘user-defined‘。

3.18.7 媒介変数モード描画 (parametric)

媒介変数モード (‘set parametric‘) では、‘plot‘ では 2 つの数式の組を、 ‘splot‘ では 3 つの数式の組を与える必要があります。

例:

      plot sin(t),t**2
      splot cos(u)*cos(v),cos(u)*sin(v),sin(u)

データファイルは前と同じように描画されます。ただし、データファイルが 描画のために与えられる前に、任意の媒介変数関数が先に完全に指定された 場合を除いてです。言い換えると、x の媒介変数関数 (上の例では ‘sin(t)‘) と y の媒介変数関数 (上の例では ‘t**2‘) との間に、他の修飾子やデータ 関数をはさみこんではいけません。そのようなことをすると、構文エラーにな り、媒介変数関数が完全には指定されていない、と表示されます。

with や title のような他の修飾子は、媒介変数関数の指定が完了した 後に指定しなければいけません。

      plot sin(t),t**2 title 'Parametric example' with linespoints

以下も参照 媒介変数モードのデモ。

3.18.8 範囲 (ranges)

このセクションでは、コマンド ‘plot‘ の一番最初の項目として書く、軸の範 囲のオプションについてのみ説明します。これを指定すると、その範囲は、そ れ以前のどの ‘set range‘ による範囲の制限よりも優先して扱われます。コ マンド ‘plot‘ の別な場所に指定する、個々の描画要素の範囲の制限ためのオ プションについては以下参照: ‘sampling‘。

書式:

      [{<dummy-var>=}{{<min>}:{<max>}}]
      [{{<min>}:{<max>}}]

1 つ目の形式の範囲指定は独立変数の範囲 (‘xrange‘、または媒介変数モード での trange) 用で、2 つ目の形式は従属変数の範囲用です。オプションの <dummy-var> で独立変数の新しい名前を利用できます (デフォルトの変数名は ‘set dummy‘ で変更できます)。

媒介変数モード (parametric) でなければ、範囲指定は以下の順に与えなけれ ばいけません:

      plot [<xrange>][<yrange>][<x2range>][<y2range>] ...

媒介変数モード (parametric) では、範囲指定は以下の順に与えなければいけ ません:

      plot [<trange>][<xrange>][<yrange>][<x2range>][<y2range>] ...

以下の ‘plot‘ コマンドは、trange を [-pi:pi], ‘xrange‘ を [-1.3:1.3], yrange を [-1:1] に設定する例です:

      plot [-pi:pi] [-1.3:1.3] [-1:1] sin(t),t**2

‘*‘ は、min (最小値) や max (最大値) に自動範囲指定 (autoscale) の機能 を使うことを可能にします。指定順番のためだけに必要な範囲指定には、空の 範囲 ‘[]‘ を使ってください。

‘plot‘ や ‘splot‘ のコマンド行で指定された範囲はそのグラフ一つにのみ影 響を及ぼします。よって、その後のグラフのデフォルトの範囲を変更するには ‘set xrange‘ や yrange を使用してください。

リンクされた軸に対しては、plot コマンドでの一時的な範囲指定の使用は、 期待する結果を生まないかもしれません (以下参照: ‘set link‘)。代わりに ‘set xrange‘ と yrange の文を別々に指定する方がいいでしょう。

時間データに対しては、範囲は、データファイルから読み込むのに使用するの と同じ書式で、引用符で囲んで指定する必要があります。以下参照: ‘set timefmt‘。

例:

以下は現在の範囲を使用します:

      plot cos(x)

以下は x の範囲のみの指定です:

      plot [-10:30] sin(pi*x)/(pi*x)

以下は上と同じですが、仮変数として t を使います:

      plot [t = -10 :30]  sin(pi*t)/(pi*t)

以下は x と y の両方の範囲の指定です:

      plot [-pi:pi] [-3:3]  tan(x), 1/x

以下は、y の範囲のみの指定です:

      plot [ ] [-2:sin(5)*-8] sin(x)**besj0(x)

以下は x の最大値と y の最小値のみの指定です。

      plot [:200] [-pi:]  $mydata using 1:2

以下は x の範囲を時系列データとして指定しています:

      set timefmt "%d/%m/%y %H:%M"
      plot ["1/6/93 12:00":"5/6/93 12:00"] 'timedata.dat'

3.18.9 サンプリング (sampling)

3.18.9.1 1 次元のサンプリング (x または t 軸) (1D sampling)

デフォルトでは、関数や疑似ファイル "+" で生成されるデータは、描画範囲 全体にわたって標本 (サンプル) が取られます。この範囲は、事前にコマンド ‘set xrange‘ で設定するか、plot コマンドか splot コマンドの最初の場所 で大域範囲を明示的に指定するかしなければ、そのグラフのすべての要素を含 む範囲内にデータ全体が入るよう x の範囲を自動縮尺 (autoscaling) します。 しかし、その標本化範囲は個々の描画要素毎にさらに制限して割り当てること もできます。

例:

以下は、x 全体の範囲を 0 から 1000 としてファイルのデータを描画し、2 つの関数を全体の範囲の一部分だけそれぞれ描画します:

      plot [0:1000] 'datafile', [0:200] func1(x), [200:500] func2(x)

以下は、上とほぼ同様ですが、全体の範囲はデータファイルの内容によって決 定します。この場合、標本化される関数は、全体がグラフ内に収まるかもしれ ませんし、収まらないかもしれません:

      set autoscale x
      plot 'datafile', [0:200] func1(x), [200:500] func2(x)

以下のコマンドにはあいまいさが含まれます。先頭の範囲は、多分最初の関数 の標本化のみに向けたのだと思いますが、実際はそうではなく、すべての描画 要素に適用するように解釈されます:

      plot [0:10] f(x), [10:20] g(x), [20:30] h(x)

以下のコマンドは、上の例のあいまいさを除くためにキーワード ‘sample‘ を 追加したもので、その範囲指定を plot 全体に適用しないようにしています:

      plot sample [0:10] f(x), [10:20] g(x), [20:30] h(x)

以下の例は、3 次元グラフにらせんの曲線を描く一つの方法を提示します:

      splot [-2:2][-2:2] sample [h=1:10] '+' using (cos(h)):(sin(h)):(h)

3.18.9.2 2 次元のサンプリング (u と v 軸) (2D sampling)

疑似ファイル ’++’ に対して計算する関数値や生成されたデータは、u, v 軸 に沿って標本化 (サンプリング) を行います。これは、5.2 より前のバージョ ンからの仕様の「変更」で、従来は x, y 軸に沿って標本化していました。以 下参照: ‘special-filenames ++‘。2 次元のサンプリングは ‘plot‘, ‘splot‘ コマンドで使用できます。

以下は、2 次元の ‘plot‘ コマンドに対する 2 次元サンプリングの例です。 これは、描画スタイル vectors で表示されるグラフを生成します。 以下参照: vectors。

     set urange [ -2.0 : 2.0 ]
     set vrange [ -2.0 : 2.0 ]
     plot '++' using ($1):($2):($2*0.4):(-$1*0.4) with vectors

以下は 3 次元の ‘splot‘ コマンドに対する 2 次元サンプリングの例です。 これは、‘sampling.dem‘ で使用されているものに似たコマンド列です。この 2 つの曲面は、生成されるグラフの範囲全体よりも狭い u, v の範囲で標本 化を行うことに注意してください。

     set title "3D sampling range distinct from plot x/y range"
     set xrange [1:100]
     set yrange [1:100]
     splot sample [u=30:70][v=0:50] '++' using 1:2:(u*v) lt 3, \
           [u=40:80][v=30:60] '++' using (u):(v):(u*sqrt(v)) lt 4

u, v のサンプリングの範囲指定には、サンプリングデータの数とスペースを 制御する、明示的なサンプリング間隔を入れることもできます:

     splot sample [u=30:70:1][v=0:50:5] '++' using 1:2:(func($1,$2))

3.18.10 plot コマンドの for ループ (for loops in plot command)

多くの同等のファイルや関数を同時に描画する場合は、それぞれの plot コマ ンドの繰り返し (iteration) でそれを行うのが便利です。

書式:

      plot for [<variable> = <start> : <end> {:<increment>}]
      plot for [<variable> in "string of words"]

繰り返しの適用範囲 (scope) は、次のコンマ (,) かコマンドの終わり、のい ずれか先に現れたところまでです。ただし、描画する項目の前に定義式 (複数 も可) が並んでいる場合は、コンマが間に入っていてもその例外となります。

 繰り返しは媒介変数モード (parametric) では機能しないことに注意してく

ださい。

例:

      plot for [j=1:3] sin(j*x)

例:

      plot for [dataset in "apples bananas"] dataset."dat" title dataset

この例では、繰り返しはファイル名と対応するタイトルの生成の両方で使われ ています。

例:

      file(n) = sprintf("dataset_%d.dat",n)
      splot for [i=1:10] file(i) title sprintf("dataset %d",i)

この例は、ファイル名で生成される文字列値関数を定義し、そのような 10 個 のファイルを同時に描画します。繰り返しの変数 (この例では ’i’) は一つの 整数として扱われ、それを 2 度以上使用できます。

例:

      set key left
      plot for [n=1:4] x**n sprintf("%d",n)

この例は、関数の組を描画します。

例:

      list = "apple banana cabbage daikon eggplant"
      item(n) = word(list,n)
      plot for [i=1:words(list)] item(i).".dat" title item(i)
      list = "new stuff"
      replot

この例では、リストに従って各ステップが進行し、その各項目に対して一つの 描画が行われます。この各項目は動的に取得されますので、そのリストを変更 し、そのまま replot することができます。

例:

      list = "apple banana cabbage daikon eggplant"
      plot for [i in list] i.".dat" title i
      list = "new stuff"
      replot

この例は、整数の繰り返し変数ではなく、文字列の繰り返し変数形式を用いて いること以外は前の例と全く同じです。

<end> の整数の代わりに記号 * を使用すれば、繰り返しはすべての有効なデ ータがなくなるまでの繰り返しとなります。これは、各行に含まれるすべての 列の処理、あるいはファイル内のすべてのデータセット (2 行の空行で区切ら れる) の処理、指定に当てはまるすべてのファイルなどを一度に処理するのに 便利です。

例:

      plot for [i=2:*] 'datafile' using 1:i with histogram
      splot for [i=0:*] 'datafile' index i using 1:2:3 with lines
      plot for [i=1:*] file=sprintf("File_%03d.dat",i) file using 2 title file

3.18.11 title

デフォルトでは各曲線は、対応する関数やファイル名でキーの中に一覧表示さ れますが、plot のオプション title を使うことで、明示的なタイトルを与 えることもできます。

書式:

      title <text> | notitle [<ignored text>]
      title columnheader | title columnheader(N)
            {at {beginning|end}} {{no}enhanced}

ここで <text> は、引用符で囲まれた文字列か、文字列と評価される式のいず れかです。引用符はキーには表示されません。

入力データの列の最初の項目 (すなわち列の先頭) を文字列フィールドと解釈 し、それをキータイトルとして利用するオプションもあります。以下参照: ‘datastrings‘。これは、columnhead を指定すればデフ ォルトの挙動となります。

曲線タイトルとサンプルは予約語 ‘notitle‘ を使うことでキーから削除でき ます。何もないタイトル (‘title ”‘) は ‘notitle‘ と同じ意味を持ちます。 サンプルだけが欲しいときは、一つ以上の空白をタイトルの後ろに入れてく ださい (‘tilte ’ ’‘)。‘notilte‘ の後ろに文字列をつけた場合、その文字列 は無視されます。

‘key autotitles‘ が設定されて (デフォルト)、かつ title も ‘notitle‘ も指定されなかった場合、曲線のタイトルは ‘plot‘ コマンド上にある関数名 かデータファイル名になります。ファイル名の場合は、指定される任意のデー タファイル修飾子もそのデフォルトタイトルに含まれます。

位置やタイトルの位置揃えなどの凡例のレイアウトは、‘set key‘ で制御でき ます。詳細は、以下参照: ‘set key‘。

キーワード ‘at‘ により、曲線のタイトルを、自動的に作られる key の箱の 外にでも置くことができるようになります。‘at {beginning|end}‘ を使用し た場合は、曲線のタイトルをグラフの曲線自身の直前、あるいは直後に置きま す。このオプションは、‘with lines‘ で描画する場合は有用ですが、他の描 画スタイルでは無意味です。

‘at <x-position>,<y-position>‘ の形式を使用すれば、曲線のタイトルをペ ージ内の任意の位置に置くことができます。デフォルトでは、その位置指定は スクリーン座標と解釈します。例えば ‘at 0.5, 0.5‘ は、グラフの軸に縮尺 や境界には関係なく、常にスクリーンのど真ん中を意味します。この方法で配 置するタイトルの書式は、key のオプション指定の影響を受けます。以下参照: ‘set key‘。

例:

以下は y=x をタイトル ’x’ で表示します:

      plot x

以下は、x の 2 乗をタイトル "x^2" で、ファイル "data.1" をタイトル "measured data" で表示します:

      plot x**2 title "x^2", 'data.1' t "measured data"

以下は、ファイルの先頭行の各列にタイトルを含む複数列のデータを描画しま す。各タイトルは、独立した凡例ではなく、対応する曲線の後ろに置きます:

      unset key
      set offset 0, graph 0.1
      plot for [i=1:4] 'data' using i with lines title columnhead at end

以下は、2 つの別々のグラフの key の場所を 1 箇所にします:

      set key Left reverse
      set multiplot layout 2,2
      plot sin(x) with points pt 6 title "Left plot is sin(x)" at 0.5, 0.30
      plot cos(x) with points pt 7 title "Right plot is cos(x)" at 0.5, 0.27
      unset multiplot

3.18.12 with

関数やデータの表示にはたくさんのスタイルのうちの一つを使うことができます。 キーワード with がその選択のために用意されています。

書式:

      with <style> { {linestyle | ls <line_style>}
                     | {{linetype  | lt <line_type>}
                        {linewidth | lw <line_width>}
                        {linecolor | lc <colorspec>}
                        {pointtype | pt <point_type>}
                        {pointsize | ps <point_size>}
                        {fill | fs <fillstyle>} {fillcolor | fc <colorspec>}
                        {nohidden3d} {nocontours} {nosurface}
                        {palette}}
                   }

ここで、<style> は以下のいずれか:

     lines        dots       steps     errorbars     xerrorbar    xyerrorlines
     points       impulses   fsteps    errorlines    xerrorlines  yerrorbars
     linespoints  labels     histeps   financebars   xyerrorbars  yerrorlines
     surface      vectors    parallelaxes

または、

     boxes         boxplot        ellipses       histograms  rgbalpha
     boxerrorbars  candlesticks   filledcurves   image       rgbimage
     boxxyerror    circles        fillsteps      pm3d        zerrorfill

または

     table

最初のグループのスタイルは、線、点、文字の属性を持ち、第 2 のグループ のスタイルは、さらに塗り潰し属性も持っています。以下参照: ‘fillstyle‘。 さらにサブスタイルを持つスタイルもあります。個々のスタイルの詳細につい ては、以下参照: ‘plotting styles‘。 スタイル ‘table‘ は、グラフの代わりに表形式の出力を生成します。以下参 照: ‘set table‘。

デフォルトのスタイルは、‘set style function‘ と ‘set style data‘ で選 択できます。

デフォルトでは、それぞれの関数やデータファイルは、使うことができる型の 最大数に達するまで異なる線種、点種を使います。すべての端末用ドライバは 最低 6 つの異なる点種をサポートしていて、もしたくさん要求された場合、 それらを順に再利用していきます。使用中の出力形式での線種、点種の集合全 体を見たければ、test としてください。

一つの描画で線種や点種を選びたいならば、<line_type> や <point_type> を 指定してください。これらの値は、その描画で使われる線種や点種を指定する 正の整定数 (または数式) です。使用する端末で使える線種、点種を表示する には test コマンドを使ってください。

描画の線の幅や点の大きさは <line_width> や <point_size> で変更できます。 これらはその各々の端末のデフォルトの値に対する相対的な値として指定しま す。点の大きさは全体に通用するように変更できます。詳細は、以下参照: ‘set pointsize‘。しかし、ここでセットされる <point_size> と、 ‘set pointsize‘ でセットされる大きさは、いずれもデフォルトのポイントサ イズに掛けられることに注意してください。すなわち、それらの効果は累積は しません。例えば、‘set pointsize 2; plot x w p ps 3‘ は、デフォルトの サイズの 3 倍であって、6 倍ではありません。

ラインスタイルの一部分、あるいは各 plot において ‘pointsize variable‘ という指定も可能です。この場合、入力には追加の 1 列が要求されます。例 えば 2D 描画では 3 列、3D 描画では 4 列のデータが必要になります。個々 の点のサイズは、全体を通しての pointsize に、データファイルからの入力 による値をかけたものとして決定されます。

‘set style line‘ を使って線種/線幅、点種/点幅の組を定義すれば、そのス タイルの番号を <line_style> にセットすることでそれらを使うことができま す。

gnuplot が ‘pm3d‘ をサポートするようにインストールされているならば、 ‘splot‘ において lines, points, dots の色を滑らかに変化させるための特 別なキーワード ‘palette‘ が使えます。その色は、コマンド ‘set palette‘ であらかじめ設定された滑らかに変化するカラーパレットから選択します。色 の値は、点の z 座標の値か、または using で 4 番目のパラメータとして 指定される色座標に対応します。2 次元、3 次元の描画 (‘plot‘ と ‘splot‘ コマンド) の両方で、パレット色を小数値かまたはカラーボックスの範囲へ対 応づけられた値のいずれかで指定することができます。パレット色の値は、 using 指定で明示的に指定された入力列から読み込むことも可能です。 以下参照: ‘colors‘, ‘set palette‘, linetype。

キーワード ‘nohidden3d‘ は、‘splot‘ コマンドで生成される描画にのみ適用 されます。通常、グローバルなオプション ‘set hidden3d‘ はグラフ上の全て の描画に適用されますが、各々の描画に ‘nohidden3d‘ オプションをつけるこ とで、それを hidden3d の処理から除外することができます。‘nohidden3d‘ がマークされた曲面以外の個々の描画要素 (線分、点、ラベル等) は、通常は 他の何らかの描画要素で隠されてしまう場合も全て描画されます。

同様に、キーワード ‘nocontours‘ は、グローバルに ‘set contour‘ 指定が 有効な場合でも、個別の plot に対する等高線描画機能をオフにします。

同様に、キーワード ‘nosurface‘ は、グローバルに ‘set surface‘ 指定が有 効な場合でも、個別の plot に対する 3 次元曲面描画をオフにします。

キーワードは暗示するような形で省略可能です。

‘linewidth‘, ‘pointsize‘, ‘palette‘ オプションは全ての端末装置でサポー トされているわけではないことに注意してください。

例:

以下は、sin(x) を鉛直線で描画します:

      plot sin(x) with impulses

以下は、x を点で描画し、x**2 をデフォルトの方式で描画します:

      plot x w points, x**2

以下は、tan(x) を関数のデフォルトの方式で、"data.1" を折れ線で描画します:

      plot [ ] [-2:5] tan(x), 'data.1' with l

以下は、"leastsq.dat" を鉛直線で描画します:

      plot 'leastsq.dat' w i

以下は、データファイル "population" を矩形で描画します:

      plot 'population' with boxes

以下は、"exper.dat" をエラーバー付きの折れ線で描画します (エラーバーは 3 列、あるいは 4 列のデータを必要とします):

      plot 'exper.dat' w lines, 'exper.dat' notitle w errorbars

もう一つの "exper.dat" のエラーバー付きの折れ線 (errorlines) での描画 方法 (エラーバーは 3 列、あるいは 4 列のデータが必要):

      plot 'exper.dat' w errorlines

以下は、sin(x) と cos(x) をマーカー付きの折れ線で描画します。折れ線は 同じ線種ですが、マーカーは異なったものを使います:

      plot sin(x) with linesp lt 1 pt 3, cos(x) with linesp lt 1 pt 4

以下は、"data" を点種 3 で、点の大きさを通常の 2 倍で描画します:

      plot 'data' with points pointtype 3 pointsize 2

以下は、"data" を描画しますが、4 列目から読んだデータを pointsize の値 として使用します:

      plot 'data' using 1:2:4 with points pt 5 pointsize variable

以下は、2 つのデータ集合に対して、幅のみ異なる線を用いて描画します:

      plot 'd1' t "good" w l lt 2 lw 3, 'd2' t "bad" w l lt 2 lw 1

以下は、x*x の曲線の内部の塗りつぶしと色の帯を描画します:

      plot x*x with filledcurve closed, 40 with filledcurve y=10

以下は、x*x の曲線と色の箱を描画します:

      plot x*x, (x>=-5 && x<=5 ? 40 : 1/0) with filledcurve y=10 lt 8

以下は、滑らかに変化する色の線で曲面を描画します:

      splot x*x-y*y with line palette

以下は、2 つの色のついた曲面を、異なる高さで表示します:

      splot x*x-y*y with pm3d, x*x+y*y with pm3d at t

3.19 print

‘print‘ コマンドは <式> の値を画面に表示します。これは ‘pause 0‘ と同 じです。<式> は、数を生成する ‘gnuplot‘ の数式か、または文字列です。

書式:

        print <式> {, <式>, ...}

以下参照: ‘expressions‘。出力ファイルは ‘set print‘ で設定できます。 以下も参照: printerr。

3.20 printerr

printerr は print コマンドとほぼ同じですが、その前の ‘set print‘ コ マンドの効果が続いている状態でも出力を常に stderr に送るところだけが違 います。

3.21 pwd

pwd コマンドはカレントディレクトリの名前を画面に表示します。

カレントディレクトリを文字列変数に保存したり、文字式の中で使いたい場合 は、変数 GPVAL_PWD を使うことができることに注意してください。以下参照: ‘show variables all‘。

3.22 quit

exit と quit の両コマンドと END-OF-FILE 文字は、‘gnuplot‘ を終了 させます。これらのコマンドは、出力装置を (clear コマンドと同様に) クリアしてから終了させます。

3.23 raise

書式:

      raise {plot_window_id}
      lower {plot_window_id}

コマンド raise と lower は、出力形式のいくつかにしか機能せず、そし てあなたが使用するウィンドウマネージャや表示優先機能の設定にも依存する 可能性があります。

      set term wxt 123     # 最初の描画ウィンドウを生成
      plot $FOO
      lower                # 存在する描画ウィンドウのみを下に
      set term wxt 456     # 2 つ目を生成 (1 つ目の上にかぶる)
      plot $BAZ
      raise 123            # 1 つ目の描画ウィンドウを上に

これらのコマンドは、あまり当てにならないと思ってください。

3.24 refresh

コマンド refresh は、replot に似ていますが、主に 2 つの点で違いが あります。refresh は、既に読み込んだデータを用いて、現在の描画を再整 形し再描画します。これは、refresh を (疑似デバイス ’-’ からの) イン ラインデータの描画、および内容が変化しうるデータファイルからの描画に使 えるということを意味します。ただし、コマンド refresh は、既に存在す る描画に新しいデータを追加するのには使えません。

マウス操作、特にズームインとズームアウトでは、適切な場合は replot の 代わりにむしろ refresh を使用します。例:

      plot 'datafile' volatile with lines, '-' with labels
      100 200 "Special point"
      e
      # 色んなマウス操作をここで実行
      set title "Zoomed in view"
      set term post
      set output 'zoom.ps'
      refresh

3.25 replot

replot コマンドを引数なしで実行すると、最後に実行した ‘plot‘ または ‘splot‘ コマンドを再実行します。これは、あるプロットを異なる ‘set‘ オ プションでみたり、同じプロットを異なる装置に出力したりするときに便利 でしょう。

replot コマンドに対する引数は最後に実行した ‘plot‘ または ‘splot‘ コマンドの引数に (暗黙の ’,’ と共に) 追加され、それから再実行されます。 replot は、範囲 (range) を除いては、‘plot‘ や ‘splot‘ と同じ引数を とることができます。よって、直前のコマンドが ‘splot‘ ではなく ‘plot‘ の場合は、関数をもう一つの軸刻みでプロットするのに replot を使うこと ができます。

注意:

      plot '-' ; ... ; replot

という使い方は推奨されません。それは、これがあなたに再び同じデータすべ ての入力を要求することになるからです。たいていの場合、代わりにコマンド refresh を使えます。これは、以前に読み込んだデータを使ってグラフを再 描画します。

‘multiplot‘ モードでは、replot コマンドはすべての plot ではなく、直 前の plot 部分だけしか再実行しないことに注意してください。

最後に実行した ‘plot‘ (‘splot‘) コマンドの内容を修正する方法については 以下も参照: ‘command-line-editing‘。

直前の描画コマンドの全体を表示させることや、それを ‘history‘ の中に コピーする方法については、以下も参照: ‘show plot‘。

3.26 reread

reread コマンドは、load コマンドまたはコマンドラインで指定した ‘gnuplot‘ のコマンドファイルを、その次のコマンドが読まれる前に、開 始点に再設定します。これは、コマンドファイルの最初から reread コマ ンドまでのコマンドの無限ループを本質的に実装していることになります。 (しかし、これは何も悪いことではありません。reread は ‘if‘ と組み合 わせることでとても有用なコマンドとなります。) 標準入力からの入力の場合は、reread コマンドは何も影響を与えません。

例:

ファイル "looper" が次のようなファイルで

      a=a+1
      plot sin(x*a)
      pause -1
      if(a<5) reread

そして、‘gnuplot‘ から次のように実行するとします。

      a=0
      load 'looper'

すると、pause のメッセージで分割された 5 回のプロットが行われることに なります。

ファイル "data" が、各行に、0 から 10 までの範囲 (yrange) の 6 つのデ ータ を持ち、最初が x 座標で、その他は 5 つの異なる関数の、その x での 値であるとします。そして、ファイル "plotter" が

      c_p = c_p+1
      plot "$0" using 1:c_p with lines linetype c_p
      if(c_p <  n_p) reread

で、‘gnuplot‘ から次のように実行するとします。

      n_p=6
      c_p=1
      unset key
      set yrange [0:10]
      set multiplot
      call 'plotter' 'data'
      unset multiplot

すると、5 つのプロットを合わせた 1 つのグラフができます。yrange は、 multiplot モードで最初のものに続けて書かれる 5 つのグラフが、同じ軸を 持つように、明示的に指定する必要があります。線種も指定しなければなりま せん。さもないと、全てのグラフが同じ線種で書かれることになります。 アニメーションのサンプルとして、demo ディレクトリの animate.dem も参照 してください。

3.27 reset

コマンド reset は、‘set‘ コマンドで定義できる、グラフに関する全ての オプションをデフォルトの値に戻します。このコマンドは、load したコマン ドファイルを実行した後でデフォルトの設定を復帰したり、設定をたくさん変 更した後で元の状態に戻したいときなどに便利です。

以下のものは、reset の影響を受けません。

     `set term` output `set loadpath` `set fontpath` linetype
     `set encoding` `set decimalsign` `set locale` `set psdir` `set fit`

reset は、必ずしもプログラム立ち上がった初期状態には戻さないことに注 意してください。それは、初期設定ファイル gnuplotrc や $HOME/.gnuplot 内のコマンドでデフォルトの値を変更した場合は、それもリセットされてしま うからです。しかし ‘reset session‘ とすれば、それらのコマンドも再実行 します。

‘reset session‘ は、ユーザ定義変数、ユーザ定義関数すべてを削除し、デフ ォルトの設定を復帰し、システム全体の初期設定ファイル gnuplotrc と個人 用の初期設定ファイル $HOME/.gnuplot を再実行します。以下参照: ‘initialization‘。

‘reset errors‘ は、エラー状態変数 GPVAL_ERRNO と GPVAL_ERRMSG のみをク リアします。

‘reset bind‘ は、キー定義をデフォルトの状態に復帰します。

3.28 save

書式:

      save  {functions | variables | terminal | set | fit} '<filename>'

どれも指定しなかった場合は、‘gnuplot‘ は、ユーザ定義関数、変数、set で 設定するオプション、最後に実行した ‘plot‘ (または ‘splot‘) コマンドの 全てを保存します。

save は、テキスト形式で出力します。また、このファイルは load コマ ンドで読み込むことができます。‘set‘ オプション付き、または何もオプショ ンをつけずに save を実行した場合、terminal の選択と output のフ ァイル名はコメント記号つきで書き出されます。これはその出力ファイルを 他の環境にインストールされた gnuplot 上で動かす場合に、修正なしに使え るようにする、あるいはうっかりファイルを上書きしてしまったりする危険性 を避ける、といった意味があります。

terminal は、terminal の状態を、コメント記号をつけずに書き出 します。これは主に、ちょっとの間だけ terminal の設定を入れ替え、その 後保存しておいた terminal の状態を読み込むことで以前の terminal の設 定に戻す場合などに役立ちます。ただ、単一の gnuplot セッションでは、現 在の terminal を保存/復元する他の方法であるコマンド ‘set term push‘ と ‘set term pop‘ を使う方がむしろいいかもしれません。以下参照: ‘set term‘。

‘save fit‘ は、直近の ‘fit‘ コマンドで使用した変数のみを保存します。そ の保存ファイルは、後で ‘via‘ キーワードを使うことで fit コマンドの初期 化用のパラメータファイルとして利用できます。

ファイル名は引用符に囲われていなければなりません。

特別なファイル名 "-" により save コマンドに標準出力に出力させること ができます。popen 関数をサポートするようなシステム (Unix など) では、 save の出力をパイプ経由で他の外部プログラムに渡すことができます。その 場合、ファイル名としてコマンド名の先頭に ’|’ をつけたものを使います。 これは、‘gnuplot‘ とパイプを通して通信するプログラムに、‘gnuplot‘ の内 部設定に関する首尾一貫したインターフェースを提供します。詳細は、以下参 照: ‘batch/interactive‘。

例:

      save 'work.gnu'
      save functions 'func.dat'
      save var 'var.dat'
      save set 'options.dat'
      save term 'myterm.gnu'
      save '-'
      save '|grep title >t.gp'

3.29 set-show

‘set‘ コマンドは実に多くのオプションを設定するのに使われます。しかし、 ‘plot‘, ‘splot‘, replot コマンドが与えられるまで何も表示しません。

‘show‘ コマンドはそれらの設定値を表示します。‘show all‘ でそれら全て を表示します。

‘set‘ コマンドで変更されたオプションは、それに対応する unset コマン ドを実行することでデフォルトの状態に戻すことができます。以下も参照: reset。これは全てのパラメータの設定をデフォルトの値に戻します。

‘set‘ と unset コマンドには繰り返し節も利用できます。以下参照: ‘plot for‘。