34.75 Xtics

x 軸の (見出しのつく) 大目盛りは コマンド set xtics で制御できます。 目盛りは set noxtics で消え、set xtics で (デフォルトの状態の) 目 盛りがつきます。y,z,x2,y2 軸の大目盛りの制御を行なう同様のコマンドがあ ります。

書式:

     set xtics {axis | border} {{no}mirror} {{no}rotate}
               {  autofreq
                | <incr>
                | <start>, <incr> {,<end>}
                | ({"<label>"} <pos> {,{"<label>"} <pos>}...) }
     set noxtics
     show xtics

同じ書式が ytics, ztics, x2tics, y2tics にも適用されます。

axis と border は gnuplot に目盛り (目盛りの刻自身とその見出し) を、それぞれ軸につけるのか、境界につけるのかを指示します。軸が境界にと ても近い場合、axis を使用すると目盛りの見出し文字が余白に書かれてい る他の文字に重ってしまう可能性があります。

mirror は gnuplot に反対側の境界の同じ位置に、見出しのない目盛りを 出力するよう指示します。nomirror は、あなたが思っている通りのことを 行ないます。

rotate は、文字列を 90 度回転させて出力させようとします。これは、文 字列の回転をサポートしている出力ドライバ (terminal) では実行されます。 norotate はこれをキャンセルします。

x と y 軸の大目盛りのデフォルトは border mirror norotate で、x2, y2 軸は border nomirror norotate がデフォルトです。z 軸には、{axis $\vert$ border} オプションは無効で、デフォルトは nomirror です。z 軸の目盛 りをミラー化したいなら、多分 set border でそのための空間をあける必要 があるでしょう。

オプションなしで set xtics を実行すると、目盛りが表示される状態であ れば、それはデフォルトの境界、または軸を復元し、そうでなければ何もしま せん。その前に指定した目盛りの間隔、位置 (と見出し) は保持されます。

目盛りの位置は、デフォルト、またはオプション autofreq が指定されてい れば自動的に計算されます。そうでなければ、次の 2 つの形式で指定されま す:

暗示的な $<$start$>$, $<$incr$>$, $<$end$>$ 形式は、目盛りの列を $<$start$>$ から $<$end$>$ の間を $<$incr$>$ の間隔で表示します。$<$end$>$ を指定しなければ、それは無限大 とみなされます。$<$incr$>$ は負の値も可能です。$<$start$>$ と $<$end$>$ の両方が指 定されていない場合、$<$start$>$ は -∞、$<$end$>$ は +∞とみなされ、目盛りは $<$incr$>$ の整数倍の位置に表示されます。軸が対数軸の場合、目盛りの間隔 (増分) は、積因子として使用されます。

例:

目盛りを 0, 0.5, 1, 1.5, ..., 9.5, 10 の位置に生成

     set xtics 0,.5,10

目盛りを ..., -10, -5, 0, 5, 10, ... に生成

     set xtics 5

目盛りを 1, 100, 1e4, 1e6, 1e8 に生成

     set logscale x; set xtics 1,100,1e8

明示的な ("$<$label$>$" $<$pos$>$, ...) の形式は、任意の目盛りの位置、あるいは 数字でない見出しの生成も可能にします。目盛りの一揃いは、位置とその見出 しからなる組の集合です。見出しは二重引用符で囲まれた文字列であることに 注意してください。それは、"hello" のような固定文字列でも構いませんし、 "%3f clients" のようにその位置を数字に変換する書式文字列を含んでも構い ませんし、空文字列 "" でも構いません。より詳しい情報については set format を参照してください。もし、文字列が与えられなければ、デフォルト の数字の見出しが使用されます。この形式では、目盛りは位置の数字の順に与 える必要はありません。

例:

     set xtics ("low" 0, "medium" 50, "high" 100)
     set xtics (1,2,4,8,16,32,64,128,256,512,1024)
     set ytics ("bottom" 0, "" 10, "top" 20)

2 番目の例では、全ての目盛りが見出し付けされます。3 番目の例では、端の ものだけが見出し付けされます。

しかし指定しても、表示されるのはあくまで描画範囲のものだけです。

目盛りの見出しの書式 (または省略) は set format で制御されます。ただ しそれは set xtics ($<$label$>$) の形式の明示的な見出し文字列が含まれ ていない場合だけです。

(見出し付けされない) 小目盛りは set mxtics コマンドで追加することが 出来ます。

時系列データの場合、位置の値は timefmt の書式にしたがった日付、また は時刻を引用符で囲んで与えなければいけません。$<$start$>$, $<$incr$>$, $<$end$>$ 形式を使う場合、$<$start$>$ と $<$end$>$ は timefmt に従って与えますが、 $<$incr$>$ は秒単位で与える必要があります。その時刻は実際には set format で与えた書式に従って表示されます。

例:

     set xdata time
     set timefmt "%d/%m"
     set format x "%b %d"
     set xrange ["01/12":"06/12"]
     set xtics "01/12", 172800, "05/12"

     set xdata time
     set timefmt "%d/%m"
     set format x "%b %d"
     set xrange ["01/12":"06/12"]
     set xtics ("01/12", "" "03/12", "05/12")

これらは両方とも "Dec 1", "Dec 3", "Dec 5", の目盛りを生成しますが、2 番目の例 "Dec 3" の目盛りは見出し付けされません。